src/lxc-pve-prestart-hook

   1 #!/usr/bin/perl
   2
   3 package lxc_pve_prestart_hook;
   4
   5 use strict;
   6 use warnings;
   7
   8 exit 0 if $ENV{LXC_NAME} && $ENV{LXC_NAME} !~ /^\d+$/;
   9
  10 use POSIX;
  11 use File::Path;
  12 use Fcntl ':mode';
  13
  14 use PVE::SafeSyslog;
  15 use PVE::Tools;
  16 use PVE::Cluster;
  17 use PVE::INotify;
  18 use PVE::RPCEnvironment;
  19 use PVE::JSONSchema qw(get_standard_option);
  20 use PVE::CLIHandler;
  21 use PVE::Storage;
  22 use PVE::LXC;
  23 use PVE::LXC::Setup;
  24 use Data::Dumper;
  25
  26 use base qw(PVE::CLIHandler);
  27
  28 __PACKAGE__->register_method ({
  29     name => 'lxc-pve-prestart-hook',
  30     path => 'lxc-pve-prestart-hook',
  31     method => 'GET',
  32     description => "Create a new container root directory.",
  33     parameters => {
  34         additionalProperties => 0,
  35         properties => {
  36             name => {
  37                 description => "The container name. This hook is only active for containers using numeric IDs, where configuration is stored on /etc/pve/lxc/<name>.conf (else it is just a NOP).",
  38                 type => 'string',
  39                 pattern => '\S+',
  40                 maxLength => 64,
  41             },
  42             path => {
  43                 description => "The path to the container configuration directory (LXC internal argument - do not pass manually!).",
  44                 type => 'string',
  45             },
  46             rootfs => {
  47                 description => "The path to the container's rootfs (LXC internal argument - do not pass manually!)",
  48                 type => 'string',
  49             },
  50         },
  51     },
  52     returns => { type => 'null' },
  53
  54     code => sub {
  55         my ($param) = @_;
  56
  57         return undef if $param->{name} !~ m/^\d+$/;
  58
  59         my $vmid = $param->{name};
  60         my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
  61         my $skiplock = 1 if -e $skiplock_flag_fn;
  62         unlink $skiplock_flag_fn if $skiplock;
  63
  64         PVE::Cluster::check_cfs_quorum(); # only start if we have quorum
  65
  66         return undef if ! -f PVE::LXC::Config->config_file($vmid);
  67
  68         my $conf = PVE::LXC::Config->load_config($vmid);
  69         if (!$skiplock && !PVE::LXC::Config->has_lock($conf, 'mounted')) {
  70             PVE::LXC::Config->check_lock($conf);
  71         }
  72
  73         my $storage_cfg = PVE::Storage::config();
  74
  75         my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
  76         my $loopdevlist = PVE::LXC::Config->get_vm_volumes($conf, 'rootfs');
  77
  78         PVE::Storage::activate_volumes($storage_cfg, $vollist);
  79
  80         my $rootdir = $param->{rootfs};
  81
  82         # Delete any leftover reboot-trigger file
  83         unlink("/var/lib/lxc/$vmid/reboot");
  84
  85         my $devlist_file = "/var/lib/lxc/$vmid/devices";
  86         unlink $devlist_file;
  87         my $devices = [];
  88
  89         my $setup_mountpoint = sub {
  90             my ($ms, $mountpoint) = @_;
  91
  92             #return if $ms eq 'rootfs';
  93             my (undef, undef, $dev) = PVE::LXC::mountpoint_mount($mountpoint, $rootdir, $storage_cfg);
  94             push @$devices, $dev if $dev && $mountpoint->{quota};
  95         };
  96
  97         PVE::LXC::Config->foreach_mountpoint($conf, $setup_mountpoint);
  98
  99         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 100         $lxc_setup->pre_start_hook();
 101
 102         if (@$devices) {
 103             my $devlist = '';
 104             foreach my $dev (@$devices) {
 105                 my ($mode, $rdev) = (stat($dev))[2,6];
 106                 next if !$mode || !S_ISBLK($mode) || !$rdev;
 107                 my $major = int($rdev / 0x100);
 108                 my $minor = $rdev % 0x100;
 109                 $devlist .= "b:$major:$minor:$dev\n";
 110             }
 111             PVE::Tools::file_set_contents($devlist_file, $devlist);
 112         }
 113         return undef;
 114     }});
 115
 116
 117 push @ARGV, 'help' if !scalar(@ARGV);
 118
 119 my $param = {};
 120
 121 if ((scalar(@ARGV) == 3) && ($ARGV[1] eq 'lxc') && ($ARGV[2] eq 'pre-start')) {
 122     $param->{name} = $ENV{'LXC_NAME'};
 123     die "got wrong name" if $param->{name} ne $ARGV[0];
 124
 125     $param->{path} = $ENV{'LXC_CONFIG_FILE'};
 126     $param->{rootfs} = $ENV{'LXC_ROOTFS_PATH'};
 127     @ARGV = ();
 128 } else {
 129     @ARGV = ('help');
 130 }
 131
 132 our $cmddef = [ __PACKAGE__, 'lxc-pve-prestart-hook', [], $param];
 133
 134 __PACKAGE__->run_cli_handler();