src/test/snapshot-test.pm

   1 package PVE::LXC::Test;
   2
   3 use strict;
   4 use warnings;
   5
   6 use lib qw(..);
   7
   8 use PVE::Storage;
   9 use PVE::Storage::Plugin;
  10 use PVE::LXC;
  11 use PVE::LXC::Config;
  12 use PVE::Tools;
  13
  14 use Test::MockModule;
  15 use Test::More;
  16
  17 my $nodename;
  18 my $snapshot_possible;
  19 my $vol_snapshot_possible = {};
  20 my $vol_snapshot_delete_possible = {};
  21 my $vol_snapshot_rollback_possible = {};
  22 my $vol_snapshot_rollback_enabled = {};
  23 my $vol_snapshot = {};
  24 my $vol_snapshot_delete = {};
  25 my $vol_snapshot_rollback = {};
  26 my $running;
  27 my $freeze_possible;
  28 my $kill_possible;
  29
  30 # Mocked methods
  31
  32 sub mocked_has_feature {
  33     my ($feature, $conf, $storecfg, $snapname) = @_;
  34     return $snapshot_possible;
  35 }
  36
  37 sub mocked_check_running {
  38     return $running;
  39 }
  40
  41 sub mocked_volume_snapshot {
  42     my ($storecfg, $volid, $snapname) = @_;
  43     die "Storage config not mocked! aborting\n"
  44         if defined($storecfg);
  45     die "volid undefined\n"
  46         if !defined($volid);
  47     die "snapname undefined\n"
  48         if !defined($snapname);
  49     if ($vol_snapshot_possible->{$volid}) {
  50         if (defined($vol_snapshot->{$volid})) {
  51             $vol_snapshot->{$volid} .= ",$snapname";
  52         } else {
  53             $vol_snapshot->{$volid} = $snapname;
  54         }
  55         return 1;
  56     } else {
  57         die "volume snapshot disabled\n";
  58     }
  59 }
  60
  61 sub mocked_volume_snapshot_delete {
  62     my ($storecfg, $volid, $snapname) = @_;
  63     die "Storage config not mocked! aborting\n"
  64         if defined($storecfg);
  65     die "volid undefined\n"
  66         if !defined($volid);
  67     die "snapname undefined\n"
  68         if !defined($snapname);
  69     if ($vol_snapshot_delete_possible->{$volid}) {
  70         if (defined($vol_snapshot_delete->{$volid})) {
  71             $vol_snapshot_delete->{$volid} .= ",$snapname";
  72         } else {
  73             $vol_snapshot_delete->{$volid} = $snapname;
  74         }
  75         return 1;
  76     } else {
  77         die "volume snapshot delete disabled\n";
  78     }
  79 }
  80
  81 sub mocked_volume_snapshot_rollback {
  82     my ($storecfg, $volid, $snapname) = @_;
  83     die "Storage config not mocked! aborting\n"
  84         if defined($storecfg);
  85     die "volid undefined\n"
  86         if !defined($volid);
  87     die "snapname undefined\n"
  88         if !defined($snapname);
  89     if ($vol_snapshot_rollback_enabled->{$volid}) {
  90         if (defined($vol_snapshot_rollback->{$volid})) {
  91             $vol_snapshot_rollback->{$volid} .= ",$snapname";
  92         } else {
  93             $vol_snapshot_rollback->{$volid} = $snapname;
  94         }
  95         return 1;
  96     } else {
  97         die "volume snapshot rollback disabled\n";
  98     }
  99 }
 100
 101 sub mocked_volume_rollback_is_possible {
 102     my ($storecfg, $volid, $snapname) = @_;
 103     die "Storage config not mocked! aborting\n"
 104         if defined($storecfg);
 105     die "volid undefined\n"
 106         if !defined($volid);
 107     die "snapname undefined\n"
 108         if !defined($snapname);
 109     return $vol_snapshot_rollback_possible->{$volid}
 110         if ($vol_snapshot_rollback_possible->{$volid});
 111     die "volume_rollback_is_possible failed\n";
 112 }
 113
 114 sub mocked_run_command {
 115     my ($cmd, %param) = @_;
 116     my $cmdstring;
 117     if (my $ref = ref($cmd)) {
 118         $cmdstring = PVE::Tools::cmd2string($cmd);
 119         if ($cmdstring =~ m/.*\/lxc-(un)?freeze.*/) {
 120             return 1 if $freeze_possible;
 121             die "lxc-[un]freeze disabled\n";
 122         }
 123         if ($cmdstring =~ m/.*\/lxc-stop.*--kill.*/) {
 124             if ($kill_possible) {
 125                 $running = 0;
 126                 return 1;
 127             } else {
 128                 return 0;
 129             }
 130         }
 131     }
 132     die "unexpected run_command call: '$cmdstring', aborting\n";
 133 }
 134
 135 # Testing methods
 136
 137 sub test_file {
 138     my ($exp_fn, $real_fn) = @_;
 139     my $ret;
 140     eval {
 141         $ret = system("diff -u '$exp_fn' '$real_fn'");
 142     };
 143     die if $@;
 144     return !$ret;
 145 }
 146
 147 sub testcase_prepare {
 148     my ($vmid, $snapname, $save_vmstate, $comment, $exp_err) = @_;
 149     subtest "Preparing snapshot '$snapname' for vm '$vmid'" => sub {
 150         plan tests => 2;
 151         $@ = undef;
 152         eval {
 153             PVE::LXC::Config->__snapshot_prepare($vmid, $snapname, $save_vmstate, $comment);
 154         };
 155         is($@, $exp_err, "\$@ correct");
 156         ok(test_file("snapshot-expected/prepare/lxc/$vmid.conf", "snapshot-working/prepare/lxc/$vmid.conf"), "config file correct");
 157     };
 158 }
 159
 160 sub testcase_commit {
 161     my ($vmid, $snapname, $exp_err) = @_;
 162     subtest "Committing snapshot '$snapname' for vm '$vmid'" => sub {
 163         plan tests => 2;
 164         $@ = undef;
 165         eval {
 166             PVE::LXC::Config->__snapshot_commit($vmid, $snapname);
 167         };
 168         is($@, $exp_err, "\$@ correct");
 169         ok(test_file("snapshot-expected/commit/lxc/$vmid.conf", "snapshot-working/commit/lxc/$vmid.conf"), "config file correct");
 170     }
 171 }
 172
 173 sub testcase_create {
 174     my ($vmid, $snapname, $save_vmstate, $comment, $exp_err, $exp_vol_snap, $exp_vol_snap_delete) = @_;
 175     subtest "Creating snapshot '$snapname' for vm '$vmid'" => sub {
 176         plan tests => 4;
 177         $vol_snapshot = {};
 178         $vol_snapshot_delete = {};
 179         $exp_vol_snap = {} if !defined($exp_vol_snap);
 180         $exp_vol_snap_delete = {} if !defined($exp_vol_snap_delete);
 181         $@ = undef;
 182         eval {
 183             PVE::LXC::Config->snapshot_create($vmid, $snapname, $save_vmstate, $comment);
 184         };
 185         is($@, $exp_err, "\$@ correct");
 186         is_deeply($vol_snapshot, $exp_vol_snap, "created correct volume snapshots");
 187         is_deeply($vol_snapshot_delete, $exp_vol_snap_delete, "deleted correct volume snapshots");
 188         ok(test_file("snapshot-expected/create/lxc/$vmid.conf", "snapshot-working/create/lxc/$vmid.conf"), "config file correct");
 189     };
 190 }
 191
 192 sub testcase_delete {
 193     my ($vmid, $snapname, $force, $exp_err, $exp_vol_snap_delete) = @_;
 194     subtest "Deleting snapshot '$snapname' of vm '$vmid'" => sub {
 195         plan tests => 3;
 196         $vol_snapshot_delete = {};
 197         $exp_vol_snap_delete = {} if !defined($exp_vol_snap_delete);
 198         $@ = undef;
 199         eval {
 200             PVE::LXC::Config->snapshot_delete($vmid, $snapname, $force);
 201         };
 202         is($@, $exp_err, "\$@ correct");
 203         is_deeply($vol_snapshot_delete, $exp_vol_snap_delete, "deleted correct volume snapshots");
 204         ok(test_file("snapshot-expected/delete/lxc/$vmid.conf", "snapshot-working/delete/lxc/$vmid.conf"), "config file correct");
 205     };
 206 }
 207
 208 sub testcase_rollback {
 209     my ($vmid, $snapname, $exp_err, $exp_vol_snap_rollback) = @_;
 210     subtest "Rolling back to snapshot '$snapname' of vm '$vmid'" => sub {
 211         plan tests => 3;
 212         $vol_snapshot_rollback = {};
 213         $running = 1;
 214         $exp_vol_snap_rollback = {} if !defined($exp_vol_snap_rollback);
 215         $@ = undef;
 216         eval {
 217             PVE::LXC::Config->snapshot_rollback($vmid, $snapname);
 218         };
 219         is($@, $exp_err, "\$@ correct");
 220         is_deeply($vol_snapshot_rollback, $exp_vol_snap_rollback, "rolled back to correct volume snapshots");
 221         ok(test_file("snapshot-expected/rollback/lxc/$vmid.conf", "snapshot-working/rollback/lxc/$vmid.conf"), "config file correct");
 222     };
 223 }
 224
 225 # BEGIN mocked PVE::LXC::Config methods
 226 sub mocked_config_file_lock {
 227     return "snapshot-working/pve-test.lock";
 228 }
 229
 230 sub mocked_cfs_config_path {
 231     my ($class, $vmid, $node) = @_;
 232
 233     $node = $nodename if !$node;
 234     return "snapshot-working/$node/lxc/$vmid.conf";
 235 }
 236
 237 sub mocked_load_config {
 238     my ($class, $vmid, $node) = @_;
 239
 240     my $filename = PVE::LXC::Config->cfs_config_path($vmid, $node);
 241
 242     my $raw = PVE::Tools::file_get_contents($filename);
 243
 244     my $conf = PVE::LXC::Config::parse_pct_config($filename, $raw);
 245     return $conf;
 246 }
 247
 248 sub mocked_write_config {
 249     my ($class, $vmid, $conf) = @_;
 250
 251     my $filename = PVE::LXC::Config->cfs_config_path($vmid);
 252
 253     if ($conf->{snapshots}) {
 254         foreach my $snapname (keys %{$conf->{snapshots}}) {
 255             $conf->{snapshots}->{$snapname}->{snaptime} = "1234567890"
 256                 if $conf->{snapshots}->{$snapname}->{snaptime};
 257         }
 258     }
 259
 260     my $raw = PVE::LXC::Config::write_pct_config($filename, $conf);
 261
 262     PVE::Tools::file_set_contents($filename, $raw);
 263 }
 264
 265 # END mocked PVE::LXC methods
 266
 267
 268 PVE::Tools::run_command("rm -rf snapshot-working");
 269 PVE::Tools::run_command("cp -a snapshot-input snapshot-working");
 270
 271 printf("\n");
 272 printf("Setting up Mocking for PVE::LXC and PVE::LXC::Config\n");
 273 my $lxc_module = new Test::MockModule('PVE::LXC');
 274 $lxc_module->mock('sync_container_namespace', sub { return; });
 275 $lxc_module->mock('check_running', \&mocked_check_running);
 276
 277 my $lxc_config_module = new Test::MockModule('PVE::LXC::Config');
 278 $lxc_config_module->mock('config_file_lock', sub { return "snapshot-working/pve-test.lock"; });
 279 $lxc_config_module->mock('cfs_config_path', \&mocked_cfs_config_path);
 280 $lxc_config_module->mock('load_config', \&mocked_load_config);
 281 $lxc_config_module->mock('write_config', \&mocked_write_config);
 282 $lxc_config_module->mock('has_feature', \&mocked_has_feature);
 283
 284 $running = 1;
 285 $freeze_possible = 1;
 286
 287 printf("\n");
 288 printf("Running prepare tests\n");
 289 printf("\n");
 290 $nodename = "prepare";
 291
 292 printf("\n");
 293 printf("Setting has_feature to return true\n");
 294 printf("\n");
 295 $snapshot_possible = 1;
 296
 297 printf("Successful snapshot_prepare with no existing snapshots\n");
 298 testcase_prepare("101", "test", 0, "test comment", '');
 299
 300 printf("Successful snapshot_prepare with one existing snapshot\n");
 301 testcase_prepare("102", "test2", 0, "test comment", "");
 302
 303 printf("Expected error for snapshot_prepare on locked container\n");
 304 testcase_prepare("200", "test", 0, "test comment", "CT is locked (snapshot)\n");
 305
 306 printf("Expected error for snapshot_prepare with duplicate snapshot name\n");
 307 testcase_prepare("201", "test", 0, "test comment", "snapshot name 'test' already used\n");
 308
 309 printf("Expected error for snapshot_prepare with save_vmstate\n");
 310 testcase_prepare("202", "test", 1, "test comment", "implement me - snapshot_save_vmstate\n");
 311
 312 printf("\n");
 313 printf("Setting has_feature to return false\n");
 314 printf("\n");
 315 $snapshot_possible = 0;
 316
 317 printf("Expected error for snapshot_prepare if snapshots not possible\n");
 318 testcase_prepare("300", "test", 0, "test comment", "snapshot feature is not available\n");
 319
 320 printf("\n");
 321 printf("Running commit tests\n");
 322 printf("\n");
 323 $nodename = "commit";
 324
 325 printf("\n");
 326 printf("Setting has_feature to return true\n");
 327 printf("\n");
 328 $snapshot_possible = 1;
 329
 330 printf("Successful snapshot_commit with one prepared snapshot\n");
 331 testcase_commit("101", "test", "");
 332
 333 printf("Successful snapshot_commit with one committed and one prepared snapshot\n");
 334 testcase_commit("102", "test2", "");
 335
 336 printf("Expected error for snapshot_commit with no snapshot lock\n");
 337 testcase_commit("201", "test", "missing snapshot lock\n");
 338
 339 printf("Expected error for snapshot_commit with invalid snapshot name\n");
 340 testcase_commit("202", "test", "snapshot 'test' does not exist\n");
 341
 342 printf("Expected error for snapshot_commit with invalid snapshot state\n");
 343 testcase_commit("203", "test", "wrong snapshot state\n");
 344
 345 $vol_snapshot_possible->{"local:snapshotable-disk-1"} = 1;
 346 $vol_snapshot_possible->{"local:snapshotable-disk-2"} = 1;
 347 $vol_snapshot_possible->{"local:snapshotable-disk-3"} = 1;
 348 $vol_snapshot_delete_possible->{"local:snapshotable-disk-1"} = 1;
 349 $vol_snapshot_rollback_enabled->{"local:snapshotable-disk-1"} = 1;
 350 $vol_snapshot_rollback_enabled->{"local:snapshotable-disk-2"} = 1;
 351 $vol_snapshot_rollback_enabled->{"local:snapshotable-disk-3"} = 1;
 352 $vol_snapshot_rollback_possible->{"local:snapshotable-disk-1"} = 1;
 353 $vol_snapshot_rollback_possible->{"local:snapshotable-disk-2"} = 1;
 354 $vol_snapshot_rollback_possible->{"local:snapshotable-disk-3"} = 1;
 355
 356 # possible, but fails
 357 $vol_snapshot_rollback_possible->{"local:snapshotable-disk-4"} = 1;
 358
 359 printf("\n");
 360 printf("Setting up Mocking for PVE::Storage\n");
 361 my $storage_module = new Test::MockModule('PVE::Storage');
 362 $storage_module->mock('config', sub { return undef; });
 363 $storage_module->mock('volume_snapshot', \&mocked_volume_snapshot);
 364 $storage_module->mock('volume_snapshot_delete', \&mocked_volume_snapshot_delete);
 365 $storage_module->mock('volume_snapshot_rollback', \&mocked_volume_snapshot_rollback);
 366 $storage_module->mock('volume_rollback_is_possible', \&mocked_volume_rollback_is_possible);
 367 printf("\tconfig(), volume_snapshot(), volume_snapshot_delete(), volume_snapshot_rollback() and volume_rollback_is_possible() mocked\n");
 368
 369 printf("\n");
 370 printf("Setting up Mocking for PVE::Tools\n");
 371 my $tools_module = new Test::MockModule('PVE::Tools');
 372 $tools_module->mock('run_command' => \&mocked_run_command);
 373 printf("\trun_command() mocked\n");
 374
 375 $nodename = "create";
 376 printf("\n");
 377 printf("Running create tests\n");
 378 printf("\n");
 379
 380 printf("Successful snapshot_create with no existing snapshots\n");
 381 testcase_create("101", "test", 0, "test comment", "", { "local:snapshotable-disk-1" => "test" });
 382
 383 printf("Successful snapshot_create with one existing snapshots\n");
 384 testcase_create("102", "test2", 0, "test comment", "", { "local:snapshotable-disk-1" => "test2" });
 385
 386 printf("Successful snapshot_create with multiple mps\n");
 387 testcase_create("103", "test", 0, "test comment", "", { "local:snapshotable-disk-1" => "test", "local:snapshotable-disk-2" => "test", "local:snapshotable-disk-3" => "test" });
 388
 389 printf("Expected error for snapshot_create when volume snapshot is not possible\n");
 390 testcase_create("201", "test", 0, "test comment", "volume snapshot disabled\n\n");
 391
 392 printf("Expected error for snapshot_create with broken lxc-freeze\n");
 393 $freeze_possible = 0;
 394 testcase_create("202", "test", 0, "test comment", "lxc-[un]freeze disabled\n\n");
 395 $freeze_possible = 1;
 396
 397 printf("Expected error for snapshot_create when mp volume snapshot is not possible\n");
 398 testcase_create("203", "test", 0, "test comment", "volume snapshot disabled\n\n", { "local:snapshotable-disk-1" => "test" }, { "local:snapshotable-disk-1" => "test" });
 399
 400 $nodename = "delete";
 401 printf("\n");
 402 printf("Running delete tests\n");
 403 printf("\n");
 404
 405 printf("Successful snapshot_delete of only existing snapshot\n");
 406 testcase_delete("101", "test", 0, "", { "local:snapshotable-disk-1" => "test" });
 407
 408 printf("Successful snapshot_delete of leaf snapshot\n");
 409 testcase_delete("102", "test2", 0, "", { "local:snapshotable-disk-1" => "test2" });
 410
 411 printf("Successful snapshot_delete of root snapshot\n");
 412 testcase_delete("103", "test", 0, "", { "local:snapshotable-disk-1" => "test" });
 413
 414 printf("Successful snapshot_delete of intermediate snapshot\n");
 415 testcase_delete("104", "test2", 0, "", { "local:snapshotable-disk-1" => "test2" });
 416
 417 printf("Successful snapshot_delete with broken volume_snapshot_delete and force=1\n");
 418 testcase_delete("105", "test", 1, "");
 419
 420 printf("Successful snapshot_delete with mp broken volume_snapshot_delete and force=1\n");
 421 testcase_delete("106", "test", 1, "", { "local:snapshotable-disk-1" => "test" });
 422
 423 printf("Expected error when snapshot_delete fails with broken volume_snapshot_delete and force=0\n");
 424 testcase_delete("201", "test", 0, "volume snapshot delete disabled\n");
 425
 426 printf("Expected error when snapshot_delete fails with broken mp volume_snapshot_delete and force=0\n");
 427 testcase_delete("203", "test", 0, "volume snapshot delete disabled\n", { "local:snapshotable-disk-1" => "test" });
 428
 429 printf("Expected error for snapshot_delete with locked config\n");
 430 testcase_delete("202", "test", 0, "CT is locked (backup)\n");
 431
 432 $nodename = "rollback";
 433 printf("\n");
 434 printf("Running rollback tests\n");
 435 printf("\n");
 436
 437 $kill_possible = 1;
 438
 439 printf("Successful snapshot_rollback to only existing snapshot\n");
 440 testcase_rollback("101", "test", "", { "local:snapshotable-disk-1" => "test" });
 441
 442 printf("Successful snapshot_rollback to leaf snapshot\n");
 443 testcase_rollback("102", "test2", "", { "local:snapshotable-disk-1" => "test2" });
 444
 445 printf("Successful snapshot_rollback to root snapshot\n");
 446 testcase_rollback("103", "test", "", { "local:snapshotable-disk-1" => "test" });
 447
 448 printf("Successful snapshot_rollback to intermediate snapshot\n");
 449 testcase_rollback("104", "test2", "", { "local:snapshotable-disk-1" => "test2" });
 450
 451 printf("Successful snapshot_rollback with multiple mp\n");
 452 testcase_rollback("105", "test", "", { "local:snapshotable-disk-1" => "test", "local:snapshotable-disk-2" => "test", "local:snapshotable-disk-3" => "test" });
 453
 454 printf("Expected error for snapshot_rollback with non-existing snapshot\n");
 455 testcase_rollback("201", "test2", "snapshot 'test2' does not exist\n");
 456
 457 printf("Expected error for snapshot_rollback if volume rollback not possible\n");
 458 testcase_rollback("202", "test", "volume_rollback_is_possible failed\n");
 459
 460 printf("Expected error for snapshot_rollback with incomplete snapshot\n");
 461 testcase_rollback("203", "test", "unable to rollback to incomplete snapshot (snapstate = delete)\n");
 462
 463 printf("Expected error for snapshot_rollback with lock\n");
 464 testcase_rollback("204", "test", "CT is locked (backup)\n");
 465
 466 printf("Expected error for snapshot_rollback with saved vmstate\n");
 467 testcase_rollback("205", "test", "implement me - save vmstate\n", { "local:snapshotable-disk-1" => "test" });
 468
 469 $kill_possible = 0;
 470
 471 printf("Expected error for snapshot_rollback with unkillable container\n");
 472 testcase_rollback("206", "test", "unable to rollback vm 206: vm is running\n");
 473
 474 $kill_possible = 1;
 475
 476 printf("Expected error for snapshot_rollback with mp rollback_is_possible failure\n");
 477 testcase_rollback("207", "test", "volume_rollback_is_possible failed\n");
 478
 479 printf("Expected error for snapshot_rollback with mp rollback failure (results in inconsistent state)\n");
 480 testcase_rollback("208", "test", "volume snapshot rollback disabled\n", { "local:snapshotable-disk-1" => "test", "local:snapshotable-disk-2" => "test" });
 481
 482 done_testing();