src/PVE/LXC/Migrate.pm

   1 package PVE::LXC::Migrate;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::AbstractMigrate;
   6 use File::Basename;
   7 use File::Copy; # fixme: remove
   8 use PVE::Tools;
   9 use PVE::INotify;
  10 use PVE::Cluster;
  11 use PVE::Storage;
  12 use PVE::LXC::Config;
  13 use PVE::LXC;
  14 use PVE::ReplicationConfig;
  15 use PVE::ReplicationState;
  16 use PVE::Replication;
  17
  18 use base qw(PVE::AbstractMigrate);
  19
  20 sub lock_vm {
  21     my ($self, $vmid, $code, @param) = @_;
  22
  23     return PVE::LXC::Config->lock_config($vmid, $code, @param);
  24 }
  25
  26 sub prepare {
  27     my ($self, $vmid) = @_;
  28
  29     my $online = $self->{opts}->{online};
  30     my $restart= $self->{opts}->{restart};
  31
  32     $self->{storecfg} = PVE::Storage::config();
  33
  34     # test if CT exists
  35     my $conf = $self->{vmconf} = PVE::LXC::Config->load_config($vmid);
  36
  37     PVE::LXC::Config->check_lock($conf);
  38
  39     my $running = 0;
  40     if (PVE::LXC::check_running($vmid)) {
  41         die "lxc live migration is currently not implemented\n" if $online;
  42         die "running container can only be migrated in restart mode" if !$restart;
  43         $running = 1;
  44     }
  45     $self->{was_running} = $running;
  46
  47     my $force = $self->{opts}->{force} // 0;
  48     my $need_activate = [];
  49
  50     PVE::LXC::Config->foreach_volume($conf, sub {
  51         my ($ms, $mountpoint) = @_;
  52
  53         my $volid = $mountpoint->{volume};
  54         my $type = $mountpoint->{type};
  55
  56         # skip dev/bind mps when forced / shared
  57         if ($type ne 'volume') {
  58             if ($force) {
  59                 warn "-force is deprecated, please use the 'shared' property on individual non-volume mount points instead!\n";
  60                 return;
  61             }
  62             if ($mountpoint->{shared}) {
  63                 return;
  64             } else {
  65                 die "cannot migrate local $type mount point '$ms'\n";
  66             }
  67         }
  68
  69         my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1) if $volid;
  70         die "can't determine assigned storage for mount point '$ms'\n" if !$storage;
  71
  72         # check if storage is available on both nodes
  73         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $storage);
  74         PVE::Storage::storage_check_node($self->{storecfg}, $storage, $self->{node});
  75
  76
  77         if ($scfg->{shared}) {
  78             # PVE::Storage::activate_storage checks this for non-shared storages
  79             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
  80             warn "Used shared storage '$storage' is not online on source node!\n"
  81                 if !$plugin->check_connection($storage, $scfg);
  82         } else {
  83             # only activate if not shared
  84             push @$need_activate, $volid;
  85
  86             # unless in restart mode because we shut the container down
  87             die "unable to migrate local mount point '$volid' while CT is running"
  88                 if $running && !$restart;
  89         }
  90
  91     });
  92
  93     PVE::Storage::activate_volumes($self->{storecfg}, $need_activate);
  94
  95     # todo: test if VM uses local resources
  96
  97     # test ssh connection
  98     my $cmd = [ @{$self->{rem_ssh}}, '/bin/true' ];
  99     eval { $self->cmd_quiet($cmd); };
 100     die "Can't connect to destination address using public key\n" if $@;
 101
 102     # in restart mode, we shutdown the container before migrating
 103     if ($restart && $running) {
 104         my $timeout = $self->{opts}->{timeout} // 180;
 105
 106         $self->log('info', "shutdown CT $vmid\n");
 107
 108         PVE::LXC::vm_stop($vmid, 0, $timeout);
 109
 110         $running = 0;
 111     }
 112
 113     return $running;
 114 }
 115
 116 sub phase1 {
 117     my ($self, $vmid) = @_;
 118
 119     $self->log('info', "starting migration of CT $self->{vmid} to node '$self->{node}' ($self->{nodeip})");
 120
 121     my $conf = $self->{vmconf};
 122     $conf->{lock} = 'migrate';
 123     PVE::LXC::Config->write_config($vmid, $conf);
 124
 125     if ($self->{running}) {
 126         $self->log('info', "container is running - using online migration");
 127     }
 128
 129     $self->{volumes} = []; # list of already migrated volumes
 130     my $volhash = {}; # 'config', 'snapshot' or 'storage' for local volumes
 131     my $volhash_errors = {};
 132     my $abort = 0;
 133
 134     my $log_error = sub {
 135         my ($msg, $volid) = @_;
 136
 137         $volhash_errors->{$volid} = $msg if !defined($volhash_errors->{$volid});
 138         $abort = 1;
 139     };
 140
 141     my $test_volid = sub {
 142         my ($volid, $snapname) = @_;
 143
 144         return if !$volid;
 145
 146         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 147
 148         # check if storage is available on both nodes
 149         my $scfg = PVE::Storage::storage_check_node($self->{storecfg}, $sid);
 150         PVE::Storage::storage_check_node($self->{storecfg}, $sid, $self->{node});
 151
 152         if ($scfg->{shared}) {
 153             $self->log('info', "volume '$volid' is on shared storage '$sid'")
 154                 if !$snapname;
 155             return;
 156         }
 157
 158         $volhash->{$volid}->{ref} = defined($snapname) ? 'snapshot' : 'config';
 159         $volhash->{$volid}->{snapshots} = defined($snapname);
 160
 161         my ($path, $owner) = PVE::Storage::path($self->{storecfg}, $volid);
 162
 163         die "owned by other guest (owner = $owner)\n"
 164             if !$owner || ($owner != $self->{vmid});
 165
 166         if (defined($snapname)) {
 167             # we cannot migrate shapshots on local storage
 168             # exceptions: 'zfspool'
 169             if (($scfg->{type} eq 'zfspool')) {
 170                 return;
 171             }
 172             die "non-migratable snapshot exists\n";
 173         }
 174     };
 175
 176     my $test_mp = sub {
 177         my ($ms, $mountpoint, $snapname) = @_;
 178
 179         my $volid = $mountpoint->{volume};
 180         # already checked in prepare
 181         if ($mountpoint->{type} ne 'volume') {
 182             $self->log('info', "ignoring shared '$mountpoint->{type}' mount point '$ms' ('$volid')")
 183                 if !$snapname;
 184             return;
 185         }
 186
 187         eval {
 188             &$test_volid($volid, $snapname);
 189         };
 190
 191         &$log_error($@, $volid) if $@;
 192     };
 193
 194     # first unused / lost volumes owned by this container
 195     my @sids = PVE::Storage::storage_ids($self->{storecfg});
 196     foreach my $storeid (@sids) {
 197         my $scfg = PVE::Storage::storage_config($self->{storecfg}, $storeid);
 198         next if $scfg->{shared};
 199         next if !PVE::Storage::storage_check_enabled($self->{storecfg}, $storeid, undef, 1);
 200
 201         # get list from PVE::Storage (for unused volumes)
 202         my $dl = PVE::Storage::vdisk_list($self->{storecfg}, $storeid, $vmid);
 203
 204         next if @{$dl->{$storeid}} == 0;
 205
 206         # check if storage is available on target node
 207         PVE::Storage::storage_check_node($self->{storecfg}, $storeid, $self->{node});
 208
 209         PVE::Storage::foreach_volid($dl, sub {
 210             my ($volid, $sid, $volname) = @_;
 211
 212             $volhash->{$volid}->{ref} = 'storage';
 213         });
 214     }
 215
 216     # then all volumes referenced in snapshots
 217     foreach my $snapname (keys %{$conf->{snapshots}}) {
 218         &$test_volid($conf->{snapshots}->{$snapname}->{'vmstate'}, 0, undef)
 219             if defined($conf->{snapshots}->{$snapname}->{'vmstate'});
 220         PVE::LXC::Config->foreach_volume($conf->{snapshots}->{$snapname}, $test_mp, $snapname);
 221     }
 222
 223     # finally all currently used volumes
 224     PVE::LXC::Config->foreach_volume($conf, $test_mp);
 225
 226
 227     # additional checks for local storage
 228     foreach my $volid (keys %$volhash) {
 229         eval {
 230             my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 231             my $scfg =  PVE::Storage::storage_config($self->{storecfg}, $sid);
 232
 233             my $migratable = ($scfg->{type} eq 'dir') || ($scfg->{type} eq 'zfspool') ||
 234                 ($scfg->{type} eq 'lvmthin') || ($scfg->{type} eq 'lvm');
 235
 236             die "storage type '$scfg->{type}' not supported\n"
 237                 if !$migratable;
 238
 239             # image is a linked clone on local storage, se we can't migrate.
 240             if (my $basename = (PVE::Storage::parse_volname($self->{storecfg}, $volid))[3]) {
 241                 die "clone of '$basename'";
 242             }
 243         };
 244         &$log_error($@, $volid) if $@;
 245     }
 246
 247     foreach my $volid (sort keys %$volhash) {
 248         my $ref = $volhash->{$volid}->{ref};
 249         if ($ref eq 'storage') {
 250             $self->log('info', "found local volume '$volid' (via storage)\n");
 251         } elsif ($ref eq 'config') {
 252             $self->log('info', "found local volume '$volid' (in current VM config)\n");
 253         } elsif ($ref eq 'snapshot') {
 254             $self->log('info', "found local volume '$volid' (referenced by snapshot(s))\n");
 255         } else {
 256             $self->log('info', "found local volume '$volid'\n");
 257         }
 258     }
 259
 260     foreach my $volid (sort keys %$volhash_errors) {
 261         $self->log('warn', "can't migrate local volume '$volid': $volhash_errors->{$volid}");
 262     }
 263
 264     if ($abort) {
 265         die "can't migrate CT - check log\n";
 266     }
 267
 268     my $rep_volumes;
 269
 270     my $rep_cfg = PVE::ReplicationConfig->new();
 271
 272     if (my $jobcfg = $rep_cfg->find_local_replication_job($vmid, $self->{node})) {
 273         die "can't live migrate VM with replicated volumes\n" if $self->{running};
 274         my $start_time = time();
 275         my $logfunc = sub { my ($msg) = @_;  $self->log('info', $msg); };
 276         $rep_volumes = PVE::Replication::run_replication(
 277             'PVE::LXC::Config', $jobcfg, $start_time, $start_time, $logfunc);
 278     }
 279
 280     my $opts = $self->{opts};
 281     my $insecure = $opts->{migration_type} eq 'insecure';
 282     foreach my $volid (keys %$volhash) {
 283         next if $rep_volumes->{$volid};
 284         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 285         push @{$self->{volumes}}, $volid;
 286         my $with_snapshots = $volhash->{$volid}->{snapshots};
 287         my $bwlimit = PVE::Storage::get_bandwidth_limit('migration', [$sid], $opts->{bwlimit});
 288         # JSONSchema and get_bandwidth_limit use kbps - storage_migrate bps
 289         $bwlimit = $bwlimit * 1024 if defined($bwlimit);
 290
 291         PVE::Storage::storage_migrate($self->{storecfg}, $volid, $self->{ssh_info}, $sid, undef, undef, undef, $bwlimit, $insecure, $with_snapshots);
 292     }
 293
 294     my $conffile = PVE::LXC::Config->config_file($vmid);
 295     my $newconffile = PVE::LXC::Config->config_file($vmid, $self->{node});
 296
 297     if ($self->{running}) {
 298         die "implement me";
 299     }
 300
 301     # make sure everything on (shared) storage is unmounted
 302     # Note: we must be 100% sure, else we get data corruption because
 303     # non-shared file system could be mounted twice (on shared storage)
 304
 305     PVE::LXC::umount_all($vmid, $self->{storecfg}, $conf);
 306
 307     #to be sure there are no active volumes
 308     my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 309     PVE::Storage::deactivate_volumes($self->{storecfg}, $vollist);
 310
 311    # transfer replication state before move config
 312     $self->transfer_replication_state() if $rep_volumes;
 313
 314     # move config
 315     die "Failed to move config to node '$self->{node}' - rename failed: $!\n"
 316         if !rename($conffile, $newconffile);
 317
 318     $self->{conf_migrated} = 1;
 319
 320     $self->switch_replication_job_target() if $rep_volumes;
 321 }
 322
 323 sub phase1_cleanup {
 324     my ($self, $vmid, $err) = @_;
 325
 326     $self->log('info', "aborting phase 1 - cleanup resources");
 327
 328     if ($self->{volumes}) {
 329         foreach my $volid (@{$self->{volumes}}) {
 330             $self->log('err', "found stale volume copy '$volid' on node '$self->{node}'");
 331             # fixme: try to remove ?
 332         }
 333     }
 334 }
 335
 336 sub phase3 {
 337     my ($self, $vmid) = @_;
 338
 339     my $volids = $self->{volumes};
 340
 341     # destroy local copies
 342     foreach my $volid (@$volids) {
 343         eval { PVE::Storage::vdisk_free($self->{storecfg}, $volid); };
 344         if (my $err = $@) {
 345             $self->log('err', "removing local copy of '$volid' failed - $err");
 346             $self->{errors} = 1;
 347             last if $err =~ /^interrupted by signal$/;
 348         }
 349     }
 350 }
 351
 352 sub final_cleanup {
 353     my ($self, $vmid) = @_;
 354
 355     $self->log('info', "start final cleanup");
 356
 357     if (!$self->{conf_migrated}) {
 358         eval { PVE::LXC::Config->remove_lock($vmid, 'migrate'); };
 359         if (my $err = $@) {
 360             $self->log('err', $err);
 361         }
 362         # in restart mode, we start the container on the source node
 363         # on migration error
 364         if ($self->{opts}->{restart} && $self->{was_running}) {
 365             $self->log('info', "start container on source node");
 366             my $skiplock = 1;
 367             PVE::LXC::vm_start($vmid, $self->{vmconf}, $skiplock);
 368         }
 369     } else {
 370         my $cmd = [ @{$self->{rem_ssh}}, 'pct', 'unlock', $vmid ];
 371         $self->cmd_logerr($cmd, errmsg => "failed to clear migrate lock");
 372
 373         # in restart mode, we start the container on the target node
 374         # after migration
 375         if ($self->{opts}->{restart} && $self->{was_running}) {
 376             $self->log('info', "start container on target node");
 377             my $cmd = [ @{$self->{rem_ssh}}, 'pct', 'start', $vmid];
 378             $self->cmd($cmd);
 379         }
 380     }
 381
 382 }
 383
 384 1;