src/PVE/Firewall.pm

   1 package PVE::Firewall;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Digest::SHA;
   7 use Encode;
   8 use File::Basename;
   9 use File::Path;
  10 use IO::File;
  11 use Net::IP;
  12 use POSIX;
  13 use Socket qw(AF_INET AF_INET6 inet_ntop inet_pton);
  14 use Storable qw(dclone);
  15
  16 use PVE::Cluster;
  17 use PVE::Corosync;
  18 use PVE::Exception qw(raise raise_param_exc);
  19 use PVE::INotify;
  20 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  21 use PVE::Network;
  22 use PVE::ProcFSTools;
  23 use PVE::SafeSyslog;
  24 use PVE::Tools qw($IPV4RE $IPV6RE);
  25 use PVE::Tools qw(run_command lock_file dir_glob_foreach);
  26
  27 my $pvefw_conf_dir = "/etc/pve/firewall";
  28 my $clusterfw_conf_filename = "$pvefw_conf_dir/cluster.fw";
  29
  30 # dynamically include PVE::QemuServer and PVE::LXC
  31 # to avoid dependency problems
  32 my $have_qemu_server;
  33 eval {
  34     require PVE::QemuServer;
  35     require PVE::QemuConfig;
  36     $have_qemu_server = 1;
  37 };
  38
  39 my $have_lxc;
  40 eval {
  41     require PVE::LXC;
  42     $have_lxc = 1;
  43 };
  44
  45 my $pve_fw_status_dir = "/var/lib/pve-firewall";
  46
  47 mkdir $pve_fw_status_dir; # make sure this exists
  48
  49 my $security_group_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  50 my $ipset_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  51 our $ip_alias_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  52
  53 my $max_alias_name_length = 64;
  54 my $max_ipset_name_length = 64;
  55 my $max_group_name_length = 18;
  56
  57 my $PROTOCOLS_WITH_PORTS = {
  58     udp => 1,     17 => 1,
  59     udplite => 1, 136 => 1,
  60     tcp => 1,     6 => 1,
  61     dccp => 1,    33 => 1,
  62     sctp => 1,    132 => 1,
  63 };
  64
  65 PVE::JSONSchema::register_format('IPorCIDR', \&pve_verify_ip_or_cidr);
  66 sub pve_verify_ip_or_cidr {
  67     my ($cidr, $noerr) = @_;
  68
  69     if ($cidr =~ m!^(?:$IPV6RE|$IPV4RE)(/(\d+))?$!) {
  70         return $cidr if Net::IP->new($cidr);
  71         return undef if $noerr;
  72         die Net::IP::Error() . "\n";
  73     }
  74     return undef if $noerr;
  75     die "value does not look like a valid IP address or CIDR network\n";
  76 }
  77
  78 PVE::JSONSchema::register_format('IPorCIDRorAlias', \&pve_verify_ip_or_cidr_or_alias);
  79 sub pve_verify_ip_or_cidr_or_alias {
  80     my ($cidr, $noerr) = @_;
  81
  82     return if $cidr =~ m/^(?:$ip_alias_pattern)$/;
  83
  84     return pve_verify_ip_or_cidr($cidr, $noerr);
  85 }
  86
  87 PVE::JSONSchema::register_standard_option('ipset-name', {
  88     description => "IP set name.",
  89     type => 'string',
  90     pattern => $ipset_name_pattern,
  91     minLength => 2,
  92     maxLength => $max_ipset_name_length,
  93 });
  94
  95 PVE::JSONSchema::register_standard_option('pve-fw-alias', {
  96     description => "Alias name.",
  97     type => 'string',
  98     pattern => $ip_alias_pattern,
  99     minLength => 2,
 100     maxLength => $max_alias_name_length,
 101 });
 102
 103 PVE::JSONSchema::register_standard_option('pve-fw-loglevel' => {
 104     description => "Log level.",
 105     type => 'string',
 106     enum => ['emerg', 'alert', 'crit', 'err', 'warning', 'notice', 'info', 'debug', 'nolog'],
 107     optional => 1,
 108 });
 109
 110 PVE::JSONSchema::register_standard_option('pve-security-group-name', {
 111     description => "Security Group name.",
 112     type => 'string',
 113     pattern => $security_group_name_pattern,
 114     minLength => 2,
 115     maxLength => $max_group_name_length,
 116 });
 117
 118 my $feature_ipset_nomatch = 0;
 119 eval  {
 120     my (undef, undef, $release) = POSIX::uname();
 121     if ($release =~ m/^(\d+)\.(\d+)\.\d+-/) {
 122         my ($major, $minor) = ($1, $2);
 123         $feature_ipset_nomatch = 1 if ($major > 3) ||
 124             ($major == 3 && $minor >= 7);
 125     }
 126
 127 };
 128
 129 my $nodename = PVE::INotify::nodename();
 130 my $hostfw_conf_filename = "/etc/pve/nodes/$nodename/host.fw";
 131
 132 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
 133
 134 my $default_log_level = 'nolog'; # avoid logs by default
 135 my $global_log_ratelimit = '--limit 1/sec';
 136
 137 my $log_level_hash = {
 138     debug => 7,
 139     info => 6,
 140     notice => 5,
 141     warning => 4,
 142     err => 3,
 143     crit => 2,
 144     alert => 1,
 145     emerg => 0,
 146 };
 147
 148 my $verbose = 0;
 149 sub set_verbose {
 150     $verbose = shift;
 151 }
 152
 153 # %rule
 154 #
 155 # name => optional
 156 # enable => [0|1]
 157 # action =>
 158 # proto =>
 159 # sport => port[,port[,port]].. or port:port
 160 # dport => port[,port[,port]].. or port:port
 161 # log => optional, loglevel
 162 # logmsg => optional, logmsg - overwrites default
 163 # iface_in => incomin interface
 164 # iface_out => outgoing interface
 165 # match => optional, overwrites generation of match
 166 # target => optional, overwrites action
 167
 168 # we need to overwrite some macros for ipv6
 169 my $pve_ipv6fw_macros = {
 170     'Ping' => [
 171         { action => 'PARAM', proto => 'icmpv6', dport => 'echo-request' },
 172     ],
 173     'NeighborDiscovery' => [
 174         "IPv6 neighbor solicitation, neighbor and router advertisement",
 175         { action => 'PARAM', proto => 'icmpv6', dport => 'router-solicitation' },
 176         { action => 'PARAM', proto => 'icmpv6', dport => 'router-advertisement' },
 177         { action => 'PARAM', proto => 'icmpv6', dport => 'neighbor-solicitation' },
 178         { action => 'PARAM', proto => 'icmpv6', dport => 'neighbor-advertisement' },
 179     ],
 180     'DHCPv6' => [
 181         "DHCPv6 traffic",
 182         { action => 'PARAM', proto => 'udp', dport => '546:547', sport => '546:547' },
 183     ],
 184     'Trcrt' => [
 185         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 186         { action => 'PARAM', proto => 'icmpv6', dport => 'echo-request' },
 187     ],
 188  };
 189
 190 # imported/converted from: /usr/share/shorewall/macro.*
 191 my $pve_fw_macros = {
 192     'Amanda' => [
 193         "Amanda Backup",
 194         { action => 'PARAM', proto => 'udp', dport => '10080' },
 195         { action => 'PARAM', proto => 'tcp', dport => '10080' },
 196     ],
 197     'Auth' => [
 198         "Auth (identd) traffic",
 199         { action => 'PARAM', proto => 'tcp', dport => '113' },
 200     ],
 201     'BGP' => [
 202         "Border Gateway Protocol traffic",
 203         { action => 'PARAM', proto => 'tcp', dport => '179' },
 204     ],
 205     'BitTorrent' => [
 206         "BitTorrent traffic for BitTorrent 3.1 and earlier",
 207         { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
 208         { action => 'PARAM', proto => 'udp', dport => '6881' },
 209     ],
 210     'BitTorrent32' => [
 211         "BitTorrent traffic for BitTorrent 3.2 and later",
 212         { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
 213         { action => 'PARAM', proto => 'udp', dport => '6881' },
 214     ],
 215     'Ceph' => [
 216         "Ceph Storage Cluster traffic (Ceph Monitors, OSD & MDS Daemons)",
 217         # Legacy port for protocol v1
 218         { action => 'PARAM', proto => 'tcp', dport => '6789' },
 219         # New port for protocol v2
 220         { action => 'PARAM', proto => 'tcp', dport => '3300' },
 221         { action => 'PARAM', proto => 'tcp', dport => '6800:7300' },
 222     ],
 223     'CVS' => [
 224         "Concurrent Versions System pserver traffic",
 225         { action => 'PARAM', proto => 'tcp', dport => '2401' },
 226     ],
 227     'Citrix' => [
 228         "Citrix/ICA traffic (ICA, ICA Browser, CGP)",
 229         { action => 'PARAM', proto => 'tcp', dport => '1494' },
 230         { action => 'PARAM', proto => 'udp', dport => '1604' },
 231         { action => 'PARAM', proto => 'tcp', dport => '2598' },
 232     ],
 233     'DAAP' => [
 234         "Digital Audio Access Protocol traffic (iTunes, Rythmbox daemons)",
 235         { action => 'PARAM', proto => 'tcp', dport => '3689' },
 236         { action => 'PARAM', proto => 'udp', dport => '3689' },
 237     ],
 238     'DCC' => [
 239         "Distributed Checksum Clearinghouse spam filtering mechanism",
 240         { action => 'PARAM', proto => 'tcp', dport => '6277' },
 241     ],
 242     'DHCPfwd' => [
 243         "Forwarded DHCP traffic",
 244         { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
 245     ],
 246     'DNS' => [
 247         "Domain Name System traffic (upd and tcp)",
 248         { action => 'PARAM', proto => 'udp', dport => '53' },
 249         { action => 'PARAM', proto => 'tcp', dport => '53' },
 250     ],
 251     'Distcc' => [
 252         "Distributed Compiler service",
 253         { action => 'PARAM', proto => 'tcp', dport => '3632' },
 254     ],
 255     'FTP' => [
 256         "File Transfer Protocol",
 257         { action => 'PARAM', proto => 'tcp', dport => '21' },
 258     ],
 259     'Finger' => [
 260         "Finger protocol (RFC 742)",
 261         { action => 'PARAM', proto => 'tcp', dport => '79' },
 262     ],
 263     'GNUnet' => [
 264         "GNUnet secure peer-to-peer networking traffic",
 265         { action => 'PARAM', proto => 'tcp', dport => '2086' },
 266         { action => 'PARAM', proto => 'udp', dport => '2086' },
 267         { action => 'PARAM', proto => 'tcp', dport => '1080' },
 268         { action => 'PARAM', proto => 'udp', dport => '1080' },
 269     ],
 270     'GRE' => [
 271         "Generic Routing Encapsulation tunneling protocol",
 272         { action => 'PARAM', proto => '47' },
 273     ],
 274     'Git' => [
 275         "Git distributed revision control traffic",
 276         { action => 'PARAM', proto => 'tcp', dport => '9418' },
 277     ],
 278     'HKP' => [
 279         "OpenPGP HTTP key server protocol traffic",
 280         { action => 'PARAM', proto => 'tcp', dport => '11371' },
 281     ],
 282     'HTTP' => [
 283         "Hypertext Transfer Protocol (WWW)",
 284         { action => 'PARAM', proto => 'tcp', dport => '80' },
 285     ],
 286     'HTTPS' => [
 287         "Hypertext Transfer Protocol (WWW) over SSL",
 288         { action => 'PARAM', proto => 'tcp', dport => '443' },
 289     ],
 290     'ICPV2' => [
 291         "Internet Cache Protocol V2 (Squid) traffic",
 292         { action => 'PARAM', proto => 'udp', dport => '3130' },
 293     ],
 294     'ICQ' => [
 295         "AOL Instant Messenger traffic",
 296         { action => 'PARAM', proto => 'tcp', dport => '5190' },
 297     ],
 298     'IMAP' => [
 299         "Internet Message Access Protocol",
 300         { action => 'PARAM', proto => 'tcp', dport => '143' },
 301     ],
 302     'IMAPS' => [
 303         "Internet Message Access Protocol over SSL",
 304         { action => 'PARAM', proto => 'tcp', dport => '993' },
 305     ],
 306     'IPIP' => [
 307         "IPIP capsulation traffic",
 308         { action => 'PARAM', proto => '94' },
 309     ],
 310     'IPsec' => [
 311         "IPsec traffic",
 312         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 313         { action => 'PARAM', proto => '50' },
 314     ],
 315     'IPsecah' => [
 316         "IPsec authentication (AH) traffic",
 317         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 318         { action => 'PARAM', proto => '51' },
 319     ],
 320     'IPsecnat' => [
 321         "IPsec traffic and Nat-Traversal",
 322         { action => 'PARAM', proto => 'udp', dport => '500' },
 323         { action => 'PARAM', proto => 'udp', dport => '4500' },
 324         { action => 'PARAM', proto => '50' },
 325     ],
 326     'IRC' => [
 327         "Internet Relay Chat traffic",
 328         { action => 'PARAM', proto => 'tcp', dport => '6667' },
 329     ],
 330     'Jetdirect' => [
 331         "HP Jetdirect printing",
 332         { action => 'PARAM', proto => 'tcp', dport => '9100' },
 333     ],
 334     'L2TP' => [
 335         "Layer 2 Tunneling Protocol traffic",
 336         { action => 'PARAM', proto => 'udp', dport => '1701' },
 337     ],
 338     'LDAP' => [
 339         "Lightweight Directory Access Protocol traffic",
 340         { action => 'PARAM', proto => 'tcp', dport => '389' },
 341     ],
 342     'LDAPS' => [
 343         "Secure Lightweight Directory Access Protocol traffic",
 344         { action => 'PARAM', proto => 'tcp', dport => '636' },
 345     ],
 346     'MSNP' => [
 347         "Microsoft Notification Protocol",
 348         { action => 'PARAM', proto => 'tcp', dport => '1863' },
 349     ],
 350     'MSSQL' => [
 351         "Microsoft SQL Server",
 352         { action => 'PARAM', proto => 'tcp', dport => '1433' },
 353     ],
 354     'Mail' => [
 355         "Mail traffic (SMTP, SMTPS, Submission)",
 356         { action => 'PARAM', proto => 'tcp', dport => '25' },
 357         { action => 'PARAM', proto => 'tcp', dport => '465' },
 358         { action => 'PARAM', proto => 'tcp', dport => '587' },
 359     ],
 360     'MDNS' => [
 361         "Multicast DNS",
 362         { action => 'PARAM', proto => 'udp', dport => '5353' },
 363     ],
 364     'Munin' => [
 365         "Munin networked resource monitoring traffic",
 366         { action => 'PARAM', proto => 'tcp', dport => '4949' },
 367     ],
 368     'MySQL' => [
 369         "MySQL server",
 370         { action => 'PARAM', proto => 'tcp', dport => '3306' },
 371     ],
 372     'NNTP' => [
 373         "NNTP traffic (Usenet).",
 374         { action => 'PARAM', proto => 'tcp', dport => '119' },
 375     ],
 376     'NNTPS' => [
 377         "Encrypted NNTP traffic (Usenet)",
 378         { action => 'PARAM', proto => 'tcp', dport => '563' },
 379     ],
 380     'NTP' => [
 381         "Network Time Protocol (ntpd)",
 382         { action => 'PARAM', proto => 'udp', dport => '123' },
 383     ],
 384     'OSPF' => [
 385         "OSPF multicast traffic",
 386         { action => 'PARAM', proto => '89' },
 387     ],
 388     'OpenVPN' => [
 389         "OpenVPN traffic",
 390         { action => 'PARAM', proto => 'udp', dport => '1194' },
 391     ],
 392     'PCA' => [
 393         "Symantec PCAnywere (tm)",
 394         { action => 'PARAM', proto => 'udp', dport => '5632' },
 395         { action => 'PARAM', proto => 'tcp', dport => '5631' },
 396     ],
 397     'PMG' => [
 398         "Proxmox Mail Gateway web interface",
 399         { action => 'PARAM', proto => 'tcp', dport => '8006' },
 400     ],
 401     'POP3' => [
 402         "POP3 traffic",
 403         { action => 'PARAM', proto => 'tcp', dport => '110' },
 404     ],
 405     'POP3S' => [
 406         "Encrypted POP3 traffic",
 407         { action => 'PARAM', proto => 'tcp', dport => '995' },
 408     ],
 409     'PPtP' => [
 410         "Point-to-Point Tunneling Protocol",
 411         { action => 'PARAM', proto => '47' },
 412         { action => 'PARAM', proto => 'tcp', dport => '1723' },
 413     ],
 414     'Ping' => [
 415         "ICMP echo request",
 416         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 417     ],
 418     'PostgreSQL' => [
 419         "PostgreSQL server",
 420         { action => 'PARAM', proto => 'tcp', dport => '5432' },
 421     ],
 422     'Printer' => [
 423         "Line Printer protocol printing",
 424         { action => 'PARAM', proto => 'tcp', dport => '515' },
 425     ],
 426     'RDP' => [
 427         "Microsoft Remote Desktop Protocol traffic",
 428         { action => 'PARAM', proto => 'tcp', dport => '3389' },
 429     ],
 430     'RIP' => [
 431         "Routing Information Protocol (bidirectional)",
 432         { action => 'PARAM', proto => 'udp', dport => '520' },
 433     ],
 434     'RNDC' => [
 435         "BIND remote management protocol",
 436         { action => 'PARAM', proto => 'tcp', dport => '953' },
 437     ],
 438     'Razor' => [
 439         "Razor Antispam System",
 440         { action => 'PARAM', proto => 'tcp', dport => '2703' },
 441     ],
 442     'Rdate' => [
 443         "Remote time retrieval (rdate)",
 444         { action => 'PARAM', proto => 'tcp', dport => '37' },
 445     ],
 446     'Rsync' => [
 447         "Rsync server",
 448         { action => 'PARAM', proto => 'tcp', dport => '873' },
 449     ],
 450     'SANE' => [
 451         "SANE network scanning",
 452         { action => 'PARAM', proto => 'tcp', dport => '6566' },
 453     ],
 454     'SMB' => [
 455         "Microsoft SMB traffic",
 456         { action => 'PARAM', proto => 'udp', dport => '135,445' },
 457         { action => 'PARAM', proto => 'udp', dport => '137:139' },
 458         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
 459         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
 460     ],
 461     'SMBswat' => [
 462         "Samba Web Administration Tool",
 463         { action => 'PARAM', proto => 'tcp', dport => '901' },
 464     ],
 465     'SMTP' => [
 466         "Simple Mail Transfer Protocol",
 467         { action => 'PARAM', proto => 'tcp', dport => '25' },
 468     ],
 469     'SMTPS' => [
 470         "Encrypted Simple Mail Transfer Protocol",
 471         { action => 'PARAM', proto => 'tcp', dport => '465' },
 472     ],
 473     'SNMP' => [
 474         "Simple Network Management Protocol",
 475         { action => 'PARAM', proto => 'udp', dport => '161:162' },
 476         { action => 'PARAM', proto => 'tcp', dport => '161' },
 477     ],
 478     'SPAMD' => [
 479         "Spam Assassin SPAMD traffic",
 480         { action => 'PARAM', proto => 'tcp', dport => '783' },
 481     ],
 482     'SSH' => [
 483         "Secure shell traffic",
 484         { action => 'PARAM', proto => 'tcp', dport => '22' },
 485     ],
 486     'SVN' => [
 487         "Subversion server (svnserve)",
 488         { action => 'PARAM', proto => 'tcp', dport => '3690' },
 489     ],
 490     'SixXS' => [
 491         "SixXS IPv6 Deployment and Tunnel Broker",
 492         { action => 'PARAM', proto => 'tcp', dport => '3874' },
 493         { action => 'PARAM', proto => 'udp', dport => '3740' },
 494         { action => 'PARAM', proto => '41' },
 495         { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
 496     ],
 497     'Squid' => [
 498         "Squid web proxy traffic",
 499         { action => 'PARAM', proto => 'tcp', dport => '3128' },
 500     ],
 501     'Submission' => [
 502         "Mail message submission traffic",
 503         { action => 'PARAM', proto => 'tcp', dport => '587' },
 504     ],
 505     'Syslog' => [
 506         "Syslog protocol (RFC 5424) traffic",
 507         { action => 'PARAM', proto => 'udp', dport => '514' },
 508         { action => 'PARAM', proto => 'tcp', dport => '514' },
 509     ],
 510     'TFTP' => [
 511         "Trivial File Transfer Protocol traffic",
 512         { action => 'PARAM', proto => 'udp', dport => '69' },
 513     ],
 514     'Telnet' => [
 515         "Telnet traffic",
 516         { action => 'PARAM', proto => 'tcp', dport => '23' },
 517     ],
 518     'Telnets' => [
 519         "Telnet over SSL",
 520         { action => 'PARAM', proto => 'tcp', dport => '992' },
 521     ],
 522     'Time' => [
 523         "RFC 868 Time protocol",
 524         { action => 'PARAM', proto => 'tcp', dport => '37' },
 525     ],
 526     'Trcrt' => [
 527         "Traceroute (for up to 30 hops) traffic",
 528         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 529         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 530     ],
 531     'VNC' => [
 532         "VNC traffic for VNC display's 0 - 99",
 533         { action => 'PARAM', proto => 'tcp', dport => '5900:5999' },
 534     ],
 535     'VNCL' => [
 536         "VNC traffic from Vncservers to Vncviewers in listen mode",
 537         { action => 'PARAM', proto => 'tcp', dport => '5500' },
 538     ],
 539     'Web' => [
 540         "WWW traffic (HTTP and HTTPS)",
 541         { action => 'PARAM', proto => 'tcp', dport => '80' },
 542         { action => 'PARAM', proto => 'tcp', dport => '443' },
 543     ],
 544     'Webcache' => [
 545         "Web Cache/Proxy traffic (port 8080)",
 546         { action => 'PARAM', proto => 'tcp', dport => '8080' },
 547     ],
 548     'Webmin' => [
 549         "Webmin traffic",
 550         { action => 'PARAM', proto => 'tcp', dport => '10000' },
 551     ],
 552     'Whois' => [
 553         "Whois (nicname, RFC 3912) traffic",
 554         { action => 'PARAM', proto => 'tcp', dport => '43' },
 555     ],
 556 };
 557
 558 my $pve_fw_parsed_macros;
 559 my $pve_fw_macro_descr;
 560 my $pve_fw_macro_ipversion = {};
 561 my $pve_fw_preferred_macro_names = {};
 562
 563 my $FWACCEPTMARK_ON  = "0x80000000/0x80000000";
 564 my $FWACCEPTMARK_OFF = "0x00000000/0x80000000";
 565
 566 my $pve_std_chains = {};
 567 my $pve_std_chains_conf = {};
 568 $pve_std_chains_conf->{4} = {
 569     'PVEFW-SET-ACCEPT-MARK' => [
 570         { target => "-j MARK --set-mark $FWACCEPTMARK_ON" },
 571     ],
 572     'PVEFW-DropBroadcast' => [
 573         # same as shorewall 'Broadcast'
 574         # simply DROP BROADCAST/MULTICAST/ANYCAST
 575         # we can use this to reduce logging
 576         { action => 'DROP', dsttype => 'BROADCAST' },
 577         { action => 'DROP', dsttype => 'MULTICAST' },
 578         { action => 'DROP', dsttype => 'ANYCAST' },
 579         { action => 'DROP', dest => '224.0.0.0/4' },
 580     ],
 581     'PVEFW-reject' => [
 582         # same as shorewall 'reject'
 583         { action => 'DROP', dsttype => 'BROADCAST' },
 584         { action => 'DROP', source => '224.0.0.0/4' },
 585         { action => 'DROP', proto => 'icmp' },
 586         { match => '-p tcp', target => '-j REJECT --reject-with tcp-reset' },
 587         { match => '-p udp', target => '-j REJECT --reject-with icmp-port-unreachable' },
 588         { match => '-p icmp', target => '-j REJECT --reject-with icmp-host-unreachable' },
 589         { target => '-j REJECT --reject-with icmp-host-prohibited' },
 590     ],
 591     'PVEFW-Drop' => [
 592         # same as shorewall 'Drop', which is equal to DROP,
 593         # but REJECT/DROP some packages to reduce logging,
 594         # and ACCEPT critical ICMP types
 595         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 596         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 597         { action => 'PVEFW-DropBroadcast' },
 598         # ACCEPT critical ICMP types
 599         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 600         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 601         # Drop packets with INVALID state
 602         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 603         # Drop Microsoft SMB noise
 604         { action => 'DROP', proto => 'udp', dport => '135,445' },
 605         { action => 'DROP', proto => 'udp', dport => '137:139' },
 606         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 607         { action => 'DROP', proto => 'tcp', dport => '135,139,445' },
 608         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 609         # Drop new/NotSyn traffic so that it doesn't get logged
 610         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 611         # Drop DNS replies
 612         { action => 'DROP', proto => 'udp', sport => 53 },
 613     ],
 614     'PVEFW-Reject' => [
 615         # same as shorewall 'Reject', which is equal to Reject,
 616         # but REJECT/DROP some packages to reduce logging,
 617         # and ACCEPT critical ICMP types
 618         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 619         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 620         { action => 'PVEFW-DropBroadcast' },
 621         # ACCEPT critical ICMP types
 622         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 623         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 624         # Drop packets with INVALID state
 625         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 626         # Drop Microsoft SMB noise
 627         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445' },
 628         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
 629         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 630         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445' },
 631         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 632         # Drop new/NotSyn traffic so that it doesn't get logged
 633         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 634         # Drop DNS replies
 635         { action => 'DROP', proto => 'udp', sport => 53 },
 636     ],
 637     'PVEFW-tcpflags' => [
 638         # same as shorewall tcpflags action.
 639         # Packets arriving on this interface are checked for some illegal combinations of TCP flags
 640         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG', target => '-g PVEFW-logflags' },
 641         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE', target => '-g PVEFW-logflags' },
 642         { match => '-p tcp -m tcp --tcp-flags SYN,RST SYN,RST', target => '-g PVEFW-logflags' },
 643         { match => '-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN', target => '-g PVEFW-logflags' },
 644         { match => '-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN', target => '-g PVEFW-logflags' },
 645     ],
 646     'PVEFW-smurfs' => [
 647         # same as shorewall smurfs action
 648         # Filter packets for smurfs (packets with a broadcast address as the source).
 649         { match => '-s 0.0.0.0/32', target => '-j RETURN' }, # allow DHCP
 650         { match => '-m addrtype --src-type BROADCAST', target => '-g PVEFW-smurflog' },
 651         { match => '-s 224.0.0.0/4', target => '-g PVEFW-smurflog' },
 652     ],
 653     'PVEFW-smurflog' => [
 654         { action => 'DROP', logmsg => 'DROP: ' },
 655     ],
 656     'PVEFW-logflags' => [
 657         { action => 'DROP', logmsg => 'DROP: ' },
 658     ],
 659 };
 660
 661 $pve_std_chains_conf->{6} = {
 662     'PVEFW-SET-ACCEPT-MARK' => [
 663         { target => "-j MARK --set-mark $FWACCEPTMARK_ON" },
 664     ],
 665     'PVEFW-DropBroadcast' => [
 666         # same as shorewall 'Broadcast'
 667         # simply DROP BROADCAST/MULTICAST/ANYCAST
 668         # we can use this to reduce logging
 669         #{ action => 'DROP', dsttype => 'BROADCAST' }, #no broadcast in ipv6
 670         # ipv6 addrtype does not work with kernel 2.6.32
 671         #{ action => 'DROP', dsttype => 'MULTICAST' },
 672         #{ action => 'DROP', dsttype => 'ANYCAST' },
 673         { action => 'DROP', dest => 'ff00::/8' },
 674         #{ action => 'DROP', dest => '224.0.0.0/4' },
 675     ],
 676     'PVEFW-reject' => [
 677         { action => 'DROP', proto => 'icmpv6' },
 678         { match => '-p tcp', target => '-j REJECT --reject-with tcp-reset' },
 679         { match => '-p udp', target => '-j REJECT --reject-with icmp6-port-unreachable' },
 680         { target => '-j REJECT --reject-with icmp6-adm-prohibited' },
 681     ],
 682     'PVEFW-Drop' => [
 683         # same as shorewall 'Drop', which is equal to DROP,
 684         # but REJECT/DROP some packages to reduce logging,
 685         # and ACCEPT critical ICMP types
 686         { action => 'PVEFW-reject', proto => 'tcp', dport => '43' }, # REJECT 'auth'
 687         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 688         { action => 'PVEFW-DropBroadcast' },
 689         # ACCEPT critical ICMP types
 690         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
 691         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
 692         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
 693         # Drop packets with INVALID state
 694         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 695         # Drop Microsoft SMB noise
 696         { action => 'DROP', proto => 'udp', dport => '135,445' },
 697         { action => 'DROP', proto => 'udp', dport => '137:139'},
 698         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 699         { action => 'DROP', proto => 'tcp', dport => '135,139,445' },
 700         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 701         # Drop new/NotSyn traffic so that it doesn't get logged
 702         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 703         # Drop DNS replies
 704         { action => 'DROP', proto => 'udp', sport => 53 },
 705     ],
 706     'PVEFW-Reject' => [
 707         # same as shorewall 'Reject', which is equal to Reject,
 708         # but REJECT/DROP some packages to reduce logging,
 709         # and ACCEPT critical ICMP types
 710         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 711         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 712         { action => 'PVEFW-DropBroadcast' },
 713         # ACCEPT critical ICMP types
 714         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
 715         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
 716         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
 717         # Drop packets with INVALID state
 718         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 719         # Drop Microsoft SMB noise
 720         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445' },
 721         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139' },
 722         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 723         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445' },
 724         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 725         # Drop new/NotSyn traffic so that it doesn't get logged
 726         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 727         # Drop DNS replies
 728         { action => 'DROP', proto => 'udp', sport => 53 },
 729     ],
 730     'PVEFW-tcpflags' => [
 731         # same as shorewall tcpflags action.
 732         # Packets arriving on this interface are checked for some illegal combinations of TCP flags
 733         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG', target => '-g PVEFW-logflags' },
 734         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE', target => '-g PVEFW-logflags' },
 735         { match => '-p tcp -m tcp --tcp-flags SYN,RST SYN,RST', target => '-g PVEFW-logflags' },
 736         { match => '-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN', target => '-g PVEFW-logflags' },
 737         { match => '-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN', target => '-g PVEFW-logflags' },
 738     ],
 739     'PVEFW-logflags' => [
 740         { action => 'DROP', logmsg => 'DROP: ' },
 741     ],
 742 };
 743
 744 # iptables -p icmp -h
 745 my $icmp_type_names = {
 746     any => 1,
 747     'echo-reply' => 1,
 748     'destination-unreachable' => 1,
 749     'network-unreachable' => 1,
 750     'host-unreachable' => 1,
 751     'protocol-unreachable' => 1,
 752     'port-unreachable' => 1,
 753     'fragmentation-needed' => 1,
 754     'source-route-failed' => 1,
 755     'network-unknown' => 1,
 756     'host-unknown' => 1,
 757     'network-prohibited' => 1,
 758     'host-prohibited' => 1,
 759     'TOS-network-unreachable' => 1,
 760     'TOS-host-unreachable' => 1,
 761     'communication-prohibited' => 1,
 762     'host-precedence-violation' => 1,
 763     'precedence-cutoff' => 1,
 764     'source-quench' => 1,
 765     'redirect' => 1,
 766     'network-redirect' => 1,
 767     'host-redirect' => 1,
 768     'TOS-network-redirect' => 1,
 769     'TOS-host-redirect' => 1,
 770     'echo-request' => 1,
 771     'router-advertisement' => 1,
 772     'router-solicitation' => 1,
 773     'time-exceeded' => 1,
 774     'ttl-zero-during-transit' => 1,
 775     'ttl-zero-during-reassembly' => 1,
 776     'parameter-problem' => 1,
 777     'ip-header-bad' => 1,
 778     'required-option-missing' => 1,
 779     'timestamp-request' => 1,
 780     'timestamp-reply' => 1,
 781     'address-mask-request' => 1,
 782     'address-mask-reply' => 1,
 783 };
 784
 785 # ip6tables -p icmpv6 -h
 786
 787 my $icmpv6_type_names = {
 788     'destination-unreachable' => 1,
 789     'no-route' => 1,
 790     'communication-prohibited' => 1,
 791     'beyond-scope' => 1,
 792     'address-unreachable' => 1,
 793     'port-unreachable' => 1,
 794     'failed-policy' => 1,
 795     'reject-route' => 1,
 796     'packet-too-big' => 1,
 797     'time-exceeded' => 1,
 798     'ttl-zero-during-transit' => 1,
 799     'ttl-zero-during-reassembly' => 1,
 800     'parameter-problem' => 1,
 801     'bad-header' => 1,
 802     'unknown-header-type' => 1,
 803     'unknown-option' => 1,
 804     'echo-request' => 1,
 805     'echo-reply' => 1,
 806     'router-solicitation' => 1,
 807     'router-advertisement' => 1,
 808     'neighbor-solicitation' => 1,
 809     'neighbour-solicitation' => 1,
 810     'neighbor-advertisement' => 1,
 811     'neighbour-advertisement' => 1,
 812     'redirect' => 1,
 813 };
 814
 815 my $is_valid_icmp_type = sub {
 816     my ($type, $valid_types) = @_;
 817
 818     if ($type =~ m/^\d+$/) {
 819         # values for icmp-type range between 0 and 255 (8 bit field)
 820         die "invalid icmp-type '$type'\n" if $type > 255;
 821     } else {
 822         die "unknown icmp-type '$type'\n" if !defined($valid_types->{$type});
 823     }
 824 };
 825
 826 sub init_firewall_macros {
 827
 828     $pve_fw_parsed_macros = {};
 829
 830     my $parse = sub {
 831         my ($k, $macro) = @_;
 832         my $lc_name = lc($k);
 833         $pve_fw_macro_ipversion->{$k} = 0;
 834         while (!ref($macro->[0])) {
 835             my $desc = shift @$macro;
 836             if ($desc eq 'ipv4only') {
 837                 $pve_fw_macro_ipversion->{$k} = 4;
 838             } elsif ($desc eq 'ipv6only') {
 839                 $pve_fw_macro_ipversion->{$k} = 6;
 840             } else {
 841                 $pve_fw_macro_descr->{$k} = $desc;
 842             }
 843         }
 844         $pve_fw_preferred_macro_names->{$lc_name} = $k;
 845         $pve_fw_parsed_macros->{$k} = $macro;
 846     };
 847
 848     foreach my $k (keys %$pve_fw_macros) {
 849         &$parse($k, $pve_fw_macros->{$k});
 850     }
 851
 852     foreach my $k (keys %$pve_ipv6fw_macros) {
 853         next if $pve_fw_parsed_macros->{$k};
 854         &$parse($k, $pve_ipv6fw_macros->{$k});
 855         $pve_fw_macro_ipversion->{$k} = 6;
 856     }
 857 }
 858
 859 init_firewall_macros();
 860
 861 sub get_macros {
 862     return wantarray ? ($pve_fw_parsed_macros, $pve_fw_macro_descr): $pve_fw_parsed_macros;
 863 }
 864
 865 my $etc_services;
 866
 867 sub get_etc_services {
 868
 869     return $etc_services if $etc_services;
 870
 871     my $filename = "/etc/services";
 872
 873     my $fh = IO::File->new($filename, O_RDONLY);
 874     if (!$fh) {
 875         warn "unable to read '$filename' - $!\n";
 876         return {};
 877     }
 878
 879     my $services = {};
 880
 881     while (my $line = <$fh>) {
 882         chomp ($line);
 883         next if $line =~m/^#/;
 884         next if ($line =~m/^\s*$/);
 885
 886         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp|sctp).*$!) {
 887             $services->{byid}->{$2}->{name} = $1;
 888             $services->{byid}->{$2}->{port} = $2;
 889             $services->{byid}->{$2}->{$3} = 1;
 890             $services->{byname}->{$1} = $services->{byid}->{$2};
 891         }
 892     }
 893
 894     close($fh);
 895
 896     $etc_services = $services;
 897
 898
 899     return $etc_services;
 900 }
 901
 902 sub parse_protocol_file {
 903     my ($filename) = @_;
 904
 905     my $fh = IO::File->new($filename, O_RDONLY);
 906     if (!$fh) {
 907         warn "unable to read '$filename' - $!\n";
 908         return {};
 909     }
 910
 911     my $protocols = {};
 912
 913     while (my $line = <$fh>) {
 914         chomp ($line);
 915         next if $line =~m/^#/;
 916         next if ($line =~m/^\s*$/);
 917
 918         if ($line =~ m!^(\S+)\s+(\d+)(?:\s+.*)?$!) {
 919             $protocols->{byid}->{$2}->{name} = $1;
 920             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
 921         }
 922     }
 923
 924     close($fh);
 925
 926     return $protocols;
 927 }
 928
 929 my $etc_protocols;
 930
 931 sub get_etc_protocols {
 932     return $etc_protocols if $etc_protocols;
 933
 934     my $protocols = parse_protocol_file('/etc/protocols');
 935
 936     # add special case for ICMP v6
 937     $protocols->{byid}->{icmpv6}->{name} = "icmpv6";
 938     $protocols->{byname}->{icmpv6} = $protocols->{byid}->{icmpv6};
 939
 940     $etc_protocols = $protocols;
 941
 942     return $etc_protocols;
 943 }
 944
 945 my $etc_ethertypes;
 946
 947 sub get_etc_ethertypes {
 948     $etc_ethertypes = parse_protocol_file('/etc/ethertypes')
 949         if !$etc_ethertypes;
 950     return $etc_ethertypes;
 951 }
 952
 953 my $__local_network;
 954
 955 sub local_network {
 956     my ($new_value) = @_;
 957
 958     $__local_network = $new_value if defined($new_value);
 959
 960     return $__local_network if defined($__local_network);
 961
 962     eval {
 963         my $nodename = PVE::INotify::nodename();
 964
 965         my $ip = PVE::Cluster::remote_node_ip($nodename);
 966
 967         my $testip = Net::IP->new($ip);
 968
 969         my $isv6 = $testip->version == 6;
 970         my $routes = $isv6 ? PVE::ProcFSTools::read_proc_net_ipv6_route()
 971                            : PVE::ProcFSTools::read_proc_net_route();
 972         foreach my $entry (@$routes) {
 973             my $mask;
 974             if ($isv6) {
 975                 $mask = $entry->{prefix};
 976                 next if !$mask; # skip the default route...
 977             } else {
 978                 $mask = $PVE::Network::ipv4_mask_hash_localnet->{$entry->{mask}};
 979                 next if !defined($mask);
 980             }
 981             my $cidr = "$entry->{dest}/$mask";
 982             my $testnet = Net::IP->new($cidr);
 983             my $overlap = $testnet->overlaps($testip);
 984             if ($overlap == $Net::IP::IP_B_IN_A_OVERLAP ||
 985                 $overlap == $Net::IP::IP_IDENTICAL)
 986             {
 987                 $__local_network = $cidr;
 988                 return;
 989             }
 990         }
 991     };
 992     warn $@ if $@;
 993
 994     return $__local_network;
 995 }
 996
 997 # ipset names are limited to 31 characters,
 998 # and we use '-v4' or '-v6' to indicate IP versions,
 999 # and we use '_swap' suffix for atomic update,
1000 # for example PVEFW-${VMID}-${ipset_name}_swap
1001
1002 my $max_iptables_ipset_name_length = 31 - length("PVEFW-") - length("_swap");
1003
1004 sub compute_ipset_chain_name {
1005     my ($vmid, $ipset_name, $ipversion) = @_;
1006
1007     $vmid = 0 if !defined($vmid);
1008
1009     my $id = "$vmid-${ipset_name}-v$ipversion";
1010
1011     if (length($id) > $max_iptables_ipset_name_length) {
1012         $id = PVE::Tools::fnv31a_hex($id);
1013     }
1014
1015     return "PVEFW-$id";
1016 }
1017
1018 sub compute_ipfilter_ipset_name {
1019     my ($iface) = @_;
1020
1021     return "ipfilter-$iface";
1022 }
1023
1024 sub parse_address_list {
1025     my ($str) = @_;
1026
1027     if ($str =~ m/^(\+)(\S+)$/) { # ipset ref
1028         die "ipset name too long\n" if length($str) > ($max_ipset_name_length + 1);
1029         return;
1030     }
1031
1032     if ($str =~ m/^${ip_alias_pattern}$/) {
1033         die "alias name too long\n" if length($str) > $max_alias_name_length;
1034         return;
1035     }
1036
1037     my $count = 0;
1038     my $iprange = 0;
1039     my $ipversion;
1040
1041     my @elements = split(/,/, $str);
1042     die "extraneous commas in list\n" if $str ne join(',', @elements);
1043     foreach my $elem (@elements) {
1044         $count++;
1045         my $ip = Net::IP->new($elem);
1046         if (!$ip) {
1047             my $err = Net::IP::Error();
1048             die "invalid IP address: $err\n";
1049         }
1050         $iprange = 1 if $elem =~ m/-/;
1051
1052         my $new_ipversion = Net::IP::ip_is_ipv6($ip->ip()) ? 6 : 4;
1053
1054         die "detected mixed ipv4/ipv6 addresses in address list '$str'\n"
1055             if $ipversion && ($new_ipversion != $ipversion);
1056
1057         $ipversion = $new_ipversion;
1058     }
1059
1060     die "you can't use a range in a list\n" if $iprange && $count > 1;
1061
1062     return $ipversion;
1063 }
1064
1065 sub parse_port_name_number_or_range {
1066     my ($str, $dport) = @_;
1067
1068     my $services = PVE::Firewall::get_etc_services();
1069     my $count = 0;
1070     my $icmp_port = 0;
1071
1072     my @elements = split(/,/, $str);
1073     die "extraneous commas in list\n" if $str ne join(',', @elements);
1074     foreach my $item (@elements) {
1075         if ($item =~ m/^([0-9]+):([0-9]+)$/) {
1076             $count += 2;
1077             my ($port1, $port2) = ($1, $2);
1078             die "invalid port '$port1'\n" if $port1 > 65535;
1079             die "invalid port '$port2'\n" if $port2 > 65535;
1080             die "backwards range '$port1:$port2' not allowed, did you mean '$port2:$port1'?\n" if $port1 > $port2;
1081         } elsif ($item =~ m/^([0-9]+)$/) {
1082             $count += 1;
1083             my $port = $1;
1084             die "invalid port '$port'\n" if $port > 65535;
1085         } else {
1086             if ($dport && $icmp_type_names->{$item}) {
1087                 $icmp_port = 1;
1088             } elsif ($dport && $icmpv6_type_names->{$item}) {
1089                 $icmp_port = 1;
1090             } else {
1091                 die "invalid port '$item'\n" if !$services->{byname}->{$item};
1092             }
1093         }
1094     }
1095
1096     die "ICMP ports not allowed in port range\n" if $icmp_port && $count > 0;
1097
1098     # I really don't like to use the word number here, but it's the only thing
1099     # that makes sense in a literal way. The range 1:100 counts as 2, not as
1100     # one and not as 100...
1101     die "too many entries in port list (> 15 numbers)\n"
1102         if $count > 15;
1103
1104     return (scalar(@elements) > 1);
1105 }
1106
1107 PVE::JSONSchema::register_format('pve-fw-sport-spec', \&pve_fw_verify_sport_spec);
1108 sub pve_fw_verify_sport_spec {
1109    my ($portstr) = @_;
1110
1111    parse_port_name_number_or_range($portstr, 0);
1112
1113    return $portstr;
1114 }
1115
1116 PVE::JSONSchema::register_format('pve-fw-dport-spec', \&pve_fw_verify_dport_spec);
1117 sub pve_fw_verify_dport_spec {
1118    my ($portstr) = @_;
1119
1120    parse_port_name_number_or_range($portstr, 1);
1121
1122    return $portstr;
1123 }
1124
1125 PVE::JSONSchema::register_format('pve-fw-addr-spec', \&pve_fw_verify_addr_spec);
1126 sub pve_fw_verify_addr_spec {
1127    my ($list) = @_;
1128
1129    parse_address_list($list);
1130
1131    return $list;
1132 }
1133
1134 PVE::JSONSchema::register_format('pve-fw-protocol-spec', \&pve_fw_verify_protocol_spec);
1135 sub pve_fw_verify_protocol_spec {
1136    my ($proto) = @_;
1137
1138    my $protocols = get_etc_protocols();
1139
1140    die "unknown protocol '$proto'\n" if $proto &&
1141        !(defined($protocols->{byname}->{$proto}) ||
1142          defined($protocols->{byid}->{$proto}));
1143
1144    return $proto;
1145 }
1146
1147 PVE::JSONSchema::register_format('pve-fw-icmp-type-spec', \&pve_fw_verify_icmp_type_spec);
1148 sub pve_fw_verify_icmp_type_spec {
1149     my ($icmp_type) = @_;
1150
1151     if ($icmp_type_names->{$icmp_type} ||  $icmpv6_type_names->{$icmp_type}) {
1152         return $icmp_type;
1153     }
1154
1155     die "invalid icmp-type value '$icmp_type'\n" if $icmp_type ne '';
1156
1157     return $icmp_type;
1158 }
1159
1160
1161 # helper function for API
1162
1163 sub copy_opject_with_digest {
1164     my ($object) = @_;
1165
1166     my $sha = Digest::SHA->new('sha1');
1167
1168     my $res = {};
1169     foreach my $k (sort keys %$object) {
1170         my $v = $object->{$k};
1171         next if !defined($v);
1172         $res->{$k} = $v;
1173         $sha->add($k, ':', $v, "\n");
1174     }
1175
1176     my $digest = $sha->hexdigest;
1177
1178     $res->{digest} = $digest;
1179
1180     return wantarray ? ($res, $digest) : $res;
1181 }
1182
1183 sub copy_list_with_digest {
1184     my ($list) = @_;
1185
1186     my $sha = Digest::SHA->new('sha1');
1187
1188     my $res = [];
1189     foreach my $entry (@$list) {
1190         my $data = {};
1191         foreach my $k (sort keys %$entry) {
1192             my $v = $entry->{$k};
1193             next if !defined($v);
1194             $data->{$k} = $v;
1195             # Note: digest ignores refs ($rule->{errors})
1196             # since Digest::SHA expects a series of bytes,
1197             #  we have to encode the value here to prevent errors when
1198             #  using utf8 characters (eg. in comments)
1199             $sha->add($k, ':', encode_utf8($v), "\n") if !ref($v); ;
1200         }
1201         push @$res, $data;
1202     }
1203
1204     my $digest = $sha->hexdigest;
1205
1206     foreach my $entry (@$res) {
1207         $entry->{digest} = $digest;
1208     }
1209
1210     return wantarray ? ($res, $digest) : $res;
1211 }
1212
1213 our $cluster_option_properties = {
1214     enable => {
1215         description => "Enable or disable the firewall cluster wide.",
1216         type => 'integer',
1217         minimum => 0,
1218         optional => 1,
1219     },
1220     ebtables => {
1221         description => "Enable ebtables rules cluster wide.",
1222         type => 'boolean',
1223         default => 1,
1224         optional => 1,
1225     },
1226     policy_in => {
1227         description => "Input policy.",
1228         type => 'string',
1229         optional => 1,
1230         enum => ['ACCEPT', 'REJECT', 'DROP'],
1231     },
1232     policy_out => {
1233         description => "Output policy.",
1234         type => 'string',
1235         optional => 1,
1236         enum => ['ACCEPT', 'REJECT', 'DROP'],
1237     },
1238     log_ratelimit => {
1239         description => "Log ratelimiting settings",
1240         type => 'string', format => {
1241             enable => {
1242                 default_key => 1,
1243                 description => 'Enable or disable log rate limiting',
1244                 type => 'boolean',
1245                 default => '1',
1246             },
1247             rate => {
1248                 type => 'string',
1249                 description => 'Frequency with which the burst bucket gets refilled',
1250                 optional => 1,
1251                 pattern => '[1-9][0-9]*\/(second|minute|hour|day)',
1252                 format_description => 'rate',
1253                 default => '1/second',
1254             },
1255             burst => {
1256                 type => 'integer',
1257                 minimum => 0,
1258                 optional => 1,
1259                 description => 'Initial burst of packages which will always get logged before the rate is applied',
1260                 default => 5,
1261             },
1262         },
1263         optional => 1,
1264     },
1265 };
1266
1267 our $host_option_properties = {
1268     enable => {
1269         description => "Enable host firewall rules.",
1270         type => 'boolean',
1271         optional => 1,
1272     },
1273     log_level_in =>  get_standard_option('pve-fw-loglevel', {
1274         description => "Log level for incoming traffic." }),
1275     log_level_out =>  get_standard_option('pve-fw-loglevel', {
1276         description => "Log level for outgoing traffic." }),
1277     tcp_flags_log_level =>  get_standard_option('pve-fw-loglevel', {
1278         description => "Log level for illegal tcp flags filter." }),
1279     smurf_log_level =>  get_standard_option('pve-fw-loglevel', {
1280         description => "Log level for SMURFS filter." }),
1281     nosmurfs => {
1282         description => "Enable SMURFS filter.",
1283         type => 'boolean',
1284         optional => 1,
1285     },
1286     tcpflags => {
1287         description => "Filter illegal combinations of TCP flags.",
1288         type => 'boolean',
1289         default => 0,
1290         optional => 1,
1291     },
1292     nf_conntrack_max => {
1293         description => "Maximum number of tracked connections.",
1294         type => 'integer',
1295         optional => 1,
1296         default => 262144,
1297         minimum => 32768,
1298     },
1299     nf_conntrack_tcp_timeout_established => {
1300         description => "Conntrack established timeout.",
1301         type => 'integer',
1302         optional => 1,
1303         default => 432000,
1304         minimum => 7875,
1305     },
1306     nf_conntrack_tcp_timeout_syn_recv => {
1307         description => "Conntrack syn recv timeout.",
1308         type => 'integer',
1309         optional => 1,
1310         default => 60,
1311         minimum => 30,
1312         maximum => 60,
1313     },
1314     ndp => {
1315         description => "Enable NDP (Neighbor Discovery Protocol).",
1316         type => 'boolean',
1317         default => 0,
1318         optional => 1,
1319     },
1320     nf_conntrack_allow_invalid => {
1321         description => "Allow invalid packets on connection tracking.",
1322         type => 'boolean',
1323         default => 0,
1324         optional => 1,
1325     },
1326     protection_synflood => {
1327         description => "Enable synflood protection",
1328         type => 'boolean',
1329         default => 0,
1330         optional => 1,
1331     },
1332     protection_synflood_rate => {
1333         description => "Synflood protection rate syn/sec by ip src.",
1334         type => 'integer',
1335         optional => 1,
1336         default => 200,
1337     },
1338     protection_synflood_burst => {
1339         description => "Synflood protection rate burst by ip src.",
1340         type => 'integer',
1341         optional => 1,
1342         default => 1000,
1343     },
1344     log_nf_conntrack => {
1345         description => "Enable logging of conntrack information.",
1346         type => 'boolean',
1347         default => 0,
1348         optional => 1
1349     },
1350 };
1351
1352 our $vm_option_properties = {
1353     enable => {
1354         description => "Enable/disable firewall rules.",
1355         type => 'boolean',
1356         default => 0,
1357         optional => 1,
1358     },
1359     macfilter => {
1360         description => "Enable/disable MAC address filter.",
1361         type => 'boolean',
1362         default => 0,
1363         optional => 1,
1364     },
1365     dhcp => {
1366         description => "Enable DHCP.",
1367         type => 'boolean',
1368         default => 0,
1369         optional => 1,
1370     },
1371     ndp => {
1372         description => "Enable NDP (Neighbor Discovery Protocol).",
1373         type => 'boolean',
1374         default => 0,
1375         optional => 1,
1376     },
1377     radv => {
1378         description => "Allow sending Router Advertisement.",
1379         type => 'boolean',
1380         optional => 1,
1381     },
1382     ipfilter => {
1383         description => "Enable default IP filters. " .
1384            "This is equivalent to adding an empty ipfilter-net<id> ipset " .
1385            "for every interface. Such ipsets implicitly contain sane default " .
1386            "restrictions such as restricting IPv6 link local addresses to " .
1387            "the one derived from the interface's MAC address. For containers " .
1388            "the configured IP addresses will be implicitly added.",
1389         type => 'boolean',
1390         optional => 1,
1391     },
1392     policy_in => {
1393         description => "Input policy.",
1394         type => 'string',
1395         optional => 1,
1396         enum => ['ACCEPT', 'REJECT', 'DROP'],
1397     },
1398     policy_out => {
1399         description => "Output policy.",
1400         type => 'string',
1401         optional => 1,
1402         enum => ['ACCEPT', 'REJECT', 'DROP'],
1403     },
1404     log_level_in =>  get_standard_option('pve-fw-loglevel', {
1405         description => "Log level for incoming traffic." }),
1406     log_level_out =>  get_standard_option('pve-fw-loglevel', {
1407         description => "Log level for outgoing traffic." }),
1408
1409 };
1410
1411
1412 my $addr_list_descr = "This can refer to a single IP address, an IP set ('+ipsetname') or an IP alias definition. You can also specify an address range like '20.34.101.207-201.3.9.99', or a list of IP addresses and networks (entries are separated by comma). Please do not mix IPv4 and IPv6 addresses inside such lists.";
1413
1414 my $port_descr = "You can use service names or simple numbers (0-65535), as defined in '/etc/services'. Port ranges can be specified with '\\d+:\\d+', for example '80:85', and you can use comma separated list to match several ports or ranges.";
1415
1416 my $rule_properties = {
1417     pos => {
1418         description => "Update rule at position <pos>.",
1419         type => 'integer',
1420         minimum => 0,
1421         optional => 1,
1422     },
1423     digest => get_standard_option('pve-config-digest'),
1424     type => {
1425         description => "Rule type.",
1426         type => 'string',
1427         optional => 1,
1428         enum => ['in', 'out', 'group'],
1429     },
1430     action => {
1431         description => "Rule action ('ACCEPT', 'DROP', 'REJECT') or security group name.",
1432         type => 'string',
1433         optional => 1,
1434         pattern => $security_group_name_pattern,
1435         maxLength => 20,
1436         minLength => 2,
1437     },
1438     macro => {
1439         description => "Use predefined standard macro.",
1440         type => 'string',
1441         optional => 1,
1442         maxLength => 128,
1443     },
1444     iface => get_standard_option('pve-iface', {
1445         description => "Network interface name. You have to use network configuration key names for VMs and containers ('net\\d+'). Host related rules can use arbitrary strings.",
1446         optional => 1
1447     }),
1448     source => {
1449         description => "Restrict packet source address. $addr_list_descr",
1450         type => 'string', format => 'pve-fw-addr-spec',
1451         optional => 1,
1452         maxLength => 512,
1453     },
1454     dest => {
1455         description => "Restrict packet destination address. $addr_list_descr",
1456         type => 'string', format => 'pve-fw-addr-spec',
1457         optional => 1,
1458         maxLength => 512,
1459     },
1460     proto => {
1461         description => "IP protocol. You can use protocol names ('tcp'/'udp') or simple numbers, as defined in '/etc/protocols'.",
1462         type => 'string', format => 'pve-fw-protocol-spec',
1463         optional => 1,
1464     },
1465     enable => {
1466         description => "Flag to enable/disable a rule.",
1467         type => 'integer',
1468         minimum => 0,
1469         optional => 1,
1470     },
1471     log => get_standard_option('pve-fw-loglevel', {
1472         description => "Log level for firewall rule.",
1473     }),
1474     sport => {
1475         description => "Restrict TCP/UDP source port. $port_descr",
1476         type => 'string', format => 'pve-fw-sport-spec',
1477         optional => 1,
1478     },
1479     dport => {
1480         description => "Restrict TCP/UDP destination port. $port_descr",
1481         type => 'string', format => 'pve-fw-dport-spec',
1482         optional => 1,
1483     },
1484     comment => {
1485         description => "Descriptive comment.",
1486         type => 'string',
1487         optional => 1,
1488     },
1489     'icmp-type' => {
1490         description => "Specify icmp-type. Only valid if proto equals 'icmp'.",
1491         type => 'string', format => 'pve-fw-icmp-type-spec',
1492         optional => 1,
1493     },
1494 };
1495
1496 sub add_rule_properties {
1497     my ($properties) = @_;
1498
1499     foreach my $k (keys %$rule_properties) {
1500         my $h = $rule_properties->{$k};
1501         # copy data, so that we can modify later without side effects
1502         foreach my $opt (keys %$h) { $properties->{$k}->{$opt} = $h->{$opt}; }
1503     }
1504
1505     return $properties;
1506 }
1507
1508 sub delete_rule_properties {
1509     my ($rule, $delete_str) = @_;
1510
1511     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1512         raise_param_exc({ 'delete' => "no such property ('$opt')"})
1513             if !defined($rule_properties->{$opt});
1514         raise_param_exc({ 'delete' => "unable to delete required property '$opt'"})
1515             if $opt eq 'type' || $opt eq 'action';
1516         delete $rule->{$opt};
1517     }
1518
1519     return $rule;
1520 }
1521
1522 my $apply_macro = sub {
1523     my ($macro_name, $param, $verify, $ipversion) = @_;
1524
1525     my $macro_rules = $pve_fw_parsed_macros->{$macro_name};
1526     die "unknown macro '$macro_name'\n" if !$macro_rules; # should not happen
1527
1528     if ($ipversion && ($ipversion == 6) && $pve_ipv6fw_macros->{$macro_name}) {
1529         $macro_rules = $pve_ipv6fw_macros->{$macro_name};
1530     }
1531
1532     # skip macros which are specific to another ipversion
1533     if ($ipversion && (my $required = $pve_fw_macro_ipversion->{$macro_name})) {
1534         return if $ipversion != $required;
1535     }
1536
1537     my $rules = [];
1538
1539     foreach my $templ (@$macro_rules) {
1540         my $rule = {};
1541         my $param_used = {};
1542         foreach my $k (keys %$templ) {
1543             my $v = $templ->{$k};
1544             if ($v eq 'PARAM') {
1545                 $v = $param->{$k};
1546                 $param_used->{$k} = 1;
1547             } elsif ($v eq 'DEST') {
1548                 $v = $param->{dest};
1549                 $param_used->{dest} = 1;
1550             } elsif ($v eq 'SOURCE') {
1551                 $v = $param->{source};
1552                 $param_used->{source} = 1;
1553             }
1554
1555             if (!defined($v)) {
1556                 my $msg = "missing parameter '$k' in macro '$macro_name'";
1557                 raise_param_exc({ macro => $msg }) if $verify;
1558                 die "$msg\n";
1559             }
1560             $rule->{$k} = $v;
1561         }
1562         foreach my $k (keys %$param) {
1563             next if $k eq 'macro';
1564             next if !defined($param->{$k});
1565             next if $param_used->{$k};
1566             if (defined($rule->{$k})) {
1567                 if ($rule->{$k} ne $param->{$k}) {
1568                     my $msg = "parameter '$k' already define in macro (value = '$rule->{$k}')";
1569                     raise_param_exc({ $k => $msg }) if $verify;
1570                     die "$msg\n";
1571                 }
1572             } else {
1573                 $rule->{$k} = $param->{$k};
1574             }
1575         }
1576         push @$rules, $rule;
1577     }
1578
1579     return $rules;
1580 };
1581
1582 my $rule_env_iface_lookup = {
1583     'ct' => 1,
1584     'vm' => 1,
1585     'group' => 0,
1586     'cluster' => 1,
1587     'host' => 1,
1588 };
1589
1590 sub verify_rule {
1591     my ($rule, $cluster_conf, $fw_conf, $rule_env, $noerr) = @_;
1592
1593     my $allow_groups = $rule_env eq 'group' ? 0 : 1;
1594
1595     my $allow_iface = $rule_env_iface_lookup->{$rule_env};
1596     die "unknown rule_env '$rule_env'\n" if !defined($allow_iface); # should not happen
1597
1598     my $errors = $rule->{errors} || {};
1599
1600     my $error_count = 0;
1601
1602     my $add_error = sub {
1603         my ($param, $msg)  = @_;
1604         chomp $msg;
1605         raise_param_exc({ $param => $msg }) if !$noerr;
1606         $error_count++;
1607         $errors->{$param} = $msg if !$errors->{$param};
1608     };
1609
1610     my $ipversion;
1611     my $set_ip_version = sub {
1612         my $vers = shift;
1613         if ($vers) {
1614             die "detected mixed ipv4/ipv6 addresses in rule\n"
1615                 if $ipversion && ($vers != $ipversion);
1616             $ipversion = $vers;
1617         }
1618     };
1619
1620     my $check_ipset_or_alias_property = sub {
1621         my ($name, $expected_ipversion) = @_;
1622
1623         if (my $value = $rule->{$name}) {
1624             if ($value =~ m/^\+/) {
1625                 if ($value =~ m/^\+(${ipset_name_pattern})$/) {
1626                     &$add_error($name, "no such ipset '$1'")
1627                         if !($cluster_conf->{ipset}->{$1} || ($fw_conf && $fw_conf->{ipset}->{$1}));
1628
1629                 } else {
1630                     &$add_error($name, "invalid ipset name '$value'");
1631                 }
1632             } elsif ($value =~ m/^${ip_alias_pattern}$/){
1633                 my $alias = lc($value);
1634                 &$add_error($name, "no such alias '$value'")
1635                     if !($cluster_conf->{aliases}->{$alias} || ($fw_conf && $fw_conf->{aliases}->{$alias}));
1636                 my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
1637                 $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1638
1639                 &$set_ip_version($e->{ipversion});
1640             }
1641         }
1642     };
1643
1644     my $type = $rule->{type};
1645     my $action = $rule->{action};
1646
1647     &$add_error('type', "missing property") if !$type;
1648     &$add_error('action', "missing property") if !$action;
1649
1650     if ($type) {
1651         if ($type eq  'in' || $type eq 'out') {
1652             &$add_error('action', "unknown action '$action'")
1653                 if $action && ($action !~ m/^(ACCEPT|DROP|REJECT)$/);
1654         } elsif ($type eq 'group') {
1655             &$add_error('type', "security groups not allowed")
1656                 if !$allow_groups;
1657             &$add_error('action', "invalid characters in security group name")
1658                 if $action && ($action !~ m/^${security_group_name_pattern}$/);
1659         } else {
1660             &$add_error('type', "unknown rule type '$type'");
1661         }
1662     }
1663
1664     if ($rule->{iface}) {
1665         &$add_error('type', "parameter -i not allowed for this rule type")
1666             if !$allow_iface;
1667         eval { PVE::JSONSchema::pve_verify_iface($rule->{iface}); };
1668         &$add_error('iface', $@) if $@;
1669         if ($rule_env eq 'vm' || $rule_env eq 'ct') {
1670             &$add_error('iface', "value does not match the regex pattern 'net\\d+'")
1671                 if $rule->{iface} !~  m/^net(\d+)$/;
1672         }
1673     }
1674
1675     if ($rule->{macro}) {
1676         if (my $preferred_name = $pve_fw_preferred_macro_names->{lc($rule->{macro})}) {
1677             $rule->{macro} = $preferred_name;
1678         } else {
1679             &$add_error('macro', "unknown macro '$rule->{macro}'");
1680         }
1681     }
1682
1683     if ($rule->{proto}) {
1684         eval { pve_fw_verify_protocol_spec($rule->{proto}); };
1685         &$add_error('proto', $@) if $@;
1686         &$set_ip_version(4) if $rule->{proto} eq 'icmp';
1687         &$set_ip_version(6) if $rule->{proto} eq 'icmpv6';
1688         &$set_ip_version(6) if $rule->{proto} eq 'ipv6-icmp';
1689     }
1690
1691     if ($rule->{dport}) {
1692         eval { parse_port_name_number_or_range($rule->{dport}, 1); };
1693         &$add_error('dport', $@) if $@;
1694         my $proto = $rule->{proto};
1695         &$add_error('proto', "missing property - 'dport' requires this property")
1696             if !$proto;
1697         &$add_error('dport', "protocol '$proto' does not support ports")
1698             if !$PROTOCOLS_WITH_PORTS->{$proto} &&
1699                 $proto ne 'icmp' && $proto ne 'icmpv6'; # special cases
1700     }
1701
1702     if (my $icmp_type = $rule ->{'icmp-type'}) {
1703         my $proto = $rule->{proto};
1704         &$add_error('proto', "missing property - 'icmp-type' requires this property")
1705             if $proto ne 'icmp' && $proto ne 'icmpv6' && $proto ne 'ipv6-icmp';
1706         &$add_error('icmp-type', "'icmp-type' cannot be specified together with 'dport'")
1707             if $rule->{dport};
1708         if ($proto eq 'icmp' && !$icmp_type_names->{$icmp_type}) {
1709             &$add_error('icmp-type', "invalid icmp-type '$icmp_type' for proto 'icmp'");
1710         } elsif (($proto eq 'icmpv6' || $proto eq 'ipv6-icmp') && !$icmpv6_type_names->{$icmp_type}) {
1711             &$add_error('icmp-type', "invalid icmp-type '$icmp_type' for proto '$proto'");
1712         }
1713     }
1714
1715     if ($rule->{sport}) {
1716         eval { parse_port_name_number_or_range($rule->{sport}, 0); };
1717         &$add_error('sport', $@) if $@;
1718         my $proto = $rule->{proto};
1719         &$add_error('proto', "missing property - 'sport' requires this property")
1720             if !$proto;
1721         &$add_error('sport', "protocol '$proto' does not support ports")
1722             if !$PROTOCOLS_WITH_PORTS->{$proto};
1723     }
1724
1725     if ($rule->{source}) {
1726         eval {
1727             my $source_ipversion = parse_address_list($rule->{source});
1728             &$set_ip_version($source_ipversion);
1729         };
1730         &$add_error('source', $@) if $@;
1731         &$check_ipset_or_alias_property('source', $ipversion);
1732     }
1733
1734     if ($rule->{dest}) {
1735         eval {
1736             my $dest_ipversion = parse_address_list($rule->{dest});
1737             &$set_ip_version($dest_ipversion);
1738         };
1739         &$add_error('dest', $@) if $@;
1740         &$check_ipset_or_alias_property('dest', $ipversion);
1741     }
1742
1743     $rule->{ipversion} = $ipversion if $ipversion;
1744
1745     if ($rule->{macro} && !$error_count) {
1746         eval { &$apply_macro($rule->{macro}, $rule, 1, $ipversion); };
1747         if (my $err = $@) {
1748             if (ref($err) eq "PVE::Exception" && $err->{errors}) {
1749                 my $eh = $err->{errors};
1750                 foreach my $p (keys %$eh) {
1751                     &$add_error($p, $eh->{$p});
1752                 }
1753             } else {
1754                 &$add_error('macro', "$err");
1755             }
1756         }
1757     }
1758
1759     $rule->{errors} = $errors if $error_count;
1760
1761     return $rule;
1762 }
1763
1764 sub copy_rule_data {
1765     my ($rule, $param) = @_;
1766
1767     foreach my $k (keys %$rule_properties) {
1768         if (defined(my $v = $param->{$k})) {
1769             if ($v eq '' || $v eq '-') {
1770                 delete $rule->{$k};
1771             } else {
1772                 $rule->{$k} = $v;
1773             }
1774         }
1775     }
1776
1777     return $rule;
1778 }
1779
1780 sub rules_modify_permissions {
1781     my ($rule_env) = @_;
1782
1783     if ($rule_env eq 'host') {
1784         return {
1785             check => ['perm', '/nodes/{node}', [ 'Sys.Modify' ]],
1786         };
1787     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1788         return {
1789             check => ['perm', '/', [ 'Sys.Modify' ]],
1790         };
1791     } elsif ($rule_env eq 'vm' || $rule_env eq 'ct') {
1792         return {
1793             check => ['perm', '/vms/{vmid}', [ 'VM.Config.Network' ]],
1794         }
1795     }
1796
1797     return undef;
1798 }
1799
1800 sub rules_audit_permissions {
1801     my ($rule_env) = @_;
1802
1803     if ($rule_env eq 'host') {
1804         return {
1805             check => ['perm', '/nodes/{node}', [ 'Sys.Audit' ]],
1806         };
1807     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1808         return {
1809             check => ['perm', '/', [ 'Sys.Audit' ]],
1810         };
1811     } elsif ($rule_env eq 'vm' || $rule_env eq 'ct') {
1812         return {
1813             check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1814         }
1815     }
1816
1817     return undef;
1818 }
1819
1820 # core functions
1821 my $bridge_firewall_enabled = 0;
1822
1823 sub enable_bridge_firewall {
1824
1825     return if $bridge_firewall_enabled; # only once
1826
1827     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
1828     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
1829
1830     # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
1831     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
1832
1833     $bridge_firewall_enabled = 1;
1834 }
1835
1836 sub iptables_restore_cmdlist {
1837     my ($cmdlist, $table) = @_;
1838
1839     $table = 'filter' if !$table;
1840     run_command(['iptables-restore', '-T', $table, '-n'], input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1841 }
1842
1843 sub ip6tables_restore_cmdlist {
1844     my ($cmdlist, $table) = @_;
1845
1846     $table = 'filter' if !$table;
1847     run_command(['ip6tables-restore', '-T', $table, '-n'], input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1848 }
1849
1850 sub ipset_restore_cmdlist {
1851     my ($cmdlist) = @_;
1852
1853     run_command(['ipset', 'restore'], input => $cmdlist, errmsg => "ipset_restore_cmdlist");
1854 }
1855
1856 sub ebtables_restore_cmdlist {
1857     my ($cmdlist) = @_;
1858
1859     run_command(['ebtables-restore'], input => $cmdlist, errmsg => "ebtables_restore_cmdlist");
1860 }
1861
1862 sub iptables_get_chains {
1863     my ($iptablescmd, $t) = @_;
1864
1865     $iptablescmd = "iptables" if !$iptablescmd;
1866     $t = 'filter' if !$t;
1867
1868     my $res = {};
1869
1870     # check what chains we want to track
1871     my $is_pvefw_chain = sub {
1872         my $name = shift;
1873
1874         return 1 if $name =~ m/^PVEFW-\S+$/;
1875
1876         return 1 if $name =~ m/^tap\d+i\d+-(?:IN|OUT)$/;
1877
1878         return 1 if $name =~ m/^veth\d+i\d+-(?:IN|OUT)$/;
1879
1880         return 1 if $name =~ m/^fwbr\d+(v\d+)?-(?:FW|IN|OUT|IPS)$/;
1881         return 1 if $name =~ m/^GROUP-(?:$security_group_name_pattern)-(?:IN|OUT)$/;
1882
1883         return undef;
1884     };
1885
1886     my $table = '';
1887
1888     my $hooks = {};
1889
1890     my $parser = sub {
1891         my $line = shift;
1892
1893         return if $line =~ m/^#/;
1894         return if $line =~ m/^\s*$/;
1895
1896         if ($line =~ m/^\*(\S+)$/) {
1897             $table = $1;
1898             return;
1899         }
1900
1901         return if $table ne $t;
1902
1903         if ($line =~ m/^:(\S+)\s/) {
1904             my $chain = $1;
1905             return if !&$is_pvefw_chain($chain);
1906             $res->{$chain} = "unknown";
1907         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
1908             my ($chain, $sig) = ($1, $2);
1909             return if !&$is_pvefw_chain($chain);
1910             $res->{$chain} = $sig;
1911         } elsif ($line =~ m/^-A\s+(INPUT|OUTPUT|FORWARD|PREROUTING)\s+-j\s+PVEFW-\1$/) {
1912             $hooks->{$1} = 1;
1913         } else {
1914             # simply ignore the rest
1915             return;
1916         }
1917     };
1918
1919     run_command(["$iptablescmd-save"], outfunc => $parser);
1920
1921     return wantarray ? ($res, $hooks) : $res;
1922 }
1923
1924 sub iptables_chain_digest {
1925     my ($rules) = @_;
1926     my $digest = Digest::SHA->new('sha1');
1927     foreach my $rule (@$rules) { # order is important
1928         $digest->add($rule);
1929     }
1930     return $digest->b64digest;
1931 }
1932
1933 sub ipset_chain_digest {
1934     my ($rules) = @_;
1935
1936     my $digest = Digest::SHA->new('sha1');
1937     foreach my $rule (sort @$rules) { # note: sorted
1938         $digest->add($rule);
1939     }
1940     return $digest->b64digest;
1941 }
1942
1943 sub ipset_get_chains {
1944
1945     my $res = {};
1946     my $chains = {};
1947
1948     my $parser = sub {
1949         my $line = shift;
1950
1951         return if $line =~ m/^#/;
1952         return if $line =~ m/^\s*$/;
1953         if ($line =~ m/^(?:\S+)\s(PVEFW-\S+)\s(?:\S+).*/) {
1954             my $chain = $1;
1955             $line =~ s/\s+$//; # delete trailing white space
1956             push @{$chains->{$chain}}, $line;
1957         } else {
1958             # simply ignore the rest
1959             return;
1960         }
1961     };
1962
1963     run_command(['ipset', 'save'], outfunc => $parser);
1964
1965     # compute digest for each chain
1966     foreach my $chain (keys %$chains) {
1967         $res->{$chain} = ipset_chain_digest($chains->{$chain});
1968     }
1969
1970     return $res;
1971 }
1972
1973 sub ebtables_get_chains {
1974
1975     my $res = {};
1976     my $chains = {};
1977     my $parser = sub {
1978         my $line = shift;
1979         return if $line =~ m/^#/;
1980         return if $line =~ m/^\s*$/;
1981         if ($line =~ m/^:(\S+)\s(ACCEPT|DROP|RETURN)$/) {
1982             # Make sure we know chains exist even if they're empty.
1983             $chains->{$1} //= [];
1984             $res->{$1}->{policy} = $2;
1985         } elsif ($line =~ m/^(?:\S+)\s(\S+)\s(?:\S+).*/) {
1986             my $chain = $1;
1987             $line =~ s/\s+$//;
1988             push @{$chains->{$chain}}, $line;
1989         } else {
1990             # simply ignore the rest
1991             return;
1992         }
1993     };
1994
1995     run_command(['ebtables-save'], outfunc => $parser);
1996     # compute digest for each chain and store rules as well
1997     foreach my $chain (keys %$chains) {
1998         $res->{$chain}->{rules} = $chains->{$chain};
1999         $res->{$chain}->{sig} = iptables_chain_digest($chains->{$chain});
2000     }
2001     return $res;
2002 }
2003
2004 # substitute action of rule according to action hash
2005 sub rule_substitude_action {
2006     my ($rule, $actions) = @_;
2007
2008     if (my $action = $rule->{action}) {
2009         $rule->{action} = $actions->{$action} if defined($actions->{$action});
2010     }
2011 }
2012
2013 # generate a src or dst match
2014 # $dir(ection) is either d or s
2015 sub ipt_gen_src_or_dst_match {
2016     my ($adr, $dir, $ipversion, $cluster_conf, $fw_conf) = @_;
2017
2018     my $srcdst;
2019     if ($dir eq 's') {
2020         $srcdst = "src";
2021     } elsif ($dir eq 'd') {
2022         $srcdst = "dst";
2023     } else {
2024         die "ipt_gen_src_or_dst_match: invalid direction $dir \n";
2025     }
2026
2027     my $match;
2028     if ($adr =~ m/^\+/) {
2029         if ($adr =~ m/^\+(${ipset_name_pattern})$/) {
2030             my $name = $1;
2031             my $ipset_chain;
2032             if ($fw_conf && $fw_conf->{ipset}->{$name}) {
2033                 $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name, $ipversion);
2034             } elsif ($cluster_conf && $cluster_conf->{ipset}->{$name}) {
2035                 $ipset_chain = compute_ipset_chain_name(0, $name, $ipversion);
2036             } else {
2037                 die "no such ipset '$name'\n";
2038             }
2039             $match = "-m set --match-set ${ipset_chain} ${srcdst}";
2040         } else {
2041             die "invalid security group name '$adr'\n";
2042         }
2043     } elsif ($adr =~ m/^${ip_alias_pattern}$/){
2044         my $alias = lc($adr);
2045         my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
2046         $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
2047         die "no such alias '$adr'\n" if !$e;
2048         $match = "-${dir} $e->{cidr}";
2049     } elsif ($adr =~ m/\-/){
2050         $match = "-m iprange --${srcdst}-range $adr";
2051     } else {
2052         $match = "-${dir} $adr";
2053     }
2054
2055     return $match;
2056 }
2057
2058 # convert a %rule to an array of iptables commands
2059 sub ipt_rule_to_cmds {
2060     my ($rule, $chain, $ipversion, $cluster_conf, $fw_conf, $vmid) = @_;
2061
2062     die "ipt_rule_to_cmds unable to handle macro" if $rule->{macro}; #should not happen
2063
2064     my @match = ();
2065
2066     if (defined $rule->{match}) {
2067         push @match, $rule->{match};
2068     } else {
2069         push @match, "-i $rule->{iface_in}" if $rule->{iface_in};
2070         push @match, "-o $rule->{iface_out}" if $rule->{iface_out};
2071
2072         if ($rule->{source}) {
2073             push @match, ipt_gen_src_or_dst_match($rule->{source}, 's', $ipversion, $cluster_conf, $fw_conf);
2074         }
2075         if ($rule->{dest}) {
2076             push @match, ipt_gen_src_or_dst_match($rule->{dest}, 'd', $ipversion, $cluster_conf, $fw_conf);
2077         }
2078
2079         if (my $proto = $rule->{proto}) {
2080             push @match, "-p $proto";
2081
2082             my $multidport = defined($rule->{dport}) && parse_port_name_number_or_range($rule->{dport}, 1);
2083             my $multisport = defined($rule->{sport}) && parse_port_name_number_or_range($rule->{sport}, 0);
2084
2085             my $add_dport = sub {
2086                 return if !defined($rule->{dport});
2087
2088                 # NOTE: we re-use dport to store --icmp-type for icmp* protocol
2089                 if ($proto eq 'icmp') {
2090                     $is_valid_icmp_type->($rule->{dport}, $icmp_type_names);
2091                     push @match, "-m icmp --icmp-type $rule->{dport}";
2092                 } elsif ($proto eq 'icmpv6') {
2093                     $is_valid_icmp_type->($rule->{dport}, $icmpv6_type_names);
2094                     push @match, "-m icmpv6 --icmpv6-type $rule->{dport}";
2095                 } elsif (!$PROTOCOLS_WITH_PORTS->{$proto}) {
2096                     die "protocol $proto does not have ports\n";
2097                 } elsif ($multidport) {
2098                     push @match, "--match multiport", "--dports $rule->{dport}";
2099                 } else {
2100                     return if !$rule->{dport};
2101                     push @match, "--dport $rule->{dport}";
2102                 }
2103             };
2104
2105             my $add_sport = sub {
2106                 return if !$rule->{sport};
2107
2108                 die "protocol $proto does not have ports\n"
2109                     if !$PROTOCOLS_WITH_PORTS->{$proto};
2110                 if ($multisport) {
2111                     push @match, "--match multiport", "--sports $rule->{sport}";
2112                 } else {
2113                     push @match, "--sport $rule->{sport}";
2114                 }
2115             };
2116
2117             my $add_icmp_type = sub {
2118                 return if !defined($rule->{'icmp-type'}) || $rule->{'icmp-type'} eq '';
2119
2120                 die "'icmp-type' can only be set if 'icmp', 'icmpv6' or 'ipv6-icmp' is specified\n"
2121                     if ($proto ne 'icmp') && ($proto ne 'icmpv6') && ($proto ne 'ipv6-icmp');
2122                 my $type = $proto eq 'icmp' ? 'icmp-type' : 'icmpv6-type';
2123
2124                 push @match, "-m $proto --$type $rule->{'icmp-type'}";
2125             };
2126
2127             # order matters - single port before multiport!
2128             $add_icmp_type->();
2129             $add_dport->() if $multisport;
2130             $add_sport->();
2131             $add_dport->() if !$multisport;
2132         } elsif ($rule->{dport} || $rule->{sport}) {
2133             die "destination port '$rule->{dport}', but no protocol specified\n" if $rule->{dport};
2134             die "source port '$rule->{sport}', but no protocol specified\n" if $rule->{sport};
2135         }
2136
2137         push @match, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
2138     }
2139     my $matchstr = scalar(@match) ? join(' ', @match) : "";
2140
2141     my $targetstr;
2142     if (defined $rule->{target}) {
2143         $targetstr = $rule->{target};
2144     } else {
2145         my $action = (defined $rule->{action}) ? $rule->{action} : "";
2146         my $goto = 1 if $action eq 'PVEFW-SET-ACCEPT-MARK';
2147         $targetstr = ($goto) ? "-g $action" : "-j $action";
2148     }
2149
2150     my @iptcmds;
2151     my $log = $rule->{log};
2152     if (defined($log) && $log ne 'nolog') {
2153         my $loglevel = $log_level_hash->{$log};
2154         my $logaction = get_log_rule_base($chain, $vmid, $rule->{logmsg}, $loglevel);
2155         push @iptcmds, "-A $chain $matchstr $logaction";
2156     }
2157     push @iptcmds, "-A $chain $matchstr $targetstr";
2158     return @iptcmds;
2159 }
2160
2161 sub ruleset_generate_rule {
2162     my ($ruleset, $chain, $ipversion, $rule, $cluster_conf, $fw_conf, $vmid) = @_;
2163
2164     my $rules;
2165
2166     if ($rule->{macro}) {
2167         $rules = &$apply_macro($rule->{macro}, $rule, 0, $ipversion);
2168     } else {
2169         $rules = [ $rule ];
2170     }
2171
2172     # update all or nothing
2173     my @ipt_rule_cmds;
2174     foreach my $r (@$rules) {
2175         push @ipt_rule_cmds, ipt_rule_to_cmds($r, $chain, $ipversion, $cluster_conf, $fw_conf, $vmid);
2176     }
2177     foreach my $c (@ipt_rule_cmds) {
2178         ruleset_add_ipt_cmd($ruleset, $chain, $c);
2179     }
2180 }
2181
2182 sub ruleset_create_chain {
2183     my ($ruleset, $chain) = @_;
2184
2185     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
2186     die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
2187
2188     die "chain '$chain' already exists\n" if $ruleset->{$chain};
2189
2190     $ruleset->{$chain} = [];
2191 }
2192
2193 sub ruleset_chain_exist {
2194     my ($ruleset, $chain) = @_;
2195
2196     return $ruleset->{$chain} ? 1 : undef;
2197 }
2198
2199 # add an iptables command (like generated by ipt_rule_to_cmds) to a chain
2200 sub ruleset_add_ipt_cmd {
2201    my ($ruleset, $chain, $iptcmd) = @_;
2202
2203    die "no such chain '$chain'\n" if !$ruleset->{$chain};
2204
2205    push @{$ruleset->{$chain}}, $iptcmd;
2206 }
2207
2208 sub ruleset_addrule {
2209     my ($ruleset, $chain, $match, $action, $log, $logmsg, $vmid) = @_;
2210
2211     die "no such chain '$chain'\n" if !$ruleset->{$chain};
2212
2213     if ($log) {
2214         my $loglevel = $log_level_hash->{$log};
2215         my $logaction = get_log_rule_base($chain, $vmid, $logmsg, $loglevel);
2216         push @{$ruleset->{$chain}}, "-A $chain $match $logaction";
2217     }
2218     # for stable ebtables digests avoid double-spaces to match ebtables-save output
2219     $match .= ' ' if length($match);
2220     push @{$ruleset->{$chain}}, "-A $chain ${match}$action";
2221 }
2222
2223 sub ruleset_insertrule {
2224    my ($ruleset, $chain, $match, $action, $log) = @_;
2225
2226    die "no such chain '$chain'\n" if !$ruleset->{$chain};
2227
2228    unshift @{$ruleset->{$chain}}, "-A $chain $match $action";
2229 }
2230
2231 sub get_log_rule_base {
2232     my ($chain, $vmid, $msg, $loglevel) = @_;
2233
2234     $vmid = 0 if !defined($vmid);
2235     $msg = "" if !defined($msg);
2236
2237     my $rlimit = '';
2238     if (defined($global_log_ratelimit)) {
2239         $rlimit = "-m limit $global_log_ratelimit ";
2240     }
2241
2242     # Note: we use special format for prefix to pass further
2243     # info to log daemon (VMID, LOGLEVEL and CHAIN)
2244     return "${rlimit}-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
2245 }
2246
2247 sub ruleset_add_chain_policy {
2248     my ($ruleset, $chain, $ipversion, $vmid, $policy, $loglevel, $accept_action) = @_;
2249
2250     if ($policy eq 'ACCEPT') {
2251
2252         my $rule = { action => 'ACCEPT' };
2253         rule_substitude_action($rule, { ACCEPT =>  $accept_action});
2254         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule);
2255
2256     } elsif ($policy eq 'DROP') {
2257
2258         ruleset_addrule($ruleset, $chain, "", "-j PVEFW-Drop");
2259
2260         ruleset_addrule($ruleset, $chain, "", "-j DROP", $loglevel, "policy $policy: ", $vmid);
2261     } elsif ($policy eq 'REJECT') {
2262         ruleset_addrule($ruleset, $chain, "", "-j PVEFW-Reject");
2263
2264         ruleset_addrule($ruleset, $chain, "", "-g PVEFW-reject", $loglevel, "policy $policy: ", $vmid);
2265     } else {
2266         # should not happen
2267         die "internal error: unknown policy '$policy'";
2268     }
2269 }
2270
2271 sub ruleset_chain_add_ndp {
2272     my ($ruleset, $chain, $ipversion, $options, $direction, $accept) = @_;
2273     return if $ipversion != 6 || (defined($options->{ndp}) && !$options->{ndp});
2274
2275     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-solicitation", $accept);
2276     if ($direction ne 'OUT' || $options->{radv}) {
2277         ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-advertisement", $accept);
2278     }
2279     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type neighbor-solicitation", $accept);
2280     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type neighbor-advertisement", $accept);
2281 }
2282
2283 sub ruleset_chain_add_conn_filters {
2284     my ($ruleset, $chain, $allow_invalid, $accept) = @_;
2285
2286     if (!$allow_invalid) {
2287         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID", "-j DROP");
2288     }
2289     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED", "-j $accept");
2290 }
2291
2292 sub ruleset_chain_add_input_filters {
2293     my ($ruleset, $chain, $ipversion, $options, $cluster_conf, $loglevel) = @_;
2294
2295     if ($cluster_conf->{ipset}->{blacklist}){
2296         if (!ruleset_chain_exist($ruleset, "PVEFW-blacklist")) {
2297             ruleset_create_chain($ruleset, "PVEFW-blacklist");
2298             ruleset_addrule($ruleset, "PVEFW-blacklist", "", "-j DROP", $loglevel, "DROP: ", 0);
2299         }
2300         my $ipset_chain = compute_ipset_chain_name(0, 'blacklist', $ipversion);
2301         ruleset_addrule($ruleset, $chain, "-m set --match-set ${ipset_chain} src", "-j PVEFW-blacklist");
2302     }
2303
2304     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
2305         if ($ipversion == 4) {
2306             ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW", "-j PVEFW-smurfs");
2307         }
2308     }
2309
2310     if ($options->{tcpflags}) {
2311         ruleset_addrule($ruleset, $chain, "-p tcp", "-j PVEFW-tcpflags");
2312     }
2313 }
2314
2315 sub ruleset_create_vm_chain {
2316     my ($ruleset, $chain, $ipversion, $options, $macaddr, $ipfilter_ipset, $direction) = @_;
2317
2318     ruleset_create_chain($ruleset, $chain);
2319     my $accept = generate_nfqueue($options);
2320
2321     if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
2322         if ($ipversion == 4) {
2323             if ($direction eq 'OUT') {
2324                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2325                                       { action => 'PVEFW-SET-ACCEPT-MARK',
2326                                         proto => 'udp', sport => 68, dport => 67 });
2327             } else {
2328                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2329                                       { action => 'ACCEPT',
2330                                         proto => 'udp', sport => 67, dport => 68 });
2331             }
2332         } elsif ($ipversion == 6) {
2333             if ($direction eq 'OUT') {
2334                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2335                                       { action => 'PVEFW-SET-ACCEPT-MARK',
2336                                         proto => 'udp', sport => 546, dport => 547 });
2337             } else {
2338                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2339                                       { action => 'ACCEPT',
2340                                         proto => 'udp', sport => 547, dport => 546 });
2341             }
2342         }
2343
2344     }
2345
2346     if ($direction eq 'OUT') {
2347         if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
2348             ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr", "-j DROP");
2349         }
2350         if ($ipversion == 6 && !$options->{radv}) {
2351             ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-advertisement", "-j DROP");
2352         }
2353         if ($ipfilter_ipset) {
2354             ruleset_addrule($ruleset, $chain, "-m set ! --match-set $ipfilter_ipset src", "-j DROP");
2355         }
2356         ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2357     }
2358
2359     my $accept_action = $direction eq 'OUT' ? '-g PVEFW-SET-ACCEPT-MARK' : "-j $accept";
2360     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, $direction, $accept_action);
2361 }
2362
2363 sub ruleset_add_group_rule {
2364     my ($ruleset, $cluster_conf, $chain, $rule, $direction, $action, $ipversion) = @_;
2365
2366     my $group = $rule->{action};
2367     my $group_chain = "GROUP-$group-$direction";
2368     if(!ruleset_chain_exist($ruleset, $group_chain)){
2369         generate_group_rules($ruleset, $cluster_conf, $group, $ipversion);
2370     }
2371
2372     if ($direction eq 'OUT' && $rule->{iface_out}) {
2373         ruleset_addrule($ruleset, $chain, "-o $rule->{iface_out}", "-j $group_chain");
2374     } elsif ($direction eq 'IN' && $rule->{iface_in}) {
2375         ruleset_addrule($ruleset, $chain, "-i $rule->{iface_in}", "-j $group_chain");
2376     } else {
2377         ruleset_addrule($ruleset, $chain, "", "-j $group_chain");
2378     }
2379
2380     ruleset_addrule($ruleset, $chain, "-m mark --mark $FWACCEPTMARK_ON", "-j $action");
2381 }
2382
2383 sub ruleset_generate_vm_rules {
2384     my ($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, $netid, $direction, $options, $ipversion, $vmid) = @_;
2385
2386     my $lc_direction = lc($direction);
2387
2388     my $in_accept = generate_nfqueue($options);
2389
2390     foreach my $rule (@$rules) {
2391         next if $rule->{iface} && $rule->{iface} ne $netid;
2392         next if !$rule->{enable} || $rule->{errors};
2393         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2394
2395         if ($rule->{type} eq 'group') {
2396             ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, $direction,
2397                                    $direction eq 'OUT' ? 'RETURN' : $in_accept, $ipversion);
2398         } else {
2399             next if $rule->{type} ne $lc_direction;
2400             eval {
2401                 $rule->{logmsg} = "$rule->{action}: ";
2402                 if ($direction eq 'OUT') {
2403                     rule_substitude_action($rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
2404                     ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $vmfw_conf, $vmid);
2405                 } else {
2406                     rule_substitude_action($rule, { ACCEPT => $in_accept , REJECT => "PVEFW-reject" });
2407                     ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $vmfw_conf, $vmid);
2408                 }
2409             };
2410             warn $@ if $@;
2411         }
2412     }
2413 }
2414
2415 sub generate_nfqueue {
2416     my ($options) = @_;
2417
2418     if ($options->{ips}) {
2419         my $action = "NFQUEUE";
2420         if ($options->{ips_queues} && $options->{ips_queues} =~ m/^(\d+)(:(\d+))?$/) {
2421             if (defined($3) && defined($1)) {
2422                 $action .= " --queue-balance $1:$3";
2423             } elsif (defined($1)) {
2424                 $action .= " --queue-num $1";
2425             }
2426         }
2427         $action .= " --queue-bypass" if $feature_ipset_nomatch; #need kernel 3.10
2428         return $action;
2429     } else {
2430         return "ACCEPT";
2431     }
2432 }
2433
2434 sub ruleset_generate_vm_ipsrules {
2435     my ($ruleset, $options, $direction, $iface) = @_;
2436
2437     if ($options->{ips} && $direction eq 'IN') {
2438         my $nfqueue = generate_nfqueue($options);
2439
2440         if (!ruleset_chain_exist($ruleset, "PVEFW-IPS")) {
2441             ruleset_create_chain($ruleset, "PVEFW-IPS");
2442         }
2443
2444         ruleset_addrule($ruleset, "PVEFW-IPS", "-m physdev --physdev-out $iface --physdev-is-bridged", "-j $nfqueue");
2445     }
2446 }
2447
2448 sub generate_tap_rules_direction {
2449     my ($ruleset, $cluster_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $direction, $ipversion) = @_;
2450
2451     my $lc_direction = lc($direction);
2452
2453     my $rules = $vmfw_conf->{rules};
2454
2455     my $options = $vmfw_conf->{options};
2456     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
2457
2458     my $tapchain = "$iface-$direction";
2459
2460     my $ipfilter_name = compute_ipfilter_ipset_name($netid);
2461     my $ipfilter_ipset = compute_ipset_chain_name($vmid, $ipfilter_name, $ipversion)
2462         if $options->{ipfilter} || $vmfw_conf->{ipset}->{$ipfilter_name};
2463
2464     if ($options->{enable}) {
2465         # create chain with mac and ip filter
2466         ruleset_create_vm_chain($ruleset, $tapchain, $ipversion, $options, $macaddr, $ipfilter_ipset, $direction);
2467
2468         ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $tapchain, $netid, $direction, $options, $ipversion, $vmid);
2469
2470         ruleset_generate_vm_ipsrules($ruleset, $options, $direction, $iface);
2471
2472         # implement policy
2473         my $policy;
2474
2475         if ($direction eq 'OUT') {
2476             $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
2477         } else {
2478             $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
2479         }
2480
2481         my $accept = generate_nfqueue($options);
2482         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
2483         ruleset_add_chain_policy($ruleset, $tapchain, $ipversion, $vmid, $policy, $loglevel, $accept_action);
2484     } else {
2485         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : 'ACCEPT';
2486         ruleset_add_chain_policy($ruleset, $tapchain, $ipversion, $vmid, 'ACCEPT', $loglevel, $accept_action);
2487     }
2488
2489     # plug the tap chain to bridge chain
2490     if ($direction eq 'IN') {
2491         ruleset_addrule($ruleset, "PVEFW-FWBR-IN",
2492                         "-m physdev --physdev-is-bridged --physdev-out $iface", "-j $tapchain");
2493     } else {
2494         ruleset_addrule($ruleset, "PVEFW-FWBR-OUT",
2495                         "-m physdev --physdev-is-bridged --physdev-in $iface", "-j $tapchain");
2496     }
2497 }
2498
2499 sub enable_host_firewall {
2500     my ($ruleset, $hostfw_conf, $cluster_conf, $ipversion, $corosync_conf) = @_;
2501
2502     my $options = $hostfw_conf->{options};
2503     my $cluster_options = $cluster_conf->{options};
2504     my $rules = $hostfw_conf->{rules};
2505     my $cluster_rules = $cluster_conf->{rules};
2506
2507     # corosync preparation
2508     my $corosync_rule = "-p udp --dport 5404:5405";
2509     my $corosync_local_addresses = {};
2510     my $multicast_enabled;
2511     my $local_hostname = PVE::INotify::nodename();
2512     if (defined($corosync_conf)) {
2513         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2514             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2515
2516             if ($node_name eq $local_hostname) {
2517                 $corosync_local_addresses->{$key} = $node_ip;
2518             }
2519         });
2520
2521         # allow multicast only if enabled in config
2522         my $corosync_transport = $corosync_conf->{main}->{totem}->{transport};
2523         $multicast_enabled = defined($corosync_transport) && $corosync_transport eq 'udp';
2524     }
2525
2526     # host inbound firewall
2527     my $chain = "PVEFW-HOST-IN";
2528     ruleset_create_chain($ruleset, $chain);
2529
2530     my $loglevel = get_option_log_level($options, "log_level_in");
2531
2532     ruleset_addrule($ruleset, $chain, "-i lo", "-j ACCEPT");
2533
2534     ruleset_chain_add_conn_filters($ruleset, $chain, 0, 'ACCEPT');
2535     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, 'IN', '-j RETURN');
2536     ruleset_chain_add_input_filters($ruleset, $chain, $ipversion, $options, $cluster_conf, $loglevel);
2537
2538     # we use RETURN because we need to check also tap rules
2539     my $accept_action = 'RETURN';
2540
2541     ruleset_addrule($ruleset, $chain, "-p igmp", "-j $accept_action"); # important for multicast
2542
2543     # add host rules first, so that cluster wide rules can be overwritten
2544     foreach my $rule (@$rules, @$cluster_rules) {
2545         next if !$rule->{enable} || $rule->{errors};
2546         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2547
2548         $rule->{iface_in} = $rule->{iface} if $rule->{iface};
2549
2550         eval {
2551             $rule->{logmsg} = "$rule->{action}: ";
2552             if ($rule->{type} eq 'group') {
2553                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'IN', $accept_action, $ipversion);
2554             } elsif ($rule->{type} eq 'in') {
2555                 rule_substitude_action($rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
2556                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $hostfw_conf, 0);
2557             }
2558         };
2559         warn $@ if $@;
2560         delete $rule->{iface_in};
2561     }
2562
2563     # allow standard traffic for management ipset (includes cluster network)
2564     my $mngmnt_ipset_chain = compute_ipset_chain_name(0, "management", $ipversion);
2565     my $mngmntsrc = "-m set --match-set ${mngmnt_ipset_chain} src";
2566     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 8006", "-j $accept_action");  # PVE API
2567     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 5900:5999", "-j $accept_action");  # PVE VNC Console
2568     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 3128", "-j $accept_action");  # SPICE Proxy
2569     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 22", "-j $accept_action");  # SSH
2570     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 60000:60050", "-j $accept_action");  # Migration
2571
2572     # corosync inbound rules
2573     if (defined($corosync_conf)) {
2574         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule", "-j $accept_action")
2575             if $multicast_enabled;
2576
2577         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2578             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2579             my $destination = $corosync_local_addresses->{$key};
2580
2581             if ($node_name ne $local_hostname && defined($destination)) {
2582                 # accept only traffic on same ring
2583                 ruleset_addrule($ruleset, $chain, "-d $destination -s $node_ip $corosync_rule", "-j $accept_action");
2584             }
2585         });
2586     }
2587
2588     # implement input policy
2589     my $policy = $cluster_options->{policy_in} || 'DROP'; # allow nothing by default
2590     ruleset_add_chain_policy($ruleset, $chain, $ipversion, 0, $policy, $loglevel, $accept_action);
2591
2592     # host outbound firewall
2593     $chain = "PVEFW-HOST-OUT";
2594     ruleset_create_chain($ruleset, $chain);
2595
2596     $loglevel = get_option_log_level($options, "log_level_out");
2597
2598     ruleset_addrule($ruleset, $chain, "-o lo", "-j ACCEPT");
2599
2600     ruleset_chain_add_conn_filters($ruleset, $chain, 0, 'ACCEPT');
2601
2602     # we use RETURN because we may want to check other thigs later
2603     $accept_action = 'RETURN';
2604     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, 'OUT', "-j $accept_action");
2605
2606     ruleset_addrule($ruleset, $chain, "-p igmp", "-j $accept_action"); # important for multicast
2607
2608     # add host rules first, so that cluster wide rules can be overwritten
2609     foreach my $rule (@$rules, @$cluster_rules) {
2610         next if !$rule->{enable} || $rule->{errors};
2611         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2612
2613         $rule->{iface_out} = $rule->{iface} if $rule->{iface};
2614         eval {
2615             $rule->{logmsg} = "$rule->{action}: ";
2616             if ($rule->{type} eq 'group') {
2617                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'OUT', $accept_action, $ipversion);
2618             } elsif ($rule->{type} eq 'out') {
2619                 rule_substitude_action($rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
2620                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $hostfw_conf, 0);
2621             }
2622         };
2623         warn $@ if $@;
2624         delete $rule->{iface_out};
2625     }
2626
2627     # allow standard traffic on cluster network
2628     my $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
2629     my $localnet_ver = $cluster_conf->{aliases}->{local_network}->{ipversion};
2630
2631     if ($localnet && ($ipversion == $localnet_ver)) {
2632         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 8006", "-j $accept_action");  # PVE API
2633         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 22", "-j $accept_action");  # SSH
2634         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 5900:5999", "-j $accept_action");  # PVE VNC Console
2635         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 3128", "-j $accept_action");  # SPICE Proxy
2636     }
2637
2638     # corosync outbound rules
2639     if (defined($corosync_conf)) {
2640         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule", "-j $accept_action")
2641             if $multicast_enabled;
2642
2643         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2644             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2645             my $source = $corosync_local_addresses->{$key};
2646
2647             if ($node_name ne $local_hostname && defined($source)) {
2648                 # accept only traffic on same ring
2649                 ruleset_addrule($ruleset, $chain, "-s $source -d $node_ip $corosync_rule", "-j $accept_action");
2650             }
2651         });
2652     }
2653
2654     # implement output policy
2655     $policy = $cluster_options->{policy_out} || 'ACCEPT'; # allow everything by default
2656     ruleset_add_chain_policy($ruleset, $chain, $ipversion, 0, $policy, $loglevel, $accept_action);
2657
2658     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "", "-j PVEFW-HOST-OUT");
2659     ruleset_addrule($ruleset, "PVEFW-INPUT", "", "-j PVEFW-HOST-IN");
2660 }
2661
2662 sub generate_group_rules {
2663     my ($ruleset, $cluster_conf, $group, $ipversion) = @_;
2664
2665     my $rules = $cluster_conf->{groups}->{$group};
2666
2667     if (!$rules) {
2668         warn "no such security group '$group'\n";
2669         $rules = []; # create empty chain
2670     }
2671
2672     my $chain = "GROUP-${group}-IN";
2673
2674     ruleset_create_chain($ruleset, $chain);
2675     ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2676
2677     foreach my $rule (@$rules) {
2678         next if $rule->{type} ne 'in';
2679         next if !$rule->{enable} || $rule->{errors};
2680         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2681         rule_substitude_action($rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
2682         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf);
2683     }
2684
2685     $chain = "GROUP-${group}-OUT";
2686
2687     ruleset_create_chain($ruleset, $chain);
2688     ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2689
2690     foreach my $rule (@$rules) {
2691         next if $rule->{type} ne 'out';
2692         next if !$rule->{enable} || $rule->{errors};
2693         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2694         # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
2695         # check also other tap rules later
2696         rule_substitude_action($rule, { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" });
2697         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf);
2698     }
2699 }
2700
2701 my $MAX_NETS = 32;
2702 my $valid_netdev_names = {};
2703 for (my $i = 0; $i < $MAX_NETS; $i++)  {
2704     $valid_netdev_names->{"net$i"} = 1;
2705 }
2706
2707 sub get_mark_values {
2708     my ($value, $mask) = @_;
2709     $value = hex($value) if $value =~ /^0x/;
2710     $mask = hex($mask) if defined($mask) && $mask =~ /^0x/;
2711     $mask = 0xffffffff if !defined($mask);
2712     return ($value, $mask);
2713 }
2714
2715 sub parse_fw_rule {
2716     my ($prefix, $line, $cluster_conf, $fw_conf, $rule_env) = @_;
2717
2718     my $orig_line = $line;
2719
2720     my $rule = {};
2721
2722     # we can add single line comments to the end of the rule
2723     if ($line =~ s/#\s*(.*?)\s*$//) {
2724         $rule->{comment} = decode('utf8', $1);
2725     }
2726
2727     # we can disable a rule when prefixed with '|'
2728
2729     $rule->{enable} = $line =~ s/^\|// ? 0 : 1;
2730
2731     $line =~ s/^(\S+)\s+(\S+)\s*// ||
2732         die "unable to parse rule: $line\n";
2733
2734     $rule->{type} = lc($1);
2735     $rule->{action} = $2;
2736
2737     if ($rule->{type} eq  'in' || $rule->{type} eq 'out') {
2738         if ($rule->{action} =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
2739             $rule->{macro} = $1;
2740             $rule->{action} = $2;
2741         }
2742     }
2743
2744     while (length($line)) {
2745         if ($line =~ s/^-i (\S+)\s*//) {
2746             $rule->{iface} = $1;
2747             next;
2748         }
2749
2750         last if $rule->{type} eq 'group';
2751
2752         if ($line =~ s/^(?:-p|--?proto) (\S+)\s*//) {
2753             $rule->{proto} = $1;
2754             next;
2755         }
2756
2757         if ($line =~ s/^--?dport (\S+)\s*//) {
2758             $rule->{dport} = $1;
2759             next;
2760         }
2761
2762         if ($line =~ s/^--?sport (\S+)\s*//) {
2763             $rule->{sport} = $1;
2764             next;
2765         }
2766         if ($line =~ s/^--?source (\S+)\s*//) {
2767             $rule->{source} = $1;
2768             next;
2769         }
2770         if ($line =~ s/^--?dest (\S+)\s*//) {
2771             $rule->{dest} = $1;
2772             next;
2773         }
2774         if ($line =~ s/^--?log (emerg|alert|crit|err|warning|notice|info|debug|nolog)\s*//) {
2775             $rule->{log} = $1;
2776             next;
2777         }
2778         if ($line =~ s/^--?icmp-type (\S+)\s*//) {
2779             $rule->{'icmp-type'} = $1;
2780             next;
2781         }
2782
2783         last;
2784     }
2785
2786     die "unable to parse rule parameters: $line\n" if length($line);
2787
2788     $rule = verify_rule($rule, $cluster_conf, $fw_conf, $rule_env, 1);
2789     if ($rule->{errors}) {
2790         # The verbose flag really means we're running from the CLI and want
2791         # output on the console - in the other case we really want such errors
2792         # to go into the syslog instead.
2793         my $log = $verbose ? sub { warn @_ } : sub { syslog(err => @_) };
2794         $log->("$prefix - errors in rule parameters: $orig_line\n");
2795         foreach my $p (keys %{$rule->{errors}}) {
2796             $log->("  $p: $rule->{errors}->{$p}\n");
2797         }
2798     }
2799
2800     return $rule;
2801 }
2802
2803 sub verify_ethertype {
2804     my ($value) = @_;
2805     my $types = get_etc_ethertypes();
2806     die "unknown ethernet protocol type: $value\n"
2807         if !defined($types->{byname}->{$value}) &&
2808            !defined($types->{byid}->{$value});
2809 }
2810
2811 sub parse_vmfw_option {
2812     my ($line) = @_;
2813
2814     my ($opt, $value);
2815
2816     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2817
2818     if ($line =~ m/^(enable|dhcp|ndp|radv|macfilter|ipfilter|ips):\s*(0|1)\s*$/i) {
2819         $opt = lc($1);
2820         $value = int($2);
2821     } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
2822         $opt = lc($1);
2823         $value = $2 ? lc($3) : '';
2824     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2825         $opt = lc($1);
2826         $value = uc($3);
2827     } elsif ($line =~ m/^(ips_queues):\s*((\d+)(:(\d+))?)\s*$/i) {
2828         $opt = lc($1);
2829         $value = $2;
2830     } elsif ($line =~ m/^(layer2_protocols):\s*(((\S+)[,]?)+)\s*$/i) {
2831         $opt = lc($1);
2832         $value = $2;
2833         verify_ethertype($_) foreach split(/\s*,\s*/, $value);
2834     } else {
2835         die "can't parse option '$line'\n"
2836     }
2837
2838     return ($opt, $value);
2839 }
2840
2841 sub parse_hostfw_option {
2842     my ($line) = @_;
2843
2844     my ($opt, $value);
2845
2846     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2847
2848     if ($line =~ m/^(enable|nosmurfs|tcpflags|ndp|log_nf_conntrack|nf_conntrack_allow_invalid|protection_synflood):\s*(0|1)\s*$/i) {
2849         $opt = lc($1);
2850         $value = int($2);
2851     } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
2852         $opt = lc($1);
2853         $value = $2 ? lc($3) : '';
2854     } elsif ($line =~ m/^(nf_conntrack_max|nf_conntrack_tcp_timeout_established|nf_conntrack_tcp_timeout_syn_recv|protection_synflood_rate|protection_synflood_burst|protection_limit):\s*(\d+)\s*$/i) {
2855         $opt = lc($1);
2856         $value = int($2);
2857     } else {
2858         die "can't parse option '$line'\n"
2859     }
2860
2861     return ($opt, $value);
2862 }
2863
2864 sub parse_clusterfw_option {
2865     my ($line) = @_;
2866
2867     my ($opt, $value);
2868
2869     if ($line =~ m/^(enable):\s*(\d+)\s*$/i) {
2870         $opt = lc($1);
2871         $value = int($2);
2872         if (($value > 1) && ((time() - $value) > 60)) {
2873             $value = 0
2874         }
2875     } elsif ($line =~ m/^(ebtables):\s*(0|1)\s*$/i) {
2876         $opt = lc($1);
2877         $value = int($2);
2878     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2879         $opt = lc($1);
2880         $value = uc($3);
2881     } elsif ($line =~ m/^(log_ratelimit):\s*(\S+)\s*$/) {
2882         $opt = lc($1);
2883         $value = $2;
2884     } else {
2885         die "can't parse option '$line'\n"
2886     }
2887
2888     return ($opt, $value);
2889 }
2890
2891 sub resolve_alias {
2892     my ($clusterfw_conf, $fw_conf, $cidr) = @_;
2893
2894     my $alias = lc($cidr);
2895     my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
2896     $e = $clusterfw_conf->{aliases}->{$alias} if !$e && $clusterfw_conf;
2897
2898     die "no such alias '$cidr'\n" if !$e;;
2899
2900     return wantarray ? ($e->{cidr}, $e->{ipversion}) : $e->{cidr};
2901 }
2902
2903 sub parse_ip_or_cidr {
2904     my ($cidr) = @_;
2905
2906     my $ipversion;
2907
2908     if ($cidr =~ m!^(?:$IPV6RE)(/(\d+))?$!) {
2909         $cidr =~ s|/128$||;
2910         $ipversion = 6;
2911     } elsif ($cidr =~ m!^(?:$IPV4RE)(/(\d+))?$!) {
2912         $cidr =~ s|/32$||;
2913         $ipversion = 4;
2914     } else {
2915         die "value does not look like a valid IP address or CIDR network\n";
2916     }
2917
2918     return wantarray ? ($cidr, $ipversion) : $cidr;
2919 }
2920
2921 sub parse_alias {
2922     my ($line) = @_;
2923
2924     # we can add single line comments to the end of the line
2925     my $comment = decode('utf8', $1) if $line =~ s/\s*#\s*(.*?)\s*$//;
2926
2927     if ($line =~ m/^(\S+)\s(\S+)$/) {
2928         my ($name, $cidr) = ($1, $2);
2929         my $ipversion;
2930
2931         ($cidr, $ipversion) = parse_ip_or_cidr($cidr);
2932
2933         my $data = {
2934             name => $name,
2935             cidr => $cidr,
2936             ipversion => $ipversion,
2937         };
2938         $data->{comment} = $comment  if $comment;
2939         return $data;
2940     }
2941
2942     return undef;
2943 }
2944
2945 sub generic_fw_config_parser {
2946     my ($filename, $cluster_conf, $empty_conf, $rule_env) = @_;
2947
2948     my $section;
2949     my $group;
2950
2951     my $res = $empty_conf;
2952
2953     my $raw;
2954     if ($filename =~ m!^/etc/pve/(.*)$!) {
2955         $raw = PVE::Cluster::get_config($1);
2956     } else {
2957         $raw = eval { PVE::Tools::file_get_contents($filename) }; # ignore errors
2958     }
2959     return {} if !$raw;
2960
2961     my $curr_group_keys = {};
2962
2963     my $linenr = 0;
2964     while ($raw =~ /^\h*(.*?)\h*$/gm) {
2965         my $line = $1;
2966         $linenr++;
2967         next if $line =~ m/^#/;
2968         next if $line =~ m/^\s*$/;
2969         chomp $line;
2970
2971         my $prefix = "$filename (line $linenr)";
2972
2973         if ($empty_conf->{options} && ($line =~ m/^\[options\]$/i)) {
2974             $section = 'options';
2975             next;
2976         }
2977
2978         if ($empty_conf->{aliases} && ($line =~ m/^\[aliases\]$/i)) {
2979             $section = 'aliases';
2980             next;
2981         }
2982
2983         if ($empty_conf->{groups} && ($line =~ m/^\[group\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
2984             $section = 'groups';
2985             $group = lc($1);
2986             my $comment = $2;
2987             eval {
2988                 die "security group name too long\n" if length($group) > $max_group_name_length;
2989                 die "invalid security group name '$group'\n" if $group !~ m/^${security_group_name_pattern}$/;
2990             };
2991             if (my $err = $@) {
2992                 ($section, $group, $comment) = undef;
2993                 warn "$prefix: $err";
2994                 next;
2995             }
2996
2997             $res->{$section}->{$group} = [];
2998             $res->{group_comments}->{$group} =  decode('utf8', $comment)
2999                 if $comment;
3000             next;
3001         }
3002
3003         if ($empty_conf->{rules} && ($line =~ m/^\[rules\]$/i)) {
3004             $section = 'rules';
3005             next;
3006         }
3007
3008         if ($empty_conf->{ipset} && ($line =~ m/^\[ipset\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
3009             $section = 'ipset';
3010             $group = lc($1);
3011             my $comment = $2;
3012             eval {
3013                 die "ipset name too long\n" if length($group) > $max_ipset_name_length;
3014                 die "invalid ipset name '$group'\n" if $group !~ m/^${ipset_name_pattern}$/;
3015             };
3016             if (my $err = $@) {
3017                 ($section, $group, $comment) = undef;
3018                 warn "$prefix: $err";
3019                 next;
3020             }
3021
3022             $res->{$section}->{$group} = [];
3023             $curr_group_keys = {};
3024
3025             $res->{ipset_comments}->{$group} = decode('utf8', $comment)
3026                 if $comment;
3027             next;
3028         }
3029
3030         if (!$section) {
3031             warn "$prefix: skip line - no section\n";
3032             next;
3033         }
3034
3035         if ($section eq 'options') {
3036             eval {
3037                 my ($opt, $value);
3038                 if ($rule_env eq 'cluster') {
3039                     ($opt, $value) = parse_clusterfw_option($line);
3040                 } elsif ($rule_env eq 'host') {
3041                     ($opt, $value) = parse_hostfw_option($line);
3042                 } else {
3043                     ($opt, $value) = parse_vmfw_option($line);
3044                 }
3045                 $res->{options}->{$opt} = $value;
3046             };
3047             warn "$prefix: $@" if $@;
3048         } elsif ($section eq 'aliases') {
3049             eval {
3050                 my $data = parse_alias($line);
3051                 $res->{aliases}->{lc($data->{name})} = $data;
3052             };
3053             warn "$prefix: $@" if $@;
3054         } elsif ($section eq 'rules') {
3055             my $rule;
3056             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, $res, $rule_env); };
3057             if (my $err = $@) {
3058                 warn "$prefix: $err";
3059                 next;
3060             }
3061             push @{$res->{$section}}, $rule;
3062         } elsif ($section eq 'groups') {
3063             my $rule;
3064             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, undef, 'group'); };
3065             if (my $err = $@) {
3066                 warn "$prefix: $err";
3067                 next;
3068             }
3069             push @{$res->{$section}->{$group}}, $rule;
3070         } elsif ($section eq 'ipset') {
3071             # we can add single line comments to the end of the rule
3072             my $comment = decode('utf8', $1) if $line =~ s/#\s*(.*?)\s*$//;
3073
3074             $line =~ m/^(\!)?\s*(\S+)\s*$/;
3075             my $nomatch = $1;
3076             my $cidr = $2;
3077             my $errors;
3078
3079             if ($nomatch && !$feature_ipset_nomatch) {
3080                 $errors->{nomatch} = "nomatch not supported by kernel";
3081             }
3082
3083             eval {
3084                 if ($cidr =~ m/^${ip_alias_pattern}$/) {
3085                     resolve_alias($cluster_conf, $res, $cidr); # make sure alias exists
3086                 } else {
3087                     $cidr = parse_ip_or_cidr($cidr);
3088                 }
3089                 die "duplicate ipset entry for '$cidr'\n"
3090                     if defined($curr_group_keys->{$cidr});
3091             };
3092             if (my $err = $@) {
3093                 chomp $err;
3094                 $errors->{cidr} = $err;
3095             }
3096
3097             if ($cidr =~ m!/0+$!) {
3098                 $errors->{cidr} = "a zero prefix is not allowed in ipset entries\n";
3099             }
3100
3101             my $entry = { cidr => $cidr };
3102             $entry->{nomatch} = 1 if $nomatch;
3103             $entry->{comment} = $comment if $comment;
3104             $entry->{errors} =  $errors if $errors;
3105
3106             if ($verbose && $errors) {
3107                 warn "$prefix - errors in ipset '$group': $line\n";
3108                 foreach my $p (keys %{$errors}) {
3109                     warn "  $p: $errors->{$p}\n";
3110                 }
3111             }
3112
3113             push @{$res->{$section}->{$group}}, $entry;
3114             $curr_group_keys->{$cidr} = 1;
3115         } else {
3116             warn "$prefix: skip line - unknown section\n";
3117             next;
3118         }
3119     }
3120
3121     return $res;
3122 }
3123
3124 # this is only used to prevent concurrent runs of rule compilation/application
3125 # see lock_*_conf for cfs locks protectiong config modification
3126 sub run_locked {
3127     my ($code, @param) = @_;
3128
3129     my $timeout = 10;
3130
3131     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
3132
3133     die $@ if $@;
3134
3135     return $res;
3136 }
3137
3138 sub read_local_vm_config {
3139
3140     my $qemu = {};
3141     my $lxc = {};
3142
3143     my $vmdata = { qemu => $qemu, lxc => $lxc };
3144
3145     my $vmlist = PVE::Cluster::get_vmlist();
3146     return $vmdata if !$vmlist || !$vmlist->{ids};
3147     my $ids = $vmlist->{ids};
3148
3149     foreach my $vmid (keys %$ids) {
3150         next if !$vmid; # skip VE0
3151         my $d = $ids->{$vmid};
3152         next if !$d->{node} || $d->{node} ne $nodename;
3153         next if !$d->{type};
3154         if ($d->{type} eq 'qemu') {
3155             if ($have_qemu_server) {
3156                 my $cfspath = PVE::QemuConfig->cfs_config_path($vmid);
3157                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
3158                     $qemu->{$vmid} = $conf;
3159                 }
3160             }
3161         } elsif ($d->{type} eq 'lxc') {
3162             if ($have_lxc) {
3163                 my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
3164                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
3165                     $lxc->{$vmid} = $conf;
3166                 }
3167             }
3168         }
3169     }
3170
3171     return $vmdata;
3172 };
3173
3174 sub lock_vmfw_conf {
3175     my ($vmid, $timeout, $code, @param) = @_;
3176
3177     die "can't lock VM firewall config for undefined VMID\n"
3178         if !defined($vmid);
3179
3180     my $res = PVE::Cluster::cfs_lock_firewall("vm-$vmid", $timeout, $code, @param);
3181     die $@ if $@;
3182
3183     return $res;
3184 }
3185
3186 sub load_vmfw_conf {
3187     my ($cluster_conf, $rule_env, $vmid, $dir) = @_;
3188
3189     $dir = $pvefw_conf_dir if !defined($dir);
3190     my $filename = "$dir/$vmid.fw";
3191
3192     my $empty_conf = {
3193         rules => [],
3194         options => {},
3195         aliases => {},
3196         ipset => {} ,
3197         ipset_comments => {},
3198     };
3199
3200     my $vmfw_conf = generic_fw_config_parser($filename, $cluster_conf, $empty_conf, $rule_env);
3201     $vmfw_conf->{vmid} = $vmid;
3202
3203     return $vmfw_conf;
3204 }
3205
3206 my $format_rules = sub {
3207     my ($rules, $allow_iface) = @_;
3208
3209     my $raw = '';
3210
3211     foreach my $rule (@$rules) {
3212         if ($rule->{type} eq  'in' || $rule->{type} eq 'out' || $rule->{type} eq 'group') {
3213             $raw .= '|' if defined($rule->{enable}) && !$rule->{enable};
3214             $raw .= uc($rule->{type});
3215             if ($rule->{macro}) {
3216                 $raw .= " $rule->{macro}($rule->{action})";
3217             } else {
3218                 $raw .= " " . $rule->{action};
3219             }
3220             if ($allow_iface && $rule->{iface}) {
3221                 $raw .= " -i $rule->{iface}";
3222             }
3223
3224             if ($rule->{type} ne  'group')  {
3225                 $raw .= " -source $rule->{source}" if $rule->{source};
3226                 $raw .= " -dest $rule->{dest}" if $rule->{dest};
3227                 $raw .= " -p $rule->{proto}" if $rule->{proto};
3228                 $raw .= " -dport $rule->{dport}" if $rule->{dport};
3229                 $raw .= " -sport $rule->{sport}" if $rule->{sport};
3230                 $raw .= " -log $rule->{log}" if $rule->{log};
3231                 $raw .= " -icmp-type $rule->{'icmp-type'}" if defined($rule->{'icmp-type'}) && $rule->{'icmp-type'} ne '';
3232             }
3233
3234             $raw .= " # " . encode('utf8', $rule->{comment})
3235                 if $rule->{comment} && $rule->{comment} !~ m/^\s*$/;
3236             $raw .= "\n";
3237         } else {
3238             die "unknown rule type '$rule->{type}'";
3239         }
3240     }
3241
3242     return $raw;
3243 };
3244
3245 my $format_options = sub {
3246     my ($options) = @_;
3247
3248     my $raw = '';
3249
3250     $raw .= "[OPTIONS]\n\n";
3251     foreach my $opt (keys %$options) {
3252         $raw .= "$opt: $options->{$opt}\n";
3253     }
3254     $raw .= "\n";
3255
3256     return $raw;
3257 };
3258
3259 my $format_aliases = sub {
3260     my ($aliases) = @_;
3261
3262     my $raw = '';
3263
3264     $raw .= "[ALIASES]\n\n";
3265     foreach my $k (keys %$aliases) {
3266         my $e = $aliases->{$k};
3267         $raw .= "$e->{name} $e->{cidr}";
3268         $raw .= " # " . encode('utf8', $e->{comment})
3269             if $e->{comment} && $e->{comment} !~ m/^\s*$/;
3270         $raw .= "\n";
3271     }
3272     $raw .= "\n";
3273
3274     return $raw;
3275 };
3276
3277 my $format_ipsets = sub {
3278     my ($fw_conf) = @_;
3279
3280     my $raw = '';
3281
3282     foreach my $ipset (sort keys %{$fw_conf->{ipset}}) {
3283         if (my $comment = $fw_conf->{ipset_comments}->{$ipset}) {
3284             my $utf8comment = encode('utf8', $comment);
3285             $raw .= "[IPSET $ipset] # $utf8comment\n\n";
3286         } else {
3287             $raw .= "[IPSET $ipset]\n\n";
3288         }
3289         my $options = $fw_conf->{ipset}->{$ipset};
3290
3291         my $nethash = {};
3292         foreach my $entry (@$options) {
3293             my $cidr = $entry->{cidr};
3294             if (defined($nethash->{$cidr})) {
3295                 warn "ignoring duplicate ipset entry '$cidr'\n";
3296                 next;
3297             }
3298
3299             $nethash->{$cidr} = $entry;
3300         }
3301
3302         foreach my $cidr (sort keys %$nethash) {
3303             my $entry = $nethash->{$cidr};
3304             my $line = $entry->{nomatch} ? '!' : '';
3305             $line .= $entry->{cidr};
3306             $line .= " # " . encode('utf8', $entry->{comment})
3307                 if $entry->{comment} && $entry->{comment} !~ m/^\s*$/;
3308             $raw .= "$line\n";
3309         }
3310
3311         $raw .= "\n";
3312     }
3313
3314     return $raw;
3315 };
3316
3317 sub save_vmfw_conf {
3318     my ($vmid, $vmfw_conf) = @_;
3319
3320     my $raw = '';
3321
3322     my $options = $vmfw_conf->{options};
3323     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3324
3325     my $aliases = $vmfw_conf->{aliases};
3326     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
3327
3328     $raw .= &$format_ipsets($vmfw_conf) if $vmfw_conf->{ipset};
3329
3330     my $rules = $vmfw_conf->{rules} || [];
3331     if ($rules && scalar(@$rules)) {
3332         $raw .= "[RULES]\n\n";
3333         $raw .= &$format_rules($rules, 1);
3334         $raw .= "\n";
3335     }
3336
3337     my $filename = "$pvefw_conf_dir/$vmid.fw";
3338     if ($raw) {
3339         mkdir $pvefw_conf_dir;
3340         PVE::Tools::file_set_contents($filename, $raw);
3341     } else {
3342         unlink $filename;
3343     }
3344 }
3345
3346 sub remove_vmfw_conf {
3347     my ($vmid) = @_;
3348
3349     my $vmfw_conffile = "$pvefw_conf_dir/$vmid.fw";
3350
3351     unlink $vmfw_conffile;
3352 }
3353
3354 sub clone_vmfw_conf {
3355     my ($vmid, $newid) = @_;
3356
3357     my $sourcevm_conffile = "$pvefw_conf_dir/$vmid.fw";
3358     my $clonevm_conffile = "$pvefw_conf_dir/$newid.fw";
3359
3360     lock_vmfw_conf($newid, 10, sub {
3361         if (-f $clonevm_conffile) {
3362             unlink $clonevm_conffile;
3363         }
3364         if (-f $sourcevm_conffile) {
3365             my $data = PVE::Tools::file_get_contents($sourcevm_conffile);
3366             PVE::Tools::file_set_contents($clonevm_conffile, $data);
3367         }
3368     });
3369 }
3370
3371 sub read_vm_firewall_configs {
3372     my ($cluster_conf, $vmdata, $dir) = @_;
3373
3374     my $vmfw_configs = {};
3375
3376     foreach my $vmid (keys %{$vmdata->{qemu}}) {
3377         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'vm', $vmid, $dir);
3378         next if !$vmfw_conf->{options}; # skip if file does not exist
3379         $vmfw_configs->{$vmid} = $vmfw_conf;
3380     }
3381     foreach my $vmid (keys %{$vmdata->{lxc}}) {
3382         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'ct', $vmid, $dir);
3383         next if !$vmfw_conf->{options}; # skip if file does not exist
3384         $vmfw_configs->{$vmid} = $vmfw_conf;
3385     }
3386
3387     return $vmfw_configs;
3388 }
3389
3390 sub get_option_log_level {
3391     my ($options, $k) = @_;
3392
3393     my $v = $options->{$k};
3394     $v = $default_log_level if !defined($v);
3395
3396     return undef if $v eq '' || $v eq 'nolog';
3397
3398     return $v if defined($log_level_hash->{$v});
3399
3400     warn "unknown log level ($k = '$v')\n";
3401
3402     return undef;
3403 }
3404
3405 sub generate_std_chains {
3406     my ($ruleset, $options, $ipversion) = @_;
3407
3408     my $std_chains = $pve_std_chains->{$ipversion} || die "internal error";
3409
3410     my $loglevel = get_option_log_level($options, 'smurf_log_level');
3411     my $chain = 'PVEFW-smurflog';
3412     if ( $std_chains->{$chain} ) {
3413         foreach my $r (@{$std_chains->{$chain}}) {
3414           $r->{log} = $loglevel;
3415         }
3416     }
3417
3418     # same as shorewall logflags action.
3419     $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
3420     $chain = 'PVEFW-logflags';
3421     if ( $std_chains->{$chain} ) {
3422         foreach my $r (@{$std_chains->{$chain}}) {
3423           $r->{log} = $loglevel;
3424         }
3425     }
3426
3427     foreach my $chain (keys %$std_chains) {
3428         ruleset_create_chain($ruleset, $chain);
3429         foreach my $rule (@{$std_chains->{$chain}}) {
3430             if (ref($rule)) {
3431                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, 0);
3432             } else {
3433                 die "rule $rule as string - should not happen";
3434             }
3435         }
3436     }
3437 }
3438
3439 sub generate_ipset_chains {
3440     my ($ipset_ruleset, $clusterfw_conf, $fw_conf, $device_ips, $ipsets) = @_;
3441
3442     foreach my $ipset (keys %{$ipsets}) {
3443
3444         my $options = $ipsets->{$ipset};
3445
3446         if ($device_ips && $ipset =~ /^ipfilter-(net\d+)$/) {
3447             if (my $ips = $device_ips->{$1}) {
3448                 $options = [@$options, @$ips];
3449             }
3450         }
3451
3452         # remove duplicates
3453         my $nethash = {};
3454         foreach my $entry (@$options) {
3455             next if $entry->{errors}; # skip entries with errors
3456             eval {
3457                 my ($cidr, $ver);
3458                 if ($entry->{cidr} =~ m/^${ip_alias_pattern}$/) {
3459                     ($cidr, $ver) = resolve_alias($clusterfw_conf, $fw_conf, $entry->{cidr});
3460                 } else {
3461                     ($cidr, $ver) = parse_ip_or_cidr($entry->{cidr});
3462                 }
3463                 #http://backreference.org/2013/03/01/ipv6-address-normalization/
3464                 if ($ver == 6) {
3465                     # ip_compress_address takes an address only, no CIDR
3466                     my ($addr, $prefix_len) = ($cidr =~ m@^([^/]*)(/.*)?$@);
3467                     $cidr = lc(Net::IP::ip_compress_address($addr, 6));
3468                     $cidr .= $prefix_len if defined($prefix_len);
3469                     $cidr =~ s|/128$||;
3470                 } else {
3471                     $cidr =~ s|/32$||;
3472                 }
3473
3474                 $nethash->{$ver}->{$cidr} = { cidr => $cidr, nomatch => $entry->{nomatch} };
3475             };
3476             warn $@ if $@;
3477         }
3478
3479         foreach my $ipversion (4, 6) {
3480             my $data = $nethash->{$ipversion};
3481
3482             my $name = compute_ipset_chain_name($fw_conf->{vmid}, $ipset, $ipversion);
3483
3484             my $hashsize = scalar(@$options);
3485             if ($hashsize <= 64) {
3486                 $hashsize = 64;
3487             } else {
3488                 $hashsize = round_powerof2($hashsize);
3489             }
3490
3491             my $family = $ipversion == "6" ? "inet6" : "inet";
3492
3493             $ipset_ruleset->{$name} = ["create $name hash:net family $family hashsize $hashsize maxelem $hashsize"];
3494
3495             foreach my $cidr (sort keys %$data) {
3496                 my $entry = $data->{$cidr};
3497
3498                 my $cmd = "add $name $cidr";
3499                 if ($entry->{nomatch}) {
3500                     if ($feature_ipset_nomatch) {
3501                         push @{$ipset_ruleset->{$name}}, "$cmd nomatch";
3502                     } else {
3503                         warn "ignore !$cidr - nomatch not supported by kernel\n";
3504                     }
3505                 } else {
3506                     push @{$ipset_ruleset->{$name}}, $cmd;
3507                 }
3508             }
3509         }
3510     }
3511 }
3512
3513 sub round_powerof2 {
3514     my ($int) = @_;
3515
3516     $int--;
3517     $int |= $int >> $_ foreach (1,2,4,8,16);
3518     return ++$int;
3519 }
3520
3521 my $set_global_log_ratelimit = sub {
3522     my $cluster_opts = shift;
3523
3524     $global_log_ratelimit = '--limit 1/sec';
3525     if (defined(my $log_rlimit = $cluster_opts->{log_ratelimit})) {
3526         my $ll_format = $cluster_option_properties->{log_ratelimit}->{format};
3527         my $limit = PVE::JSONSchema::parse_property_string($ll_format, $log_rlimit);
3528
3529         if ($limit->{enable}) {
3530             if (my $rate = $limit->{rate}) {
3531                 $global_log_ratelimit = "--limit $rate";
3532             }
3533             if (my $burst = $limit->{burst}) {
3534                 $global_log_ratelimit .= " --limit-burst $burst";
3535             }
3536         } else {
3537             $global_log_ratelimit = undef;
3538         }
3539     }
3540 };
3541
3542 sub lock_clusterfw_conf {
3543     my ($timeout, $code, @param) = @_;
3544
3545     my $res = PVE::Cluster::cfs_lock_firewall("cluster", $timeout, $code, @param);
3546     die $@ if $@;
3547
3548     return $res;
3549 }
3550
3551 sub load_clusterfw_conf {
3552     my ($filename) = @_;
3553
3554     $filename = $clusterfw_conf_filename if !defined($filename);
3555     my $empty_conf = {
3556         rules => [],
3557         options => {},
3558         aliases => {},
3559         groups => {},
3560         group_comments => {},
3561         ipset => {} ,
3562         ipset_comments => {},
3563     };
3564
3565     my $cluster_conf = generic_fw_config_parser($filename, $empty_conf, $empty_conf, 'cluster');
3566     $set_global_log_ratelimit->($cluster_conf->{options});
3567
3568     return $cluster_conf;
3569 }
3570
3571 sub save_clusterfw_conf {
3572     my ($cluster_conf) = @_;
3573
3574     my $raw = '';
3575
3576     my $options = $cluster_conf->{options};
3577     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3578
3579     my $aliases = $cluster_conf->{aliases};
3580     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
3581
3582     $raw .= &$format_ipsets($cluster_conf) if $cluster_conf->{ipset};
3583
3584     my $rules = $cluster_conf->{rules};
3585     if ($rules && scalar(@$rules)) {
3586         $raw .= "[RULES]\n\n";
3587         $raw .= &$format_rules($rules, 1);
3588         $raw .= "\n";
3589     }
3590
3591     if ($cluster_conf->{groups}) {
3592         foreach my $group (sort keys %{$cluster_conf->{groups}}) {
3593             my $rules = $cluster_conf->{groups}->{$group};
3594             if (my $comment = $cluster_conf->{group_comments}->{$group}) {
3595                 my $utf8comment = encode('utf8', $comment);
3596                 $raw .= "[group $group] # $utf8comment\n\n";
3597             } else {
3598                 $raw .= "[group $group]\n\n";
3599             }
3600
3601             $raw .= &$format_rules($rules, 0);
3602             $raw .= "\n";
3603         }
3604     }
3605
3606     if ($raw) {
3607         mkdir $pvefw_conf_dir;
3608         PVE::Tools::file_set_contents($clusterfw_conf_filename, $raw);
3609     } else {
3610         unlink $clusterfw_conf_filename;
3611     }
3612 }
3613
3614 sub lock_hostfw_conf {
3615     my ($timeout, $code, @param) = @_;
3616
3617     my $res = PVE::Cluster::cfs_lock_firewall("host-$nodename", $timeout, $code, @param);
3618     die $@ if $@;
3619
3620     return $res;
3621 }
3622
3623 sub load_hostfw_conf {
3624     my ($cluster_conf, $filename) = @_;
3625
3626     $filename = $hostfw_conf_filename if !defined($filename);
3627
3628     my $empty_conf = { rules => [], options => {}};
3629     return generic_fw_config_parser($filename, $cluster_conf, $empty_conf, 'host');
3630 }
3631
3632 sub save_hostfw_conf {
3633     my ($hostfw_conf) = @_;
3634
3635     my $raw = '';
3636
3637     my $options = $hostfw_conf->{options};
3638     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3639
3640     my $rules = $hostfw_conf->{rules};
3641     if ($rules && scalar(@$rules)) {
3642         $raw .= "[RULES]\n\n";
3643         $raw .= &$format_rules($rules, 1);
3644         $raw .= "\n";
3645     }
3646
3647     if ($raw) {
3648         PVE::Tools::file_set_contents($hostfw_conf_filename, $raw);
3649     } else {
3650         unlink $hostfw_conf_filename;
3651     }
3652 }
3653
3654 sub compile {
3655     my ($cluster_conf, $hostfw_conf, $vmdata, $corosync_conf) = @_;
3656
3657     my $vmfw_configs;
3658
3659     # fixme: once we read standard chains from config this needs to be put in test/standard cases below
3660     $pve_std_chains = dclone($pve_std_chains_conf);
3661
3662     if ($vmdata) { # test mode
3663         my $testdir = $vmdata->{testdir} || die "no test directory specified";
3664         my $filename = "$testdir/cluster.fw";
3665         $cluster_conf = load_clusterfw_conf($filename);
3666
3667         $filename = "$testdir/host.fw";
3668         $hostfw_conf = load_hostfw_conf($cluster_conf, $filename);
3669
3670         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, $testdir);
3671     } else { # normal operation
3672         $cluster_conf = load_clusterfw_conf(undef) if !$cluster_conf;
3673
3674         $hostfw_conf = load_hostfw_conf($cluster_conf, undef) if !$hostfw_conf;
3675
3676         # cfs_update is handled by daemon or API
3677         $corosync_conf = PVE::Cluster::cfs_read_file("corosync.conf")
3678             if !defined($corosync_conf) && PVE::Corosync::check_conf_exists(1);
3679
3680         $vmdata = read_local_vm_config();
3681         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, undef);
3682     }
3683
3684     return ({},{},{},{}) if !$cluster_conf->{options}->{enable};
3685
3686     my $localnet;
3687     if ($cluster_conf->{aliases}->{local_network}) {
3688         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
3689     } else {
3690         my $localnet_ver;
3691         ($localnet, $localnet_ver) = parse_ip_or_cidr(local_network() || '127.0.0.0/8');
3692
3693         $cluster_conf->{aliases}->{local_network} = {
3694             name => 'local_network', cidr => $localnet, ipversion => $localnet_ver };
3695     }
3696
3697     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
3698
3699     my $ruleset = {};
3700     my $rulesetv6 = {};
3701     $ruleset->{filter} = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 4);
3702     $ruleset->{raw} = compile_iptables_raw($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 4);
3703     $rulesetv6->{filter} = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 6);
3704     $rulesetv6->{raw} = compile_iptables_raw($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 6);
3705     my $ebtables_ruleset = compile_ebtables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata);
3706     my $ipset_ruleset = compile_ipsets($cluster_conf, $vmfw_configs, $vmdata);
3707
3708     return ($ruleset, $ipset_ruleset, $rulesetv6, $ebtables_ruleset);
3709 }
3710
3711 sub compile_iptables_raw {
3712     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, $ipversion) = @_;
3713
3714     my $ruleset = {};
3715
3716     my $hostfw_options = $hostfw_conf->{options} || {};
3717     my $protection_synflood = $hostfw_options->{protection_synflood} || 0;
3718
3719     if($protection_synflood) {
3720
3721         my $protection_synflood_rate = $hostfw_options->{protection_synflood_rate} ? $hostfw_options->{protection_synflood_rate} : 200;
3722         my $protection_synflood_burst = $hostfw_options->{protection_synflood_burst} ? $hostfw_options->{protection_synflood_burst} : 1000;
3723         my $protection_synflood_limit = $hostfw_options->{protection_synflood_limit} ? $hostfw_options->{protection_synflood_limit} : 3000;
3724         my $protection_synflood_expire = $hostfw_options->{nf_conntrack_tcp_timeout_syn_recv} ? $hostfw_options->{nf_conntrack_tcp_timeout_syn_recv} : 60;
3725         $protection_synflood_expire = $protection_synflood_expire * 1000;
3726         my $protection_synflood_mask = $ipversion == 4 ? 32 : 64;
3727
3728         ruleset_create_chain($ruleset, "PVEFW-PREROUTING");
3729         ruleset_addrule($ruleset, "PVEFW-PREROUTING", "-p tcp -m tcp --tcp-flags FIN,SYN,RST,ACK SYN -m hashlimit --hashlimit-above $protection_synflood_rate/sec --hashlimit-burst $protection_synflood_burst --hashlimit-mode srcip --hashlimit-name syn --hashlimit-htable-size 2097152 --hashlimit-srcmask $protection_synflood_mask --hashlimit-htable-expire $protection_synflood_expire", "-j DROP");
3730     }
3731
3732     return $ruleset;
3733 }
3734
3735 sub compile_iptables_filter {
3736     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, $ipversion) = @_;
3737
3738     my $ruleset = {};
3739
3740     ruleset_create_chain($ruleset, "PVEFW-INPUT");
3741     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
3742
3743     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
3744
3745     my $hostfw_options = $hostfw_conf->{options} || {};
3746
3747     # fixme: what log level should we use here?
3748     my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
3749
3750     my $conn_allow_invalid = $hostfw_options->{nf_conntrack_allow_invalid} // 0;
3751     ruleset_chain_add_conn_filters($ruleset, "PVEFW-FORWARD", $conn_allow_invalid, "ACCEPT");
3752
3753     ruleset_create_chain($ruleset, "PVEFW-FWBR-IN");
3754     ruleset_chain_add_input_filters($ruleset, "PVEFW-FWBR-IN", $ipversion, $hostfw_options, $cluster_conf, $loglevel);
3755
3756     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-in fwln+", "-j PVEFW-FWBR-IN");
3757
3758     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
3759     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-out fwln+", "-j PVEFW-FWBR-OUT");
3760
3761     generate_std_chains($ruleset, $hostfw_options, $ipversion);
3762
3763     my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
3764
3765     if ($hostfw_enable) {
3766         eval { enable_host_firewall($ruleset, $hostfw_conf, $cluster_conf, $ipversion, $corosync_conf); };
3767         warn $@ if $@; # just to be sure - should not happen
3768     }
3769
3770     # generate firewall rules for QEMU VMs
3771     foreach my $vmid (sort keys %{$vmdata->{qemu}}) {
3772         eval {
3773             my $conf = $vmdata->{qemu}->{$vmid};
3774             my $vmfw_conf = $vmfw_configs->{$vmid};
3775             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
3776
3777             foreach my $netid (sort keys %$conf) {
3778                 next if $netid !~ m/^net(\d+)$/;
3779                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3780                 next if !$net->{firewall};
3781
3782                 my $iface = "tap${vmid}i$1";
3783                 my $macaddr = $net->{macaddr};
3784                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3785                                              $vmfw_conf, $vmid, 'IN', $ipversion);
3786                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3787                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
3788             }
3789         };
3790         warn $@ if $@; # just to be sure - should not happen
3791     }
3792
3793     # generate firewall rules for LXC containers
3794     foreach my $vmid (sort keys %{$vmdata->{lxc}}) {
3795         eval {
3796             my $conf = $vmdata->{lxc}->{$vmid};
3797             my $vmfw_conf = $vmfw_configs->{$vmid};
3798             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
3799
3800             foreach my $netid (sort keys %$conf) {
3801                 next if $netid !~ m/^net(\d+)$/;
3802                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
3803                 next if !$net->{firewall};
3804
3805                 my $iface = "veth${vmid}i$1";
3806                 my $macaddr = $net->{hwaddr};
3807                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3808                                              $vmfw_conf, $vmid, 'IN', $ipversion);
3809                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3810                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
3811             }
3812         };
3813         warn $@ if $@; # just to be sure - should not happen
3814     }
3815
3816     if (ruleset_chain_exist($ruleset, "PVEFW-IPS")){
3817         ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED", "-j PVEFW-IPS");
3818     }
3819
3820     return $ruleset;
3821 }
3822
3823 sub mac_to_linklocal {
3824     my ($macaddr) = @_;
3825     my @parts = split(/:/, $macaddr);
3826     # The standard link local address uses the fe80::/64 prefix with the
3827     # modified EUI-64 identifier derived from the MAC address by flipping the
3828     # universal/local bit and inserting FF:FE in the middle.
3829     # See RFC 4291.
3830     $parts[0] = sprintf("%02x", hex($parts[0]) ^ 0x02);
3831     my @meui64 = (@parts[0,1,2], 'ff', 'fe', @parts[3,4,5]);
3832     return "fe80::$parts[0]$parts[1]:$parts[2]FF:FE$parts[3]:$parts[4]$parts[5]";
3833 }
3834
3835 sub compile_ipsets {
3836     my ($cluster_conf, $vmfw_configs, $vmdata) = @_;
3837
3838     my $localnet;
3839     if ($cluster_conf->{aliases}->{local_network}) {
3840         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
3841     } else {
3842         my $localnet_ver;
3843         ($localnet, $localnet_ver) = parse_ip_or_cidr(local_network() || '127.0.0.0/8');
3844
3845         $cluster_conf->{aliases}->{local_network} = {
3846             name => 'local_network', cidr => $localnet, ipversion => $localnet_ver };
3847     }
3848
3849     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
3850
3851
3852     my $ipset_ruleset = {};
3853
3854     # generate ipsets for QEMU VMs
3855     foreach my $vmid (keys %{$vmdata->{qemu}}) {
3856         eval {
3857             my $conf = $vmdata->{qemu}->{$vmid};
3858             my $vmfw_conf = $vmfw_configs->{$vmid};
3859             return if !$vmfw_conf;
3860
3861             # When the 'ipfilter' option is enabled every device for which there
3862             # is no 'ipfilter-netX' ipset defined gets an implicit empty default
3863             # ipset.
3864             # The reason is that ipfilter ipsets are always filled with standard
3865             # IPv6 link-local filters.
3866             my $ipsets = $vmfw_conf->{ipset};
3867             my $implicit_sets = {};
3868
3869             my $device_ips = {};
3870             foreach my $netid (keys %$conf) {
3871                 next if $netid !~ m/^net(\d+)$/;
3872                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3873                 next if !$net->{firewall};
3874
3875                 if ($vmfw_conf->{options}->{ipfilter} && !$ipsets->{"ipfilter-$netid"}) {
3876                     $implicit_sets->{"ipfilter-$netid"} = [];
3877                 }
3878
3879                 my $macaddr = $net->{macaddr};
3880                 my $linklocal = mac_to_linklocal($macaddr);
3881                 $device_ips->{$netid} = [
3882                     { cidr => $linklocal },
3883                     { cidr => 'fe80::/10', nomatch => 1 }
3884                 ];
3885             }
3886
3887             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $ipsets);
3888             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $implicit_sets);
3889         };
3890         warn $@ if $@; # just to be sure - should not happen
3891     }
3892
3893     # generate firewall rules for LXC containers
3894     foreach my $vmid (keys %{$vmdata->{lxc}}) {
3895         eval {
3896             my $conf = $vmdata->{lxc}->{$vmid};
3897             my $vmfw_conf = $vmfw_configs->{$vmid};
3898             return if !$vmfw_conf;
3899
3900             # When the 'ipfilter' option is enabled every device for which there
3901             # is no 'ipfilter-netX' ipset defined gets an implicit empty default
3902             # ipset.
3903             # The reason is that ipfilter ipsets are always filled with standard
3904             # IPv6 link-local filters, as well as the IP addresses configured
3905             # for the container.
3906             my $ipsets = $vmfw_conf->{ipset};
3907             my $implicit_sets = {};
3908
3909             my $device_ips = {};
3910             foreach my $netid (keys %$conf) {
3911                 next if $netid !~ m/^net(\d+)$/;
3912                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
3913                 next if !$net->{firewall};
3914
3915                 if ($vmfw_conf->{options}->{ipfilter} && !$ipsets->{"ipfilter-$netid"}) {
3916                     $implicit_sets->{"ipfilter-$netid"} = [];
3917                 }
3918
3919                 my $macaddr = $net->{hwaddr};
3920                 my $linklocal = mac_to_linklocal($macaddr);
3921                 my $set = $device_ips->{$netid} = [
3922                     { cidr => $linklocal },
3923                     { cidr => 'fe80::/10', nomatch => 1 }
3924                 ];
3925                 if (defined($net->{ip}) && $net->{ip} =~ m!^($IPV4RE)(?:/\d+)?$!) {
3926                     push @$set, { cidr => $1 };
3927                 }
3928                 if (defined($net->{ip6}) && $net->{ip6} =~ m!^($IPV6RE)(?:/\d+)?$!) {
3929                     push @$set, { cidr => $1 };
3930                 }
3931             }
3932
3933             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $ipsets);
3934             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $implicit_sets);
3935         };
3936         warn $@ if $@; # just to be sure - should not happen
3937     }
3938
3939     generate_ipset_chains($ipset_ruleset, undef, $cluster_conf, undef, $cluster_conf->{ipset});
3940
3941     return $ipset_ruleset;
3942 }
3943
3944 sub compile_ebtables_filter {
3945     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata) = @_;
3946
3947     if (!($cluster_conf->{options}->{ebtables} // 1)) {
3948         return {};
3949     }
3950
3951     my $ruleset = {};
3952
3953     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
3954
3955     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
3956     #for ipv4 and ipv6, check macaddress in iptables, so we use conntrack 'ESTABLISHED', to speedup rules
3957     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-p IPv4', '-j ACCEPT');
3958     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-p IPv6', '-j ACCEPT');
3959     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-o fwln+', '-j PVEFW-FWBR-OUT');
3960
3961     # generate firewall rules for QEMU VMs
3962     foreach my $vmid (sort keys %{$vmdata->{qemu}}) {
3963         eval {
3964             my $conf = $vmdata->{qemu}->{$vmid};
3965             my $vmfw_conf = $vmfw_configs->{$vmid};
3966             return if !$vmfw_conf;
3967             my $ipsets = $vmfw_conf->{ipset};
3968
3969             foreach my $netid (sort keys %$conf) {
3970                 next if $netid !~ m/^net(\d+)$/;
3971                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3972                 next if !$net->{firewall};
3973                 my $iface = "tap${vmid}i$1";
3974                 my $macaddr = $net->{macaddr};
3975                 my $arpfilter = [];
3976                 if (defined(my $ipset = $ipsets->{"ipfilter-$netid"})) {
3977                     foreach my $ipaddr (@$ipset) {
3978                         my($ip, $version) = parse_ip_or_cidr($ipaddr->{cidr});
3979                         next if !$ip || ($version && $version != 4);
3980                         push(@$arpfilter, $ip);
3981                     }
3982                 }
3983                 generate_tap_layer2filter($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter);
3984             }
3985         };
3986         warn $@ if $@; # just to be sure - should not happen
3987     }
3988
3989     # generate firewall rules for LXC containers
3990     foreach my $vmid (sort keys %{$vmdata->{lxc}}) {
3991         eval {
3992             my $conf = $vmdata->{lxc}->{$vmid};
3993
3994             my $vmfw_conf = $vmfw_configs->{$vmid};
3995             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
3996             my $ipsets = $vmfw_conf->{ipset};
3997
3998             foreach my $netid (sort keys %$conf) {
3999                 next if $netid !~ m/^net(\d+)$/;
4000                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
4001                 next if !$net->{firewall};
4002                 my $iface = "veth${vmid}i$1";
4003                 my $macaddr = $net->{hwaddr};
4004                 my $arpfilter = [];
4005                 if (defined(my $ipset = $ipsets->{"ipfilter-$netid"})) {
4006                     foreach my $ipaddr (@$ipset) {
4007                         my($ip, $version) = parse_ip_or_cidr($ipaddr->{cidr});
4008                         next if !$ip || ($version && $version != 4);
4009                         push(@$arpfilter, $ip);
4010                     }
4011                 }
4012                 if (defined(my $ip = $net->{ip}) && $vmfw_conf->{options}->{ipfilter}) {
4013                     # ebtables changes this to a .0/MASK network but we just
4014                     # want the address here, no network - see #2193
4015                     $ip =~ s|/(\d+)$||;
4016                     if ($ip ne 'dhcp') {
4017                         push @$arpfilter, $ip;
4018                     }
4019                 }
4020                 generate_tap_layer2filter($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter);
4021             }
4022         };
4023         warn $@ if $@; # just to be sure - should not happen
4024     }
4025
4026     return $ruleset;
4027 }
4028
4029 sub generate_tap_layer2filter {
4030     my ($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter) = @_;
4031     my $options = $vmfw_conf->{options};
4032
4033     my $tapchain = $iface."-OUT";
4034
4035     # ebtables remove zeros from mac pairs
4036     $macaddr =~ s/0([0-9a-f])/$1/ig;
4037     $macaddr = lc($macaddr);
4038
4039     ruleset_create_chain($ruleset, $tapchain);
4040
4041     if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
4042             ruleset_addrule($ruleset, $tapchain, "-s ! $macaddr", '-j DROP');
4043     }
4044
4045     if (@$arpfilter){
4046         my $arpchain = $tapchain."-ARP";
4047         ruleset_addrule($ruleset, $tapchain, "-p ARP", "-j $arpchain");
4048         ruleset_create_chain($ruleset, $arpchain);
4049
4050         foreach my $ip (@{$arpfilter}) {
4051             ruleset_addrule($ruleset, $arpchain, "-p ARP --arp-ip-src $ip", '-j RETURN');
4052         }
4053         ruleset_addrule($ruleset, $arpchain, '', '-j DROP');
4054     }
4055
4056     if (defined($options->{layer2_protocols})){
4057         my $protochain = $tapchain."-PROTO";
4058         ruleset_addrule($ruleset, $tapchain, '', "-j $protochain");
4059         ruleset_create_chain($ruleset, $protochain);
4060
4061         foreach my $proto (split(/,/, $options->{layer2_protocols})) {
4062             ruleset_addrule($ruleset, $protochain, "-p $proto", '-j RETURN');
4063         }
4064         ruleset_addrule($ruleset, $protochain, '', '-j DROP');
4065     }
4066
4067     ruleset_addrule($ruleset, $tapchain, '', '-j ACCEPT');
4068
4069     ruleset_addrule($ruleset, 'PVEFW-FWBR-OUT', "-i $iface", "-j $tapchain");
4070 }
4071
4072 # the parameter $change_only_regex changes two things if defined:
4073 # * all chains not matching it will be left intact
4074 # * both the $active_chains hash and the returned status_hash have different
4075 #   structure (they contain a key named 'rules').
4076 sub get_ruleset_status {
4077     my ($ruleset, $active_chains, $digest_fn, $change_only_regex) = @_;
4078
4079     my $statushash = {};
4080
4081     foreach my $chain (sort keys %$ruleset) {
4082         my $rules = $ruleset->{$chain};
4083         my $sig = &$digest_fn($rules);
4084         my $oldsig;
4085
4086         $statushash->{$chain}->{sig} = $sig;
4087         if (defined($change_only_regex)) {
4088             $oldsig = $active_chains->{$chain}->{sig};
4089             $statushash->{$chain}->{rules} = $rules;
4090         } else {
4091             $oldsig = $active_chains->{$chain};
4092         }
4093         if (!defined($oldsig)) {
4094             $statushash->{$chain}->{action} = 'create';
4095         } else {
4096             if ($oldsig eq $sig) {
4097                 $statushash->{$chain}->{action} = 'exists';
4098             } else {
4099                 $statushash->{$chain}->{action} = 'update';
4100             }
4101         }
4102         if ($verbose) {
4103             print "$statushash->{$chain}->{action} $chain ($sig)\n";
4104             foreach my $cmd (@{$rules}) {
4105                 print "\t$cmd\n";
4106             }
4107         }
4108     }
4109
4110     foreach my $chain (sort keys %$active_chains) {
4111         next if defined($ruleset->{$chain});
4112         my $action = 'delete';
4113         my $sig = $active_chains->{$chain};
4114         if (defined($change_only_regex)) {
4115             $action = 'ignore' if ($chain !~ m/$change_only_regex/);
4116             $statushash->{$chain}->{rules} = $active_chains->{$chain}->{rules};
4117             $statushash->{$chain}->{policy} = $active_chains->{$chain}->{policy};
4118             $sig = $sig->{sig};
4119         }
4120         $statushash->{$chain}->{action} = $action;
4121         $statushash->{$chain}->{sig} = $sig;
4122         print "$action $chain ($sig)\n" if $verbose;
4123     }
4124
4125     return $statushash;
4126 }
4127
4128 sub print_sig_rule {
4129     my ($chain, $sig) = @_;
4130
4131     # We just use this to store a SHA1 checksum used to detect changes
4132     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
4133 }
4134
4135 sub get_ruleset_cmdlist {
4136     my ($ruleset, $iptablescmd, $table) = @_;
4137
4138     $table = 'filter' if !$table;
4139
4140     my $cmdlist = "*$table\n"; # we pass this to iptables-restore;
4141
4142     my ($active_chains, $hooks) = iptables_get_chains($iptablescmd, $table);
4143     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest);
4144
4145     # create missing chains first
4146     foreach my $chain (sort keys %$ruleset) {
4147         my $stat = $statushash->{$chain};
4148         die "internal error" if !$stat;
4149         next if $stat->{action} ne 'create';
4150
4151         $cmdlist .= ":$chain - [0:0]\n";
4152     }
4153
4154     foreach my $h (qw(INPUT OUTPUT FORWARD PREROUTING)) {
4155         my $chain = "PVEFW-$h";
4156         if ($ruleset->{$chain} && !$hooks->{$h}) {
4157             $cmdlist .= "-A $h -j $chain\n";
4158         }
4159     }
4160
4161     foreach my $chain (sort keys %$ruleset) {
4162         my $stat = $statushash->{$chain};
4163         die "internal error" if !$stat;
4164
4165         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
4166             $cmdlist .= "-F $chain\n";
4167             foreach my $cmd (@{$ruleset->{$chain}}) {
4168                 $cmdlist .= "$cmd\n";
4169             }
4170             $cmdlist .= print_sig_rule($chain, $stat->{sig});
4171         } elsif ($stat->{action} eq 'delete') {
4172             die "internal error"; # this should not happen
4173         } elsif ($stat->{action} eq 'exists') {
4174             # do nothing
4175         } else {
4176             die "internal error - unknown status '$stat->{action}'";
4177         }
4178     }
4179
4180     foreach my $chain (keys %$statushash) {
4181         next if $statushash->{$chain}->{action} ne 'delete';
4182         $cmdlist .= "-F $chain\n";
4183     }
4184     foreach my $chain (keys %$statushash) {
4185         next if $statushash->{$chain}->{action} ne 'delete';
4186         next if $chain eq 'PVEFW-INPUT';
4187         next if $chain eq 'PVEFW-OUTPUT';
4188         next if $chain eq 'PVEFW-FORWARD';
4189         next if $chain eq 'PVEFW-PREROUTING';
4190         $cmdlist .= "-X $chain\n";
4191     }
4192
4193     my $changes = $cmdlist ne "*$table\n" ? 1 : 0;
4194
4195     $cmdlist .= "COMMIT\n";
4196
4197     return wantarray ? ($cmdlist, $changes) : $cmdlist;
4198 }
4199
4200 my $pve_ebtables_chainname_regex = qr/PVEFW-\S+|(?:tap|veth)\d+i\d+-(?:IN|OUT)/;
4201
4202 sub get_ebtables_cmdlist {
4203     my ($ruleset) = @_;
4204
4205     my $changes = 0;
4206     my $cmdlist = "*filter\n";
4207
4208     my $active_chains = ebtables_get_chains();
4209     my $statushash = get_ruleset_status($ruleset, $active_chains,
4210                                         \&iptables_chain_digest,
4211                                         $pve_ebtables_chainname_regex);
4212
4213     # create chains first and make sure PVE rules are evaluated if active
4214     my $append_pve_to_forward = '-A FORWARD -j PVEFW-FORWARD';
4215     my $pve_include = 0;
4216     foreach my $chain (sort keys %$statushash) {
4217         next if ($statushash->{$chain}->{action} eq 'delete');
4218         my $policy = $statushash->{$chain}->{policy} // 'ACCEPT';
4219         $cmdlist .= ":$chain $policy\n";
4220         $pve_include = 1 if ($chain eq 'PVEFW-FORWARD');
4221     }
4222
4223     foreach my $chain (sort keys %$statushash) {
4224         my $stat = $statushash->{$chain};
4225         $changes = 1 if ($stat->{action} !~ 'ignore|exists');
4226         next if ($stat->{action} eq 'delete');
4227
4228         foreach my $cmd (@{$statushash->{$chain}->{'rules'}}) {
4229             if ($chain eq 'FORWARD' && $cmd eq $append_pve_to_forward) {
4230                 next if ! $pve_include;
4231                 $pve_include = 0;
4232             }
4233             $cmdlist .= "$cmd\n";
4234         }
4235     }
4236     $cmdlist .= "$append_pve_to_forward\n" if $pve_include;
4237
4238     return wantarray ? ($cmdlist, $changes) : $cmdlist;
4239 }
4240
4241 sub get_ipset_cmdlist {
4242     my ($ruleset) = @_;
4243
4244     my $cmdlist = "";
4245
4246     my $delete_cmdlist = "";
4247
4248     my $active_chains = ipset_get_chains();
4249     my $statushash = get_ruleset_status($ruleset, $active_chains, \&ipset_chain_digest);
4250
4251     # remove stale _swap chains
4252     foreach my $chain (keys %$active_chains) {
4253         if ($chain =~ m/^PVEFW-\S+_swap$/) {
4254             $cmdlist .= "destroy $chain\n";
4255         }
4256     }
4257
4258     foreach my $chain (keys %$ruleset) {
4259         my $stat = $statushash->{$chain};
4260         die "internal error" if !$stat;
4261
4262         if ($stat->{action} eq 'create') {
4263             foreach my $cmd (@{$ruleset->{$chain}}) {
4264                 $cmdlist .= "$cmd\n";
4265             }
4266         }
4267     }
4268
4269     foreach my $chain (keys %$ruleset) {
4270         my $stat = $statushash->{$chain};
4271         die "internal error" if !$stat;
4272
4273         if ($stat->{action} eq 'update') {
4274             my $chain_swap = $chain."_swap";
4275
4276             foreach my $cmd (@{$ruleset->{$chain}}) {
4277                 $cmd =~ s/$chain/$chain_swap/;
4278                 $cmdlist .= "$cmd\n";
4279             }
4280             $cmdlist .= "swap $chain_swap $chain\n";
4281             $cmdlist .= "flush $chain_swap\n";
4282             $cmdlist .= "destroy $chain_swap\n";
4283         }
4284     }
4285
4286      # the remove unused chains
4287     foreach my $chain (keys %$statushash) {
4288         next if $statushash->{$chain}->{action} ne 'delete';
4289
4290         $delete_cmdlist .= "flush $chain\n";
4291         $delete_cmdlist .= "destroy $chain\n";
4292     }
4293
4294     my $changes = ($cmdlist || $delete_cmdlist) ? 1 : 0;
4295
4296     return ($cmdlist, $delete_cmdlist, $changes);
4297 }
4298
4299 sub apply_ruleset {
4300     my ($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6, $ebtables_ruleset) = @_;
4301
4302     enable_bridge_firewall();
4303
4304     my ($ipset_create_cmdlist, $ipset_delete_cmdlist, $ipset_changes) =
4305         get_ipset_cmdlist($ipset_ruleset);
4306
4307     my ($cmdlist, $changes) = get_ruleset_cmdlist($ruleset->{filter});
4308     my ($cmdlistv6, $changesv6) = get_ruleset_cmdlist($rulesetv6->{filter}, "ip6tables");
4309     my ($ebtables_cmdlist, $ebtables_changes) = get_ebtables_cmdlist($ebtables_ruleset);
4310     my ($cmdlist_raw, $changes_raw) = get_ruleset_cmdlist($ruleset->{raw}, undef, 'raw');
4311     my ($cmdlistv6_raw, $changesv6_raw) = get_ruleset_cmdlist($rulesetv6->{raw}, "ip6tables", 'raw');
4312
4313     if ($verbose) {
4314         if ($ipset_changes) {
4315             print "ipset changes:\n";
4316             print $ipset_create_cmdlist if $ipset_create_cmdlist;
4317             print $ipset_delete_cmdlist if $ipset_delete_cmdlist;
4318         }
4319
4320         if ($changes) {
4321             print "iptables changes:\n";
4322             print $cmdlist;
4323         }
4324
4325         if ($changesv6) {
4326             print "ip6tables changes:\n";
4327             print $cmdlistv6;
4328         }
4329
4330         if ($changes_raw) {
4331             print "iptables table raw changes:\n";
4332             print $cmdlist_raw;
4333         }
4334
4335         if ($changesv6_raw) {
4336             print "ip6tables table raw changes:\n";
4337             print $cmdlistv6_raw;
4338         }
4339
4340         if ($ebtables_changes) {
4341             print "ebtables changes:\n";
4342             print $ebtables_cmdlist;
4343         }
4344     }
4345
4346     my $tmpfile = "$pve_fw_status_dir/ipsetcmdlist1";
4347     PVE::Tools::file_set_contents($tmpfile, $ipset_create_cmdlist || '');
4348
4349     ipset_restore_cmdlist($ipset_create_cmdlist);
4350
4351     $tmpfile = "$pve_fw_status_dir/ip4cmdlist";
4352     PVE::Tools::file_set_contents($tmpfile, $cmdlist || '');
4353
4354     iptables_restore_cmdlist($cmdlist);
4355
4356     $tmpfile = "$pve_fw_status_dir/ip4cmdlistraw";
4357     PVE::Tools::file_set_contents($tmpfile, $cmdlist_raw || '');
4358
4359     iptables_restore_cmdlist($cmdlist_raw, 'raw');
4360
4361     $tmpfile = "$pve_fw_status_dir/ip6cmdlist";
4362     PVE::Tools::file_set_contents($tmpfile, $cmdlistv6 || '');
4363
4364     ip6tables_restore_cmdlist($cmdlistv6);
4365
4366     $tmpfile = "$pve_fw_status_dir/ip6cmdlistraw";
4367     PVE::Tools::file_set_contents($tmpfile, $cmdlistv6_raw || '');
4368
4369     ip6tables_restore_cmdlist($cmdlistv6_raw, 'raw');
4370
4371     $tmpfile = "$pve_fw_status_dir/ipsetcmdlist2";
4372     PVE::Tools::file_set_contents($tmpfile, $ipset_delete_cmdlist || '');
4373
4374     ipset_restore_cmdlist($ipset_delete_cmdlist) if $ipset_delete_cmdlist;
4375
4376     ebtables_restore_cmdlist($ebtables_cmdlist);
4377
4378     $tmpfile = "$pve_fw_status_dir/ebtablescmdlist";
4379     PVE::Tools::file_set_contents($tmpfile, $ebtables_cmdlist || '');
4380
4381     # test: re-read status and check if everything is up to date
4382     my $ruleset_filter = $ruleset->{filter};
4383     my $active_chains = iptables_get_chains();
4384     my $statushash = get_ruleset_status($ruleset_filter, $active_chains, \&iptables_chain_digest);
4385
4386     my $errors;
4387     foreach my $chain (sort keys %$ruleset_filter) {
4388         my $stat = $statushash->{$chain};
4389         if ($stat->{action} ne 'exists') {
4390             warn "unable to update chain '$chain'\n";
4391             $errors = 1;
4392         }
4393     }
4394
4395     my $rulesetv6_filter = $rulesetv6->{filter};
4396     my $active_chainsv6 = iptables_get_chains("ip6tables");
4397     my $statushashv6 = get_ruleset_status($rulesetv6_filter, $active_chainsv6, \&iptables_chain_digest);
4398
4399     foreach my $chain (sort keys %$rulesetv6_filter) {
4400         my $stat = $statushashv6->{$chain};
4401         if ($stat->{action} ne 'exists') {
4402             warn "unable to update chain '$chain'\n";
4403             $errors = 1;
4404         }
4405     }
4406
4407     my $ruleset_raw = $ruleset->{raw};
4408     my $active_chains_raw = iptables_get_chains(undef, 'raw');
4409     my $statushash_raw = get_ruleset_status($ruleset_raw, $active_chains_raw, \&iptables_chain_digest);
4410
4411     foreach my $chain (sort keys %$ruleset_raw) {
4412         my $stat = $statushash_raw->{$chain};
4413         if ($stat->{action} ne 'exists') {
4414             warn "unable to update chain '$chain'\n";
4415             $errors = 1;
4416         }
4417     }
4418
4419     my $rulesetv6_raw = $rulesetv6->{raw};
4420     my $active_chainsv6_raw = iptables_get_chains("ip6tables", 'raw');
4421     my $statushashv6_raw = get_ruleset_status($rulesetv6_raw, $active_chainsv6_raw, \&iptables_chain_digest);
4422
4423     foreach my $chain (sort keys %$rulesetv6_raw) {
4424         my $stat = $statushashv6_raw->{$chain};
4425         if ($stat->{action} ne 'exists') {
4426             warn "unable to update chain '$chain'\n";
4427             $errors = 1;
4428         }
4429     }
4430
4431     my $active_ebtables_chains = ebtables_get_chains();
4432     my $ebtables_statushash = get_ruleset_status($ebtables_ruleset,
4433                                 $active_ebtables_chains, \&iptables_chain_digest,
4434                                 $pve_ebtables_chainname_regex);
4435
4436     foreach my $chain (sort keys %$ebtables_ruleset) {
4437         my $stat = $ebtables_statushash->{$chain};
4438         if ($stat->{action} ne 'exists') {
4439             warn "ebtables : unable to update chain '$chain'\n";
4440             $errors = 1;
4441         }
4442     }
4443
4444     die "unable to apply firewall changes\n" if $errors;
4445
4446     update_nf_conntrack_max($hostfw_conf);
4447
4448     update_nf_conntrack_tcp_timeout_established($hostfw_conf);
4449
4450     update_nf_conntrack_tcp_timeout_syn_recv($hostfw_conf);
4451
4452     update_nf_conntrack_logging($hostfw_conf);
4453 }
4454
4455 sub update_nf_conntrack_max {
4456     my ($hostfw_conf) = @_;
4457
4458     my $max = 262144; # reasonable default (2^16 * 4), see nf_conntrack-sysctl docs
4459
4460     my $options = $hostfw_conf->{options} || {};
4461
4462     if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
4463         $max = $options->{nf_conntrack_max};
4464         $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
4465     }
4466
4467     my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
4468     my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
4469
4470     my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
4471
4472     if ($current != $max) {
4473         my $hashsize = int($max/4);
4474         PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
4475         PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
4476     }
4477 }
4478
4479 sub update_nf_conntrack_tcp_timeout_established {
4480     my ($hostfw_conf) = @_;
4481
4482     my $options = $hostfw_conf->{options} || {};
4483
4484     my $value = defined($options->{nf_conntrack_tcp_timeout_established}) ? $options->{nf_conntrack_tcp_timeout_established} : 432000;
4485
4486     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_established", $value);
4487 }
4488
4489 sub update_nf_conntrack_tcp_timeout_syn_recv {
4490     my ($hostfw_conf) = @_;
4491
4492     my $options = $hostfw_conf->{options} || {};
4493
4494     my $value = defined($options->{nf_conntrack_tcp_timeout_syn_recv}) ? $options->{nf_conntrack_tcp_timeout_syn_recev} : 60;
4495
4496     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_syn_recv", $value);
4497 }
4498
4499 my $log_nf_conntrack_enabled = undef;
4500 sub update_nf_conntrack_logging {
4501     my ($hostfw_conf) = @_;
4502
4503     my $options = $hostfw_conf->{options} || {};
4504     my $value = $options->{log_nf_conntrack} || 0;
4505     if (!defined($log_nf_conntrack_enabled)
4506         || $value != $log_nf_conntrack_enabled)
4507     {
4508         my $tmpfile = "$pve_fw_status_dir/log_nf_conntrack";
4509         PVE::Tools::file_set_contents($tmpfile, $value);
4510
4511         run_command([qw(systemctl try-reload-or-restart pvefw-logger.service)]);
4512         $log_nf_conntrack_enabled = $value;
4513     }
4514 }
4515
4516 sub remove_pvefw_chains {
4517
4518     PVE::Firewall::remove_pvefw_chains_iptables("iptables");
4519     PVE::Firewall::remove_pvefw_chains_iptables("ip6tables");
4520     PVE::Firewall::remove_pvefw_chains_iptables("iptables", "raw");
4521     PVE::Firewall::remove_pvefw_chains_iptables("ip6tables", "raw");
4522     PVE::Firewall::remove_pvefw_chains_ipset();
4523     PVE::Firewall::remove_pvefw_chains_ebtables();
4524
4525 }
4526
4527 sub remove_pvefw_chains_iptables {
4528     my ($iptablescmd, $table) = @_;
4529
4530     $table = 'filter' if !$table;
4531
4532     my ($chash, $hooks) = iptables_get_chains($iptablescmd, $table);
4533     my $cmdlist = "*$table\n";
4534
4535     foreach my $h (qw(INPUT OUTPUT FORWARD PREROUTING)) {
4536         if ($hooks->{$h}) {
4537             $cmdlist .= "-D $h -j PVEFW-$h\n";
4538         }
4539     }
4540
4541     foreach my $chain (keys %$chash) {
4542         $cmdlist .= "-F $chain\n";
4543     }
4544
4545     foreach my $chain (keys %$chash) {
4546         $cmdlist .= "-X $chain\n";
4547     }
4548     $cmdlist .= "COMMIT\n";
4549
4550     if($iptablescmd eq "ip6tables") {
4551         ip6tables_restore_cmdlist($cmdlist, $table);
4552     } else {
4553         iptables_restore_cmdlist($cmdlist, $table);
4554     }
4555 }
4556
4557 sub remove_pvefw_chains_ipset {
4558
4559     my $ipset_chains = ipset_get_chains();
4560
4561     my $cmdlist = "";
4562
4563     foreach my $chain (keys %$ipset_chains) {
4564         $cmdlist .= "flush $chain\n";
4565         $cmdlist .= "destroy $chain\n";
4566     }
4567
4568     ipset_restore_cmdlist($cmdlist) if $cmdlist;
4569 }
4570
4571 sub remove_pvefw_chains_ebtables {
4572     # apply empty ruleset = remove all our chains
4573     ebtables_restore_cmdlist(get_ebtables_cmdlist({}));
4574 }
4575
4576 sub init {
4577     my $cluster_conf = load_clusterfw_conf();
4578     my $cluster_options = $cluster_conf->{options};
4579     my $enable = $cluster_options->{enable};
4580
4581     return if !$enable;
4582
4583     # load required modules here
4584 }
4585
4586 sub update {
4587     my $code = sub {
4588
4589         my $cluster_conf = load_clusterfw_conf();
4590         my $cluster_options = $cluster_conf->{options};
4591
4592         if (!$cluster_options->{enable}) {
4593             PVE::Firewall::remove_pvefw_chains();
4594             return;
4595         }
4596
4597         my $hostfw_conf = load_hostfw_conf($cluster_conf);
4598
4599         my ($ruleset, $ipset_ruleset, $rulesetv6, $ebtables_ruleset) = compile($cluster_conf, $hostfw_conf);
4600
4601         apply_ruleset($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6, $ebtables_ruleset);
4602     };
4603
4604     run_locked($code);
4605 }
4606
4607 1;