src/PVE/Firewall.pm

   1 package PVE::Firewall;
   2
   3 use warnings;
   4 use strict;
   5 use POSIX;
   6 use Data::Dumper;
   7 use Digest::SHA;
   8 use Socket qw(AF_INET6 inet_ntop inet_pton);
   9 use PVE::INotify;
  10 use PVE::Exception qw(raise raise_param_exc);
  11 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  12 use PVE::Cluster;
  13 use PVE::ProcFSTools;
  14 use PVE::Tools qw($IPV4RE $IPV6RE);
  15 use File::Basename;
  16 use File::Path;
  17 use IO::File;
  18 use Net::IP;
  19 use PVE::Tools qw(run_command lock_file dir_glob_foreach);
  20 use Encode;
  21
  22 my $hostfw_conf_filename = "/etc/pve/local/host.fw";
  23 my $pvefw_conf_dir = "/etc/pve/firewall";
  24 my $clusterfw_conf_filename = "$pvefw_conf_dir/cluster.fw";
  25
  26 # dynamically include PVE::QemuServer and PVE::OpenVZ
  27 # to avoid dependency problems
  28 my $have_qemu_server;
  29 eval {
  30     require PVE::QemuServer;
  31     $have_qemu_server = 1;
  32 };
  33
  34 my $have_pve_manager;
  35 eval {
  36     require PVE::OpenVZ;
  37     $have_pve_manager = 1;
  38 };
  39
  40 my $pve_fw_status_dir = "/var/lib/pve-firewall";
  41
  42 mkdir $pve_fw_status_dir; # make sure this exists
  43
  44 my $security_group_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  45 my $ipset_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  46 our $ip_alias_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  47
  48 my $max_alias_name_length = 64;
  49 my $max_ipset_name_length = 64;
  50 my $max_group_name_length = 20;
  51
  52 PVE::JSONSchema::register_format('IPorCIDR', \&pve_verify_ip_or_cidr);
  53 sub pve_verify_ip_or_cidr {
  54     my ($cidr, $noerr) = @_;
  55
  56     if ($cidr =~ m!^(?:$IPV6RE|$IPV4RE)(/(\d+))?$!) {
  57         return $cidr if Net::IP->new($cidr);
  58         return undef if $noerr;
  59         die Net::IP::Error() . "\n";
  60     }
  61     return undef if $noerr;
  62     die "value does not look like a valid IP address or CIDR network\n";
  63 }
  64
  65 PVE::JSONSchema::register_format('IPorCIDRorAlias', \&pve_verify_ip_or_cidr_or_alias);
  66 sub pve_verify_ip_or_cidr_or_alias {
  67     my ($cidr, $noerr) = @_;
  68
  69     return if $cidr =~ m/^(?:$ip_alias_pattern)$/;
  70
  71     return pve_verify_ip_or_cidr($cidr, $noerr);
  72 }
  73
  74 PVE::JSONSchema::register_standard_option('ipset-name', {
  75     description => "IP set name.",
  76     type => 'string',
  77     pattern => $ipset_name_pattern,
  78     minLength => 2,
  79     maxLength => $max_ipset_name_length,
  80 });
  81
  82 PVE::JSONSchema::register_standard_option('pve-fw-alias', {
  83     description => "Alias name.",
  84     type => 'string',
  85     pattern => $ip_alias_pattern,
  86     minLength => 2,
  87     maxLength => $max_alias_name_length,
  88 });
  89
  90 PVE::JSONSchema::register_standard_option('pve-fw-loglevel' => {
  91     description => "Log level.",
  92     type => 'string',
  93     enum => ['emerg', 'alert', 'crit', 'err', 'warning', 'notice', 'info', 'debug', 'nolog'],
  94     optional => 1,
  95 });
  96
  97 PVE::JSONSchema::register_standard_option('pve-security-group-name', {
  98     description => "Security Group name.",
  99     type => 'string',
 100     pattern => $security_group_name_pattern,
 101     minLength => 2,
 102     maxLength => $max_group_name_length,
 103 });
 104
 105 my $feature_ipset_nomatch = 0;
 106 eval  {
 107     my (undef, undef, $release) = POSIX::uname();
 108     if ($release =~ m/^(\d+)\.(\d+)\.\d+-/) {
 109         my ($major, $minor) = ($1, $2);
 110         $feature_ipset_nomatch = 1 if ($major > 3) ||
 111             ($major == 3 && $minor >= 7);
 112     }
 113
 114 };
 115
 116 my $nodename = PVE::INotify::nodename();
 117
 118 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
 119
 120 my $default_log_level = 'nolog'; # avoid logs by default
 121
 122 my $log_level_hash = {
 123     debug => 7,
 124     info => 6,
 125     notice => 5,
 126     warning => 4,
 127     err => 3,
 128     crit => 2,
 129     alert => 1,
 130     emerg => 0,
 131 };
 132
 133 # we need to overwrite some macros for ipv6
 134 my $pve_ipv6fw_macros = {
 135     'Ping' => [
 136         { action => 'PARAM', proto => 'icmpv6', dport => 'echo-request' },
 137     ],
 138     'Trcrt' => [
 139         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 140         { action => 'PARAM', proto => 'icmpv6', dport => 'echo-request' },
 141     ],
 142  };
 143
 144 # imported/converted from: /usr/share/shorewall/macro.*
 145 my $pve_fw_macros = {
 146     'Amanda' => [
 147         "Amanda Backup",
 148         { action => 'PARAM', proto => 'udp', dport => '10080' },
 149         { action => 'PARAM', proto => 'tcp', dport => '10080' },
 150     ],
 151     'Auth' => [
 152         "Auth (identd) traffic",
 153         { action => 'PARAM', proto => 'tcp', dport => '113' },
 154     ],
 155     'BGP' => [
 156         "Border Gateway Protocol traffic",
 157         { action => 'PARAM', proto => 'tcp', dport => '179' },
 158     ],
 159     'BitTorrent' => [
 160         "BitTorrent traffic for BitTorrent 3.1 and earlier",
 161         { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
 162         { action => 'PARAM', proto => 'udp', dport => '6881' },
 163     ],
 164     'BitTorrent32' => [
 165         "BitTorrent traffic for BitTorrent 3.2 and later",
 166         { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
 167         { action => 'PARAM', proto => 'udp', dport => '6881' },
 168     ],
 169     'Ceph' => [
 170         "Ceph Storage Cluster traffic (Ceph Monitors, OSD & MDS Deamons)",
 171         { action => 'PARAM', proto => 'tcp', dport => '6789' },
 172         { action => 'PARAM', proto => 'tcp', dport => '6800:7300' },
 173     ],
 174     'CVS' => [
 175         "Concurrent Versions System pserver traffic",
 176         { action => 'PARAM', proto => 'tcp', dport => '2401' },
 177     ],
 178     'Citrix' => [
 179         "Citrix/ICA traffic (ICA, ICA Browser, CGP)",
 180         { action => 'PARAM', proto => 'tcp', dport => '1494' },
 181         { action => 'PARAM', proto => 'udp', dport => '1604' },
 182         { action => 'PARAM', proto => 'tcp', dport => '2598' },
 183     ],
 184     'DAAP' => [
 185         "Digital Audio Access Protocol traffic (iTunes, Rythmbox daemons)",
 186         { action => 'PARAM', proto => 'tcp', dport => '3689' },
 187         { action => 'PARAM', proto => 'udp', dport => '3689' },
 188     ],
 189     'DCC' => [
 190         "Distributed Checksum Clearinghouse spam filtering mechanism",
 191         { action => 'PARAM', proto => 'tcp', dport => '6277' },
 192     ],
 193     'DHCPfwd' => [
 194         "Forwarded DHCP traffic",
 195         { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
 196     ],
 197     'DNS' => [
 198         "Domain Name System traffic (upd and tcp)",
 199         { action => 'PARAM', proto => 'udp', dport => '53' },
 200         { action => 'PARAM', proto => 'tcp', dport => '53' },
 201     ],
 202     'Distcc' => [
 203         "Distributed Compiler service",
 204         { action => 'PARAM', proto => 'tcp', dport => '3632' },
 205     ],
 206     'FTP' => [
 207         "File Transfer Protocol",
 208         { action => 'PARAM', proto => 'tcp', dport => '21' },
 209     ],
 210     'Finger' => [
 211         "Finger protocol (RFC 742)",
 212         { action => 'PARAM', proto => 'tcp', dport => '79' },
 213     ],
 214     'GNUnet' => [
 215         "GNUnet secure peer-to-peer networking traffic",
 216         { action => 'PARAM', proto => 'tcp', dport => '2086' },
 217         { action => 'PARAM', proto => 'udp', dport => '2086' },
 218         { action => 'PARAM', proto => 'tcp', dport => '1080' },
 219         { action => 'PARAM', proto => 'udp', dport => '1080' },
 220     ],
 221     'GRE' => [
 222         "Generic Routing Encapsulation tunneling protocol",
 223         { action => 'PARAM', proto => '47' },
 224     ],
 225     'Git' => [
 226         "Git distributed revision control traffic",
 227         { action => 'PARAM', proto => 'tcp', dport => '9418' },
 228     ],
 229     'HKP' => [
 230         "OpenPGP HTTP keyserver protocol traffic",
 231         { action => 'PARAM', proto => 'tcp', dport => '11371' },
 232     ],
 233     'HTTP' => [
 234         "Hypertext Transfer Protocol (WWW)",
 235         { action => 'PARAM', proto => 'tcp', dport => '80' },
 236     ],
 237     'HTTPS' => [
 238         "Hypertext Transfer Protocol (WWW) over SSL",
 239         { action => 'PARAM', proto => 'tcp', dport => '443' },
 240     ],
 241     'ICPV2' => [
 242         "Internet Cache Protocol V2 (Squid) traffic",
 243         { action => 'PARAM', proto => 'udp', dport => '3130' },
 244     ],
 245     'ICQ' => [
 246         "AOL Instant Messenger traffic",
 247         { action => 'PARAM', proto => 'tcp', dport => '5190' },
 248     ],
 249     'IMAP' => [
 250         "Internet Message Access Protocol",
 251         { action => 'PARAM', proto => 'tcp', dport => '143' },
 252     ],
 253     'IMAPS' => [
 254         "Internet Message Access Protocol over SSL",
 255         { action => 'PARAM', proto => 'tcp', dport => '993' },
 256     ],
 257     'IPIP' => [
 258         "IPIP capsulation traffic",
 259         { action => 'PARAM', proto => '94' },
 260     ],
 261     'IPsec' => [
 262         "IPsec traffic",
 263         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 264         { action => 'PARAM', proto => '50' },
 265     ],
 266     'IPsecah' => [
 267         "IPsec authentication (AH) traffic",
 268         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 269         { action => 'PARAM', proto => '51' },
 270     ],
 271     'IPsecnat' => [
 272         "IPsec traffic and Nat-Traversal",
 273         { action => 'PARAM', proto => 'udp', dport => '500' },
 274         { action => 'PARAM', proto => 'udp', dport => '4500' },
 275         { action => 'PARAM', proto => '50' },
 276     ],
 277     'IRC' => [
 278         "Internet Relay Chat traffic",
 279         { action => 'PARAM', proto => 'tcp', dport => '6667' },
 280     ],
 281     'Jetdirect' => [
 282         "HP Jetdirect printing",
 283         { action => 'PARAM', proto => 'tcp', dport => '9100' },
 284     ],
 285     'L2TP' => [
 286         "Layer 2 Tunneling Protocol traffic",
 287         { action => 'PARAM', proto => 'udp', dport => '1701' },
 288     ],
 289     'LDAP' => [
 290         "Lightweight Directory Access Protocol traffic",
 291         { action => 'PARAM', proto => 'tcp', dport => '389' },
 292     ],
 293     'LDAPS' => [
 294         "Secure Lightweight Directory Access Protocol traffic",
 295         { action => 'PARAM', proto => 'tcp', dport => '636' },
 296     ],
 297     'MSNP' => [
 298         "Microsoft Notification Protocol",
 299         { action => 'PARAM', proto => 'tcp', dport => '1863' },
 300     ],
 301     'MSSQL' => [
 302         "Microsoft SQL Server",
 303         { action => 'PARAM', proto => 'tcp', dport => '1433' },
 304     ],
 305     'Mail' => [
 306         "Mail traffic (SMTP, SMTPS, Submission)",
 307         { action => 'PARAM', proto => 'tcp', dport => '25' },
 308         { action => 'PARAM', proto => 'tcp', dport => '465' },
 309         { action => 'PARAM', proto => 'tcp', dport => '587' },
 310     ],
 311     'Munin' => [
 312         "Munin networked resource monitoring traffic",
 313         { action => 'PARAM', proto => 'tcp', dport => '4949' },
 314     ],
 315     'MySQL' => [
 316         "MySQL server",
 317         { action => 'PARAM', proto => 'tcp', dport => '3306' },
 318     ],
 319     'NNTP' => [
 320         "NNTP traffic (Usenet).",
 321         { action => 'PARAM', proto => 'tcp', dport => '119' },
 322     ],
 323     'NNTPS' => [
 324         "Encrypted NNTP traffic (Usenet)",
 325         { action => 'PARAM', proto => 'tcp', dport => '563' },
 326     ],
 327     'NTP' => [
 328         "Network Time Protocol (ntpd)",
 329         { action => 'PARAM', proto => 'udp', dport => '123' },
 330     ],
 331     'OSPF' => [
 332         "OSPF multicast traffic",
 333         { action => 'PARAM', proto => '89' },
 334     ],
 335     'OpenVPN' => [
 336         "OpenVPN traffic",
 337         { action => 'PARAM', proto => 'udp', dport => '1194' },
 338     ],
 339     'PCA' => [
 340         "Symantec PCAnywere (tm)",
 341         { action => 'PARAM', proto => 'udp', dport => '5632' },
 342         { action => 'PARAM', proto => 'tcp', dport => '5631' },
 343     ],
 344     'POP3' => [
 345         "POP3 traffic",
 346         { action => 'PARAM', proto => 'tcp', dport => '110' },
 347     ],
 348     'POP3S' => [
 349         "Encrypted POP3 traffic",
 350         { action => 'PARAM', proto => 'tcp', dport => '995' },
 351     ],
 352     'PPtP' => [
 353         "Point-to-Point Tunneling Protocol",
 354         { action => 'PARAM', proto => '47' },
 355         { action => 'PARAM', proto => 'tcp', dport => '1723' },
 356     ],
 357     'Ping' => [
 358         "ICMP echo request",
 359         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 360     ],
 361     'PostgreSQL' => [
 362         "PostgreSQL server",
 363         { action => 'PARAM', proto => 'tcp', dport => '5432' },
 364     ],
 365     'Printer' => [
 366         "Line Printer protocol printing",
 367         { action => 'PARAM', proto => 'tcp', dport => '515' },
 368     ],
 369     'RDP' => [
 370         "Microsoft Remote Desktop Protocol traffic",
 371         { action => 'PARAM', proto => 'tcp', dport => '3389' },
 372     ],
 373     'RIP' => [
 374         "Routing Information Protocol (bidirectional)",
 375         { action => 'PARAM', proto => 'udp', dport => '520' },
 376     ],
 377     'RNDC' => [
 378         "BIND remote management protocol",
 379         { action => 'PARAM', proto => 'tcp', dport => '953' },
 380     ],
 381     'Razor' => [
 382         "Razor Antispam System",
 383         { action => 'ACCEPT', proto => 'tcp', dport => '2703' },
 384     ],
 385     'Rdate' => [
 386         "Remote time retrieval (rdate)",
 387         { action => 'PARAM', proto => 'tcp', dport => '37' },
 388     ],
 389     'Rsync' => [
 390         "Rsync server",
 391         { action => 'PARAM', proto => 'tcp', dport => '873' },
 392     ],
 393     'SANE' => [
 394         "SANE network scanning",
 395         { action => 'PARAM', proto => 'tcp', dport => '6566' },
 396     ],
 397     'SMB' => [
 398         "Microsoft SMB traffic",
 399         { action => 'PARAM', proto => 'udp', dport => '135,445' },
 400         { action => 'PARAM', proto => 'udp', dport => '137:139' },
 401         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
 402         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
 403     ],
 404     'SMBswat' => [
 405         "Samba Web Administration Tool",
 406         { action => 'PARAM', proto => 'tcp', dport => '901' },
 407     ],
 408     'SMTP' => [
 409         "Simple Mail Transfer Protocol",
 410         { action => 'PARAM', proto => 'tcp', dport => '25' },
 411     ],
 412     'SMTPS' => [
 413         "Encrypted Simple Mail Transfer Protocol",
 414         { action => 'PARAM', proto => 'tcp', dport => '465' },
 415     ],
 416     'SNMP' => [
 417         "Simple Network Management Protocol",
 418         { action => 'PARAM', proto => 'udp', dport => '161:162' },
 419         { action => 'PARAM', proto => 'tcp', dport => '161' },
 420     ],
 421     'SPAMD' => [
 422         "Spam Assassin SPAMD traffic",
 423         { action => 'PARAM', proto => 'tcp', dport => '783' },
 424     ],
 425     'SSH' => [
 426         "Secure shell traffic",
 427         { action => 'PARAM', proto => 'tcp', dport => '22' },
 428     ],
 429     'SVN' => [
 430         "Subversion server (svnserve)",
 431         { action => 'PARAM', proto => 'tcp', dport => '3690' },
 432     ],
 433     'SixXS' => [
 434         "SixXS IPv6 Deployment and Tunnel Broker",
 435         { action => 'PARAM', proto => 'tcp', dport => '3874' },
 436         { action => 'PARAM', proto => 'udp', dport => '3740' },
 437         { action => 'PARAM', proto => '41' },
 438         { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
 439     ],
 440     'Squid' => [
 441         "Squid web proxy traffic",
 442         { action => 'PARAM', proto => 'tcp', dport => '3128' },
 443     ],
 444     'Submission' => [
 445         "Mail message submission traffic",
 446         { action => 'PARAM', proto => 'tcp', dport => '587' },
 447     ],
 448     'Syslog' => [
 449         "Syslog protocol (RFC 5424) traffic",
 450         { action => 'PARAM', proto => 'udp', dport => '514' },
 451         { action => 'PARAM', proto => 'tcp', dport => '514' },
 452     ],
 453     'TFTP' => [
 454         "Trivial File Transfer Protocol traffic",
 455         { action => 'PARAM', proto => 'udp', dport => '69' },
 456     ],
 457     'Telnet' => [
 458         "Telnet traffic",
 459         { action => 'PARAM', proto => 'tcp', dport => '23' },
 460     ],
 461     'Telnets' => [
 462         "Telnet over SSL",
 463         { action => 'PARAM', proto => 'tcp', dport => '992' },
 464     ],
 465     'Time' => [
 466         "RFC 868 Time protocol",
 467         { action => 'PARAM', proto => 'tcp', dport => '37' },
 468     ],
 469     'Trcrt' => [
 470         "Traceroute (for up to 30 hops) traffic",
 471         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 472         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 473     ],
 474     'VNC' => [
 475         "VNC traffic for VNC display's 0 - 99",
 476         { action => 'PARAM', proto => 'tcp', dport => '5900:5999' },
 477     ],
 478     'VNCL' => [
 479         "VNC traffic from Vncservers to Vncviewers in listen mode",
 480         { action => 'PARAM', proto => 'tcp', dport => '5500' },
 481     ],
 482     'Web' => [
 483         "WWW traffic (HTTP and HTTPS)",
 484         { action => 'PARAM', proto => 'tcp', dport => '80' },
 485         { action => 'PARAM', proto => 'tcp', dport => '443' },
 486     ],
 487     'Webcache' => [
 488         "Web Cache/Proxy traffic (port 8080)",
 489         { action => 'PARAM', proto => 'tcp', dport => '8080' },
 490     ],
 491     'Webmin' => [
 492         "Webmin traffic",
 493         { action => 'PARAM', proto => 'tcp', dport => '10000' },
 494     ],
 495     'Whois' => [
 496         "Whois (nicname, RFC 3912) traffic",
 497         { action => 'PARAM', proto => 'tcp', dport => '43' },
 498     ],
 499 };
 500
 501 my $pve_fw_parsed_macros;
 502 my $pve_fw_macro_descr;
 503 my $pve_fw_preferred_macro_names = {};
 504
 505 my $pve_std_chains = {};
 506 $pve_std_chains->{4} = {
 507     'PVEFW-SET-ACCEPT-MARK' => [
 508         "-j MARK --set-mark 1",
 509     ],
 510     'PVEFW-DropBroadcast' => [
 511         # same as shorewall 'Broadcast'
 512         # simply DROP BROADCAST/MULTICAST/ANYCAST
 513         # we can use this to reduce logging
 514         { action => 'DROP', dsttype => 'BROADCAST' },
 515         { action => 'DROP', dsttype => 'MULTICAST' },
 516         { action => 'DROP', dsttype => 'ANYCAST' },
 517         { action => 'DROP', dest => '224.0.0.0/4' },
 518     ],
 519     'PVEFW-reject' => [
 520         # same as shorewall 'reject'
 521         { action => 'DROP', dsttype => 'BROADCAST' },
 522         { action => 'DROP', source => '224.0.0.0/4' },
 523         { action => 'DROP', proto => 'icmp' },
 524         "-p tcp -j REJECT --reject-with tcp-reset",
 525         "-p udp -j REJECT --reject-with icmp-port-unreachable",
 526         "-p icmp -j REJECT --reject-with icmp-host-unreachable",
 527         "-j REJECT --reject-with icmp-host-prohibited",
 528     ],
 529     'PVEFW-Drop' => [
 530         # same as shorewall 'Drop', which is equal to DROP,
 531         # but REJECT/DROP some packages to reduce logging,
 532         # and ACCEPT critical ICMP types
 533         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 534         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 535         { action => 'PVEFW-DropBroadcast' },
 536         # ACCEPT critical ICMP types
 537         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 538         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 539         # Drop packets with INVALID state
 540         "-m conntrack --ctstate INVALID -j DROP",
 541         # Drop Microsoft SMB noise
 542         { action => 'DROP', proto => 'udp', dport => '135,445', nbdport => 2 },
 543         { action => 'DROP', proto => 'udp', dport => '137:139'},
 544         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 545         { action => 'DROP', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
 546         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 547         # Drop new/NotSyn traffic so that it doesn't get logged
 548         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
 549         # Drop DNS replies
 550         { action => 'DROP', proto => 'udp', sport => 53 },
 551     ],
 552     'PVEFW-Reject' => [
 553         # same as shorewall 'Reject', which is equal to Reject,
 554         # but REJECT/DROP some packages to reduce logging,
 555         # and ACCEPT critical ICMP types
 556         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 557         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 558         { action => 'PVEFW-DropBroadcast' },
 559         # ACCEPT critical ICMP types
 560         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 561         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 562         # Drop packets with INVALID state
 563         "-m conntrack --ctstate INVALID -j DROP",
 564         # Drop Microsoft SMB noise
 565         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445', nbdport => 2 },
 566         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
 567         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 568         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
 569         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 570         # Drop new/NotSyn traffic so that it doesn't get logged
 571         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
 572         # Drop DNS replies
 573         { action => 'DROP', proto => 'udp', sport => 53 },
 574     ],
 575     'PVEFW-tcpflags' => [
 576         # same as shorewall tcpflags action.
 577         # Packets arriving on this interface are checked for som illegal combinations of TCP flags
 578         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG -g PVEFW-logflags",
 579         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE -g PVEFW-logflags",
 580         "-p tcp -m tcp --tcp-flags SYN,RST SYN,RST -g PVEFW-logflags",
 581         "-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN -g PVEFW-logflags",
 582         "-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN -g PVEFW-logflags",
 583     ],
 584     'PVEFW-smurfs' => [
 585         # same as shorewall smurfs action
 586         # Filter packets for smurfs (packets with a broadcast address as the source).
 587         "-s 0.0.0.0/32 -j RETURN",
 588         "-m addrtype --src-type BROADCAST -g PVEFW-smurflog",
 589         "-s 224.0.0.0/4 -g PVEFW-smurflog",
 590     ],
 591 };
 592
 593 $pve_std_chains->{6} = {
 594     'PVEFW-SET-ACCEPT-MARK' => [
 595         "-j MARK --set-mark 1",
 596     ],
 597     'PVEFW-DropBroadcast' => [
 598         # same as shorewall 'Broadcast'
 599         # simply DROP BROADCAST/MULTICAST/ANYCAST
 600         # we can use this to reduce logging
 601         #{ action => 'DROP', dsttype => 'BROADCAST' }, #no broadcast in ipv6
 602         # ipv6 addrtype does not work with kernel 2.6.32
 603         #{ action => 'DROP', dsttype => 'MULTICAST' },
 604         #{ action => 'DROP', dsttype => 'ANYCAST' },
 605         { action => 'DROP', dest => 'ff00::/8' },
 606         #{ action => 'DROP', dest => '224.0.0.0/4' },
 607     ],
 608     'PVEFW-reject' => [
 609         # same as shorewall 'reject'
 610         #{ action => 'DROP', dsttype => 'BROADCAST' },
 611         #{ action => 'DROP', source => '224.0.0.0/4' },
 612         { action => 'DROP', proto => 'icmpv6' },
 613         "-p tcp -j REJECT --reject-with tcp-reset",
 614         #"-p udp -j REJECT --reject-with icmp-port-unreachable",
 615         #"-p icmp -j REJECT --reject-with icmp-host-unreachable",
 616         #"-j REJECT --reject-with icmp-host-prohibited",
 617     ],
 618     'PVEFW-Drop' => [
 619         # same as shorewall 'Drop', which is equal to DROP,
 620         # but REJECT/DROP some packages to reduce logging,
 621         # and ACCEPT critical ICMP types
 622         { action => 'PVEFW-reject', proto => 'tcp', dport => '43' }, # REJECT 'auth'
 623         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 624         { action => 'PVEFW-DropBroadcast' },
 625         # ACCEPT critical ICMP types
 626         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
 627         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
 628         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
 629
 630         # Drop packets with INVALID state
 631         "-m conntrack --ctstate INVALID -j DROP",
 632         # Drop Microsoft SMB noise
 633         { action => 'DROP', proto => 'udp', dport => '135,445', nbdport => 2 },
 634         { action => 'DROP', proto => 'udp', dport => '137:139'},
 635         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 636         { action => 'DROP', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
 637         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 638         # Drop new/NotSyn traffic so that it doesn't get logged
 639         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
 640         # Drop DNS replies
 641         { action => 'DROP', proto => 'udp', sport => 53 },
 642     ],
 643     'PVEFW-Reject' => [
 644         # same as shorewall 'Reject', which is equal to Reject,
 645         # but REJECT/DROP some packages to reduce logging,
 646         # and ACCEPT critical ICMP types
 647         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 648         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 649         { action => 'PVEFW-DropBroadcast' },
 650         # ACCEPT critical ICMP types
 651         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
 652         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
 653         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
 654
 655         # Drop packets with INVALID state
 656         "-m conntrack --ctstate INVALID -j DROP",
 657         # Drop Microsoft SMB noise
 658         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445', nbdport => 2 },
 659         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
 660         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 661         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
 662         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 663         # Drop new/NotSyn traffic so that it doesn't get logged
 664         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
 665         # Drop DNS replies
 666         { action => 'DROP', proto => 'udp', sport => 53 },
 667     ],
 668     'PVEFW-tcpflags' => [
 669         # same as shorewall tcpflags action.
 670         # Packets arriving on this interface are checked for som illegal combinations of TCP flags
 671         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG -g PVEFW-logflags",
 672         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE -g PVEFW-logflags",
 673         "-p tcp -m tcp --tcp-flags SYN,RST SYN,RST -g PVEFW-logflags",
 674         "-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN -g PVEFW-logflags",
 675         "-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN -g PVEFW-logflags",
 676     ],
 677 };
 678
 679 # iptables -p icmp -h
 680 my $icmp_type_names = {
 681     any => 1,
 682     'echo-reply' => 1,
 683     'destination-unreachable' => 1,
 684     'network-unreachable' => 1,
 685     'host-unreachable' => 1,
 686     'protocol-unreachable' => 1,
 687     'port-unreachable' => 1,
 688     'fragmentation-needed' => 1,
 689     'source-route-failed' => 1,
 690     'network-unknown' => 1,
 691     'host-unknown' => 1,
 692     'network-prohibited' => 1,
 693     'host-prohibited' => 1,
 694     'TOS-network-unreachable' => 1,
 695     'TOS-host-unreachable' => 1,
 696     'communication-prohibited' => 1,
 697     'host-precedence-violation' => 1,
 698     'precedence-cutoff' => 1,
 699     'source-quench' => 1,
 700     'redirect' => 1,
 701     'network-redirect' => 1,
 702     'host-redirect' => 1,
 703     'TOS-network-redirect' => 1,
 704     'TOS-host-redirect' => 1,
 705     'echo-request' => 1,
 706     'router-advertisement' => 1,
 707     'router-solicitation' => 1,
 708     'time-exceeded' => 1,
 709     'ttl-zero-during-transit' => 1,
 710     'ttl-zero-during-reassembly' => 1,
 711     'parameter-problem' => 1,
 712     'ip-header-bad' => 1,
 713     'required-option-missing' => 1,
 714     'timestamp-request' => 1,
 715     'timestamp-reply' => 1,
 716     'address-mask-request' => 1,
 717     'address-mask-reply' => 1,
 718 };
 719
 720 # ip6tables -p icmpv6 -h
 721
 722 my $icmpv6_type_names = {
 723     'any' => 1,
 724     'destination-unreachable' => 1,
 725     'no-route' => 1,
 726     'communication-prohibited' => 1,
 727     'address-unreachable' => 1,
 728     'port-unreachable' => 1,
 729     'packet-too-big' => 1,
 730     'time-exceeded' => 1,
 731     'ttl-zero-during-transit' => 1,
 732     'ttl-zero-during-reassembly' => 1,
 733     'parameter-problem' => 1,
 734     'bad-header' => 1,
 735     'unknown-header-type' => 1,
 736     'unknown-option' => 1,
 737     'echo-request' => 1,
 738     'echo-reply' => 1,
 739     'router-solicitation' => 1,
 740     'router-advertisement' => 1,
 741     'neighbor-solicitation' => 1,
 742     'neighbour-solicitation' => 1,
 743     'neighbor-advertisement' => 1,
 744     'neighbour-advertisement' => 1,
 745     'redirect' => 1,
 746 };
 747
 748 sub init_firewall_macros {
 749
 750     $pve_fw_parsed_macros = {};
 751
 752     foreach my $k (keys %$pve_fw_macros) {
 753         my $lc_name = lc($k);
 754         my $macro = $pve_fw_macros->{$k};
 755         if (!ref($macro->[0])) {
 756             $pve_fw_macro_descr->{$k} = shift @$macro;
 757         }
 758         $pve_fw_preferred_macro_names->{$lc_name} = $k;
 759         $pve_fw_parsed_macros->{$k} = $macro;
 760     }
 761 }
 762
 763 init_firewall_macros();
 764
 765 sub get_macros {
 766     return wantarray ? ($pve_fw_parsed_macros, $pve_fw_macro_descr): $pve_fw_parsed_macros;
 767 }
 768
 769 my $etc_services;
 770
 771 sub get_etc_services {
 772
 773     return $etc_services if $etc_services;
 774
 775     my $filename = "/etc/services";
 776
 777     my $fh = IO::File->new($filename, O_RDONLY);
 778     if (!$fh) {
 779         warn "unable to read '$filename' - $!\n";
 780         return {};
 781     }
 782
 783     my $services = {};
 784
 785     while (my $line = <$fh>) {
 786         chomp ($line);
 787         next if $line =~m/^#/;
 788         next if ($line =~m/^\s*$/);
 789
 790         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp).*$!) {
 791             $services->{byid}->{$2}->{name} = $1;
 792             $services->{byid}->{$2}->{port} = $2;
 793             $services->{byid}->{$2}->{$3} = 1;
 794             $services->{byname}->{$1} = $services->{byid}->{$2};
 795         }
 796     }
 797
 798     close($fh);
 799
 800     $etc_services = $services;
 801
 802
 803     return $etc_services;
 804 }
 805
 806 my $etc_protocols;
 807
 808 sub get_etc_protocols {
 809     return $etc_protocols if $etc_protocols;
 810
 811     my $filename = "/etc/protocols";
 812
 813     my $fh = IO::File->new($filename, O_RDONLY);
 814     if (!$fh) {
 815         warn "unable to read '$filename' - $!\n";
 816         return {};
 817     }
 818
 819     my $protocols = {};
 820
 821     while (my $line = <$fh>) {
 822         chomp ($line);
 823         next if $line =~m/^#/;
 824         next if ($line =~m/^\s*$/);
 825
 826         if ($line =~ m!^(\S+)\s+(\d+)\s+.*$!) {
 827             $protocols->{byid}->{$2}->{name} = $1;
 828             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
 829         }
 830     }
 831
 832     close($fh);
 833
 834     # add special case for ICMP v6
 835     $protocols->{byid}->{icmpv6}->{name} = "icmpv6";
 836     $protocols->{byname}->{icmpv6} = $protocols->{byid}->{icmpv6};
 837
 838     $etc_protocols = $protocols;
 839
 840     return $etc_protocols;
 841 }
 842
 843 my $ipv4_mask_hash_localnet = {
 844     '255.255.0.0' => 16,
 845     '255.255.128.0' => 17,
 846     '255.255.192.0' => 18,
 847     '255.255.224.0' => 19,
 848     '255.255.240.0' => 20,
 849     '255.255.248.0' => 21,
 850     '255.255.252.0' => 22,
 851     '255.255.254.0' => 23,
 852     '255.255.255.0' => 24,
 853     '255.255.255.128' => 25,
 854     '255.255.255.192' => 26,
 855     '255.255.255.224' => 27,
 856     '255.255.255.240' => 28,
 857     '255.255.255.248' => 29,
 858     '255.255.255.252' => 30,
 859 };
 860
 861 my $__local_network;
 862
 863 sub local_network {
 864     my ($new_value) = @_;
 865
 866     $__local_network = $new_value if defined($new_value);
 867
 868     return $__local_network if defined($__local_network);
 869
 870     eval {
 871         my $nodename = PVE::INotify::nodename();
 872
 873         my $ip = PVE::Cluster::remote_node_ip($nodename);
 874
 875         my $testip = Net::IP->new($ip);
 876
 877         my $routes = PVE::ProcFSTools::read_proc_net_route();
 878         foreach my $entry (@$routes) {
 879             my $mask = $ipv4_mask_hash_localnet->{$entry->{mask}};
 880             next if !defined($mask);
 881             return if $mask eq '0.0.0.0';
 882             my $cidr = "$entry->{dest}/$mask";
 883             my $testnet = Net::IP->new($cidr);
 884             if ($testnet->overlaps($testip)) {
 885                 $__local_network = $cidr;
 886                 return;
 887             }
 888         }
 889     };
 890     warn $@ if $@;
 891
 892     return $__local_network;
 893 }
 894
 895 # ipset names are limited to 31 characters,
 896 # and we use '-v4' or '-v6' to indicate IP versions,
 897 # and we use '_swap' suffix for atomic update,
 898 # for example PVEFW-${VMID}-${ipset_name}_swap
 899
 900 my $max_iptables_ipset_name_length = 31 - length("PVEFW-") - length("_swap");
 901
 902 sub compute_ipset_chain_name {
 903     my ($vmid, $ipset_name, $ipversion) = @_;
 904
 905     $vmid = 0 if !defined($vmid);
 906
 907     my $id = "$vmid-${ipset_name}-v$ipversion";
 908
 909     if (length($id) > $max_iptables_ipset_name_length) {
 910         $id = PVE::Tools::fnv31a_hex($id);
 911     }
 912
 913     return "PVEFW-$id";
 914 }
 915
 916 sub compute_ipfilter_ipset_name {
 917     my ($iface) = @_;
 918
 919     return "ipfilter-$iface";
 920 }
 921
 922 sub parse_address_list {
 923     my ($str) = @_;
 924
 925     if ($str =~ m/^(\+)(\S+)$/) { # ipset ref
 926         die "ipset name too long\n" if length($str) > ($max_ipset_name_length + 1);
 927         return;
 928     }
 929
 930     if ($str =~ m/^${ip_alias_pattern}$/) {
 931         die "alias name too long\n" if length($str) > $max_alias_name_length;
 932         return;
 933     }
 934
 935     my $count = 0;
 936     my $iprange = 0;
 937     my $ipversion;
 938
 939     foreach my $elem (split(/,/, $str)) {
 940         $count++;
 941         my $ip = Net::IP->new($elem);
 942         if (!$ip) {
 943             my $err = Net::IP::Error();
 944             die "invalid IP address: $err\n";
 945         }
 946         $iprange = 1 if $elem =~ m/-/;
 947
 948         my $new_ipversion = Net::IP::ip_is_ipv6($ip->ip()) ? 6 : 4;
 949
 950         die "detected mixed ipv4/ipv6 addresses in address list '$str'\n"
 951             if $ipversion && ($new_ipversion != $ipversion);
 952
 953         $ipversion = $new_ipversion;
 954     }
 955
 956     die "you can't use a range in a list\n" if $iprange && $count > 1;
 957
 958     return $ipversion;
 959 }
 960
 961 sub parse_port_name_number_or_range {
 962     my ($str) = @_;
 963
 964     my $services = PVE::Firewall::get_etc_services();
 965     my $count = 0;
 966     my $icmp_port = 0;
 967
 968     foreach my $item (split(/,/, $str)) {
 969         $count++;
 970         if ($item =~ m/^(\d+):(\d+)$/) {
 971             my ($port1, $port2) = ($1, $2);
 972             die "invalid port '$port1'\n" if $port1 > 65535;
 973             die "invalid port '$port2'\n" if $port2 > 65535;
 974         } elsif ($item =~ m/^(\d+)$/) {
 975             my $port = $1;
 976             die "invalid port '$port'\n" if $port > 65535;
 977         } else {
 978             if ($icmp_type_names->{$item}) {
 979                 $icmp_port = 1;
 980             } elsif ($icmpv6_type_names->{$item}) {
 981                 $icmp_port = 1;
 982             } else {
 983                 die "invalid port '$item'\n" if !$services->{byname}->{$item};
 984             }
 985         }
 986     }
 987
 988     die "ICPM ports not allowed in port range\n" if $icmp_port && $count > 1;
 989
 990     return $count;
 991 }
 992
 993 PVE::JSONSchema::register_format('pve-fw-port-spec', \&pve_fw_verify_port_spec);
 994 sub pve_fw_verify_port_spec {
 995    my ($portstr) = @_;
 996
 997    parse_port_name_number_or_range($portstr);
 998
 999    return $portstr;
1000 }
1001
1002 PVE::JSONSchema::register_format('pve-fw-addr-spec', \&pve_fw_verify_addr_spec);
1003 sub pve_fw_verify_addr_spec {
1004    my ($list) = @_;
1005
1006    parse_address_list($list);
1007
1008    return $list;
1009 }
1010
1011 PVE::JSONSchema::register_format('pve-fw-protocol-spec', \&pve_fw_verify_protocol_spec);
1012 sub pve_fw_verify_protocol_spec {
1013    my ($proto) = @_;
1014
1015    my $protocols = get_etc_protocols();
1016
1017    die "unknown protocol '$proto'\n" if $proto &&
1018        !(defined($protocols->{byname}->{$proto}) ||
1019          defined($protocols->{byid}->{$proto}));
1020
1021    return $proto;
1022 }
1023
1024
1025 # helper function for API
1026
1027 sub copy_opject_with_digest {
1028     my ($object) = @_;
1029
1030     my $sha = Digest::SHA->new('sha1');
1031
1032     my $res = {};
1033     foreach my $k (sort keys %$object) {
1034         my $v = $object->{$k};
1035         next if !defined($v);
1036         $res->{$k} = $v;
1037         $sha->add($k, ':', $v, "\n");
1038     }
1039
1040     my $digest = $sha->hexdigest;
1041
1042     $res->{digest} = $digest;
1043
1044     return wantarray ? ($res, $digest) : $res;
1045 }
1046
1047 sub copy_list_with_digest {
1048     my ($list) = @_;
1049
1050     my $sha = Digest::SHA->new('sha1');
1051
1052     my $res = [];
1053     foreach my $entry (@$list) {
1054         my $data = {};
1055         foreach my $k (sort keys %$entry) {
1056             my $v = $entry->{$k};
1057             next if !defined($v);
1058             $data->{$k} = $v;
1059             # Note: digest ignores refs ($rule->{errors})
1060             $sha->add($k, ':', $v, "\n") if !ref($v); ;
1061         }
1062         push @$res, $data;
1063     }
1064
1065     my $digest = $sha->hexdigest;
1066
1067     foreach my $entry (@$res) {
1068         $entry->{digest} = $digest;
1069     }
1070
1071     return wantarray ? ($res, $digest) : $res;
1072 }
1073
1074 my $rule_properties = {
1075     pos => {
1076         description => "Update rule at position <pos>.",
1077         type => 'integer',
1078         minimum => 0,
1079         optional => 1,
1080     },
1081     digest => get_standard_option('pve-config-digest'),
1082     type => {
1083         type => 'string',
1084         optional => 1,
1085         enum => ['in', 'out', 'group'],
1086     },
1087     action => {
1088         description => "Rule action ('ACCEPT', 'DROP', 'REJECT') or security group name.",
1089         type => 'string',
1090         optional => 1,
1091         pattern => $security_group_name_pattern,
1092         maxLength => 20,
1093         minLength => 2,
1094     },
1095     macro => {
1096         type => 'string',
1097         optional => 1,
1098         maxLength => 128,
1099     },
1100     iface => get_standard_option('pve-iface', { optional => 1 }),
1101     source => {
1102         type => 'string', format => 'pve-fw-addr-spec',
1103         optional => 1,
1104     },
1105     dest => {
1106         type => 'string', format => 'pve-fw-addr-spec',
1107         optional => 1,
1108     },
1109     proto => {
1110         type => 'string', format => 'pve-fw-protocol-spec',
1111         optional => 1,
1112     },
1113     enable => {
1114         type => 'integer',
1115         minimum => 0,
1116         optional => 1,
1117     },
1118     sport => {
1119         type => 'string', format => 'pve-fw-port-spec',
1120         optional => 1,
1121     },
1122     dport => {
1123         type => 'string', format => 'pve-fw-port-spec',
1124         optional => 1,
1125     },
1126     comment => {
1127         type => 'string',
1128         optional => 1,
1129     },
1130 };
1131
1132 sub add_rule_properties {
1133     my ($properties) = @_;
1134
1135     foreach my $k (keys %$rule_properties) {
1136         my $h = $rule_properties->{$k};
1137         # copy data, so that we can modify later without side effects
1138         foreach my $opt (keys %$h) { $properties->{$k}->{$opt} = $h->{$opt}; }
1139     }
1140
1141     return $properties;
1142 }
1143
1144 sub delete_rule_properties {
1145     my ($rule, $delete_str) = @_;
1146
1147     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1148         raise_param_exc({ 'delete' => "no such property ('$opt')"})
1149             if !defined($rule_properties->{$opt});
1150         raise_param_exc({ 'delete' => "unable to delete required property '$opt'"})
1151             if $opt eq 'type' || $opt eq 'action';
1152         delete $rule->{$opt};
1153     }
1154
1155     return $rule;
1156 }
1157
1158 my $apply_macro = sub {
1159     my ($macro_name, $param, $verify, $ipversion) = @_;
1160
1161     my $macro_rules = $pve_fw_parsed_macros->{$macro_name};
1162     die "unknown macro '$macro_name'\n" if !$macro_rules; # should not happen
1163
1164     if ($ipversion && ($ipversion == 6) && $pve_ipv6fw_macros->{$macro_name}) {
1165         $macro_rules = $pve_ipv6fw_macros->{$macro_name};
1166     }
1167
1168     my $rules = [];
1169
1170     foreach my $templ (@$macro_rules) {
1171         my $rule = {};
1172         my $param_used = {};
1173         foreach my $k (keys %$templ) {
1174             my $v = $templ->{$k};
1175             if ($v eq 'PARAM') {
1176                 $v = $param->{$k};
1177                 $param_used->{$k} = 1;
1178             } elsif ($v eq 'DEST') {
1179                 $v = $param->{dest};
1180                 $param_used->{dest} = 1;
1181             } elsif ($v eq 'SOURCE') {
1182                 $v = $param->{source};
1183                 $param_used->{source} = 1;
1184             }
1185
1186             if (!defined($v)) {
1187                 my $msg = "missing parameter '$k' in macro '$macro_name'";
1188                 raise_param_exc({ macro => $msg }) if $verify;
1189                 die "$msg\n";
1190             }
1191             $rule->{$k} = $v;
1192         }
1193         foreach my $k (keys %$param) {
1194             next if $k eq 'macro';
1195             next if !defined($param->{$k});
1196             next if $param_used->{$k};
1197             if (defined($rule->{$k})) {
1198                 if ($rule->{$k} ne $param->{$k}) {
1199                     my $msg = "parameter '$k' already define in macro (value = '$rule->{$k}')";
1200                     raise_param_exc({ $k => $msg }) if $verify;
1201                     die "$msg\n";
1202                 }
1203             } else {
1204                 $rule->{$k} = $param->{$k};
1205             }
1206         }
1207         push @$rules, $rule;
1208     }
1209
1210     return $rules;
1211 };
1212
1213 my $rule_env_iface_lookup = {
1214     'ct' => 1,
1215     'vm' => 1,
1216     'group' => 0,
1217     'cluster' => 1,
1218     'host' => 1,
1219 };
1220
1221 sub verify_rule {
1222     my ($rule, $cluster_conf, $fw_conf, $rule_env, $noerr) = @_;
1223
1224     my $allow_groups = $rule_env eq 'group' ? 0 : 1;
1225
1226     my $allow_iface = $rule_env_iface_lookup->{$rule_env};
1227     die "unknown rule_env '$rule_env'\n" if !defined($allow_iface); # should not happen
1228
1229     my $errors = $rule->{errors} || {};
1230
1231     my $error_count = 0;
1232
1233     my $add_error = sub {
1234         my ($param, $msg)  = @_;
1235         chomp $msg;
1236         raise_param_exc({ $param => $msg }) if !$noerr;
1237         $error_count++;
1238         $errors->{$param} = $msg if !$errors->{$param};
1239     };
1240
1241     my $ipversion;
1242     my $set_ip_version = sub {
1243         my $vers = shift;
1244         if ($vers) {
1245             die "detected mixed ipv4/ipv6 adresses in rule\n"
1246                 if $ipversion && ($vers != $ipversion);
1247             $ipversion = $vers;
1248         }
1249     };
1250
1251     my $check_ipset_or_alias_property = sub {
1252         my ($name, $expected_ipversion) = @_;
1253
1254         if (my $value = $rule->{$name}) {
1255             if ($value =~ m/^\+/) {
1256                 if ($value =~ m/^\+(${ipset_name_pattern})$/) {
1257                     &$add_error($name, "no such ipset '$1'")
1258                         if !($cluster_conf->{ipset}->{$1} || ($fw_conf && $fw_conf->{ipset}->{$1}));
1259
1260                 } else {
1261                     &$add_error($name, "invalid ipset name '$value'");
1262                 }
1263             } elsif ($value =~ m/^${ip_alias_pattern}$/){
1264                 my $alias = lc($value);
1265                 &$add_error($name, "no such alias '$value'")
1266                     if !($cluster_conf->{aliases}->{$alias} || ($fw_conf && $fw_conf->{aliases}->{$alias}));
1267                 my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
1268                 $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1269
1270                 &$set_ip_version($e->{ipversion});
1271             }
1272         }
1273     };
1274
1275     my $type = $rule->{type};
1276     my $action = $rule->{action};
1277
1278     &$add_error('type', "missing property") if !$type;
1279     &$add_error('action', "missing property") if !$action;
1280
1281     if ($type) {
1282         if ($type eq  'in' || $type eq 'out') {
1283             &$add_error('action', "unknown action '$action'")
1284                 if $action && ($action !~ m/^(ACCEPT|DROP|REJECT)$/);
1285         } elsif ($type eq 'group') {
1286             &$add_error('type', "security groups not allowed")
1287                 if !$allow_groups;
1288             &$add_error('action', "invalid characters in security group name")
1289                 if $action && ($action !~ m/^${security_group_name_pattern}$/);
1290         } else {
1291             &$add_error('type', "unknown rule type '$type'");
1292         }
1293     }
1294
1295     if ($rule->{iface}) {
1296         &$add_error('type', "parameter -i not allowed for this rule type")
1297             if !$allow_iface;
1298         eval { PVE::JSONSchema::pve_verify_iface($rule->{iface}); };
1299         &$add_error('iface', $@) if $@;
1300         if ($rule_env eq 'vm') {
1301             &$add_error('iface', "value does not match the regex pattern 'net\\d+'")
1302                 if $rule->{iface} !~  m/^net(\d+)$/;
1303         } elsif ($rule_env eq 'ct') {
1304             &$add_error('iface', "value does not match the regex pattern '(venet|eth\\d+)'")
1305                 if $rule->{iface} !~  m/^(venet|eth(\d+))$/;
1306         }
1307     }
1308
1309     if ($rule->{macro}) {
1310         if (my $preferred_name = $pve_fw_preferred_macro_names->{lc($rule->{macro})}) {
1311             $rule->{macro} = $preferred_name;
1312         } else {
1313             &$add_error('macro', "unknown macro '$rule->{macro}'");
1314         }
1315     }
1316
1317     if ($rule->{proto}) {
1318         eval { pve_fw_verify_protocol_spec($rule->{proto}); };
1319         &$add_error('proto', $@) if $@;
1320         &$set_ip_version(4) if $rule->{proto} eq 'icmp';
1321         &$set_ip_version(6) if $rule->{proto} eq 'icmpv6';
1322     }
1323
1324     if ($rule->{dport}) {
1325         eval { parse_port_name_number_or_range($rule->{dport}); };
1326         &$add_error('dport', $@) if $@;
1327         &$add_error('proto', "missing property - 'dport' requires this property")
1328             if !$rule->{proto};
1329     }
1330
1331     if ($rule->{sport}) {
1332         eval { parse_port_name_number_or_range($rule->{sport}); };
1333         &$add_error('sport', $@) if $@;
1334         &$add_error('proto', "missing property - 'sport' requires this property")
1335             if !$rule->{proto};
1336     }
1337
1338     if ($rule->{source}) {
1339         eval {
1340             my $source_ipversion = parse_address_list($rule->{source});
1341             &$set_ip_version($source_ipversion);
1342         };
1343         &$add_error('source', $@) if $@;
1344         &$check_ipset_or_alias_property('source', $ipversion);
1345     }
1346
1347     if ($rule->{dest}) {
1348         eval {
1349             my $dest_ipversion = parse_address_list($rule->{dest});
1350             &$set_ip_version($dest_ipversion);
1351         };
1352         &$add_error('dest', $@) if $@;
1353         &$check_ipset_or_alias_property('dest', $ipversion);
1354     }
1355
1356     $rule->{ipversion} = $ipversion if $ipversion;
1357
1358     if ($rule->{macro} && !$error_count) {
1359         eval { &$apply_macro($rule->{macro}, $rule, 1, $ipversion); };
1360         if (my $err = $@) {
1361             if (ref($err) eq "PVE::Exception" && $err->{errors}) {
1362                 my $eh = $err->{errors};
1363                 foreach my $p (keys %$eh) {
1364                     &$add_error($p, $eh->{$p});
1365                 }
1366             } else {
1367                 &$add_error('macro', "$err");
1368             }
1369         }
1370     }
1371
1372     $rule->{errors} = $errors if $error_count;
1373
1374     return $rule;
1375 }
1376
1377 sub copy_rule_data {
1378     my ($rule, $param) = @_;
1379
1380     foreach my $k (keys %$rule_properties) {
1381         if (defined(my $v = $param->{$k})) {
1382             if ($v eq '' || $v eq '-') {
1383                 delete $rule->{$k};
1384             } else {
1385                 $rule->{$k} = $v;
1386             }
1387         }
1388     }
1389
1390     return $rule;
1391 }
1392
1393 sub rules_modify_permissions {
1394     my ($rule_env) = @_;
1395
1396     if ($rule_env eq 'host') {
1397         return {
1398             check => ['perm', '/nodes/{node}', [ 'Sys.Modify' ]],
1399         };
1400     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1401         return {
1402             check => ['perm', '/', [ 'Sys.Modify' ]],
1403         };
1404     } elsif ($rule_env eq 'vm' ||   $rule_env eq 'ct') {
1405         return {
1406             check => ['perm', '/vms/{vmid}', [ 'VM.Config.Network' ]],
1407         }
1408     }
1409
1410     return undef;
1411 }
1412
1413 sub rules_audit_permissions {
1414     my ($rule_env) = @_;
1415
1416     if ($rule_env eq 'host') {
1417         return {
1418             check => ['perm', '/nodes/{node}', [ 'Sys.Audit' ]],
1419         };
1420     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1421         return {
1422             check => ['perm', '/', [ 'Sys.Audit' ]],
1423         };
1424     } elsif ($rule_env eq 'vm' ||   $rule_env eq 'ct') {
1425         return {
1426             check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1427         }
1428     }
1429
1430     return undef;
1431 }
1432
1433 # core functions
1434 my $bridge_firewall_enabled = 0;
1435
1436 sub enable_bridge_firewall {
1437
1438     return if $bridge_firewall_enabled; # only once
1439
1440     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
1441     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
1442
1443     # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
1444     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
1445
1446     $bridge_firewall_enabled = 1;
1447 }
1448
1449 my $rule_format = "%-15s %-30s %-30s %-15s %-15s %-15s\n";
1450
1451 sub iptables_restore_cmdlist {
1452     my ($cmdlist) = @_;
1453
1454     run_command("/sbin/iptables-restore -n", input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1455 }
1456
1457 sub ip6tables_restore_cmdlist {
1458     my ($cmdlist) = @_;
1459
1460     run_command("/sbin/ip6tables-restore -n", input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1461 }
1462
1463 sub ipset_restore_cmdlist {
1464     my ($cmdlist) = @_;
1465
1466     run_command("/sbin/ipset restore", input => $cmdlist, errmsg => "ipset_restore_cmdlist");
1467 }
1468
1469 sub iptables_get_chains {
1470     my ($iptablescmd) = @_;
1471
1472     $iptablescmd = "iptables" if !$iptablescmd;
1473
1474     my $res = {};
1475
1476     # check what chains we want to track
1477     my $is_pvefw_chain = sub {
1478         my $name = shift;
1479
1480         return 1 if $name =~ m/^PVEFW-\S+$/;
1481
1482         return 1 if $name =~ m/^tap\d+i\d+-(:?IN|OUT)$/;
1483
1484         return 1 if $name =~ m/^veth\d+.\d+-(:?IN|OUT)$/; # fixme: dev name is configurable
1485
1486         return 1 if $name =~ m/^venet0-\d+-(:?IN|OUT)$/;
1487
1488         return 1 if $name =~ m/^fwbr\d+(v\d+)?-(:?FW|IN|OUT|IPS)$/;
1489         return 1 if $name =~ m/^GROUP-(:?[^\s\-]+)-(:?IN|OUT)$/;
1490
1491         return undef;
1492     };
1493
1494     my $table = '';
1495
1496     my $hooks = {};
1497
1498     my $parser = sub {
1499         my $line = shift;
1500
1501         return if $line =~ m/^#/;
1502         return if $line =~ m/^\s*$/;
1503
1504         if ($line =~ m/^\*(\S+)$/) {
1505             $table = $1;
1506             return;
1507         }
1508
1509         return if $table ne 'filter';
1510
1511         if ($line =~ m/^:(\S+)\s/) {
1512             my $chain = $1;
1513             return if !&$is_pvefw_chain($chain);
1514             $res->{$chain} = "unknown";
1515         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
1516             my ($chain, $sig) = ($1, $2);
1517             return if !&$is_pvefw_chain($chain);
1518             $res->{$chain} = $sig;
1519         } elsif ($line =~ m/^-A\s+(INPUT|OUTPUT|FORWARD)\s+-j\s+PVEFW-\1$/) {
1520             $hooks->{$1} = 1;
1521         } else {
1522             # simply ignore the rest
1523             return;
1524         }
1525     };
1526
1527     run_command("/sbin/$iptablescmd-save", outfunc => $parser);
1528
1529     return wantarray ? ($res, $hooks) : $res;
1530 }
1531
1532 sub iptables_chain_digest {
1533     my ($rules) = @_;
1534     my $digest = Digest::SHA->new('sha1');
1535     foreach my $rule (@$rules) { # order is important
1536         $digest->add($rule);
1537     }
1538     return $digest->b64digest;
1539 }
1540
1541 sub ipset_chain_digest {
1542     my ($rules) = @_;
1543
1544     my $digest = Digest::SHA->new('sha1');
1545     foreach my $rule (sort @$rules) { # note: sorted
1546         $digest->add($rule);
1547     }
1548     return $digest->b64digest;
1549 }
1550
1551 sub ipset_get_chains {
1552
1553     my $res = {};
1554     my $chains = {};
1555
1556     my $parser = sub {
1557         my $line = shift;
1558
1559         return if $line =~ m/^#/;
1560         return if $line =~ m/^\s*$/;
1561         if ($line =~ m/^(?:\S+)\s(PVEFW-\S+)\s(?:\S+).*/) {
1562             my $chain = $1;
1563             $line =~ s/\s+$//; # delete trailing white space
1564             push @{$chains->{$chain}}, $line;
1565         } else {
1566             # simply ignore the rest
1567             return;
1568         }
1569     };
1570
1571     run_command("/sbin/ipset save", outfunc => $parser);
1572
1573     # compute digest for each chain
1574     foreach my $chain (keys %$chains) {
1575         $res->{$chain} = ipset_chain_digest($chains->{$chain});
1576     }
1577
1578     return $res;
1579 }
1580
1581 sub ruleset_generate_cmdstr {
1582     my ($ruleset, $chain, $ipversion, $rule, $actions, $goto, $cluster_conf, $fw_conf) = @_;
1583
1584     return if defined($rule->{enable}) && !$rule->{enable};
1585     return if $rule->{errors};
1586
1587     die "unable to emit macro - internal error" if $rule->{macro}; # should not happen
1588
1589     my $nbdport = defined($rule->{dport}) ? parse_port_name_number_or_range($rule->{dport}) : 0;
1590     my $nbsport = defined($rule->{sport}) ? parse_port_name_number_or_range($rule->{sport}) : 0;
1591
1592     my @cmd = ();
1593
1594     push @cmd, "-i $rule->{iface_in}" if $rule->{iface_in};
1595     push @cmd, "-o $rule->{iface_out}" if $rule->{iface_out};
1596
1597     my $source = $rule->{source};
1598     my $dest = $rule->{dest};
1599
1600     if ($source) {
1601         if ($source =~ m/^\+/) {
1602             if ($source =~ m/^\+(${ipset_name_pattern})$/) {
1603                 my $name = $1;
1604                 if ($fw_conf && $fw_conf->{ipset}->{$name}) {
1605                     my $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name, $ipversion);
1606                     push @cmd, "-m set --match-set ${ipset_chain} src";
1607                 } elsif ($cluster_conf && $cluster_conf->{ipset}->{$name}) {
1608                     my $ipset_chain = compute_ipset_chain_name(0, $name, $ipversion);
1609                     push @cmd, "-m set --match-set ${ipset_chain} src";
1610                 } else {
1611                     die "no such ipset '$name'\n";
1612                 }
1613             } else {
1614                 die "invalid security group name '$source'\n";
1615             }
1616         } elsif ($source =~ m/^${ip_alias_pattern}$/){
1617             my $alias = lc($source);
1618             my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
1619             $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1620             die "no such alias '$source'\n" if !$e;
1621             push @cmd, "-s $e->{cidr}";
1622         } elsif ($source =~ m/\-/){
1623             push @cmd, "-m iprange --src-range $source";
1624         } else {
1625             push @cmd, "-s $source";
1626         }
1627     }
1628
1629     if ($dest) {
1630         if ($dest =~ m/^\+/) {
1631             if ($dest =~ m/^\+(${ipset_name_pattern})$/) {
1632                 my $name = $1;
1633                 if ($fw_conf && $fw_conf->{ipset}->{$name}) {
1634                     my $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name, $ipversion);
1635                     push @cmd, "-m set --match-set ${ipset_chain} dst";
1636                 } elsif ($cluster_conf && $cluster_conf->{ipset}->{$name}) {
1637                     my $ipset_chain = compute_ipset_chain_name(0, $name, $ipversion);
1638                     push @cmd, "-m set --match-set ${ipset_chain} dst";
1639                 } else {
1640                     die "no such ipset '$name'\n";
1641                 }
1642             } else {
1643                 die "invalid security group name '$dest'\n";
1644             }
1645         } elsif ($dest =~ m/^${ip_alias_pattern}$/){
1646             my $alias = lc($dest);
1647             my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
1648             $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1649             die "no such alias '$dest'\n" if !$e;
1650             push @cmd, "-d $e->{cidr}";
1651         } elsif ($dest =~ m/^(\d+)\.(\d+).(\d+).(\d+)\-(\d+)\.(\d+).(\d+).(\d+)$/){
1652             push @cmd, "-m iprange --dst-range $dest";
1653         } else {
1654             push @cmd, "-d $dest";
1655         }
1656     }
1657
1658     if ($rule->{proto}) {
1659         push @cmd, "-p $rule->{proto}";
1660
1661         my $multiport = 0;
1662         $multiport++ if $nbdport > 1;
1663         $multiport++ if $nbsport > 1;
1664
1665         push @cmd, "--match multiport" if $multiport;
1666
1667         die "multiport: option '--sports' cannot be used together with '--dports'\n"
1668             if ($multiport == 2) && ($rule->{dport} ne $rule->{sport});
1669
1670         if ($rule->{dport}) {
1671             if ($rule->{proto} && $rule->{proto} eq 'icmp') {
1672                 # Note: we use dport to store --icmp-type
1673                 die "unknown icmp-type '$rule->{dport}'\n" if !defined($icmp_type_names->{$rule->{dport}});
1674                 push @cmd, "-m icmp --icmp-type $rule->{dport}";
1675             } elsif ($rule->{proto} && $rule->{proto} eq 'icmpv6') {
1676                 # Note: we use dport to store --icmpv6-type
1677                 die "unknown icmpv6-type '$rule->{dport}'\n" if !defined($icmpv6_type_names->{$rule->{dport}});
1678                 push @cmd, "-m icmpv6 --icmpv6-type $rule->{dport}";
1679             } else {
1680                 if ($nbdport > 1) {
1681                     if ($multiport == 2) {
1682                         push @cmd,  "--ports $rule->{dport}";
1683                     } else {
1684                         push @cmd, "--dports $rule->{dport}";
1685                     }
1686                 } else {
1687                     push @cmd, "--dport $rule->{dport}";
1688                 }
1689             }
1690         }
1691
1692         if ($rule->{sport}) {
1693             if ($nbsport > 1) {
1694                 push @cmd, "--sports $rule->{sport}" if $multiport != 2;
1695             } else {
1696                 push @cmd, "--sport $rule->{sport}";
1697             }
1698         }
1699     } elsif ($rule->{dport} || $rule->{sport}) {
1700         die "destination port '$rule->{dport}', but no protocol specified\n" if $rule->{dport};
1701         die "source port '$rule->{sport}', but no protocol specified\n" if $rule->{sport};
1702     }
1703
1704     push @cmd, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
1705
1706     if (my $action = $rule->{action}) {
1707         $action = $actions->{$action} if defined($actions->{$action});
1708         $goto = 1 if !defined($goto) && $action eq 'PVEFW-SET-ACCEPT-MARK';
1709         push @cmd, $goto ? "-g $action" : "-j $action";
1710     }
1711
1712     return scalar(@cmd) ? join(' ', @cmd) : undef;
1713 }
1714
1715 sub ruleset_generate_rule {
1716     my ($ruleset, $chain, $ipversion, $rule, $actions, $goto, $cluster_conf, $fw_conf) = @_;
1717
1718     my $rules;
1719
1720     if ($rule->{macro}) {
1721         $rules = &$apply_macro($rule->{macro}, $rule, 0, $ipversion);
1722     } else {
1723         $rules = [ $rule ];
1724     }
1725
1726     # update all or nothing
1727
1728     my @cmds = ();
1729     foreach my $tmp (@$rules) {
1730         if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $ipversion, $tmp, $actions, $goto, $cluster_conf, $fw_conf)) {
1731             push @cmds, $cmdstr;
1732         }
1733     }
1734
1735     foreach my $cmdstr (@cmds) {
1736         ruleset_addrule($ruleset, $chain, $cmdstr);
1737     }
1738 }
1739
1740 sub ruleset_generate_rule_insert {
1741     my ($ruleset, $chain, $ipversion, $rule, $actions, $goto) = @_;
1742
1743     die "implement me" if $rule->{macro}; # not implemented, because not needed so far
1744
1745     if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $ipversion, $rule, $actions, $goto)) {
1746         ruleset_insertrule($ruleset, $chain, $cmdstr);
1747     }
1748 }
1749
1750 sub ruleset_create_chain {
1751     my ($ruleset, $chain) = @_;
1752
1753     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
1754     die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
1755
1756     die "chain '$chain' already exists\n" if $ruleset->{$chain};
1757
1758     $ruleset->{$chain} = [];
1759 }
1760
1761 sub ruleset_chain_exist {
1762     my ($ruleset, $chain) = @_;
1763
1764     return $ruleset->{$chain} ? 1 : undef;
1765 }
1766
1767 sub ruleset_addrule {
1768    my ($ruleset, $chain, $rule) = @_;
1769
1770    die "no such chain '$chain'\n" if !$ruleset->{$chain};
1771
1772    push @{$ruleset->{$chain}}, "-A $chain $rule";
1773 }
1774
1775 sub ruleset_insertrule {
1776    my ($ruleset, $chain, $rule) = @_;
1777
1778    die "no such chain '$chain'\n" if !$ruleset->{$chain};
1779
1780    unshift @{$ruleset->{$chain}}, "-A $chain $rule";
1781 }
1782
1783 sub get_log_rule_base {
1784     my ($chain, $vmid, $msg, $loglevel) = @_;
1785
1786     die "internal error - no log level" if !defined($loglevel);
1787
1788     $vmid = 0 if !defined($vmid);
1789
1790     # Note: we use special format for prefix to pass further
1791     # info to log daemon (VMID, LOGVELEL and CHAIN)
1792
1793     return "-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
1794 }
1795
1796 sub ruleset_addlog {
1797     my ($ruleset, $chain, $vmid, $msg, $loglevel, $rule) = @_;
1798
1799     return if !defined($loglevel);
1800
1801     my $logrule = get_log_rule_base($chain, $vmid, $msg, $loglevel);
1802
1803     $logrule = "$rule $logrule" if defined($rule);
1804
1805     ruleset_addrule($ruleset, $chain, $logrule);
1806 }
1807
1808 sub ruleset_add_chain_policy {
1809     my ($ruleset, $chain, $ipversion, $vmid, $policy, $loglevel, $accept_action) = @_;
1810
1811     if ($policy eq 'ACCEPT') {
1812
1813         ruleset_generate_rule($ruleset, $chain, $ipversion, { action => 'ACCEPT' },
1814                               { ACCEPT =>  $accept_action});
1815
1816     } elsif ($policy eq 'DROP') {
1817
1818         ruleset_addrule($ruleset, $chain, "-j PVEFW-Drop");
1819
1820         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1821
1822         ruleset_addrule($ruleset, $chain, "-j DROP");
1823     } elsif ($policy eq 'REJECT') {
1824         ruleset_addrule($ruleset, $chain, "-j PVEFW-Reject");
1825
1826         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1827
1828         ruleset_addrule($ruleset, $chain, "-g PVEFW-reject");
1829     } else {
1830         # should not happen
1831         die "internal error: unknown policy '$policy'";
1832     }
1833 }
1834
1835 sub ruleset_chain_add_conn_filters {
1836     my ($ruleset, $chain, $accept) = @_;
1837
1838     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1839     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j $accept");
1840 }
1841
1842 sub ruleset_chain_add_input_filters {
1843     my ($ruleset, $chain, $ipversion, $options, $cluster_conf, $loglevel) = @_;
1844
1845     if ($cluster_conf->{ipset}->{blacklist}){
1846         if (!ruleset_chain_exist($ruleset, "PVEFW-blacklist")) {
1847             ruleset_create_chain($ruleset, "PVEFW-blacklist");
1848             ruleset_addlog($ruleset, "PVEFW-blacklist", 0, "DROP: ", $loglevel) if $loglevel;
1849             ruleset_addrule($ruleset, "PVEFW-blacklist", "-j DROP");
1850         }
1851         my $ipset_chain = compute_ipset_chain_name(0, 'blacklist', $ipversion);
1852         ruleset_addrule($ruleset, $chain, "-m set --match-set ${ipset_chain} src -j PVEFW-blacklist");
1853     }
1854
1855     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
1856         if ($ipversion == 4) {
1857             ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW -j PVEFW-smurfs");
1858         }
1859     }
1860
1861     if ($options->{tcpflags}) {
1862         ruleset_addrule($ruleset, $chain, "-p tcp -j PVEFW-tcpflags");
1863     }
1864 }
1865
1866 sub ruleset_create_vm_chain {
1867     my ($ruleset, $chain, $ipversion, $options, $macaddr, $ipfilter_ipset, $direction) = @_;
1868
1869     ruleset_create_chain($ruleset, $chain);
1870     my $accept = generate_nfqueue($options);
1871
1872     if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
1873         if ($direction eq 'OUT') {
1874             ruleset_generate_rule($ruleset, $chain, $ipversion,
1875                                   { action => 'PVEFW-SET-ACCEPT-MARK',
1876                                     proto => 'udp', sport => 68, dport => 67 });
1877         } else {
1878             ruleset_generate_rule($ruleset, $chain, $ipversion,
1879                                   { action => 'ACCEPT',
1880                                     proto => 'udp', sport => 67, dport => 68 });
1881         }
1882     }
1883
1884     if ($direction eq 'OUT') {
1885         if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
1886             ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr -j DROP");
1887         }
1888         if ($ipfilter_ipset) {
1889             ruleset_addrule($ruleset, $chain, "-m set ! --match-set $ipfilter_ipset src -j DROP");
1890         }
1891         ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1892     }
1893 }
1894
1895 sub ruleset_add_group_rule {
1896     my ($ruleset, $cluster_conf, $chain, $rule, $direction, $action, $ipversion) = @_;
1897
1898     my $group = $rule->{action};
1899     my $group_chain = "GROUP-$group-$direction";
1900     if(!ruleset_chain_exist($ruleset, $group_chain)){
1901         generate_group_rules($ruleset, $cluster_conf, $group, $ipversion);
1902     }
1903
1904     if ($direction eq 'OUT' && $rule->{iface_out}) {
1905         ruleset_addrule($ruleset, $chain, "-o $rule->{iface_out} -j $group_chain");
1906     } elsif ($direction eq 'IN' && $rule->{iface_in}) {
1907         ruleset_addrule($ruleset, $chain, "-i $rule->{iface_in} -j $group_chain");
1908     } else {
1909         ruleset_addrule($ruleset, $chain, "-j $group_chain");
1910     }
1911
1912     ruleset_addrule($ruleset, $chain, "-m mark --mark 1 -j $action");
1913 }
1914
1915 sub ruleset_generate_vm_rules {
1916     my ($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, $netid, $direction, $options, $ipversion) = @_;
1917
1918     my $lc_direction = lc($direction);
1919
1920     my $in_accept = generate_nfqueue($options);
1921
1922     foreach my $rule (@$rules) {
1923         next if $rule->{iface} && $rule->{iface} ne $netid;
1924         next if !$rule->{enable} || $rule->{errors};
1925         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
1926
1927         if ($rule->{type} eq 'group') {
1928             ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, $direction,
1929                                    $direction eq 'OUT' ? 'RETURN' : $in_accept, $ipversion);
1930         } else {
1931             next if $rule->{type} ne $lc_direction;
1932             eval {
1933                 if ($direction eq 'OUT') {
1934                     ruleset_generate_rule($ruleset, $chain, $ipversion, $rule,
1935                                           { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" },
1936                                           undef, $cluster_conf, $vmfw_conf);
1937                 } else {
1938                     ruleset_generate_rule($ruleset, $chain, $ipversion, $rule,
1939                                           { ACCEPT => $in_accept , REJECT => "PVEFW-reject" },
1940                                           undef, $cluster_conf, $vmfw_conf);
1941                 }
1942             };
1943             warn $@ if $@;
1944         }
1945     }
1946 }
1947
1948 sub generate_nfqueue {
1949     my ($options) = @_;
1950
1951     if ($options->{ips}) {
1952         my $action = "NFQUEUE";
1953         if ($options->{ips_queues} && $options->{ips_queues} =~ m/^(\d+)(:(\d+))?$/) {
1954             if (defined($3) && defined($1)) {
1955                 $action .= " --queue-balance $1:$3";
1956             } elsif (defined($1)) {
1957                 $action .= " --queue-num $1";
1958             }
1959         }
1960         $action .= " --queue-bypass" if $feature_ipset_nomatch; #need kernel 3.10
1961         return $action;
1962     } else {
1963         return "ACCEPT";
1964     }
1965 }
1966
1967 sub ruleset_generate_vm_ipsrules {
1968     my ($ruleset, $options, $direction, $iface) = @_;
1969
1970     if ($options->{ips} && $direction eq 'IN') {
1971         my $nfqueue = generate_nfqueue($options);
1972
1973         if (!ruleset_chain_exist($ruleset, "PVEFW-IPS")) {
1974             ruleset_create_chain($ruleset, "PVEFW-IPS");
1975         }
1976
1977         ruleset_addrule($ruleset, "PVEFW-IPS", "-m physdev --physdev-out $iface --physdev-is-bridged -j $nfqueue");
1978     }
1979 }
1980
1981 sub generate_venet_rules_direction {
1982     my ($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip, $direction, $ipversion) = @_;
1983
1984     my $lc_direction = lc($direction);
1985
1986     my $rules = $vmfw_conf->{rules};
1987
1988     my $options = $vmfw_conf->{options};
1989     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1990
1991     my $chain = "venet0-$vmid-$direction";
1992
1993     ruleset_create_vm_chain($ruleset, $chain, $ipversion, $options, undef, undef, $direction);
1994
1995     ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, 'venet', $direction, undef, $ipversion);
1996
1997     # implement policy
1998     my $policy;
1999
2000     if ($direction eq 'OUT') {
2001         $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
2002     } else {
2003         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
2004     }
2005
2006     my $accept = generate_nfqueue($options);
2007     my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
2008     ruleset_add_chain_policy($ruleset, $chain, $ipversion, $vmid, $policy, $loglevel, $accept_action);
2009
2010     if ($direction eq 'OUT') {
2011         ruleset_generate_rule_insert($ruleset, "PVEFW-VENET-OUT", $ipversion, {
2012             action => $chain,
2013             source => $ip,
2014             iface_in => 'venet0'});
2015     } else {
2016         ruleset_generate_rule($ruleset, "PVEFW-VENET-IN", $ipversion, {
2017             action => $chain,
2018             dest => $ip,
2019             iface_out => 'venet0'});
2020     }
2021 }
2022
2023 sub generate_tap_rules_direction {
2024     my ($ruleset, $cluster_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $direction, $ipversion) = @_;
2025
2026     my $lc_direction = lc($direction);
2027
2028     my $rules = $vmfw_conf->{rules};
2029
2030     my $options = $vmfw_conf->{options};
2031     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
2032
2033     my $tapchain = "$iface-$direction";
2034
2035     my $ipfilter_name = compute_ipfilter_ipset_name($netid);
2036     my $ipfilter_ipset = compute_ipset_chain_name($vmid, $ipfilter_name, $ipversion)
2037         if $vmfw_conf->{ipset}->{$ipfilter_name};
2038
2039     # create chain with mac and ip filter
2040     ruleset_create_vm_chain($ruleset, $tapchain, $ipversion, $options, $macaddr, $ipfilter_ipset, $direction);
2041
2042     if ($options->{enable}) {
2043         ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $tapchain, $netid, $direction, $options, $ipversion);
2044
2045         ruleset_generate_vm_ipsrules($ruleset, $options, $direction, $iface);
2046
2047         # implement policy
2048         my $policy;
2049
2050         if ($direction eq 'OUT') {
2051             $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
2052         } else {
2053         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
2054         }
2055
2056         my $accept = generate_nfqueue($options);
2057         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
2058         ruleset_add_chain_policy($ruleset, $tapchain, $ipversion, $vmid, $policy, $loglevel, $accept_action);
2059     } else {
2060         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : 'ACCEPT';
2061         ruleset_add_chain_policy($ruleset, $tapchain, $ipversion, $vmid, 'ACCEPT', $loglevel, $accept_action);
2062     }
2063
2064     # plug the tap chain to bridge chain
2065     if ($direction eq 'IN') {
2066         ruleset_addrule($ruleset, "PVEFW-FWBR-IN",
2067                         "-m physdev --physdev-is-bridged --physdev-out $iface -j $tapchain");
2068     } else {
2069         ruleset_addrule($ruleset, "PVEFW-FWBR-OUT",
2070                         "-m physdev --physdev-is-bridged --physdev-in $iface -j $tapchain");
2071     }
2072 }
2073
2074 sub enable_host_firewall {
2075     my ($ruleset, $hostfw_conf, $cluster_conf, $ipversion) = @_;
2076
2077     my $options = $hostfw_conf->{options};
2078     my $cluster_options = $cluster_conf->{options};
2079     my $rules = $hostfw_conf->{rules};
2080     my $cluster_rules = $cluster_conf->{rules};
2081
2082     # host inbound firewall
2083     my $chain = "PVEFW-HOST-IN";
2084     ruleset_create_chain($ruleset, $chain);
2085
2086     my $loglevel = get_option_log_level($options, "log_level_in");
2087
2088     ruleset_addrule($ruleset, $chain, "-i lo -j ACCEPT");
2089
2090     ruleset_chain_add_conn_filters($ruleset, $chain, 'ACCEPT');
2091     ruleset_chain_add_input_filters($ruleset, $chain, $ipversion, $options, $cluster_conf, $loglevel);
2092
2093     # we use RETURN because we need to check also tap rules
2094     my $accept_action = 'RETURN';
2095
2096     ruleset_addrule($ruleset, $chain, "-p igmp -j $accept_action"); # important for multicast
2097
2098     # add host rules first, so that cluster wide rules can be overwritten
2099     foreach my $rule (@$rules, @$cluster_rules) {
2100         next if !$rule->{enable} || $rule->{errors};
2101         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2102
2103         $rule->{iface_in} = $rule->{iface} if $rule->{iface};
2104
2105         eval {
2106             if ($rule->{type} eq 'group') {
2107                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'IN', $accept_action, $ipversion);
2108             } elsif ($rule->{type} eq 'in') {
2109                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule,
2110                                       { ACCEPT => $accept_action, REJECT => "PVEFW-reject" },
2111                                       undef, $cluster_conf, $hostfw_conf);
2112             }
2113         };
2114         warn $@ if $@;
2115         delete $rule->{iface_in};
2116     }
2117
2118     # allow standard traffic for management ipset (includes cluster network)
2119     my $mngmnt_ipset_chain = compute_ipset_chain_name(0, "management", $ipversion);
2120     my $mngmntsrc = "-m set --match-set ${mngmnt_ipset_chain} src";
2121     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 8006 -j $accept_action");  # PVE API
2122     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 5900:5999 -j $accept_action");  # PVE VNC Console
2123     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 3128 -j $accept_action");  # SPICE Proxy
2124     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 22 -j $accept_action");  # SSH
2125
2126     my $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
2127     my $localnet_ver = $cluster_conf->{aliases}->{local_network}->{ipversion};
2128
2129     # corosync
2130     if ($localnet && ($ipversion == $localnet_ver)) {
2131         my $corosync_rule = "-p udp --dport 5404:5405 -j $accept_action";
2132         ruleset_addrule($ruleset, $chain, "-s $localnet -d $localnet $corosync_rule");
2133         ruleset_addrule($ruleset, $chain, "-s $localnet -m addrtype --dst-type MULTICAST $corosync_rule");
2134     }
2135
2136     # implement input policy
2137     my $policy = $cluster_options->{policy_in} || 'DROP'; # allow nothing by default
2138     ruleset_add_chain_policy($ruleset, $chain, $ipversion, 0, $policy, $loglevel, $accept_action);
2139
2140     # host outbound firewall
2141     $chain = "PVEFW-HOST-OUT";
2142     ruleset_create_chain($ruleset, $chain);
2143
2144     $loglevel = get_option_log_level($options, "log_level_out");
2145
2146     ruleset_addrule($ruleset, $chain, "-o lo -j ACCEPT");
2147
2148     ruleset_chain_add_conn_filters($ruleset, $chain, 'ACCEPT');
2149
2150     # we use RETURN because we may want to check other thigs later
2151     $accept_action = 'RETURN';
2152
2153     ruleset_addrule($ruleset, $chain, "-p igmp -j $accept_action"); # important for multicast
2154
2155     # add host rules first, so that cluster wide rules can be overwritten
2156     foreach my $rule (@$rules, @$cluster_rules) {
2157         next if !$rule->{enable} || $rule->{errors};
2158         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2159
2160         $rule->{iface_out} = $rule->{iface} if $rule->{iface};
2161         eval {
2162             if ($rule->{type} eq 'group') {
2163                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'OUT', $accept_action, $ipversion);
2164             } elsif ($rule->{type} eq 'out') {
2165                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2166                                       $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" },
2167                                       undef, $cluster_conf, $hostfw_conf);
2168             }
2169         };
2170         warn $@ if $@;
2171         delete $rule->{iface_out};
2172     }
2173
2174     # allow standard traffic on cluster network
2175     if ($localnet && ($ipversion == $localnet_ver)) {
2176         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 8006 -j $accept_action");  # PVE API
2177         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 22 -j $accept_action");  # SSH
2178         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 5900:5999 -j $accept_action");  # PVE VNC Console
2179         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 3128 -j $accept_action");  # SPICE Proxy
2180
2181         my $corosync_rule = "-p udp --dport 5404:5405 -j $accept_action";
2182         ruleset_addrule($ruleset, $chain, "-d $localnet $corosync_rule");
2183         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule");
2184     }
2185
2186     # implement output policy
2187     $policy = $cluster_options->{policy_out} || 'ACCEPT'; # allow everything by default
2188     ruleset_add_chain_policy($ruleset, $chain, $ipversion, 0, $policy, $loglevel, $accept_action);
2189
2190     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-j PVEFW-HOST-OUT");
2191     ruleset_addrule($ruleset, "PVEFW-INPUT", "-j PVEFW-HOST-IN");
2192 }
2193
2194 sub generate_group_rules {
2195     my ($ruleset, $cluster_conf, $group, $ipversion) = @_;
2196
2197     my $rules = $cluster_conf->{groups}->{$group};
2198
2199     if (!$rules) {
2200         warn "no such security group '$group'\n";
2201         $rules = []; # create empty chain
2202     }
2203
2204     my $chain = "GROUP-${group}-IN";
2205
2206     ruleset_create_chain($ruleset, $chain);
2207     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
2208
2209     foreach my $rule (@$rules) {
2210         next if $rule->{type} ne 'in';
2211         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2212         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule,
2213                               { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" },
2214                               undef, $cluster_conf);
2215     }
2216
2217     $chain = "GROUP-${group}-OUT";
2218
2219     ruleset_create_chain($ruleset, $chain);
2220     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
2221
2222     foreach my $rule (@$rules) {
2223         next if $rule->{type} ne 'out';
2224         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2225         # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
2226         # check also other tap rules later
2227         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule,
2228                               { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" },
2229                               undef, $cluster_conf);
2230     }
2231 }
2232
2233 my $MAX_NETS = 32;
2234 my $valid_netdev_names = {};
2235 for (my $i = 0; $i < $MAX_NETS; $i++)  {
2236     $valid_netdev_names->{"net$i"} = 1;
2237 }
2238
2239 sub parse_fw_rule {
2240     my ($prefix, $line, $cluster_conf, $fw_conf, $rule_env, $verbose) = @_;
2241
2242     my $orig_line = $line;
2243
2244     my $rule = {};
2245
2246     # we can add single line comments to the end of the rule
2247     if ($line =~ s/#\s*(.*?)\s*$//) {
2248         $rule->{comment} = decode('utf8', $1);
2249     }
2250
2251     # we can disable a rule when prefixed with '|'
2252
2253     $rule->{enable} = $line =~ s/^\|// ? 0 : 1;
2254
2255     $line =~ s/^(\S+)\s+(\S+)\s*// ||
2256         die "unable to parse rule: $line\n";
2257
2258     $rule->{type} = lc($1);
2259     $rule->{action} = $2;
2260
2261     if ($rule->{type} eq  'in' || $rule->{type} eq 'out') {
2262         if ($rule->{action} =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
2263             $rule->{macro} = $1;
2264             $rule->{action} = $2;
2265         }
2266     }
2267
2268     while (length($line)) {
2269         if ($line =~ s/^-i (\S+)\s*//) {
2270             $rule->{iface} = $1;
2271             next;
2272         }
2273
2274         last if $rule->{type} eq 'group';
2275
2276         if ($line =~ s/^-p (\S+)\s*//) {
2277             $rule->{proto} = $1;
2278             next;
2279         }
2280
2281         if ($line =~ s/^-dport (\S+)\s*//) {
2282             $rule->{dport} = $1;
2283             next;
2284         }
2285
2286         if ($line =~ s/^-sport (\S+)\s*//) {
2287             $rule->{sport} = $1;
2288             next;
2289         }
2290         if ($line =~ s/^-source (\S+)\s*//) {
2291             $rule->{source} = $1;
2292             next;
2293         }
2294         if ($line =~ s/^-dest (\S+)\s*//) {
2295             $rule->{dest} = $1;
2296             next;
2297         }
2298
2299         last;
2300     }
2301
2302     die "unable to parse rule parameters: $line\n" if length($line);
2303
2304     $rule = verify_rule($rule, $cluster_conf, $fw_conf, $rule_env, 1);
2305     if ($verbose && $rule->{errors}) {
2306         warn "$prefix - errors in rule parameters: $orig_line\n";
2307         foreach my $p (keys %{$rule->{errors}}) {
2308             warn "  $p: $rule->{errors}->{$p}\n";
2309         }
2310     }
2311
2312     return $rule;
2313 }
2314
2315 sub parse_vmfw_option {
2316     my ($line) = @_;
2317
2318     my ($opt, $value);
2319
2320     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2321
2322     if ($line =~ m/^(enable|dhcp|macfilter|ips):\s*(0|1)\s*$/i) {
2323         $opt = lc($1);
2324         $value = int($2);
2325     } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
2326         $opt = lc($1);
2327         $value = $2 ? lc($3) : '';
2328     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2329         $opt = lc($1);
2330         $value = uc($3);
2331     } elsif ($line =~ m/^(ips_queues):\s*((\d+)(:(\d+))?)\s*$/i) {
2332         $opt = lc($1);
2333         $value = $2;
2334     } else {
2335         die "can't parse option '$line'\n"
2336     }
2337
2338     return ($opt, $value);
2339 }
2340
2341 sub parse_hostfw_option {
2342     my ($line) = @_;
2343
2344     my ($opt, $value);
2345
2346     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2347
2348     if ($line =~ m/^(enable|nosmurfs|tcpflags):\s*(0|1)\s*$/i) {
2349         $opt = lc($1);
2350         $value = int($2);
2351     } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
2352         $opt = lc($1);
2353         $value = $2 ? lc($3) : '';
2354     } elsif ($line =~ m/^(nf_conntrack_max|nf_conntrack_tcp_timeout_established):\s*(\d+)\s*$/i) {
2355         $opt = lc($1);
2356         $value = int($2);
2357     } else {
2358         die "can't parse option '$line'\n"
2359     }
2360
2361     return ($opt, $value);
2362 }
2363
2364 sub parse_clusterfw_option {
2365     my ($line) = @_;
2366
2367     my ($opt, $value);
2368
2369     if ($line =~ m/^(enable):\s*(\d+)\s*$/i) {
2370         $opt = lc($1);
2371         $value = int($2);
2372         if (($value > 1) && ((time() - $value) > 60)) {
2373             $value = 0
2374         }
2375     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2376         $opt = lc($1);
2377         $value = uc($3);
2378     } else {
2379         die "can't parse option '$line'\n"
2380     }
2381
2382     return ($opt, $value);
2383 }
2384
2385 sub resolve_alias {
2386     my ($clusterfw_conf, $fw_conf, $cidr) = @_;
2387
2388     my $alias = lc($cidr);
2389     my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
2390     $e = $clusterfw_conf->{aliases}->{$alias} if !$e && $clusterfw_conf;
2391
2392     die "no such alias '$cidr'\n" if !$e;;
2393
2394     return wantarray ? ($e->{cidr}, $e->{ipversion}) : $e->{cidr};
2395 }
2396
2397 sub parse_ip_or_cidr {
2398     my ($cidr) = @_;
2399
2400     my $ipversion;
2401
2402     if ($cidr =~ m!^(?:$IPV6RE)(/(\d+))?$!) {
2403         $cidr =~ s|/128$||;
2404         $ipversion = 6;
2405     } elsif ($cidr =~ m!^(?:$IPV4RE)(/(\d+))?$!) {
2406         $cidr =~ s|/32$||;
2407         $ipversion = 4;
2408     } else {
2409         die "value does not look like a valid IP address or CIDR network\n";
2410     }
2411
2412     return wantarray ? ($cidr, $ipversion) : $cidr;
2413 }
2414
2415 sub parse_alias {
2416     my ($line) = @_;
2417
2418     # we can add single line comments to the end of the line
2419     my $comment = decode('utf8', $1) if $line =~ s/\s*#\s*(.*?)\s*$//;
2420
2421     if ($line =~ m/^(\S+)\s(\S+)$/) {
2422         my ($name, $cidr) = ($1, $2);
2423         my $ipversion;
2424
2425         ($cidr, $ipversion) = parse_ip_or_cidr($cidr);
2426
2427         my $data = {
2428             name => $name,
2429             cidr => $cidr,
2430             ipversion => $ipversion,
2431         };
2432         $data->{comment} = $comment  if $comment;
2433         return $data;
2434     }
2435
2436     return undef;
2437 }
2438
2439 sub generic_fw_config_parser {
2440     my ($filename, $fh, $verbose, $cluster_conf, $empty_conf, $rule_env) = @_;
2441
2442     my $section;
2443     my $group;
2444
2445     my $res = $empty_conf;
2446
2447     while (defined(my $line = <$fh>)) {
2448         next if $line =~ m/^#/;
2449         next if $line =~ m/^\s*$/;
2450
2451         chomp $line;
2452
2453         my $linenr = $fh->input_line_number();
2454         my $prefix = "$filename (line $linenr)";
2455
2456         if ($empty_conf->{options} && ($line =~ m/^\[options\]$/i)) {
2457             $section = 'options';
2458             next;
2459         }
2460
2461         if ($empty_conf->{aliases} && ($line =~ m/^\[aliases\]$/i)) {
2462             $section = 'aliases';
2463             next;
2464         }
2465
2466         if ($empty_conf->{groups} && ($line =~ m/^\[group\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
2467             $section = 'groups';
2468             $group = lc($1);
2469             my $comment = $2;
2470             eval {
2471                 die "security group name too long\n" if length($group) > $max_group_name_length;
2472                 die "invalid security group name '$group'\n" if $group !~ m/^${security_group_name_pattern}$/;
2473             };
2474             if (my $err = $@) {
2475                 ($section, $group, $comment) = undef;
2476                 warn "$prefix: $err";
2477                 next;
2478             }
2479
2480             $res->{$section}->{$group} = [];
2481             $res->{group_comments}->{$group} =  decode('utf8', $comment)
2482                 if $comment;
2483             next;
2484         }
2485
2486         if ($empty_conf->{rules} && ($line =~ m/^\[rules\]$/i)) {
2487             $section = 'rules';
2488             next;
2489         }
2490
2491         if ($empty_conf->{ipset} && ($line =~ m/^\[ipset\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
2492             $section = 'ipset';
2493             $group = lc($1);
2494             my $comment = $2;
2495             eval {
2496                 die "ipset name too long\n" if length($group) > $max_ipset_name_length;
2497                 die "invalid ipset name '$group'\n" if $group !~ m/^${ipset_name_pattern}$/;
2498             };
2499             if (my $err = $@) {
2500                 ($section, $group, $comment) = undef;
2501                 warn "$prefix: $err";
2502                 next;
2503             }
2504
2505             $res->{$section}->{$group} = [];
2506             $res->{ipset_comments}->{$group} = decode('utf8', $comment)
2507                 if $comment;
2508             next;
2509         }
2510
2511         if (!$section) {
2512             warn "$prefix: skip line - no section\n";
2513             next;
2514         }
2515
2516         if ($section eq 'options') {
2517             eval {
2518                 my ($opt, $value);
2519                 if ($rule_env eq 'cluster') {
2520                     ($opt, $value) = parse_clusterfw_option($line);
2521                 } elsif ($rule_env eq 'host') {
2522                     ($opt, $value) = parse_hostfw_option($line);
2523                 } else {
2524                     ($opt, $value) = parse_vmfw_option($line);
2525                 }
2526                 $res->{options}->{$opt} = $value;
2527             };
2528             warn "$prefix: $@" if $@;
2529         } elsif ($section eq 'aliases') {
2530             eval {
2531                 my $data = parse_alias($line);
2532                 $res->{aliases}->{lc($data->{name})} = $data;
2533             };
2534             warn "$prefix: $@" if $@;
2535         } elsif ($section eq 'rules') {
2536             my $rule;
2537             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, $res, $rule_env, $verbose); };
2538             if (my $err = $@) {
2539                 warn "$prefix: $err";
2540                 next;
2541             }
2542             push @{$res->{$section}}, $rule;
2543         } elsif ($section eq 'groups') {
2544             my $rule;
2545             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, undef, 'group', $verbose); };
2546             if (my $err = $@) {
2547                 warn "$prefix: $err";
2548                 next;
2549             }
2550             push @{$res->{$section}->{$group}}, $rule;
2551         } elsif ($section eq 'ipset') {
2552             # we can add single line comments to the end of the rule
2553             my $comment = decode('utf8', $1) if $line =~ s/#\s*(.*?)\s*$//;
2554
2555             $line =~ m/^(\!)?\s*(\S+)\s*$/;
2556             my $nomatch = $1;
2557             my $cidr = $2;
2558             my $errors;
2559
2560             if ($nomatch && !$feature_ipset_nomatch) {
2561                 $errors->{nomatch} = "nomatch not supported by kernel";
2562             }
2563
2564             eval {
2565                 if ($cidr =~ m/^${ip_alias_pattern}$/) {
2566                     resolve_alias($cluster_conf, $res, $cidr); # make sure alias exists
2567                 } else {
2568                     $cidr = parse_ip_or_cidr($cidr);
2569                 }
2570             };
2571             if (my $err = $@) {
2572                 chomp $err;
2573                 $errors->{cidr} = $err;
2574             }
2575
2576             my $entry = { cidr => $cidr };
2577             $entry->{nomatch} = 1 if $nomatch;
2578             $entry->{comment} = $comment if $comment;
2579             $entry->{errors} =  $errors if $errors;
2580
2581             if ($verbose && $errors) {
2582                 warn "$prefix - errors in ipset '$group': $line\n";
2583                 foreach my $p (keys %{$errors}) {
2584                     warn "  $p: $errors->{$p}\n";
2585                 }
2586             }
2587
2588             push @{$res->{$section}->{$group}}, $entry;
2589         } else {
2590             warn "$prefix: skip line - unknown section\n";
2591             next;
2592         }
2593     }
2594
2595     return $res;
2596 }
2597
2598 sub parse_hostfw_config {
2599     my ($filename, $fh, $cluster_conf, $verbose) = @_;
2600
2601     my $empty_conf = { rules => [], options => {}};
2602
2603     return generic_fw_config_parser($filename, $fh, $verbose, $cluster_conf, $empty_conf, 'host');
2604 }
2605
2606 sub parse_vmfw_config {
2607     my ($filename, $fh, $cluster_conf, $rule_env, $verbose) = @_;
2608
2609     my $empty_conf = {
2610         rules => [],
2611         options => {},
2612         aliases => {},
2613         ipset => {} ,
2614         ipset_comments => {},
2615     };
2616
2617     return generic_fw_config_parser($filename, $fh, $verbose, $cluster_conf, $empty_conf, $rule_env);
2618 }
2619
2620 sub parse_clusterfw_config {
2621     my ($filename, $fh, $verbose) = @_;
2622
2623     my $section;
2624     my $group;
2625
2626     my $empty_conf = {
2627         rules => [],
2628         options => {},
2629         aliases => {},
2630         groups => {},
2631         group_comments => {},
2632         ipset => {} ,
2633         ipset_comments => {},
2634     };
2635
2636     return generic_fw_config_parser($filename, $fh, $verbose, $empty_conf, $empty_conf, 'cluster');
2637 }
2638
2639 sub run_locked {
2640     my ($code, @param) = @_;
2641
2642     my $timeout = 10;
2643
2644     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
2645
2646     die $@ if $@;
2647
2648     return $res;
2649 }
2650
2651 sub read_local_vm_config {
2652
2653     my $openvz = {};
2654     my $qemu = {};
2655
2656     my $vmdata = { openvz => $openvz, qemu => $qemu };
2657
2658     my $vmlist = PVE::Cluster::get_vmlist();
2659     return $vmdata if !$vmlist || !$vmlist->{ids};
2660     my $ids = $vmlist->{ids};
2661
2662     foreach my $vmid (keys %$ids) {
2663         next if !$vmid; # skip VE0
2664         my $d = $ids->{$vmid};
2665         next if !$d->{node} || $d->{node} ne $nodename;
2666         next if !$d->{type};
2667         if ($d->{type} eq 'openvz') {
2668             if ($have_pve_manager) {
2669                 my $cfspath = PVE::OpenVZ::cfs_config_path($vmid);
2670                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
2671                     $openvz->{$vmid} = $conf;
2672                 }
2673             }
2674         } elsif ($d->{type} eq 'qemu') {
2675             if ($have_qemu_server) {
2676                 my $cfspath = PVE::QemuServer::cfs_config_path($vmid);
2677                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
2678                     $qemu->{$vmid} = $conf;
2679                 }
2680             }
2681         }
2682     }
2683
2684     return $vmdata;
2685 };
2686
2687 sub load_vmfw_conf {
2688     my ($cluster_conf, $rule_env, $vmid, $dir, $verbose) = @_;
2689
2690     my $vmfw_conf = {};
2691
2692     $dir = $pvefw_conf_dir if !defined($dir);
2693
2694     my $filename = "$dir/$vmid.fw";
2695     if (my $fh = IO::File->new($filename, O_RDONLY)) {
2696         $vmfw_conf = parse_vmfw_config($filename, $fh, $cluster_conf, $rule_env, $verbose);
2697         $vmfw_conf->{vmid} = $vmid;
2698     }
2699
2700     return $vmfw_conf;
2701 }
2702
2703 my $format_rules = sub {
2704     my ($rules, $allow_iface) = @_;
2705
2706     my $raw = '';
2707
2708     foreach my $rule (@$rules) {
2709         if ($rule->{type} eq  'in' || $rule->{type} eq 'out' || $rule->{type} eq 'group') {
2710             $raw .= '|' if defined($rule->{enable}) && !$rule->{enable};
2711             $raw .= uc($rule->{type});
2712             if ($rule->{macro}) {
2713                 $raw .= " $rule->{macro}($rule->{action})";
2714             } else {
2715                 $raw .= " " . $rule->{action};
2716             }
2717             if ($allow_iface && $rule->{iface}) {
2718                 $raw .= " -i $rule->{iface}";
2719             }
2720
2721             if ($rule->{type} ne  'group')  {
2722                 $raw .= " -source $rule->{source}" if $rule->{source};
2723                 $raw .= " -dest $rule->{dest}" if $rule->{dest};
2724                 $raw .= " -p $rule->{proto}" if $rule->{proto};
2725                 $raw .= " -dport $rule->{dport}" if $rule->{dport};
2726                 $raw .= " -sport $rule->{sport}" if $rule->{sport};
2727             }
2728
2729             $raw .= " # " . encode('utf8', $rule->{comment})
2730                 if $rule->{comment} && $rule->{comment} !~ m/^\s*$/;
2731             $raw .= "\n";
2732         } else {
2733             die "unknown rule type '$rule->{type}'";
2734         }
2735     }
2736
2737     return $raw;
2738 };
2739
2740 my $format_options = sub {
2741     my ($options) = @_;
2742
2743     my $raw = '';
2744
2745     $raw .= "[OPTIONS]\n\n";
2746     foreach my $opt (keys %$options) {
2747         $raw .= "$opt: $options->{$opt}\n";
2748     }
2749     $raw .= "\n";
2750
2751     return $raw;
2752 };
2753
2754 my $format_aliases = sub {
2755     my ($aliases) = @_;
2756
2757     my $raw = '';
2758
2759     $raw .= "[ALIASES]\n\n";
2760     foreach my $k (keys %$aliases) {
2761         my $e = $aliases->{$k};
2762         $raw .= "$e->{name} $e->{cidr}";
2763         $raw .= " # " . encode('utf8', $e->{comment})
2764             if $e->{comment} && $e->{comment} !~ m/^\s*$/;
2765         $raw .= "\n";
2766     }
2767     $raw .= "\n";
2768
2769     return $raw;
2770 };
2771
2772 my $format_ipsets = sub {
2773     my ($fw_conf) = @_;
2774
2775     my $raw = '';
2776
2777     foreach my $ipset (sort keys %{$fw_conf->{ipset}}) {
2778         if (my $comment = $fw_conf->{ipset_comments}->{$ipset}) {
2779             my $utf8comment = encode('utf8', $comment);
2780             $raw .= "[IPSET $ipset] # $utf8comment\n\n";
2781         } else {
2782             $raw .= "[IPSET $ipset]\n\n";
2783         }
2784         my $options = $fw_conf->{ipset}->{$ipset};
2785
2786         my $nethash = {};
2787         foreach my $entry (@$options) {
2788             $nethash->{$entry->{cidr}} = $entry;
2789         }
2790
2791         foreach my $cidr (sort keys %$nethash) {
2792             my $entry = $nethash->{$cidr};
2793             my $line = $entry->{nomatch} ? '!' : '';
2794             $line .= $entry->{cidr};
2795             $line .= " # " . encode('utf8', $entry->{comment})
2796                 if $entry->{comment} && $entry->{comment} !~ m/^\s*$/;
2797             $raw .= "$line\n";
2798         }
2799
2800         $raw .= "\n";
2801     }
2802
2803     return $raw;
2804 };
2805
2806 sub save_vmfw_conf {
2807     my ($vmid, $vmfw_conf) = @_;
2808
2809     my $raw = '';
2810
2811     my $options = $vmfw_conf->{options};
2812     $raw .= &$format_options($options) if $options && scalar(keys %$options);
2813
2814     my $aliases = $vmfw_conf->{aliases};
2815     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
2816
2817     $raw .= &$format_ipsets($vmfw_conf) if $vmfw_conf->{ipset};
2818
2819     my $rules = $vmfw_conf->{rules} || [];
2820     if ($rules && scalar(@$rules)) {
2821         $raw .= "[RULES]\n\n";
2822         $raw .= &$format_rules($rules, 1);
2823         $raw .= "\n";
2824     }
2825
2826     mkdir $pvefw_conf_dir;
2827
2828     my $filename = "$pvefw_conf_dir/$vmid.fw";
2829     PVE::Tools::file_set_contents($filename, $raw);
2830 }
2831
2832 sub read_vm_firewall_configs {
2833     my ($cluster_conf, $vmdata, $dir, $verbose) = @_;
2834
2835     my $vmfw_configs = {};
2836
2837     foreach my $vmid (keys %{$vmdata->{qemu}}) {
2838         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'vm', $vmid, $dir, $verbose);
2839         next if !$vmfw_conf->{options}; # skip if file does not exists
2840         $vmfw_configs->{$vmid} = $vmfw_conf;
2841     }
2842     foreach my $vmid (keys %{$vmdata->{openvz}}) {
2843         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'ct', $vmid, $dir, $verbose);
2844         next if !$vmfw_conf->{options}; # skip if file does not exists
2845         $vmfw_configs->{$vmid} = $vmfw_conf;
2846     }
2847
2848     return $vmfw_configs;
2849 }
2850
2851 sub get_option_log_level {
2852     my ($options, $k) = @_;
2853
2854     my $v = $options->{$k};
2855     $v = $default_log_level if !defined($v);
2856
2857     return undef if $v eq '' || $v eq 'nolog';
2858
2859     $v = $log_level_hash->{$v} if defined($log_level_hash->{$v});
2860
2861     return $v if ($v >= 0) && ($v <= 7);
2862
2863     warn "unknown log level ($k = '$v')\n";
2864
2865     return undef;
2866 }
2867
2868 sub generate_std_chains {
2869     my ($ruleset, $options, $ipversion) = @_;
2870
2871     my $std_chains = $pve_std_chains->{$ipversion} || die "internal error";
2872
2873     my $loglevel = get_option_log_level($options, 'smurf_log_level');
2874
2875     my $chain;
2876
2877     if ($ipversion == 4) {
2878         # same as shorewall smurflog.
2879         $chain = 'PVEFW-smurflog';
2880         $std_chains->{$chain} = [];
2881
2882         push @{$std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
2883         push @{$std_chains->{$chain}}, "-j DROP";
2884     }
2885
2886     # same as shorewall logflags action.
2887     $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
2888     $chain = 'PVEFW-logflags';
2889     $std_chains->{$chain} = [];
2890
2891     # fixme: is this correctly logged by pvewf-logger? (ther is no --log-ip-options for NFLOG)
2892     push @{$std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
2893     push @{$std_chains->{$chain}}, "-j DROP";
2894
2895     foreach my $chain (keys %$std_chains) {
2896         ruleset_create_chain($ruleset, $chain);
2897         foreach my $rule (@{$std_chains->{$chain}}) {
2898             if (ref($rule)) {
2899                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule);
2900             } else {
2901                 ruleset_addrule($ruleset, $chain, $rule);
2902             }
2903         }
2904     }
2905 }
2906
2907 sub generate_ipset_chains {
2908     my ($ipset_ruleset, $clusterfw_conf, $fw_conf) = @_; #fixme
2909
2910     foreach my $ipset (keys %{$fw_conf->{ipset}}) {
2911
2912         my $options = $fw_conf->{ipset}->{$ipset};
2913
2914         # remove duplicates
2915         my $nethash = {};
2916         foreach my $entry (@$options) {
2917             next if $entry->{errors}; # skip entries with errors
2918             eval {
2919                 my ($cidr, $ver);
2920                 if ($entry->{cidr} =~ m/^${ip_alias_pattern}$/) {
2921                     ($cidr, $ver) = resolve_alias($clusterfw_conf, $fw_conf, $entry->{cidr});
2922                 } else {
2923                     ($cidr, $ver) = parse_ip_or_cidr($entry->{cidr});
2924                 }
2925                 #http://backreference.org/2013/03/01/ipv6-address-normalization/
2926                 if ($ver == 6) {
2927                     my $ipv6 = inet_pton(AF_INET6, lc($cidr));
2928                     $cidr = inet_ntop(AF_INET6, $ipv6);
2929                     $cidr =~ s|/128$||;
2930                 } else {
2931                     $cidr =~ s|/32$||;
2932                 }
2933
2934                 $nethash->{$ver}->{$cidr} = { cidr => $cidr, nomatch => $entry->{nomatch} };
2935             };
2936             warn $@ if $@;
2937         }
2938
2939         foreach my $ipversion (4, 6) {
2940             my $data = $nethash->{$ipversion};
2941
2942             my $name = compute_ipset_chain_name($fw_conf->{vmid}, $ipset, $ipversion);
2943
2944             my $hashsize = scalar(@$options);
2945             if ($hashsize <= 64) {
2946                 $hashsize = 64;
2947             } else {
2948                 $hashsize = round_powerof2($hashsize);
2949             }
2950
2951             my $family = $ipversion == "6" ? "inet6" : "inet";
2952
2953             $ipset_ruleset->{$name} = ["create $name hash:net family $family hashsize $hashsize maxelem $hashsize"];
2954
2955             foreach my $cidr (sort keys %$data) {
2956                 my $entry = $data->{$cidr};
2957
2958                 my $cmd = "add $name $cidr";
2959                 if ($entry->{nomatch}) {
2960                     if ($feature_ipset_nomatch) {
2961                         push @{$ipset_ruleset->{$name}}, "$cmd nomatch";
2962                     } else {
2963                         warn "ignore !$cidr - nomatch not supported by kernel\n";
2964                     }
2965                 } else {
2966                     push @{$ipset_ruleset->{$name}}, $cmd;
2967                 }
2968             }
2969         }
2970     }
2971 }
2972
2973 sub round_powerof2 {
2974     my ($int) = @_;
2975
2976     $int--;
2977     $int |= $int >> $_ foreach (1,2,4,8,16);
2978     return ++$int;
2979 }
2980
2981 sub load_clusterfw_conf {
2982     my ($filename, $verbose) = @_;
2983
2984     $filename = $clusterfw_conf_filename if !defined($filename);
2985
2986     my $cluster_conf = {};
2987     if (my $fh = IO::File->new($filename, O_RDONLY)) {
2988         $cluster_conf = parse_clusterfw_config($filename, $fh, $verbose);
2989     }
2990
2991     return $cluster_conf;
2992 }
2993
2994 sub save_clusterfw_conf {
2995     my ($cluster_conf) = @_;
2996
2997     my $raw = '';
2998
2999     my $options = $cluster_conf->{options};
3000     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3001
3002     my $aliases = $cluster_conf->{aliases};
3003     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
3004
3005     $raw .= &$format_ipsets($cluster_conf) if $cluster_conf->{ipset};
3006
3007     my $rules = $cluster_conf->{rules};
3008     if ($rules && scalar(@$rules)) {
3009         $raw .= "[RULES]\n\n";
3010         $raw .= &$format_rules($rules, 1);
3011         $raw .= "\n";
3012     }
3013
3014     if ($cluster_conf->{groups}) {
3015         foreach my $group (sort keys %{$cluster_conf->{groups}}) {
3016             my $rules = $cluster_conf->{groups}->{$group};
3017             if (my $comment = $cluster_conf->{group_comments}->{$group}) {
3018                 my $utf8comment = encode('utf8', $comment);
3019                 $raw .= "[group $group] # $utf8comment\n\n";
3020             } else {
3021                 $raw .= "[group $group]\n\n";
3022             }
3023
3024             $raw .= &$format_rules($rules, 0);
3025             $raw .= "\n";
3026         }
3027     }
3028
3029     mkdir $pvefw_conf_dir;
3030     PVE::Tools::file_set_contents($clusterfw_conf_filename, $raw);
3031 }
3032
3033 sub load_hostfw_conf {
3034     my ($cluster_conf, $filename, $verbose) = @_;
3035
3036     $filename = $hostfw_conf_filename if !defined($filename);
3037
3038     my $hostfw_conf = {};
3039     if (my $fh = IO::File->new($filename, O_RDONLY)) {
3040         $hostfw_conf = parse_hostfw_config($filename, $fh, $cluster_conf, $verbose);
3041     }
3042     return $hostfw_conf;
3043 }
3044
3045 sub save_hostfw_conf {
3046     my ($hostfw_conf) = @_;
3047
3048     my $raw = '';
3049
3050     my $options = $hostfw_conf->{options};
3051     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3052
3053     my $rules = $hostfw_conf->{rules};
3054     if ($rules && scalar(@$rules)) {
3055         $raw .= "[RULES]\n\n";
3056         $raw .= &$format_rules($rules, 1);
3057         $raw .= "\n";
3058     }
3059
3060     PVE::Tools::file_set_contents($hostfw_conf_filename, $raw);
3061 }
3062
3063 sub compile {
3064     my ($cluster_conf, $hostfw_conf, $vmdata, $verbose) = @_;
3065
3066     my $vmfw_configs;
3067
3068     if ($vmdata) { # test mode
3069         my $testdir = $vmdata->{testdir} || die "no test directory specified";
3070         my $filename = "$testdir/cluster.fw";
3071         $cluster_conf = load_clusterfw_conf($filename, $verbose);
3072
3073         $filename = "$testdir/host.fw";
3074         $hostfw_conf = load_hostfw_conf($cluster_conf, $filename, $verbose);
3075
3076         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, $testdir, $verbose);
3077     } else { # normal operation
3078         $cluster_conf = load_clusterfw_conf(undef, $verbose) if !$cluster_conf;
3079
3080         $hostfw_conf = load_hostfw_conf($cluster_conf, undef, $verbose) if !$hostfw_conf;
3081
3082         $vmdata = read_local_vm_config();
3083         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, undef, $verbose);
3084     }
3085
3086     my ($ruleset, $ipset_ruleset) = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, 4, $verbose);
3087     my ($rulesetv6) = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, 6, $verbose);
3088
3089     return ($ruleset, $ipset_ruleset, $rulesetv6);
3090 }
3091
3092 sub compile_iptables_filter {
3093     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $ipversion, $verbose) = @_;
3094
3095     $cluster_conf->{ipset}->{venet0} = [];
3096     my $venet0_ipset_chain = compute_ipset_chain_name(0, 'venet0', $ipversion);
3097
3098     my $localnet;
3099     if ($cluster_conf->{aliases}->{local_network}) {
3100         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
3101     } else {
3102         my $localnet_ver;
3103         ($localnet, $localnet_ver) = parse_ip_or_cidr(local_network() || '127.0.0.0/8');
3104
3105         $cluster_conf->{aliases}->{local_network} = {
3106             name => 'local_network', cidr => $localnet, ipversion => $localnet_ver };
3107     }
3108
3109     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
3110
3111     return ({}, {}) if !$cluster_conf->{options}->{enable};
3112
3113     my $ruleset = {};
3114
3115     ruleset_create_chain($ruleset, "PVEFW-INPUT");
3116     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
3117
3118     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
3119
3120     my $hostfw_options = $hostfw_conf->{options} || {};
3121
3122     # fixme: what log level should we use here?
3123     my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
3124
3125     ruleset_chain_add_conn_filters($ruleset, "PVEFW-FORWARD", "ACCEPT");
3126
3127
3128     ruleset_create_chain($ruleset, "PVEFW-VENET-OUT");
3129     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i venet0 -m set --match-set ${venet0_ipset_chain} src -j PVEFW-VENET-OUT");
3130     ruleset_addrule($ruleset, "PVEFW-INPUT", "-i venet0 -m set --match-set ${venet0_ipset_chain} src -j PVEFW-VENET-OUT");
3131
3132     ruleset_create_chain($ruleset, "PVEFW-FWBR-IN");
3133     ruleset_chain_add_input_filters($ruleset, "PVEFW-FWBR-IN", $ipversion, $hostfw_options, $cluster_conf, $loglevel);
3134
3135     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-in fwln+ -j PVEFW-FWBR-IN");
3136
3137     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
3138     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-out fwln+ -j PVEFW-FWBR-OUT");
3139
3140     ruleset_create_chain($ruleset, "PVEFW-VENET-IN");
3141     ruleset_chain_add_input_filters($ruleset, "PVEFW-VENET-IN", $ipversion, $hostfw_options, $cluster_conf, $loglevel);
3142
3143     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o venet0 -m set --match-set ${venet0_ipset_chain} dst -j PVEFW-VENET-IN");
3144
3145     generate_std_chains($ruleset, $hostfw_options, $ipversion);
3146
3147     my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
3148
3149     my $ipset_ruleset = {};
3150
3151     if ($hostfw_enable) {
3152         eval { enable_host_firewall($ruleset, $hostfw_conf, $cluster_conf, $ipversion); };
3153         warn $@ if $@; # just to be sure - should not happen
3154     }
3155
3156     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-o venet0 -m set --match-set ${venet0_ipset_chain} dst -j PVEFW-VENET-IN");
3157
3158     # generate firewall rules for QEMU VMs
3159     foreach my $vmid (keys %{$vmdata->{qemu}}) {
3160         eval {
3161             my $conf = $vmdata->{qemu}->{$vmid};
3162             my $vmfw_conf = $vmfw_configs->{$vmid};
3163             return if !$vmfw_conf;
3164
3165             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf);
3166
3167             foreach my $netid (keys %$conf) {
3168                 next if $netid !~ m/^net(\d+)$/;
3169                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3170                 next if !$net->{firewall};
3171                 my $iface = "tap${vmid}i$1";
3172
3173                 my $macaddr = $net->{macaddr};
3174                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3175                                              $vmfw_conf, $vmid, 'IN', $ipversion);
3176                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3177                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
3178             }
3179         };
3180         warn $@ if $@; # just to be sure - should not happen
3181     }
3182
3183     # generate firewall rules for OpenVZ containers
3184     foreach my $vmid (keys %{$vmdata->{openvz}}) {
3185         eval {
3186             my $conf = $vmdata->{openvz}->{$vmid};
3187
3188             my $vmfw_conf = $vmfw_configs->{$vmid};
3189             return if !$vmfw_conf;
3190
3191             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf);
3192
3193             if ($vmfw_conf->{options}->{enable}) {
3194                 if ($conf->{ip_address} && $conf->{ip_address}->{value}) {
3195                     my $ip = $conf->{ip_address}->{value};
3196                     $ip =~ s/\s+/,/g;
3197
3198                     my @ips = ();
3199
3200                     foreach my $singleip (split(',', $ip)) {
3201                         my $singleip_ver = parse_address_list($singleip); # make sure we have a valid $ip list
3202                         push @{$cluster_conf->{ipset}->{venet0}}, { cidr => $singleip };
3203                         push @ips, $singleip if $singleip_ver == $ipversion;
3204                     }
3205
3206                     if (scalar(@ips)) {
3207                         my $ip_list = join(',', @ips);
3208                         generate_venet_rules_direction($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip_list, 'IN', $ipversion);
3209                         generate_venet_rules_direction($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip_list, 'OUT', $ipversion);
3210                     }
3211                 }
3212             }
3213
3214             if ($conf->{netif} && $conf->{netif}->{value}) {
3215                 my $netif = PVE::OpenVZ::parse_netif($conf->{netif}->{value});
3216                 foreach my $netid (keys %$netif) {
3217                     my $d = $netif->{$netid};
3218                     my $bridge = $d->{bridge};
3219                     next if !$bridge || $bridge !~ m/^vmbr\d+(v(\d+))?f$/; # firewall enabled ?
3220                     my $macaddr = $d->{mac};
3221                     my $iface = $d->{host_ifname};
3222                     generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3223                                                  $vmfw_conf, $vmid, 'IN', $ipversion);
3224                     generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3225                                                  $vmfw_conf, $vmid, 'OUT', $ipversion);
3226                 }
3227             }
3228         };
3229         warn $@ if $@; # just to be sure - should not happen
3230     }
3231
3232     if(ruleset_chain_exist($ruleset, "PVEFW-IPS")){
3233         ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED -j PVEFW-IPS");
3234     }
3235
3236     generate_ipset_chains($ipset_ruleset, undef, $cluster_conf);
3237
3238     return ($ruleset, $ipset_ruleset);
3239 }
3240
3241 sub get_ruleset_status {
3242     my ($ruleset, $active_chains, $digest_fn, $verbose) = @_;
3243
3244     my $statushash = {};
3245
3246     foreach my $chain (sort keys %$ruleset) {
3247         my $sig = &$digest_fn($ruleset->{$chain});
3248
3249         $statushash->{$chain}->{sig} = $sig;
3250
3251         my $oldsig = $active_chains->{$chain};
3252         if (!defined($oldsig)) {
3253             $statushash->{$chain}->{action} = 'create';
3254         } else {
3255             if ($oldsig eq $sig) {
3256                 $statushash->{$chain}->{action} = 'exists';
3257             } else {
3258                 $statushash->{$chain}->{action} = 'update';
3259             }
3260         }
3261         print "$statushash->{$chain}->{action} $chain ($sig)\n" if $verbose;
3262         foreach my $cmd (@{$ruleset->{$chain}}) {
3263             print "\t$cmd\n" if $verbose;
3264         }
3265     }
3266
3267     foreach my $chain (sort keys %$active_chains) {
3268         if (!defined($ruleset->{$chain})) {
3269             my $sig = $active_chains->{$chain};
3270             $statushash->{$chain}->{action} = 'delete';
3271             $statushash->{$chain}->{sig} = $sig;
3272             print "delete $chain ($sig)\n" if $verbose;
3273         }
3274     }
3275
3276     return $statushash;
3277 }
3278
3279 sub print_sig_rule {
3280     my ($chain, $sig) = @_;
3281
3282     # We just use this to store a SHA1 checksum used to detect changes
3283     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
3284 }
3285
3286 sub get_ruleset_cmdlist {
3287     my ($ruleset, $verbose, $iptablescmd) = @_;
3288
3289     my $cmdlist = "*filter\n"; # we pass this to iptables-restore;
3290
3291     my ($active_chains, $hooks) = iptables_get_chains($iptablescmd);
3292     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest, $verbose);
3293
3294     # create missing chains first
3295     foreach my $chain (sort keys %$ruleset) {
3296         my $stat = $statushash->{$chain};
3297         die "internal error" if !$stat;
3298         next if $stat->{action} ne 'create';
3299
3300         $cmdlist .= ":$chain - [0:0]\n";
3301     }
3302
3303     foreach my $h (qw(INPUT OUTPUT FORWARD)) {
3304         my $chain = "PVEFW-$h";
3305         if ($ruleset->{$chain} && !$hooks->{$h}) {
3306             $cmdlist .= "-A $h -j $chain\n";
3307         }
3308     }
3309
3310     foreach my $chain (sort keys %$ruleset) {
3311         my $stat = $statushash->{$chain};
3312         die "internal error" if !$stat;
3313
3314         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
3315             $cmdlist .= "-F $chain\n";
3316             foreach my $cmd (@{$ruleset->{$chain}}) {
3317                 $cmdlist .= "$cmd\n";
3318             }
3319             $cmdlist .= print_sig_rule($chain, $stat->{sig});
3320         } elsif ($stat->{action} eq 'delete') {
3321             die "internal error"; # this should not happen
3322         } elsif ($stat->{action} eq 'exists') {
3323             # do nothing
3324         } else {
3325             die "internal error - unknown status '$stat->{action}'";
3326         }
3327     }
3328
3329     foreach my $chain (keys %$statushash) {
3330         next if $statushash->{$chain}->{action} ne 'delete';
3331         $cmdlist .= "-F $chain\n";
3332     }
3333     foreach my $chain (keys %$statushash) {
3334         next if $statushash->{$chain}->{action} ne 'delete';
3335         next if $chain eq 'PVEFW-INPUT';
3336         next if $chain eq 'PVEFW-OUTPUT';
3337         next if $chain eq 'PVEFW-FORWARD';
3338         $cmdlist .= "-X $chain\n";
3339     }
3340
3341     my $changes = $cmdlist ne "*filter\n" ? 1 : 0;
3342
3343     $cmdlist .= "COMMIT\n";
3344
3345     return wantarray ? ($cmdlist, $changes) : $cmdlist;
3346 }
3347
3348 sub get_ipset_cmdlist {
3349     my ($ruleset, $verbose) = @_;
3350
3351     my $cmdlist = "";
3352
3353     my $delete_cmdlist = "";
3354
3355     my $active_chains = ipset_get_chains();
3356     my $statushash = get_ruleset_status($ruleset, $active_chains, \&ipset_chain_digest, $verbose);
3357
3358     # remove stale _swap chains
3359     foreach my $chain (keys %$active_chains) {
3360         if ($chain =~ m/^PVEFW-\S+_swap$/) {
3361             $cmdlist .= "destroy $chain\n";
3362         }
3363     }
3364
3365     foreach my $chain (keys %$ruleset) {
3366         my $stat = $statushash->{$chain};
3367         die "internal error" if !$stat;
3368
3369         if ($stat->{action} eq 'create') {
3370             foreach my $cmd (@{$ruleset->{$chain}}) {
3371                 $cmdlist .= "$cmd\n";
3372             }
3373         }
3374     }
3375
3376     foreach my $chain (keys %$ruleset) {
3377         my $stat = $statushash->{$chain};
3378         die "internal error" if !$stat;
3379
3380         if ($stat->{action} eq 'update') {
3381             my $chain_swap = $chain."_swap";
3382
3383             foreach my $cmd (@{$ruleset->{$chain}}) {
3384                 $cmd =~ s/$chain/$chain_swap/;
3385                 $cmdlist .= "$cmd\n";
3386             }
3387             $cmdlist .= "swap $chain_swap $chain\n";
3388             $cmdlist .= "flush $chain_swap\n";
3389             $cmdlist .= "destroy $chain_swap\n";
3390         }
3391     }
3392
3393      # the remove unused chains
3394     foreach my $chain (keys %$statushash) {
3395         next if $statushash->{$chain}->{action} ne 'delete';
3396
3397         $delete_cmdlist .= "flush $chain\n";
3398         $delete_cmdlist .= "destroy $chain\n";
3399     }
3400
3401     my $changes = ($cmdlist || $delete_cmdlist) ? 1 : 0;
3402
3403     return ($cmdlist, $delete_cmdlist, $changes);
3404 }
3405
3406 sub apply_ruleset {
3407     my ($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6, $verbose) = @_;
3408
3409     enable_bridge_firewall();
3410
3411     my ($ipset_create_cmdlist, $ipset_delete_cmdlist, $ipset_changes) =
3412         get_ipset_cmdlist($ipset_ruleset, undef, $verbose);
3413
3414     my ($cmdlist, $changes) = get_ruleset_cmdlist($ruleset, $verbose);
3415     my ($cmdlistv6, $changesv6) = get_ruleset_cmdlist($rulesetv6, $verbose, "ip6tables");
3416
3417     if ($verbose) {
3418         if ($ipset_changes) {
3419             print "ipset changes:\n";
3420             print $ipset_create_cmdlist if $ipset_create_cmdlist;
3421             print $ipset_delete_cmdlist if $ipset_delete_cmdlist;
3422         }
3423
3424         if ($changes) {
3425             print "iptables changes:\n";
3426             print $cmdlist;
3427         }
3428
3429         if ($changesv6) {
3430             print "ip6tables changes:\n";
3431             print $cmdlistv6;
3432         }
3433     }
3434
3435     my $tmpfile = "$pve_fw_status_dir/ipsetcmdlist1";
3436     PVE::Tools::file_set_contents($tmpfile, $ipset_create_cmdlist || '');
3437
3438     ipset_restore_cmdlist($ipset_create_cmdlist);
3439
3440     $tmpfile = "$pve_fw_status_dir/ip4cmdlist";
3441     PVE::Tools::file_set_contents($tmpfile, $cmdlist || '');
3442
3443     iptables_restore_cmdlist($cmdlist);
3444
3445     $tmpfile = "$pve_fw_status_dir/ip6cmdlist";
3446     PVE::Tools::file_set_contents($tmpfile, $cmdlistv6 || '');
3447
3448     ip6tables_restore_cmdlist($cmdlistv6);
3449
3450     $tmpfile = "$pve_fw_status_dir/ipsetcmdlist2";
3451     PVE::Tools::file_set_contents($tmpfile, $ipset_delete_cmdlist || '');
3452
3453     ipset_restore_cmdlist($ipset_delete_cmdlist) if $ipset_delete_cmdlist;
3454
3455     # test: re-read status and check if everything is up to date
3456     my $active_chains = iptables_get_chains();
3457     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest, 0);
3458
3459     my $errors;
3460     foreach my $chain (sort keys %$ruleset) {
3461         my $stat = $statushash->{$chain};
3462         if ($stat->{action} ne 'exists') {
3463             warn "unable to update chain '$chain'\n";
3464             $errors = 1;
3465         }
3466     }
3467
3468     my $active_chainsv6 = iptables_get_chains("ip6tables");
3469     my $statushashv6 = get_ruleset_status($rulesetv6, $active_chainsv6, \&iptables_chain_digest, 0);
3470
3471     foreach my $chain (sort keys %$rulesetv6) {
3472         my $stat = $statushashv6->{$chain};
3473         if ($stat->{action} ne 'exists') {
3474             warn "unable to update chain '$chain'\n";
3475             $errors = 1;
3476         }
3477     }
3478
3479     die "unable to apply firewall changes\n" if $errors;
3480
3481     update_nf_conntrack_max($hostfw_conf);
3482
3483     update_nf_conntrack_tcp_timeout_established($hostfw_conf);
3484
3485 }
3486
3487 sub update_nf_conntrack_max {
3488     my ($hostfw_conf) = @_;
3489
3490     my $max = 65536; # reasonable default
3491
3492     my $options = $hostfw_conf->{options} || {};
3493
3494     if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
3495         $max = $options->{nf_conntrack_max};
3496         $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
3497     }
3498
3499     my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
3500     my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
3501
3502     my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
3503
3504     if ($current != $max) {
3505         my $hashsize = int($max/4);
3506         PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
3507         PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
3508     }
3509 }
3510
3511 sub update_nf_conntrack_tcp_timeout_established {
3512     my ($hostfw_conf) = @_;
3513
3514     my $options = $hostfw_conf->{options} || {};
3515
3516     my $value = defined($options->{nf_conntrack_tcp_timeout_established}) ? $options->{nf_conntrack_tcp_timeout_established} : 432000;
3517
3518     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_established", $value);
3519 }
3520
3521 sub remove_pvefw_chains {
3522
3523     PVE::Firewall::remove_pvefw_chains_iptables("iptables");
3524     PVE::Firewall::remove_pvefw_chains_iptables("ip6tables");
3525     PVE::Firewall::remove_pvefw_chains_ipset();
3526
3527 }
3528
3529 sub remove_pvefw_chains_iptables {
3530     my ($iptablescmd) = @_;
3531
3532     my ($chash, $hooks) = iptables_get_chains($iptablescmd);
3533     my $cmdlist = "*filter\n";
3534
3535     foreach my $h (qw(INPUT OUTPUT FORWARD)) {
3536         if ($hooks->{$h}) {
3537             $cmdlist .= "-D $h -j PVEFW-$h\n";
3538         }
3539     }
3540
3541     foreach my $chain (keys %$chash) {
3542         $cmdlist .= "-F $chain\n";
3543     }
3544
3545     foreach my $chain (keys %$chash) {
3546         $cmdlist .= "-X $chain\n";
3547     }
3548     $cmdlist .= "COMMIT\n";
3549
3550     if($iptablescmd eq "ip6tables") {
3551         ip6tables_restore_cmdlist($cmdlist);
3552     } else {
3553         iptables_restore_cmdlist($cmdlist);
3554     }
3555 }
3556
3557 sub remove_pvefw_chains_ipset {
3558
3559     my $ipset_chains = ipset_get_chains();
3560
3561     my $cmdlist = "";
3562
3563     foreach my $chain (keys %$ipset_chains) {
3564         $cmdlist .= "flush $chain\n";
3565         $cmdlist .= "destroy $chain\n";
3566     }
3567
3568     ipset_restore_cmdlist($cmdlist) if $cmdlist;
3569 }
3570
3571 sub init {
3572     my $cluster_conf = load_clusterfw_conf();
3573     my $cluster_options = $cluster_conf->{options};
3574     my $enable = $cluster_options->{enable};
3575
3576     return if !$enable;
3577
3578     # load required modules here
3579 }
3580
3581 sub update {
3582     my $code = sub {
3583
3584         my $cluster_conf = load_clusterfw_conf();
3585         my $cluster_options = $cluster_conf->{options};
3586
3587         if (!$cluster_options->{enable}) {
3588             PVE::Firewall::remove_pvefw_chains();
3589             return;
3590         }
3591
3592         my $hostfw_conf = load_hostfw_conf($cluster_conf);
3593
3594         my ($ruleset, $ipset_ruleset, $rulesetv6) = compile($cluster_conf, $hostfw_conf);
3595
3596         apply_ruleset($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6);
3597     };
3598
3599     run_locked($code);
3600 }
3601
3602 1;