verify_rule: correctly set ipversion for aliases
[pve-firewall.git] / src / PVE / Firewall.pm
1 package PVE::Firewall;
2
3 use warnings;
4 use strict;
5 use POSIX;
6 use Data::Dumper;
7 use Digest::SHA;
8 use Socket qw(AF_INET6 inet_ntop inet_pton);
9 use PVE::INotify;
10 use PVE::Exception qw(raise raise_param_exc);
11 use PVE::JSONSchema qw(register_standard_option get_standard_option);
12 use PVE::Cluster;
13 use PVE::ProcFSTools;
14 use PVE::Tools qw($IPV4RE $IPV6RE);
15 use File::Basename;
16 use File::Path;
17 use IO::File;
18 use Net::IP;
19 use PVE::Tools qw(run_command lock_file dir_glob_foreach);
20 use Encode;
21
22 my $hostfw_conf_filename = "/etc/pve/local/host.fw";
23 my $pvefw_conf_dir = "/etc/pve/firewall";
24 my $clusterfw_conf_filename = "$pvefw_conf_dir/cluster.fw";
25
26 # dynamically include PVE::QemuServer and PVE::OpenVZ
27 # to avoid dependency problems
28 my $have_qemu_server;
29 eval {
30     require PVE::QemuServer;
31     $have_qemu_server = 1;
32 };
33
34 my $have_pve_manager;
35 eval {
36     require PVE::OpenVZ;
37     $have_pve_manager = 1;
38 };
39
40 my $pve_fw_status_dir = "/var/lib/pve-firewall";
41
42 mkdir $pve_fw_status_dir; # make sure this exists
43
44 my $security_group_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
45 my $ipset_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
46 our $ip_alias_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
47
48 my $max_alias_name_length = 64;
49 my $max_ipset_name_length = 64;
50 my $max_group_name_length = 20;
51
52 PVE::JSONSchema::register_format('IPorCIDR', \&pve_verify_ip_or_cidr);
53 sub pve_verify_ip_or_cidr {
54     my ($cidr, $noerr) = @_;
55
56     if ($cidr =~ m!^(?:$IPV6RE|$IPV4RE)(/(\d+))?$!) {
57         return $cidr if Net::IP->new($cidr);
58         return undef if $noerr;
59         die Net::IP::Error() . "\n";
60     }
61     return undef if $noerr;
62     die "value does not look like a valid IP address or CIDR network\n";
63 }
64
65 PVE::JSONSchema::register_format('IPorCIDRorAlias', \&pve_verify_ip_or_cidr_or_alias);
66 sub pve_verify_ip_or_cidr_or_alias {
67     my ($cidr, $noerr) = @_;
68
69     return if $cidr =~ m/^(?:$ip_alias_pattern)$/;
70
71     return pve_verify_ip_or_cidr($cidr, $noerr);
72 }
73
74 PVE::JSONSchema::register_standard_option('ipset-name', {
75     description => "IP set name.",
76     type => 'string',
77     pattern => $ipset_name_pattern,
78     minLength => 2,
79     maxLength => $max_ipset_name_length,
80 });
81
82 PVE::JSONSchema::register_standard_option('pve-fw-alias', {
83     description => "Alias name.",
84     type => 'string',
85     pattern => $ip_alias_pattern,
86     minLength => 2,
87     maxLength => $max_alias_name_length,
88 });
89
90 PVE::JSONSchema::register_standard_option('pve-fw-loglevel' => {
91     description => "Log level.",
92     type => 'string',
93     enum => ['emerg', 'alert', 'crit', 'err', 'warning', 'notice', 'info', 'debug', 'nolog'],
94     optional => 1,
95 });
96
97 PVE::JSONSchema::register_standard_option('pve-security-group-name', {
98     description => "Security Group name.",
99     type => 'string',
100     pattern => $security_group_name_pattern,
101     minLength => 2,
102     maxLength => $max_group_name_length,
103 });
104
105 my $feature_ipset_nomatch = 0;
106 eval  {
107     my (undef, undef, $release) = POSIX::uname();
108     if ($release =~ m/^(\d+)\.(\d+)\.\d+-/) {
109         my ($major, $minor) = ($1, $2);
110         $feature_ipset_nomatch = 1 if ($major > 3) ||
111             ($major == 3 && $minor >= 7);
112     }
113
114 };
115
116 use Data::Dumper;
117
118 my $nodename = PVE::INotify::nodename();
119
120 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
121
122 my $default_log_level = 'nolog'; # avoid logs by default
123
124 my $log_level_hash = {
125     debug => 7,
126     info => 6,
127     notice => 5,
128     warning => 4,
129     err => 3,
130     crit => 2,
131     alert => 1,
132     emerg => 0,
133 };
134
135 # imported/converted from: /usr/share/shorewall/macro.*
136 my $pve_fw_macros = {
137     'Amanda' => [
138         "Amanda Backup",
139         { action => 'PARAM', proto => 'udp', dport => '10080' },
140         { action => 'PARAM', proto => 'tcp', dport => '10080' },
141     ],
142     'Auth' => [
143         "Auth (identd) traffic",
144         { action => 'PARAM', proto => 'tcp', dport => '113' },
145     ],
146     'BGP' => [
147         "Border Gateway Protocol traffic",
148         { action => 'PARAM', proto => 'tcp', dport => '179' },
149     ],
150     'BitTorrent' => [
151         "BitTorrent traffic for BitTorrent 3.1 and earlier",
152         { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
153         { action => 'PARAM', proto => 'udp', dport => '6881' },
154     ],
155     'BitTorrent32' => [
156         "BitTorrent traffic for BitTorrent 3.2 and later",
157         { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
158         { action => 'PARAM', proto => 'udp', dport => '6881' },
159     ],
160     'CVS' => [
161         "Concurrent Versions System pserver traffic",
162         { action => 'PARAM', proto => 'tcp', dport => '2401' },
163     ],
164     'Citrix' => [
165         "Citrix/ICA traffic (ICA, ICA Browser, CGP)",
166         { action => 'PARAM', proto => 'tcp', dport => '1494' },
167         { action => 'PARAM', proto => 'udp', dport => '1604' },
168         { action => 'PARAM', proto => 'tcp', dport => '2598' },
169     ],
170     'DAAP' => [
171         "Digital Audio Access Protocol traffic (iTunes, Rythmbox daemons)",
172         { action => 'PARAM', proto => 'tcp', dport => '3689' },
173         { action => 'PARAM', proto => 'udp', dport => '3689' },
174     ],
175     'DCC' => [
176         "Distributed Checksum Clearinghouse spam filtering mechanism",
177         { action => 'PARAM', proto => 'tcp', dport => '6277' },
178     ],
179     'DHCPfwd' => [
180         "Forwarded DHCP traffic",
181         { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
182     ],
183     'DNS' => [
184         "Domain Name System traffic (upd and tcp)",
185         { action => 'PARAM', proto => 'udp', dport => '53' },
186         { action => 'PARAM', proto => 'tcp', dport => '53' },
187     ],
188     'Distcc' => [
189         "Distributed Compiler service",
190         { action => 'PARAM', proto => 'tcp', dport => '3632' },
191     ],
192     'FTP' => [
193         "File Transfer Protocol",
194         { action => 'PARAM', proto => 'tcp', dport => '21' },
195     ],
196     'Finger' => [
197         "Finger protocol (RFC 742)",
198         { action => 'PARAM', proto => 'tcp', dport => '79' },
199     ],
200     'GNUnet' => [
201         "GNUnet secure peer-to-peer networking traffic",
202         { action => 'PARAM', proto => 'tcp', dport => '2086' },
203         { action => 'PARAM', proto => 'udp', dport => '2086' },
204         { action => 'PARAM', proto => 'tcp', dport => '1080' },
205         { action => 'PARAM', proto => 'udp', dport => '1080' },
206     ],
207     'GRE' => [
208         "Generic Routing Encapsulation tunneling protocol",
209         { action => 'PARAM', proto => '47' },
210     ],
211     'Git' => [
212         "Git distributed revision control traffic",
213         { action => 'PARAM', proto => 'tcp', dport => '9418' },
214     ],
215     'HKP' => [
216         "OpenPGP HTTP keyserver protocol traffic",
217         { action => 'PARAM', proto => 'tcp', dport => '11371' },
218     ],
219     'HTTP' => [
220         "Hypertext Transfer Protocol (WWW)",
221         { action => 'PARAM', proto => 'tcp', dport => '80' },
222     ],
223     'HTTPS' => [
224         "Hypertext Transfer Protocol (WWW) over SSL",
225         { action => 'PARAM', proto => 'tcp', dport => '443' },
226     ],
227     'ICPV2' => [
228         "Internet Cache Protocol V2 (Squid) traffic",
229         { action => 'PARAM', proto => 'udp', dport => '3130' },
230     ],
231     'ICQ' => [
232         "AOL Instant Messenger traffic",
233         { action => 'PARAM', proto => 'tcp', dport => '5190' },
234     ],
235     'IMAP' => [
236         "Internet Message Access Protocol",
237         { action => 'PARAM', proto => 'tcp', dport => '143' },
238     ],
239     'IMAPS' => [
240         "Internet Message Access Protocol over SSL",
241         { action => 'PARAM', proto => 'tcp', dport => '993' },
242     ],
243     'IPIP' => [
244         "IPIP capsulation traffic",
245         { action => 'PARAM', proto => '94' },
246     ],
247     'IPsec' => [
248         "IPsec traffic",
249         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
250         { action => 'PARAM', proto => '50' },
251     ],
252     'IPsecah' => [
253         "IPsec authentication (AH) traffic",
254         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
255         { action => 'PARAM', proto => '51' },
256     ],
257     'IPsecnat' => [
258         "IPsec traffic and Nat-Traversal",
259         { action => 'PARAM', proto => 'udp', dport => '500' },
260         { action => 'PARAM', proto => 'udp', dport => '4500' },
261         { action => 'PARAM', proto => '50' },
262     ],
263     'IRC' => [
264         "Internet Relay Chat traffic",
265         { action => 'PARAM', proto => 'tcp', dport => '6667' },
266     ],
267     'Jetdirect' => [
268         "HP Jetdirect printing",
269         { action => 'PARAM', proto => 'tcp', dport => '9100' },
270     ],
271     'L2TP' => [
272         "Layer 2 Tunneling Protocol traffic",
273         { action => 'PARAM', proto => 'udp', dport => '1701' },
274     ],
275     'LDAP' => [
276         "Lightweight Directory Access Protocol traffic",
277         { action => 'PARAM', proto => 'tcp', dport => '389' },
278     ],
279     'LDAPS' => [
280         "Secure Lightweight Directory Access Protocol traffic",
281         { action => 'PARAM', proto => 'tcp', dport => '636' },
282     ],
283     'MSNP' => [
284         "Microsoft Notification Protocol",
285         { action => 'PARAM', proto => 'tcp', dport => '1863' },
286     ],
287     'MSSQL' => [
288         "Microsoft SQL Server",
289         { action => 'PARAM', proto => 'tcp', dport => '1433' },
290     ],
291     'Mail' => [
292         "Mail traffic (SMTP, SMTPS, Submission)",
293         { action => 'PARAM', proto => 'tcp', dport => '25' },
294         { action => 'PARAM', proto => 'tcp', dport => '465' },
295         { action => 'PARAM', proto => 'tcp', dport => '587' },
296     ],
297     'Munin' => [
298         "Munin networked resource monitoring traffic",
299         { action => 'PARAM', proto => 'tcp', dport => '4949' },
300     ],
301     'MySQL' => [
302         "MySQL server",
303         { action => 'PARAM', proto => 'tcp', dport => '3306' },
304     ],
305     'NNTP' => [
306         "NNTP traffic (Usenet).",
307         { action => 'PARAM', proto => 'tcp', dport => '119' },
308     ],
309     'NNTPS' => [
310         "Encrypted NNTP traffic (Usenet)",
311         { action => 'PARAM', proto => 'tcp', dport => '563' },
312     ],
313     'NTP' => [
314         "Network Time Protocol (ntpd)",
315         { action => 'PARAM', proto => 'udp', dport => '123' },
316     ],
317     'OSPF' => [
318         "OSPF multicast traffic",
319         { action => 'PARAM', proto => '89' },
320     ],
321     'OpenVPN' => [
322         "OpenVPN traffic",
323         { action => 'PARAM', proto => 'udp', dport => '1194' },
324     ],
325     'PCA' => [
326         "Symantec PCAnywere (tm)",
327         { action => 'PARAM', proto => 'udp', dport => '5632' },
328         { action => 'PARAM', proto => 'tcp', dport => '5631' },
329     ],
330     'POP3' => [
331         "POP3 traffic",
332         { action => 'PARAM', proto => 'tcp', dport => '110' },
333     ],
334     'POP3S' => [
335         "Encrypted POP3 traffic",
336         { action => 'PARAM', proto => 'tcp', dport => '995' },
337     ],
338     'PPtP' => [
339         "Point-to-Point Tunneling Protocol",
340         { action => 'PARAM', proto => '47' },
341         { action => 'PARAM', proto => 'tcp', dport => '1723' },
342     ],
343     'Ping' => [
344         "ICMP echo request",
345         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
346     ],
347     'PostgreSQL' => [
348         "PostgreSQL server",
349         { action => 'PARAM', proto => 'tcp', dport => '5432' },
350     ],
351     'Printer' => [
352         "Line Printer protocol printing",
353         { action => 'PARAM', proto => 'tcp', dport => '515' },
354     ],
355     'RDP' => [
356         "Microsoft Remote Desktop Protocol traffic",
357         { action => 'PARAM', proto => 'tcp', dport => '3389' },
358     ],
359     'RIP' => [
360         "Routing Information Protocol (bidirectional)",
361         { action => 'PARAM', proto => 'udp', dport => '520' },
362     ],
363     'RNDC' => [
364         "BIND remote management protocol",
365         { action => 'PARAM', proto => 'tcp', dport => '953' },
366     ],
367     'Razor' => [
368         "Razor Antispam System",
369         { action => 'ACCEPT', proto => 'tcp', dport => '2703' },
370     ],
371     'Rdate' => [
372         "Remote time retrieval (rdate)",
373         { action => 'PARAM', proto => 'tcp', dport => '37' },
374     ],
375     'Rsync' => [
376         "Rsync server",
377         { action => 'PARAM', proto => 'tcp', dport => '873' },
378     ],
379     'SANE' => [
380         "SANE network scanning",
381         { action => 'PARAM', proto => 'tcp', dport => '6566' },
382     ],
383     'SMB' => [
384         "Microsoft SMB traffic",
385         { action => 'PARAM', proto => 'udp', dport => '135,445' },
386         { action => 'PARAM', proto => 'udp', dport => '137:139' },
387         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
388         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
389     ],
390     'SMBswat' => [
391         "Samba Web Administration Tool",
392         { action => 'PARAM', proto => 'tcp', dport => '901' },
393     ],
394     'SMTP' => [
395         "Simple Mail Transfer Protocol",
396         { action => 'PARAM', proto => 'tcp', dport => '25' },
397     ],
398     'SMTPS' => [
399         "Encrypted Simple Mail Transfer Protocol",
400         { action => 'PARAM', proto => 'tcp', dport => '465' },
401     ],
402     'SNMP' => [
403         "Simple Network Management Protocol",
404         { action => 'PARAM', proto => 'udp', dport => '161:162' },
405         { action => 'PARAM', proto => 'tcp', dport => '161' },
406     ],
407     'SPAMD' => [
408         "Spam Assassin SPAMD traffic",
409         { action => 'PARAM', proto => 'tcp', dport => '783' },
410     ],
411     'SSH' => [
412         "Secure shell traffic",
413         { action => 'PARAM', proto => 'tcp', dport => '22' },
414     ],
415     'SVN' => [
416         "Subversion server (svnserve)",
417         { action => 'PARAM', proto => 'tcp', dport => '3690' },
418     ],
419     'SixXS' => [
420         "SixXS IPv6 Deployment and Tunnel Broker",
421         { action => 'PARAM', proto => 'tcp', dport => '3874' },
422         { action => 'PARAM', proto => 'udp', dport => '3740' },
423         { action => 'PARAM', proto => '41' },
424         { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
425     ],
426     'Squid' => [
427         "Squid web proxy traffic",
428         { action => 'PARAM', proto => 'tcp', dport => '3128' },
429     ],
430     'Submission' => [
431         "Mail message submission traffic",
432         { action => 'PARAM', proto => 'tcp', dport => '587' },
433     ],
434     'Syslog' => [
435         "Syslog protocol (RFC 5424) traffic",
436         { action => 'PARAM', proto => 'udp', dport => '514' },
437         { action => 'PARAM', proto => 'tcp', dport => '514' },
438     ],
439     'TFTP' => [
440         "Trivial File Transfer Protocol traffic",
441         { action => 'PARAM', proto => 'udp', dport => '69' },
442     ],
443     'Telnet' => [
444         "Telnet traffic",
445         { action => 'PARAM', proto => 'tcp', dport => '23' },
446     ],
447     'Telnets' => [
448         "Telnet over SSL",
449         { action => 'PARAM', proto => 'tcp', dport => '992' },
450     ],
451     'Time' => [
452         "RFC 868 Time protocol",
453         { action => 'PARAM', proto => 'tcp', dport => '37' },
454     ],
455     'Trcrt' => [
456         "Traceroute (for up to 30 hops) traffic",
457         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
458         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
459     ],
460     'VNC' => [
461         "VNC traffic for VNC display's 0 - 99",
462         { action => 'PARAM', proto => 'tcp', dport => '5900:5999' },
463     ],
464     'VNCL' => [
465         "VNC traffic from Vncservers to Vncviewers in listen mode",
466         { action => 'PARAM', proto => 'tcp', dport => '5500' },
467     ],
468     'Web' => [
469         "WWW traffic (HTTP and HTTPS)",
470         { action => 'PARAM', proto => 'tcp', dport => '80' },
471         { action => 'PARAM', proto => 'tcp', dport => '443' },
472     ],
473     'Webcache' => [
474         "Web Cache/Proxy traffic (port 8080)",
475         { action => 'PARAM', proto => 'tcp', dport => '8080' },
476     ],
477     'Webmin' => [
478         "Webmin traffic",
479         { action => 'PARAM', proto => 'tcp', dport => '10000' },
480     ],
481     'Whois' => [
482         "Whois (nicname, RFC 3912) traffic",
483         { action => 'PARAM', proto => 'tcp', dport => '43' },
484     ],
485 };
486
487 my $pve_fw_parsed_macros;
488 my $pve_fw_macro_descr;
489 my $pve_fw_preferred_macro_names = {};
490
491 my $pve_std_chains = {};
492 $pve_std_chains->{4} = {
493     'PVEFW-SET-ACCEPT-MARK' => [
494         "-j MARK --set-mark 1",
495     ],
496     'PVEFW-DropBroadcast' => [
497         # same as shorewall 'Broadcast'
498         # simply DROP BROADCAST/MULTICAST/ANYCAST
499         # we can use this to reduce logging
500         { action => 'DROP', dsttype => 'BROADCAST' },
501         { action => 'DROP', dsttype => 'MULTICAST' },
502         { action => 'DROP', dsttype => 'ANYCAST' },
503         { action => 'DROP', dest => '224.0.0.0/4' },
504     ],
505     'PVEFW-reject' => [
506         # same as shorewall 'reject'
507         { action => 'DROP', dsttype => 'BROADCAST' },
508         { action => 'DROP', source => '224.0.0.0/4' },
509         { action => 'DROP', proto => 'icmp' },
510         "-p tcp -j REJECT --reject-with tcp-reset",
511         "-p udp -j REJECT --reject-with icmp-port-unreachable",
512         "-p icmp -j REJECT --reject-with icmp-host-unreachable",
513         "-j REJECT --reject-with icmp-host-prohibited",
514     ],
515     'PVEFW-Drop' => [
516         # same as shorewall 'Drop', which is equal to DROP,
517         # but REJECT/DROP some packages to reduce logging,
518         # and ACCEPT critical ICMP types
519         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
520         # we are not interested in BROADCAST/MULTICAST/ANYCAST
521         { action => 'PVEFW-DropBroadcast' },
522         # ACCEPT critical ICMP types
523         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
524         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
525         # Drop packets with INVALID state
526         "-m conntrack --ctstate INVALID -j DROP",
527         # Drop Microsoft SMB noise
528         { action => 'DROP', proto => 'udp', dport => '135,445', nbdport => 2 },
529         { action => 'DROP', proto => 'udp', dport => '137:139'},
530         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
531         { action => 'DROP', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
532         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
533         # Drop new/NotSyn traffic so that it doesn't get logged
534         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
535         # Drop DNS replies
536         { action => 'DROP', proto => 'udp', sport => 53 },
537     ],
538     'PVEFW-Reject' => [
539         # same as shorewall 'Reject', which is equal to Reject,
540         # but REJECT/DROP some packages to reduce logging,
541         # and ACCEPT critical ICMP types
542         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
543         # we are not interested in BROADCAST/MULTICAST/ANYCAST
544         { action => 'PVEFW-DropBroadcast' },
545         # ACCEPT critical ICMP types
546         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
547         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
548         # Drop packets with INVALID state
549         "-m conntrack --ctstate INVALID -j DROP",
550         # Drop Microsoft SMB noise
551         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445', nbdport => 2 },
552         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
553         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
554         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
555         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
556         # Drop new/NotSyn traffic so that it doesn't get logged
557         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
558         # Drop DNS replies
559         { action => 'DROP', proto => 'udp', sport => 53 },
560     ],
561     'PVEFW-tcpflags' => [
562         # same as shorewall tcpflags action.
563         # Packets arriving on this interface are checked for som illegal combinations of TCP flags
564         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG -g PVEFW-logflags",
565         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE -g PVEFW-logflags",
566         "-p tcp -m tcp --tcp-flags SYN,RST SYN,RST -g PVEFW-logflags",
567         "-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN -g PVEFW-logflags",
568         "-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN -g PVEFW-logflags",
569     ],
570     'PVEFW-smurfs' => [
571         # same as shorewall smurfs action
572         # Filter packets for smurfs (packets with a broadcast address as the source).
573         "-s 0.0.0.0/32 -j RETURN",
574         "-m addrtype --src-type BROADCAST -g PVEFW-smurflog",
575         "-s 224.0.0.0/4 -g PVEFW-smurflog",
576     ],
577 };
578
579 $pve_std_chains->{6} = {
580     'PVEFW-SET-ACCEPT-MARK' => [
581         "-j MARK --set-mark 1",
582     ],
583     'PVEFW-DropBroadcast' => [
584         # same as shorewall 'Broadcast'
585         # simply DROP BROADCAST/MULTICAST/ANYCAST
586         # we can use this to reduce logging
587         #{ action => 'DROP', dsttype => 'BROADCAST' }, #no broadcast in ipv6
588         # ipv6 addrtype does not work with kernel 2.6.32
589         #{ action => 'DROP', dsttype => 'MULTICAST' },
590         #{ action => 'DROP', dsttype => 'ANYCAST' },
591         { action => 'DROP', dest => 'ff00::/8' },
592         #{ action => 'DROP', dest => '224.0.0.0/4' },
593     ],
594     'PVEFW-reject' => [
595         # same as shorewall 'reject'
596         #{ action => 'DROP', dsttype => 'BROADCAST' },
597         #{ action => 'DROP', source => '224.0.0.0/4' },
598         { action => 'DROP', proto => 'icmpv6' },
599         "-p tcp -j REJECT --reject-with tcp-reset",
600         #"-p udp -j REJECT --reject-with icmp-port-unreachable",
601         #"-p icmp -j REJECT --reject-with icmp-host-unreachable",
602         #"-j REJECT --reject-with icmp-host-prohibited",
603     ],
604     'PVEFW-Drop' => [
605         # same as shorewall 'Drop', which is equal to DROP,
606         # but REJECT/DROP some packages to reduce logging,
607         # and ACCEPT critical ICMP types
608         { action => 'PVEFW-reject', proto => 'tcp', dport => '43' }, # REJECT 'auth'
609         # we are not interested in BROADCAST/MULTICAST/ANYCAST
610         { action => 'PVEFW-DropBroadcast' },
611         # ACCEPT critical ICMP types
612         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
613         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
614         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
615
616         # Drop packets with INVALID state
617         "-m conntrack --ctstate INVALID -j DROP",
618         # Drop Microsoft SMB noise
619         { action => 'DROP', proto => 'udp', dport => '135,445', nbdport => 2 },
620         { action => 'DROP', proto => 'udp', dport => '137:139'},
621         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
622         { action => 'DROP', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
623         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
624         # Drop new/NotSyn traffic so that it doesn't get logged
625         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
626         # Drop DNS replies
627         { action => 'DROP', proto => 'udp', sport => 53 },
628     ],
629     'PVEFW-Reject' => [
630         # same as shorewall 'Reject', which is equal to Reject,
631         # but REJECT/DROP some packages to reduce logging,
632         # and ACCEPT critical ICMP types
633         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
634         # we are not interested in BROADCAST/MULTICAST/ANYCAST
635         { action => 'PVEFW-DropBroadcast' },
636         # ACCEPT critical ICMP types
637         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
638         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
639         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
640
641         # Drop packets with INVALID state
642         "-m conntrack --ctstate INVALID -j DROP",
643         # Drop Microsoft SMB noise
644         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445', nbdport => 2 },
645         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
646         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
647         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445', nbdport => 3 },
648         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
649         # Drop new/NotSyn traffic so that it doesn't get logged
650         "-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN -j DROP",
651         # Drop DNS replies
652         { action => 'DROP', proto => 'udp', sport => 53 },
653     ],
654     'PVEFW-tcpflags' => [
655         # same as shorewall tcpflags action.
656         # Packets arriving on this interface are checked for som illegal combinations of TCP flags
657         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG -g PVEFW-logflags",
658         "-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE -g PVEFW-logflags",
659         "-p tcp -m tcp --tcp-flags SYN,RST SYN,RST -g PVEFW-logflags",
660         "-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN -g PVEFW-logflags",
661         "-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN -g PVEFW-logflags",
662     ],
663 };
664
665 # iptables -p icmp -h
666 my $icmp_type_names = {
667     any => 1,
668     'echo-reply' => 1,
669     'destination-unreachable' => 1,
670     'network-unreachable' => 1,
671     'host-unreachable' => 1,
672     'protocol-unreachable' => 1,
673     'port-unreachable' => 1,
674     'fragmentation-needed' => 1,
675     'source-route-failed' => 1,
676     'network-unknown' => 1,
677     'host-unknown' => 1,
678     'network-prohibited' => 1,
679     'host-prohibited' => 1,
680     'TOS-network-unreachable' => 1,
681     'TOS-host-unreachable' => 1,
682     'communication-prohibited' => 1,
683     'host-precedence-violation' => 1,
684     'precedence-cutoff' => 1,
685     'source-quench' => 1,
686     'redirect' => 1,
687     'network-redirect' => 1,
688     'host-redirect' => 1,
689     'TOS-network-redirect' => 1,
690     'TOS-host-redirect' => 1,
691     'echo-request' => 1,
692     'router-advertisement' => 1,
693     'router-solicitation' => 1,
694     'time-exceeded' => 1,
695     'ttl-zero-during-transit' => 1,
696     'ttl-zero-during-reassembly' => 1,
697     'parameter-problem' => 1,
698     'ip-header-bad' => 1,
699     'required-option-missing' => 1,
700     'timestamp-request' => 1,
701     'timestamp-reply' => 1,
702     'address-mask-request' => 1,
703     'address-mask-reply' => 1,
704 };
705
706 # ip6tables -p icmpv6 -h
707
708 my $icmpv6_type_names = {
709     'any' => 1,
710     'destination-unreachable' => 1,
711     'no-route' => 1,
712     'communication-prohibited' => 1,
713     'address-unreachable' => 1,
714     'port-unreachable' => 1,
715     'packet-too-big' => 1,
716     'time-exceeded' => 1,
717     'ttl-zero-during-transit' => 1,
718     'ttl-zero-during-reassembly' => 1,
719     'parameter-problem' => 1,
720     'bad-header' => 1,
721     'unknown-header-type' => 1,
722     'unknown-option' => 1,
723     'echo-request' => 1,
724     'echo-reply' => 1,
725     'router-solicitation' => 1,
726     'router-advertisement' => 1,
727     'neighbour-solicitation' => 1,
728     'neighbour-advertisement' => 1,
729     'redirect' => 1,
730 };
731
732 sub init_firewall_macros {
733
734     $pve_fw_parsed_macros = {};
735
736     foreach my $k (keys %$pve_fw_macros) {
737         my $lc_name = lc($k);
738         my $macro = $pve_fw_macros->{$k};
739         if (!ref($macro->[0])) {
740             $pve_fw_macro_descr->{$k} = shift @$macro;
741         }
742         $pve_fw_preferred_macro_names->{$lc_name} = $k;
743         $pve_fw_parsed_macros->{$k} = $macro;
744     }
745 }
746
747 init_firewall_macros();
748
749 sub get_macros {
750     return wantarray ? ($pve_fw_parsed_macros, $pve_fw_macro_descr): $pve_fw_parsed_macros;
751 }
752
753 my $etc_services;
754
755 sub get_etc_services {
756
757     return $etc_services if $etc_services;
758
759     my $filename = "/etc/services";
760
761     my $fh = IO::File->new($filename, O_RDONLY);
762     if (!$fh) {
763         warn "unable to read '$filename' - $!\n";
764         return {};
765     }
766
767     my $services = {};
768
769     while (my $line = <$fh>) {
770         chomp ($line);
771         next if $line =~m/^#/;
772         next if ($line =~m/^\s*$/);
773
774         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp).*$!) {
775             $services->{byid}->{$2}->{name} = $1;
776             $services->{byid}->{$2}->{port} = $2;
777             $services->{byid}->{$2}->{$3} = 1;
778             $services->{byname}->{$1} = $services->{byid}->{$2};
779         }
780     }
781
782     close($fh);
783
784     $etc_services = $services;
785
786
787     return $etc_services;
788 }
789
790 my $etc_protocols;
791
792 sub get_etc_protocols {
793     return $etc_protocols if $etc_protocols;
794
795     my $filename = "/etc/protocols";
796
797     my $fh = IO::File->new($filename, O_RDONLY);
798     if (!$fh) {
799         warn "unable to read '$filename' - $!\n";
800         return {};
801     }
802
803     my $protocols = {};
804
805     while (my $line = <$fh>) {
806         chomp ($line);
807         next if $line =~m/^#/;
808         next if ($line =~m/^\s*$/);
809
810         if ($line =~ m!^(\S+)\s+(\d+)\s+.*$!) {
811             $protocols->{byid}->{$2}->{name} = $1;
812             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
813         }
814     }
815
816     close($fh);
817
818     # add special case for ICMP v6
819     $protocols->{byid}->{icmpv6}->{name} = "icmpv6";
820     $protocols->{byname}->{icmpv6} = $protocols->{byid}->{icmpv6};
821
822     $etc_protocols = $protocols;
823
824     return $etc_protocols;
825 }
826
827 my $ipv4_mask_hash_localnet = {
828     '255.255.0.0' => 16,
829     '255.255.128.0' => 17,
830     '255.255.192.0' => 18,
831     '255.255.224.0' => 19,
832     '255.255.240.0' => 20,
833     '255.255.248.0' => 21,
834     '255.255.252.0' => 22,
835     '255.255.254.0' => 23,
836     '255.255.255.0' => 24,
837     '255.255.255.128' => 25,
838     '255.255.255.192' => 26,
839     '255.255.255.224' => 27,
840     '255.255.255.240' => 28,
841     '255.255.255.248' => 29,
842     '255.255.255.252' => 30,
843 };
844
845 my $__local_network;
846
847 sub local_network {
848     my ($new_value) = @_;
849
850     $__local_network = $new_value if defined($new_value);
851
852     return $__local_network if defined($__local_network);
853
854     eval {
855         my $nodename = PVE::INotify::nodename();
856
857         my $ip = PVE::Cluster::remote_node_ip($nodename);
858
859         my $testip = Net::IP->new($ip);
860
861         my $routes = PVE::ProcFSTools::read_proc_net_route();
862         foreach my $entry (@$routes) {
863             my $mask = $ipv4_mask_hash_localnet->{$entry->{mask}};
864             next if !defined($mask);
865             return if $mask eq '0.0.0.0';
866             my $cidr = "$entry->{dest}/$mask";
867             my $testnet = Net::IP->new($cidr);
868             if ($testnet->overlaps($testip)) {
869                 $__local_network = $cidr;
870                 return;
871             }
872         }
873     };
874     warn $@ if $@;
875
876     return $__local_network;
877 }
878
879 # ipset names are limited to 31 characters,
880 # and we use '-v4' or '-v6' to indicate IP versions, 
881 # and we use '_swap' suffix for atomic update, 
882 # for example PVEFW-${VMID}-${ipset_name}_swap
883
884 my $max_iptables_ipset_name_length = 31 - length("_swap") - length("-v4");
885
886 sub compute_ipset_chain_name {
887     my ($vmid, $ipset_name) = @_;
888
889     $vmid = 0 if !defined($vmid);
890
891     my $id = "$vmid-${ipset_name}";
892
893     if ((length($id) + 6) > $max_iptables_ipset_name_length) {
894         $id = PVE::Tools::fnv31a_hex($id);
895     }
896
897     return "PVEFW-$id";
898 }
899
900 sub compute_ipfilter_ipset_name {
901     my ($iface) = @_;
902
903     return "ipfilter-$iface";
904 }
905
906 sub parse_address_list {
907     my ($str) = @_;
908
909     if ($str =~ m/^(\+)(\S+)$/) { # ipset ref
910         die "ipset name too long\n" if length($str) > ($max_ipset_name_length + 1);
911         return;
912     }
913
914     if ($str =~ m/^${ip_alias_pattern}$/) {
915         die "alias name too long\n" if length($str) > $max_alias_name_length;
916         return;
917     }
918
919     my $count = 0;
920     my $iprange = 0;
921     my $ipversion;
922
923     foreach my $elem (split(/,/, $str)) {
924         $count++;
925         my $ip = Net::IP->new($elem);
926         if (!$ip) {
927             my $err = Net::IP::Error();
928             die "invalid IP address: $err\n";
929         }
930         $iprange = 1 if $elem =~ m/-/;
931
932         my $new_ipversion = Net::IP::ip_is_ipv6($ip->ip()) ? 6 : 4;
933
934         die "detected mixed ipv4/ipv6 addresses in address list '$str'\n"
935             if $ipversion && ($new_ipversion != $ipversion);
936
937         $ipversion = $new_ipversion;
938     }
939
940     die "you can't use a range in a list\n" if $iprange && $count > 1;
941
942     return $ipversion;
943 }
944
945 sub parse_port_name_number_or_range {
946     my ($str) = @_;
947
948     my $services = PVE::Firewall::get_etc_services();
949     my $count = 0;
950     my $icmp_port = 0;
951
952     foreach my $item (split(/,/, $str)) {
953         $count++;
954         if ($item =~ m/^(\d+):(\d+)$/) {
955             my ($port1, $port2) = ($1, $2);
956             die "invalid port '$port1'\n" if $port1 > 65535;
957             die "invalid port '$port2'\n" if $port2 > 65535;
958         } elsif ($item =~ m/^(\d+)$/) {
959             my $port = $1;
960             die "invalid port '$port'\n" if $port > 65535;
961         } else {
962             if ($icmp_type_names->{$item}) {
963                 $icmp_port = 1;
964             } elsif ($icmpv6_type_names->{$item}) {
965                 $icmp_port = 1;
966             } else {
967                 die "invalid port '$item'\n" if !$services->{byname}->{$item};
968             }
969         }
970     }
971
972     die "ICPM ports not allowed in port range\n" if $icmp_port && $count > 1;
973
974     return $count;
975 }
976
977 PVE::JSONSchema::register_format('pve-fw-port-spec', \&pve_fw_verify_port_spec);
978 sub pve_fw_verify_port_spec {
979    my ($portstr) = @_;
980
981    parse_port_name_number_or_range($portstr);
982
983    return $portstr;
984 }
985
986 PVE::JSONSchema::register_format('pve-fw-addr-spec', \&pve_fw_verify_addr_spec);
987 sub pve_fw_verify_addr_spec {
988    my ($list) = @_;
989
990    parse_address_list($list);
991
992    return $list;
993 }
994
995 PVE::JSONSchema::register_format('pve-fw-protocol-spec', \&pve_fw_verify_protocol_spec);
996 sub pve_fw_verify_protocol_spec {
997    my ($proto) = @_;
998
999    my $protocols = get_etc_protocols();
1000
1001    die "unknown protocol '$proto'\n" if $proto &&
1002        !(defined($protocols->{byname}->{$proto}) ||
1003          defined($protocols->{byid}->{$proto}));
1004
1005    return $proto;
1006 }
1007
1008
1009 # helper function for API
1010
1011 sub copy_opject_with_digest {
1012     my ($object) = @_;
1013
1014     my $sha = Digest::SHA->new('sha1');
1015
1016     my $res = {};
1017     foreach my $k (sort keys %$object) {
1018         my $v = $object->{$k};
1019         next if !defined($v);
1020         $res->{$k} = $v;
1021         $sha->add($k, ':', $v, "\n");
1022     }
1023
1024     my $digest = $sha->hexdigest;
1025
1026     $res->{digest} = $digest;
1027
1028     return wantarray ? ($res, $digest) : $res;
1029 }
1030
1031 sub copy_list_with_digest {
1032     my ($list) = @_;
1033
1034     my $sha = Digest::SHA->new('sha1');
1035
1036     my $res = [];
1037     foreach my $entry (@$list) {
1038         my $data = {};
1039         foreach my $k (sort keys %$entry) {
1040             my $v = $entry->{$k};
1041             next if !defined($v);
1042             $data->{$k} = $v;
1043             # Note: digest ignores refs ($rule->{errors})
1044             $sha->add($k, ':', $v, "\n") if !ref($v); ;
1045         }
1046         push @$res, $data;
1047     }
1048
1049     my $digest = $sha->hexdigest;
1050
1051     foreach my $entry (@$res) {
1052         $entry->{digest} = $digest;
1053     }
1054
1055     return wantarray ? ($res, $digest) : $res;
1056 }
1057
1058 my $rule_properties = {
1059     pos => {
1060         description => "Update rule at position <pos>.",
1061         type => 'integer',
1062         minimum => 0,
1063         optional => 1,
1064     },
1065     digest => get_standard_option('pve-config-digest'),
1066     type => {
1067         type => 'string',
1068         optional => 1,
1069         enum => ['in', 'out', 'group'],
1070     },
1071     action => {
1072         description => "Rule action ('ACCEPT', 'DROP', 'REJECT') or security group name.",
1073         type => 'string',
1074         optional => 1,
1075         pattern => $security_group_name_pattern,
1076         maxLength => 20,
1077         minLength => 2,
1078     },
1079     macro => {
1080         type => 'string',
1081         optional => 1,
1082         maxLength => 128,
1083     },
1084     iface => get_standard_option('pve-iface', { optional => 1 }),
1085     source => {
1086         type => 'string', format => 'pve-fw-addr-spec',
1087         optional => 1,
1088     },
1089     dest => {
1090         type => 'string', format => 'pve-fw-addr-spec',
1091         optional => 1,
1092     },
1093     proto => {
1094         type => 'string', format => 'pve-fw-protocol-spec',
1095         optional => 1,
1096     },
1097     enable => {
1098         type => 'boolean',
1099         optional => 1,
1100     },
1101     sport => {
1102         type => 'string', format => 'pve-fw-port-spec',
1103         optional => 1,
1104     },
1105     dport => {
1106         type => 'string', format => 'pve-fw-port-spec',
1107         optional => 1,
1108     },
1109     comment => {
1110         type => 'string',
1111         optional => 1,
1112     },
1113 };
1114
1115 sub add_rule_properties {
1116     my ($properties) = @_;
1117
1118     foreach my $k (keys %$rule_properties) {
1119         my $h = $rule_properties->{$k};
1120         # copy data, so that we can modify later without side effects
1121         foreach my $opt (keys %$h) { $properties->{$k}->{$opt} = $h->{$opt}; }
1122     }
1123
1124     return $properties;
1125 }
1126
1127 sub delete_rule_properties {
1128     my ($rule, $delete_str) = @_;
1129
1130     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1131         raise_param_exc({ 'delete' => "no such property ('$opt')"})
1132             if !defined($rule_properties->{$opt});
1133         raise_param_exc({ 'delete' => "unable to delete required property '$opt'"})
1134             if $opt eq 'type' || $opt eq 'action';
1135         delete $rule->{$opt};
1136     }
1137
1138     return $rule;
1139 }
1140
1141 my $apply_macro = sub {
1142     my ($macro_name, $param, $verify) = @_;
1143
1144     my $macro_rules = $pve_fw_parsed_macros->{$macro_name};
1145     die "unknown macro '$macro_name'\n" if !$macro_rules; # should not happen
1146
1147     my $rules = [];
1148
1149     foreach my $templ (@$macro_rules) {
1150         my $rule = {};
1151         my $param_used = {};
1152         foreach my $k (keys %$templ) {
1153             my $v = $templ->{$k};
1154             if ($v eq 'PARAM') {
1155                 $v = $param->{$k};
1156                 $param_used->{$k} = 1;
1157             } elsif ($v eq 'DEST') {
1158                 $v = $param->{dest};
1159                 $param_used->{dest} = 1;
1160             } elsif ($v eq 'SOURCE') {
1161                 $v = $param->{source};
1162                 $param_used->{source} = 1;
1163             }
1164
1165             if (!defined($v)) {
1166                 my $msg = "missing parameter '$k' in macro '$macro_name'";
1167                 raise_param_exc({ macro => $msg }) if $verify;
1168                 die "$msg\n";
1169             }
1170             $rule->{$k} = $v;
1171         }
1172         foreach my $k (keys %$param) {
1173             next if $k eq 'macro';
1174             next if !defined($param->{$k});
1175             next if $param_used->{$k};
1176             if (defined($rule->{$k})) {
1177                 if ($rule->{$k} ne $param->{$k}) {
1178                     my $msg = "parameter '$k' already define in macro (value = '$rule->{$k}')";
1179                     raise_param_exc({ $k => $msg }) if $verify;
1180                     die "$msg\n";
1181                 }
1182             } else {
1183                 $rule->{$k} = $param->{$k};
1184             }
1185         }
1186         push @$rules, $rule;
1187     }
1188
1189     return $rules;
1190 };
1191
1192 my $rule_env_iface_lookup = {
1193     'ct' => 1,
1194     'vm' => 1,
1195     'group' => 0,
1196     'cluster' => 1,
1197     'host' => 1,
1198 };
1199
1200 sub verify_rule {
1201     my ($rule, $cluster_conf, $fw_conf, $rule_env, $noerr) = @_;
1202
1203     my $allow_groups = $rule_env eq 'group' ? 0 : 1;
1204
1205     my $allow_iface = $rule_env_iface_lookup->{$rule_env};
1206     die "unknown rule_env '$rule_env'\n" if !defined($allow_iface); # should not happen
1207
1208     my $errors = $rule->{errors} || {};
1209
1210     my $error_count = 0;
1211
1212     my $add_error = sub {
1213         my ($param, $msg)  = @_;
1214         chomp $msg;
1215         raise_param_exc({ $param => $msg }) if !$noerr;
1216         $error_count++;
1217         $errors->{$param} = $msg if !$errors->{$param};
1218     };
1219
1220     my $ipversion;
1221     my $set_ip_version = sub {
1222         my $vers = shift;
1223         if ($vers) {
1224             die "detected mixed ipv4/ipv6 adresses in rule\n"
1225                 if $ipversion && ($vers != $ipversion);
1226             $ipversion = $vers;
1227         }
1228     };
1229
1230     my $check_ipset_or_alias_property = sub {
1231         my ($name, $expected_ipversion) = @_;
1232
1233         if (my $value = $rule->{$name}) {
1234             if ($value =~ m/^\+/) {
1235                 if ($value =~ m/^\+(${ipset_name_pattern})$/) {
1236                     &$add_error($name, "no such ipset '$1'")
1237                         if !($cluster_conf->{ipset}->{$1} || ($fw_conf && $fw_conf->{ipset}->{$1}));
1238
1239                 } else {
1240                     &$add_error($name, "invalid ipset name '$value'");
1241                 }
1242             } elsif ($value =~ m/^${ip_alias_pattern}$/){
1243                 my $alias = lc($value);
1244                 &$add_error($name, "no such alias '$value'")
1245                     if !($cluster_conf->{aliases}->{$alias} || ($fw_conf && $fw_conf->{aliases}->{$alias}));
1246
1247                 my $e = $fw_conf->{aliases}->{$alias} if $fw_conf;
1248                 $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1249
1250                 &$set_ip_version($e->{ipversion});
1251             }
1252         }
1253     };
1254
1255     my $type = $rule->{type};
1256     my $action = $rule->{action};
1257
1258     &$add_error('type', "missing property") if !$type;
1259     &$add_error('action', "missing property") if !$action;
1260
1261     if ($type) {
1262         if ($type eq  'in' || $type eq 'out') {
1263             &$add_error('action', "unknown action '$action'")
1264                 if $action && ($action !~ m/^(ACCEPT|DROP|REJECT)$/);
1265         } elsif ($type eq 'group') {
1266             &$add_error('type', "security groups not allowed")
1267                 if !$allow_groups;
1268             &$add_error('action', "invalid characters in security group name")
1269                 if $action && ($action !~ m/^${security_group_name_pattern}$/);
1270         } else {
1271             &$add_error('type', "unknown rule type '$type'");
1272         }
1273     }
1274
1275     if ($rule->{iface}) {
1276         &$add_error('type', "parameter -i not allowed for this rule type")
1277             if !$allow_iface;
1278         eval { PVE::JSONSchema::pve_verify_iface($rule->{iface}); };
1279         &$add_error('iface', $@) if $@;
1280         if ($rule_env eq 'vm') {
1281             &$add_error('iface', "value does not match the regex pattern 'net\\d+'")
1282                 if $rule->{iface} !~  m/^net(\d+)$/;
1283         } elsif ($rule_env eq 'ct') {
1284             &$add_error('iface', "value does not match the regex pattern '(venet|eth\\d+)'")
1285                 if $rule->{iface} !~  m/^(venet|eth(\d+))$/;
1286         }
1287     }
1288
1289     if ($rule->{macro}) {
1290         if (my $preferred_name = $pve_fw_preferred_macro_names->{lc($rule->{macro})}) {
1291             $rule->{macro} = $preferred_name;
1292         } else {
1293             &$add_error('macro', "unknown macro '$rule->{macro}'");
1294         }
1295     }
1296
1297     if ($rule->{proto}) {
1298         eval { pve_fw_verify_protocol_spec($rule->{proto}); };
1299         &$add_error('proto', $@) if $@;
1300         &$set_ip_version(4) if $rule->{proto} eq 'icmp';
1301         &$set_ip_version(6) if $rule->{proto} eq 'icmpv6';
1302     }
1303
1304     if ($rule->{dport}) {
1305         eval { parse_port_name_number_or_range($rule->{dport}); };
1306         &$add_error('dport', $@) if $@;
1307         &$add_error('proto', "missing property - 'dport' requires this property")
1308             if !$rule->{proto};
1309     }
1310
1311     if ($rule->{sport}) {
1312         eval { parse_port_name_number_or_range($rule->{sport}); };
1313         &$add_error('sport', $@) if $@;
1314         &$add_error('proto', "missing property - 'sport' requires this property")
1315             if !$rule->{proto};
1316     }
1317
1318     if ($rule->{source}) {
1319         eval { 
1320             my $source_ipversion = parse_address_list($rule->{source});
1321             &$set_ip_version($source_ipversion);
1322         };
1323         &$add_error('source', $@) if $@;
1324         &$check_ipset_or_alias_property('source', $ipversion);
1325     }
1326
1327     if ($rule->{dest}) {
1328         eval { 
1329             my $dest_ipversion = parse_address_list($rule->{dest}); 
1330             &$set_ip_version($dest_ipversion);
1331         };
1332         &$add_error('dest', $@) if $@;
1333         &$check_ipset_or_alias_property('dest', $ipversion);
1334     }
1335
1336     if ($rule->{macro} && !$error_count) {
1337         eval { &$apply_macro($rule->{macro}, $rule, 1); };
1338         if (my $err = $@) {
1339             if (ref($err) eq "PVE::Exception" && $err->{errors}) {
1340                 my $eh = $err->{errors};
1341                 foreach my $p (keys %$eh) {
1342                     &$add_error($p, $eh->{$p});
1343                 }
1344             } else {
1345                 &$add_error('macro', "$err");
1346             }
1347         }
1348     }
1349
1350     $rule->{errors} = $errors if $error_count;
1351     $rule->{ipversion} = $ipversion if $ipversion;
1352
1353     return $rule;
1354 }
1355
1356 sub copy_rule_data {
1357     my ($rule, $param) = @_;
1358
1359     foreach my $k (keys %$rule_properties) {
1360         if (defined(my $v = $param->{$k})) {
1361             if ($v eq '' || $v eq '-') {
1362                 delete $rule->{$k};
1363             } else {
1364                 $rule->{$k} = $v;
1365             }
1366         }
1367     }
1368
1369     return $rule;
1370 }
1371
1372 sub rules_modify_permissions {
1373     my ($rule_env) = @_;
1374
1375     if ($rule_env eq 'host') {
1376         return {
1377             check => ['perm', '/nodes/{node}', [ 'Sys.Modify' ]],
1378         };
1379     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1380         return {
1381             check => ['perm', '/', [ 'Sys.Modify' ]],
1382         };
1383     } elsif ($rule_env eq 'vm' ||   $rule_env eq 'ct') {
1384         return {
1385             check => ['perm', '/vms/{vmid}', [ 'VM.Config.Network' ]],
1386         }
1387     }
1388
1389     return undef;
1390 }
1391
1392 sub rules_audit_permissions {
1393     my ($rule_env) = @_;
1394
1395     if ($rule_env eq 'host') {
1396         return {
1397             check => ['perm', '/nodes/{node}', [ 'Sys.Audit' ]],
1398         };
1399     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1400         return {
1401             check => ['perm', '/', [ 'Sys.Audit' ]],
1402         };
1403     } elsif ($rule_env eq 'vm' ||   $rule_env eq 'ct') {
1404         return {
1405             check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1406         }
1407     }
1408
1409     return undef;
1410 }
1411
1412 # core functions
1413 my $bridge_firewall_enabled = 0;
1414
1415 sub enable_bridge_firewall {
1416
1417     return if $bridge_firewall_enabled; # only once
1418
1419     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
1420     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
1421
1422     # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
1423     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
1424
1425     $bridge_firewall_enabled = 1;
1426 }
1427
1428 my $rule_format = "%-15s %-30s %-30s %-15s %-15s %-15s\n";
1429
1430 sub iptables_restore_cmdlist {
1431     my ($cmdlist) = @_;
1432
1433     run_command("/sbin/iptables-restore -n", input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1434 }
1435
1436 sub ip6tables_restore_cmdlist {
1437     my ($cmdlist) = @_;
1438
1439     run_command("/sbin/ip6tables-restore -n", input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1440 }
1441
1442 sub ipset_restore_cmdlist {
1443     my ($cmdlist) = @_;
1444
1445     run_command("/usr/sbin/ipset restore", input => $cmdlist, errmsg => "ipset_restore_cmdlist");
1446 }
1447
1448 sub iptables_get_chains {
1449     my ($iptablescmd) = @_;
1450
1451     $iptablescmd = "iptables" if !$iptablescmd;
1452
1453     my $res = {};
1454
1455     # check what chains we want to track
1456     my $is_pvefw_chain = sub {
1457         my $name = shift;
1458
1459         return 1 if $name =~ m/^PVEFW-\S+$/;
1460
1461         return 1 if $name =~ m/^tap\d+i\d+-(:?IN|OUT)$/;
1462
1463         return 1 if $name =~ m/^veth\d+.\d+-(:?IN|OUT)$/; # fixme: dev name is configurable
1464
1465         return 1 if $name =~ m/^venet0-\d+-(:?IN|OUT)$/;
1466
1467         return 1 if $name =~ m/^fwbr\d+(v\d+)?-(:?FW|IN|OUT|IPS)$/;
1468         return 1 if $name =~ m/^GROUP-(:?[^\s\-]+)-(:?IN|OUT)$/;
1469
1470         return undef;
1471     };
1472
1473     my $table = '';
1474
1475     my $hooks = {};
1476
1477     my $parser = sub {
1478         my $line = shift;
1479
1480         return if $line =~ m/^#/;
1481         return if $line =~ m/^\s*$/;
1482
1483         if ($line =~ m/^\*(\S+)$/) {
1484             $table = $1;
1485             return;
1486         }
1487
1488         return if $table ne 'filter';
1489
1490         if ($line =~ m/^:(\S+)\s/) {
1491             my $chain = $1;
1492             return if !&$is_pvefw_chain($chain);
1493             $res->{$chain} = "unknown";
1494         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
1495             my ($chain, $sig) = ($1, $2);
1496             return if !&$is_pvefw_chain($chain);
1497             $res->{$chain} = $sig;
1498         } elsif ($line =~ m/^-A\s+(INPUT|OUTPUT|FORWARD)\s+-j\s+PVEFW-\1$/) {
1499             $hooks->{$1} = 1;
1500         } else {
1501             # simply ignore the rest
1502             return;
1503         }
1504     };
1505
1506     run_command("/sbin/$iptablescmd-save", outfunc => $parser);
1507
1508     return wantarray ? ($res, $hooks) : $res;
1509 }
1510
1511 sub iptables_chain_digest {
1512     my ($rules) = @_;
1513     my $digest = Digest::SHA->new('sha1');
1514     foreach my $rule (@$rules) { # order is important
1515         $digest->add($rule);
1516     }
1517     return $digest->b64digest;
1518 }
1519
1520 sub ipset_chain_digest {
1521     my ($rules) = @_;
1522
1523     my $digest = Digest::SHA->new('sha1');
1524     foreach my $rule (sort @$rules) { # note: sorted
1525         $digest->add($rule);
1526     }
1527     return $digest->b64digest;
1528 }
1529
1530 sub ipset_get_chains {
1531
1532     my $res = {};
1533     my $chains = {};
1534
1535     my $parser = sub {
1536         my $line = shift;
1537
1538         return if $line =~ m/^#/;
1539         return if $line =~ m/^\s*$/;
1540         if ($line =~ m/^(?:\S+)\s(PVEFW-\S+)\s(?:\S+).*/) {
1541             my $chain = $1;
1542             $line =~ s/\s+$//; # delete trailing white space
1543             push @{$chains->{$chain}}, $line;
1544         } else {
1545             # simply ignore the rest
1546             return;
1547         }
1548     };
1549
1550     run_command("/usr/sbin/ipset save", outfunc => $parser);
1551
1552     # compute digest for each chain
1553     foreach my $chain (keys %$chains) {
1554         $res->{$chain} = ipset_chain_digest($chains->{$chain});
1555     }
1556
1557     return $res;
1558 }
1559
1560 sub ruleset_generate_cmdstr {
1561     my ($ruleset, $chain, $rule, $actions, $goto, $cluster_conf, $fw_conf) = @_;
1562
1563     return if defined($rule->{enable}) && !$rule->{enable};
1564     return if $rule->{errors};
1565
1566     die "unable to emit macro - internal error" if $rule->{macro}; # should not happen
1567
1568     my $nbdport = defined($rule->{dport}) ? parse_port_name_number_or_range($rule->{dport}) : 0;
1569     my $nbsport = defined($rule->{sport}) ? parse_port_name_number_or_range($rule->{sport}) : 0;
1570
1571     my @cmd = ();
1572
1573     push @cmd, "-i $rule->{iface_in}" if $rule->{iface_in};
1574     push @cmd, "-o $rule->{iface_out}" if $rule->{iface_out};
1575
1576     my $source = $rule->{source};
1577     my $dest = $rule->{dest};
1578
1579     if ($source) {
1580         if ($source =~ m/^\+/) {
1581             if ($source =~ m/^\+(${ipset_name_pattern})$/) {
1582                 my $name = $1;
1583                 if ($fw_conf && $fw_conf->{ipset}->{$name}) {
1584                     my $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name);
1585                     push @cmd, "-m set --match-set ${ipset_chain} src";
1586                 } elsif ($cluster_conf && $cluster_conf->{ipset}->{$name}) {
1587                     my $ipset_chain = compute_ipset_chain_name(0, $name);
1588                     push @cmd, "-m set --match-set ${ipset_chain} src";
1589                 } else {
1590                     die "no such ipset '$name'\n";
1591                 }
1592             } else {
1593                 die "invalid security group name '$source'\n";
1594             }
1595         } elsif ($source =~ m/^${ip_alias_pattern}$/){
1596             my $alias = lc($source);
1597             my $e = $fw_conf->{aliases}->{$alias} if $fw_conf;
1598             $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1599             die "no such alias '$source'\n" if !$e;
1600             push @cmd, "-s $e->{cidr}";
1601         } elsif ($source =~ m/\-/){
1602             push @cmd, "-m iprange --src-range $source";
1603         } else {
1604             push @cmd, "-s $source";
1605         }
1606     }
1607
1608     if ($dest) {
1609         if ($dest =~ m/^\+/) {
1610             if ($dest =~ m/^\+(${ipset_name_pattern})$/) {
1611                 my $name = $1;
1612                 if ($fw_conf && $fw_conf->{ipset}->{$name}) {
1613                     my $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name);
1614                     push @cmd, "-m set --match-set ${ipset_chain} dst";
1615                 } elsif ($cluster_conf && $cluster_conf->{ipset}->{$name}) {
1616                     my $ipset_chain = compute_ipset_chain_name(0, $name);
1617                     push @cmd, "-m set --match-set ${ipset_chain} dst";
1618                 } else {
1619                     die "no such ipset '$name'\n";
1620                 }
1621             } else {
1622                 die "invalid security group name '$dest'\n";
1623             }
1624         } elsif ($dest =~ m/^${ip_alias_pattern}$/){
1625             my $alias = lc($dest);
1626             my $e = $fw_conf->{aliases}->{$alias} if $fw_conf;
1627             $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1628             die "no such alias '$dest'\n" if !$e;
1629             push @cmd, "-d $e->{cidr}";
1630         } elsif ($dest =~ m/^(\d+)\.(\d+).(\d+).(\d+)\-(\d+)\.(\d+).(\d+).(\d+)$/){
1631             push @cmd, "-m iprange --dst-range $dest";
1632         } else {
1633             push @cmd, "-d $dest";
1634         }
1635     }
1636
1637     if ($rule->{proto}) {
1638         push @cmd, "-p $rule->{proto}";
1639
1640         my $multiport = 0;
1641         $multiport++ if $nbdport > 1;
1642         $multiport++ if $nbsport > 1;
1643
1644         push @cmd, "--match multiport" if $multiport;
1645
1646         die "multiport: option '--sports' cannot be used together with '--dports'\n"
1647             if ($multiport == 2) && ($rule->{dport} ne $rule->{sport});
1648
1649         if ($rule->{dport}) {
1650             if ($rule->{proto} && $rule->{proto} eq 'icmp') {
1651                 # Note: we use dport to store --icmp-type
1652                 die "unknown icmp-type '$rule->{dport}'\n" if !defined($icmp_type_names->{$rule->{dport}});
1653                 push @cmd, "-m icmp --icmp-type $rule->{dport}";
1654             } elsif ($rule->{proto} && $rule->{proto} eq 'icmpv6') {
1655                 # Note: we use dport to store --icmpv6-type
1656                 die "unknown icmpv6-type '$rule->{dport}'\n" if !defined($icmpv6_type_names->{$rule->{dport}});
1657                 push @cmd, "-m icmpv6 --icmpv6-type $rule->{dport}";
1658             } else {
1659                 if ($nbdport > 1) {
1660                     if ($multiport == 2) {
1661                         push @cmd,  "--ports $rule->{dport}";
1662                     } else {
1663                         push @cmd, "--dports $rule->{dport}";
1664                     }
1665                 } else {
1666                     push @cmd, "--dport $rule->{dport}";
1667                 }
1668             }
1669         }
1670
1671         if ($rule->{sport}) {
1672             if ($nbsport > 1) {
1673                 push @cmd, "--sports $rule->{sport}" if $multiport != 2;
1674             } else {
1675                 push @cmd, "--sport $rule->{sport}";
1676             }
1677         }
1678     } elsif ($rule->{dport} || $rule->{sport}) {
1679         die "destination port '$rule->{dport}', but no protocol specified\n" if $rule->{dport};
1680         die "source port '$rule->{sport}', but no protocol specified\n" if $rule->{sport};
1681     }
1682
1683     push @cmd, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
1684
1685     if (my $action = $rule->{action}) {
1686         $action = $actions->{$action} if defined($actions->{$action});
1687         $goto = 1 if !defined($goto) && $action eq 'PVEFW-SET-ACCEPT-MARK';
1688         push @cmd, $goto ? "-g $action" : "-j $action";
1689     }
1690
1691     return scalar(@cmd) ? join(' ', @cmd) : undef;
1692 }
1693
1694 sub ruleset_generate_rule {
1695     my ($ruleset, $chain, $rule, $actions, $goto, $cluster_conf, $fw_conf) = @_;
1696
1697     my $rules;
1698
1699     if ($rule->{macro}) {
1700         $rules = &$apply_macro($rule->{macro}, $rule);
1701     } else {
1702         $rules = [ $rule ];
1703     }
1704
1705     # update all or nothing
1706
1707     my @cmds = ();
1708     foreach my $tmp (@$rules) {
1709         if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $tmp, $actions, $goto, $cluster_conf, $fw_conf)) {
1710             push @cmds, $cmdstr;
1711         }
1712     }
1713
1714     foreach my $cmdstr (@cmds) {
1715         ruleset_addrule($ruleset, $chain, $cmdstr);
1716     }
1717 }
1718
1719 sub ruleset_generate_rule_insert {
1720     my ($ruleset, $chain, $rule, $actions, $goto) = @_;
1721
1722     die "implement me" if $rule->{macro}; # not implemented, because not needed so far
1723
1724     if (my $cmdstr = ruleset_generate_cmdstr($ruleset, $chain, $rule, $actions, $goto)) {
1725         ruleset_insertrule($ruleset, $chain, $cmdstr);
1726     }
1727 }
1728
1729 sub ruleset_create_chain {
1730     my ($ruleset, $chain) = @_;
1731
1732     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
1733     die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
1734
1735     die "chain '$chain' already exists\n" if $ruleset->{$chain};
1736
1737     $ruleset->{$chain} = [];
1738 }
1739
1740 sub ruleset_chain_exist {
1741     my ($ruleset, $chain) = @_;
1742
1743     return $ruleset->{$chain} ? 1 : undef;
1744 }
1745
1746 sub ruleset_addrule {
1747    my ($ruleset, $chain, $rule) = @_;
1748
1749    die "no such chain '$chain'\n" if !$ruleset->{$chain};
1750
1751    push @{$ruleset->{$chain}}, "-A $chain $rule";
1752 }
1753
1754 sub ruleset_insertrule {
1755    my ($ruleset, $chain, $rule) = @_;
1756
1757    die "no such chain '$chain'\n" if !$ruleset->{$chain};
1758
1759    unshift @{$ruleset->{$chain}}, "-A $chain $rule";
1760 }
1761
1762 sub get_log_rule_base {
1763     my ($chain, $vmid, $msg, $loglevel) = @_;
1764
1765     die "internal error - no log level" if !defined($loglevel);
1766
1767     $vmid = 0 if !defined($vmid);
1768
1769     # Note: we use special format for prefix to pass further
1770     # info to log daemon (VMID, LOGVELEL and CHAIN)
1771
1772     return "-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
1773 }
1774
1775 sub ruleset_addlog {
1776     my ($ruleset, $chain, $vmid, $msg, $loglevel, $rule) = @_;
1777
1778     return if !defined($loglevel);
1779
1780     my $logrule = get_log_rule_base($chain, $vmid, $msg, $loglevel);
1781
1782     $logrule = "$rule $logrule" if defined($rule);
1783
1784     ruleset_addrule($ruleset, $chain, $logrule);
1785 }
1786
1787 sub ruleset_add_chain_policy {
1788     my ($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action) = @_;
1789
1790     if ($policy eq 'ACCEPT') {
1791
1792         ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT' },
1793                               { ACCEPT =>  $accept_action});
1794
1795     } elsif ($policy eq 'DROP') {
1796
1797         ruleset_addrule($ruleset, $chain, "-j PVEFW-Drop");
1798
1799         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1800
1801         ruleset_addrule($ruleset, $chain, "-j DROP");
1802     } elsif ($policy eq 'REJECT') {
1803         ruleset_addrule($ruleset, $chain, "-j PVEFW-Reject");
1804
1805         ruleset_addlog($ruleset, $chain, $vmid, "policy $policy: ", $loglevel);
1806
1807         ruleset_addrule($ruleset, $chain, "-g PVEFW-reject");
1808     } else {
1809         # should not happen
1810         die "internal error: unknown policy '$policy'";
1811     }
1812 }
1813
1814 sub ruleset_chain_add_conn_filters {
1815     my ($ruleset, $chain, $accept) = @_;
1816
1817     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID -j DROP");
1818     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED -j $accept");
1819 }
1820
1821 sub ruleset_chain_add_input_filters {
1822     my ($ruleset, $chain, $options, $cluster_conf, $ipversion, $loglevel) = @_;
1823
1824     if ($cluster_conf->{ipset}->{blacklist}){
1825         if (!ruleset_chain_exist($ruleset, "PVEFW-blacklist")) {
1826             ruleset_create_chain($ruleset, "PVEFW-blacklist");
1827             ruleset_addlog($ruleset, "PVEFW-blacklist", 0, "DROP: ", $loglevel) if $loglevel;
1828             ruleset_addrule($ruleset, "PVEFW-blacklist", "-j DROP");
1829         }
1830         my $ipset_chain = compute_ipset_chain_name(0, 'blacklist');
1831         ruleset_addrule($ruleset, $chain, "-m set --match-set ${ipset_chain} src -j PVEFW-blacklist");
1832     }
1833
1834     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
1835         if ($ipversion == 4) {
1836             ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW -j PVEFW-smurfs");
1837         }
1838     }
1839
1840     if ($options->{tcpflags}) {
1841         ruleset_addrule($ruleset, $chain, "-p tcp -j PVEFW-tcpflags");
1842     }
1843 }
1844
1845 sub ruleset_create_vm_chain {
1846     my ($ruleset, $chain, $options, $macaddr, $ipfilter_ipset, $direction) = @_;
1847
1848     ruleset_create_chain($ruleset, $chain);
1849     my $accept = generate_nfqueue($options);
1850
1851     if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
1852         if ($direction eq 'OUT') {
1853             ruleset_generate_rule($ruleset, $chain, { action => 'PVEFW-SET-ACCEPT-MARK',
1854                                                       proto => 'udp', sport => 68, dport => 67 });
1855         } else {
1856             ruleset_generate_rule($ruleset, $chain, { action => 'ACCEPT',
1857                                                       proto => 'udp', sport => 67, dport => 68 });
1858         }
1859     }
1860
1861     if ($direction eq 'OUT') {
1862         if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
1863             ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr -j DROP");
1864         }
1865         if ($ipfilter_ipset) {
1866             ruleset_addrule($ruleset, $chain, "-m set ! --match-set $ipfilter_ipset src -j DROP");
1867         }
1868         ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
1869     }
1870 }
1871
1872 sub ruleset_add_group_rule {
1873     my ($ruleset, $cluster_conf, $chain, $rule, $direction, $action, $ipversion) = @_;
1874
1875     my $group = $rule->{action};
1876     my $group_chain = "GROUP-$group-$direction";
1877     if(!ruleset_chain_exist($ruleset, $group_chain)){
1878         generate_group_rules($ruleset, $cluster_conf, $group, $ipversion);
1879     }
1880
1881     if ($direction eq 'OUT' && $rule->{iface_out}) {
1882         ruleset_addrule($ruleset, $chain, "-o $rule->{iface_out} -j $group_chain");
1883     } elsif ($direction eq 'IN' && $rule->{iface_in}) {
1884         ruleset_addrule($ruleset, $chain, "-i $rule->{iface_in} -j $group_chain");
1885     } else {
1886         ruleset_addrule($ruleset, $chain, "-j $group_chain");
1887     }
1888
1889     ruleset_addrule($ruleset, $chain, "-m mark --mark 1 -j $action");
1890 }
1891
1892 sub ruleset_generate_vm_rules {
1893     my ($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, $netid, $direction, $options, $ipversion) = @_;
1894
1895     my $lc_direction = lc($direction);
1896
1897     my $in_accept = generate_nfqueue($options);
1898
1899     foreach my $rule (@$rules) {
1900         next if $rule->{iface} && $rule->{iface} ne $netid;
1901         next if !$rule->{enable} || $rule->{errors};
1902         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
1903
1904         if ($rule->{type} eq 'group') {
1905             ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, $direction,
1906                                    $direction eq 'OUT' ? 'RETURN' : $in_accept, $ipversion);
1907         } else {
1908             next if $rule->{type} ne $lc_direction;
1909             eval {
1910                 if ($direction eq 'OUT') {
1911                     ruleset_generate_rule($ruleset, $chain, $rule,
1912                                           { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" },
1913                                           undef, $cluster_conf, $vmfw_conf);
1914                 } else {
1915                     ruleset_generate_rule($ruleset, $chain, $rule,
1916                                           { ACCEPT => $in_accept , REJECT => "PVEFW-reject" },
1917                                           undef, $cluster_conf, $vmfw_conf);
1918                 }
1919             };
1920             warn $@ if $@;
1921         }
1922     }
1923 }
1924
1925 sub generate_nfqueue {
1926     my ($options) = @_;
1927
1928     if ($options->{ips}) {
1929         my $action = "NFQUEUE";
1930         if ($options->{ips_queues} && $options->{ips_queues} =~ m/^(\d+)(:(\d+))?$/) {
1931             if (defined($3) && defined($1)) {
1932                 $action .= " --queue-balance $1:$3";
1933             } elsif (defined($1)) {
1934                 $action .= " --queue-num $1";
1935             }
1936         }
1937         $action .= " --queue-bypass" if $feature_ipset_nomatch; #need kernel 3.10
1938         return $action;
1939     } else {
1940         return "ACCEPT";
1941     }
1942 }
1943
1944 sub ruleset_generate_vm_ipsrules {
1945     my ($ruleset, $options, $direction, $iface) = @_;
1946
1947     if ($options->{ips} && $direction eq 'IN') {
1948         my $nfqueue = generate_nfqueue($options);
1949
1950         if (!ruleset_chain_exist($ruleset, "PVEFW-IPS")) {
1951             ruleset_create_chain($ruleset, "PVEFW-IPS");
1952         }
1953
1954         ruleset_addrule($ruleset, "PVEFW-IPS", "-m physdev --physdev-out $iface --physdev-is-bridged -j $nfqueue");
1955     }
1956 }
1957
1958 sub generate_venet_rules_direction {
1959     my ($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip, $direction, $ipversion) = @_;
1960
1961     my $lc_direction = lc($direction);
1962
1963     my $rules = $vmfw_conf->{rules};
1964
1965     my $options = $vmfw_conf->{options};
1966     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
1967
1968     my $chain = "venet0-$vmid-$direction";
1969
1970     ruleset_create_vm_chain($ruleset, $chain, $options, undef, undef, $direction);
1971
1972     ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, 'venet', $direction, undef, $ipversion);
1973
1974     # implement policy
1975     my $policy;
1976
1977     if ($direction eq 'OUT') {
1978         $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
1979     } else {
1980         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
1981     }
1982
1983     my $accept = generate_nfqueue($options);
1984     my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
1985     ruleset_add_chain_policy($ruleset, $chain, $vmid, $policy, $loglevel, $accept_action);
1986
1987     if ($direction eq 'OUT') {
1988         ruleset_generate_rule_insert($ruleset, "PVEFW-VENET-OUT", {
1989             action => $chain,
1990             source => $ip,
1991             iface_in => 'venet0'});
1992     } else {
1993         ruleset_generate_rule($ruleset, "PVEFW-VENET-IN", {
1994             action => $chain,
1995             dest => $ip,
1996             iface_out => 'venet0'});
1997     }
1998 }
1999
2000 sub generate_tap_rules_direction {
2001     my ($ruleset, $cluster_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $direction, $ipversion) = @_;
2002
2003     my $lc_direction = lc($direction);
2004
2005     my $rules = $vmfw_conf->{rules};
2006
2007     my $options = $vmfw_conf->{options};
2008     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
2009
2010     my $tapchain = "$iface-$direction";
2011
2012     my $ipfilter_name = compute_ipfilter_ipset_name($netid);
2013     my $ipfilter_ipset = compute_ipset_chain_name($vmid, $ipfilter_name)
2014         if $vmfw_conf->{ipset}->{$ipfilter_name};       
2015
2016     # create chain with mac and ip filter
2017     ruleset_create_vm_chain($ruleset, $tapchain, $options, $macaddr, $ipfilter_ipset, $direction);
2018
2019     if ($options->{enable}) {
2020         ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $tapchain, $netid, $direction, $options, $ipversion);
2021
2022         ruleset_generate_vm_ipsrules($ruleset, $options, $direction, $iface);
2023
2024         # implement policy
2025         my $policy;
2026
2027         if ($direction eq 'OUT') {
2028             $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
2029         } else {
2030         $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
2031         }
2032
2033         my $accept = generate_nfqueue($options);
2034         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
2035         ruleset_add_chain_policy($ruleset, $tapchain, $vmid, $policy, $loglevel, $accept_action);
2036     } else {
2037         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : 'ACCEPT';
2038         ruleset_add_chain_policy($ruleset, $tapchain, $vmid, 'ACCEPT', $loglevel, $accept_action);
2039     }
2040
2041     # plug the tap chain to bridge chain
2042     if ($direction eq 'IN') {
2043         ruleset_addrule($ruleset, "PVEFW-FWBR-IN",
2044                         "-m physdev --physdev-is-bridged --physdev-out $iface -j $tapchain");
2045     } else {
2046         ruleset_addrule($ruleset, "PVEFW-FWBR-OUT",
2047                         "-m physdev --physdev-is-bridged --physdev-in $iface -j $tapchain");
2048     }
2049 }
2050
2051 sub enable_host_firewall {
2052     my ($ruleset, $hostfw_conf, $cluster_conf, $ipversion) = @_;
2053
2054     my $options = $hostfw_conf->{options};
2055     my $cluster_options = $cluster_conf->{options};
2056     my $rules = $hostfw_conf->{rules};
2057     my $cluster_rules = $cluster_conf->{rules};
2058
2059     # host inbound firewall
2060     my $chain = "PVEFW-HOST-IN";
2061     ruleset_create_chain($ruleset, $chain);
2062
2063     my $loglevel = get_option_log_level($options, "log_level_in");
2064
2065     ruleset_addrule($ruleset, $chain, "-i lo -j ACCEPT");
2066
2067     ruleset_chain_add_conn_filters($ruleset, $chain, 'ACCEPT');
2068     ruleset_chain_add_input_filters($ruleset, $chain, $options, $cluster_conf, $ipversion, $loglevel);
2069
2070     # we use RETURN because we need to check also tap rules
2071     my $accept_action = 'RETURN';
2072
2073     ruleset_addrule($ruleset, $chain, "-p igmp -j $accept_action"); # important for multicast
2074
2075     # add host rules first, so that cluster wide rules can be overwritten
2076     foreach my $rule (@$rules, @$cluster_rules) {
2077         next if !$rule->{enable} || $rule->{errors};
2078
2079         $rule->{iface_in} = $rule->{iface} if $rule->{iface};
2080
2081         eval {
2082             if ($rule->{type} eq 'group') {
2083                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'IN', $accept_action, $ipversion);
2084             } elsif ($rule->{type} eq 'in') {
2085                 ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" },
2086                                       undef, $cluster_conf, $hostfw_conf);
2087             }
2088         };
2089         warn $@ if $@;
2090         delete $rule->{iface_in};
2091     }
2092
2093     # allow standard traffic for management ipset (includes cluster network)
2094     my $mngmnt_ipset_chain = compute_ipset_chain_name(0, "management");
2095     my $mngmntsrc = "-m set --match-set ${mngmnt_ipset_chain} src";
2096     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 8006 -j $accept_action");  # PVE API
2097     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 5900:5999 -j $accept_action");  # PVE VNC Console
2098     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 3128 -j $accept_action");  # SPICE Proxy
2099     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 22 -j $accept_action");  # SSH
2100
2101     my $localnet = local_network();
2102
2103     # corosync
2104     if ($localnet) {
2105         my $corosync_rule = "-p udp --dport 5404:5405 -j $accept_action";
2106         ruleset_addrule($ruleset, $chain, "-s $localnet -d $localnet $corosync_rule");
2107         ruleset_addrule($ruleset, $chain, "-s $localnet -m addrtype --dst-type MULTICAST $corosync_rule");
2108     }
2109
2110     # implement input policy
2111     my $policy = $cluster_options->{policy_in} || 'DROP'; # allow nothing by default
2112     ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
2113
2114     # host outbound firewall
2115     $chain = "PVEFW-HOST-OUT";
2116     ruleset_create_chain($ruleset, $chain);
2117
2118     $loglevel = get_option_log_level($options, "log_level_out");
2119
2120     ruleset_addrule($ruleset, $chain, "-o lo -j ACCEPT");
2121
2122     ruleset_chain_add_conn_filters($ruleset, $chain, 'ACCEPT');
2123
2124     # we use RETURN because we may want to check other thigs later
2125     $accept_action = 'RETURN';
2126
2127     ruleset_addrule($ruleset, $chain, "-p igmp -j $accept_action"); # important for multicast
2128
2129     # add host rules first, so that cluster wide rules can be overwritten
2130     foreach my $rule (@$rules, @$cluster_rules) {
2131         next if !$rule->{enable} || $rule->{errors};
2132
2133         $rule->{iface_out} = $rule->{iface} if $rule->{iface};
2134         eval {
2135             if ($rule->{type} eq 'group') {
2136                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'OUT', $accept_action, $ipversion);
2137             } elsif ($rule->{type} eq 'out') {
2138                 ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" },
2139                                       undef, $cluster_conf, $hostfw_conf);
2140             }
2141         };
2142         warn $@ if $@;
2143         delete $rule->{iface_out};
2144     }
2145
2146     # allow standard traffic on cluster network
2147     if ($localnet) {
2148         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 8006 -j $accept_action");  # PVE API
2149         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 22 -j $accept_action");  # SSH
2150         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 5900:5999 -j $accept_action");  # PVE VNC Console
2151         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 3128 -j $accept_action");  # SPICE Proxy
2152
2153         my $corosync_rule = "-p udp --dport 5404:5405 -j $accept_action";
2154         ruleset_addrule($ruleset, $chain, "-d $localnet $corosync_rule");
2155         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule");
2156     }
2157
2158     # implement output policy
2159     $policy = $cluster_options->{policy_out} || 'ACCEPT'; # allow everything by default
2160     ruleset_add_chain_policy($ruleset, $chain, 0, $policy, $loglevel, $accept_action);
2161
2162     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-j PVEFW-HOST-OUT");
2163     ruleset_addrule($ruleset, "PVEFW-INPUT", "-j PVEFW-HOST-IN");
2164 }
2165
2166 sub generate_group_rules {
2167     my ($ruleset, $cluster_conf, $group, $ipversion) = @_;
2168
2169     my $rules = $cluster_conf->{groups}->{$group};
2170
2171     if (!$rules) {
2172         warn "no such security group '$group'\n";
2173         $rules = []; # create empty chain
2174     }
2175
2176     my $chain = "GROUP-${group}-IN";
2177
2178     ruleset_create_chain($ruleset, $chain);
2179     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
2180
2181     foreach my $rule (@$rules) {
2182         next if $rule->{type} ne 'in';
2183         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2184         ruleset_generate_rule($ruleset, $chain, $rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" }, undef, $cluster_conf);
2185     }
2186
2187     $chain = "GROUP-${group}-OUT";
2188
2189     ruleset_create_chain($ruleset, $chain);
2190     ruleset_addrule($ruleset, $chain, "-j MARK --set-mark 0"); # clear mark
2191
2192     foreach my $rule (@$rules) {
2193         next if $rule->{type} ne 'out';
2194         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2195         # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
2196         # check also other tap rules later
2197         ruleset_generate_rule($ruleset, $chain, $rule,
2198                               { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" }, undef, $cluster_conf);
2199     }
2200 }
2201
2202 my $MAX_NETS = 32;
2203 my $valid_netdev_names = {};
2204 for (my $i = 0; $i < $MAX_NETS; $i++)  {
2205     $valid_netdev_names->{"net$i"} = 1;
2206 }
2207
2208 sub parse_fw_rule {
2209     my ($prefix, $line, $cluster_conf, $fw_conf, $rule_env, $verbose) = @_;
2210
2211     my $orig_line = $line;
2212
2213     my $rule = {};
2214
2215     # we can add single line comments to the end of the rule
2216     if ($line =~ s/#\s*(.*?)\s*$//) {
2217         $rule->{comment} = decode('utf8', $1);
2218     }
2219
2220     # we can disable a rule when prefixed with '|'
2221
2222     $rule->{enable} = $line =~ s/^\|// ? 0 : 1;
2223
2224     $line =~ s/^(\S+)\s+(\S+)\s*// ||
2225         die "unable to parse rule: $line\n";
2226
2227     $rule->{type} = lc($1);
2228     $rule->{action} = $2;
2229
2230     if ($rule->{type} eq  'in' || $rule->{type} eq 'out') {
2231         if ($rule->{action} =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
2232             $rule->{macro} = $1;
2233             $rule->{action} = $2;
2234         }
2235     }
2236
2237     while (length($line)) {
2238         if ($line =~ s/^-i (\S+)\s*//) {
2239             $rule->{iface} = $1;
2240             next;
2241         }
2242
2243         last if $rule->{type} eq 'group';
2244
2245         if ($line =~ s/^-p (\S+)\s*//) {
2246             $rule->{proto} = $1;
2247             next;
2248         }
2249
2250         if ($line =~ s/^-dport (\S+)\s*//) {
2251             $rule->{dport} = $1;
2252             next;
2253         }
2254
2255         if ($line =~ s/^-sport (\S+)\s*//) {
2256             $rule->{sport} = $1;
2257             next;
2258         }
2259         if ($line =~ s/^-source (\S+)\s*//) {
2260             $rule->{source} = $1;
2261             next;
2262         }
2263         if ($line =~ s/^-dest (\S+)\s*//) {
2264             $rule->{dest} = $1;
2265             next;
2266         }
2267
2268         last;
2269     }
2270
2271     die "unable to parse rule parameters: $line\n" if length($line);
2272
2273     $rule = verify_rule($rule, $cluster_conf, $fw_conf, $rule_env, 1);
2274     if ($verbose && $rule->{errors}) {
2275         warn "$prefix - errors in rule parameters: $orig_line\n";
2276         foreach my $p (keys %{$rule->{errors}}) {
2277             warn "  $p: $rule->{errors}->{$p}\n";
2278         }
2279     }
2280
2281     return $rule;
2282 }
2283
2284 sub parse_vmfw_option {
2285     my ($line) = @_;
2286
2287     my ($opt, $value);
2288
2289     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2290
2291     if ($line =~ m/^(enable|dhcp|macfilter|ips):\s*(0|1)\s*$/i) {
2292         $opt = lc($1);
2293         $value = int($2);
2294     } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
2295         $opt = lc($1);
2296         $value = $2 ? lc($3) : '';
2297     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2298         $opt = lc($1);
2299         $value = uc($3);
2300     } elsif ($line =~ m/^(ips_queues):\s*((\d+)(:(\d+))?)\s*$/i) {
2301         $opt = lc($1);
2302         $value = $2;
2303     } else {
2304         die "can't parse option '$line'\n"
2305     }
2306
2307     return ($opt, $value);
2308 }
2309
2310 sub parse_hostfw_option {
2311     my ($line) = @_;
2312
2313     my ($opt, $value);
2314
2315     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2316
2317     if ($line =~ m/^(enable|nosmurfs|tcpflags):\s*(0|1)\s*$/i) {
2318         $opt = lc($1);
2319         $value = int($2);
2320     } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
2321         $opt = lc($1);
2322         $value = $2 ? lc($3) : '';
2323     } elsif ($line =~ m/^(nf_conntrack_max|nf_conntrack_tcp_timeout_established):\s*(\d+)\s*$/i) {
2324         $opt = lc($1);
2325         $value = int($2);
2326     } else {
2327         die "can't parse option '$line'\n"
2328     }
2329
2330     return ($opt, $value);
2331 }
2332
2333 sub parse_clusterfw_option {
2334     my ($line) = @_;
2335
2336     my ($opt, $value);
2337
2338     if ($line =~ m/^(enable):\s*(0|1)\s*$/i) {
2339         $opt = lc($1);
2340         $value = int($2);
2341     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2342         $opt = lc($1);
2343         $value = uc($3);
2344     } else {
2345         die "can't parse option '$line'\n"
2346     }
2347
2348     return ($opt, $value);
2349 }
2350
2351 sub resolve_alias {
2352     my ($clusterfw_conf, $fw_conf, $cidr) = @_;
2353
2354     my $alias = lc($cidr);
2355     my $e = $fw_conf->{aliases}->{$alias} if $fw_conf;
2356     $e = $clusterfw_conf->{aliases}->{$alias} if !$e && $clusterfw_conf;
2357
2358     die "no such alias '$cidr'\n" if !$e;;
2359
2360     return wantarray ? ($e->{cidr}, $e->{ipversion}) : $e->{cidr};
2361 }
2362
2363 sub parse_ip_or_cidr {
2364     my ($cidr) = @_;
2365
2366     my $ipversion;
2367     
2368     if ($cidr =~ m!^(?:$IPV6RE)(/(\d+))?$!) {
2369         $cidr =~ s|/128$||;
2370         $ipversion = 6;
2371     } elsif ($cidr =~ m!^(?:$IPV4RE)(/(\d+))?$!) {
2372         $cidr =~ s|/32$||;
2373         $ipversion = 4;
2374     } else {
2375         die "value does not look like a valid IP address or CIDR network\n";
2376     }
2377
2378     return wantarray ? ($cidr, $ipversion) : $cidr;
2379 }
2380
2381 sub parse_alias {
2382     my ($line) = @_;
2383
2384     # we can add single line comments to the end of the line
2385     my $comment = decode('utf8', $1) if $line =~ s/\s*#\s*(.*?)\s*$//;
2386
2387     if ($line =~ m/^(\S+)\s(\S+)$/) {
2388         my ($name, $cidr) = ($1, $2);
2389         my $ipversion;
2390
2391         ($cidr, $ipversion) = parse_ip_or_cidr($cidr);
2392
2393         my $data = {
2394             name => $name,
2395             cidr => $cidr,
2396             ipversion => $ipversion,
2397         };
2398         $data->{comment} = $comment  if $comment;
2399         return $data;
2400     }
2401
2402     return undef;
2403 }
2404
2405 sub generic_fw_config_parser {
2406     my ($filename, $fh, $verbose, $cluster_conf, $empty_conf, $rule_env) = @_;
2407
2408     my $section;
2409     my $group;
2410
2411     my $res = $empty_conf;
2412
2413     while (defined(my $line = <$fh>)) {
2414         next if $line =~ m/^#/;
2415         next if $line =~ m/^\s*$/;
2416
2417         chomp $line;
2418
2419         my $linenr = $fh->input_line_number();
2420         my $prefix = "$filename (line $linenr)";
2421
2422         if ($empty_conf->{options} && ($line =~ m/^\[options\]$/i)) {
2423             $section = 'options';
2424             next;
2425         }
2426
2427         if ($empty_conf->{aliases} && ($line =~ m/^\[aliases\]$/i)) {
2428             $section = 'aliases';
2429             next;
2430         }
2431
2432         if ($empty_conf->{groups} && ($line =~ m/^\[group\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
2433             $section = 'groups';
2434             $group = lc($1);
2435             my $comment = $2;
2436             eval {
2437                 die "security group name too long\n" if length($group) > $max_group_name_length;
2438                 die "invalid security group name '$group'\n" if $group !~ m/^${security_group_name_pattern}$/;
2439             };
2440             if (my $err = $@) {
2441                 ($section, $group, $comment) = undef;
2442                 warn "$prefix: $err";
2443                 next;
2444             }
2445             
2446             $res->{$section}->{$group} = [];
2447             $res->{group_comments}->{$group} =  decode('utf8', $comment)
2448                 if $comment;
2449             next;
2450         }
2451
2452         if ($empty_conf->{rules} && ($line =~ m/^\[rules\]$/i)) {
2453             $section = 'rules';
2454             next;
2455         }
2456
2457         if ($empty_conf->{ipset} && ($line =~ m/^\[ipset\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
2458             $section = 'ipset';
2459             $group = lc($1);
2460             my $comment = $2;
2461             eval {      
2462                 die "ipset name too long\n" if length($group) > $max_ipset_name_length;
2463                 die "invalid ipset name '$group'\n" if $group !~ m/^${ipset_name_pattern}$/;
2464             };
2465             if (my $err = $@) {
2466                 ($section, $group, $comment) = undef;
2467                 warn "$prefix: $err";
2468                 next;
2469             }
2470
2471             $res->{$section}->{$group} = [];
2472             $res->{ipset_comments}->{$group} = decode('utf8', $comment)
2473                 if $comment;
2474             next;
2475         }
2476
2477         if (!$section) {
2478             warn "$prefix: skip line - no section\n";
2479             next;
2480         }
2481
2482         if ($section eq 'options') {
2483             eval {
2484                 my ($opt, $value);
2485                 if ($rule_env eq 'cluster') {
2486                     ($opt, $value) = parse_clusterfw_option($line);
2487                 } elsif ($rule_env eq 'host') {
2488                     ($opt, $value) = parse_hostfw_option($line);
2489                 } else {
2490                     ($opt, $value) = parse_vmfw_option($line);
2491                 }
2492                 $res->{options}->{$opt} = $value;
2493             };
2494             warn "$prefix: $@" if $@;
2495         } elsif ($section eq 'aliases') {
2496             eval {
2497                 my $data = parse_alias($line);
2498                 $res->{aliases}->{lc($data->{name})} = $data;
2499             };
2500             warn "$prefix: $@" if $@;
2501         } elsif ($section eq 'rules') {
2502             my $rule;
2503             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, $res, $rule_env, $verbose); };
2504             if (my $err = $@) {
2505                 warn "$prefix: $err";
2506                 next;
2507             }
2508             push @{$res->{$section}}, $rule;
2509         } elsif ($section eq 'groups') {
2510             my $rule;
2511             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, undef, 'group', $verbose); };
2512             if (my $err = $@) {
2513                 warn "$prefix: $err";
2514                 next;
2515             }
2516             push @{$res->{$section}->{$group}}, $rule;
2517         } elsif ($section eq 'ipset') {
2518             # we can add single line comments to the end of the rule
2519             my $comment = decode('utf8', $1) if $line =~ s/#\s*(.*?)\s*$//;
2520
2521             $line =~ m/^(\!)?\s*(\S+)\s*$/;
2522             my $nomatch = $1;
2523             my $cidr = $2;
2524             my $errors;
2525
2526             if ($nomatch && !$feature_ipset_nomatch) {
2527                 $errors->{nomatch} = "nomatch not supported by kernel";
2528             }
2529
2530             eval { 
2531                 if ($cidr =~ m/^${ip_alias_pattern}$/) {
2532                     resolve_alias($cluster_conf, $res, $cidr); # make sure alias exists
2533                 } else {
2534                     $cidr = parse_ip_or_cidr($cidr);
2535                 }
2536             };
2537             if (my $err = $@) {
2538                 chomp $err;
2539                 $errors->{cidr} = $err;
2540             }
2541
2542             my $entry = { cidr => $cidr };
2543             $entry->{nomatch} = 1 if $nomatch;
2544             $entry->{comment} = $comment if $comment;
2545             $entry->{errors} =  $errors if $errors;
2546
2547             if ($verbose && $errors) {
2548                 warn "$prefix - errors in ipset '$group': $line\n";
2549                 foreach my $p (keys %{$errors}) {
2550                     warn "  $p: $errors->{$p}\n";
2551                 }
2552             }
2553
2554             push @{$res->{$section}->{$group}}, $entry;
2555         } else {
2556             warn "$prefix: skip line - unknown section\n";
2557             next;
2558         }
2559     }
2560
2561     return $res;
2562 }
2563
2564 sub parse_hostfw_config {
2565     my ($filename, $fh, $cluster_conf, $verbose) = @_;
2566
2567     my $empty_conf = { rules => [], options => {}};
2568
2569     return generic_fw_config_parser($filename, $fh, $verbose, $cluster_conf, $empty_conf, 'host');
2570 }
2571
2572 sub parse_vmfw_config {
2573     my ($filename, $fh, $cluster_conf, $rule_env, $verbose) = @_;
2574
2575     my $empty_conf = {
2576         rules => [],
2577         options => {},
2578         aliases => {},
2579         ipset => {} ,
2580         ipset_comments => {},
2581     };
2582
2583     return generic_fw_config_parser($filename, $fh, $verbose, $cluster_conf, $empty_conf, $rule_env);
2584 }
2585
2586 sub parse_clusterfw_config {
2587     my ($filename, $fh, $verbose) = @_;
2588
2589     my $section;
2590     my $group;
2591
2592     my $empty_conf = {
2593         rules => [],
2594         options => {},
2595         aliases => {},
2596         groups => {},
2597         group_comments => {},
2598         ipset => {} ,
2599         ipset_comments => {},
2600     };
2601
2602     return generic_fw_config_parser($filename, $fh, $verbose, $empty_conf, $empty_conf, 'cluster');
2603 }
2604
2605 sub run_locked {
2606     my ($code, @param) = @_;
2607
2608     my $timeout = 10;
2609
2610     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
2611
2612     die $@ if $@;
2613
2614     return $res;
2615 }
2616
2617 sub read_local_vm_config {
2618
2619     my $openvz = {};
2620     my $qemu = {};
2621
2622     my $vmdata = { openvz => $openvz, qemu => $qemu };
2623
2624     my $vmlist = PVE::Cluster::get_vmlist();
2625     return $vmdata if !$vmlist || !$vmlist->{ids};
2626     my $ids = $vmlist->{ids};
2627
2628     foreach my $vmid (keys %$ids) {
2629         next if !$vmid; # skip VE0
2630         my $d = $ids->{$vmid};
2631         next if !$d->{node} || $d->{node} ne $nodename;
2632         next if !$d->{type};
2633         if ($d->{type} eq 'openvz') {
2634             if ($have_pve_manager) {
2635                 my $cfspath = PVE::OpenVZ::cfs_config_path($vmid);
2636                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
2637                     $openvz->{$vmid} = $conf;
2638                 }
2639             }
2640         } elsif ($d->{type} eq 'qemu') {
2641             if ($have_qemu_server) {
2642                 my $cfspath = PVE::QemuServer::cfs_config_path($vmid);
2643                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
2644                     $qemu->{$vmid} = $conf;
2645                 }
2646             }
2647         }
2648     }
2649
2650     return $vmdata;
2651 };
2652
2653 sub load_vmfw_conf {
2654     my ($cluster_conf, $rule_env, $vmid, $dir, $verbose) = @_;
2655
2656     my $vmfw_conf = {};
2657
2658     $dir = $pvefw_conf_dir if !defined($dir);
2659
2660     my $filename = "$dir/$vmid.fw";
2661     if (my $fh = IO::File->new($filename, O_RDONLY)) {
2662         $vmfw_conf = parse_vmfw_config($filename, $fh, $cluster_conf, $rule_env, $verbose);
2663         $vmfw_conf->{vmid} = $vmid;
2664     }
2665
2666     return $vmfw_conf;
2667 }
2668
2669 my $format_rules = sub {
2670     my ($rules, $allow_iface) = @_;
2671
2672     my $raw = '';
2673
2674     foreach my $rule (@$rules) {
2675         if ($rule->{type} eq  'in' || $rule->{type} eq 'out' || $rule->{type} eq 'group') {
2676             $raw .= '|' if defined($rule->{enable}) && !$rule->{enable};
2677             $raw .= uc($rule->{type});
2678             if ($rule->{macro}) {
2679                 $raw .= " $rule->{macro}($rule->{action})";
2680             } else {
2681                 $raw .= " " . $rule->{action};
2682             }
2683             if ($allow_iface && $rule->{iface}) {
2684                 $raw .= " -i $rule->{iface}";
2685             }
2686
2687             if ($rule->{type} ne  'group')  {
2688                 $raw .= " -source $rule->{source}" if $rule->{source};
2689                 $raw .= " -dest $rule->{dest}" if $rule->{dest};
2690                 $raw .= " -p $rule->{proto}" if $rule->{proto};
2691                 $raw .= " -dport $rule->{dport}" if $rule->{dport};
2692                 $raw .= " -sport $rule->{sport}" if $rule->{sport};
2693             }
2694
2695             $raw .= " # " . encode('utf8', $rule->{comment})
2696                 if $rule->{comment} && $rule->{comment} !~ m/^\s*$/;
2697             $raw .= "\n";
2698         } else {
2699             die "unknown rule type '$rule->{type}'";
2700         }
2701     }
2702
2703     return $raw;
2704 };
2705
2706 my $format_options = sub {
2707     my ($options) = @_;
2708
2709     my $raw = '';
2710
2711     $raw .= "[OPTIONS]\n\n";
2712     foreach my $opt (keys %$options) {
2713         $raw .= "$opt: $options->{$opt}\n";
2714     }
2715     $raw .= "\n";
2716
2717     return $raw;
2718 };
2719
2720 my $format_aliases = sub {
2721     my ($aliases) = @_;
2722
2723     my $raw = '';
2724
2725     $raw .= "[ALIASES]\n\n";
2726     foreach my $k (keys %$aliases) {
2727         my $e = $aliases->{$k};
2728         $raw .= "$e->{name} $e->{cidr}";
2729         $raw .= " # " . encode('utf8', $e->{comment})
2730             if $e->{comment} && $e->{comment} !~ m/^\s*$/;
2731         $raw .= "\n";
2732     }
2733     $raw .= "\n";
2734
2735     return $raw;
2736 };
2737
2738 my $format_ipsets = sub {
2739     my ($fw_conf) = @_;
2740     
2741     my $raw = '';
2742
2743     foreach my $ipset (sort keys %{$fw_conf->{ipset}}) {
2744         if (my $comment = $fw_conf->{ipset_comments}->{$ipset}) {
2745             my $utf8comment = encode('utf8', $comment);
2746             $raw .= "[IPSET $ipset] # $utf8comment\n\n";
2747         } else {
2748             $raw .= "[IPSET $ipset]\n\n";
2749         }
2750         my $options = $fw_conf->{ipset}->{$ipset};
2751
2752         my $nethash = {};
2753         foreach my $entry (@$options) {
2754             $nethash->{$entry->{cidr}} = $entry;
2755         }
2756
2757         foreach my $cidr (sort keys %$nethash) {
2758             my $entry = $nethash->{$cidr};
2759             my $line = $entry->{nomatch} ? '!' : '';
2760             $line .= $entry->{cidr};
2761             $line .= " # " . encode('utf8', $entry->{comment})
2762                 if $entry->{comment} && $entry->{comment} !~ m/^\s*$/;
2763             $raw .= "$line\n";
2764         }
2765
2766         $raw .= "\n";
2767     }
2768
2769     return $raw;
2770 };
2771
2772 sub save_vmfw_conf {
2773     my ($vmid, $vmfw_conf) = @_;
2774
2775     my $raw = '';
2776
2777     my $options = $vmfw_conf->{options};
2778     $raw .= &$format_options($options) if $options && scalar(keys %$options);
2779
2780     my $aliases = $vmfw_conf->{aliases};
2781     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
2782
2783     $raw .= &$format_ipsets($vmfw_conf) if $vmfw_conf->{ipset};
2784
2785     my $rules = $vmfw_conf->{rules} || [];
2786     if ($rules && scalar(@$rules)) {
2787         $raw .= "[RULES]\n\n";
2788         $raw .= &$format_rules($rules, 1);
2789         $raw .= "\n";
2790     }
2791
2792     mkdir $pvefw_conf_dir;
2793
2794     my $filename = "$pvefw_conf_dir/$vmid.fw";
2795     PVE::Tools::file_set_contents($filename, $raw);
2796 }
2797
2798 sub read_vm_firewall_configs {
2799     my ($cluster_conf, $vmdata, $dir, $verbose) = @_;
2800
2801     my $vmfw_configs = {};
2802
2803     foreach my $vmid (keys %{$vmdata->{qemu}}) {
2804         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'vm', $vmid, $dir, $verbose);
2805         next if !$vmfw_conf->{options}; # skip if file does not exists
2806         $vmfw_configs->{$vmid} = $vmfw_conf;
2807     }
2808     foreach my $vmid (keys %{$vmdata->{openvz}}) {
2809         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'ct', $vmid, $dir, $verbose);
2810         next if !$vmfw_conf->{options}; # skip if file does not exists
2811         $vmfw_configs->{$vmid} = $vmfw_conf;
2812     }
2813
2814     return $vmfw_configs;
2815 }
2816
2817 sub get_option_log_level {
2818     my ($options, $k) = @_;
2819
2820     my $v = $options->{$k};
2821     $v = $default_log_level if !defined($v);
2822
2823     return undef if $v eq '' || $v eq 'nolog';
2824
2825     $v = $log_level_hash->{$v} if defined($log_level_hash->{$v});
2826
2827     return $v if ($v >= 0) && ($v <= 7);
2828
2829     warn "unknown log level ($k = '$v')\n";
2830
2831     return undef;
2832 }
2833
2834 sub generate_std_chains {
2835     my ($ruleset, $options, $ipversion) = @_;
2836
2837     my $std_chains = $pve_std_chains->{$ipversion} || die "internal error";
2838
2839     my $loglevel = get_option_log_level($options, 'smurf_log_level');
2840
2841     my $chain;
2842
2843     if ($ipversion == 4) {
2844         # same as shorewall smurflog.
2845         $chain = 'PVEFW-smurflog';
2846         $std_chains->{$chain} = [];
2847         
2848         push @{$std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
2849         push @{$std_chains->{$chain}}, "-j DROP";
2850     }
2851
2852     # same as shorewall logflags action.
2853     $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
2854     $chain = 'PVEFW-logflags';
2855     $std_chains->{$chain} = [];
2856
2857     # fixme: is this correctly logged by pvewf-logger? (ther is no --log-ip-options for NFLOG)
2858     push @{$std_chains->{$chain}}, get_log_rule_base($chain, 0, "DROP: ", $loglevel) if $loglevel;
2859     push @{$std_chains->{$chain}}, "-j DROP";
2860
2861     foreach my $chain (keys %$std_chains) {
2862         ruleset_create_chain($ruleset, $chain);
2863         foreach my $rule (@{$std_chains->{$chain}}) {
2864             if (ref($rule)) {
2865                 ruleset_generate_rule($ruleset, $chain, $rule);
2866             } else {
2867                 ruleset_addrule($ruleset, $chain, $rule);
2868             }
2869         }
2870     }
2871 }
2872
2873 sub generate_ipset_chains {
2874     my ($ipset_ruleset, $clusterfw_conf, $fw_conf) = @_;
2875
2876     foreach my $ipset (keys %{$fw_conf->{ipset}}) {
2877         my $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $ipset);
2878         generate_ipset($ipset_ruleset, $ipset_chain, $fw_conf->{ipset}->{$ipset}, $clusterfw_conf, $fw_conf);
2879     }
2880 }
2881
2882 sub generate_ipset {
2883     my ($ipset_ruleset, $name, $options, $clusterfw_conf, $fw_conf) = @_;
2884
2885     die "duplicate ipset chain '$name'\n" if defined($ipset_ruleset->{$name});
2886
2887     $ipset_ruleset->{$name} = ["create $name list:set size 4"];
2888
2889     # remove duplicates
2890     my $nethash = {};
2891     foreach my $entry (@$options) {
2892         next if $entry->{errors}; # skip entries with errors
2893         eval {
2894             my ($cidr, $ipversion);
2895             if ($entry->{cidr} =~ m/^${ip_alias_pattern}$/) {
2896                 ($cidr, $ipversion) = resolve_alias($clusterfw_conf, $fw_conf, $entry->{cidr});
2897             } else {
2898                 ($cidr, $ipversion) = parse_ip_or_cidr($entry->{cidr});
2899             }
2900             #http://backreference.org/2013/03/01/ipv6-address-normalization/
2901             if ($ipversion == 6) {
2902                 my $ipv6 = inet_pton(AF_INET6, lc($cidr));
2903                 $cidr = inet_ntop(AF_INET6, $ipv6);
2904                 $cidr =~ s|/128$||;
2905             } else {
2906                 $cidr =~ s|/32$||;
2907             }
2908
2909             $nethash->{$ipversion}->{$cidr} = { cidr => $cidr, nomatch => $entry->{nomatch} };
2910         };
2911         warn $@ if $@;
2912     }
2913
2914     foreach my $ipversion (sort keys %$nethash) {
2915         my $data = $nethash->{$ipversion};
2916         my $subname = "$name-v$ipversion";
2917
2918         my $hashsize = scalar(@$options);
2919         if ($hashsize <= 64) {
2920             $hashsize = 64;
2921         } else {
2922             $hashsize = round_powerof2($hashsize);
2923         }
2924
2925         my $family = $ipversion == "6" ? "inet6" : "inet";
2926
2927         $ipset_ruleset->{$subname} = ["create $subname hash:net family $family hashsize $hashsize maxelem $hashsize"];
2928
2929         foreach my $cidr (sort keys %$data) {
2930             my $entry = $data->{$cidr};
2931
2932             my $cmd = "add $subname $cidr";
2933             if ($entry->{nomatch}) {
2934                 if ($feature_ipset_nomatch) {
2935                     push @{$ipset_ruleset->{$subname}}, "$cmd nomatch";
2936                 } else {
2937                     warn "ignore !$cidr - nomatch not supported by kernel\n";
2938                 }
2939             } else {
2940                 push @{$ipset_ruleset->{$subname}}, $cmd;
2941             }
2942         }
2943
2944         push @{$ipset_ruleset->{$name}}, "add $name $subname";
2945     }
2946 }
2947
2948 sub round_powerof2 {
2949     my ($int) = @_;
2950
2951     $int--;
2952     $int |= $int >> $_ foreach (1,2,4,8,16);
2953     return ++$int;
2954 }
2955
2956 sub load_clusterfw_conf {
2957     my ($filename, $verbose) = @_;
2958
2959     $filename = $clusterfw_conf_filename if !defined($filename);
2960
2961     my $cluster_conf = {};
2962     if (my $fh = IO::File->new($filename, O_RDONLY)) {
2963         $cluster_conf = parse_clusterfw_config($filename, $fh, $verbose);
2964     }
2965
2966     return $cluster_conf;
2967 }
2968
2969 sub save_clusterfw_conf {
2970     my ($cluster_conf) = @_;
2971
2972     my $raw = '';
2973
2974     my $options = $cluster_conf->{options};
2975     $raw .= &$format_options($options) if $options && scalar(keys %$options);
2976
2977     my $aliases = $cluster_conf->{aliases};
2978     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
2979
2980     $raw .= &$format_ipsets($cluster_conf) if $cluster_conf->{ipset};
2981  
2982     my $rules = $cluster_conf->{rules};
2983     if ($rules && scalar(@$rules)) {
2984         $raw .= "[RULES]\n\n";
2985         $raw .= &$format_rules($rules, 1);
2986         $raw .= "\n";
2987     }
2988
2989     if ($cluster_conf->{groups}) {
2990         foreach my $group (sort keys %{$cluster_conf->{groups}}) {
2991             my $rules = $cluster_conf->{groups}->{$group};
2992             if (my $comment = $cluster_conf->{group_comments}->{$group}) {
2993                 my $utf8comment = encode('utf8', $comment);
2994                 $raw .= "[group $group] # $utf8comment\n\n";
2995             } else {
2996                 $raw .= "[group $group]\n\n";
2997             }
2998
2999             $raw .= &$format_rules($rules, 0);
3000             $raw .= "\n";
3001         }
3002     }
3003
3004     mkdir $pvefw_conf_dir;
3005     PVE::Tools::file_set_contents($clusterfw_conf_filename, $raw);
3006 }
3007
3008 sub load_hostfw_conf {
3009     my ($cluster_conf, $filename, $verbose) = @_;
3010
3011     $filename = $hostfw_conf_filename if !defined($filename);
3012
3013     my $hostfw_conf = {};
3014     if (my $fh = IO::File->new($filename, O_RDONLY)) {
3015         $hostfw_conf = parse_hostfw_config($filename, $fh, $cluster_conf, $verbose);
3016     }
3017     return $hostfw_conf;
3018 }
3019
3020 sub save_hostfw_conf {
3021     my ($hostfw_conf) = @_;
3022
3023     my $raw = '';
3024
3025     my $options = $hostfw_conf->{options};
3026     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3027
3028     my $rules = $hostfw_conf->{rules};
3029     if ($rules && scalar(@$rules)) {
3030         $raw .= "[RULES]\n\n";
3031         $raw .= &$format_rules($rules, 1);
3032         $raw .= "\n";
3033     }
3034
3035     PVE::Tools::file_set_contents($hostfw_conf_filename, $raw);
3036 }
3037
3038 sub compile {
3039     my ($cluster_conf, $hostfw_conf, $vmdata, $verbose) = @_;
3040
3041     my $vmfw_configs;
3042
3043     if ($vmdata) { # test mode
3044         my $testdir = $vmdata->{testdir} || die "no test directory specified";
3045         my $filename = "$testdir/cluster.fw";
3046         $cluster_conf = load_clusterfw_conf($filename, $verbose);
3047
3048         $filename = "$testdir/host.fw";
3049         $hostfw_conf = load_hostfw_conf($cluster_conf, $filename, $verbose);
3050
3051         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, $testdir, $verbose);
3052     } else { # normal operation
3053         $cluster_conf = load_clusterfw_conf(undef, $verbose) if !$cluster_conf;
3054
3055         $hostfw_conf = load_hostfw_conf($cluster_conf, undef, $verbose) if !$hostfw_conf;
3056
3057         $vmdata = read_local_vm_config();
3058         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, undef, $verbose);
3059     }
3060
3061     my ($ruleset, $ipset_ruleset) = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, 4, $verbose);
3062     my ($rulesetv6) = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, 6, $verbose);
3063
3064     return ($ruleset, $ipset_ruleset, $rulesetv6);
3065 }
3066
3067 sub compile_iptables_filter {
3068     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $ipversion, $verbose) = @_;
3069
3070     $cluster_conf->{ipset}->{venet0} = [];
3071     my $venet0_ipset_chain = compute_ipset_chain_name(0, 'venet0');
3072
3073     my $localnet;
3074     if ($cluster_conf->{aliases}->{local_network}) {
3075         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
3076     } else {
3077         $localnet = local_network() || '127.0.0.0/8';
3078         $cluster_conf->{aliases}->{local_network} = { cidr => $localnet };
3079     }
3080
3081     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
3082
3083     return ({}, {}) if !$cluster_conf->{options}->{enable};
3084
3085     my $ruleset = {};
3086
3087     ruleset_create_chain($ruleset, "PVEFW-INPUT");
3088     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
3089
3090     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
3091
3092     my $hostfw_options = $hostfw_conf->{options} || {};
3093
3094     # fixme: what log level should we use here?
3095     my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
3096
3097     ruleset_chain_add_conn_filters($ruleset, "PVEFW-FORWARD", "ACCEPT");
3098
3099
3100     ruleset_create_chain($ruleset, "PVEFW-VENET-OUT");
3101     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-i venet0 -m set --match-set ${venet0_ipset_chain} src -j PVEFW-VENET-OUT");
3102     ruleset_addrule($ruleset, "PVEFW-INPUT", "-i venet0 -m set --match-set ${venet0_ipset_chain} src -j PVEFW-VENET-OUT");
3103
3104     ruleset_create_chain($ruleset, "PVEFW-FWBR-IN");
3105     ruleset_chain_add_input_filters($ruleset, "PVEFW-FWBR-IN", $hostfw_options, $cluster_conf, $ipversion, $loglevel);
3106
3107     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-in fwln+ -j PVEFW-FWBR-IN");
3108
3109     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
3110     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-out fwln+ -j PVEFW-FWBR-OUT");
3111
3112     ruleset_create_chain($ruleset, "PVEFW-VENET-IN");
3113     ruleset_chain_add_input_filters($ruleset, "PVEFW-VENET-IN", $hostfw_options, $cluster_conf, $ipversion, $loglevel);
3114
3115     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-o venet0 -m set --match-set ${venet0_ipset_chain} dst -j PVEFW-VENET-IN");
3116
3117     generate_std_chains($ruleset, $hostfw_options, $ipversion);
3118
3119     my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
3120
3121     my $ipset_ruleset = {};
3122
3123     # currently pveproxy don't works with ipv6, so let's generate host fw ipv4 only for the moment
3124     if ($hostfw_enable && ($ipversion == 4)) {
3125         eval { enable_host_firewall($ruleset, $hostfw_conf, $cluster_conf, $ipversion); };
3126         warn $@ if $@; # just to be sure - should not happen
3127     }
3128
3129     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "-o venet0 -m set --match-set ${venet0_ipset_chain} dst -j PVEFW-VENET-IN");
3130
3131     # generate firewall rules for QEMU VMs
3132     foreach my $vmid (keys %{$vmdata->{qemu}}) {
3133         eval {
3134             my $conf = $vmdata->{qemu}->{$vmid};
3135             my $vmfw_conf = $vmfw_configs->{$vmid};
3136             return if !$vmfw_conf;
3137
3138             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf);
3139
3140             foreach my $netid (keys %$conf) {
3141                 next if $netid !~ m/^net(\d+)$/;
3142                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3143                 next if !$net->{firewall};
3144                 my $iface = "tap${vmid}i$1";
3145
3146                 my $macaddr = $net->{macaddr};
3147                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3148                                              $vmfw_conf, $vmid, 'IN', $ipversion);
3149                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3150                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
3151             }
3152         };
3153         warn $@ if $@; # just to be sure - should not happen
3154     }
3155
3156     # generate firewall rules for OpenVZ containers
3157     foreach my $vmid (keys %{$vmdata->{openvz}}) {
3158         eval {
3159             my $conf = $vmdata->{openvz}->{$vmid};
3160
3161             my $vmfw_conf = $vmfw_configs->{$vmid};
3162             return if !$vmfw_conf;
3163
3164             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf);
3165
3166             if ($vmfw_conf->{options}->{enable}) {
3167                 if ($conf->{ip_address} && $conf->{ip_address}->{value}) {
3168                     my $ip = $conf->{ip_address}->{value};
3169                     $ip =~ s/\s+/,/g;
3170
3171                     my @ips = ();
3172
3173                     foreach my $singleip (split(',', $ip)) {
3174                         my $singleip_ver = parse_address_list($singleip); # make sure we have a valid $ip list
3175                         push @{$cluster_conf->{ipset}->{venet0}}, { cidr => $singleip };
3176                         push @ips, $singleip if $singleip_ver == $ipversion;
3177                     }
3178
3179                     if (scalar(@ips)) {
3180                         my $ip_list = join(',', @ips);
3181                         generate_venet_rules_direction($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip_list, 'IN', $ipversion);
3182                         generate_venet_rules_direction($ruleset, $cluster_conf, $vmfw_conf, $vmid, $ip_list, 'OUT', $ipversion);
3183                     }
3184                 }
3185             }
3186
3187             if ($conf->{netif} && $conf->{netif}->{value}) {
3188                 my $netif = PVE::OpenVZ::parse_netif($conf->{netif}->{value});
3189                 foreach my $netid (keys %$netif) {
3190                     my $d = $netif->{$netid};
3191                     my $bridge = $d->{bridge};
3192                     next if !$bridge || $bridge !~ m/^vmbr\d+(v(\d+))?f$/; # firewall enabled ?
3193                     my $macaddr = $d->{mac};
3194                     my $iface = $d->{host_ifname};
3195                     generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3196                                                  $vmfw_conf, $vmid, 'IN', $ipversion);
3197                     generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3198                                                  $vmfw_conf, $vmid, 'OUT', $ipversion);
3199                 }
3200             }
3201         };
3202         warn $@ if $@; # just to be sure - should not happen
3203     }
3204
3205     if(ruleset_chain_exist($ruleset, "PVEFW-IPS")){
3206         ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED -j PVEFW-IPS");
3207     }
3208
3209     generate_ipset_chains($ipset_ruleset, undef, $cluster_conf);
3210
3211     return ($ruleset, $ipset_ruleset);
3212 }
3213
3214 sub get_ruleset_status {
3215     my ($ruleset, $active_chains, $digest_fn, $verbose) = @_;
3216
3217     my $statushash = {};
3218
3219     foreach my $chain (sort keys %$ruleset) {
3220         my $sig = &$digest_fn($ruleset->{$chain});
3221
3222         $statushash->{$chain}->{sig} = $sig;
3223
3224         my $oldsig = $active_chains->{$chain};
3225         if (!defined($oldsig)) {
3226             $statushash->{$chain}->{action} = 'create';
3227         } else {
3228             if ($oldsig eq $sig) {
3229                 $statushash->{$chain}->{action} = 'exists';
3230             } else {
3231                 $statushash->{$chain}->{action} = 'update';
3232             }
3233         }
3234         print "$statushash->{$chain}->{action} $chain ($sig)\n" if $verbose;
3235         foreach my $cmd (@{$ruleset->{$chain}}) {
3236             print "\t$cmd\n" if $verbose;
3237         }
3238     }
3239
3240     foreach my $chain (sort keys %$active_chains) {
3241         if (!defined($ruleset->{$chain})) {
3242             my $sig = $active_chains->{$chain};
3243             $statushash->{$chain}->{action} = 'delete';
3244             $statushash->{$chain}->{sig} = $sig;
3245             print "delete $chain ($sig)\n" if $verbose;
3246         }
3247     }
3248
3249     return $statushash;
3250 }
3251
3252 sub print_sig_rule {
3253     my ($chain, $sig) = @_;
3254
3255     # We just use this to store a SHA1 checksum used to detect changes
3256     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
3257 }
3258
3259 sub get_ruleset_cmdlist {
3260     my ($ruleset, $verbose, $iptablescmd) = @_;
3261
3262     my $cmdlist = "*filter\n"; # we pass this to iptables-restore;
3263
3264     my ($active_chains, $hooks) = iptables_get_chains($iptablescmd);
3265     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest, $verbose);
3266
3267     # create missing chains first
3268     foreach my $chain (sort keys %$ruleset) {
3269         my $stat = $statushash->{$chain};
3270         die "internal error" if !$stat;
3271         next if $stat->{action} ne 'create';
3272
3273         $cmdlist .= ":$chain - [0:0]\n";
3274     }
3275
3276     foreach my $h (qw(INPUT OUTPUT FORWARD)) {
3277         my $chain = "PVEFW-$h";
3278         if ($ruleset->{$chain} && !$hooks->{$h}) {
3279             $cmdlist .= "-A $h -j $chain\n";
3280         }
3281     }
3282
3283     foreach my $chain (sort keys %$ruleset) {
3284         my $stat = $statushash->{$chain};
3285         die "internal error" if !$stat;
3286
3287         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
3288             $cmdlist .= "-F $chain\n";
3289             foreach my $cmd (@{$ruleset->{$chain}}) {
3290                 $cmdlist .= "$cmd\n";
3291             }
3292             $cmdlist .= print_sig_rule($chain, $stat->{sig});
3293         } elsif ($stat->{action} eq 'delete') {
3294             die "internal error"; # this should not happen
3295         } elsif ($stat->{action} eq 'exists') {
3296             # do nothing
3297         } else {
3298             die "internal error - unknown status '$stat->{action}'";
3299         }
3300     }
3301
3302     foreach my $chain (keys %$statushash) {
3303         next if $statushash->{$chain}->{action} ne 'delete';
3304         $cmdlist .= "-F $chain\n";
3305     }
3306     foreach my $chain (keys %$statushash) {
3307         next if $statushash->{$chain}->{action} ne 'delete';
3308         next if $chain eq 'PVEFW-INPUT';
3309         next if $chain eq 'PVEFW-OUTPUT';
3310         next if $chain eq 'PVEFW-FORWARD';
3311         $cmdlist .= "-X $chain\n";
3312     }
3313
3314     my $changes = $cmdlist ne "*filter\n" ? 1 : 0;
3315
3316     $cmdlist .= "COMMIT\n";
3317
3318     return wantarray ? ($cmdlist, $changes) : $cmdlist;
3319 }
3320
3321 sub get_ipset_cmdlist {
3322     my ($ruleset, $verbose) = @_;
3323
3324     my $cmdlist = "";
3325
3326     my $delete_cmdlist = "";
3327
3328     my $active_chains = ipset_get_chains();
3329     my $statushash = get_ruleset_status($ruleset, $active_chains, \&ipset_chain_digest, $verbose);
3330
3331     # remove stale _swap chains
3332     foreach my $chain (keys %$active_chains) {
3333         if ($chain =~ m/^PVEFW-\S+_swap$/) {
3334             $cmdlist .= "destroy $chain\n";
3335         }
3336     }
3337
3338     # create -v4 and -v6 chains first
3339     foreach my $chain (keys %$ruleset) {
3340         next if $chain !~ m/-v[46]$/;
3341         my $stat = $statushash->{$chain};
3342         die "internal error" if !$stat;
3343
3344         if ($stat->{action} eq 'create') {
3345             foreach my $cmd (@{$ruleset->{$chain}}) {
3346                 $cmdlist .= "$cmd\n";
3347             }
3348         }
3349     }
3350
3351     # then create list chains which use above -v4 and -v6 chains
3352     foreach my $chain (keys %$ruleset) {
3353         next if $chain =~ m/-v[46]$/;
3354         my $stat = $statushash->{$chain};
3355         die "internal error" if !$stat;
3356
3357         if ($stat->{action} eq 'create') {
3358             foreach my $cmd (@{$ruleset->{$chain}}) {
3359                 $cmdlist .= "$cmd\n";
3360             }
3361         }
3362     }
3363
3364     foreach my $chain (keys %$ruleset) {
3365         my $stat = $statushash->{$chain};
3366         die "internal error" if !$stat;
3367
3368         if ($stat->{action} eq 'update') {
3369             my $chain_swap = $chain."_swap";
3370
3371             foreach my $cmd (@{$ruleset->{$chain}}) {
3372                 $cmd =~ s/$chain/$chain_swap/;
3373                 $cmdlist .= "$cmd\n";
3374             }
3375             $cmdlist .= "swap $chain_swap $chain\n";
3376             $cmdlist .= "flush $chain_swap\n";
3377             $cmdlist .= "destroy $chain_swap\n";
3378         }
3379     }
3380
3381     # remove unused list chains first
3382     foreach my $chain (keys %$statushash) {
3383         next if $statushash->{$chain}->{action} ne 'delete';
3384         next if $chain !~ m/-v[46]$/;
3385
3386         $delete_cmdlist .= "flush $chain\n";
3387         $delete_cmdlist .= "destroy $chain\n";
3388     }
3389
3390     # the remove unused -v4 -v6 chains
3391     foreach my $chain (keys %$statushash) {
3392         next if $statushash->{$chain}->{action} ne 'delete';
3393         next if $chain =~ m/-v[46]$/;
3394
3395         $delete_cmdlist .= "flush $chain\n";
3396         $delete_cmdlist .= "destroy $chain\n";
3397     }
3398
3399     my $changes = ($cmdlist || $delete_cmdlist) ? 1 : 0;
3400
3401     return ($cmdlist, $delete_cmdlist, $changes);
3402 }
3403
3404 sub apply_ruleset {
3405     my ($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6, $verbose) = @_;
3406
3407     enable_bridge_firewall();
3408
3409     my ($ipset_create_cmdlist, $ipset_delete_cmdlist, $ipset_changes) =
3410         get_ipset_cmdlist($ipset_ruleset, undef, $verbose);
3411
3412     my ($cmdlist, $changes) = get_ruleset_cmdlist($ruleset, $verbose);
3413     my ($cmdlistv6, $changesv6) = get_ruleset_cmdlist($rulesetv6, $verbose, "ip6tables");
3414
3415     if ($verbose) {
3416         if ($ipset_changes) {
3417             print "ipset changes:\n";
3418             print $ipset_create_cmdlist if $ipset_create_cmdlist;
3419             print $ipset_delete_cmdlist if $ipset_delete_cmdlist;
3420         }
3421
3422         if ($changes) {
3423             print "iptables changes:\n";
3424             print $cmdlist;
3425         }
3426
3427         if ($changesv6) {
3428             print "ip6tables changes:\n";
3429             print $cmdlistv6;
3430         }
3431     }
3432
3433     my $tmpfile = "$pve_fw_status_dir/ipsetcmdlist1";
3434     PVE::Tools::file_set_contents($tmpfile, $ipset_create_cmdlist || '');
3435
3436     ipset_restore_cmdlist($ipset_create_cmdlist);
3437
3438     $tmpfile = "$pve_fw_status_dir/ip4cmdlist";
3439     PVE::Tools::file_set_contents($tmpfile, $cmdlist || '');
3440
3441     iptables_restore_cmdlist($cmdlist);
3442
3443     $tmpfile = "$pve_fw_status_dir/ip6cmdlist";
3444     PVE::Tools::file_set_contents($tmpfile, $cmdlistv6 || '');
3445
3446     ip6tables_restore_cmdlist($cmdlistv6);
3447
3448     $tmpfile = "$pve_fw_status_dir/ipsetcmdlist2";
3449     PVE::Tools::file_set_contents($tmpfile, $ipset_delete_cmdlist || '');
3450
3451     ipset_restore_cmdlist($ipset_delete_cmdlist) if $ipset_delete_cmdlist;
3452
3453     # test: re-read status and check if everything is up to date
3454     my $active_chains = iptables_get_chains();
3455     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest, 0);
3456
3457     my $errors;
3458     foreach my $chain (sort keys %$ruleset) {
3459         my $stat = $statushash->{$chain};
3460         if ($stat->{action} ne 'exists') {
3461             warn "unable to update chain '$chain'\n";
3462             $errors = 1;
3463         }
3464     }
3465
3466     my $active_chainsv6 = iptables_get_chains("ip6tables");
3467     my $statushashv6 = get_ruleset_status($rulesetv6, $active_chainsv6, \&iptables_chain_digest, 0);
3468
3469     foreach my $chain (sort keys %$rulesetv6) {
3470         my $stat = $statushashv6->{$chain};
3471         if ($stat->{action} ne 'exists') {
3472             warn "unable to update chain '$chain'\n";
3473             $errors = 1;
3474         }
3475     }
3476
3477     die "unable to apply firewall changes\n" if $errors;
3478
3479     update_nf_conntrack_max($hostfw_conf);
3480
3481     update_nf_conntrack_tcp_timeout_established($hostfw_conf);
3482
3483 }
3484
3485 sub update_nf_conntrack_max {
3486     my ($hostfw_conf) = @_;
3487
3488     my $max = 65536; # reasonable default
3489
3490     my $options = $hostfw_conf->{options} || {};
3491
3492     if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
3493         $max = $options->{nf_conntrack_max};
3494         $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
3495     }
3496
3497     my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
3498     my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
3499
3500     my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
3501
3502     if ($current != $max) {
3503         my $hashsize = int($max/4);
3504         PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
3505         PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
3506     }
3507 }
3508
3509 sub update_nf_conntrack_tcp_timeout_established {
3510     my ($hostfw_conf) = @_;
3511
3512     my $options = $hostfw_conf->{options} || {};
3513
3514     my $value = defined($options->{nf_conntrack_tcp_timeout_established}) ? $options->{nf_conntrack_tcp_timeout_established} : 432000;
3515
3516     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_established", $value);
3517 }
3518
3519 sub remove_pvefw_chains {
3520
3521     PVE::Firewall::remove_pvefw_chains_iptables("iptables");
3522     PVE::Firewall::remove_pvefw_chains_iptables("ip6tables");
3523     PVE::Firewall::remove_pvefw_chains_ipset();
3524
3525 }
3526
3527 sub remove_pvefw_chains_iptables {
3528     my ($iptablescmd) = @_;
3529
3530     my ($chash, $hooks) = iptables_get_chains($iptablescmd);
3531     my $cmdlist = "*filter\n";
3532
3533     foreach my $h (qw(INPUT OUTPUT FORWARD)) {
3534         if ($hooks->{$h}) {
3535             $cmdlist .= "-D $h -j PVEFW-$h\n";
3536         }
3537     }
3538
3539     foreach my $chain (keys %$chash) {
3540         $cmdlist .= "-F $chain\n";
3541     }
3542
3543     foreach my $chain (keys %$chash) {
3544         $cmdlist .= "-X $chain\n";
3545     }
3546     $cmdlist .= "COMMIT\n";
3547
3548     if($iptablescmd eq "ip6tables") {
3549         ip6tables_restore_cmdlist($cmdlist);
3550     } else {
3551         iptables_restore_cmdlist($cmdlist);
3552     }
3553 }
3554
3555 sub remove_pvefw_chains_ipset {
3556
3557     my $ipset_chains = ipset_get_chains();
3558
3559     my $sub_cmdlist = "";
3560     my $cmdlist = "";
3561  
3562     foreach my $chain (keys %$ipset_chains) {
3563         if ($chain =~ m/^PVEFW-\S+\-(v4|v6)$/) {
3564            $sub_cmdlist .= "flush $chain\n";
3565            $sub_cmdlist .= "destroy $chain\n";
3566         }else{
3567            $cmdlist .= "flush $chain\n";
3568            $cmdlist .= "destroy $chain\n";
3569         }
3570     }
3571
3572     $cmdlist .= $sub_cmdlist;
3573
3574     ipset_restore_cmdlist($cmdlist) if $cmdlist;
3575 }
3576
3577 sub init {
3578     my $cluster_conf = load_clusterfw_conf();
3579     my $cluster_options = $cluster_conf->{options};
3580     my $enable = $cluster_options->{enable};
3581
3582     return if !$enable;
3583
3584     # load required modules here
3585 }
3586
3587 sub update {
3588     my $code = sub {
3589
3590         my $cluster_conf = load_clusterfw_conf();
3591         my $cluster_options = $cluster_conf->{options};
3592
3593         if (!$cluster_options->{enable}) {
3594             PVE::Firewall::remove_pvefw_chains();
3595             return;
3596         }
3597
3598         my $hostfw_conf = load_hostfw_conf();
3599
3600         my ($ruleset, $ipset_ruleset, $rulesetv6) = compile($cluster_conf, $hostfw_conf);
3601
3602         apply_ruleset($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6);
3603     };
3604