src/PVE/Firewall.pm

   1 package PVE::Firewall;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Digest::SHA;
   7 use Encode;
   8 use File::Basename;
   9 use File::Path;
  10 use IO::File;
  11 use Net::IP;
  12 use POSIX;
  13 use Socket qw(AF_INET AF_INET6 inet_ntop inet_pton);
  14 use Storable qw(dclone);
  15
  16 use PVE::Cluster;
  17 use PVE::Corosync;
  18 use PVE::Exception qw(raise raise_param_exc);
  19 use PVE::INotify;
  20 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  21 use PVE::Network;
  22 use PVE::ProcFSTools;
  23 use PVE::SafeSyslog;
  24 use PVE::Tools qw($IPV4RE $IPV6RE);
  25 use PVE::Tools qw(run_command lock_file dir_glob_foreach);
  26
  27 use PVE::Firewall::Helpers;
  28
  29 my $pvefw_conf_dir = "/etc/pve/firewall";
  30 my $clusterfw_conf_filename = "$pvefw_conf_dir/cluster.fw";
  31
  32 # dynamically include PVE::QemuServer and PVE::LXC
  33 # to avoid dependency problems
  34 my $have_qemu_server;
  35 eval {
  36     require PVE::QemuServer;
  37     require PVE::QemuConfig;
  38     $have_qemu_server = 1;
  39 };
  40
  41 my $have_lxc;
  42 eval {
  43     require PVE::LXC;
  44     $have_lxc = 1;
  45 };
  46
  47 my $pve_fw_status_dir = "/var/lib/pve-firewall";
  48
  49 mkdir $pve_fw_status_dir; # make sure this exists
  50
  51 my $security_group_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  52 my $ipset_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  53 our $ip_alias_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  54
  55 my $max_alias_name_length = 64;
  56 my $max_ipset_name_length = 64;
  57 my $max_group_name_length = 18;
  58
  59 my $PROTOCOLS_WITH_PORTS = {
  60     udp => 1,     17 => 1,
  61     udplite => 1, 136 => 1,
  62     tcp => 1,     6 => 1,
  63     dccp => 1,    33 => 1,
  64     sctp => 1,    132 => 1,
  65 };
  66
  67 PVE::JSONSchema::register_format('IPorCIDR', \&pve_verify_ip_or_cidr);
  68 sub pve_verify_ip_or_cidr {
  69     my ($cidr, $noerr) = @_;
  70
  71     if ($cidr =~ m!^(?:$IPV6RE|$IPV4RE)(?:/\d+)?$!) {
  72         # Net::IP throws an error if the masked CIDR part isn't zero, e.g., `192.168.1.155/24`
  73         # fails but `192.168.1.0/24` succeeds. clean_cidr removes the non zero bits from the CIDR.
  74         my $clean_cidr = clean_cidr($cidr);
  75         return $cidr if Net::IP->new($clean_cidr);
  76         return undef if $noerr;
  77
  78         die Net::IP::Error() . "\n";
  79     }
  80     return undef if $noerr;
  81     die "value does not look like a valid IP address or CIDR network\n";
  82 }
  83
  84 PVE::JSONSchema::register_format('IPorCIDRorAlias', \&pve_verify_ip_or_cidr_or_alias);
  85 sub pve_verify_ip_or_cidr_or_alias {
  86     my ($cidr, $noerr) = @_;
  87
  88     return if $cidr =~ m/^(?:$ip_alias_pattern)$/;
  89
  90     return pve_verify_ip_or_cidr($cidr, $noerr);
  91 }
  92
  93 sub clean_cidr {
  94     my ($cidr) = @_;
  95     my ($ip, $len) = split('/', $cidr);
  96     return $cidr if !$len;
  97     my $ver = ($ip =~ m!^$IPV4RE$!) ? 4 : 6;
  98
  99     my $bin_ip = Net::IP::ip_iptobin( Net::IP::ip_expand_address($ip, $ver), $ver);
 100     my $bin_mask = Net::IP::ip_get_mask($len, $ver);
 101     my $clean_ip = Net::IP::ip_compress_address( Net::IP::ip_bintoip($bin_ip & $bin_mask, $ver), $ver);
 102
 103     return "${clean_ip}/$len";
 104 }
 105
 106 PVE::JSONSchema::register_standard_option('ipset-name', {
 107     description => "IP set name.",
 108     type => 'string',
 109     pattern => $ipset_name_pattern,
 110     minLength => 2,
 111     maxLength => $max_ipset_name_length,
 112 });
 113
 114 PVE::JSONSchema::register_standard_option('pve-fw-alias', {
 115     description => "Alias name.",
 116     type => 'string',
 117     pattern => $ip_alias_pattern,
 118     minLength => 2,
 119     maxLength => $max_alias_name_length,
 120 });
 121
 122 PVE::JSONSchema::register_standard_option('pve-fw-loglevel' => {
 123     description => "Log level.",
 124     type => 'string',
 125     enum => ['emerg', 'alert', 'crit', 'err', 'warning', 'notice', 'info', 'debug', 'nolog'],
 126     optional => 1,
 127 });
 128
 129 PVE::JSONSchema::register_standard_option('pve-security-group-name', {
 130     description => "Security Group name.",
 131     type => 'string',
 132     pattern => $security_group_name_pattern,
 133     minLength => 2,
 134     maxLength => $max_group_name_length,
 135 });
 136
 137 my $feature_ipset_nomatch = 0;
 138 eval  {
 139     my (undef, undef, $release) = POSIX::uname();
 140     if ($release =~ m/^(\d+)\.(\d+)\.\d+-/) {
 141         my ($major, $minor) = ($1, $2);
 142         $feature_ipset_nomatch = 1 if ($major > 3) ||
 143             ($major == 3 && $minor >= 7);
 144     }
 145
 146 };
 147
 148 my $nodename = PVE::INotify::nodename();
 149 my $hostfw_conf_filename = "/etc/pve/nodes/$nodename/host.fw";
 150
 151 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
 152
 153 my $default_log_level = 'nolog'; # avoid logs by default
 154 my $global_log_ratelimit = '--limit 1/sec';
 155
 156 my $log_level_hash = {
 157     debug => 7,
 158     info => 6,
 159     notice => 5,
 160     warning => 4,
 161     err => 3,
 162     crit => 2,
 163     alert => 1,
 164     emerg => 0,
 165 };
 166
 167 my $verbose = 0;
 168 sub set_verbose {
 169     $verbose = shift;
 170 }
 171
 172 # %rule
 173 #
 174 # name => optional
 175 # enable => [0|1]
 176 # action =>
 177 # proto =>
 178 # sport => port[,port[,port]].. or port:port
 179 # dport => port[,port[,port]].. or port:port
 180 # log => optional, loglevel
 181 # logmsg => optional, logmsg - overwrites default
 182 # iface_in => incomin interface
 183 # iface_out => outgoing interface
 184 # match => optional, overwrites generation of match
 185 # target => optional, overwrites action
 186
 187 # we need to overwrite some macros for ipv6
 188 my $pve_ipv6fw_macros = {
 189     'Ping' => [
 190         { action => 'PARAM', proto => 'icmpv6', dport => 'echo-request' },
 191     ],
 192     'NeighborDiscovery' => [
 193         "IPv6 neighbor solicitation, neighbor and router advertisement",
 194         { action => 'PARAM', proto => 'icmpv6', dport => 'router-solicitation' },
 195         { action => 'PARAM', proto => 'icmpv6', dport => 'router-advertisement' },
 196         { action => 'PARAM', proto => 'icmpv6', dport => 'neighbor-solicitation' },
 197         { action => 'PARAM', proto => 'icmpv6', dport => 'neighbor-advertisement' },
 198     ],
 199     'DHCPv6' => [
 200         "DHCPv6 traffic",
 201         { action => 'PARAM', proto => 'udp', dport => '546:547', sport => '546:547' },
 202     ],
 203     'Trcrt' => [
 204         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 205         { action => 'PARAM', proto => 'icmpv6', dport => 'echo-request' },
 206     ],
 207  };
 208
 209 # imported/converted from: /usr/share/shorewall/macro.*
 210 my $pve_fw_macros = {
 211     'Amanda' => [
 212         "Amanda Backup",
 213         { action => 'PARAM', proto => 'udp', dport => '10080' },
 214         { action => 'PARAM', proto => 'tcp', dport => '10080' },
 215     ],
 216     'Auth' => [
 217         "Auth (identd) traffic",
 218         { action => 'PARAM', proto => 'tcp', dport => '113' },
 219     ],
 220     'BGP' => [
 221         "Border Gateway Protocol traffic",
 222         { action => 'PARAM', proto => 'tcp', dport => '179' },
 223     ],
 224     'BitTorrent' => [
 225         "BitTorrent traffic for BitTorrent 3.1 and earlier",
 226         { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
 227         { action => 'PARAM', proto => 'udp', dport => '6881' },
 228     ],
 229     'BitTorrent32' => [
 230         "BitTorrent traffic for BitTorrent 3.2 and later",
 231         { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
 232         { action => 'PARAM', proto => 'udp', dport => '6881' },
 233     ],
 234     'Ceph' => [
 235         "Ceph Storage Cluster traffic (Ceph Monitors, OSD & MDS Daemons)",
 236         # Legacy port for protocol v1
 237         { action => 'PARAM', proto => 'tcp', dport => '6789' },
 238         # New port for protocol v2
 239         { action => 'PARAM', proto => 'tcp', dport => '3300' },
 240         { action => 'PARAM', proto => 'tcp', dport => '6800:7300' },
 241     ],
 242     'CVS' => [
 243         "Concurrent Versions System pserver traffic",
 244         { action => 'PARAM', proto => 'tcp', dport => '2401' },
 245     ],
 246     'Citrix' => [
 247         "Citrix/ICA traffic (ICA, ICA Browser, CGP)",
 248         { action => 'PARAM', proto => 'tcp', dport => '1494' },
 249         { action => 'PARAM', proto => 'udp', dport => '1604' },
 250         { action => 'PARAM', proto => 'tcp', dport => '2598' },
 251     ],
 252     'DAAP' => [
 253         "Digital Audio Access Protocol traffic (iTunes, Rythmbox daemons)",
 254         { action => 'PARAM', proto => 'tcp', dport => '3689' },
 255         { action => 'PARAM', proto => 'udp', dport => '3689' },
 256     ],
 257     'DCC' => [
 258         "Distributed Checksum Clearinghouse spam filtering mechanism",
 259         { action => 'PARAM', proto => 'tcp', dport => '6277' },
 260     ],
 261     'DHCPfwd' => [
 262         "Forwarded DHCP traffic",
 263         { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
 264     ],
 265     'DNS' => [
 266         "Domain Name System traffic (upd and tcp)",
 267         { action => 'PARAM', proto => 'udp', dport => '53' },
 268         { action => 'PARAM', proto => 'tcp', dport => '53' },
 269     ],
 270     'Distcc' => [
 271         "Distributed Compiler service",
 272         { action => 'PARAM', proto => 'tcp', dport => '3632' },
 273     ],
 274     'FTP' => [
 275         "File Transfer Protocol",
 276         { action => 'PARAM', proto => 'tcp', dport => '21' },
 277     ],
 278     'Finger' => [
 279         "Finger protocol (RFC 742)",
 280         { action => 'PARAM', proto => 'tcp', dport => '79' },
 281     ],
 282     'GNUnet' => [
 283         "GNUnet secure peer-to-peer networking traffic",
 284         { action => 'PARAM', proto => 'tcp', dport => '2086' },
 285         { action => 'PARAM', proto => 'udp', dport => '2086' },
 286         { action => 'PARAM', proto => 'tcp', dport => '1080' },
 287         { action => 'PARAM', proto => 'udp', dport => '1080' },
 288     ],
 289     'GRE' => [
 290         "Generic Routing Encapsulation tunneling protocol",
 291         { action => 'PARAM', proto => '47' },
 292     ],
 293     'Git' => [
 294         "Git distributed revision control traffic",
 295         { action => 'PARAM', proto => 'tcp', dport => '9418' },
 296     ],
 297     'HKP' => [
 298         "OpenPGP HTTP key server protocol traffic",
 299         { action => 'PARAM', proto => 'tcp', dport => '11371' },
 300     ],
 301     'HTTP' => [
 302         "Hypertext Transfer Protocol (WWW)",
 303         { action => 'PARAM', proto => 'tcp', dport => '80' },
 304     ],
 305     'HTTPS' => [
 306         "Hypertext Transfer Protocol (WWW) over SSL",
 307         { action => 'PARAM', proto => 'tcp', dport => '443' },
 308     ],
 309     'ICPV2' => [
 310         "Internet Cache Protocol V2 (Squid) traffic",
 311         { action => 'PARAM', proto => 'udp', dport => '3130' },
 312     ],
 313     'ICQ' => [
 314         "AOL Instant Messenger traffic",
 315         { action => 'PARAM', proto => 'tcp', dport => '5190' },
 316     ],
 317     'IMAP' => [
 318         "Internet Message Access Protocol",
 319         { action => 'PARAM', proto => 'tcp', dport => '143' },
 320     ],
 321     'IMAPS' => [
 322         "Internet Message Access Protocol over SSL",
 323         { action => 'PARAM', proto => 'tcp', dport => '993' },
 324     ],
 325     'IPIP' => [
 326         "IPIP capsulation traffic",
 327         { action => 'PARAM', proto => '94' },
 328     ],
 329     'IPsec' => [
 330         "IPsec traffic",
 331         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 332         { action => 'PARAM', proto => '50' },
 333     ],
 334     'IPsecah' => [
 335         "IPsec authentication (AH) traffic",
 336         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 337         { action => 'PARAM', proto => '51' },
 338     ],
 339     'IPsecnat' => [
 340         "IPsec traffic and Nat-Traversal",
 341         { action => 'PARAM', proto => 'udp', dport => '500' },
 342         { action => 'PARAM', proto => 'udp', dport => '4500' },
 343         { action => 'PARAM', proto => '50' },
 344     ],
 345     'IRC' => [
 346         "Internet Relay Chat traffic",
 347         { action => 'PARAM', proto => 'tcp', dport => '6667' },
 348     ],
 349     'Jetdirect' => [
 350         "HP Jetdirect printing",
 351         { action => 'PARAM', proto => 'tcp', dport => '9100' },
 352     ],
 353     'L2TP' => [
 354         "Layer 2 Tunneling Protocol traffic",
 355         { action => 'PARAM', proto => 'udp', dport => '1701' },
 356     ],
 357     'LDAP' => [
 358         "Lightweight Directory Access Protocol traffic",
 359         { action => 'PARAM', proto => 'tcp', dport => '389' },
 360     ],
 361     'LDAPS' => [
 362         "Secure Lightweight Directory Access Protocol traffic",
 363         { action => 'PARAM', proto => 'tcp', dport => '636' },
 364     ],
 365     'MSNP' => [
 366         "Microsoft Notification Protocol",
 367         { action => 'PARAM', proto => 'tcp', dport => '1863' },
 368     ],
 369     'MSSQL' => [
 370         "Microsoft SQL Server",
 371         { action => 'PARAM', proto => 'tcp', dport => '1433' },
 372     ],
 373     'Mail' => [
 374         "Mail traffic (SMTP, SMTPS, Submission)",
 375         { action => 'PARAM', proto => 'tcp', dport => '25' },
 376         { action => 'PARAM', proto => 'tcp', dport => '465' },
 377         { action => 'PARAM', proto => 'tcp', dport => '587' },
 378     ],
 379     'MDNS' => [
 380         "Multicast DNS",
 381         { action => 'PARAM', proto => 'udp', dport => '5353' },
 382     ],
 383     'Munin' => [
 384         "Munin networked resource monitoring traffic",
 385         { action => 'PARAM', proto => 'tcp', dport => '4949' },
 386     ],
 387     'MySQL' => [
 388         "MySQL server",
 389         { action => 'PARAM', proto => 'tcp', dport => '3306' },
 390     ],
 391     'NNTP' => [
 392         "NNTP traffic (Usenet).",
 393         { action => 'PARAM', proto => 'tcp', dport => '119' },
 394     ],
 395     'NNTPS' => [
 396         "Encrypted NNTP traffic (Usenet)",
 397         { action => 'PARAM', proto => 'tcp', dport => '563' },
 398     ],
 399     'NTP' => [
 400         "Network Time Protocol (ntpd)",
 401         { action => 'PARAM', proto => 'udp', dport => '123' },
 402     ],
 403     'OSPF' => [
 404         "OSPF multicast traffic",
 405         { action => 'PARAM', proto => '89' },
 406     ],
 407     'OpenVPN' => [
 408         "OpenVPN traffic",
 409         { action => 'PARAM', proto => 'udp', dport => '1194' },
 410     ],
 411     'PCA' => [
 412         "Symantec PCAnywere (tm)",
 413         { action => 'PARAM', proto => 'udp', dport => '5632' },
 414         { action => 'PARAM', proto => 'tcp', dport => '5631' },
 415     ],
 416     'PMG' => [
 417         "Proxmox Mail Gateway web interface",
 418         { action => 'PARAM', proto => 'tcp', dport => '8006' },
 419     ],
 420     'POP3' => [
 421         "POP3 traffic",
 422         { action => 'PARAM', proto => 'tcp', dport => '110' },
 423     ],
 424     'POP3S' => [
 425         "Encrypted POP3 traffic",
 426         { action => 'PARAM', proto => 'tcp', dport => '995' },
 427     ],
 428     'PPtP' => [
 429         "Point-to-Point Tunneling Protocol",
 430         { action => 'PARAM', proto => '47' },
 431         { action => 'PARAM', proto => 'tcp', dport => '1723' },
 432     ],
 433     'Ping' => [
 434         "ICMP echo request",
 435         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 436     ],
 437     'PostgreSQL' => [
 438         "PostgreSQL server",
 439         { action => 'PARAM', proto => 'tcp', dport => '5432' },
 440     ],
 441     'Printer' => [
 442         "Line Printer protocol printing",
 443         { action => 'PARAM', proto => 'tcp', dport => '515' },
 444     ],
 445     'RDP' => [
 446         "Microsoft Remote Desktop Protocol traffic",
 447         { action => 'PARAM', proto => 'tcp', dport => '3389' },
 448     ],
 449     'RIP' => [
 450         "Routing Information Protocol (bidirectional)",
 451         { action => 'PARAM', proto => 'udp', dport => '520' },
 452     ],
 453     'RNDC' => [
 454         "BIND remote management protocol",
 455         { action => 'PARAM', proto => 'tcp', dport => '953' },
 456     ],
 457     'Razor' => [
 458         "Razor Antispam System",
 459         { action => 'PARAM', proto => 'tcp', dport => '2703' },
 460     ],
 461     'Rdate' => [
 462         "Remote time retrieval (rdate)",
 463         { action => 'PARAM', proto => 'tcp', dport => '37' },
 464     ],
 465     'Rsync' => [
 466         "Rsync server",
 467         { action => 'PARAM', proto => 'tcp', dport => '873' },
 468     ],
 469     'SANE' => [
 470         "SANE network scanning",
 471         { action => 'PARAM', proto => 'tcp', dport => '6566' },
 472     ],
 473     'SMB' => [
 474         "Microsoft SMB traffic",
 475         { action => 'PARAM', proto => 'udp', dport => '135,445' },
 476         { action => 'PARAM', proto => 'udp', dport => '137:139' },
 477         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
 478         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
 479     ],
 480     'SMBswat' => [
 481         "Samba Web Administration Tool",
 482         { action => 'PARAM', proto => 'tcp', dport => '901' },
 483     ],
 484     'SMTP' => [
 485         "Simple Mail Transfer Protocol",
 486         { action => 'PARAM', proto => 'tcp', dport => '25' },
 487     ],
 488     'SMTPS' => [
 489         "Encrypted Simple Mail Transfer Protocol",
 490         { action => 'PARAM', proto => 'tcp', dport => '465' },
 491     ],
 492     'SNMP' => [
 493         "Simple Network Management Protocol",
 494         { action => 'PARAM', proto => 'udp', dport => '161:162' },
 495         { action => 'PARAM', proto => 'tcp', dport => '161' },
 496     ],
 497     'SPAMD' => [
 498         "Spam Assassin SPAMD traffic",
 499         { action => 'PARAM', proto => 'tcp', dport => '783' },
 500     ],
 501     'SSH' => [
 502         "Secure shell traffic",
 503         { action => 'PARAM', proto => 'tcp', dport => '22' },
 504     ],
 505     'SVN' => [
 506         "Subversion server (svnserve)",
 507         { action => 'PARAM', proto => 'tcp', dport => '3690' },
 508     ],
 509     'SixXS' => [
 510         "SixXS IPv6 Deployment and Tunnel Broker",
 511         { action => 'PARAM', proto => 'tcp', dport => '3874' },
 512         { action => 'PARAM', proto => 'udp', dport => '3740' },
 513         { action => 'PARAM', proto => '41' },
 514         { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
 515     ],
 516     'SPICEproxy' => [
 517         "Proxmox VE SPICE display proxy traffic",
 518         { action => 'PARAM', proto => 'tcp', dport => '3128' },
 519     ],
 520     'Squid' => [
 521         "Squid web proxy traffic",
 522         { action => 'PARAM', proto => 'tcp', dport => '3128' },
 523     ],
 524     'Submission' => [
 525         "Mail message submission traffic",
 526         { action => 'PARAM', proto => 'tcp', dport => '587' },
 527     ],
 528     'Syslog' => [
 529         "Syslog protocol (RFC 5424) traffic",
 530         { action => 'PARAM', proto => 'udp', dport => '514' },
 531         { action => 'PARAM', proto => 'tcp', dport => '514' },
 532     ],
 533     'TFTP' => [
 534         "Trivial File Transfer Protocol traffic",
 535         { action => 'PARAM', proto => 'udp', dport => '69' },
 536     ],
 537     'Telnet' => [
 538         "Telnet traffic",
 539         { action => 'PARAM', proto => 'tcp', dport => '23' },
 540     ],
 541     'Telnets' => [
 542         "Telnet over SSL",
 543         { action => 'PARAM', proto => 'tcp', dport => '992' },
 544     ],
 545     'Time' => [
 546         "RFC 868 Time protocol",
 547         { action => 'PARAM', proto => 'tcp', dport => '37' },
 548     ],
 549     'Trcrt' => [
 550         "Traceroute (for up to 30 hops) traffic",
 551         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 552         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 553     ],
 554     'VNC' => [
 555         "VNC traffic for VNC display's 0 - 99",
 556         { action => 'PARAM', proto => 'tcp', dport => '5900:5999' },
 557     ],
 558     'VNCL' => [
 559         "VNC traffic from Vncservers to Vncviewers in listen mode",
 560         { action => 'PARAM', proto => 'tcp', dport => '5500' },
 561     ],
 562     'Web' => [
 563         "WWW traffic (HTTP and HTTPS)",
 564         { action => 'PARAM', proto => 'tcp', dport => '80' },
 565         { action => 'PARAM', proto => 'tcp', dport => '443' },
 566     ],
 567     'Webcache' => [
 568         "Web Cache/Proxy traffic (port 8080)",
 569         { action => 'PARAM', proto => 'tcp', dport => '8080' },
 570     ],
 571     'Webmin' => [
 572         "Webmin traffic",
 573         { action => 'PARAM', proto => 'tcp', dport => '10000' },
 574     ],
 575     'Whois' => [
 576         "Whois (nicname, RFC 3912) traffic",
 577         { action => 'PARAM', proto => 'tcp', dport => '43' },
 578     ],
 579 };
 580
 581 my $pve_fw_helpers = {
 582     'amanda' => { proto => 'udp', dport => '10080', 'v4' => 1, 'v6' => 1 },
 583     'ftp' => { proto => 'tcp', dport => '21', 'v4' => 1, 'v6' => 1},
 584     'irc' => { proto => 'tcp', dport => '6667', 'v4' => 1 },
 585     'netbios-ns' => { proto => 'udp', dport => '137', 'v4' => 1 },
 586     'pptp' => { proto => 'tcp', dport => '1723', 'v4' => 1, },
 587     'sane' => { proto => 'tcp', dport => '6566', 'v4' => 1, 'v6' => 1 },
 588     'sip' => { proto => 'udp', dport => '5060', 'v4' => 1, 'v6' => 1 },
 589     'snmp' => { proto => 'udp', dport => '161', 'v4' => 1 },
 590     'tftp' => { proto => 'udp', dport => '69', 'v4' => 1, 'v6' => 1},
 591 };
 592
 593 my $pve_fw_parsed_macros;
 594 my $pve_fw_macro_descr;
 595 my $pve_fw_macro_ipversion = {};
 596 my $pve_fw_preferred_macro_names = {};
 597
 598 my $FWACCEPTMARK_ON  = "0x80000000/0x80000000";
 599 my $FWACCEPTMARK_OFF = "0x00000000/0x80000000";
 600
 601 my $pve_std_chains = {};
 602 my $pve_std_chains_conf = {};
 603 $pve_std_chains_conf->{4} = {
 604     'PVEFW-SET-ACCEPT-MARK' => [
 605         { target => "-j MARK --set-mark $FWACCEPTMARK_ON" },
 606     ],
 607     'PVEFW-DropBroadcast' => [
 608         # same as shorewall 'Broadcast'
 609         # simply DROP BROADCAST/MULTICAST/ANYCAST
 610         # we can use this to reduce logging
 611         { action => 'DROP', dsttype => 'BROADCAST' },
 612         { action => 'DROP', dsttype => 'MULTICAST' },
 613         { action => 'DROP', dsttype => 'ANYCAST' },
 614         { action => 'DROP', dest => '224.0.0.0/4' },
 615     ],
 616     'PVEFW-reject' => [
 617         # same as shorewall 'reject'
 618         { action => 'DROP', dsttype => 'BROADCAST' },
 619         { action => 'DROP', source => '224.0.0.0/4' },
 620         { action => 'DROP', proto => 'icmp' },
 621         { match => '-p tcp', target => '-j REJECT --reject-with tcp-reset' },
 622         { match => '-p udp', target => '-j REJECT --reject-with icmp-port-unreachable' },
 623         { match => '-p icmp', target => '-j REJECT --reject-with icmp-host-unreachable' },
 624         { target => '-j REJECT --reject-with icmp-host-prohibited' },
 625     ],
 626     'PVEFW-Drop' => [
 627         # same as shorewall 'Drop', which is equal to DROP,
 628         # but REJECT/DROP some packages to reduce logging,
 629         # and ACCEPT critical ICMP types
 630         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 631         { action => 'PVEFW-DropBroadcast' },
 632         # ACCEPT critical ICMP types
 633         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 634         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 635         # Drop packets with INVALID state
 636         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 637         # Drop Microsoft SMB noise
 638         { action => 'DROP', proto => 'udp', dport => '135,445' },
 639         { action => 'DROP', proto => 'udp', dport => '137:139' },
 640         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 641         { action => 'DROP', proto => 'tcp', dport => '135,139,445' },
 642         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 643         # Drop new/NotSyn traffic so that it doesn't get logged
 644         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 645         # Drop DNS replies
 646         { action => 'DROP', proto => 'udp', sport => 53 },
 647     ],
 648     'PVEFW-Reject' => [
 649         # same as shorewall 'Reject', which is equal to Reject,
 650         # but REJECT/DROP some packages to reduce logging,
 651         # and ACCEPT critical ICMP types
 652         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 653         { action => 'PVEFW-DropBroadcast' },
 654         # ACCEPT critical ICMP types
 655         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 656         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 657         # Drop packets with INVALID state
 658         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 659         # Drop Microsoft SMB noise
 660         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445' },
 661         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
 662         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 663         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445' },
 664         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 665         # Drop new/NotSyn traffic so that it doesn't get logged
 666         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 667         # Drop DNS replies
 668         { action => 'DROP', proto => 'udp', sport => 53 },
 669     ],
 670     'PVEFW-tcpflags' => [
 671         # same as shorewall tcpflags action.
 672         # Packets arriving on this interface are checked for some illegal combinations of TCP flags
 673         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG', target => '-g PVEFW-logflags' },
 674         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE', target => '-g PVEFW-logflags' },
 675         { match => '-p tcp -m tcp --tcp-flags SYN,RST SYN,RST', target => '-g PVEFW-logflags' },
 676         { match => '-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN', target => '-g PVEFW-logflags' },
 677         { match => '-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN', target => '-g PVEFW-logflags' },
 678     ],
 679     'PVEFW-smurfs' => [
 680         # same as shorewall smurfs action
 681         # Filter packets for smurfs (packets with a broadcast address as the source).
 682         { match => '-s 0.0.0.0/32', target => '-j RETURN' }, # allow DHCP
 683         { match => '-m addrtype --src-type BROADCAST', target => '-g PVEFW-smurflog' },
 684         { match => '-s 224.0.0.0/4', target => '-g PVEFW-smurflog' },
 685     ],
 686     'PVEFW-smurflog' => [
 687         { action => 'DROP', logmsg => 'DROP: ' },
 688     ],
 689     'PVEFW-logflags' => [
 690         { action => 'DROP', logmsg => 'DROP: ' },
 691     ],
 692 };
 693
 694 $pve_std_chains_conf->{6} = {
 695     'PVEFW-SET-ACCEPT-MARK' => [
 696         { target => "-j MARK --set-mark $FWACCEPTMARK_ON" },
 697     ],
 698     'PVEFW-DropBroadcast' => [
 699         # same as shorewall 'Broadcast'
 700         # simply DROP BROADCAST/MULTICAST/ANYCAST
 701         # we can use this to reduce logging
 702         #{ action => 'DROP', dsttype => 'BROADCAST' }, #no broadcast in ipv6
 703         # ipv6 addrtype does not work with kernel 2.6.32
 704         #{ action => 'DROP', dsttype => 'MULTICAST' },
 705         #{ action => 'DROP', dsttype => 'ANYCAST' },
 706         { action => 'DROP', dest => 'ff00::/8' },
 707         #{ action => 'DROP', dest => '224.0.0.0/4' },
 708     ],
 709     'PVEFW-reject' => [
 710         { action => 'DROP', proto => 'icmpv6' },
 711         { match => '-p tcp', target => '-j REJECT --reject-with tcp-reset' },
 712         { match => '-p udp', target => '-j REJECT --reject-with icmp6-port-unreachable' },
 713         { target => '-j REJECT --reject-with icmp6-adm-prohibited' },
 714     ],
 715     'PVEFW-Drop' => [
 716         # same as shorewall 'Drop', which is equal to DROP,
 717         # but REJECT/DROP some packages to reduce logging,
 718         # and ACCEPT critical ICMP types
 719         { action => 'PVEFW-reject', proto => 'tcp', dport => '43' }, # REJECT 'auth'
 720         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 721         { action => 'PVEFW-DropBroadcast' },
 722         # ACCEPT critical ICMP types
 723         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
 724         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
 725         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
 726         # Drop packets with INVALID state
 727         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 728         # Drop Microsoft SMB noise
 729         { action => 'DROP', proto => 'udp', dport => '135,445' },
 730         { action => 'DROP', proto => 'udp', dport => '137:139'},
 731         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 732         { action => 'DROP', proto => 'tcp', dport => '135,139,445' },
 733         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 734         # Drop new/NotSyn traffic so that it doesn't get logged
 735         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 736         # Drop DNS replies
 737         { action => 'DROP', proto => 'udp', sport => 53 },
 738     ],
 739     'PVEFW-Reject' => [
 740         # same as shorewall 'Reject', which is equal to Reject,
 741         # but REJECT/DROP some packages to reduce logging,
 742         # and ACCEPT critical ICMP types
 743         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 744         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 745         { action => 'PVEFW-DropBroadcast' },
 746         # ACCEPT critical ICMP types
 747         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
 748         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
 749         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
 750         # Drop packets with INVALID state
 751         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 752         # Drop Microsoft SMB noise
 753         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445' },
 754         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139' },
 755         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 756         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445' },
 757         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 758         # Drop new/NotSyn traffic so that it doesn't get logged
 759         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 760         # Drop DNS replies
 761         { action => 'DROP', proto => 'udp', sport => 53 },
 762     ],
 763     'PVEFW-tcpflags' => [
 764         # same as shorewall tcpflags action.
 765         # Packets arriving on this interface are checked for some illegal combinations of TCP flags
 766         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG', target => '-g PVEFW-logflags' },
 767         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE', target => '-g PVEFW-logflags' },
 768         { match => '-p tcp -m tcp --tcp-flags SYN,RST SYN,RST', target => '-g PVEFW-logflags' },
 769         { match => '-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN', target => '-g PVEFW-logflags' },
 770         { match => '-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN', target => '-g PVEFW-logflags' },
 771     ],
 772     'PVEFW-logflags' => [
 773         { action => 'DROP', logmsg => 'DROP: ' },
 774     ],
 775 };
 776
 777 # iptables -p icmp -h
 778 my $icmp_type_names = {
 779     any => 1,
 780     'echo-reply' => 1,
 781     'destination-unreachable' => 1,
 782     'network-unreachable' => 1,
 783     'host-unreachable' => 1,
 784     'protocol-unreachable' => 1,
 785     'port-unreachable' => 1,
 786     'fragmentation-needed' => 1,
 787     'source-route-failed' => 1,
 788     'network-unknown' => 1,
 789     'host-unknown' => 1,
 790     'network-prohibited' => 1,
 791     'host-prohibited' => 1,
 792     'TOS-network-unreachable' => 1,
 793     'TOS-host-unreachable' => 1,
 794     'communication-prohibited' => 1,
 795     'host-precedence-violation' => 1,
 796     'precedence-cutoff' => 1,
 797     'source-quench' => 1,
 798     'redirect' => 1,
 799     'network-redirect' => 1,
 800     'host-redirect' => 1,
 801     'TOS-network-redirect' => 1,
 802     'TOS-host-redirect' => 1,
 803     'echo-request' => 1,
 804     'router-advertisement' => 1,
 805     'router-solicitation' => 1,
 806     'time-exceeded' => 1,
 807     'ttl-zero-during-transit' => 1,
 808     'ttl-zero-during-reassembly' => 1,
 809     'parameter-problem' => 1,
 810     'ip-header-bad' => 1,
 811     'required-option-missing' => 1,
 812     'timestamp-request' => 1,
 813     'timestamp-reply' => 1,
 814     'address-mask-request' => 1,
 815     'address-mask-reply' => 1,
 816 };
 817
 818 # ip6tables -p icmpv6 -h
 819
 820 my $icmpv6_type_names = {
 821     'destination-unreachable' => 1,
 822     'no-route' => 1,
 823     'communication-prohibited' => 1,
 824     'beyond-scope' => 1,
 825     'address-unreachable' => 1,
 826     'port-unreachable' => 1,
 827     'failed-policy' => 1,
 828     'reject-route' => 1,
 829     'packet-too-big' => 1,
 830     'time-exceeded' => 1,
 831     'ttl-zero-during-transit' => 1,
 832     'ttl-zero-during-reassembly' => 1,
 833     'parameter-problem' => 1,
 834     'bad-header' => 1,
 835     'unknown-header-type' => 1,
 836     'unknown-option' => 1,
 837     'echo-request' => 1,
 838     'echo-reply' => 1,
 839     'router-solicitation' => 1,
 840     'router-advertisement' => 1,
 841     'neighbor-solicitation' => 1,
 842     'neighbour-solicitation' => 1,
 843     'neighbor-advertisement' => 1,
 844     'neighbour-advertisement' => 1,
 845     'redirect' => 1,
 846 };
 847
 848 my $is_valid_icmp_type = sub {
 849     my ($type, $valid_types) = @_;
 850
 851     if ($type =~ m/^\d+$/) {
 852         # values for icmp-type range between 0 and 255 (8 bit field)
 853         die "invalid icmp-type '$type'\n" if $type > 255;
 854     } else {
 855         die "unknown icmp-type '$type'\n" if !defined($valid_types->{$type});
 856     }
 857 };
 858
 859 my $proto_is_icmp = sub {
 860     my $proto = shift;
 861     return $proto eq 'icmp' || $proto eq 'icmpv6' || $proto eq 'ipv6-icmp';
 862 };
 863
 864 sub init_firewall_macros {
 865
 866     $pve_fw_parsed_macros = {};
 867
 868     my $parse = sub {
 869         my ($k, $macro) = @_;
 870         my $lc_name = lc($k);
 871         $pve_fw_macro_ipversion->{$k} = 0;
 872         while (!ref($macro->[0])) {
 873             my $desc = shift @$macro;
 874             if ($desc eq 'ipv4only') {
 875                 $pve_fw_macro_ipversion->{$k} = 4;
 876             } elsif ($desc eq 'ipv6only') {
 877                 $pve_fw_macro_ipversion->{$k} = 6;
 878             } else {
 879                 $pve_fw_macro_descr->{$k} = $desc;
 880             }
 881         }
 882         $pve_fw_preferred_macro_names->{$lc_name} = $k;
 883         $pve_fw_parsed_macros->{$k} = $macro;
 884     };
 885
 886     foreach my $k (keys %$pve_fw_macros) {
 887         &$parse($k, $pve_fw_macros->{$k});
 888     }
 889
 890     foreach my $k (keys %$pve_ipv6fw_macros) {
 891         next if $pve_fw_parsed_macros->{$k};
 892         &$parse($k, $pve_ipv6fw_macros->{$k});
 893         $pve_fw_macro_ipversion->{$k} = 6;
 894     }
 895 }
 896
 897 init_firewall_macros();
 898
 899 sub get_macros {
 900     return wantarray ? ($pve_fw_parsed_macros, $pve_fw_macro_descr): $pve_fw_parsed_macros;
 901 }
 902
 903 my $etc_services;
 904
 905 sub get_etc_services {
 906
 907     return $etc_services if $etc_services;
 908
 909     my $filename = "/etc/services";
 910
 911     my $fh = IO::File->new($filename, O_RDONLY);
 912     if (!$fh) {
 913         warn "unable to read '$filename' - $!\n";
 914         return {};
 915     }
 916
 917     my $services = {};
 918
 919     while (my $line = <$fh>) {
 920         chomp ($line);
 921         next if $line =~m/^#/;
 922         next if ($line =~m/^\s*$/);
 923
 924         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp|sctp).*$!) {
 925             $services->{byid}->{$2}->{name} = $1;
 926             $services->{byid}->{$2}->{port} = $2;
 927             $services->{byid}->{$2}->{$3} = 1;
 928             $services->{byname}->{$1} = $services->{byid}->{$2};
 929         }
 930     }
 931
 932     close($fh);
 933
 934     $etc_services = $services;
 935
 936
 937     return $etc_services;
 938 }
 939
 940 sub parse_protocol_file {
 941     my ($filename) = @_;
 942
 943     my $fh = IO::File->new($filename, O_RDONLY);
 944     if (!$fh) {
 945         warn "unable to read '$filename' - $!\n";
 946         return {};
 947     }
 948
 949     my $protocols = {};
 950
 951     while (my $line = <$fh>) {
 952         chomp ($line);
 953         next if $line =~m/^#/;
 954         next if ($line =~m/^\s*$/);
 955
 956         if ($line =~ m!^(\S+)\s+(\d+)(?:\s+.*)?$!) {
 957             $protocols->{byid}->{$2}->{name} = $1;
 958             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
 959         }
 960     }
 961
 962     close($fh);
 963
 964     return $protocols;
 965 }
 966
 967 my $etc_protocols;
 968
 969 sub get_etc_protocols {
 970     return $etc_protocols if $etc_protocols;
 971
 972     my $protocols = parse_protocol_file('/etc/protocols');
 973
 974     # add special case for ICMP v6
 975     $protocols->{byid}->{icmpv6}->{name} = "icmpv6";
 976     $protocols->{byname}->{icmpv6} = $protocols->{byid}->{icmpv6};
 977
 978     $etc_protocols = $protocols;
 979
 980     return $etc_protocols;
 981 }
 982
 983 my $etc_ethertypes;
 984
 985 sub get_etc_ethertypes {
 986     $etc_ethertypes = parse_protocol_file('/etc/ethertypes')
 987         if !$etc_ethertypes;
 988     return $etc_ethertypes;
 989 }
 990
 991 my $__local_network;
 992
 993 sub local_network {
 994     my ($new_value) = @_;
 995
 996     $__local_network = $new_value if defined($new_value);
 997
 998     return $__local_network if defined($__local_network);
 999
1000     eval {
1001         my $nodename = PVE::INotify::nodename();
1002
1003         my $ip = PVE::Cluster::remote_node_ip($nodename);
1004
1005         my $testip = Net::IP->new($ip);
1006
1007         my $isv6 = $testip->version == 6;
1008         my $routes = $isv6 ? PVE::ProcFSTools::read_proc_net_ipv6_route()
1009                            : PVE::ProcFSTools::read_proc_net_route();
1010         foreach my $entry (@$routes) {
1011             my $mask;
1012             if ($isv6) {
1013                 $mask = $entry->{prefix};
1014                 next if !$mask; # skip the default route...
1015             } else {
1016                 $mask = $PVE::Network::ipv4_mask_hash_localnet->{$entry->{mask}};
1017                 next if !defined($mask);
1018             }
1019             my $cidr = "$entry->{dest}/$mask";
1020             my $testnet = Net::IP->new($cidr);
1021             my $overlap = $testnet->overlaps($testip);
1022             if ($overlap == $Net::IP::IP_B_IN_A_OVERLAP ||
1023                 $overlap == $Net::IP::IP_IDENTICAL)
1024             {
1025                 $__local_network = $cidr;
1026                 return;
1027             }
1028         }
1029     };
1030     warn $@ if $@;
1031
1032     return $__local_network;
1033 }
1034
1035 # ipset names are limited to 31 characters,
1036 # and we use '-v4' or '-v6' to indicate IP versions,
1037 # and we use '_swap' suffix for atomic update,
1038 # for example PVEFW-${VMID}-${ipset_name}_swap
1039
1040 my $max_iptables_ipset_name_length = 31 - length("PVEFW-") - length("_swap");
1041
1042 sub compute_ipset_chain_name {
1043     my ($vmid, $ipset_name, $ipversion) = @_;
1044
1045     $vmid = 0 if !defined($vmid);
1046
1047     my $id = "$vmid-${ipset_name}-v$ipversion";
1048
1049     if (length($id) > $max_iptables_ipset_name_length) {
1050         $id = PVE::Tools::fnv31a_hex($id);
1051     }
1052
1053     return "PVEFW-$id";
1054 }
1055
1056 sub compute_ipfilter_ipset_name {
1057     my ($iface) = @_;
1058
1059     return "ipfilter-$iface";
1060 }
1061
1062 sub parse_address_list {
1063     my ($str) = @_;
1064
1065     if ($str =~ m/^(\+)(\S+)$/) { # ipset ref
1066         die "ipset name too long\n" if length($str) > ($max_ipset_name_length + 1);
1067         return;
1068     }
1069
1070     if ($str =~ m/^${ip_alias_pattern}$/) {
1071         die "alias name too long\n" if length($str) > $max_alias_name_length;
1072         return;
1073     }
1074
1075     my $count = 0;
1076     my $iprange = 0;
1077     my $ipversion;
1078
1079     my @elements = split(/,/, $str);
1080     die "extraneous commas in list\n" if $str ne join(',', @elements);
1081     foreach my $elem (@elements) {
1082         $count++;
1083         my $ip = Net::IP->new($elem);
1084         if (!$ip) {
1085             my $err = Net::IP::Error();
1086             die "invalid IP address: $err\n";
1087         }
1088         $iprange = 1 if $elem =~ m/-/;
1089
1090         my $new_ipversion = Net::IP::ip_is_ipv6($ip->ip()) ? 6 : 4;
1091
1092         die "detected mixed ipv4/ipv6 addresses in address list '$str'\n"
1093             if $ipversion && ($new_ipversion != $ipversion);
1094
1095         $ipversion = $new_ipversion;
1096     }
1097
1098     die "you can't use a range in a list\n" if $iprange && $count > 1;
1099
1100     return $ipversion;
1101 }
1102
1103 sub parse_port_name_number_or_range {
1104     my ($str, $dport) = @_;
1105
1106     my $services = PVE::Firewall::get_etc_services();
1107     my $count = 0;
1108     my $icmp_port = 0;
1109
1110     my @elements = split(/,/, $str);
1111     die "extraneous commas in list\n" if $str ne join(',', @elements);
1112     foreach my $item (@elements) {
1113         if ($item =~ m/^([0-9]+):([0-9]+)$/) {
1114             $count += 2;
1115             my ($port1, $port2) = ($1, $2);
1116             die "invalid port '$port1'\n" if $port1 > 65535;
1117             die "invalid port '$port2'\n" if $port2 > 65535;
1118             die "backwards range '$port1:$port2' not allowed, did you mean '$port2:$port1'?\n" if $port1 > $port2;
1119         } elsif ($item =~ m/^([0-9]+)$/) {
1120             $count += 1;
1121             my $port = $1;
1122             die "invalid port '$port'\n" if $port > 65535;
1123         } else {
1124             if ($dport && $icmp_type_names->{$item}) {
1125                 $icmp_port = 1;
1126             } elsif ($dport && $icmpv6_type_names->{$item}) {
1127                 $icmp_port = 1;
1128             } else {
1129                 die "invalid port '$item'\n" if !$services->{byname}->{$item};
1130             }
1131         }
1132     }
1133
1134     die "ICMP ports not allowed in port range\n" if $icmp_port && $count > 0;
1135
1136     # I really don't like to use the word number here, but it's the only thing
1137     # that makes sense in a literal way. The range 1:100 counts as 2, not as
1138     # one and not as 100...
1139     die "too many entries in port list (> 15 numbers)\n"
1140         if $count > 15;
1141
1142     return (scalar(@elements) > 1);
1143 }
1144
1145 PVE::JSONSchema::register_format('pve-fw-conntrack-helper', \&pve_fw_verify_conntrack_helper);
1146 sub pve_fw_verify_conntrack_helper {
1147    my ($list) = @_;
1148
1149    my @helpers = split(/,/, $list);
1150    die "extraneous commas in list\n" if $list ne join(',', @helpers);
1151    foreach my $helper (@helpers) {
1152         die "unknown helper $helper" if !$pve_fw_helpers->{$helper};
1153    }
1154
1155    return $list;
1156 }
1157
1158 PVE::JSONSchema::register_format('pve-fw-sport-spec', \&pve_fw_verify_sport_spec);
1159 sub pve_fw_verify_sport_spec {
1160    my ($portstr) = @_;
1161
1162    parse_port_name_number_or_range($portstr, 0);
1163
1164    return $portstr;
1165 }
1166
1167 PVE::JSONSchema::register_format('pve-fw-dport-spec', \&pve_fw_verify_dport_spec);
1168 sub pve_fw_verify_dport_spec {
1169    my ($portstr) = @_;
1170
1171    parse_port_name_number_or_range($portstr, 1);
1172
1173    return $portstr;
1174 }
1175
1176 PVE::JSONSchema::register_format('pve-fw-addr-spec', \&pve_fw_verify_addr_spec);
1177 sub pve_fw_verify_addr_spec {
1178    my ($list) = @_;
1179
1180    parse_address_list($list);
1181
1182    return $list;
1183 }
1184
1185 PVE::JSONSchema::register_format('pve-fw-protocol-spec', \&pve_fw_verify_protocol_spec);
1186 sub pve_fw_verify_protocol_spec {
1187    my ($proto) = @_;
1188
1189    my $protocols = get_etc_protocols();
1190
1191    die "unknown protocol '$proto'\n" if $proto &&
1192        !(defined($protocols->{byname}->{$proto}) ||
1193          defined($protocols->{byid}->{$proto}));
1194
1195    return $proto;
1196 }
1197
1198 PVE::JSONSchema::register_format('pve-fw-icmp-type-spec', \&pve_fw_verify_icmp_type_spec);
1199 sub pve_fw_verify_icmp_type_spec {
1200     my ($icmp_type) = @_;
1201
1202     if ($icmp_type_names->{$icmp_type} ||  $icmpv6_type_names->{$icmp_type}) {
1203         return $icmp_type;
1204     }
1205
1206     die "invalid icmp-type value '$icmp_type'\n" if $icmp_type ne '';
1207
1208     return $icmp_type;
1209 }
1210
1211
1212 # helper function for API
1213
1214 sub copy_opject_with_digest {
1215     my ($object) = @_;
1216
1217     my $sha = Digest::SHA->new('sha1');
1218
1219     my $res = {};
1220     foreach my $k (sort keys %$object) {
1221         my $v = $object->{$k};
1222         next if !defined($v);
1223         $res->{$k} = $v;
1224         $sha->add($k, ':', $v, "\n");
1225     }
1226
1227     my $digest = $sha->hexdigest;
1228
1229     $res->{digest} = $digest;
1230
1231     return wantarray ? ($res, $digest) : $res;
1232 }
1233
1234 sub copy_list_with_digest {
1235     my ($list) = @_;
1236
1237     my $sha = Digest::SHA->new('sha1');
1238
1239     my $res = [];
1240     foreach my $entry (@$list) {
1241         my $data = {};
1242         foreach my $k (sort keys %$entry) {
1243             my $v = $entry->{$k};
1244             next if !defined($v);
1245             $data->{$k} = $v;
1246             # Note: digest ignores refs ($rule->{errors})
1247             # since Digest::SHA expects a series of bytes,
1248             #  we have to encode the value here to prevent errors when
1249             #  using utf8 characters (eg. in comments)
1250             $sha->add($k, ':', encode_utf8($v), "\n") if !ref($v); ;
1251         }
1252         push @$res, $data;
1253     }
1254
1255     my $digest = $sha->hexdigest;
1256
1257     foreach my $entry (@$res) {
1258         $entry->{digest} = $digest;
1259     }
1260
1261     return wantarray ? ($res, $digest) : $res;
1262 }
1263
1264 our $cluster_option_properties = {
1265     enable => {
1266         description => "Enable or disable the firewall cluster wide.",
1267         type => 'integer',
1268         minimum => 0,
1269         optional => 1,
1270     },
1271     ebtables => {
1272         description => "Enable ebtables rules cluster wide.",
1273         type => 'boolean',
1274         default => 1,
1275         optional => 1,
1276     },
1277     policy_in => {
1278         description => "Input policy.",
1279         type => 'string',
1280         optional => 1,
1281         enum => ['ACCEPT', 'REJECT', 'DROP'],
1282     },
1283     policy_out => {
1284         description => "Output policy.",
1285         type => 'string',
1286         optional => 1,
1287         enum => ['ACCEPT', 'REJECT', 'DROP'],
1288     },
1289     log_ratelimit => {
1290         description => "Log ratelimiting settings",
1291         type => 'string', format => {
1292             enable => {
1293                 default_key => 1,
1294                 description => 'Enable or disable log rate limiting',
1295                 type => 'boolean',
1296                 default => '1',
1297             },
1298             rate => {
1299                 type => 'string',
1300                 description => 'Frequency with which the burst bucket gets refilled',
1301                 optional => 1,
1302                 pattern => '[1-9][0-9]*\/(second|minute|hour|day)',
1303                 format_description => 'rate',
1304                 default => '1/second',
1305             },
1306             burst => {
1307                 type => 'integer',
1308                 minimum => 0,
1309                 optional => 1,
1310                 description => 'Initial burst of packages which will always get logged before the rate is applied',
1311                 default => 5,
1312             },
1313         },
1314         optional => 1,
1315     },
1316 };
1317
1318 our $host_option_properties = {
1319     enable => {
1320         description => "Enable host firewall rules.",
1321         type => 'boolean',
1322         optional => 1,
1323     },
1324     log_level_in =>  get_standard_option('pve-fw-loglevel', {
1325         description => "Log level for incoming traffic." }),
1326     log_level_out =>  get_standard_option('pve-fw-loglevel', {
1327         description => "Log level for outgoing traffic." }),
1328     tcp_flags_log_level =>  get_standard_option('pve-fw-loglevel', {
1329         description => "Log level for illegal tcp flags filter." }),
1330     smurf_log_level =>  get_standard_option('pve-fw-loglevel', {
1331         description => "Log level for SMURFS filter." }),
1332     nosmurfs => {
1333         description => "Enable SMURFS filter.",
1334         type => 'boolean',
1335         optional => 1,
1336     },
1337     tcpflags => {
1338         description => "Filter illegal combinations of TCP flags.",
1339         type => 'boolean',
1340         default => 0,
1341         optional => 1,
1342     },
1343     nf_conntrack_max => {
1344         description => "Maximum number of tracked connections.",
1345         type => 'integer',
1346         optional => 1,
1347         default => 262144,
1348         minimum => 32768,
1349     },
1350     nf_conntrack_tcp_timeout_established => {
1351         description => "Conntrack established timeout.",
1352         type => 'integer',
1353         optional => 1,
1354         default => 432000,
1355         minimum => 7875,
1356     },
1357     nf_conntrack_tcp_timeout_syn_recv => {
1358         description => "Conntrack syn recv timeout.",
1359         type => 'integer',
1360         optional => 1,
1361         default => 60,
1362         minimum => 30,
1363         maximum => 60,
1364     },
1365     ndp => {
1366         description => "Enable NDP (Neighbor Discovery Protocol).",
1367         type => 'boolean',
1368         default => 0,
1369         optional => 1,
1370     },
1371     nf_conntrack_allow_invalid => {
1372         description => "Allow invalid packets on connection tracking.",
1373         type => 'boolean',
1374         default => 0,
1375         optional => 1,
1376     },
1377     nf_conntrack_helpers => {
1378         type => 'string', format => 'pve-fw-conntrack-helper',
1379         description => "Enable conntrack helpers for specific protocols. ".
1380             "Supported protocols: amanda, ftp, irc, netbios-ns, pptp, sane, sip, snmp, tftp",
1381         default => '',
1382         optional => 1,
1383     },
1384     protection_synflood => {
1385         description => "Enable synflood protection",
1386         type => 'boolean',
1387         default => 0,
1388         optional => 1,
1389     },
1390     protection_synflood_rate => {
1391         description => "Synflood protection rate syn/sec by ip src.",
1392         type => 'integer',
1393         optional => 1,
1394         default => 200,
1395     },
1396     protection_synflood_burst => {
1397         description => "Synflood protection rate burst by ip src.",
1398         type => 'integer',
1399         optional => 1,
1400         default => 1000,
1401     },
1402     log_nf_conntrack => {
1403         description => "Enable logging of conntrack information.",
1404         type => 'boolean',
1405         default => 0,
1406         optional => 1
1407     },
1408 };
1409
1410 our $vm_option_properties = {
1411     enable => {
1412         description => "Enable/disable firewall rules.",
1413         type => 'boolean',
1414         default => 0,
1415         optional => 1,
1416     },
1417     macfilter => {
1418         description => "Enable/disable MAC address filter.",
1419         type => 'boolean',
1420         default => 1,
1421         optional => 1,
1422     },
1423     dhcp => {
1424         description => "Enable DHCP.",
1425         type => 'boolean',
1426         default => 0,
1427         optional => 1,
1428     },
1429     ndp => {
1430         description => "Enable NDP (Neighbor Discovery Protocol).",
1431         type => 'boolean',
1432         default => 0,
1433         optional => 1,
1434     },
1435     radv => {
1436         description => "Allow sending Router Advertisement.",
1437         type => 'boolean',
1438         optional => 1,
1439     },
1440     ipfilter => {
1441         description => "Enable default IP filters. " .
1442            "This is equivalent to adding an empty ipfilter-net<id> ipset " .
1443            "for every interface. Such ipsets implicitly contain sane default " .
1444            "restrictions such as restricting IPv6 link local addresses to " .
1445            "the one derived from the interface's MAC address. For containers " .
1446            "the configured IP addresses will be implicitly added.",
1447         type => 'boolean',
1448         optional => 1,
1449     },
1450     policy_in => {
1451         description => "Input policy.",
1452         type => 'string',
1453         optional => 1,
1454         enum => ['ACCEPT', 'REJECT', 'DROP'],
1455     },
1456     policy_out => {
1457         description => "Output policy.",
1458         type => 'string',
1459         optional => 1,
1460         enum => ['ACCEPT', 'REJECT', 'DROP'],
1461     },
1462     log_level_in =>  get_standard_option('pve-fw-loglevel', {
1463         description => "Log level for incoming traffic." }),
1464     log_level_out =>  get_standard_option('pve-fw-loglevel', {
1465         description => "Log level for outgoing traffic." }),
1466
1467 };
1468
1469
1470 my $addr_list_descr = "This can refer to a single IP address, an IP set ('+ipsetname') or an IP alias definition. You can also specify an address range like '20.34.101.207-201.3.9.99', or a list of IP addresses and networks (entries are separated by comma). Please do not mix IPv4 and IPv6 addresses inside such lists.";
1471
1472 my $port_descr = "You can use service names or simple numbers (0-65535), as defined in '/etc/services'. Port ranges can be specified with '\\d+:\\d+', for example '80:85', and you can use comma separated list to match several ports or ranges.";
1473
1474 my $rule_properties = {
1475     pos => {
1476         description => "Update rule at position <pos>.",
1477         type => 'integer',
1478         minimum => 0,
1479         optional => 1,
1480     },
1481     digest => get_standard_option('pve-config-digest'),
1482     type => {
1483         description => "Rule type.",
1484         type => 'string',
1485         optional => 1,
1486         enum => ['in', 'out', 'group'],
1487     },
1488     action => {
1489         description => "Rule action ('ACCEPT', 'DROP', 'REJECT') or security group name.",
1490         type => 'string',
1491         optional => 1,
1492         pattern => $security_group_name_pattern,
1493         maxLength => 20,
1494         minLength => 2,
1495     },
1496     macro => {
1497         description => "Use predefined standard macro.",
1498         type => 'string',
1499         optional => 1,
1500         maxLength => 128,
1501     },
1502     iface => get_standard_option('pve-iface', {
1503         description => "Network interface name. You have to use network configuration key names for VMs and containers ('net\\d+'). Host related rules can use arbitrary strings.",
1504         optional => 1
1505     }),
1506     source => {
1507         description => "Restrict packet source address. $addr_list_descr",
1508         type => 'string', format => 'pve-fw-addr-spec',
1509         optional => 1,
1510         maxLength => 512,
1511     },
1512     dest => {
1513         description => "Restrict packet destination address. $addr_list_descr",
1514         type => 'string', format => 'pve-fw-addr-spec',
1515         optional => 1,
1516         maxLength => 512,
1517     },
1518     proto => {
1519         description => "IP protocol. You can use protocol names ('tcp'/'udp') or simple numbers, as defined in '/etc/protocols'.",
1520         type => 'string', format => 'pve-fw-protocol-spec',
1521         optional => 1,
1522     },
1523     enable => {
1524         description => "Flag to enable/disable a rule.",
1525         type => 'integer',
1526         minimum => 0,
1527         optional => 1,
1528     },
1529     log => get_standard_option('pve-fw-loglevel', {
1530         description => "Log level for firewall rule.",
1531     }),
1532     sport => {
1533         description => "Restrict TCP/UDP source port. $port_descr",
1534         type => 'string', format => 'pve-fw-sport-spec',
1535         optional => 1,
1536     },
1537     dport => {
1538         description => "Restrict TCP/UDP destination port. $port_descr",
1539         type => 'string', format => 'pve-fw-dport-spec',
1540         optional => 1,
1541     },
1542     comment => {
1543         description => "Descriptive comment.",
1544         type => 'string',
1545         optional => 1,
1546     },
1547     'icmp-type' => {
1548         description => "Specify icmp-type. Only valid if proto equals 'icmp' or 'icmpv6'/'ipv6-icmp'.",
1549         type => 'string', format => 'pve-fw-icmp-type-spec',
1550         optional => 1,
1551     },
1552 };
1553
1554 sub add_rule_properties {
1555     my ($properties) = @_;
1556
1557     foreach my $k (keys %$rule_properties) {
1558         my $h = $rule_properties->{$k};
1559         # copy data, so that we can modify later without side effects
1560         foreach my $opt (keys %$h) { $properties->{$k}->{$opt} = $h->{$opt}; }
1561     }
1562
1563     return $properties;
1564 }
1565
1566 sub delete_rule_properties {
1567     my ($rule, $delete_str) = @_;
1568
1569     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1570         raise_param_exc({ 'delete' => "no such property ('$opt')"})
1571             if !defined($rule_properties->{$opt});
1572         raise_param_exc({ 'delete' => "unable to delete required property '$opt'"})
1573             if $opt eq 'type' || $opt eq 'action';
1574         delete $rule->{$opt};
1575     }
1576
1577     return $rule;
1578 }
1579
1580 my $apply_macro = sub {
1581     my ($macro_name, $param, $verify, $ipversion) = @_;
1582
1583     my $macro_rules = $pve_fw_parsed_macros->{$macro_name};
1584     die "unknown macro '$macro_name'\n" if !$macro_rules; # should not happen
1585
1586     if ($ipversion && ($ipversion == 6) && $pve_ipv6fw_macros->{$macro_name}) {
1587         $macro_rules = $pve_ipv6fw_macros->{$macro_name};
1588     }
1589
1590     # skip macros which are specific to another ipversion
1591     if ($ipversion && (my $required = $pve_fw_macro_ipversion->{$macro_name})) {
1592         return if $ipversion != $required;
1593     }
1594
1595     my $rules = [];
1596
1597     foreach my $templ (@$macro_rules) {
1598         my $rule = {};
1599         my $param_used = {};
1600         foreach my $k (keys %$templ) {
1601             my $v = $templ->{$k};
1602             if ($v eq 'PARAM') {
1603                 $v = $param->{$k};
1604                 $param_used->{$k} = 1;
1605             } elsif ($v eq 'DEST') {
1606                 $v = $param->{dest};
1607                 $param_used->{dest} = 1;
1608             } elsif ($v eq 'SOURCE') {
1609                 $v = $param->{source};
1610                 $param_used->{source} = 1;
1611             }
1612
1613             if (!defined($v)) {
1614                 my $msg = "missing parameter '$k' in macro '$macro_name'";
1615                 raise_param_exc({ macro => $msg }) if $verify;
1616                 die "$msg\n";
1617             }
1618             $rule->{$k} = $v;
1619         }
1620         foreach my $k (keys %$param) {
1621             next if $k eq 'macro';
1622             next if !defined($param->{$k});
1623             next if $param_used->{$k};
1624             if (defined($rule->{$k})) {
1625                 if ($rule->{$k} ne $param->{$k}) {
1626                     my $msg = "parameter '$k' already define in macro (value = '$rule->{$k}')";
1627                     raise_param_exc({ $k => $msg }) if $verify;
1628                     die "$msg\n";
1629                 }
1630             } else {
1631                 $rule->{$k} = $param->{$k};
1632             }
1633         }
1634         push @$rules, $rule;
1635     }
1636
1637     return $rules;
1638 };
1639
1640 my $rule_env_iface_lookup = {
1641     'ct' => 1,
1642     'vm' => 1,
1643     'group' => 0,
1644     'cluster' => 1,
1645     'host' => 1,
1646 };
1647
1648 sub verify_rule {
1649     my ($rule, $cluster_conf, $fw_conf, $rule_env, $noerr) = @_;
1650
1651     my $allow_groups = $rule_env eq 'group' ? 0 : 1;
1652
1653     my $allow_iface = $rule_env_iface_lookup->{$rule_env};
1654     die "unknown rule_env '$rule_env'\n" if !defined($allow_iface); # should not happen
1655
1656     my $errors = $rule->{errors} || {};
1657
1658     my $error_count = 0;
1659
1660     my $add_error = sub {
1661         my ($param, $msg)  = @_;
1662         chomp $msg;
1663         raise_param_exc({ $param => $msg }) if !$noerr;
1664         $error_count++;
1665         $errors->{$param} = $msg if !$errors->{$param};
1666     };
1667
1668     my $ipversion;
1669     my $set_ip_version = sub {
1670         my $vers = shift;
1671         if ($vers) {
1672             die "detected mixed ipv4/ipv6 addresses in rule\n"
1673                 if $ipversion && ($vers != $ipversion);
1674             $ipversion = $vers;
1675         }
1676     };
1677
1678     my $check_ipset_or_alias_property = sub {
1679         my ($name, $expected_ipversion) = @_;
1680
1681         if (my $value = $rule->{$name}) {
1682             if ($value =~ m/^\+/) {
1683                 if ($value =~ m/^\+(${ipset_name_pattern})$/) {
1684                     &$add_error($name, "no such ipset '$1'")
1685                         if !($cluster_conf->{ipset}->{$1} || ($fw_conf && $fw_conf->{ipset}->{$1}));
1686
1687                 } else {
1688                     &$add_error($name, "invalid ipset name '$value'");
1689                 }
1690             } elsif ($value =~ m/^${ip_alias_pattern}$/){
1691                 my $alias = lc($value);
1692                 &$add_error($name, "no such alias '$value'")
1693                     if !($cluster_conf->{aliases}->{$alias} || ($fw_conf && $fw_conf->{aliases}->{$alias}));
1694                 my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
1695                 $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
1696
1697                 &$set_ip_version($e->{ipversion});
1698             }
1699         }
1700     };
1701
1702     my $type = $rule->{type};
1703     my $action = $rule->{action};
1704
1705     &$add_error('type', "missing property") if !$type;
1706     &$add_error('action', "missing property") if !$action;
1707
1708     if ($type) {
1709         if ($type eq  'in' || $type eq 'out') {
1710             &$add_error('action', "unknown action '$action'")
1711                 if $action && ($action !~ m/^(ACCEPT|DROP|REJECT)$/);
1712         } elsif ($type eq 'group') {
1713             &$add_error('type', "security groups not allowed")
1714                 if !$allow_groups;
1715             &$add_error('action', "invalid characters in security group name")
1716                 if $action && ($action !~ m/^${security_group_name_pattern}$/);
1717         } else {
1718             &$add_error('type', "unknown rule type '$type'");
1719         }
1720     }
1721
1722     if ($rule->{iface}) {
1723         &$add_error('type', "parameter -i not allowed for this rule type")
1724             if !$allow_iface;
1725         eval { PVE::JSONSchema::pve_verify_iface($rule->{iface}); };
1726         &$add_error('iface', $@) if $@;
1727         if ($rule_env eq 'vm' || $rule_env eq 'ct') {
1728             &$add_error('iface', "value does not match the regex pattern 'net\\d+'")
1729                 if $rule->{iface} !~  m/^net(\d+)$/;
1730         }
1731     }
1732
1733     if ($rule->{macro}) {
1734         if (my $preferred_name = $pve_fw_preferred_macro_names->{lc($rule->{macro})}) {
1735             $rule->{macro} = $preferred_name;
1736         } else {
1737             &$add_error('macro', "unknown macro '$rule->{macro}'");
1738         }
1739     }
1740
1741     my $is_icmp = 0;
1742     if ($rule->{proto}) {
1743         eval { pve_fw_verify_protocol_spec($rule->{proto}); };
1744         &$add_error('proto', $@) if $@;
1745         &$set_ip_version(4) if $rule->{proto} eq 'icmp';
1746         &$set_ip_version(6) if $rule->{proto} eq 'icmpv6';
1747         &$set_ip_version(6) if $rule->{proto} eq 'ipv6-icmp';
1748         $is_icmp = $proto_is_icmp->($rule->{proto});
1749     }
1750
1751     if ($rule->{dport}) {
1752         eval { parse_port_name_number_or_range($rule->{dport}, 1); };
1753         &$add_error('dport', $@) if $@;
1754         my $proto = $rule->{proto};
1755         &$add_error('proto', "missing property - 'dport' requires this property")
1756             if !$proto;
1757         &$add_error('dport', "protocol '$proto' does not support ports")
1758             if !$PROTOCOLS_WITH_PORTS->{$proto} && !$is_icmp; #special cases
1759     }
1760
1761     if (my $icmp_type = $rule ->{'icmp-type'}) {
1762         my $proto = $rule->{proto};
1763         &$add_error('proto', "missing property - 'icmp-type' requires this property")
1764             if !$is_icmp;
1765         &$add_error('icmp-type', "'icmp-type' cannot be specified together with 'dport'")
1766             if $rule->{dport};
1767         if ($proto eq 'icmp' && !$icmp_type_names->{$icmp_type}) {
1768             &$add_error('icmp-type', "invalid icmp-type '$icmp_type' for proto 'icmp'");
1769         } elsif (($proto eq 'icmpv6' || $proto eq 'ipv6-icmp') && !$icmpv6_type_names->{$icmp_type}) {
1770             &$add_error('icmp-type', "invalid icmp-type '$icmp_type' for proto '$proto'");
1771         }
1772     }
1773
1774     if ($rule->{sport}) {
1775         eval { parse_port_name_number_or_range($rule->{sport}, 0); };
1776         &$add_error('sport', $@) if $@;
1777         my $proto = $rule->{proto};
1778         &$add_error('proto', "missing property - 'sport' requires this property")
1779             if !$proto;
1780         &$add_error('sport', "protocol '$proto' does not support ports")
1781             if !$PROTOCOLS_WITH_PORTS->{$proto};
1782     }
1783
1784     if ($rule->{source}) {
1785         eval {
1786             my $source_ipversion = parse_address_list($rule->{source});
1787             &$set_ip_version($source_ipversion);
1788         };
1789         &$add_error('source', $@) if $@;
1790         &$check_ipset_or_alias_property('source', $ipversion);
1791     }
1792
1793     if ($rule->{dest}) {
1794         eval {
1795             my $dest_ipversion = parse_address_list($rule->{dest});
1796             &$set_ip_version($dest_ipversion);
1797         };
1798         &$add_error('dest', $@) if $@;
1799         &$check_ipset_or_alias_property('dest', $ipversion);
1800     }
1801
1802     $rule->{ipversion} = $ipversion if $ipversion;
1803
1804     if ($rule->{macro} && !$error_count) {
1805         eval { &$apply_macro($rule->{macro}, $rule, 1, $ipversion); };
1806         if (my $err = $@) {
1807             if (ref($err) eq "PVE::Exception" && $err->{errors}) {
1808                 my $eh = $err->{errors};
1809                 foreach my $p (keys %$eh) {
1810                     &$add_error($p, $eh->{$p});
1811                 }
1812             } else {
1813                 &$add_error('macro', "$err");
1814             }
1815         }
1816     }
1817
1818     $rule->{errors} = $errors if $error_count;
1819
1820     return $rule;
1821 }
1822
1823 sub copy_rule_data {
1824     my ($rule, $param) = @_;
1825
1826     foreach my $k (keys %$rule_properties) {
1827         if (defined(my $v = $param->{$k})) {
1828             if ($v eq '' || $v eq '-') {
1829                 delete $rule->{$k};
1830             } else {
1831                 $rule->{$k} = $v;
1832             }
1833         }
1834     }
1835
1836     return $rule;
1837 }
1838
1839 sub rules_modify_permissions {
1840     my ($rule_env) = @_;
1841
1842     if ($rule_env eq 'host') {
1843         return {
1844             check => ['perm', '/nodes/{node}', [ 'Sys.Modify' ]],
1845         };
1846     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1847         return {
1848             check => ['perm', '/', [ 'Sys.Modify' ]],
1849         };
1850     } elsif ($rule_env eq 'vm' || $rule_env eq 'ct') {
1851         return {
1852             check => ['perm', '/vms/{vmid}', [ 'VM.Config.Network' ]],
1853         }
1854     }
1855
1856     return undef;
1857 }
1858
1859 sub rules_audit_permissions {
1860     my ($rule_env) = @_;
1861
1862     if ($rule_env eq 'host') {
1863         return {
1864             check => ['perm', '/nodes/{node}', [ 'Sys.Audit' ]],
1865         };
1866     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1867         return {
1868             check => ['perm', '/', [ 'Sys.Audit' ]],
1869         };
1870     } elsif ($rule_env eq 'vm' || $rule_env eq 'ct') {
1871         return {
1872             check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1873         }
1874     }
1875
1876     return undef;
1877 }
1878
1879 # core functions
1880
1881 sub enable_bridge_firewall {
1882
1883
1884     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
1885     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
1886
1887     # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
1888     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
1889
1890 }
1891
1892 sub iptables_restore_cmdlist {
1893     my ($cmdlist, $table) = @_;
1894
1895     $table = 'filter' if !$table;
1896     run_command(['iptables-restore', '-T', $table, '-n'], input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1897 }
1898
1899 sub ip6tables_restore_cmdlist {
1900     my ($cmdlist, $table) = @_;
1901
1902     $table = 'filter' if !$table;
1903     run_command(['ip6tables-restore', '-T', $table, '-n'], input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1904 }
1905
1906 sub ipset_restore_cmdlist {
1907     my ($cmdlist) = @_;
1908
1909     run_command(['ipset', 'restore'], input => $cmdlist, errmsg => "ipset_restore_cmdlist");
1910 }
1911
1912 sub ebtables_restore_cmdlist {
1913     my ($cmdlist) = @_;
1914
1915     run_command(['ebtables-restore'], input => $cmdlist, errmsg => "ebtables_restore_cmdlist");
1916 }
1917
1918 sub iptables_get_chains {
1919     my ($iptablescmd, $t) = @_;
1920
1921     $iptablescmd = "iptables" if !$iptablescmd;
1922     $t = 'filter' if !$t;
1923
1924     my $res = {};
1925
1926     # check what chains we want to track
1927     my $is_pvefw_chain = sub {
1928         my $name = shift;
1929
1930         return 1 if $name =~ m/^PVEFW-\S+$/;
1931
1932         return 1 if $name =~ m/^tap\d+i\d+-(?:IN|OUT)$/;
1933
1934         return 1 if $name =~ m/^veth\d+i\d+-(?:IN|OUT)$/;
1935
1936         return 1 if $name =~ m/^fwbr\d+(v\d+)?-(?:FW|IN|OUT|IPS)$/;
1937         return 1 if $name =~ m/^GROUP-(?:$security_group_name_pattern)-(?:IN|OUT)$/;
1938
1939         return undef;
1940     };
1941
1942     my $table = '';
1943
1944     my $hooks = {};
1945
1946     my $parser = sub {
1947         my $line = shift;
1948
1949         return if $line =~ m/^#/;
1950         return if $line =~ m/^\s*$/;
1951
1952         if ($line =~ m/^\*(\S+)$/) {
1953             $table = $1;
1954             return;
1955         }
1956
1957         return if $table ne $t;
1958
1959         if ($line =~ m/^:(\S+)\s/) {
1960             my $chain = $1;
1961             return if !&$is_pvefw_chain($chain);
1962             $res->{$chain} = "unknown";
1963         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
1964             my ($chain, $sig) = ($1, $2);
1965             return if !&$is_pvefw_chain($chain);
1966             $res->{$chain} = $sig;
1967         } elsif ($line =~ m/^-A\s+(INPUT|OUTPUT|FORWARD|PREROUTING)\s+-j\s+PVEFW-\1$/) {
1968             $hooks->{$1} = 1;
1969         } else {
1970             # simply ignore the rest
1971             return;
1972         }
1973     };
1974
1975     run_command(["$iptablescmd-save"], outfunc => $parser);
1976
1977     return wantarray ? ($res, $hooks) : $res;
1978 }
1979
1980 sub iptables_chain_digest {
1981     my ($rules) = @_;
1982     my $digest = Digest::SHA->new('sha1');
1983     foreach my $rule (@$rules) { # order is important
1984         $digest->add($rule);
1985     }
1986     return $digest->b64digest;
1987 }
1988
1989 sub ipset_chain_digest {
1990     my ($rules) = @_;
1991
1992     my $digest = Digest::SHA->new('sha1');
1993     foreach my $rule (sort @$rules) { # note: sorted
1994         $digest->add($rule);
1995     }
1996     return $digest->b64digest;
1997 }
1998
1999 sub ipset_get_chains {
2000
2001     my $res = {};
2002     my $chains = {};
2003
2004     my $parser = sub {
2005         my $line = shift;
2006
2007         return if $line =~ m/^#/;
2008         return if $line =~ m/^\s*$/;
2009         if ($line =~ m/^(?:\S+)\s(PVEFW-\S+)\s(?:\S+).*/) {
2010             my $chain = $1;
2011             # ignore initval from ipset v7.7+, won't set that yet so it'd mess up change detection
2012             $line =~ s/\binitval 0x[0-9a-f]+//;
2013             $line =~ s/\s+$//; # delete trailing white space
2014             push @{$chains->{$chain}}, $line;
2015         } else {
2016             # simply ignore the rest
2017             return;
2018         }
2019     };
2020
2021     run_command(['ipset', 'save'], outfunc => $parser);
2022
2023     # compute digest for each chain
2024     foreach my $chain (keys %$chains) {
2025         $res->{$chain} = ipset_chain_digest($chains->{$chain});
2026     }
2027
2028     return $res;
2029 }
2030
2031 sub ebtables_get_chains {
2032
2033     my $res = {};
2034     my $chains = {};
2035     my $table;
2036     my $parser = sub {
2037         my $line = shift;
2038         return if $line =~ m/^#/;
2039         return if $line =~ m/^\s*$/;
2040         if ($line =~ m/^\*(\S+)$/) {
2041             $table = $1;
2042             return;
2043         }
2044
2045         return if $table ne "filter";
2046
2047         if ($line =~ m/^:(\S+)\s(ACCEPT|DROP|RETURN)$/) {
2048             # Make sure we know chains exist even if they're empty.
2049             $chains->{$1} //= [];
2050             $res->{$1}->{policy} = $2;
2051         } elsif ($line =~ m/^(?:\S+)\s(\S+)\s(?:\S+).*/) {
2052             my $chain = $1;
2053             $line =~ s/\s+$//;
2054             push @{$chains->{$chain}}, $line;
2055         } else {
2056             # simply ignore the rest
2057             return;
2058         }
2059     };
2060
2061     run_command(['ebtables-save'], outfunc => $parser);
2062     # compute digest for each chain and store rules as well
2063     foreach my $chain (keys %$chains) {
2064         $res->{$chain}->{rules} = $chains->{$chain};
2065         $res->{$chain}->{sig} = iptables_chain_digest($chains->{$chain});
2066     }
2067     return $res;
2068 }
2069
2070 # substitute action of rule according to action hash
2071 sub rule_substitude_action {
2072     my ($rule, $actions) = @_;
2073
2074     if (my $action = $rule->{action}) {
2075         $rule->{action} = $actions->{$action} if defined($actions->{$action});
2076     }
2077 }
2078
2079 # generate a src or dst match
2080 # $dir(ection) is either d or s
2081 sub ipt_gen_src_or_dst_match {
2082     my ($adr, $dir, $ipversion, $cluster_conf, $fw_conf) = @_;
2083
2084     my $srcdst;
2085     if ($dir eq 's') {
2086         $srcdst = "src";
2087     } elsif ($dir eq 'd') {
2088         $srcdst = "dst";
2089     } else {
2090         die "ipt_gen_src_or_dst_match: invalid direction $dir \n";
2091     }
2092
2093     my $match;
2094     if ($adr =~ m/^\+/) {
2095         if ($adr =~ m/^\+(${ipset_name_pattern})$/) {
2096             my $name = $1;
2097             my $ipset_chain;
2098             if ($fw_conf && $fw_conf->{ipset}->{$name}) {
2099                 $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name, $ipversion);
2100             } elsif ($cluster_conf && $cluster_conf->{ipset}->{$name}) {
2101                 $ipset_chain = compute_ipset_chain_name(0, $name, $ipversion);
2102             } else {
2103                 die "no such ipset '$name'\n";
2104             }
2105             $match = "-m set --match-set ${ipset_chain} ${srcdst}";
2106         } else {
2107             die "invalid security group name '$adr'\n";
2108         }
2109     } elsif ($adr =~ m/^${ip_alias_pattern}$/){
2110         my $alias = lc($adr);
2111         my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
2112         $e = $cluster_conf->{aliases}->{$alias} if !$e && $cluster_conf;
2113         die "no such alias '$adr'\n" if !$e;
2114         $match = "-${dir} $e->{cidr}";
2115     } elsif ($adr =~ m/\-/){
2116         $match = "-m iprange --${srcdst}-range $adr";
2117     } else {
2118         $match = "-${dir} $adr";
2119     }
2120
2121     return $match;
2122 }
2123
2124 # convert a %rule to an array of iptables commands
2125 sub ipt_rule_to_cmds {
2126     my ($rule, $chain, $ipversion, $cluster_conf, $fw_conf, $vmid) = @_;
2127
2128     die "ipt_rule_to_cmds unable to handle macro" if $rule->{macro}; #should not happen
2129
2130     my @match = ();
2131
2132     if (defined $rule->{match}) {
2133         push @match, $rule->{match};
2134     } else {
2135         push @match, "-i $rule->{iface_in}" if $rule->{iface_in};
2136         push @match, "-o $rule->{iface_out}" if $rule->{iface_out};
2137
2138         if ($rule->{source}) {
2139             push @match, ipt_gen_src_or_dst_match($rule->{source}, 's', $ipversion, $cluster_conf, $fw_conf);
2140         }
2141         if ($rule->{dest}) {
2142             push @match, ipt_gen_src_or_dst_match($rule->{dest}, 'd', $ipversion, $cluster_conf, $fw_conf);
2143         }
2144
2145         if (my $proto = $rule->{proto}) {
2146             push @match, "-p $proto";
2147             my $is_icmp = $proto_is_icmp->($proto);
2148
2149             my $multidport = defined($rule->{dport}) && parse_port_name_number_or_range($rule->{dport}, 1);
2150             my $multisport = defined($rule->{sport}) && parse_port_name_number_or_range($rule->{sport}, 0);
2151
2152             my $add_dport = sub {
2153                 return if !defined($rule->{dport});
2154
2155                 # NOTE: we re-use dport to store --icmp-type for icmp* protocol
2156                 if ($proto eq 'icmp') {
2157                     $is_valid_icmp_type->($rule->{dport}, $icmp_type_names);
2158                     push @match, "-m icmp --icmp-type $rule->{dport}";
2159                 } elsif ($proto eq 'icmpv6') {
2160                     $is_valid_icmp_type->($rule->{dport}, $icmpv6_type_names);
2161                     push @match, "-m icmpv6 --icmpv6-type $rule->{dport}";
2162                 } elsif (!$PROTOCOLS_WITH_PORTS->{$proto}) {
2163                     die "protocol $proto does not have ports\n";
2164                 } elsif ($multidport) {
2165                     push @match, "--match multiport", "--dports $rule->{dport}";
2166                 } else {
2167                     return if !$rule->{dport};
2168                     push @match, "--dport $rule->{dport}";
2169                 }
2170             };
2171
2172             my $add_sport = sub {
2173                 return if !$rule->{sport};
2174
2175                 die "protocol $proto does not have ports\n"
2176                     if !$PROTOCOLS_WITH_PORTS->{$proto};
2177                 if ($multisport) {
2178                     push @match, "--match multiport", "--sports $rule->{sport}";
2179                 } else {
2180                     push @match, "--sport $rule->{sport}";
2181                 }
2182             };
2183
2184             my $add_icmp_type = sub {
2185                 return if !defined($rule->{'icmp-type'}) || $rule->{'icmp-type'} eq '';
2186
2187                 die "'icmp-type' can only be set if 'icmp', 'icmpv6' or 'ipv6-icmp' is specified\n"
2188                     if !$is_icmp;
2189                 my $type = $proto eq 'icmp' ? 'icmp-type' : 'icmpv6-type';
2190
2191                 push @match, "-m $proto --$type $rule->{'icmp-type'}";
2192             };
2193
2194             # order matters - single port before multiport!
2195             $add_icmp_type->();
2196             $add_dport->() if $multisport;
2197             $add_sport->();
2198             $add_dport->() if !$multisport;
2199         } elsif ($rule->{dport} || $rule->{sport}) {
2200             die "destination port '$rule->{dport}', but no protocol specified\n" if $rule->{dport};
2201             die "source port '$rule->{sport}', but no protocol specified\n" if $rule->{sport};
2202         }
2203
2204         push @match, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
2205     }
2206     my $matchstr = scalar(@match) ? join(' ', @match) : "";
2207
2208     my $targetstr;
2209     if (defined $rule->{target}) {
2210         $targetstr = $rule->{target};
2211     } else {
2212         my $action = (defined $rule->{action}) ? $rule->{action} : "";
2213         $targetstr = $action eq 'PVEFW-SET-ACCEPT-MARK' ? "-g $action" : "-j $action";
2214     }
2215
2216     my @iptcmds;
2217     my $log = $rule->{log};
2218     if (defined($log) && $log ne 'nolog') {
2219         my $loglevel = $log_level_hash->{$log};
2220         my $logaction = get_log_rule_base($chain, $vmid, $rule->{logmsg}, $loglevel);
2221         push @iptcmds, "-A $chain $matchstr $logaction";
2222     }
2223     push @iptcmds, "-A $chain $matchstr $targetstr";
2224     return @iptcmds;
2225 }
2226
2227 sub ruleset_generate_rule {
2228     my ($ruleset, $chain, $ipversion, $rule, $cluster_conf, $fw_conf, $vmid) = @_;
2229
2230     my $rules;
2231
2232     if ($rule->{macro}) {
2233         $rules = &$apply_macro($rule->{macro}, $rule, 0, $ipversion);
2234     } else {
2235         $rules = [ $rule ];
2236     }
2237
2238     # update all or nothing
2239     my @ipt_rule_cmds;
2240     foreach my $r (@$rules) {
2241         push @ipt_rule_cmds, ipt_rule_to_cmds($r, $chain, $ipversion, $cluster_conf, $fw_conf, $vmid);
2242     }
2243     foreach my $c (@ipt_rule_cmds) {
2244         ruleset_add_ipt_cmd($ruleset, $chain, $c);
2245     }
2246 }
2247
2248 sub ruleset_create_chain {
2249     my ($ruleset, $chain) = @_;
2250
2251     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
2252     die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
2253
2254     die "chain '$chain' already exists\n" if $ruleset->{$chain};
2255
2256     $ruleset->{$chain} = [];
2257 }
2258
2259 sub ruleset_chain_exist {
2260     my ($ruleset, $chain) = @_;
2261
2262     return $ruleset->{$chain} ? 1 : undef;
2263 }
2264
2265 # add an iptables command (like generated by ipt_rule_to_cmds) to a chain
2266 sub ruleset_add_ipt_cmd {
2267    my ($ruleset, $chain, $iptcmd) = @_;
2268
2269    die "no such chain '$chain'\n" if !$ruleset->{$chain};
2270
2271    push @{$ruleset->{$chain}}, $iptcmd;
2272 }
2273
2274 sub ruleset_addrule {
2275     my ($ruleset, $chain, $match, $action, $log, $logmsg, $vmid) = @_;
2276
2277     die "no such chain '$chain'\n" if !$ruleset->{$chain};
2278
2279     if ($log) {
2280         my $loglevel = $log_level_hash->{$log};
2281         my $logaction = get_log_rule_base($chain, $vmid, $logmsg, $loglevel);
2282         push @{$ruleset->{$chain}}, "-A $chain $match $logaction";
2283     }
2284     # for stable ebtables digests avoid double-spaces to match ebtables-save output
2285     $match .= ' ' if length($match);
2286     push @{$ruleset->{$chain}}, "-A $chain ${match}$action";
2287 }
2288
2289 sub ruleset_insertrule {
2290    my ($ruleset, $chain, $match, $action, $log) = @_;
2291
2292    die "no such chain '$chain'\n" if !$ruleset->{$chain};
2293
2294    unshift @{$ruleset->{$chain}}, "-A $chain $match $action";
2295 }
2296
2297 sub get_log_rule_base {
2298     my ($chain, $vmid, $msg, $loglevel) = @_;
2299
2300     $vmid = 0 if !defined($vmid);
2301     $msg = "" if !defined($msg);
2302
2303     my $rlimit = '';
2304     if (defined($global_log_ratelimit)) {
2305         $rlimit = "-m limit $global_log_ratelimit ";
2306     }
2307
2308     # Note: we use special format for prefix to pass further
2309     # info to log daemon (VMID, LOGLEVEL and CHAIN)
2310     return "${rlimit}-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
2311 }
2312
2313 sub ruleset_add_chain_policy {
2314     my ($ruleset, $chain, $ipversion, $vmid, $policy, $loglevel, $accept_action) = @_;
2315
2316     if ($policy eq 'ACCEPT') {
2317
2318         my $rule = { action => 'ACCEPT' };
2319         rule_substitude_action($rule, { ACCEPT =>  $accept_action});
2320         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule);
2321
2322     } elsif ($policy eq 'DROP') {
2323
2324         ruleset_addrule($ruleset, $chain, "", "-j PVEFW-Drop");
2325
2326         ruleset_addrule($ruleset, $chain, "", "-j DROP", $loglevel, "policy $policy: ", $vmid);
2327     } elsif ($policy eq 'REJECT') {
2328         ruleset_addrule($ruleset, $chain, "", "-j PVEFW-Reject");
2329
2330         ruleset_addrule($ruleset, $chain, "", "-g PVEFW-reject", $loglevel, "policy $policy: ", $vmid);
2331     } else {
2332         # should not happen
2333         die "internal error: unknown policy '$policy'";
2334     }
2335 }
2336
2337 sub ruleset_chain_add_ndp {
2338     my ($ruleset, $chain, $ipversion, $options, $direction, $accept) = @_;
2339     return if $ipversion != 6 || (defined($options->{ndp}) && !$options->{ndp});
2340
2341     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-solicitation", $accept);
2342     if ($direction ne 'OUT' || $options->{radv}) {
2343         ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-advertisement", $accept);
2344     }
2345     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type neighbor-solicitation", $accept);
2346     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type neighbor-advertisement", $accept);
2347 }
2348
2349 sub ruleset_chain_add_conn_filters {
2350     my ($ruleset, $chain, $allow_invalid, $accept) = @_;
2351
2352     if (!$allow_invalid) {
2353         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID", "-j DROP");
2354     }
2355     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED", "-j $accept");
2356 }
2357
2358 sub ruleset_chain_add_input_filters {
2359     my ($ruleset, $chain, $ipversion, $options, $cluster_conf, $loglevel) = @_;
2360
2361     if ($cluster_conf->{ipset}->{blacklist}){
2362         if (!ruleset_chain_exist($ruleset, "PVEFW-blacklist")) {
2363             ruleset_create_chain($ruleset, "PVEFW-blacklist");
2364             ruleset_addrule($ruleset, "PVEFW-blacklist", "", "-j DROP", $loglevel, "DROP: ", 0);
2365         }
2366         my $ipset_chain = compute_ipset_chain_name(0, 'blacklist', $ipversion);
2367         ruleset_addrule($ruleset, $chain, "-m set --match-set ${ipset_chain} src", "-j PVEFW-blacklist");
2368     }
2369
2370     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
2371         if ($ipversion == 4) {
2372             ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW", "-j PVEFW-smurfs");
2373         }
2374     }
2375
2376     if ($options->{tcpflags}) {
2377         ruleset_addrule($ruleset, $chain, "-p tcp", "-j PVEFW-tcpflags");
2378     }
2379 }
2380
2381 sub ruleset_create_vm_chain {
2382     my ($ruleset, $chain, $ipversion, $options, $macaddr, $ipfilter_ipset, $direction) = @_;
2383
2384     ruleset_create_chain($ruleset, $chain);
2385     my $accept = generate_nfqueue($options);
2386
2387     if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
2388         if ($ipversion == 4) {
2389             if ($direction eq 'OUT') {
2390                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2391                                       { action => 'PVEFW-SET-ACCEPT-MARK',
2392                                         proto => 'udp', sport => 68, dport => 67 });
2393             } else {
2394                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2395                                       { action => 'ACCEPT',
2396                                         proto => 'udp', sport => 67, dport => 68 });
2397             }
2398         } elsif ($ipversion == 6) {
2399             if ($direction eq 'OUT') {
2400                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2401                                       { action => 'PVEFW-SET-ACCEPT-MARK',
2402                                         proto => 'udp', sport => 546, dport => 547 });
2403             } else {
2404                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2405                                       { action => 'ACCEPT',
2406                                         proto => 'udp', sport => 547, dport => 546 });
2407             }
2408         }
2409
2410     }
2411
2412     if ($direction eq 'OUT') {
2413         if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
2414             ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr", "-j DROP");
2415         }
2416         if ($ipversion == 6 && !$options->{radv}) {
2417             ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-advertisement", "-j DROP");
2418         }
2419         if ($ipfilter_ipset) {
2420             ruleset_addrule($ruleset, $chain, "-m set ! --match-set $ipfilter_ipset src", "-j DROP");
2421         }
2422         ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2423     }
2424
2425     my $accept_action = $direction eq 'OUT' ? '-g PVEFW-SET-ACCEPT-MARK' : "-j $accept";
2426     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, $direction, $accept_action);
2427 }
2428
2429 sub ruleset_add_group_rule {
2430     my ($ruleset, $cluster_conf, $chain, $rule, $direction, $action, $ipversion) = @_;
2431
2432     my $group = $rule->{action};
2433     my $group_chain = "GROUP-$group-$direction";
2434     if(!ruleset_chain_exist($ruleset, $group_chain)){
2435         generate_group_rules($ruleset, $cluster_conf, $group, $ipversion);
2436     }
2437
2438     if ($direction eq 'OUT' && $rule->{iface_out}) {
2439         ruleset_addrule($ruleset, $chain, "-o $rule->{iface_out}", "-j $group_chain");
2440     } elsif ($direction eq 'IN' && $rule->{iface_in}) {
2441         ruleset_addrule($ruleset, $chain, "-i $rule->{iface_in}", "-j $group_chain");
2442     } else {
2443         ruleset_addrule($ruleset, $chain, "", "-j $group_chain");
2444     }
2445
2446     ruleset_addrule($ruleset, $chain, "-m mark --mark $FWACCEPTMARK_ON", "-j $action");
2447 }
2448
2449 sub ruleset_generate_vm_rules {
2450     my ($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, $netid, $direction, $options, $ipversion, $vmid) = @_;
2451
2452     my $lc_direction = lc($direction);
2453
2454     my $in_accept = generate_nfqueue($options);
2455
2456     foreach my $rule (@$rules) {
2457         next if $rule->{iface} && $rule->{iface} ne $netid;
2458         next if !$rule->{enable} || $rule->{errors};
2459         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2460
2461         if ($rule->{type} eq 'group') {
2462             ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, $direction,
2463                                    $direction eq 'OUT' ? 'RETURN' : $in_accept, $ipversion);
2464         } else {
2465             next if $rule->{type} ne $lc_direction;
2466             eval {
2467                 $rule->{logmsg} = "$rule->{action}: ";
2468                 if ($direction eq 'OUT') {
2469                     rule_substitude_action($rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
2470                     ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $vmfw_conf, $vmid);
2471                 } else {
2472                     rule_substitude_action($rule, { ACCEPT => $in_accept , REJECT => "PVEFW-reject" });
2473                     ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $vmfw_conf, $vmid);
2474                 }
2475             };
2476             warn $@ if $@;
2477         }
2478     }
2479 }
2480
2481 sub generate_nfqueue {
2482     my ($options) = @_;
2483
2484     if ($options->{ips}) {
2485         my $action = "NFQUEUE";
2486         if ($options->{ips_queues} && $options->{ips_queues} =~ m/^(\d+)(:(\d+))?$/) {
2487             if (defined($3) && defined($1)) {
2488                 $action .= " --queue-balance $1:$3";
2489             } elsif (defined($1)) {
2490                 $action .= " --queue-num $1";
2491             }
2492         }
2493         $action .= " --queue-bypass" if $feature_ipset_nomatch; #need kernel 3.10
2494         return $action;
2495     } else {
2496         return "ACCEPT";
2497     }
2498 }
2499
2500 sub ruleset_generate_vm_ipsrules {
2501     my ($ruleset, $options, $direction, $iface) = @_;
2502
2503     if ($options->{ips} && $direction eq 'IN') {
2504         my $nfqueue = generate_nfqueue($options);
2505
2506         if (!ruleset_chain_exist($ruleset, "PVEFW-IPS")) {
2507             ruleset_create_chain($ruleset, "PVEFW-IPS");
2508         }
2509
2510         ruleset_addrule($ruleset, "PVEFW-IPS", "-m physdev --physdev-out $iface --physdev-is-bridged", "-j $nfqueue");
2511     }
2512 }
2513
2514 sub generate_tap_rules_direction {
2515     my ($ruleset, $cluster_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $direction, $ipversion) = @_;
2516
2517     my $lc_direction = lc($direction);
2518
2519     my $rules = $vmfw_conf->{rules};
2520
2521     my $options = $vmfw_conf->{options};
2522     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
2523
2524     my $tapchain = "$iface-$direction";
2525
2526     my $ipfilter_name = compute_ipfilter_ipset_name($netid);
2527     my $ipfilter_ipset;
2528     $ipfilter_ipset = compute_ipset_chain_name($vmid, $ipfilter_name, $ipversion)
2529         if $options->{ipfilter} || $vmfw_conf->{ipset}->{$ipfilter_name};
2530
2531     if ($options->{enable}) {
2532         # create chain with mac and ip filter
2533         ruleset_create_vm_chain($ruleset, $tapchain, $ipversion, $options, $macaddr, $ipfilter_ipset, $direction);
2534
2535         ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $tapchain, $netid, $direction, $options, $ipversion, $vmid);
2536
2537         ruleset_generate_vm_ipsrules($ruleset, $options, $direction, $iface);
2538
2539         # implement policy
2540         my $policy;
2541
2542         if ($direction eq 'OUT') {
2543             $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
2544         } else {
2545             $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
2546         }
2547
2548         my $accept = generate_nfqueue($options);
2549         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
2550         ruleset_add_chain_policy($ruleset, $tapchain, $ipversion, $vmid, $policy, $loglevel, $accept_action);
2551     } else {
2552         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : 'ACCEPT';
2553         ruleset_add_chain_policy($ruleset, $tapchain, $ipversion, $vmid, 'ACCEPT', $loglevel, $accept_action);
2554     }
2555
2556     # plug the tap chain to bridge chain
2557     if ($direction eq 'IN') {
2558         ruleset_addrule($ruleset, "PVEFW-FWBR-IN",
2559                         "-m physdev --physdev-is-bridged --physdev-out $iface", "-j $tapchain");
2560     } else {
2561         ruleset_addrule($ruleset, "PVEFW-FWBR-OUT",
2562                         "-m physdev --physdev-is-bridged --physdev-in $iface", "-j $tapchain");
2563     }
2564 }
2565
2566 sub enable_host_firewall {
2567     my ($ruleset, $hostfw_conf, $cluster_conf, $ipversion, $corosync_conf) = @_;
2568
2569     my $options = $hostfw_conf->{options};
2570     my $cluster_options = $cluster_conf->{options};
2571     my $rules = $hostfw_conf->{rules};
2572     my $cluster_rules = $cluster_conf->{rules};
2573
2574     # corosync preparation
2575     my $corosync_rule = "-p udp --dport 5404:5405";
2576     my $corosync_local_addresses = {};
2577     my $multicast_enabled;
2578     my $local_hostname = PVE::INotify::nodename();
2579     if (defined($corosync_conf)) {
2580         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2581             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2582
2583             if ($node_name eq $local_hostname) {
2584                 $corosync_local_addresses->{$key} = $node_ip;
2585             }
2586         });
2587
2588         # allow multicast only if enabled in config
2589         my $corosync_transport = $corosync_conf->{main}->{totem}->{transport};
2590         $multicast_enabled = defined($corosync_transport) && $corosync_transport eq 'udp';
2591     }
2592
2593     # host inbound firewall
2594     my $chain = "PVEFW-HOST-IN";
2595     ruleset_create_chain($ruleset, $chain);
2596
2597     my $loglevel = get_option_log_level($options, "log_level_in");
2598
2599     ruleset_addrule($ruleset, $chain, "-i lo", "-j ACCEPT");
2600
2601     ruleset_chain_add_conn_filters($ruleset, $chain, 0, 'ACCEPT');
2602     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, 'IN', '-j RETURN');
2603     ruleset_chain_add_input_filters($ruleset, $chain, $ipversion, $options, $cluster_conf, $loglevel);
2604
2605     # we use RETURN because we need to check also tap rules
2606     my $accept_action = 'RETURN';
2607
2608     ruleset_addrule($ruleset, $chain, "-p igmp", "-j $accept_action"); # important for multicast
2609
2610     # add host rules first, so that cluster wide rules can be overwritten
2611     foreach my $rule (@$rules, @$cluster_rules) {
2612         next if !$rule->{enable} || $rule->{errors};
2613         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2614
2615         $rule->{iface_in} = $rule->{iface} if $rule->{iface};
2616
2617         eval {
2618             $rule->{logmsg} = "$rule->{action}: ";
2619             if ($rule->{type} eq 'group') {
2620                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'IN', $accept_action, $ipversion);
2621             } elsif ($rule->{type} eq 'in') {
2622                 rule_substitude_action($rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
2623                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $hostfw_conf, 0);
2624             }
2625         };
2626         warn $@ if $@;
2627         delete $rule->{iface_in};
2628     }
2629
2630     # allow standard traffic for management ipset (includes cluster network)
2631     my $mngmnt_ipset_chain = compute_ipset_chain_name(0, "management", $ipversion);
2632     my $mngmntsrc = "-m set --match-set ${mngmnt_ipset_chain} src";
2633     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 8006", "-j $accept_action");  # PVE API
2634     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 5900:5999", "-j $accept_action");  # PVE VNC Console
2635     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 3128", "-j $accept_action");  # SPICE Proxy
2636     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 22", "-j $accept_action");  # SSH
2637     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 60000:60050", "-j $accept_action");  # Migration
2638
2639     # corosync inbound rules
2640     if (defined($corosync_conf)) {
2641         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule", "-j $accept_action")
2642             if $multicast_enabled;
2643
2644         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2645             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2646             my $destination = $corosync_local_addresses->{$key};
2647
2648             if ($node_name ne $local_hostname && defined($destination)) {
2649                 # accept only traffic on same ring
2650                 ruleset_addrule($ruleset, $chain, "-d $destination -s $node_ip $corosync_rule", "-j $accept_action");
2651             }
2652         });
2653     }
2654
2655     # implement input policy
2656     my $policy = $cluster_options->{policy_in} || 'DROP'; # allow nothing by default
2657     ruleset_add_chain_policy($ruleset, $chain, $ipversion, 0, $policy, $loglevel, $accept_action);
2658
2659     # host outbound firewall
2660     $chain = "PVEFW-HOST-OUT";
2661     ruleset_create_chain($ruleset, $chain);
2662
2663     $loglevel = get_option_log_level($options, "log_level_out");
2664
2665     ruleset_addrule($ruleset, $chain, "-o lo", "-j ACCEPT");
2666
2667     ruleset_chain_add_conn_filters($ruleset, $chain, 0, 'ACCEPT');
2668
2669     # we use RETURN because we may want to check other thigs later
2670     $accept_action = 'RETURN';
2671     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, 'OUT', "-j $accept_action");
2672
2673     ruleset_addrule($ruleset, $chain, "-p igmp", "-j $accept_action"); # important for multicast
2674
2675     # add host rules first, so that cluster wide rules can be overwritten
2676     foreach my $rule (@$rules, @$cluster_rules) {
2677         next if !$rule->{enable} || $rule->{errors};
2678         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2679
2680         $rule->{iface_out} = $rule->{iface} if $rule->{iface};
2681         eval {
2682             $rule->{logmsg} = "$rule->{action}: ";
2683             if ($rule->{type} eq 'group') {
2684                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'OUT', $accept_action, $ipversion);
2685             } elsif ($rule->{type} eq 'out') {
2686                 rule_substitude_action($rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
2687                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $hostfw_conf, 0);
2688             }
2689         };
2690         warn $@ if $@;
2691         delete $rule->{iface_out};
2692     }
2693
2694     # allow standard traffic on cluster network
2695     my $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
2696     my $localnet_ver = $cluster_conf->{aliases}->{local_network}->{ipversion};
2697
2698     if ($localnet && ($ipversion == $localnet_ver)) {
2699         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 8006", "-j $accept_action");  # PVE API
2700         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 22", "-j $accept_action");  # SSH
2701         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 5900:5999", "-j $accept_action");  # PVE VNC Console
2702         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 3128", "-j $accept_action");  # SPICE Proxy
2703     }
2704
2705     # corosync outbound rules
2706     if (defined($corosync_conf)) {
2707         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule", "-j $accept_action")
2708             if $multicast_enabled;
2709
2710         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2711             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2712             my $source = $corosync_local_addresses->{$key};
2713
2714             if ($node_name ne $local_hostname && defined($source)) {
2715                 # accept only traffic on same ring
2716                 ruleset_addrule($ruleset, $chain, "-s $source -d $node_ip $corosync_rule", "-j $accept_action");
2717             }
2718         });
2719     }
2720
2721     # implement output policy
2722     $policy = $cluster_options->{policy_out} || 'ACCEPT'; # allow everything by default
2723     ruleset_add_chain_policy($ruleset, $chain, $ipversion, 0, $policy, $loglevel, $accept_action);
2724
2725     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "", "-j PVEFW-HOST-OUT");
2726     ruleset_addrule($ruleset, "PVEFW-INPUT", "", "-j PVEFW-HOST-IN");
2727 }
2728
2729 sub generate_group_rules {
2730     my ($ruleset, $cluster_conf, $group, $ipversion) = @_;
2731
2732     my $rules = $cluster_conf->{groups}->{$group};
2733
2734     if (!$rules) {
2735         warn "no such security group '$group'\n";
2736         $rules = []; # create empty chain
2737     }
2738
2739     my $chain = "GROUP-${group}-IN";
2740
2741     ruleset_create_chain($ruleset, $chain);
2742     ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2743
2744     foreach my $rule (@$rules) {
2745         next if $rule->{type} ne 'in';
2746         next if !$rule->{enable} || $rule->{errors};
2747         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2748         rule_substitude_action($rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
2749         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf);
2750     }
2751
2752     $chain = "GROUP-${group}-OUT";
2753
2754     ruleset_create_chain($ruleset, $chain);
2755     ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2756
2757     foreach my $rule (@$rules) {
2758         next if $rule->{type} ne 'out';
2759         next if !$rule->{enable} || $rule->{errors};
2760         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2761         # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
2762         # check also other tap rules later
2763         rule_substitude_action($rule, { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" });
2764         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf);
2765     }
2766 }
2767
2768 my $MAX_NETS = 32;
2769 my $valid_netdev_names = {};
2770 for (my $i = 0; $i < $MAX_NETS; $i++)  {
2771     $valid_netdev_names->{"net$i"} = 1;
2772 }
2773
2774 sub get_mark_values {
2775     my ($value, $mask) = @_;
2776     $value = hex($value) if $value =~ /^0x/;
2777     $mask = hex($mask) if defined($mask) && $mask =~ /^0x/;
2778     $mask = 0xffffffff if !defined($mask);
2779     return ($value, $mask);
2780 }
2781
2782 sub parse_fw_rule {
2783     my ($prefix, $line, $cluster_conf, $fw_conf, $rule_env) = @_;
2784
2785     my $orig_line = $line;
2786
2787     my $rule = {};
2788
2789     # we can add single line comments to the end of the rule
2790     if ($line =~ s/#\s*(.*?)\s*$//) {
2791         $rule->{comment} = decode('utf8', $1);
2792     }
2793
2794     # we can disable a rule when prefixed with '|'
2795
2796     $rule->{enable} = $line =~ s/^\|// ? 0 : 1;
2797
2798     $line =~ s/^(\S+)\s+(\S+)\s*// ||
2799         die "unable to parse rule: $line\n";
2800
2801     $rule->{type} = lc($1);
2802     $rule->{action} = $2;
2803
2804     if ($rule->{type} eq  'in' || $rule->{type} eq 'out') {
2805         if ($rule->{action} =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
2806             $rule->{macro} = $1;
2807             $rule->{action} = $2;
2808         }
2809     }
2810
2811     while (length($line)) {
2812         if ($line =~ s/^-i (\S+)\s*//) {
2813             $rule->{iface} = $1;
2814             next;
2815         }
2816
2817         last if $rule->{type} eq 'group';
2818
2819         if ($line =~ s/^(?:-p|--?proto) (\S+)\s*//) {
2820             $rule->{proto} = $1;
2821             next;
2822         }
2823
2824         if ($line =~ s/^--?dport (\S+)\s*//) {
2825             $rule->{dport} = $1;
2826             next;
2827         }
2828
2829         if ($line =~ s/^--?sport (\S+)\s*//) {
2830             $rule->{sport} = $1;
2831             next;
2832         }
2833         if ($line =~ s/^--?source (\S+)\s*//) {
2834             $rule->{source} = $1;
2835             next;
2836         }
2837         if ($line =~ s/^--?dest (\S+)\s*//) {
2838             $rule->{dest} = $1;
2839             next;
2840         }
2841         if ($line =~ s/^--?log (emerg|alert|crit|err|warning|notice|info|debug|nolog)\s*//) {
2842             $rule->{log} = $1;
2843             next;
2844         }
2845         if ($line =~ s/^--?icmp-type (\S+)\s*//) {
2846             $rule->{'icmp-type'} = $1;
2847             next;
2848         }
2849
2850         last;
2851     }
2852
2853     die "unable to parse rule parameters: $line\n" if length($line);
2854
2855     $rule = verify_rule($rule, $cluster_conf, $fw_conf, $rule_env, 1);
2856     if ($rule->{errors}) {
2857         # The verbose flag really means we're running from the CLI and want
2858         # output on the console - in the other case we really want such errors
2859         # to go into the syslog instead.
2860         my $log = $verbose ? sub { warn @_ } : sub { syslog(err => @_) };
2861         $log->("$prefix - errors in rule parameters: $orig_line\n");
2862         foreach my $p (keys %{$rule->{errors}}) {
2863             $log->("  $p: $rule->{errors}->{$p}\n");
2864         }
2865     }
2866
2867     return $rule;
2868 }
2869
2870 sub verify_ethertype {
2871     my ($value) = @_;
2872     my $types = get_etc_ethertypes();
2873     die "unknown ethernet protocol type: $value\n"
2874         if !defined($types->{byname}->{$value}) &&
2875            !defined($types->{byid}->{$value});
2876 }
2877
2878 sub parse_vmfw_option {
2879     my ($line) = @_;
2880
2881     my ($opt, $value);
2882
2883     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2884
2885     if ($line =~ m/^(enable|dhcp|ndp|radv|macfilter|ipfilter|ips):\s*(0|1)\s*$/i) {
2886         $opt = lc($1);
2887         $value = int($2);
2888     } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
2889         $opt = lc($1);
2890         $value = $2 ? lc($3) : '';
2891     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2892         $opt = lc($1);
2893         $value = uc($3);
2894     } elsif ($line =~ m/^(ips_queues):\s*((\d+)(:(\d+))?)\s*$/i) {
2895         $opt = lc($1);
2896         $value = $2;
2897     } elsif ($line =~ m/^(layer2_protocols):\s*(((\S+)[,]?)+)\s*$/i) {
2898         $opt = lc($1);
2899         $value = $2;
2900         verify_ethertype($_) foreach split(/\s*,\s*/, $value);
2901     } else {
2902         die "can't parse option '$line'\n"
2903     }
2904
2905     return ($opt, $value);
2906 }
2907
2908 sub parse_hostfw_option {
2909     my ($line) = @_;
2910
2911     my ($opt, $value);
2912
2913     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2914
2915     if ($line =~ m/^(enable|nosmurfs|tcpflags|ndp|log_nf_conntrack|nf_conntrack_allow_invalid|protection_synflood):\s*(0|1)\s*$/i) {
2916         $opt = lc($1);
2917         $value = int($2);
2918     } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
2919         $opt = lc($1);
2920         $value = $2 ? lc($3) : '';
2921     } elsif ($line =~ m/^(nf_conntrack_helpers):\s*(((\S+)[,]?)+)\s*$/i) {
2922         $opt = lc($1);
2923         $value = lc($2);
2924         pve_fw_verify_conntrack_helper($value);
2925     } elsif ($line =~ m/^(nf_conntrack_max|nf_conntrack_tcp_timeout_established|nf_conntrack_tcp_timeout_syn_recv|protection_synflood_rate|protection_synflood_burst|protection_limit):\s*(\d+)\s*$/i) {
2926         $opt = lc($1);
2927         $value = int($2);
2928     } else {
2929         die "can't parse option '$line'\n"
2930     }
2931
2932     return ($opt, $value);
2933 }
2934
2935 sub parse_clusterfw_option {
2936     my ($line) = @_;
2937
2938     my ($opt, $value);
2939
2940     if ($line =~ m/^(enable):\s*(\d+)\s*$/i) {
2941         $opt = lc($1);
2942         $value = int($2);
2943         if (($value > 1) && ((time() - $value) > 60)) {
2944             $value = 0
2945         }
2946     } elsif ($line =~ m/^(ebtables):\s*(0|1)\s*$/i) {
2947         $opt = lc($1);
2948         $value = int($2);
2949     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2950         $opt = lc($1);
2951         $value = uc($3);
2952     } elsif ($line =~ m/^(log_ratelimit):\s*(\S+)\s*$/) {
2953         $opt = lc($1);
2954         $value = $2;
2955     } else {
2956         die "can't parse option '$line'\n"
2957     }
2958
2959     return ($opt, $value);
2960 }
2961
2962 sub resolve_alias {
2963     my ($clusterfw_conf, $fw_conf, $cidr) = @_;
2964
2965     my $alias = lc($cidr);
2966     my $e = $fw_conf ? $fw_conf->{aliases}->{$alias} : undef;
2967     $e = $clusterfw_conf->{aliases}->{$alias} if !$e && $clusterfw_conf;
2968
2969     die "no such alias '$cidr'\n" if !$e;;
2970
2971     return wantarray ? ($e->{cidr}, $e->{ipversion}) : $e->{cidr};
2972 }
2973
2974 sub parse_ip_or_cidr {
2975     my ($cidr) = @_;
2976
2977     my $ipversion;
2978
2979     if ($cidr =~ m!^(?:$IPV6RE)(/(\d+))?$!) {
2980         $cidr =~ s|/128$||;
2981         $ipversion = 6;
2982     } elsif ($cidr =~ m!^(?:$IPV4RE)(/(\d+))?$!) {
2983         $cidr =~ s|/32$||;
2984         $ipversion = 4;
2985     } else {
2986         die "value does not look like a valid IP address or CIDR network\n";
2987     }
2988
2989     return wantarray ? ($cidr, $ipversion) : $cidr;
2990 }
2991
2992 sub parse_alias {
2993     my ($line) = @_;
2994
2995     # we can add single line comments to the end of the line
2996     my $comment = $line =~ s/\s*#\s*(.*?)\s*$// ? decode('utf8', $1) : undef;
2997
2998     if ($line =~ m/^(\S+)\s(\S+)$/) {
2999         my ($name, $cidr) = ($1, $2);
3000         my $ipversion;
3001
3002         ($cidr, $ipversion) = parse_ip_or_cidr($cidr);
3003
3004         my $data = {
3005             name => $name,
3006             cidr => $cidr,
3007             ipversion => $ipversion,
3008         };
3009         $data->{comment} = $comment  if $comment;
3010         return $data;
3011     }
3012
3013     return undef;
3014 }
3015
3016 sub generic_fw_config_parser {
3017     my ($filename, $cluster_conf, $empty_conf, $rule_env) = @_;
3018
3019     my $section;
3020     my $group;
3021
3022     my $res = $empty_conf;
3023
3024     my $raw;
3025     if ($filename =~ m!^/etc/pve/(.*)$!) {
3026         $raw = PVE::Cluster::get_config($1);
3027     } else {
3028         $raw = eval { PVE::Tools::file_get_contents($filename) }; # ignore errors
3029     }
3030     return {} if !$raw;
3031
3032     my $curr_group_keys = {};
3033
3034     my $linenr = 0;
3035     while ($raw =~ /^\h*(.*?)\h*$/gm) {
3036         my $line = $1;
3037         $linenr++;
3038         next if $line =~ m/^#/;
3039         next if $line =~ m/^\s*$/;
3040         chomp $line;
3041
3042         my $prefix = "$filename (line $linenr)";
3043
3044         if ($empty_conf->{options} && ($line =~ m/^\[options\]$/i)) {
3045             $section = 'options';
3046             next;
3047         }
3048
3049         if ($empty_conf->{aliases} && ($line =~ m/^\[aliases\]$/i)) {
3050             $section = 'aliases';
3051             next;
3052         }
3053
3054         if ($empty_conf->{groups} && ($line =~ m/^\[group\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
3055             $section = 'groups';
3056             $group = lc($1);
3057             my $comment = $2;
3058             eval {
3059                 die "security group name too long\n" if length($group) > $max_group_name_length;
3060                 die "invalid security group name '$group'\n" if $group !~ m/^${security_group_name_pattern}$/;
3061             };
3062             if (my $err = $@) {
3063                 ($section, $group, $comment) = undef;
3064                 warn "$prefix: $err";
3065                 next;
3066             }
3067
3068             $res->{$section}->{$group} = [];
3069             $res->{group_comments}->{$group} =  decode('utf8', $comment)
3070                 if $comment;
3071             next;
3072         }
3073
3074         if ($empty_conf->{rules} && ($line =~ m/^\[rules\]$/i)) {
3075             $section = 'rules';
3076             next;
3077         }
3078
3079         if ($empty_conf->{ipset} && ($line =~ m/^\[ipset\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
3080             $section = 'ipset';
3081             $group = lc($1);
3082             my $comment = $2;
3083             eval {
3084                 die "ipset name too long\n" if length($group) > $max_ipset_name_length;
3085                 die "invalid ipset name '$group'\n" if $group !~ m/^${ipset_name_pattern}$/;
3086             };
3087             if (my $err = $@) {
3088                 ($section, $group, $comment) = undef;
3089                 warn "$prefix: $err";
3090                 next;
3091             }
3092
3093             $res->{$section}->{$group} = [];
3094             $curr_group_keys = {};
3095
3096             $res->{ipset_comments}->{$group} = decode('utf8', $comment)
3097                 if $comment;
3098             next;
3099         }
3100
3101         if (!$section) {
3102             warn "$prefix: skip line - no section\n";
3103             next;
3104         }
3105
3106         if ($section eq 'options') {
3107             eval {
3108                 my ($opt, $value);
3109                 if ($rule_env eq 'cluster') {
3110                     ($opt, $value) = parse_clusterfw_option($line);
3111                 } elsif ($rule_env eq 'host') {
3112                     ($opt, $value) = parse_hostfw_option($line);
3113                 } else {
3114                     ($opt, $value) = parse_vmfw_option($line);
3115                 }
3116                 $res->{options}->{$opt} = $value;
3117             };
3118             warn "$prefix: $@" if $@;
3119         } elsif ($section eq 'aliases') {
3120             eval {
3121                 my $data = parse_alias($line);
3122                 $res->{aliases}->{lc($data->{name})} = $data;
3123             };
3124             warn "$prefix: $@" if $@;
3125         } elsif ($section eq 'rules') {
3126             my $rule;
3127             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, $res, $rule_env); };
3128             if (my $err = $@) {
3129                 warn "$prefix: $err";
3130                 next;
3131             }
3132             push @{$res->{$section}}, $rule;
3133         } elsif ($section eq 'groups') {
3134             my $rule;
3135             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, undef, 'group'); };
3136             if (my $err = $@) {
3137                 warn "$prefix: $err";
3138                 next;
3139             }
3140             push @{$res->{$section}->{$group}}, $rule;
3141         } elsif ($section eq 'ipset') {
3142             # we can add single line comments to the end of the rule
3143             my $comment = $line =~ s/#\s*(.*?)\s*$// ? decode('utf8', $1) : undef;
3144
3145             $line =~ m/^(\!)?\s*(\S+)\s*$/;
3146             my $nomatch = $1;
3147             my $cidr = $2;
3148             my $errors;
3149
3150             if ($nomatch && !$feature_ipset_nomatch) {
3151                 $errors->{nomatch} = "nomatch not supported by kernel";
3152             }
3153
3154             eval {
3155                 if ($cidr =~ m/^${ip_alias_pattern}$/) {
3156                     resolve_alias($cluster_conf, $res, $cidr); # make sure alias exists
3157                 } else {
3158                     $cidr = parse_ip_or_cidr($cidr);
3159                 }
3160                 die "duplicate ipset entry for '$cidr'\n"
3161                     if defined($curr_group_keys->{$cidr});
3162             };
3163             if (my $err = $@) {
3164                 chomp $err;
3165                 $errors->{cidr} = $err;
3166             }
3167
3168             if ($cidr =~ m!/0+$!) {
3169                 $errors->{cidr} = "a zero prefix is not allowed in ipset entries\n";
3170             }
3171
3172             my $entry = { cidr => $cidr };
3173             $entry->{nomatch} = 1 if $nomatch;
3174             $entry->{comment} = $comment if $comment;
3175             $entry->{errors} =  $errors if $errors;
3176
3177             if ($verbose && $errors) {
3178                 warn "$prefix - errors in ipset '$group': $line\n";
3179                 foreach my $p (keys %{$errors}) {
3180                     warn "  $p: $errors->{$p}\n";
3181                 }
3182             }
3183
3184             push @{$res->{$section}->{$group}}, $entry;
3185             $curr_group_keys->{$cidr} = 1;
3186         } else {
3187             warn "$prefix: skip line - unknown section\n";
3188             next;
3189         }
3190     }
3191
3192     return $res;
3193 }
3194
3195 # this is only used to prevent concurrent runs of rule compilation/application
3196 # see lock_*_conf for cfs locks protectiong config modification
3197 sub run_locked {
3198     my ($code, @param) = @_;
3199
3200     my $timeout = 10;
3201
3202     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
3203
3204     die $@ if $@;
3205
3206     return $res;
3207 }
3208
3209 sub read_local_vm_config {
3210
3211     my $qemu = {};
3212     my $lxc = {};
3213
3214     my $vmdata = { qemu => $qemu, lxc => $lxc };
3215
3216     my $vmlist = PVE::Cluster::get_vmlist();
3217     return $vmdata if !$vmlist || !$vmlist->{ids};
3218     my $ids = $vmlist->{ids};
3219
3220     foreach my $vmid (keys %$ids) {
3221         next if !$vmid; # skip VE0
3222         my $d = $ids->{$vmid};
3223         next if !$d->{node} || $d->{node} ne $nodename;
3224         next if !$d->{type};
3225         if ($d->{type} eq 'qemu') {
3226             if ($have_qemu_server) {
3227                 my $cfspath = PVE::QemuConfig->cfs_config_path($vmid);
3228                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
3229                     $qemu->{$vmid} = $conf;
3230                 }
3231             }
3232         } elsif ($d->{type} eq 'lxc') {
3233             if ($have_lxc) {
3234                 my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
3235                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
3236                     $lxc->{$vmid} = $conf;
3237                 }
3238             }
3239         }
3240     }
3241
3242     return $vmdata;
3243 };
3244
3245 # FIXME: move use sites over to moved helper and break older packages, then remove this here
3246 sub lock_vmfw_conf {
3247     return PVE::Firewall::Helpers::lock_vmfw_conf(@_);
3248 }
3249
3250 sub load_vmfw_conf {
3251     my ($cluster_conf, $rule_env, $vmid, $dir) = @_;
3252
3253     $dir = $pvefw_conf_dir if !defined($dir);
3254     my $filename = "$dir/$vmid.fw";
3255
3256     my $empty_conf = {
3257         rules => [],
3258         options => {},
3259         aliases => {},
3260         ipset => {} ,
3261         ipset_comments => {},
3262     };
3263
3264     my $vmfw_conf = generic_fw_config_parser($filename, $cluster_conf, $empty_conf, $rule_env);
3265     $vmfw_conf->{vmid} = $vmid;
3266
3267     return $vmfw_conf;
3268 }
3269
3270 my $format_rules = sub {
3271     my ($rules, $allow_iface) = @_;
3272
3273     my $raw = '';
3274
3275     foreach my $rule (@$rules) {
3276         if ($rule->{type} eq  'in' || $rule->{type} eq 'out' || $rule->{type} eq 'group') {
3277             $raw .= '|' if defined($rule->{enable}) && !$rule->{enable};
3278             $raw .= uc($rule->{type});
3279             if ($rule->{macro}) {
3280                 $raw .= " $rule->{macro}($rule->{action})";
3281             } else {
3282                 $raw .= " " . $rule->{action};
3283             }
3284             if ($allow_iface && $rule->{iface}) {
3285                 $raw .= " -i $rule->{iface}";
3286             }
3287
3288             if ($rule->{type} ne  'group')  {
3289                 $raw .= " -source $rule->{source}" if $rule->{source};
3290                 $raw .= " -dest $rule->{dest}" if $rule->{dest};
3291                 $raw .= " -p $rule->{proto}" if $rule->{proto};
3292                 $raw .= " -dport $rule->{dport}" if $rule->{dport};
3293                 $raw .= " -sport $rule->{sport}" if $rule->{sport};
3294                 $raw .= " -log $rule->{log}" if $rule->{log};
3295                 $raw .= " -icmp-type $rule->{'icmp-type'}" if defined($rule->{'icmp-type'}) && $rule->{'icmp-type'} ne '';
3296             }
3297
3298             $raw .= " # " . encode('utf8', $rule->{comment})
3299                 if $rule->{comment} && $rule->{comment} !~ m/^\s*$/;
3300             $raw .= "\n";
3301         } else {
3302             die "unknown rule type '$rule->{type}'";
3303         }
3304     }
3305
3306     return $raw;
3307 };
3308
3309 my $format_options = sub {
3310     my ($options) = @_;
3311
3312     my $raw = '';
3313
3314     $raw .= "[OPTIONS]\n\n";
3315     foreach my $opt (keys %$options) {
3316         $raw .= "$opt: $options->{$opt}\n";
3317     }
3318     $raw .= "\n";
3319
3320     return $raw;
3321 };
3322
3323 my $format_aliases = sub {
3324     my ($aliases) = @_;
3325
3326     my $raw = '';
3327
3328     $raw .= "[ALIASES]\n\n";
3329     foreach my $k (keys %$aliases) {
3330         my $e = $aliases->{$k};
3331         $raw .= "$e->{name} $e->{cidr}";
3332         $raw .= " # " . encode('utf8', $e->{comment})
3333             if $e->{comment} && $e->{comment} !~ m/^\s*$/;
3334         $raw .= "\n";
3335     }
3336     $raw .= "\n";
3337
3338     return $raw;
3339 };
3340
3341 my $format_ipsets = sub {
3342     my ($fw_conf) = @_;
3343
3344     my $raw = '';
3345
3346     foreach my $ipset (sort keys %{$fw_conf->{ipset}}) {
3347         if (my $comment = $fw_conf->{ipset_comments}->{$ipset}) {
3348             my $utf8comment = encode('utf8', $comment);
3349             $raw .= "[IPSET $ipset] # $utf8comment\n\n";
3350         } else {
3351             $raw .= "[IPSET $ipset]\n\n";
3352         }
3353         my $options = $fw_conf->{ipset}->{$ipset};
3354
3355         my $nethash = {};
3356         foreach my $entry (@$options) {
3357             my $cidr = $entry->{cidr};
3358             if (defined($nethash->{$cidr})) {
3359                 warn "ignoring duplicate ipset entry '$cidr'\n";
3360                 next;
3361             }
3362
3363             $nethash->{$cidr} = $entry;
3364         }
3365
3366         foreach my $cidr (sort keys %$nethash) {
3367             my $entry = $nethash->{$cidr};
3368             my $line = $entry->{nomatch} ? '!' : '';
3369             $line .= $entry->{cidr};
3370             $line .= " # " . encode('utf8', $entry->{comment})
3371                 if $entry->{comment} && $entry->{comment} !~ m/^\s*$/;
3372             $raw .= "$line\n";
3373         }
3374
3375         $raw .= "\n";
3376     }
3377
3378     return $raw;
3379 };
3380
3381 sub save_vmfw_conf {
3382     my ($vmid, $vmfw_conf) = @_;
3383
3384     my $raw = '';
3385
3386     my $options = $vmfw_conf->{options};
3387     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3388
3389     my $aliases = $vmfw_conf->{aliases};
3390     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
3391
3392     $raw .= &$format_ipsets($vmfw_conf) if $vmfw_conf->{ipset};
3393
3394     my $rules = $vmfw_conf->{rules} || [];
3395     if ($rules && scalar(@$rules)) {
3396         $raw .= "[RULES]\n\n";
3397         $raw .= &$format_rules($rules, 1);
3398         $raw .= "\n";
3399     }
3400
3401     my $filename = "$pvefw_conf_dir/$vmid.fw";
3402     if ($raw) {
3403         mkdir $pvefw_conf_dir;
3404         PVE::Tools::file_set_contents($filename, $raw);
3405     } else {
3406         unlink $filename;
3407     }
3408 }
3409
3410 # FIXME: remove with 8.0 and break older qemu-server/pve-container
3411 sub remove_vmfw_conf {
3412     return PVE::Firewall::Helpers::remove_vmfw_conf(@_);
3413 }
3414
3415 # FIXME: remove with 8.0 and break older qemu-server/pve-container
3416 sub clone_vmfw_conf {
3417     return PVE::Firewall::Helpers::clone_vmfw_conf(@_);
3418 }
3419
3420 sub read_vm_firewall_configs {
3421     my ($cluster_conf, $vmdata, $dir) = @_;
3422
3423     my $vmfw_configs = {};
3424
3425     foreach my $vmid (keys %{$vmdata->{qemu}}) {
3426         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'vm', $vmid, $dir);
3427         next if !$vmfw_conf->{options}; # skip if file does not exist
3428         $vmfw_configs->{$vmid} = $vmfw_conf;
3429     }
3430     foreach my $vmid (keys %{$vmdata->{lxc}}) {
3431         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'ct', $vmid, $dir);
3432         next if !$vmfw_conf->{options}; # skip if file does not exist
3433         $vmfw_configs->{$vmid} = $vmfw_conf;
3434     }
3435
3436     return $vmfw_configs;
3437 }
3438
3439 sub get_option_log_level {
3440     my ($options, $k) = @_;
3441
3442     my $v = $options->{$k};
3443     $v = $default_log_level if !defined($v);
3444
3445     return undef if $v eq '' || $v eq 'nolog';
3446
3447     return $v if defined($log_level_hash->{$v});
3448
3449     warn "unknown log level ($k = '$v')\n";
3450
3451     return undef;
3452 }
3453
3454 sub generate_std_chains {
3455     my ($ruleset, $options, $ipversion) = @_;
3456
3457     my $std_chains = $pve_std_chains->{$ipversion} || die "internal error";
3458
3459     my $loglevel = get_option_log_level($options, 'smurf_log_level');
3460     my $chain = 'PVEFW-smurflog';
3461     if ( $std_chains->{$chain} ) {
3462         foreach my $r (@{$std_chains->{$chain}}) {
3463           $r->{log} = $loglevel;
3464         }
3465     }
3466
3467     # same as shorewall logflags action.
3468     $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
3469     $chain = 'PVEFW-logflags';
3470     if ( $std_chains->{$chain} ) {
3471         foreach my $r (@{$std_chains->{$chain}}) {
3472           $r->{log} = $loglevel;
3473         }
3474     }
3475
3476     foreach my $chain (keys %$std_chains) {
3477         ruleset_create_chain($ruleset, $chain);
3478         foreach my $rule (@{$std_chains->{$chain}}) {
3479             if (ref($rule)) {
3480                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, 0);
3481             } else {
3482                 die "rule $rule as string - should not happen";
3483             }
3484         }
3485     }
3486 }
3487
3488 sub generate_ipset_chains {
3489     my ($ipset_ruleset, $clusterfw_conf, $fw_conf, $device_ips, $ipsets) = @_;
3490
3491     foreach my $ipset (keys %{$ipsets}) {
3492
3493         my $options = $ipsets->{$ipset};
3494
3495         if ($device_ips && $ipset =~ /^ipfilter-(net\d+)$/) {
3496             if (my $ips = $device_ips->{$1}) {
3497                 $options = [@$options, @$ips];
3498             }
3499         }
3500
3501         # remove duplicates
3502         my $nethash = {};
3503         foreach my $entry (@$options) {
3504             next if $entry->{errors}; # skip entries with errors
3505             eval {
3506                 my ($cidr, $ver);
3507                 if ($entry->{cidr} =~ m/^${ip_alias_pattern}$/) {
3508                     ($cidr, $ver) = resolve_alias($clusterfw_conf, $fw_conf, $entry->{cidr});
3509                 } else {
3510                     ($cidr, $ver) = parse_ip_or_cidr($entry->{cidr});
3511                 }
3512                 #http://backreference.org/2013/03/01/ipv6-address-normalization/
3513                 if ($ver == 6) {
3514                     # ip_compress_address takes an address only, no CIDR
3515                     my ($addr, $prefix_len) = ($cidr =~ m@^([^/]*)(/.*)?$@);
3516                     $cidr = lc(Net::IP::ip_compress_address($addr, 6));
3517                     $cidr .= $prefix_len if defined($prefix_len);
3518                     $cidr =~ s|/128$||;
3519                 } else {
3520                     $cidr =~ s|/32$||;
3521                 }
3522
3523                 $nethash->{$ver}->{$cidr} = { cidr => $cidr, nomatch => $entry->{nomatch} };
3524             };
3525             warn $@ if $@;
3526         }
3527
3528         foreach my $ipversion (4, 6) {
3529             my $data = $nethash->{$ipversion};
3530
3531             my $name = compute_ipset_chain_name($fw_conf->{vmid}, $ipset, $ipversion);
3532
3533             my $hashsize = scalar(@$options);
3534             if ($hashsize <= 64) {
3535                 $hashsize = 64;
3536             } else {
3537                 $hashsize = round_powerof2($hashsize);
3538             }
3539
3540             my $bucketsize = 12; # lower than the default of 14, faster but slightly more memory use
3541
3542             my $family = $ipversion == "6" ? "inet6" : "inet";
3543
3544             $ipset_ruleset->{$name} = [
3545                 "create $name hash:net family $family hashsize $hashsize maxelem $hashsize bucketsize $bucketsize"
3546             ];
3547
3548             foreach my $cidr (sort keys %$data) {
3549                 my $entry = $data->{$cidr};
3550
3551                 my $cmd = "add $name $cidr";
3552                 if ($entry->{nomatch}) {
3553                     if ($feature_ipset_nomatch) {
3554                         push @{$ipset_ruleset->{$name}}, "$cmd nomatch";
3555                     } else {
3556                         warn "ignore !$cidr - nomatch not supported by kernel\n";
3557                     }
3558                 } else {
3559                     push @{$ipset_ruleset->{$name}}, $cmd;
3560                 }
3561             }
3562         }
3563     }
3564 }
3565
3566 sub round_powerof2 {
3567     my ($int) = @_;
3568
3569     $int--;
3570     $int |= $int >> $_ foreach (1,2,4,8,16);
3571     return ++$int;
3572 }
3573
3574 my $set_global_log_ratelimit = sub {
3575     my $cluster_opts = shift;
3576
3577     $global_log_ratelimit = '--limit 1/sec';
3578     if (defined(my $log_rlimit = $cluster_opts->{log_ratelimit})) {
3579         my $ll_format = $cluster_option_properties->{log_ratelimit}->{format};
3580         my $limit = PVE::JSONSchema::parse_property_string($ll_format, $log_rlimit);
3581
3582         if ($limit->{enable}) {
3583             if (my $rate = $limit->{rate}) {
3584                 $global_log_ratelimit = "--limit $rate";
3585             }
3586             if (my $burst = $limit->{burst}) {
3587                 $global_log_ratelimit .= " --limit-burst $burst";
3588             }
3589         } else {
3590             $global_log_ratelimit = undef;
3591         }
3592     }
3593 };
3594
3595 sub lock_clusterfw_conf {
3596     my ($timeout, $code, @param) = @_;
3597
3598     my $res = PVE::Cluster::cfs_lock_firewall("cluster", $timeout, $code, @param);
3599     die $@ if $@;
3600
3601     return $res;
3602 }
3603
3604 sub load_clusterfw_conf {
3605     my ($filename) = @_;
3606
3607     $filename = $clusterfw_conf_filename if !defined($filename);
3608     my $empty_conf = {
3609         rules => [],
3610         options => {},
3611         aliases => {},
3612         groups => {},
3613         group_comments => {},
3614         ipset => {} ,
3615         ipset_comments => {},
3616     };
3617
3618     my $cluster_conf = generic_fw_config_parser($filename, $empty_conf, $empty_conf, 'cluster');
3619     $set_global_log_ratelimit->($cluster_conf->{options});
3620
3621     return $cluster_conf;
3622 }
3623
3624 sub save_clusterfw_conf {
3625     my ($cluster_conf) = @_;
3626
3627     my $raw = '';
3628
3629     my $options = $cluster_conf->{options};
3630     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3631
3632     my $aliases = $cluster_conf->{aliases};
3633     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
3634
3635     $raw .= &$format_ipsets($cluster_conf) if $cluster_conf->{ipset};
3636
3637     my $rules = $cluster_conf->{rules};
3638     if ($rules && scalar(@$rules)) {
3639         $raw .= "[RULES]\n\n";
3640         $raw .= &$format_rules($rules, 1);
3641         $raw .= "\n";
3642     }
3643
3644     if ($cluster_conf->{groups}) {
3645         foreach my $group (sort keys %{$cluster_conf->{groups}}) {
3646             my $rules = $cluster_conf->{groups}->{$group};
3647             if (my $comment = $cluster_conf->{group_comments}->{$group}) {
3648                 my $utf8comment = encode('utf8', $comment);
3649                 $raw .= "[group $group] # $utf8comment\n\n";
3650             } else {
3651                 $raw .= "[group $group]\n\n";
3652             }
3653
3654             $raw .= &$format_rules($rules, 0);
3655             $raw .= "\n";
3656         }
3657     }
3658
3659     if ($raw) {
3660         mkdir $pvefw_conf_dir;
3661         PVE::Tools::file_set_contents($clusterfw_conf_filename, $raw);
3662     } else {
3663         unlink $clusterfw_conf_filename;
3664     }
3665 }
3666
3667 sub lock_hostfw_conf : prototype($$$@) {
3668     my ($node, $timeout, $code, @param) = @_;
3669
3670     $node = $nodename if !defined($node);
3671
3672     my $res = PVE::Cluster::cfs_lock_firewall("host-$node", $timeout, $code, @param);
3673     die $@ if $@;
3674
3675     return $res;
3676 }
3677
3678 sub load_hostfw_conf {
3679     my ($cluster_conf, $filename) = @_;
3680
3681     $filename = $hostfw_conf_filename if !defined($filename);
3682
3683     my $empty_conf = { rules => [], options => {}};
3684     return generic_fw_config_parser($filename, $cluster_conf, $empty_conf, 'host');
3685 }
3686
3687 sub save_hostfw_conf {
3688     my ($hostfw_conf, $filename) = @_;
3689
3690     $filename = $hostfw_conf_filename if !defined($filename);
3691
3692     my $raw = '';
3693
3694     my $options = $hostfw_conf->{options};
3695     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3696
3697     my $rules = $hostfw_conf->{rules};
3698     if ($rules && scalar(@$rules)) {
3699         $raw .= "[RULES]\n\n";
3700         $raw .= &$format_rules($rules, 1);
3701         $raw .= "\n";
3702     }
3703
3704     if ($raw) {
3705         PVE::Tools::file_set_contents($filename, $raw);
3706     } else {
3707         unlink $filename;
3708     }
3709 }
3710
3711 sub compile {
3712     my ($cluster_conf, $hostfw_conf, $vmdata, $corosync_conf) = @_;
3713
3714     my $vmfw_configs;
3715
3716     # fixme: once we read standard chains from config this needs to be put in test/standard cases below
3717     $pve_std_chains = dclone($pve_std_chains_conf);
3718
3719     if ($vmdata) { # test mode
3720         my $testdir = $vmdata->{testdir} || die "no test directory specified";
3721         my $filename = "$testdir/cluster.fw";
3722         $cluster_conf = load_clusterfw_conf($filename);
3723
3724         $filename = "$testdir/host.fw";
3725         $hostfw_conf = load_hostfw_conf($cluster_conf, $filename);
3726
3727         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, $testdir);
3728     } else { # normal operation
3729         $cluster_conf = load_clusterfw_conf(undef) if !$cluster_conf;
3730
3731         $hostfw_conf = load_hostfw_conf($cluster_conf, undef) if !$hostfw_conf;
3732
3733         # cfs_update is handled by daemon or API
3734         $corosync_conf = PVE::Cluster::cfs_read_file("corosync.conf")
3735             if !defined($corosync_conf) && PVE::Corosync::check_conf_exists(1);
3736
3737         $vmdata = read_local_vm_config();
3738         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, undef);
3739     }
3740
3741     return ({},{},{},{}) if !$cluster_conf->{options}->{enable};
3742
3743     my $localnet;
3744     if ($cluster_conf->{aliases}->{local_network}) {
3745         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
3746     } else {
3747         my $localnet_ver;
3748         ($localnet, $localnet_ver) = parse_ip_or_cidr(local_network() || '127.0.0.0/8');
3749
3750         $cluster_conf->{aliases}->{local_network} = {
3751             name => 'local_network', cidr => $localnet, ipversion => $localnet_ver };
3752     }
3753
3754     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
3755
3756     my $ruleset = {};
3757     my $rulesetv6 = {};
3758     $ruleset->{filter} = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 4);
3759     $ruleset->{raw} = compile_iptables_raw($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 4);
3760     $rulesetv6->{filter} = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 6);
3761     $rulesetv6->{raw} = compile_iptables_raw($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 6);
3762     my $ebtables_ruleset = compile_ebtables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata);
3763     my $ipset_ruleset = compile_ipsets($cluster_conf, $vmfw_configs, $vmdata);
3764
3765     return ($ruleset, $ipset_ruleset, $rulesetv6, $ebtables_ruleset);
3766 }
3767
3768 sub compile_iptables_raw {
3769     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, $ipversion) = @_;
3770
3771     my $ruleset = {};
3772
3773     my $hostfw_options = $hostfw_conf->{options} || {};
3774     my $protection_synflood = $hostfw_options->{protection_synflood} || 0;
3775     my $conntrack_helpers = $hostfw_options->{nf_conntrack_helpers} || '';
3776
3777     ruleset_create_chain($ruleset, "PVEFW-PREROUTING") if $protection_synflood != 0 || $conntrack_helpers ne '';
3778
3779     if($protection_synflood) {
3780
3781         my $protection_synflood_rate = $hostfw_options->{protection_synflood_rate} ? $hostfw_options->{protection_synflood_rate} : 200;
3782         my $protection_synflood_burst = $hostfw_options->{protection_synflood_burst} ? $hostfw_options->{protection_synflood_burst} : 1000;
3783         my $protection_synflood_limit = $hostfw_options->{protection_synflood_limit} ? $hostfw_options->{protection_synflood_limit} : 3000;
3784         my $protection_synflood_expire = $hostfw_options->{nf_conntrack_tcp_timeout_syn_recv} ? $hostfw_options->{nf_conntrack_tcp_timeout_syn_recv} : 60;
3785         $protection_synflood_expire = $protection_synflood_expire * 1000;
3786         my $protection_synflood_mask = $ipversion == 4 ? 32 : 64;
3787
3788         ruleset_addrule($ruleset, "PVEFW-PREROUTING", "-p tcp -m tcp --tcp-flags FIN,SYN,RST,ACK SYN -m hashlimit --hashlimit-above $protection_synflood_rate/sec --hashlimit-burst $protection_synflood_burst --hashlimit-mode srcip --hashlimit-name syn --hashlimit-htable-size 2097152 --hashlimit-srcmask $protection_synflood_mask --hashlimit-htable-expire $protection_synflood_expire", "-j DROP");
3789     }
3790
3791     foreach my $conntrack_helper (split(/,/, $conntrack_helpers)) {
3792         my $helper = $pve_fw_helpers->{$conntrack_helper};
3793         ruleset_addrule($ruleset, "PVEFW-PREROUTING", "-p $helper->{proto} -m $helper->{proto} --dport $helper->{dport} -j CT", "--helper $conntrack_helper") if $helper && $helper->{"v$ipversion"};
3794     }
3795
3796     return $ruleset;
3797 }
3798
3799 sub compile_iptables_filter {
3800     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, $ipversion) = @_;
3801
3802     my $ruleset = {};
3803
3804     ruleset_create_chain($ruleset, "PVEFW-INPUT");
3805     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
3806
3807     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
3808
3809     my $hostfw_options = $hostfw_conf->{options} || {};
3810
3811     # fixme: what log level should we use here?
3812     my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
3813
3814     my $conn_allow_invalid = $hostfw_options->{nf_conntrack_allow_invalid} // 0;
3815     ruleset_chain_add_conn_filters($ruleset, "PVEFW-FORWARD", $conn_allow_invalid, "ACCEPT");
3816
3817     ruleset_create_chain($ruleset, "PVEFW-FWBR-IN");
3818     ruleset_chain_add_input_filters($ruleset, "PVEFW-FWBR-IN", $ipversion, $hostfw_options, $cluster_conf, $loglevel);
3819
3820     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-in fwln+", "-j PVEFW-FWBR-IN");
3821
3822     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
3823     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-out fwln+", "-j PVEFW-FWBR-OUT");
3824
3825     generate_std_chains($ruleset, $hostfw_options, $ipversion);
3826
3827     my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
3828
3829     if ($hostfw_enable) {
3830         eval { enable_host_firewall($ruleset, $hostfw_conf, $cluster_conf, $ipversion, $corosync_conf); };
3831         warn $@ if $@; # just to be sure - should not happen
3832     }
3833
3834     # generate firewall rules for QEMU VMs
3835     foreach my $vmid (sort keys %{$vmdata->{qemu}}) {
3836         eval {
3837             my $conf = $vmdata->{qemu}->{$vmid};
3838             my $vmfw_conf = $vmfw_configs->{$vmid};
3839             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
3840
3841             foreach my $netid (sort keys %$conf) {
3842                 next if $netid !~ m/^net(\d+)$/;
3843                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3844                 next if !$net->{firewall};
3845
3846                 my $iface = "tap${vmid}i$1";
3847                 my $macaddr = $net->{macaddr};
3848                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3849                                              $vmfw_conf, $vmid, 'IN', $ipversion);
3850                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3851                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
3852             }
3853         };
3854         warn $@ if $@; # just to be sure - should not happen
3855     }
3856
3857     # generate firewall rules for LXC containers
3858     foreach my $vmid (sort keys %{$vmdata->{lxc}}) {
3859         eval {
3860             my $conf = $vmdata->{lxc}->{$vmid};
3861             my $vmfw_conf = $vmfw_configs->{$vmid};
3862             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
3863
3864             foreach my $netid (sort keys %$conf) {
3865                 next if $netid !~ m/^net(\d+)$/;
3866                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
3867                 next if !$net->{firewall};
3868
3869                 my $iface = "veth${vmid}i$1";
3870                 my $macaddr = $net->{hwaddr};
3871                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3872                                              $vmfw_conf, $vmid, 'IN', $ipversion);
3873                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3874                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
3875             }
3876         };
3877         warn $@ if $@; # just to be sure - should not happen
3878     }
3879
3880     if (ruleset_chain_exist($ruleset, "PVEFW-IPS")){
3881         ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED", "-j PVEFW-IPS");
3882     }
3883
3884     return $ruleset;
3885 }
3886
3887 sub mac_to_linklocal {
3888     my ($macaddr) = @_;
3889     my @parts = split(/:/, $macaddr);
3890     # The standard link local address uses the fe80::/64 prefix with the
3891     # modified EUI-64 identifier derived from the MAC address by flipping the
3892     # universal/local bit and inserting FF:FE in the middle.
3893     # See RFC 4291.
3894     $parts[0] = sprintf("%02x", hex($parts[0]) ^ 0x02);
3895     my @meui64 = (@parts[0,1,2], 'ff', 'fe', @parts[3,4,5]);
3896     return "fe80::$parts[0]$parts[1]:$parts[2]FF:FE$parts[3]:$parts[4]$parts[5]";
3897 }
3898
3899 sub compile_ipsets {
3900     my ($cluster_conf, $vmfw_configs, $vmdata) = @_;
3901
3902     my $localnet;
3903     if ($cluster_conf->{aliases}->{local_network}) {
3904         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
3905     } else {
3906         my $localnet_ver;
3907         ($localnet, $localnet_ver) = parse_ip_or_cidr(local_network() || '127.0.0.0/8');
3908
3909         $cluster_conf->{aliases}->{local_network} = {
3910             name => 'local_network', cidr => $localnet, ipversion => $localnet_ver };
3911     }
3912
3913     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
3914
3915
3916     my $ipset_ruleset = {};
3917
3918     # generate ipsets for QEMU VMs
3919     foreach my $vmid (keys %{$vmdata->{qemu}}) {
3920         eval {
3921             my $conf = $vmdata->{qemu}->{$vmid};
3922             my $vmfw_conf = $vmfw_configs->{$vmid};
3923             return if !$vmfw_conf;
3924
3925             # When the 'ipfilter' option is enabled every device for which there
3926             # is no 'ipfilter-netX' ipset defined gets an implicit empty default
3927             # ipset.
3928             # The reason is that ipfilter ipsets are always filled with standard
3929             # IPv6 link-local filters.
3930             my $ipsets = $vmfw_conf->{ipset};
3931             my $implicit_sets = {};
3932
3933             my $device_ips = {};
3934             foreach my $netid (keys %$conf) {
3935                 next if $netid !~ m/^net(\d+)$/;
3936                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3937                 next if !$net->{firewall};
3938
3939                 if ($vmfw_conf->{options}->{ipfilter} && !$ipsets->{"ipfilter-$netid"}) {
3940                     $implicit_sets->{"ipfilter-$netid"} = [];
3941                 }
3942
3943                 my $macaddr = $net->{macaddr};
3944                 my $linklocal = mac_to_linklocal($macaddr);
3945                 $device_ips->{$netid} = [
3946                     { cidr => $linklocal },
3947                     { cidr => 'fe80::/10', nomatch => 1 }
3948                 ];
3949             }
3950
3951             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $ipsets);
3952             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $implicit_sets);
3953         };
3954         warn $@ if $@; # just to be sure - should not happen
3955     }
3956
3957     # generate firewall rules for LXC containers
3958     foreach my $vmid (keys %{$vmdata->{lxc}}) {
3959         eval {
3960             my $conf = $vmdata->{lxc}->{$vmid};
3961             my $vmfw_conf = $vmfw_configs->{$vmid};
3962             return if !$vmfw_conf;
3963
3964             # When the 'ipfilter' option is enabled every device for which there
3965             # is no 'ipfilter-netX' ipset defined gets an implicit empty default
3966             # ipset.
3967             # The reason is that ipfilter ipsets are always filled with standard
3968             # IPv6 link-local filters, as well as the IP addresses configured
3969             # for the container.
3970             my $ipsets = $vmfw_conf->{ipset};
3971             my $implicit_sets = {};
3972
3973             my $device_ips = {};
3974             foreach my $netid (keys %$conf) {
3975                 next if $netid !~ m/^net(\d+)$/;
3976                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
3977                 next if !$net->{firewall};
3978
3979                 if ($vmfw_conf->{options}->{ipfilter} && !$ipsets->{"ipfilter-$netid"}) {
3980                     $implicit_sets->{"ipfilter-$netid"} = [];
3981                 }
3982
3983                 my $macaddr = $net->{hwaddr};
3984                 my $linklocal = mac_to_linklocal($macaddr);
3985                 my $set = $device_ips->{$netid} = [
3986                     { cidr => $linklocal },
3987                     { cidr => 'fe80::/10', nomatch => 1 }
3988                 ];
3989                 if (defined($net->{ip}) && $net->{ip} =~ m!^($IPV4RE)(?:/\d+)?$!) {
3990                     push @$set, { cidr => $1 };
3991                 }
3992                 if (defined($net->{ip6}) && $net->{ip6} =~ m!^($IPV6RE)(?:/\d+)?$!) {
3993                     push @$set, { cidr => $1 };
3994                 }
3995             }
3996
3997             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $ipsets);
3998             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $implicit_sets);
3999         };
4000         warn $@ if $@; # just to be sure - should not happen
4001     }
4002
4003     generate_ipset_chains($ipset_ruleset, undef, $cluster_conf, undef, $cluster_conf->{ipset});
4004
4005     return $ipset_ruleset;
4006 }
4007
4008 sub compile_ebtables_filter {
4009     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata) = @_;
4010
4011     if (!($cluster_conf->{options}->{ebtables} // 1)) {
4012         return {};
4013     }
4014
4015     my $ruleset = {};
4016
4017     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
4018
4019     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
4020     #for ipv4 and ipv6, check macaddress in iptables, so we use conntrack 'ESTABLISHED', to speedup rules
4021     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-p IPv4', '-j ACCEPT');
4022     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-p IPv6', '-j ACCEPT');
4023     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-o fwln+', '-j PVEFW-FWBR-OUT');
4024
4025     # generate firewall rules for QEMU VMs
4026     foreach my $vmid (sort keys %{$vmdata->{qemu}}) {
4027         eval {
4028             my $conf = $vmdata->{qemu}->{$vmid};
4029             my $vmfw_conf = $vmfw_configs->{$vmid};
4030             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
4031             my $ipsets = $vmfw_conf->{ipset};
4032
4033             foreach my $netid (sort keys %$conf) {
4034                 next if $netid !~ m/^net(\d+)$/;
4035                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
4036                 next if !$net->{firewall};
4037                 my $iface = "tap${vmid}i$1";
4038                 my $macaddr = $net->{macaddr};
4039                 my $arpfilter = [];
4040                 if (defined(my $ipset = $ipsets->{"ipfilter-$netid"})) {
4041                     foreach my $ipaddr (@$ipset) {
4042                         my($ip, $version) = parse_ip_or_cidr($ipaddr->{cidr});
4043                         next if !$ip || ($version && $version != 4);
4044                         push(@$arpfilter, $ip);
4045                     }
4046                 }
4047                 generate_tap_layer2filter($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter);
4048             }
4049         };
4050         warn $@ if $@; # just to be sure - should not happen
4051     }
4052
4053     # generate firewall rules for LXC containers
4054     foreach my $vmid (sort keys %{$vmdata->{lxc}}) {
4055         eval {
4056             my $conf = $vmdata->{lxc}->{$vmid};
4057
4058             my $vmfw_conf = $vmfw_configs->{$vmid};
4059             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
4060             my $ipsets = $vmfw_conf->{ipset};
4061
4062             foreach my $netid (sort keys %$conf) {
4063                 next if $netid !~ m/^net(\d+)$/;
4064                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
4065                 next if !$net->{firewall};
4066                 my $iface = "veth${vmid}i$1";
4067                 my $macaddr = $net->{hwaddr};
4068                 my $arpfilter = [];
4069                 if (defined(my $ipset = $ipsets->{"ipfilter-$netid"})) {
4070                     foreach my $ipaddr (@$ipset) {
4071                         my($ip, $version) = parse_ip_or_cidr($ipaddr->{cidr});
4072                         next if !$ip || ($version && $version != 4);
4073                         push(@$arpfilter, $ip);
4074                     }
4075                 }
4076                 if (defined(my $ip = $net->{ip}) && $vmfw_conf->{options}->{ipfilter}) {
4077                     # ebtables changes this to a .0/MASK network but we just
4078                     # want the address here, no network - see #2193
4079                     $ip =~ s|/(\d+)$||;
4080                     if ($ip ne 'dhcp') {
4081                         push @$arpfilter, $ip;
4082                     }
4083                 }
4084                 generate_tap_layer2filter($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter);
4085             }
4086         };
4087         warn $@ if $@; # just to be sure - should not happen
4088     }
4089
4090     return $ruleset;
4091 }
4092
4093 sub generate_tap_layer2filter {
4094     my ($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter) = @_;
4095     my $options = $vmfw_conf->{options};
4096
4097     my $tapchain = $iface."-OUT";
4098
4099     # ebtables remove zeros from mac pairs
4100     $macaddr =~ s/0([0-9a-f])/$1/ig;
4101     $macaddr = lc($macaddr);
4102
4103     ruleset_create_chain($ruleset, $tapchain);
4104
4105     if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
4106         ruleset_addrule($ruleset, $tapchain, "-s ! $macaddr", '-j DROP');
4107     }
4108
4109     if (@$arpfilter){
4110         my $arpchain = $tapchain."-ARP";
4111         ruleset_addrule($ruleset, $tapchain, "-p ARP", "-j $arpchain");
4112         ruleset_create_chain($ruleset, $arpchain);
4113
4114         foreach my $ip (@{$arpfilter}) {
4115             ruleset_addrule($ruleset, $arpchain, "-p ARP --arp-ip-src $ip", '-j RETURN');
4116         }
4117         ruleset_addrule($ruleset, $arpchain, '', '-j DROP');
4118     }
4119
4120     if (defined($options->{layer2_protocols})){
4121         my $protochain = $tapchain."-PROTO";
4122         ruleset_addrule($ruleset, $tapchain, '', "-j $protochain");
4123         ruleset_create_chain($ruleset, $protochain);
4124
4125         foreach my $proto (split(/,/, $options->{layer2_protocols})) {
4126             ruleset_addrule($ruleset, $protochain, "-p $proto", '-j RETURN');
4127         }
4128         ruleset_addrule($ruleset, $protochain, '', '-j DROP');
4129     }
4130
4131     ruleset_addrule($ruleset, $tapchain, '', '-j ACCEPT');
4132
4133     ruleset_addrule($ruleset, 'PVEFW-FWBR-OUT', "-i $iface", "-j $tapchain");
4134 }
4135
4136 # the parameter $change_only_regex changes two things if defined:
4137 # * all chains not matching it will be left intact
4138 # * both the $active_chains hash and the returned status_hash have different
4139 #   structure (they contain a key named 'rules').
4140 sub get_ruleset_status {
4141     my ($ruleset, $active_chains, $digest_fn, $change_only_regex) = @_;
4142
4143     my $statushash = {};
4144
4145     foreach my $chain (sort keys %$ruleset) {
4146         my $rules = $ruleset->{$chain};
4147         my $sig = &$digest_fn($rules);
4148         my $oldsig;
4149
4150         $statushash->{$chain}->{sig} = $sig;
4151         if (defined($change_only_regex)) {
4152             $oldsig = $active_chains->{$chain}->{sig};
4153             $statushash->{$chain}->{rules} = $rules;
4154         } else {
4155             $oldsig = $active_chains->{$chain};
4156         }
4157         if (!defined($oldsig)) {
4158             $statushash->{$chain}->{action} = 'create';
4159         } else {
4160             if ($oldsig eq $sig) {
4161                 $statushash->{$chain}->{action} = 'exists';
4162             } else {
4163                 $statushash->{$chain}->{action} = 'update';
4164             }
4165         }
4166         if ($verbose) {
4167             print "$statushash->{$chain}->{action} $chain ($sig)\n";
4168             foreach my $cmd (@{$rules}) {
4169                 print "\t$cmd\n";
4170             }
4171         }
4172     }
4173
4174     foreach my $chain (sort keys %$active_chains) {
4175         next if defined($ruleset->{$chain});
4176         my $action = 'delete';
4177         my $sig = $active_chains->{$chain};
4178         if (defined($change_only_regex)) {
4179             $action = 'ignore' if ($chain !~ m/$change_only_regex/);
4180             $statushash->{$chain}->{rules} = $active_chains->{$chain}->{rules};
4181             $statushash->{$chain}->{policy} = $active_chains->{$chain}->{policy};
4182             $sig = $sig->{sig};
4183         }
4184         $statushash->{$chain}->{action} = $action;
4185         $statushash->{$chain}->{sig} = $sig;
4186         print "$action $chain ($sig)\n" if $verbose;
4187     }
4188
4189     return $statushash;
4190 }
4191
4192 sub print_sig_rule {
4193     my ($chain, $sig) = @_;
4194
4195     # We just use this to store a SHA1 checksum used to detect changes
4196     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
4197 }
4198
4199 sub get_ruleset_cmdlist {
4200     my ($ruleset, $iptablescmd, $table) = @_;
4201
4202     $table = 'filter' if !$table;
4203
4204     my $cmdlist = "*$table\n"; # we pass this to iptables-restore;
4205
4206     my ($active_chains, $hooks) = iptables_get_chains($iptablescmd, $table);
4207     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest);
4208
4209     # create missing chains first
4210     foreach my $chain (sort keys %$ruleset) {
4211         my $stat = $statushash->{$chain};
4212         die "internal error" if !$stat;
4213         next if $stat->{action} ne 'create';
4214
4215         $cmdlist .= ":$chain - [0:0]\n";
4216     }
4217
4218     foreach my $h (qw(INPUT OUTPUT FORWARD PREROUTING)) {
4219         my $chain = "PVEFW-$h";
4220         if ($ruleset->{$chain} && !$hooks->{$h}) {
4221             $cmdlist .= "-A $h -j $chain\n";
4222         }
4223     }
4224
4225     foreach my $chain (sort keys %$ruleset) {
4226         my $stat = $statushash->{$chain};
4227         die "internal error" if !$stat;
4228
4229         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
4230             $cmdlist .= "-F $chain\n";
4231             foreach my $cmd (@{$ruleset->{$chain}}) {
4232                 $cmdlist .= "$cmd\n";
4233             }
4234             $cmdlist .= print_sig_rule($chain, $stat->{sig});
4235         } elsif ($stat->{action} eq 'delete') {
4236             die "internal error"; # this should not happen
4237         } elsif ($stat->{action} eq 'exists') {
4238             # do nothing
4239         } else {
4240             die "internal error - unknown status '$stat->{action}'";
4241         }
4242     }
4243
4244     foreach my $chain (keys %$statushash) {
4245         next if $statushash->{$chain}->{action} ne 'delete';
4246         $cmdlist .= "-F $chain\n";
4247     }
4248     foreach my $chain (keys %$statushash) {
4249         next if $statushash->{$chain}->{action} ne 'delete';
4250         next if $chain eq 'PVEFW-INPUT';
4251         next if $chain eq 'PVEFW-OUTPUT';
4252         next if $chain eq 'PVEFW-FORWARD';
4253         next if $chain eq 'PVEFW-PREROUTING';
4254         $cmdlist .= "-X $chain\n";
4255     }
4256
4257     my $changes = $cmdlist ne "*$table\n" ? 1 : 0;
4258
4259     $cmdlist .= "COMMIT\n";
4260
4261     return wantarray ? ($cmdlist, $changes) : $cmdlist;
4262 }
4263
4264 my $pve_ebtables_chainname_regex = qr/PVEFW-\S+|(?:tap|veth)\d+i\d+-(?:IN|OUT)/;
4265
4266 sub get_ebtables_cmdlist {
4267     my ($ruleset) = @_;
4268
4269     my $changes = 0;
4270     my $cmdlist = "*filter\n";
4271
4272     my $active_chains = ebtables_get_chains();
4273     my $statushash = get_ruleset_status($ruleset, $active_chains,
4274                                         \&iptables_chain_digest,
4275                                         $pve_ebtables_chainname_regex);
4276
4277     # create chains first and make sure PVE rules are evaluated if active
4278     my $append_pve_to_forward = '-A FORWARD -j PVEFW-FORWARD';
4279     my $pve_include = 0;
4280     foreach my $chain (sort keys %$statushash) {
4281         next if ($statushash->{$chain}->{action} eq 'delete');
4282         my $policy = $statushash->{$chain}->{policy} // 'ACCEPT';
4283         $cmdlist .= ":$chain $policy\n";
4284         $pve_include = 1 if ($chain eq 'PVEFW-FORWARD');
4285     }
4286
4287     foreach my $chain (sort keys %$statushash) {
4288         my $stat = $statushash->{$chain};
4289         $changes = 1 if ($stat->{action} !~ 'ignore|exists');
4290         next if ($stat->{action} eq 'delete');
4291
4292         foreach my $cmd (@{$statushash->{$chain}->{'rules'}}) {
4293             if ($chain eq 'FORWARD' && $cmd eq $append_pve_to_forward) {
4294                 next if ! $pve_include;
4295                 $pve_include = 0;
4296             }
4297             $cmdlist .= "$cmd\n";
4298         }
4299     }
4300     $cmdlist .= "$append_pve_to_forward\n" if $pve_include;
4301
4302     return wantarray ? ($cmdlist, $changes) : $cmdlist;
4303 }
4304
4305 sub get_ipset_cmdlist {
4306     my ($ruleset) = @_;
4307
4308     my $cmdlist = "";
4309
4310     my $delete_cmdlist = "";
4311
4312     my $active_chains = ipset_get_chains();
4313     my $statushash = get_ruleset_status($ruleset, $active_chains, \&ipset_chain_digest);
4314
4315     # remove stale _swap chains
4316     foreach my $chain (keys %$active_chains) {
4317         if ($chain =~ m/^PVEFW-\S+_swap$/) {
4318             $cmdlist .= "destroy $chain\n";
4319         }
4320     }
4321
4322     foreach my $chain (keys %$ruleset) {
4323         my $stat = $statushash->{$chain};
4324         die "internal error" if !$stat;
4325
4326         if ($stat->{action} eq 'create') {
4327             foreach my $cmd (@{$ruleset->{$chain}}) {
4328                 $cmdlist .= "$cmd\n";
4329             }
4330         }
4331     }
4332
4333     foreach my $chain (keys %$ruleset) {
4334         my $stat = $statushash->{$chain};
4335         die "internal error" if !$stat;
4336
4337         if ($stat->{action} eq 'update') {
4338             my $chain_swap = $chain."_swap";
4339
4340             foreach my $cmd (@{$ruleset->{$chain}}) {
4341                 $cmd =~ s/$chain/$chain_swap/;
4342                 $cmdlist .= "$cmd\n";
4343             }
4344             $cmdlist .= "swap $chain_swap $chain\n";
4345             $cmdlist .= "flush $chain_swap\n";
4346             $cmdlist .= "destroy $chain_swap\n";
4347         }
4348     }
4349
4350      # the remove unused chains
4351     foreach my $chain (keys %$statushash) {
4352         next if $statushash->{$chain}->{action} ne 'delete';
4353
4354         $delete_cmdlist .= "flush $chain\n";
4355         $delete_cmdlist .= "destroy $chain\n";
4356     }
4357
4358     my $changes = ($cmdlist || $delete_cmdlist) ? 1 : 0;
4359
4360     return ($cmdlist, $delete_cmdlist, $changes);
4361 }
4362
4363 sub apply_ruleset {
4364     my ($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6, $ebtables_ruleset) = @_;
4365
4366     enable_bridge_firewall();
4367
4368     my ($ipset_create_cmdlist, $ipset_delete_cmdlist, $ipset_changes) =
4369         get_ipset_cmdlist($ipset_ruleset);
4370
4371     my ($cmdlist, $changes) = get_ruleset_cmdlist($ruleset->{filter});
4372     my ($cmdlistv6, $changesv6) = get_ruleset_cmdlist($rulesetv6->{filter}, "ip6tables");
4373     my ($ebtables_cmdlist, $ebtables_changes) = get_ebtables_cmdlist($ebtables_ruleset);
4374     my ($cmdlist_raw, $changes_raw) = get_ruleset_cmdlist($ruleset->{raw}, undef, 'raw');
4375     my ($cmdlistv6_raw, $changesv6_raw) = get_ruleset_cmdlist($rulesetv6->{raw}, "ip6tables", 'raw');
4376
4377     if ($verbose) {
4378         if ($ipset_changes) {
4379             print "ipset changes:\n";
4380             print $ipset_create_cmdlist if $ipset_create_cmdlist;
4381             print $ipset_delete_cmdlist if $ipset_delete_cmdlist;
4382         }
4383
4384         if ($changes) {
4385             print "iptables changes:\n";
4386             print $cmdlist;
4387         }
4388
4389         if ($changesv6) {
4390             print "ip6tables changes:\n";
4391             print $cmdlistv6;
4392         }
4393
4394         if ($changes_raw) {
4395             print "iptables table raw changes:\n";
4396             print $cmdlist_raw;
4397         }
4398
4399         if ($changesv6_raw) {
4400             print "ip6tables table raw changes:\n";
4401             print $cmdlistv6_raw;
4402         }
4403
4404         if ($ebtables_changes) {
4405             print "ebtables changes:\n";
4406             print $ebtables_cmdlist;
4407         }
4408     }
4409
4410     my $tmpfile = "$pve_fw_status_dir/ipsetcmdlist1";
4411     PVE::Tools::file_set_contents($tmpfile, $ipset_create_cmdlist || '');
4412
4413     ipset_restore_cmdlist($ipset_create_cmdlist);
4414
4415     $tmpfile = "$pve_fw_status_dir/ip4cmdlist";
4416     PVE::Tools::file_set_contents($tmpfile, $cmdlist || '');
4417
4418     iptables_restore_cmdlist($cmdlist);
4419
4420     $tmpfile = "$pve_fw_status_dir/ip4cmdlistraw";
4421     PVE::Tools::file_set_contents($tmpfile, $cmdlist_raw || '');
4422
4423     iptables_restore_cmdlist($cmdlist_raw, 'raw');
4424
4425     $tmpfile = "$pve_fw_status_dir/ip6cmdlist";
4426     PVE::Tools::file_set_contents($tmpfile, $cmdlistv6 || '');
4427
4428     ip6tables_restore_cmdlist($cmdlistv6);
4429
4430     $tmpfile = "$pve_fw_status_dir/ip6cmdlistraw";
4431     PVE::Tools::file_set_contents($tmpfile, $cmdlistv6_raw || '');
4432
4433     ip6tables_restore_cmdlist($cmdlistv6_raw, 'raw');
4434
4435     $tmpfile = "$pve_fw_status_dir/ipsetcmdlist2";
4436     PVE::Tools::file_set_contents($tmpfile, $ipset_delete_cmdlist || '');
4437
4438     ipset_restore_cmdlist($ipset_delete_cmdlist) if $ipset_delete_cmdlist;
4439
4440     ebtables_restore_cmdlist($ebtables_cmdlist);
4441
4442     $tmpfile = "$pve_fw_status_dir/ebtablescmdlist";
4443     PVE::Tools::file_set_contents($tmpfile, $ebtables_cmdlist || '');
4444
4445     # test: re-read status and check if everything is up to date
4446     my $ruleset_filter = $ruleset->{filter};
4447     my $active_chains = iptables_get_chains();
4448     my $statushash = get_ruleset_status($ruleset_filter, $active_chains, \&iptables_chain_digest);
4449
4450     my $errors;
4451     foreach my $chain (sort keys %$ruleset_filter) {
4452         my $stat = $statushash->{$chain};
4453         if ($stat->{action} ne 'exists') {
4454             warn "unable to update chain '$chain'\n";
4455             $errors = 1;
4456         }
4457     }
4458
4459     my $rulesetv6_filter = $rulesetv6->{filter};
4460     my $active_chainsv6 = iptables_get_chains("ip6tables");
4461     my $statushashv6 = get_ruleset_status($rulesetv6_filter, $active_chainsv6, \&iptables_chain_digest);
4462
4463     foreach my $chain (sort keys %$rulesetv6_filter) {
4464         my $stat = $statushashv6->{$chain};
4465         if ($stat->{action} ne 'exists') {
4466             warn "unable to update chain '$chain'\n";
4467             $errors = 1;
4468         }
4469     }
4470
4471     my $ruleset_raw = $ruleset->{raw};
4472     my $active_chains_raw = iptables_get_chains(undef, 'raw');
4473     my $statushash_raw = get_ruleset_status($ruleset_raw, $active_chains_raw, \&iptables_chain_digest);
4474
4475     foreach my $chain (sort keys %$ruleset_raw) {
4476         my $stat = $statushash_raw->{$chain};
4477         if ($stat->{action} ne 'exists') {
4478             warn "unable to update chain '$chain'\n";
4479             $errors = 1;
4480         }
4481     }
4482
4483     my $rulesetv6_raw = $rulesetv6->{raw};
4484     my $active_chainsv6_raw = iptables_get_chains("ip6tables", 'raw');
4485     my $statushashv6_raw = get_ruleset_status($rulesetv6_raw, $active_chainsv6_raw, \&iptables_chain_digest);
4486
4487     foreach my $chain (sort keys %$rulesetv6_raw) {
4488         my $stat = $statushashv6_raw->{$chain};
4489         if ($stat->{action} ne 'exists') {
4490             warn "unable to update chain '$chain'\n";
4491             $errors = 1;
4492         }
4493     }
4494
4495     my $active_ebtables_chains = ebtables_get_chains();
4496     my $ebtables_statushash = get_ruleset_status($ebtables_ruleset,
4497                                 $active_ebtables_chains, \&iptables_chain_digest,
4498                                 $pve_ebtables_chainname_regex);
4499
4500     foreach my $chain (sort keys %$ebtables_ruleset) {
4501         my $stat = $ebtables_statushash->{$chain};
4502         if ($stat->{action} ne 'exists') {
4503             warn "ebtables : unable to update chain '$chain'\n";
4504             $errors = 1;
4505         }
4506     }
4507
4508     die "unable to apply firewall changes\n" if $errors;
4509
4510     update_nf_conntrack_max($hostfw_conf);
4511
4512     update_nf_conntrack_tcp_timeout_established($hostfw_conf);
4513
4514     update_nf_conntrack_tcp_timeout_syn_recv($hostfw_conf);
4515
4516     update_nf_conntrack_logging($hostfw_conf);
4517 }
4518
4519 sub update_nf_conntrack_max {
4520     my ($hostfw_conf) = @_;
4521
4522     my $max = 262144; # reasonable default (2^16 * 4), see nf_conntrack-sysctl docs
4523
4524     my $options = $hostfw_conf->{options} || {};
4525
4526     if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
4527         $max = $options->{nf_conntrack_max};
4528         $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
4529     }
4530
4531     my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
4532     my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
4533
4534     my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
4535
4536     if ($current != $max) {
4537         my $hashsize = int($max/4);
4538         PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
4539         PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
4540     }
4541 }
4542
4543 sub update_nf_conntrack_tcp_timeout_established {
4544     my ($hostfw_conf) = @_;
4545
4546     my $options = $hostfw_conf->{options} || {};
4547
4548     my $value = defined($options->{nf_conntrack_tcp_timeout_established}) ? $options->{nf_conntrack_tcp_timeout_established} : 432000;
4549
4550     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_established", $value);
4551 }
4552
4553 sub update_nf_conntrack_tcp_timeout_syn_recv {
4554     my ($hostfw_conf) = @_;
4555
4556     my $options = $hostfw_conf->{options} || {};
4557
4558     my $value = defined($options->{nf_conntrack_tcp_timeout_syn_recv}) ? $options->{nf_conntrack_tcp_timeout_syn_recev} : 60;
4559
4560     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_syn_recv", $value);
4561 }
4562
4563 my $log_nf_conntrack_enabled = undef;
4564 sub update_nf_conntrack_logging {
4565     my ($hostfw_conf) = @_;
4566
4567     my $options = $hostfw_conf->{options} || {};
4568     my $value = $options->{log_nf_conntrack} || 0;
4569     if (!defined($log_nf_conntrack_enabled)
4570         || $value != $log_nf_conntrack_enabled)
4571     {
4572         my $tmpfile = "$pve_fw_status_dir/log_nf_conntrack";
4573         PVE::Tools::file_set_contents($tmpfile, $value);
4574
4575         run_command([qw(systemctl try-reload-or-restart pvefw-logger.service)]);
4576         $log_nf_conntrack_enabled = $value;
4577     }
4578 }
4579
4580 sub remove_pvefw_chains {
4581
4582     PVE::Firewall::remove_pvefw_chains_iptables("iptables");
4583     PVE::Firewall::remove_pvefw_chains_iptables("ip6tables");
4584     PVE::Firewall::remove_pvefw_chains_iptables("iptables", "raw");
4585     PVE::Firewall::remove_pvefw_chains_iptables("ip6tables", "raw");
4586     PVE::Firewall::remove_pvefw_chains_ipset();
4587     PVE::Firewall::remove_pvefw_chains_ebtables();
4588
4589 }
4590
4591 sub remove_pvefw_chains_iptables {
4592     my ($iptablescmd, $table) = @_;
4593
4594     $table = 'filter' if !$table;
4595
4596     my ($chash, $hooks) = iptables_get_chains($iptablescmd, $table);
4597     my $cmdlist = "*$table\n";
4598
4599     foreach my $h (qw(INPUT OUTPUT FORWARD PREROUTING)) {
4600         if ($hooks->{$h}) {
4601             $cmdlist .= "-D $h -j PVEFW-$h\n";
4602         }
4603     }
4604
4605     foreach my $chain (keys %$chash) {
4606         $cmdlist .= "-F $chain\n";
4607     }
4608
4609     foreach my $chain (keys %$chash) {
4610         $cmdlist .= "-X $chain\n";
4611     }
4612     $cmdlist .= "COMMIT\n";
4613
4614     if($iptablescmd eq "ip6tables") {
4615         ip6tables_restore_cmdlist($cmdlist, $table);
4616     } else {
4617         iptables_restore_cmdlist($cmdlist, $table);
4618     }
4619 }
4620
4621 sub remove_pvefw_chains_ipset {
4622
4623     my $ipset_chains = ipset_get_chains();
4624
4625     my $cmdlist = "";
4626
4627     foreach my $chain (keys %$ipset_chains) {
4628         $cmdlist .= "flush $chain\n";
4629         $cmdlist .= "destroy $chain\n";
4630     }
4631
4632     ipset_restore_cmdlist($cmdlist) if $cmdlist;
4633 }
4634
4635 sub remove_pvefw_chains_ebtables {
4636     # apply empty ruleset = remove all our chains
4637     ebtables_restore_cmdlist(get_ebtables_cmdlist({}));
4638 }
4639
4640 sub init {
4641     my $cluster_conf = load_clusterfw_conf();
4642     my $cluster_options = $cluster_conf->{options};
4643     my $enable = $cluster_options->{enable};
4644
4645     return if !$enable;
4646
4647     # load required modules here
4648 }
4649
4650 sub update {
4651     my $code = sub {
4652
4653         my $cluster_conf = load_clusterfw_conf();
4654         my $cluster_options = $cluster_conf->{options};
4655
4656         if (!$cluster_options->{enable}) {
4657             PVE::Firewall::remove_pvefw_chains();
4658             return;
4659         }
4660
4661         my $hostfw_conf = load_hostfw_conf($cluster_conf);
4662
4663         my ($ruleset, $ipset_ruleset, $rulesetv6, $ebtables_ruleset) = compile($cluster_conf, $hostfw_conf);
4664
4665         apply_ruleset($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6, $ebtables_ruleset);
4666     };
4667
4668     run_locked($code);
4669 }
4670
4671 1;