src/PVE/Firewall.pm

   1 package PVE::Firewall;
   2
   3 use warnings;
   4 use strict;
   5
   6 use Digest::SHA;
   7 use Encode;
   8 use File::Basename;
   9 use File::Path;
  10 use IO::File;
  11 use Net::IP;
  12 use POSIX;
  13 use Socket qw(AF_INET AF_INET6 inet_ntop inet_pton);
  14 use Storable qw(dclone);
  15
  16 use PVE::Cluster;
  17 use PVE::Corosync;
  18 use PVE::Exception qw(raise raise_param_exc);
  19 use PVE::INotify;
  20 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  21 use PVE::Network;
  22 use PVE::ProcFSTools;
  23 use PVE::SafeSyslog;
  24 use PVE::Tools qw($IPV4RE $IPV6RE);
  25 use PVE::Tools qw(run_command lock_file dir_glob_foreach);
  26
  27 use PVE::Firewall::Helpers;
  28
  29 my $pvefw_conf_dir = "/etc/pve/firewall";
  30 my $clusterfw_conf_filename = "$pvefw_conf_dir/cluster.fw";
  31
  32 # dynamically include PVE::QemuServer and PVE::LXC
  33 # to avoid dependency problems
  34 my $have_qemu_server;
  35 eval {
  36     require PVE::QemuServer;
  37     require PVE::QemuConfig;
  38     $have_qemu_server = 1;
  39 };
  40
  41 my $have_lxc;
  42 eval {
  43     require PVE::LXC;
  44     $have_lxc = 1;
  45 };
  46
  47 my $pve_fw_status_dir = "/var/lib/pve-firewall";
  48
  49 mkdir $pve_fw_status_dir; # make sure this exists
  50
  51 my $security_group_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  52 my $ipset_name_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  53 our $ip_alias_pattern = '[A-Za-z][A-Za-z0-9\-\_]+';
  54
  55 my $max_alias_name_length = 64;
  56 my $max_ipset_name_length = 64;
  57 my $max_group_name_length = 18;
  58
  59 my $PROTOCOLS_WITH_PORTS = {
  60     udp => 1,     17 => 1,
  61     udplite => 1, 136 => 1,
  62     tcp => 1,     6 => 1,
  63     dccp => 1,    33 => 1,
  64     sctp => 1,    132 => 1,
  65 };
  66
  67 PVE::JSONSchema::register_format('IPorCIDR', \&pve_verify_ip_or_cidr);
  68 sub pve_verify_ip_or_cidr {
  69     my ($cidr, $noerr) = @_;
  70
  71     if ($cidr =~ m!^(?:$IPV6RE|$IPV4RE)(?:/\d+)?$!) {
  72         # Net::IP throws an error if the masked CIDR part isn't zero, e.g., `192.168.1.155/24`
  73         # fails but `192.168.1.0/24` succeeds. clean_cidr removes the non zero bits from the CIDR.
  74         my $clean_cidr = clean_cidr($cidr);
  75         return $cidr if Net::IP->new($clean_cidr);
  76         return undef if $noerr;
  77
  78         die Net::IP::Error() . "\n";
  79     }
  80     return undef if $noerr;
  81     die "value does not look like a valid IP address or CIDR network\n";
  82 }
  83
  84 PVE::JSONSchema::register_format('IPorCIDRorAlias', \&pve_verify_ip_or_cidr_or_alias);
  85 sub pve_verify_ip_or_cidr_or_alias {
  86     my ($cidr, $noerr) = @_;
  87
  88     return if $cidr =~ m@^(dc/|guest/)?(?:$ip_alias_pattern)$@;
  89
  90     return pve_verify_ip_or_cidr($cidr, $noerr);
  91 }
  92
  93 sub clean_cidr {
  94     my ($cidr) = @_;
  95     my ($ip, $len) = split('/', $cidr);
  96     return $cidr if !$len;
  97     my $ver = ($ip =~ m!^$IPV4RE$!) ? 4 : 6;
  98
  99     my $bin_ip = Net::IP::ip_iptobin( Net::IP::ip_expand_address($ip, $ver), $ver);
 100     my $bin_mask = Net::IP::ip_get_mask($len, $ver);
 101     my $clean_ip = Net::IP::ip_compress_address( Net::IP::ip_bintoip($bin_ip & $bin_mask, $ver), $ver);
 102
 103     return "${clean_ip}/$len";
 104 }
 105
 106 PVE::JSONSchema::register_standard_option('ipset-name', {
 107     description => "IP set name.",
 108     type => 'string',
 109     pattern => $ipset_name_pattern,
 110     minLength => 2,
 111     maxLength => $max_ipset_name_length,
 112 });
 113
 114 PVE::JSONSchema::register_standard_option('pve-fw-alias', {
 115     description => "Alias name.",
 116     type => 'string',
 117     pattern => $ip_alias_pattern,
 118     minLength => 2,
 119     maxLength => $max_alias_name_length,
 120 });
 121
 122 PVE::JSONSchema::register_standard_option('pve-fw-loglevel' => {
 123     description => "Log level.",
 124     type => 'string',
 125     enum => ['emerg', 'alert', 'crit', 'err', 'warning', 'notice', 'info', 'debug', 'nolog'],
 126     optional => 1,
 127 });
 128
 129 PVE::JSONSchema::register_standard_option('pve-security-group-name', {
 130     description => "Security Group name.",
 131     type => 'string',
 132     pattern => $security_group_name_pattern,
 133     minLength => 2,
 134     maxLength => $max_group_name_length,
 135 });
 136
 137 my $feature_ipset_nomatch = 0;
 138 eval  {
 139     my (undef, undef, $release) = POSIX::uname();
 140     if ($release =~ m/^(\d+)\.(\d+)\.\d+-/) {
 141         my ($major, $minor) = ($1, $2);
 142         $feature_ipset_nomatch = 1 if ($major > 3) ||
 143             ($major == 3 && $minor >= 7);
 144     }
 145
 146 };
 147
 148 my $nodename = PVE::INotify::nodename();
 149 my $hostfw_conf_filename = "/etc/pve/nodes/$nodename/host.fw";
 150
 151 my $pve_fw_lock_filename = "/var/lock/pvefw.lck";
 152
 153 my $default_log_level = 'nolog'; # avoid logs by default
 154 my $global_log_ratelimit = '--limit 1/sec';
 155
 156 my $log_level_hash = {
 157     debug => 7,
 158     info => 6,
 159     notice => 5,
 160     warning => 4,
 161     err => 3,
 162     crit => 2,
 163     alert => 1,
 164     emerg => 0,
 165 };
 166
 167 my $verbose = 0;
 168 sub set_verbose {
 169     $verbose = shift;
 170 }
 171
 172 # %rule
 173 #
 174 # name => optional
 175 # enable => [0|1]
 176 # action =>
 177 # proto =>
 178 # sport => port[,port[,port]].. or port:port
 179 # dport => port[,port[,port]].. or port:port
 180 # log => optional, loglevel
 181 # logmsg => optional, logmsg - overwrites default
 182 # iface_in => incomin interface
 183 # iface_out => outgoing interface
 184 # match => optional, overwrites generation of match
 185 # target => optional, overwrites action
 186
 187 # we need to overwrite some macros for ipv6
 188 my $pve_ipv6fw_macros = {
 189     'Ping' => [
 190         { action => 'PARAM', proto => 'icmpv6', dport => 'echo-request' },
 191     ],
 192     'NeighborDiscovery' => [
 193         "IPv6 neighbor solicitation, neighbor and router advertisement",
 194         { action => 'PARAM', proto => 'icmpv6', dport => 'router-solicitation' },
 195         { action => 'PARAM', proto => 'icmpv6', dport => 'router-advertisement' },
 196         { action => 'PARAM', proto => 'icmpv6', dport => 'neighbor-solicitation' },
 197         { action => 'PARAM', proto => 'icmpv6', dport => 'neighbor-advertisement' },
 198     ],
 199     'DHCPv6' => [
 200         "DHCPv6 traffic",
 201         { action => 'PARAM', proto => 'udp', dport => '546:547', sport => '546:547' },
 202     ],
 203     'Trcrt' => [
 204         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 205         { action => 'PARAM', proto => 'icmpv6', dport => 'echo-request' },
 206     ],
 207  };
 208
 209 # imported/converted from: /usr/share/shorewall/macro.*
 210 my $pve_fw_macros = {
 211     'Amanda' => [
 212         "Amanda Backup",
 213         { action => 'PARAM', proto => 'udp', dport => '10080' },
 214         { action => 'PARAM', proto => 'tcp', dport => '10080' },
 215     ],
 216     'Auth' => [
 217         "Auth (identd) traffic",
 218         { action => 'PARAM', proto => 'tcp', dport => '113' },
 219     ],
 220     'BGP' => [
 221         "Border Gateway Protocol traffic",
 222         { action => 'PARAM', proto => 'tcp', dport => '179' },
 223     ],
 224     'BitTorrent' => [
 225         "BitTorrent traffic for BitTorrent 3.1 and earlier",
 226         { action => 'PARAM', proto => 'tcp', dport => '6881:6889' },
 227         { action => 'PARAM', proto => 'udp', dport => '6881' },
 228     ],
 229     'BitTorrent32' => [
 230         "BitTorrent traffic for BitTorrent 3.2 and later",
 231         { action => 'PARAM', proto => 'tcp', dport => '6881:6999' },
 232         { action => 'PARAM', proto => 'udp', dport => '6881' },
 233     ],
 234     'Ceph' => [
 235         "Ceph Storage Cluster traffic (Ceph Monitors, OSD & MDS Daemons)",
 236         # Legacy port for protocol v1
 237         { action => 'PARAM', proto => 'tcp', dport => '6789' },
 238         # New port for protocol v2
 239         { action => 'PARAM', proto => 'tcp', dport => '3300' },
 240         { action => 'PARAM', proto => 'tcp', dport => '6800:7300' },
 241     ],
 242     'CVS' => [
 243         "Concurrent Versions System pserver traffic",
 244         { action => 'PARAM', proto => 'tcp', dport => '2401' },
 245     ],
 246     'Citrix' => [
 247         "Citrix/ICA traffic (ICA, ICA Browser, CGP)",
 248         { action => 'PARAM', proto => 'tcp', dport => '1494' },
 249         { action => 'PARAM', proto => 'udp', dport => '1604' },
 250         { action => 'PARAM', proto => 'tcp', dport => '2598' },
 251     ],
 252     'DAAP' => [
 253         "Digital Audio Access Protocol traffic (iTunes, Rythmbox daemons)",
 254         { action => 'PARAM', proto => 'tcp', dport => '3689' },
 255         { action => 'PARAM', proto => 'udp', dport => '3689' },
 256     ],
 257     'DCC' => [
 258         "Distributed Checksum Clearinghouse spam filtering mechanism",
 259         { action => 'PARAM', proto => 'tcp', dport => '6277' },
 260     ],
 261     'DHCPfwd' => [
 262         "Forwarded DHCP traffic",
 263         { action => 'PARAM', proto => 'udp', dport => '67:68', sport => '67:68' },
 264     ],
 265     'DNS' => [
 266         "Domain Name System traffic (upd and tcp)",
 267         { action => 'PARAM', proto => 'udp', dport => '53' },
 268         { action => 'PARAM', proto => 'tcp', dport => '53' },
 269     ],
 270     'Distcc' => [
 271         "Distributed Compiler service",
 272         { action => 'PARAM', proto => 'tcp', dport => '3632' },
 273     ],
 274     'FTP' => [
 275         "File Transfer Protocol",
 276         { action => 'PARAM', proto => 'tcp', dport => '21' },
 277     ],
 278     'Finger' => [
 279         "Finger protocol (RFC 742)",
 280         { action => 'PARAM', proto => 'tcp', dport => '79' },
 281     ],
 282     'GNUnet' => [
 283         "GNUnet secure peer-to-peer networking traffic",
 284         { action => 'PARAM', proto => 'tcp', dport => '2086' },
 285         { action => 'PARAM', proto => 'udp', dport => '2086' },
 286         { action => 'PARAM', proto => 'tcp', dport => '1080' },
 287         { action => 'PARAM', proto => 'udp', dport => '1080' },
 288     ],
 289     'GRE' => [
 290         "Generic Routing Encapsulation tunneling protocol",
 291         { action => 'PARAM', proto => '47' },
 292     ],
 293     'Git' => [
 294         "Git distributed revision control traffic",
 295         { action => 'PARAM', proto => 'tcp', dport => '9418' },
 296     ],
 297     'HKP' => [
 298         "OpenPGP HTTP key server protocol traffic",
 299         { action => 'PARAM', proto => 'tcp', dport => '11371' },
 300     ],
 301     'HTTP' => [
 302         "Hypertext Transfer Protocol (WWW)",
 303         { action => 'PARAM', proto => 'tcp', dport => '80' },
 304     ],
 305     'HTTPS' => [
 306         "Hypertext Transfer Protocol (WWW) over SSL",
 307         { action => 'PARAM', proto => 'tcp', dport => '443' },
 308     ],
 309     'ICPV2' => [
 310         "Internet Cache Protocol V2 (Squid) traffic",
 311         { action => 'PARAM', proto => 'udp', dport => '3130' },
 312     ],
 313     'ICQ' => [
 314         "AOL Instant Messenger traffic",
 315         { action => 'PARAM', proto => 'tcp', dport => '5190' },
 316     ],
 317     'IMAP' => [
 318         "Internet Message Access Protocol",
 319         { action => 'PARAM', proto => 'tcp', dport => '143' },
 320     ],
 321     'IMAPS' => [
 322         "Internet Message Access Protocol over SSL",
 323         { action => 'PARAM', proto => 'tcp', dport => '993' },
 324     ],
 325     'IPIP' => [
 326         "IPIP capsulation traffic",
 327         { action => 'PARAM', proto => '94' },
 328     ],
 329     'IPsec' => [
 330         "IPsec traffic",
 331         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 332         { action => 'PARAM', proto => '50' },
 333     ],
 334     'IPsecah' => [
 335         "IPsec authentication (AH) traffic",
 336         { action => 'PARAM', proto => 'udp', dport => '500', sport => '500' },
 337         { action => 'PARAM', proto => '51' },
 338     ],
 339     'IPsecnat' => [
 340         "IPsec traffic and Nat-Traversal",
 341         { action => 'PARAM', proto => 'udp', dport => '500' },
 342         { action => 'PARAM', proto => 'udp', dport => '4500' },
 343         { action => 'PARAM', proto => '50' },
 344     ],
 345     'IRC' => [
 346         "Internet Relay Chat traffic",
 347         { action => 'PARAM', proto => 'tcp', dport => '6667' },
 348     ],
 349     'Jetdirect' => [
 350         "HP Jetdirect printing",
 351         { action => 'PARAM', proto => 'tcp', dport => '9100' },
 352     ],
 353     'L2TP' => [
 354         "Layer 2 Tunneling Protocol traffic",
 355         { action => 'PARAM', proto => 'udp', dport => '1701' },
 356     ],
 357     'LDAP' => [
 358         "Lightweight Directory Access Protocol traffic",
 359         { action => 'PARAM', proto => 'tcp', dport => '389' },
 360     ],
 361     'LDAPS' => [
 362         "Secure Lightweight Directory Access Protocol traffic",
 363         { action => 'PARAM', proto => 'tcp', dport => '636' },
 364     ],
 365     'MSNP' => [
 366         "Microsoft Notification Protocol",
 367         { action => 'PARAM', proto => 'tcp', dport => '1863' },
 368     ],
 369     'MSSQL' => [
 370         "Microsoft SQL Server",
 371         { action => 'PARAM', proto => 'tcp', dport => '1433' },
 372     ],
 373     'Mail' => [
 374         "Mail traffic (SMTP, SMTPS, Submission)",
 375         { action => 'PARAM', proto => 'tcp', dport => '25' },
 376         { action => 'PARAM', proto => 'tcp', dport => '465' },
 377         { action => 'PARAM', proto => 'tcp', dport => '587' },
 378     ],
 379     'MDNS' => [
 380         "Multicast DNS",
 381         { action => 'PARAM', proto => 'udp', dport => '5353' },
 382     ],
 383     'Munin' => [
 384         "Munin networked resource monitoring traffic",
 385         { action => 'PARAM', proto => 'tcp', dport => '4949' },
 386     ],
 387     'MySQL' => [
 388         "MySQL server",
 389         { action => 'PARAM', proto => 'tcp', dport => '3306' },
 390     ],
 391     'NNTP' => [
 392         "NNTP traffic (Usenet).",
 393         { action => 'PARAM', proto => 'tcp', dport => '119' },
 394     ],
 395     'NNTPS' => [
 396         "Encrypted NNTP traffic (Usenet)",
 397         { action => 'PARAM', proto => 'tcp', dport => '563' },
 398     ],
 399     'NTP' => [
 400         "Network Time Protocol (ntpd)",
 401         { action => 'PARAM', proto => 'udp', dport => '123' },
 402     ],
 403     'OSPF' => [
 404         "OSPF multicast traffic",
 405         { action => 'PARAM', proto => '89' },
 406     ],
 407     'OpenVPN' => [
 408         "OpenVPN traffic",
 409         { action => 'PARAM', proto => 'udp', dport => '1194' },
 410     ],
 411     'PCA' => [
 412         "Symantec PCAnywere (tm)",
 413         { action => 'PARAM', proto => 'udp', dport => '5632' },
 414         { action => 'PARAM', proto => 'tcp', dport => '5631' },
 415     ],
 416     'PMG' => [
 417         "Proxmox Mail Gateway web interface",
 418         { action => 'PARAM', proto => 'tcp', dport => '8006' },
 419     ],
 420     'POP3' => [
 421         "POP3 traffic",
 422         { action => 'PARAM', proto => 'tcp', dport => '110' },
 423     ],
 424     'POP3S' => [
 425         "Encrypted POP3 traffic",
 426         { action => 'PARAM', proto => 'tcp', dport => '995' },
 427     ],
 428     'PPtP' => [
 429         "Point-to-Point Tunneling Protocol",
 430         { action => 'PARAM', proto => '47' },
 431         { action => 'PARAM', proto => 'tcp', dport => '1723' },
 432     ],
 433     'Ping' => [
 434         "ICMP echo request",
 435         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 436     ],
 437     'PostgreSQL' => [
 438         "PostgreSQL server",
 439         { action => 'PARAM', proto => 'tcp', dport => '5432' },
 440     ],
 441     'Printer' => [
 442         "Line Printer protocol printing",
 443         { action => 'PARAM', proto => 'tcp', dport => '515' },
 444     ],
 445     'RDP' => [
 446         "Microsoft Remote Desktop Protocol traffic",
 447         { action => 'PARAM', proto => 'tcp', dport => '3389' },
 448     ],
 449     'RIP' => [
 450         "Routing Information Protocol (bidirectional)",
 451         { action => 'PARAM', proto => 'udp', dport => '520' },
 452     ],
 453     'RNDC' => [
 454         "BIND remote management protocol",
 455         { action => 'PARAM', proto => 'tcp', dport => '953' },
 456     ],
 457     'Razor' => [
 458         "Razor Antispam System",
 459         { action => 'PARAM', proto => 'tcp', dport => '2703' },
 460     ],
 461     'Rdate' => [
 462         "Remote time retrieval (rdate)",
 463         { action => 'PARAM', proto => 'tcp', dport => '37' },
 464     ],
 465     'Rsync' => [
 466         "Rsync server",
 467         { action => 'PARAM', proto => 'tcp', dport => '873' },
 468     ],
 469     'SANE' => [
 470         "SANE network scanning",
 471         { action => 'PARAM', proto => 'tcp', dport => '6566' },
 472     ],
 473     'SMB' => [
 474         "Microsoft SMB traffic",
 475         { action => 'PARAM', proto => 'udp', dport => '135,445' },
 476         { action => 'PARAM', proto => 'udp', dport => '137:139' },
 477         { action => 'PARAM', proto => 'udp', dport => '1024:65535', sport => '137' },
 478         { action => 'PARAM', proto => 'tcp', dport => '135,139,445' },
 479     ],
 480     'SMBswat' => [
 481         "Samba Web Administration Tool",
 482         { action => 'PARAM', proto => 'tcp', dport => '901' },
 483     ],
 484     'SMTP' => [
 485         "Simple Mail Transfer Protocol",
 486         { action => 'PARAM', proto => 'tcp', dport => '25' },
 487     ],
 488     'SMTPS' => [
 489         "Encrypted Simple Mail Transfer Protocol",
 490         { action => 'PARAM', proto => 'tcp', dport => '465' },
 491     ],
 492     'SNMP' => [
 493         "Simple Network Management Protocol",
 494         { action => 'PARAM', proto => 'udp', dport => '161:162' },
 495         { action => 'PARAM', proto => 'tcp', dport => '161' },
 496     ],
 497     'SPAMD' => [
 498         "Spam Assassin SPAMD traffic",
 499         { action => 'PARAM', proto => 'tcp', dport => '783' },
 500     ],
 501     'SSH' => [
 502         "Secure shell traffic",
 503         { action => 'PARAM', proto => 'tcp', dport => '22' },
 504     ],
 505     'SVN' => [
 506         "Subversion server (svnserve)",
 507         { action => 'PARAM', proto => 'tcp', dport => '3690' },
 508     ],
 509     'SixXS' => [
 510         "SixXS IPv6 Deployment and Tunnel Broker",
 511         { action => 'PARAM', proto => 'tcp', dport => '3874' },
 512         { action => 'PARAM', proto => 'udp', dport => '3740' },
 513         { action => 'PARAM', proto => '41' },
 514         { action => 'PARAM', proto => 'udp', dport => '5072,8374' },
 515     ],
 516     'SPICEproxy' => [
 517         "Proxmox VE SPICE display proxy traffic",
 518         { action => 'PARAM', proto => 'tcp', dport => '3128' },
 519     ],
 520     'Squid' => [
 521         "Squid web proxy traffic",
 522         { action => 'PARAM', proto => 'tcp', dport => '3128' },
 523     ],
 524     'Submission' => [
 525         "Mail message submission traffic",
 526         { action => 'PARAM', proto => 'tcp', dport => '587' },
 527     ],
 528     'Syslog' => [
 529         "Syslog protocol (RFC 5424) traffic",
 530         { action => 'PARAM', proto => 'udp', dport => '514' },
 531         { action => 'PARAM', proto => 'tcp', dport => '514' },
 532     ],
 533     'TFTP' => [
 534         "Trivial File Transfer Protocol traffic",
 535         { action => 'PARAM', proto => 'udp', dport => '69' },
 536     ],
 537     'Telnet' => [
 538         "Telnet traffic",
 539         { action => 'PARAM', proto => 'tcp', dport => '23' },
 540     ],
 541     'Telnets' => [
 542         "Telnet over SSL",
 543         { action => 'PARAM', proto => 'tcp', dport => '992' },
 544     ],
 545     'Time' => [
 546         "RFC 868 Time protocol",
 547         { action => 'PARAM', proto => 'tcp', dport => '37' },
 548     ],
 549     'Trcrt' => [
 550         "Traceroute (for up to 30 hops) traffic",
 551         { action => 'PARAM', proto => 'udp', dport => '33434:33524' },
 552         { action => 'PARAM', proto => 'icmp', dport => 'echo-request' },
 553     ],
 554     'VNC' => [
 555         "VNC traffic for VNC display's 0 - 99",
 556         { action => 'PARAM', proto => 'tcp', dport => '5900:5999' },
 557     ],
 558     'VNCL' => [
 559         "VNC traffic from Vncservers to Vncviewers in listen mode",
 560         { action => 'PARAM', proto => 'tcp', dport => '5500' },
 561     ],
 562     'Web' => [
 563         "WWW traffic (HTTP and HTTPS)",
 564         { action => 'PARAM', proto => 'tcp', dport => '80' },
 565         { action => 'PARAM', proto => 'tcp', dport => '443' },
 566     ],
 567     'Webcache' => [
 568         "Web Cache/Proxy traffic (port 8080)",
 569         { action => 'PARAM', proto => 'tcp', dport => '8080' },
 570     ],
 571     'Webmin' => [
 572         "Webmin traffic",
 573         { action => 'PARAM', proto => 'tcp', dport => '10000' },
 574     ],
 575     'Whois' => [
 576         "Whois (nicname, RFC 3912) traffic",
 577         { action => 'PARAM', proto => 'tcp', dport => '43' },
 578     ],
 579 };
 580
 581 my $pve_fw_helpers = {
 582     'amanda' => { proto => 'udp', dport => '10080', 'v4' => 1, 'v6' => 1 },
 583     'ftp' => { proto => 'tcp', dport => '21', 'v4' => 1, 'v6' => 1},
 584     'irc' => { proto => 'tcp', dport => '6667', 'v4' => 1 },
 585     'netbios-ns' => { proto => 'udp', dport => '137', 'v4' => 1 },
 586     'pptp' => { proto => 'tcp', dport => '1723', 'v4' => 1, },
 587     'sane' => { proto => 'tcp', dport => '6566', 'v4' => 1, 'v6' => 1 },
 588     'sip' => { proto => 'udp', dport => '5060', 'v4' => 1, 'v6' => 1 },
 589     'snmp' => { proto => 'udp', dport => '161', 'v4' => 1 },
 590     'tftp' => { proto => 'udp', dport => '69', 'v4' => 1, 'v6' => 1},
 591 };
 592
 593 my $pve_fw_parsed_macros;
 594 my $pve_fw_macro_descr;
 595 my $pve_fw_macro_ipversion = {};
 596 my $pve_fw_preferred_macro_names = {};
 597
 598 my $FWACCEPTMARK_ON  = "0x80000000/0x80000000";
 599 my $FWACCEPTMARK_OFF = "0x00000000/0x80000000";
 600
 601 my $pve_std_chains = {};
 602 my $pve_std_chains_conf = {};
 603 $pve_std_chains_conf->{4} = {
 604     'PVEFW-SET-ACCEPT-MARK' => [
 605         { target => "-j MARK --set-mark $FWACCEPTMARK_ON" },
 606     ],
 607     'PVEFW-DropBroadcast' => [
 608         # same as shorewall 'Broadcast'
 609         # simply DROP BROADCAST/MULTICAST/ANYCAST
 610         # we can use this to reduce logging
 611         { action => 'DROP', dsttype => 'BROADCAST' },
 612         { action => 'DROP', dsttype => 'MULTICAST' },
 613         { action => 'DROP', dsttype => 'ANYCAST' },
 614         { action => 'DROP', dest => '224.0.0.0/4' },
 615     ],
 616     'PVEFW-reject' => [
 617         # same as shorewall 'reject'
 618         { action => 'DROP', dsttype => 'BROADCAST' },
 619         { action => 'DROP', source => '224.0.0.0/4' },
 620         { action => 'DROP', proto => 'icmp' },
 621         { match => '-p tcp', target => '-j REJECT --reject-with tcp-reset' },
 622         { match => '-p udp', target => '-j REJECT --reject-with icmp-port-unreachable' },
 623         { match => '-p icmp', target => '-j REJECT --reject-with icmp-host-unreachable' },
 624         { target => '-j REJECT --reject-with icmp-host-prohibited' },
 625     ],
 626     'PVEFW-Drop' => [
 627         # same as shorewall 'Drop', which is equal to DROP,
 628         # but REJECT/DROP some packages to reduce logging,
 629         # and ACCEPT critical ICMP types
 630         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 631         { action => 'PVEFW-DropBroadcast' },
 632         # ACCEPT critical ICMP types
 633         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 634         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 635         # Drop packets with INVALID state
 636         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 637         # Drop Microsoft SMB noise
 638         { action => 'DROP', proto => 'udp', dport => '135,445' },
 639         { action => 'DROP', proto => 'udp', dport => '137:139' },
 640         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 641         { action => 'DROP', proto => 'tcp', dport => '135,139,445' },
 642         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 643         # Drop new/NotSyn traffic so that it doesn't get logged
 644         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 645         # Drop DNS replies
 646         { action => 'DROP', proto => 'udp', sport => 53 },
 647     ],
 648     'PVEFW-Reject' => [
 649         # same as shorewall 'Reject', which is equal to Reject,
 650         # but REJECT/DROP some packages to reduce logging,
 651         # and ACCEPT critical ICMP types
 652         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 653         { action => 'PVEFW-DropBroadcast' },
 654         # ACCEPT critical ICMP types
 655         { action => 'ACCEPT', proto => 'icmp', dport => 'fragmentation-needed' },
 656         { action => 'ACCEPT', proto => 'icmp', dport => 'time-exceeded' },
 657         # Drop packets with INVALID state
 658         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 659         # Drop Microsoft SMB noise
 660         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445' },
 661         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139'},
 662         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 663         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445' },
 664         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 665         # Drop new/NotSyn traffic so that it doesn't get logged
 666         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 667         # Drop DNS replies
 668         { action => 'DROP', proto => 'udp', sport => 53 },
 669     ],
 670     'PVEFW-tcpflags' => [
 671         # same as shorewall tcpflags action.
 672         # Packets arriving on this interface are checked for some illegal combinations of TCP flags
 673         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG', target => '-g PVEFW-logflags' },
 674         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE', target => '-g PVEFW-logflags' },
 675         { match => '-p tcp -m tcp --tcp-flags SYN,RST SYN,RST', target => '-g PVEFW-logflags' },
 676         { match => '-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN', target => '-g PVEFW-logflags' },
 677         { match => '-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN', target => '-g PVEFW-logflags' },
 678     ],
 679     'PVEFW-smurfs' => [
 680         # same as shorewall smurfs action
 681         # Filter packets for smurfs (packets with a broadcast address as the source).
 682         { match => '-s 0.0.0.0/32', target => '-j RETURN' }, # allow DHCP
 683         { match => '-m addrtype --src-type BROADCAST', target => '-g PVEFW-smurflog' },
 684         { match => '-s 224.0.0.0/4', target => '-g PVEFW-smurflog' },
 685     ],
 686     'PVEFW-smurflog' => [
 687         { action => 'DROP', logmsg => 'DROP: ' },
 688     ],
 689     'PVEFW-logflags' => [
 690         { action => 'DROP', logmsg => 'DROP: ' },
 691     ],
 692 };
 693
 694 $pve_std_chains_conf->{6} = {
 695     'PVEFW-SET-ACCEPT-MARK' => [
 696         { target => "-j MARK --set-mark $FWACCEPTMARK_ON" },
 697     ],
 698     'PVEFW-DropBroadcast' => [
 699         # same as shorewall 'Broadcast'
 700         # simply DROP BROADCAST/MULTICAST/ANYCAST
 701         # we can use this to reduce logging
 702         #{ action => 'DROP', dsttype => 'BROADCAST' }, #no broadcast in ipv6
 703         # ipv6 addrtype does not work with kernel 2.6.32
 704         #{ action => 'DROP', dsttype => 'MULTICAST' },
 705         #{ action => 'DROP', dsttype => 'ANYCAST' },
 706         { action => 'DROP', dest => 'ff00::/8' },
 707         #{ action => 'DROP', dest => '224.0.0.0/4' },
 708     ],
 709     'PVEFW-reject' => [
 710         { action => 'DROP', proto => 'icmpv6' },
 711         { match => '-p tcp', target => '-j REJECT --reject-with tcp-reset' },
 712         { match => '-p udp', target => '-j REJECT --reject-with icmp6-port-unreachable' },
 713         { target => '-j REJECT --reject-with icmp6-adm-prohibited' },
 714     ],
 715     'PVEFW-Drop' => [
 716         # same as shorewall 'Drop', which is equal to DROP,
 717         # but REJECT/DROP some packages to reduce logging,
 718         # and ACCEPT critical ICMP types
 719         { action => 'PVEFW-reject', proto => 'tcp', dport => '43' }, # REJECT 'auth'
 720         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 721         { action => 'PVEFW-DropBroadcast' },
 722         # ACCEPT critical ICMP types
 723         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
 724         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
 725         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
 726         # Drop packets with INVALID state
 727         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 728         # Drop Microsoft SMB noise
 729         { action => 'DROP', proto => 'udp', dport => '135,445' },
 730         { action => 'DROP', proto => 'udp', dport => '137:139'},
 731         { action => 'DROP', proto => 'udp', dport => '1024:65535', sport => 137 },
 732         { action => 'DROP', proto => 'tcp', dport => '135,139,445' },
 733         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 734         # Drop new/NotSyn traffic so that it doesn't get logged
 735         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 736         # Drop DNS replies
 737         { action => 'DROP', proto => 'udp', sport => 53 },
 738     ],
 739     'PVEFW-Reject' => [
 740         # same as shorewall 'Reject', which is equal to Reject,
 741         # but REJECT/DROP some packages to reduce logging,
 742         # and ACCEPT critical ICMP types
 743         { action => 'PVEFW-reject',  proto => 'tcp', dport => '43' }, # REJECT 'auth'
 744         # we are not interested in BROADCAST/MULTICAST/ANYCAST
 745         { action => 'PVEFW-DropBroadcast' },
 746         # ACCEPT critical ICMP types
 747         { action => 'ACCEPT', proto => 'icmpv6', dport => 'destination-unreachable' },
 748         { action => 'ACCEPT', proto => 'icmpv6', dport => 'time-exceeded' },
 749         { action => 'ACCEPT', proto => 'icmpv6', dport => 'packet-too-big' },
 750         # Drop packets with INVALID state
 751         { action => 'DROP', match => '-m conntrack --ctstate INVALID', },
 752         # Drop Microsoft SMB noise
 753         { action => 'PVEFW-reject', proto => 'udp', dport => '135,445' },
 754         { action => 'PVEFW-reject', proto => 'udp', dport => '137:139' },
 755         { action => 'PVEFW-reject', proto => 'udp', dport => '1024:65535', sport => 137 },
 756         { action => 'PVEFW-reject', proto => 'tcp', dport => '135,139,445' },
 757         { action => 'DROP', proto => 'udp', dport => 1900 }, # UPnP
 758         # Drop new/NotSyn traffic so that it doesn't get logged
 759         { action => 'DROP', match => '-p tcp -m tcp ! --tcp-flags FIN,SYN,RST,ACK SYN' },
 760         # Drop DNS replies
 761         { action => 'DROP', proto => 'udp', sport => 53 },
 762     ],
 763     'PVEFW-tcpflags' => [
 764         # same as shorewall tcpflags action.
 765         # Packets arriving on this interface are checked for some illegal combinations of TCP flags
 766         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG FIN,PSH,URG', target => '-g PVEFW-logflags' },
 767         { match => '-p tcp -m tcp --tcp-flags FIN,SYN,RST,PSH,ACK,URG NONE', target => '-g PVEFW-logflags' },
 768         { match => '-p tcp -m tcp --tcp-flags SYN,RST SYN,RST', target => '-g PVEFW-logflags' },
 769         { match => '-p tcp -m tcp --tcp-flags FIN,SYN FIN,SYN', target => '-g PVEFW-logflags' },
 770         { match => '-p tcp -m tcp --sport 0 --tcp-flags FIN,SYN,RST,ACK SYN', target => '-g PVEFW-logflags' },
 771     ],
 772     'PVEFW-logflags' => [
 773         { action => 'DROP', logmsg => 'DROP: ' },
 774     ],
 775 };
 776
 777 # iptables -p icmp -h
 778 my $icmp_type_names = {
 779     any => 1,
 780     'echo-reply' => 1,
 781     'destination-unreachable' => 1,
 782     'network-unreachable' => 1,
 783     'host-unreachable' => 1,
 784     'protocol-unreachable' => 1,
 785     'port-unreachable' => 1,
 786     'fragmentation-needed' => 1,
 787     'source-route-failed' => 1,
 788     'network-unknown' => 1,
 789     'host-unknown' => 1,
 790     'network-prohibited' => 1,
 791     'host-prohibited' => 1,
 792     'TOS-network-unreachable' => 1,
 793     'TOS-host-unreachable' => 1,
 794     'communication-prohibited' => 1,
 795     'host-precedence-violation' => 1,
 796     'precedence-cutoff' => 1,
 797     'source-quench' => 1,
 798     'redirect' => 1,
 799     'network-redirect' => 1,
 800     'host-redirect' => 1,
 801     'TOS-network-redirect' => 1,
 802     'TOS-host-redirect' => 1,
 803     'echo-request' => 1,
 804     'router-advertisement' => 1,
 805     'router-solicitation' => 1,
 806     'time-exceeded' => 1,
 807     'ttl-zero-during-transit' => 1,
 808     'ttl-zero-during-reassembly' => 1,
 809     'parameter-problem' => 1,
 810     'ip-header-bad' => 1,
 811     'required-option-missing' => 1,
 812     'timestamp-request' => 1,
 813     'timestamp-reply' => 1,
 814     'address-mask-request' => 1,
 815     'address-mask-reply' => 1,
 816 };
 817
 818 # ip6tables -p icmpv6 -h
 819
 820 my $icmpv6_type_names = {
 821     'destination-unreachable' => 1,
 822     'no-route' => 1,
 823     'communication-prohibited' => 1,
 824     'beyond-scope' => 1,
 825     'address-unreachable' => 1,
 826     'port-unreachable' => 1,
 827     'failed-policy' => 1,
 828     'reject-route' => 1,
 829     'packet-too-big' => 1,
 830     'time-exceeded' => 1,
 831     'ttl-zero-during-transit' => 1,
 832     'ttl-zero-during-reassembly' => 1,
 833     'parameter-problem' => 1,
 834     'bad-header' => 1,
 835     'unknown-header-type' => 1,
 836     'unknown-option' => 1,
 837     'echo-request' => 1,
 838     'echo-reply' => 1,
 839     'router-solicitation' => 1,
 840     'router-advertisement' => 1,
 841     'neighbor-solicitation' => 1,
 842     'neighbour-solicitation' => 1,
 843     'neighbor-advertisement' => 1,
 844     'neighbour-advertisement' => 1,
 845     'redirect' => 1,
 846 };
 847
 848 my $is_valid_icmp_type = sub {
 849     my ($type, $valid_types) = @_;
 850
 851     if ($type =~ m/^\d+$/) {
 852         # values for icmp-type range between 0 and 255 (8 bit field)
 853         die "invalid icmp-type '$type'\n" if $type > 255;
 854     } else {
 855         die "unknown icmp-type '$type'\n" if !defined($valid_types->{$type});
 856     }
 857 };
 858
 859 my $proto_is_icmp = sub {
 860     my $proto = shift;
 861     return $proto eq 'icmp' || $proto eq 'icmpv6' || $proto eq 'ipv6-icmp';
 862 };
 863
 864 sub init_firewall_macros {
 865
 866     $pve_fw_parsed_macros = {};
 867
 868     my $parse = sub {
 869         my ($k, $macro) = @_;
 870         my $lc_name = lc($k);
 871         $pve_fw_macro_ipversion->{$k} = 0;
 872         while (!ref($macro->[0])) {
 873             my $desc = shift @$macro;
 874             if ($desc eq 'ipv4only') {
 875                 $pve_fw_macro_ipversion->{$k} = 4;
 876             } elsif ($desc eq 'ipv6only') {
 877                 $pve_fw_macro_ipversion->{$k} = 6;
 878             } else {
 879                 $pve_fw_macro_descr->{$k} = $desc;
 880             }
 881         }
 882         $pve_fw_preferred_macro_names->{$lc_name} = $k;
 883         $pve_fw_parsed_macros->{$k} = $macro;
 884     };
 885
 886     foreach my $k (keys %$pve_fw_macros) {
 887         &$parse($k, $pve_fw_macros->{$k});
 888     }
 889
 890     foreach my $k (keys %$pve_ipv6fw_macros) {
 891         next if $pve_fw_parsed_macros->{$k};
 892         &$parse($k, $pve_ipv6fw_macros->{$k});
 893         $pve_fw_macro_ipversion->{$k} = 6;
 894     }
 895 }
 896
 897 init_firewall_macros();
 898
 899 sub get_macros {
 900     return wantarray ? ($pve_fw_parsed_macros, $pve_fw_macro_descr): $pve_fw_parsed_macros;
 901 }
 902
 903 my $etc_services;
 904
 905 sub get_etc_services {
 906
 907     return $etc_services if $etc_services;
 908
 909     my $filename = "/etc/services";
 910
 911     my $fh = IO::File->new($filename, O_RDONLY);
 912     if (!$fh) {
 913         warn "unable to read '$filename' - $!\n";
 914         return {};
 915     }
 916
 917     my $services = {};
 918
 919     while (my $line = <$fh>) {
 920         chomp ($line);
 921         next if $line =~m/^#/;
 922         next if ($line =~m/^\s*$/);
 923
 924         if ($line =~ m!^(\S+)\s+(\S+)/(tcp|udp|sctp).*$!) {
 925             $services->{byid}->{$2}->{name} = $1;
 926             $services->{byid}->{$2}->{port} = $2;
 927             $services->{byid}->{$2}->{$3} = 1;
 928             $services->{byname}->{$1} = $services->{byid}->{$2};
 929         }
 930     }
 931
 932     close($fh);
 933
 934     $etc_services = $services;
 935
 936
 937     return $etc_services;
 938 }
 939
 940 sub parse_protocol_file {
 941     my ($filename) = @_;
 942
 943     my $fh = IO::File->new($filename, O_RDONLY);
 944     if (!$fh) {
 945         warn "unable to read '$filename' - $!\n";
 946         return {};
 947     }
 948
 949     my $protocols = {};
 950
 951     while (my $line = <$fh>) {
 952         chomp ($line);
 953         next if $line =~m/^#/;
 954         next if ($line =~m/^\s*$/);
 955
 956         if ($line =~ m!^(\S+)\s+(\d+)(?:\s+.*)?$!) {
 957             $protocols->{byid}->{$2}->{name} = $1;
 958             $protocols->{byname}->{$1} = $protocols->{byid}->{$2};
 959         }
 960     }
 961
 962     close($fh);
 963
 964     return $protocols;
 965 }
 966
 967 my $etc_protocols;
 968
 969 sub get_etc_protocols {
 970     return $etc_protocols if $etc_protocols;
 971
 972     my $protocols = parse_protocol_file('/etc/protocols');
 973
 974     # add special case for ICMP v6
 975     $protocols->{byid}->{icmpv6}->{name} = "icmpv6";
 976     $protocols->{byname}->{icmpv6} = $protocols->{byid}->{icmpv6};
 977
 978     $etc_protocols = $protocols;
 979
 980     return $etc_protocols;
 981 }
 982
 983 my $etc_ethertypes;
 984
 985 sub get_etc_ethertypes {
 986     $etc_ethertypes = parse_protocol_file('/etc/ethertypes')
 987         if !$etc_ethertypes;
 988     return $etc_ethertypes;
 989 }
 990
 991 my $__local_network;
 992
 993 sub local_network {
 994     my ($new_value) = @_;
 995
 996     $__local_network = $new_value if defined($new_value);
 997
 998     return $__local_network if defined($__local_network);
 999
1000     eval {
1001         my $nodename = PVE::INotify::nodename();
1002
1003         my $ip = PVE::Cluster::remote_node_ip($nodename);
1004
1005         my $testip = Net::IP->new($ip);
1006
1007         my $isv6 = $testip->version == 6;
1008         my $routes = $isv6 ? PVE::ProcFSTools::read_proc_net_ipv6_route()
1009                            : PVE::ProcFSTools::read_proc_net_route();
1010         foreach my $entry (@$routes) {
1011             my $mask;
1012             if ($isv6) {
1013                 $mask = $entry->{prefix};
1014                 next if !$mask; # skip the default route...
1015             } else {
1016                 $mask = $PVE::Network::ipv4_mask_hash_localnet->{$entry->{mask}};
1017                 next if !defined($mask);
1018             }
1019             my $cidr = "$entry->{dest}/$mask";
1020             my $testnet = Net::IP->new($cidr);
1021             my $overlap = $testnet->overlaps($testip);
1022             if ($overlap == $Net::IP::IP_B_IN_A_OVERLAP ||
1023                 $overlap == $Net::IP::IP_IDENTICAL)
1024             {
1025                 $__local_network = $cidr;
1026                 return;
1027             }
1028         }
1029     };
1030     warn $@ if $@;
1031
1032     return $__local_network;
1033 }
1034
1035 # ipset names are limited to 31 characters,
1036 # and we use '-v4' or '-v6' to indicate IP versions,
1037 # and we use '_swap' suffix for atomic update,
1038 # for example PVEFW-${VMID}-${ipset_name}_swap
1039
1040 my $max_iptables_ipset_name_length = 31 - length("PVEFW-") - length("_swap");
1041
1042 sub compute_ipset_chain_name {
1043     my ($vmid, $ipset_name, $ipversion) = @_;
1044
1045     $vmid = 0 if !defined($vmid);
1046
1047     my $id = "$vmid-${ipset_name}-v$ipversion";
1048
1049     if (length($id) > $max_iptables_ipset_name_length) {
1050         $id = PVE::Tools::fnv31a_hex($id);
1051     }
1052
1053     return "PVEFW-$id";
1054 }
1055
1056 sub compute_ipfilter_ipset_name {
1057     my ($iface) = @_;
1058
1059     return "ipfilter-$iface";
1060 }
1061
1062 sub parse_address_list {
1063     my ($str) = @_;
1064
1065     if ($str =~ m/^(\+)(\S+)$/) { # ipset ref
1066         die "ipset name too long\n" if length($str) > ($max_ipset_name_length + 1);
1067         return;
1068     }
1069
1070     if ($str =~ m@^(dc/|guest/)?${ip_alias_pattern}$@) {
1071         die "alias name too long\n" if length($str) > $max_alias_name_length;
1072         return;
1073     }
1074
1075     my $count = 0;
1076     my $iprange = 0;
1077     my $ipversion;
1078
1079     my @elements = split(/,/, $str);
1080     die "extraneous commas in list\n" if $str ne join(',', @elements);
1081     foreach my $elem (@elements) {
1082         $count++;
1083         my $ip = Net::IP->new($elem);
1084         if (!$ip) {
1085             my $err = Net::IP::Error();
1086             die "invalid IP address: $err\n";
1087         }
1088         $iprange = 1 if $elem =~ m/-/;
1089
1090         my $new_ipversion = Net::IP::ip_is_ipv6($ip->ip()) ? 6 : 4;
1091
1092         die "detected mixed ipv4/ipv6 addresses in address list '$str'\n"
1093             if $ipversion && ($new_ipversion != $ipversion);
1094
1095         $ipversion = $new_ipversion;
1096     }
1097
1098     die "you can't use a range in a list\n" if $iprange && $count > 1;
1099
1100     return $ipversion;
1101 }
1102
1103 # $dport must only be set to 1 if the parsed parameter is dport and the
1104 # protocol is one of the ICMP variants - ICMP type values used to be stored in
1105 # the dport parameter.
1106 sub parse_port_name_number_or_range {
1107     my ($str, $dport) = @_;
1108
1109     my $services = PVE::Firewall::get_etc_services();
1110     my $count = 0;
1111     my $icmp_port = 0;
1112
1113     my @elements = split(/,/, $str);
1114     die "extraneous commas in list\n" if $str ne join(',', @elements);
1115     foreach my $item (@elements) {
1116         if ($item =~ m/^([0-9]+):([0-9]+)$/) {
1117             $count += 2;
1118             my ($port1, $port2) = ($1, $2);
1119             die "invalid port '$port1'\n" if $port1 > 65535;
1120             die "invalid port '$port2'\n" if $port2 > 65535;
1121             die "backwards range '$port1:$port2' not allowed, did you mean '$port2:$port1'?\n" if $port1 > $port2;
1122         } elsif ($item =~ m/^([0-9]+)$/) {
1123             $count += 1;
1124             my $port = $1;
1125             die "invalid port '$port'\n" if $port > 65535;
1126         } else {
1127             if ($dport && $icmp_type_names->{$item}) {
1128                 $icmp_port = 1;
1129             } elsif ($dport && $icmpv6_type_names->{$item}) {
1130                 $icmp_port = 1;
1131             } else {
1132                 die "invalid port '$item'\n" if !$services->{byname}->{$item};
1133             }
1134         }
1135     }
1136
1137     die "ICMP ports not allowed in port range\n" if $icmp_port && $count > 0;
1138
1139     # I really don't like to use the word number here, but it's the only thing
1140     # that makes sense in a literal way. The range 1:100 counts as 2, not as
1141     # one and not as 100...
1142     die "too many entries in port list (> 15 numbers)\n"
1143         if $count > 15;
1144
1145     return (scalar(@elements) > 1);
1146 }
1147
1148 PVE::JSONSchema::register_format('pve-fw-conntrack-helper', \&pve_fw_verify_conntrack_helper);
1149 sub pve_fw_verify_conntrack_helper {
1150    my ($list) = @_;
1151
1152    my @helpers = split(/,/, $list);
1153    die "extraneous commas in list\n" if $list ne join(',', @helpers);
1154    foreach my $helper (@helpers) {
1155         die "unknown helper $helper" if !$pve_fw_helpers->{$helper};
1156    }
1157
1158    return $list;
1159 }
1160
1161 PVE::JSONSchema::register_format('pve-fw-sport-spec', \&pve_fw_verify_sport_spec);
1162 sub pve_fw_verify_sport_spec {
1163    my ($portstr) = @_;
1164
1165    parse_port_name_number_or_range($portstr, 0);
1166
1167    return $portstr;
1168 }
1169
1170 PVE::JSONSchema::register_format('pve-fw-dport-spec', \&pve_fw_verify_dport_spec);
1171 sub pve_fw_verify_dport_spec {
1172    my ($portstr) = @_;
1173
1174    parse_port_name_number_or_range($portstr, 1);
1175
1176    return $portstr;
1177 }
1178
1179 PVE::JSONSchema::register_format('pve-fw-addr-spec', \&pve_fw_verify_addr_spec);
1180 sub pve_fw_verify_addr_spec {
1181    my ($list) = @_;
1182
1183    parse_address_list($list);
1184
1185    return $list;
1186 }
1187
1188 PVE::JSONSchema::register_format('pve-fw-protocol-spec', \&pve_fw_verify_protocol_spec);
1189 sub pve_fw_verify_protocol_spec {
1190    my ($proto) = @_;
1191
1192    my $protocols = get_etc_protocols();
1193
1194    die "unknown protocol '$proto'\n" if $proto &&
1195        !(defined($protocols->{byname}->{$proto}) ||
1196          defined($protocols->{byid}->{$proto}));
1197
1198    return $proto;
1199 }
1200
1201 PVE::JSONSchema::register_format('pve-fw-icmp-type-spec', \&pve_fw_verify_icmp_type_spec);
1202 sub pve_fw_verify_icmp_type_spec {
1203     my ($icmp_type) = @_;
1204
1205     if ($icmp_type_names->{$icmp_type} ||  $icmpv6_type_names->{$icmp_type}) {
1206         return $icmp_type;
1207     }
1208
1209     die "invalid icmp-type value '$icmp_type'\n" if $icmp_type ne '';
1210
1211     return $icmp_type;
1212 }
1213
1214
1215 # helper function for API
1216
1217 sub copy_opject_with_digest {
1218     my ($object) = @_;
1219
1220     my $sha = Digest::SHA->new('sha1');
1221
1222     my $res = {};
1223     foreach my $k (sort keys %$object) {
1224         my $v = $object->{$k};
1225         next if !defined($v);
1226         $res->{$k} = $v;
1227         $sha->add($k, ':', $v, "\n");
1228     }
1229
1230     my $digest = $sha->hexdigest;
1231
1232     $res->{digest} = $digest;
1233
1234     return wantarray ? ($res, $digest) : $res;
1235 }
1236
1237 sub copy_list_with_digest {
1238     my ($list) = @_;
1239
1240     my $sha = Digest::SHA->new('sha1');
1241
1242     my $res = [];
1243     foreach my $entry (@$list) {
1244         my $data = {};
1245         foreach my $k (sort keys %$entry) {
1246             my $v = $entry->{$k};
1247             next if !defined($v);
1248             $data->{$k} = $v;
1249             # Note: digest ignores refs ($rule->{errors})
1250             # since Digest::SHA expects a series of bytes,
1251             #  we have to encode the value here to prevent errors when
1252             #  using utf8 characters (eg. in comments)
1253             $sha->add($k, ':', encode_utf8($v), "\n") if !ref($v); ;
1254         }
1255         push @$res, $data;
1256     }
1257
1258     my $digest = $sha->hexdigest;
1259
1260     foreach my $entry (@$res) {
1261         $entry->{digest} = $digest;
1262     }
1263
1264     return wantarray ? ($res, $digest) : $res;
1265 }
1266
1267 our $cluster_option_properties = {
1268     enable => {
1269         description => "Enable or disable the firewall cluster wide.",
1270         type => 'integer',
1271         minimum => 0,
1272         optional => 1,
1273     },
1274     ebtables => {
1275         description => "Enable ebtables rules cluster wide.",
1276         type => 'boolean',
1277         default => 1,
1278         optional => 1,
1279     },
1280     policy_in => {
1281         description => "Input policy.",
1282         type => 'string',
1283         optional => 1,
1284         enum => ['ACCEPT', 'REJECT', 'DROP'],
1285     },
1286     policy_out => {
1287         description => "Output policy.",
1288         type => 'string',
1289         optional => 1,
1290         enum => ['ACCEPT', 'REJECT', 'DROP'],
1291     },
1292     log_ratelimit => {
1293         description => "Log ratelimiting settings",
1294         type => 'string', format => {
1295             enable => {
1296                 default_key => 1,
1297                 description => 'Enable or disable log rate limiting',
1298                 type => 'boolean',
1299                 default => '1',
1300             },
1301             rate => {
1302                 type => 'string',
1303                 description => 'Frequency with which the burst bucket gets refilled',
1304                 optional => 1,
1305                 pattern => '[1-9][0-9]*\/(second|minute|hour|day)',
1306                 format_description => 'rate',
1307                 default => '1/second',
1308             },
1309             burst => {
1310                 type => 'integer',
1311                 minimum => 0,
1312                 optional => 1,
1313                 description => 'Initial burst of packages which will always get logged before the rate is applied',
1314                 default => 5,
1315             },
1316         },
1317         optional => 1,
1318     },
1319 };
1320
1321 our $host_option_properties = {
1322     enable => {
1323         description => "Enable host firewall rules.",
1324         type => 'boolean',
1325         optional => 1,
1326     },
1327     log_level_in =>  get_standard_option('pve-fw-loglevel', {
1328         description => "Log level for incoming traffic." }),
1329     log_level_out =>  get_standard_option('pve-fw-loglevel', {
1330         description => "Log level for outgoing traffic." }),
1331     tcp_flags_log_level =>  get_standard_option('pve-fw-loglevel', {
1332         description => "Log level for illegal tcp flags filter." }),
1333     smurf_log_level =>  get_standard_option('pve-fw-loglevel', {
1334         description => "Log level for SMURFS filter." }),
1335     nosmurfs => {
1336         description => "Enable SMURFS filter.",
1337         type => 'boolean',
1338         optional => 1,
1339     },
1340     tcpflags => {
1341         description => "Filter illegal combinations of TCP flags.",
1342         type => 'boolean',
1343         default => 0,
1344         optional => 1,
1345     },
1346     nf_conntrack_max => {
1347         description => "Maximum number of tracked connections.",
1348         type => 'integer',
1349         optional => 1,
1350         default => 262144,
1351         minimum => 32768,
1352     },
1353     nf_conntrack_tcp_timeout_established => {
1354         description => "Conntrack established timeout.",
1355         type => 'integer',
1356         optional => 1,
1357         default => 432000,
1358         minimum => 7875,
1359     },
1360     nf_conntrack_tcp_timeout_syn_recv => {
1361         description => "Conntrack syn recv timeout.",
1362         type => 'integer',
1363         optional => 1,
1364         default => 60,
1365         minimum => 30,
1366         maximum => 60,
1367     },
1368     ndp => {
1369         description => "Enable NDP (Neighbor Discovery Protocol).",
1370         type => 'boolean',
1371         default => 0,
1372         optional => 1,
1373     },
1374     nf_conntrack_allow_invalid => {
1375         description => "Allow invalid packets on connection tracking.",
1376         type => 'boolean',
1377         default => 0,
1378         optional => 1,
1379     },
1380     nf_conntrack_helpers => {
1381         type => 'string', format => 'pve-fw-conntrack-helper',
1382         description => "Enable conntrack helpers for specific protocols. ".
1383             "Supported protocols: amanda, ftp, irc, netbios-ns, pptp, sane, sip, snmp, tftp",
1384         default => '',
1385         optional => 1,
1386     },
1387     protection_synflood => {
1388         description => "Enable synflood protection",
1389         type => 'boolean',
1390         default => 0,
1391         optional => 1,
1392     },
1393     protection_synflood_rate => {
1394         description => "Synflood protection rate syn/sec by ip src.",
1395         type => 'integer',
1396         optional => 1,
1397         default => 200,
1398     },
1399     protection_synflood_burst => {
1400         description => "Synflood protection rate burst by ip src.",
1401         type => 'integer',
1402         optional => 1,
1403         default => 1000,
1404     },
1405     log_nf_conntrack => {
1406         description => "Enable logging of conntrack information.",
1407         type => 'boolean',
1408         default => 0,
1409         optional => 1
1410     },
1411 };
1412
1413 our $vm_option_properties = {
1414     enable => {
1415         description => "Enable/disable firewall rules.",
1416         type => 'boolean',
1417         default => 0,
1418         optional => 1,
1419     },
1420     macfilter => {
1421         description => "Enable/disable MAC address filter.",
1422         type => 'boolean',
1423         default => 1,
1424         optional => 1,
1425     },
1426     dhcp => {
1427         description => "Enable DHCP.",
1428         type => 'boolean',
1429         default => 0,
1430         optional => 1,
1431     },
1432     ndp => {
1433         description => "Enable NDP (Neighbor Discovery Protocol).",
1434         type => 'boolean',
1435         default => 0,
1436         optional => 1,
1437     },
1438     radv => {
1439         description => "Allow sending Router Advertisement.",
1440         type => 'boolean',
1441         optional => 1,
1442     },
1443     ipfilter => {
1444         description => "Enable default IP filters. " .
1445            "This is equivalent to adding an empty ipfilter-net<id> ipset " .
1446            "for every interface. Such ipsets implicitly contain sane default " .
1447            "restrictions such as restricting IPv6 link local addresses to " .
1448            "the one derived from the interface's MAC address. For containers " .
1449            "the configured IP addresses will be implicitly added.",
1450         type => 'boolean',
1451         optional => 1,
1452     },
1453     policy_in => {
1454         description => "Input policy.",
1455         type => 'string',
1456         optional => 1,
1457         enum => ['ACCEPT', 'REJECT', 'DROP'],
1458     },
1459     policy_out => {
1460         description => "Output policy.",
1461         type => 'string',
1462         optional => 1,
1463         enum => ['ACCEPT', 'REJECT', 'DROP'],
1464     },
1465     log_level_in =>  get_standard_option('pve-fw-loglevel', {
1466         description => "Log level for incoming traffic." }),
1467     log_level_out =>  get_standard_option('pve-fw-loglevel', {
1468         description => "Log level for outgoing traffic." }),
1469
1470 };
1471
1472
1473 my $addr_list_descr = "This can refer to a single IP address, an IP set ('+ipsetname') or an IP alias definition. You can also specify an address range like '20.34.101.207-201.3.9.99', or a list of IP addresses and networks (entries are separated by comma). Please do not mix IPv4 and IPv6 addresses inside such lists.";
1474
1475 my $port_descr = "You can use service names or simple numbers (0-65535), as defined in '/etc/services'. Port ranges can be specified with '\\d+:\\d+', for example '80:85', and you can use comma separated list to match several ports or ranges.";
1476
1477 my $rule_properties = {
1478     pos => {
1479         description => "Update rule at position <pos>.",
1480         type => 'integer',
1481         minimum => 0,
1482         optional => 1,
1483     },
1484     digest => get_standard_option('pve-config-digest'),
1485     type => {
1486         description => "Rule type.",
1487         type => 'string',
1488         optional => 1,
1489         enum => ['in', 'out', 'group'],
1490     },
1491     action => {
1492         description => "Rule action ('ACCEPT', 'DROP', 'REJECT') or security group name.",
1493         type => 'string',
1494         optional => 1,
1495         pattern => $security_group_name_pattern,
1496         maxLength => 20,
1497         minLength => 2,
1498     },
1499     macro => {
1500         description => "Use predefined standard macro.",
1501         type => 'string',
1502         optional => 1,
1503         maxLength => 128,
1504     },
1505     iface => get_standard_option('pve-iface', {
1506         description => "Network interface name. You have to use network configuration key names for VMs and containers ('net\\d+'). Host related rules can use arbitrary strings.",
1507         optional => 1
1508     }),
1509     source => {
1510         description => "Restrict packet source address. $addr_list_descr",
1511         type => 'string', format => 'pve-fw-addr-spec',
1512         optional => 1,
1513         maxLength => 512,
1514     },
1515     dest => {
1516         description => "Restrict packet destination address. $addr_list_descr",
1517         type => 'string', format => 'pve-fw-addr-spec',
1518         optional => 1,
1519         maxLength => 512,
1520     },
1521     proto => {
1522         description => "IP protocol. You can use protocol names ('tcp'/'udp') or simple numbers, as defined in '/etc/protocols'.",
1523         type => 'string', format => 'pve-fw-protocol-spec',
1524         optional => 1,
1525     },
1526     enable => {
1527         description => "Flag to enable/disable a rule.",
1528         type => 'integer',
1529         minimum => 0,
1530         optional => 1,
1531     },
1532     log => get_standard_option('pve-fw-loglevel', {
1533         description => "Log level for firewall rule.",
1534     }),
1535     sport => {
1536         description => "Restrict TCP/UDP source port. $port_descr",
1537         type => 'string', format => 'pve-fw-sport-spec',
1538         optional => 1,
1539     },
1540     dport => {
1541         description => "Restrict TCP/UDP destination port. $port_descr",
1542         type => 'string', format => 'pve-fw-dport-spec',
1543         optional => 1,
1544     },
1545     comment => {
1546         description => "Descriptive comment.",
1547         type => 'string',
1548         optional => 1,
1549     },
1550     'icmp-type' => {
1551         description => "Specify icmp-type. Only valid if proto equals 'icmp' or 'icmpv6'/'ipv6-icmp'.",
1552         type => 'string', format => 'pve-fw-icmp-type-spec',
1553         optional => 1,
1554     },
1555 };
1556
1557 sub add_rule_properties {
1558     my ($properties) = @_;
1559
1560     foreach my $k (keys %$rule_properties) {
1561         my $h = $rule_properties->{$k};
1562         # copy data, so that we can modify later without side effects
1563         foreach my $opt (keys %$h) { $properties->{$k}->{$opt} = $h->{$opt}; }
1564     }
1565
1566     return $properties;
1567 }
1568
1569 sub delete_rule_properties {
1570     my ($rule, $delete_str) = @_;
1571
1572     foreach my $opt (PVE::Tools::split_list($delete_str)) {
1573         raise_param_exc({ 'delete' => "no such property ('$opt')"})
1574             if !defined($rule_properties->{$opt});
1575         raise_param_exc({ 'delete' => "unable to delete required property '$opt'"})
1576             if $opt eq 'type' || $opt eq 'action';
1577         delete $rule->{$opt};
1578     }
1579
1580     return $rule;
1581 }
1582
1583 my $apply_macro = sub {
1584     my ($macro_name, $param, $verify, $ipversion) = @_;
1585
1586     my $macro_rules = $pve_fw_parsed_macros->{$macro_name};
1587     die "unknown macro '$macro_name'\n" if !$macro_rules; # should not happen
1588
1589     if ($ipversion && ($ipversion == 6) && $pve_ipv6fw_macros->{$macro_name}) {
1590         $macro_rules = $pve_ipv6fw_macros->{$macro_name};
1591     }
1592
1593     # skip macros which are specific to another ipversion
1594     if ($ipversion && (my $required = $pve_fw_macro_ipversion->{$macro_name})) {
1595         return if $ipversion != $required;
1596     }
1597
1598     my $rules = [];
1599
1600     foreach my $templ (@$macro_rules) {
1601         my $rule = {};
1602         my $param_used = {};
1603         foreach my $k (keys %$templ) {
1604             my $v = $templ->{$k};
1605             if ($v eq 'PARAM') {
1606                 $v = $param->{$k};
1607                 $param_used->{$k} = 1;
1608             } elsif ($v eq 'DEST') {
1609                 $v = $param->{dest};
1610                 $param_used->{dest} = 1;
1611             } elsif ($v eq 'SOURCE') {
1612                 $v = $param->{source};
1613                 $param_used->{source} = 1;
1614             }
1615
1616             if (!defined($v)) {
1617                 my $msg = "missing parameter '$k' in macro '$macro_name'";
1618                 raise_param_exc({ macro => $msg }) if $verify;
1619                 die "$msg\n";
1620             }
1621             $rule->{$k} = $v;
1622         }
1623         foreach my $k (keys %$param) {
1624             next if $k eq 'macro';
1625             next if !defined($param->{$k});
1626             next if $param_used->{$k};
1627             if (defined($rule->{$k})) {
1628                 if ($rule->{$k} ne $param->{$k}) {
1629                     my $msg = "parameter '$k' already define in macro (value = '$rule->{$k}')";
1630                     raise_param_exc({ $k => $msg }) if $verify;
1631                     die "$msg\n";
1632                 }
1633             } else {
1634                 $rule->{$k} = $param->{$k};
1635             }
1636         }
1637         push @$rules, $rule;
1638     }
1639
1640     return $rules;
1641 };
1642
1643 my $rule_env_iface_lookup = {
1644     'ct' => 1,
1645     'vm' => 1,
1646     'group' => 0,
1647     'cluster' => 1,
1648     'host' => 1,
1649 };
1650
1651 sub verify_rule {
1652     my ($rule, $cluster_conf, $fw_conf, $rule_env, $noerr) = @_;
1653
1654     my $allow_groups = $rule_env eq 'group' ? 0 : 1;
1655
1656     my $allow_iface = $rule_env_iface_lookup->{$rule_env};
1657     die "unknown rule_env '$rule_env'\n" if !defined($allow_iface); # should not happen
1658
1659     my $errors = $rule->{errors} || {};
1660
1661     my $error_count = 0;
1662
1663     my $add_error = sub {
1664         my ($param, $msg)  = @_;
1665         chomp $msg;
1666         raise_param_exc({ $param => $msg }) if !$noerr;
1667         $error_count++;
1668         $errors->{$param} = $msg if !$errors->{$param};
1669     };
1670
1671     my $ipversion;
1672     my $set_ip_version = sub {
1673         my $vers = shift;
1674         if ($vers) {
1675             die "detected mixed ipv4/ipv6 addresses in rule\n"
1676                 if $ipversion && ($vers != $ipversion);
1677             $ipversion = $vers;
1678         }
1679     };
1680
1681     my $check_ipset_or_alias_property = sub {
1682         my ($name, $expected_ipversion) = @_;
1683
1684         if (my $value = $rule->{$name}) {
1685             if ($value =~ m/^\+/) {
1686                 if ($value =~ m@^\+(guest/|dc/)?(${ipset_name_pattern})$@) {
1687                     &$add_error($name, "no such ipset '$2'")
1688                         if !($cluster_conf->{ipset}->{$2} || ($fw_conf && $fw_conf->{ipset}->{$2}));
1689
1690                 } else {
1691                     &$add_error($name, "invalid ipset name '$value'");
1692                 }
1693             } elsif ($value =~ m@^(guest/|dc/)?(${ip_alias_pattern})$@){
1694                 my $scope = $1 // "";
1695                 my $alias = lc($2);
1696                 &$add_error($name, "no such alias '$value'")
1697                     if !($cluster_conf->{aliases}->{$alias} || ($fw_conf && $fw_conf->{aliases}->{$alias}));
1698
1699                 my $e;
1700                 if ($scope ne 'dc/' && $fw_conf) {
1701                     $e = $fw_conf->{aliases}->{$alias};
1702                 }
1703                 if ($scope ne 'guest/' && !$e && $cluster_conf) {
1704                     $e = $cluster_conf->{aliases}->{$alias};
1705                 }
1706
1707                 &$set_ip_version($e->{ipversion});
1708             }
1709         }
1710     };
1711
1712     my $type = $rule->{type};
1713     my $action = $rule->{action};
1714
1715     &$add_error('type', "missing property") if !$type;
1716     &$add_error('action', "missing property") if !$action;
1717
1718     if ($type) {
1719         if ($type eq  'in' || $type eq 'out') {
1720             &$add_error('action', "unknown action '$action'")
1721                 if $action && ($action !~ m/^(ACCEPT|DROP|REJECT)$/);
1722         } elsif ($type eq 'group') {
1723             &$add_error('type', "security groups not allowed")
1724                 if !$allow_groups;
1725             &$add_error('action', "invalid characters in security group name")
1726                 if $action && ($action !~ m/^${security_group_name_pattern}$/);
1727         } else {
1728             &$add_error('type', "unknown rule type '$type'");
1729         }
1730     }
1731
1732     if ($rule->{iface}) {
1733         &$add_error('type', "parameter -i not allowed for this rule type")
1734             if !$allow_iface;
1735         eval { PVE::JSONSchema::pve_verify_iface($rule->{iface}); };
1736         &$add_error('iface', $@) if $@;
1737         if ($rule_env eq 'vm' || $rule_env eq 'ct') {
1738             &$add_error('iface', "value does not match the regex pattern 'net\\d+'")
1739                 if $rule->{iface} !~  m/^net(\d+)$/;
1740         }
1741     }
1742
1743     if ($rule->{macro}) {
1744         if (my $preferred_name = $pve_fw_preferred_macro_names->{lc($rule->{macro})}) {
1745             $rule->{macro} = $preferred_name;
1746         } else {
1747             &$add_error('macro', "unknown macro '$rule->{macro}'");
1748         }
1749     }
1750
1751     my $is_icmp = 0;
1752     if ($rule->{proto}) {
1753         eval { pve_fw_verify_protocol_spec($rule->{proto}); };
1754         &$add_error('proto', $@) if $@;
1755         &$set_ip_version(4) if $rule->{proto} eq 'icmp';
1756         &$set_ip_version(6) if $rule->{proto} eq 'icmpv6';
1757         &$set_ip_version(6) if $rule->{proto} eq 'ipv6-icmp';
1758         $is_icmp = $proto_is_icmp->($rule->{proto});
1759     }
1760
1761     if ($rule->{dport}) {
1762         eval { parse_port_name_number_or_range($rule->{dport}, $is_icmp); };
1763         &$add_error('dport', $@) if $@;
1764         my $proto = $rule->{proto};
1765         &$add_error('proto', "missing property - 'dport' requires this property")
1766             if !$proto;
1767         &$add_error('dport', "protocol '$proto' does not support ports")
1768             if !$PROTOCOLS_WITH_PORTS->{$proto} && !$is_icmp; #special cases
1769     }
1770
1771     if (my $icmp_type = $rule ->{'icmp-type'}) {
1772         my $proto = $rule->{proto};
1773         &$add_error('proto', "missing property - 'icmp-type' requires this property")
1774             if !$is_icmp;
1775         &$add_error('icmp-type', "'icmp-type' cannot be specified together with 'dport'")
1776             if $rule->{dport};
1777         if ($proto eq 'icmp' && !$icmp_type_names->{$icmp_type}) {
1778             &$add_error('icmp-type', "invalid icmp-type '$icmp_type' for proto 'icmp'");
1779         } elsif (($proto eq 'icmpv6' || $proto eq 'ipv6-icmp') && !$icmpv6_type_names->{$icmp_type}) {
1780             &$add_error('icmp-type', "invalid icmp-type '$icmp_type' for proto '$proto'");
1781         }
1782     }
1783
1784     if ($rule->{sport}) {
1785         eval { parse_port_name_number_or_range($rule->{sport}, 0); };
1786         &$add_error('sport', $@) if $@;
1787         my $proto = $rule->{proto};
1788         &$add_error('proto', "missing property - 'sport' requires this property")
1789             if !$proto;
1790         &$add_error('sport', "protocol '$proto' does not support ports")
1791             if !$PROTOCOLS_WITH_PORTS->{$proto};
1792     }
1793
1794     if ($rule->{source}) {
1795         eval {
1796             my $source_ipversion = parse_address_list($rule->{source});
1797             &$set_ip_version($source_ipversion);
1798         };
1799         &$add_error('source', $@) if $@;
1800         &$check_ipset_or_alias_property('source', $ipversion);
1801     }
1802
1803     if ($rule->{dest}) {
1804         eval {
1805             my $dest_ipversion = parse_address_list($rule->{dest});
1806             &$set_ip_version($dest_ipversion);
1807         };
1808         &$add_error('dest', $@) if $@;
1809         &$check_ipset_or_alias_property('dest', $ipversion);
1810     }
1811
1812     $rule->{ipversion} = $ipversion if $ipversion;
1813
1814     if ($rule->{macro} && !$error_count) {
1815         eval { &$apply_macro($rule->{macro}, $rule, 1, $ipversion); };
1816         if (my $err = $@) {
1817             if (ref($err) eq "PVE::Exception" && $err->{errors}) {
1818                 my $eh = $err->{errors};
1819                 foreach my $p (keys %$eh) {
1820                     &$add_error($p, $eh->{$p});
1821                 }
1822             } else {
1823                 &$add_error('macro', "$err");
1824             }
1825         }
1826     }
1827
1828     $rule->{errors} = $errors if $error_count;
1829
1830     return $rule;
1831 }
1832
1833 sub copy_rule_data {
1834     my ($rule, $param) = @_;
1835
1836     foreach my $k (keys %$rule_properties) {
1837         if (defined(my $v = $param->{$k})) {
1838             if ($v eq '' || $v eq '-') {
1839                 delete $rule->{$k};
1840             } else {
1841                 $rule->{$k} = $v;
1842             }
1843         }
1844     }
1845
1846     return $rule;
1847 }
1848
1849 sub rules_modify_permissions {
1850     my ($rule_env) = @_;
1851
1852     if ($rule_env eq 'host') {
1853         return {
1854             check => ['perm', '/nodes/{node}', [ 'Sys.Modify' ]],
1855         };
1856     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1857         return {
1858             check => ['perm', '/', [ 'Sys.Modify' ]],
1859         };
1860     } elsif ($rule_env eq 'vm' || $rule_env eq 'ct') {
1861         return {
1862             check => ['perm', '/vms/{vmid}', [ 'VM.Config.Network' ]],
1863         }
1864     }
1865
1866     return undef;
1867 }
1868
1869 sub rules_audit_permissions {
1870     my ($rule_env) = @_;
1871
1872     if ($rule_env eq 'host') {
1873         return {
1874             check => ['perm', '/nodes/{node}', [ 'Sys.Audit' ]],
1875         };
1876     } elsif ($rule_env eq 'cluster' || $rule_env eq 'group') {
1877         return {
1878             check => ['perm', '/', [ 'Sys.Audit' ]],
1879         };
1880     } elsif ($rule_env eq 'vm' || $rule_env eq 'ct') {
1881         return {
1882             check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
1883         }
1884     }
1885
1886     return undef;
1887 }
1888
1889 # core functions
1890
1891 sub enable_bridge_firewall {
1892
1893
1894     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-iptables", "1");
1895     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/bridge/bridge-nf-call-ip6tables", "1");
1896
1897     # make sure syncookies are enabled (which is default on newer 3.X kernels anyways)
1898     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/ipv4/tcp_syncookies", "1");
1899
1900 }
1901
1902 sub iptables_restore_cmdlist {
1903     my ($cmdlist, $table) = @_;
1904
1905     $table = 'filter' if !$table;
1906     run_command(['iptables-restore', '-T', $table, '-n'], input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1907 }
1908
1909 sub ip6tables_restore_cmdlist {
1910     my ($cmdlist, $table) = @_;
1911
1912     $table = 'filter' if !$table;
1913     run_command(['ip6tables-restore', '-T', $table, '-n'], input => $cmdlist, errmsg => "iptables_restore_cmdlist");
1914 }
1915
1916 sub ipset_restore_cmdlist {
1917     my ($cmdlist) = @_;
1918
1919     run_command(['ipset', 'restore'], input => $cmdlist, errmsg => "ipset_restore_cmdlist");
1920 }
1921
1922 sub ebtables_restore_cmdlist {
1923     my ($cmdlist) = @_;
1924
1925     run_command(['ebtables-restore'], input => $cmdlist, errmsg => "ebtables_restore_cmdlist");
1926 }
1927
1928 sub iptables_get_chains {
1929     my ($iptablescmd, $t) = @_;
1930
1931     $iptablescmd = "iptables" if !$iptablescmd;
1932     $t = 'filter' if !$t;
1933
1934     my $res = {};
1935
1936     # check what chains we want to track
1937     my $is_pvefw_chain = sub {
1938         my $name = shift;
1939
1940         return 1 if $name =~ m/^PVEFW-\S+$/;
1941
1942         return 1 if $name =~ m/^tap\d+i\d+-(?:IN|OUT)$/;
1943
1944         return 1 if $name =~ m/^veth\d+i\d+-(?:IN|OUT)$/;
1945
1946         return 1 if $name =~ m/^fwbr\d+(v\d+)?-(?:FW|IN|OUT|IPS)$/;
1947         return 1 if $name =~ m/^GROUP-(?:$security_group_name_pattern)-(?:IN|OUT)$/;
1948
1949         return undef;
1950     };
1951
1952     my $table = '';
1953
1954     my $hooks = {};
1955
1956     my $parser = sub {
1957         my $line = shift;
1958
1959         return if $line =~ m/^#/;
1960         return if $line =~ m/^\s*$/;
1961
1962         if ($line =~ m/^\*(\S+)$/) {
1963             $table = $1;
1964             return;
1965         }
1966
1967         return if $table ne $t;
1968
1969         if ($line =~ m/^:(\S+)\s/) {
1970             my $chain = $1;
1971             return if !&$is_pvefw_chain($chain);
1972             $res->{$chain} = "unknown";
1973         } elsif ($line =~ m/^-A\s+(\S+)\s.*--comment\s+\"PVESIG:(\S+)\"/) {
1974             my ($chain, $sig) = ($1, $2);
1975             return if !&$is_pvefw_chain($chain);
1976             $res->{$chain} = $sig;
1977         } elsif ($line =~ m/^-A\s+(INPUT|OUTPUT|FORWARD|PREROUTING)\s+-j\s+PVEFW-\1$/) {
1978             $hooks->{$1} = 1;
1979         } else {
1980             # simply ignore the rest
1981             return;
1982         }
1983     };
1984
1985     run_command(["$iptablescmd-save"], outfunc => $parser);
1986
1987     return wantarray ? ($res, $hooks) : $res;
1988 }
1989
1990 sub iptables_chain_digest {
1991     my ($rules) = @_;
1992     my $digest = Digest::SHA->new('sha1');
1993     foreach my $rule (@$rules) { # order is important
1994         $digest->add($rule);
1995     }
1996     return $digest->b64digest;
1997 }
1998
1999 sub ipset_chain_digest {
2000     my ($rules) = @_;
2001
2002     my $digest = Digest::SHA->new('sha1');
2003     foreach my $rule (sort @$rules) { # note: sorted
2004         $digest->add($rule);
2005     }
2006     return $digest->b64digest;
2007 }
2008
2009 sub ipset_get_chains {
2010
2011     my $res = {};
2012     my $chains = {};
2013
2014     my $parser = sub {
2015         my $line = shift;
2016
2017         return if $line =~ m/^#/;
2018         return if $line =~ m/^\s*$/;
2019         if ($line =~ m/^(?:\S+)\s(PVEFW-\S+)\s(?:\S+).*/) {
2020             my $chain = $1;
2021             # ignore initval from ipset v7.7+, won't set that yet so it'd mess up change detection
2022             $line =~ s/\binitval 0x[0-9a-f]+//;
2023             $line =~ s/\s+$//; # delete trailing white space
2024             push @{$chains->{$chain}}, $line;
2025         } else {
2026             # simply ignore the rest
2027             return;
2028         }
2029     };
2030
2031     run_command(['ipset', 'save'], outfunc => $parser);
2032
2033     # compute digest for each chain
2034     foreach my $chain (keys %$chains) {
2035         $res->{$chain} = ipset_chain_digest($chains->{$chain});
2036     }
2037
2038     return $res;
2039 }
2040
2041 sub ebtables_get_chains {
2042
2043     my $res = {};
2044     my $chains = {};
2045     my $table;
2046     my $parser = sub {
2047         my $line = shift;
2048         return if $line =~ m/^#/;
2049         return if $line =~ m/^\s*$/;
2050         if ($line =~ m/^\*(\S+)$/) {
2051             $table = $1;
2052             return;
2053         }
2054
2055         return if $table ne "filter";
2056
2057         if ($line =~ m/^:(\S+)\s(ACCEPT|DROP|RETURN)$/) {
2058             # Make sure we know chains exist even if they're empty.
2059             $chains->{$1} //= [];
2060             $res->{$1}->{policy} = $2;
2061         } elsif ($line =~ m/^(?:\S+)\s(\S+)\s(?:\S+).*/) {
2062             my $chain = $1;
2063             $line =~ s/\s+$//;
2064             push @{$chains->{$chain}}, $line;
2065         } else {
2066             # simply ignore the rest
2067             return;
2068         }
2069     };
2070
2071     run_command(['ebtables-save'], outfunc => $parser);
2072     # compute digest for each chain and store rules as well
2073     foreach my $chain (keys %$chains) {
2074         $res->{$chain}->{rules} = $chains->{$chain};
2075         $res->{$chain}->{sig} = iptables_chain_digest($chains->{$chain});
2076     }
2077     return $res;
2078 }
2079
2080 # substitute action of rule according to action hash
2081 sub rule_substitude_action {
2082     my ($rule, $actions) = @_;
2083
2084     if (my $action = $rule->{action}) {
2085         $rule->{action} = $actions->{$action} if defined($actions->{$action});
2086     }
2087 }
2088
2089 # generate a src or dst match
2090 # $dir(ection) is either d or s
2091 sub ipt_gen_src_or_dst_match {
2092     my ($adr, $dir, $ipversion, $cluster_conf, $fw_conf) = @_;
2093
2094     my $srcdst;
2095     if ($dir eq 's') {
2096         $srcdst = "src";
2097     } elsif ($dir eq 'd') {
2098         $srcdst = "dst";
2099     } else {
2100         die "ipt_gen_src_or_dst_match: invalid direction $dir \n";
2101     }
2102
2103     my $match;
2104     if ($adr =~ m/^\+/) {
2105         if ($adr =~ m@^\+(guest/|dc/)?(${ipset_name_pattern})$@) {
2106             my $scope = $1 // "";
2107             my $name = $2;
2108             my $ipset_chain;
2109             if ($scope ne 'dc/' && $fw_conf && $fw_conf->{ipset}->{$name}) {
2110                 $ipset_chain = compute_ipset_chain_name($fw_conf->{vmid}, $name, $ipversion);
2111             } elsif ($scope ne 'guest/' && $cluster_conf && $cluster_conf->{ipset}->{$name}) {
2112                 $ipset_chain = compute_ipset_chain_name(0, $name, $ipversion);
2113             } else {
2114                 die "no such ipset '$name'\n";
2115             }
2116             $match = "-m set --match-set ${ipset_chain} ${srcdst}";
2117         } else {
2118             die "invalid security group name '$adr'\n";
2119         }
2120     } elsif ($adr =~ m@^(dc/|guest/)?(${ip_alias_pattern})$@){
2121         my $scope = $1 // "";
2122         my $alias = lc($2);
2123         my $e;
2124         if ($scope ne 'dc/' && $fw_conf) {
2125             $e = $fw_conf->{aliases}->{$alias};
2126         }
2127         if ($scope ne 'guest/' && !$e && $cluster_conf) {
2128             $e = $cluster_conf->{aliases}->{$alias};
2129         }
2130         die "no such alias '$adr'\n" if !$e;
2131         $match = "-${dir} $e->{cidr}";
2132     } elsif ($adr =~ m/\-/){
2133         $match = "-m iprange --${srcdst}-range $adr";
2134     } else {
2135         $match = "-${dir} $adr";
2136     }
2137
2138     return $match;
2139 }
2140
2141 # convert a %rule to an array of iptables commands
2142 sub ipt_rule_to_cmds {
2143     my ($rule, $chain, $ipversion, $cluster_conf, $fw_conf, $vmid) = @_;
2144
2145     die "ipt_rule_to_cmds unable to handle macro" if $rule->{macro}; #should not happen
2146
2147     my @match = ();
2148
2149     if (defined $rule->{match}) {
2150         push @match, $rule->{match};
2151     } else {
2152         push @match, "-i $rule->{iface_in}" if $rule->{iface_in};
2153         push @match, "-o $rule->{iface_out}" if $rule->{iface_out};
2154
2155         if ($rule->{source}) {
2156             push @match, ipt_gen_src_or_dst_match($rule->{source}, 's', $ipversion, $cluster_conf, $fw_conf);
2157         }
2158         if ($rule->{dest}) {
2159             push @match, ipt_gen_src_or_dst_match($rule->{dest}, 'd', $ipversion, $cluster_conf, $fw_conf);
2160         }
2161
2162         if (my $proto = $rule->{proto}) {
2163             push @match, "-p $proto";
2164             my $is_icmp = $proto_is_icmp->($proto);
2165
2166             my $multidport = defined($rule->{dport}) && parse_port_name_number_or_range($rule->{dport}, $is_icmp);
2167             my $multisport = defined($rule->{sport}) && parse_port_name_number_or_range($rule->{sport}, 0);
2168
2169             my $add_dport = sub {
2170                 return if !defined($rule->{dport});
2171
2172                 # NOTE: we re-use dport to store --icmp-type for icmp* protocol
2173                 if ($proto eq 'icmp') {
2174                     $is_valid_icmp_type->($rule->{dport}, $icmp_type_names);
2175                     push @match, "-m icmp --icmp-type $rule->{dport}";
2176                 } elsif ($proto eq 'icmpv6') {
2177                     $is_valid_icmp_type->($rule->{dport}, $icmpv6_type_names);
2178                     push @match, "-m icmpv6 --icmpv6-type $rule->{dport}";
2179                 } elsif (!$PROTOCOLS_WITH_PORTS->{$proto}) {
2180                     die "protocol $proto does not have ports\n";
2181                 } elsif ($multidport) {
2182                     push @match, "--match multiport", "--dports $rule->{dport}";
2183                 } else {
2184                     return if !$rule->{dport};
2185                     push @match, "--dport $rule->{dport}";
2186                 }
2187             };
2188
2189             my $add_sport = sub {
2190                 return if !$rule->{sport};
2191
2192                 die "protocol $proto does not have ports\n"
2193                     if !$PROTOCOLS_WITH_PORTS->{$proto};
2194                 if ($multisport) {
2195                     push @match, "--match multiport", "--sports $rule->{sport}";
2196                 } else {
2197                     push @match, "--sport $rule->{sport}";
2198                 }
2199             };
2200
2201             my $add_icmp_type = sub {
2202                 return if !defined($rule->{'icmp-type'}) || $rule->{'icmp-type'} eq '';
2203
2204                 die "'icmp-type' can only be set if 'icmp', 'icmpv6' or 'ipv6-icmp' is specified\n"
2205                     if !$is_icmp;
2206                 my $type = $proto eq 'icmp' ? 'icmp-type' : 'icmpv6-type';
2207
2208                 push @match, "-m $proto --$type $rule->{'icmp-type'}";
2209             };
2210
2211             # order matters - single port before multiport!
2212             $add_icmp_type->();
2213             $add_dport->() if $multisport;
2214             $add_sport->();
2215             $add_dport->() if !$multisport;
2216         } elsif ($rule->{dport} || $rule->{sport}) {
2217             die "destination port '$rule->{dport}', but no protocol specified\n" if $rule->{dport};
2218             die "source port '$rule->{sport}', but no protocol specified\n" if $rule->{sport};
2219         }
2220
2221         push @match, "-m addrtype --dst-type $rule->{dsttype}" if $rule->{dsttype};
2222     }
2223     my $matchstr = scalar(@match) ? join(' ', @match) : "";
2224
2225     my $targetstr;
2226     if (defined $rule->{target}) {
2227         $targetstr = $rule->{target};
2228     } else {
2229         my $action = (defined $rule->{action}) ? $rule->{action} : "";
2230         $targetstr = $action eq 'PVEFW-SET-ACCEPT-MARK' ? "-g $action" : "-j $action";
2231     }
2232
2233     my @iptcmds;
2234     my $log = $rule->{log};
2235     if (defined($log) && $log ne 'nolog') {
2236         my $loglevel = $log_level_hash->{$log};
2237         my $logaction = get_log_rule_base($chain, $vmid, $rule->{logmsg}, $loglevel);
2238         push @iptcmds, "-A $chain $matchstr $logaction";
2239     }
2240     push @iptcmds, "-A $chain $matchstr $targetstr";
2241     return @iptcmds;
2242 }
2243
2244 sub ruleset_generate_rule {
2245     my ($ruleset, $chain, $ipversion, $rule, $cluster_conf, $fw_conf, $vmid) = @_;
2246
2247     my $rules;
2248
2249     if ($rule->{macro}) {
2250         $rules = &$apply_macro($rule->{macro}, $rule, 0, $ipversion);
2251     } else {
2252         $rules = [ $rule ];
2253     }
2254
2255     # update all or nothing
2256     my @ipt_rule_cmds;
2257     foreach my $r (@$rules) {
2258         push @ipt_rule_cmds, ipt_rule_to_cmds($r, $chain, $ipversion, $cluster_conf, $fw_conf, $vmid);
2259     }
2260     foreach my $c (@ipt_rule_cmds) {
2261         ruleset_add_ipt_cmd($ruleset, $chain, $c);
2262     }
2263 }
2264
2265 sub ruleset_create_chain {
2266     my ($ruleset, $chain) = @_;
2267
2268     die "Invalid chain name '$chain' (28 char max)\n" if length($chain) > 28;
2269     die "chain name may not contain collons\n" if $chain =~ m/:/; # because of log format
2270
2271     die "chain '$chain' already exists\n" if $ruleset->{$chain};
2272
2273     $ruleset->{$chain} = [];
2274 }
2275
2276 sub ruleset_chain_exist {
2277     my ($ruleset, $chain) = @_;
2278
2279     return $ruleset->{$chain} ? 1 : undef;
2280 }
2281
2282 # add an iptables command (like generated by ipt_rule_to_cmds) to a chain
2283 sub ruleset_add_ipt_cmd {
2284    my ($ruleset, $chain, $iptcmd) = @_;
2285
2286    die "no such chain '$chain'\n" if !$ruleset->{$chain};
2287
2288    push @{$ruleset->{$chain}}, $iptcmd;
2289 }
2290
2291 sub ruleset_addrule {
2292     my ($ruleset, $chain, $match, $action, $log, $logmsg, $vmid) = @_;
2293
2294     die "no such chain '$chain'\n" if !$ruleset->{$chain};
2295
2296     if ($log) {
2297         my $loglevel = $log_level_hash->{$log};
2298         my $logaction = get_log_rule_base($chain, $vmid, $logmsg, $loglevel);
2299         push @{$ruleset->{$chain}}, "-A $chain $match $logaction";
2300     }
2301     # for stable ebtables digests avoid double-spaces to match ebtables-save output
2302     $match .= ' ' if length($match);
2303     push @{$ruleset->{$chain}}, "-A $chain ${match}$action";
2304 }
2305
2306 sub ruleset_insertrule {
2307    my ($ruleset, $chain, $match, $action, $log) = @_;
2308
2309    die "no such chain '$chain'\n" if !$ruleset->{$chain};
2310
2311    unshift @{$ruleset->{$chain}}, "-A $chain $match $action";
2312 }
2313
2314 sub get_log_rule_base {
2315     my ($chain, $vmid, $msg, $loglevel) = @_;
2316
2317     $vmid = 0 if !defined($vmid);
2318     $msg = "" if !defined($msg);
2319
2320     my $rlimit = '';
2321     if (defined($global_log_ratelimit)) {
2322         $rlimit = "-m limit $global_log_ratelimit ";
2323     }
2324
2325     # Note: we use special format for prefix to pass further
2326     # info to log daemon (VMID, LOGLEVEL and CHAIN)
2327     return "${rlimit}-j NFLOG --nflog-prefix \":$vmid:$loglevel:$chain: $msg\"";
2328 }
2329
2330 sub ruleset_add_chain_policy {
2331     my ($ruleset, $chain, $ipversion, $vmid, $policy, $loglevel, $accept_action) = @_;
2332
2333     if ($policy eq 'ACCEPT') {
2334
2335         my $rule = { action => 'ACCEPT' };
2336         rule_substitude_action($rule, { ACCEPT =>  $accept_action});
2337         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule);
2338
2339     } elsif ($policy eq 'DROP') {
2340
2341         ruleset_addrule($ruleset, $chain, "", "-j PVEFW-Drop");
2342
2343         ruleset_addrule($ruleset, $chain, "", "-j DROP", $loglevel, "policy $policy: ", $vmid);
2344     } elsif ($policy eq 'REJECT') {
2345         ruleset_addrule($ruleset, $chain, "", "-j PVEFW-Reject");
2346
2347         ruleset_addrule($ruleset, $chain, "", "-g PVEFW-reject", $loglevel, "policy $policy: ", $vmid);
2348     } else {
2349         # should not happen
2350         die "internal error: unknown policy '$policy'";
2351     }
2352 }
2353
2354 sub ruleset_chain_add_ndp {
2355     my ($ruleset, $chain, $ipversion, $options, $direction, $accept) = @_;
2356     return if $ipversion != 6 || (defined($options->{ndp}) && !$options->{ndp});
2357
2358     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-solicitation", $accept);
2359     if ($direction ne 'OUT' || $options->{radv}) {
2360         ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-advertisement", $accept);
2361     }
2362     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type neighbor-solicitation", $accept);
2363     ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type neighbor-advertisement", $accept);
2364 }
2365
2366 sub ruleset_chain_add_conn_filters {
2367     my ($ruleset, $chain, $allow_invalid, $accept) = @_;
2368
2369     if (!$allow_invalid) {
2370         ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID", "-j DROP");
2371     }
2372     ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate RELATED,ESTABLISHED", "-j $accept");
2373 }
2374
2375 sub ruleset_chain_add_input_filters {
2376     my ($ruleset, $chain, $ipversion, $options, $cluster_conf, $loglevel) = @_;
2377
2378     if ($cluster_conf->{ipset}->{blacklist}){
2379         if (!ruleset_chain_exist($ruleset, "PVEFW-blacklist")) {
2380             ruleset_create_chain($ruleset, "PVEFW-blacklist");
2381             ruleset_addrule($ruleset, "PVEFW-blacklist", "", "-j DROP", $loglevel, "DROP: ", 0);
2382         }
2383         my $ipset_chain = compute_ipset_chain_name(0, 'blacklist', $ipversion);
2384         ruleset_addrule($ruleset, $chain, "-m set --match-set ${ipset_chain} src", "-j PVEFW-blacklist");
2385     }
2386
2387     if (!(defined($options->{nosmurfs}) && $options->{nosmurfs} == 0)) {
2388         if ($ipversion == 4) {
2389             ruleset_addrule($ruleset, $chain, "-m conntrack --ctstate INVALID,NEW", "-j PVEFW-smurfs");
2390         }
2391     }
2392
2393     if ($options->{tcpflags}) {
2394         ruleset_addrule($ruleset, $chain, "-p tcp", "-j PVEFW-tcpflags");
2395     }
2396 }
2397
2398 sub ruleset_create_vm_chain {
2399     my ($ruleset, $chain, $ipversion, $options, $macaddr, $ipfilter_ipset, $direction) = @_;
2400
2401     ruleset_create_chain($ruleset, $chain);
2402     my $accept = generate_nfqueue($options);
2403
2404     if (!(defined($options->{dhcp}) && $options->{dhcp} == 0)) {
2405         if ($ipversion == 4) {
2406             if ($direction eq 'OUT') {
2407                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2408                                       { action => 'PVEFW-SET-ACCEPT-MARK',
2409                                         proto => 'udp', sport => 68, dport => 67 });
2410             } else {
2411                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2412                                       { action => 'ACCEPT',
2413                                         proto => 'udp', sport => 67, dport => 68 });
2414             }
2415         } elsif ($ipversion == 6) {
2416             if ($direction eq 'OUT') {
2417                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2418                                       { action => 'PVEFW-SET-ACCEPT-MARK',
2419                                         proto => 'udp', sport => 546, dport => 547 });
2420             } else {
2421                 ruleset_generate_rule($ruleset, $chain, $ipversion,
2422                                       { action => 'ACCEPT',
2423                                         proto => 'udp', sport => 547, dport => 546 });
2424             }
2425         }
2426
2427     }
2428
2429     if ($direction eq 'OUT') {
2430         if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
2431             ruleset_addrule($ruleset, $chain, "-m mac ! --mac-source $macaddr", "-j DROP");
2432         }
2433         if ($ipversion == 6 && !$options->{radv}) {
2434             ruleset_addrule($ruleset, $chain, "-p icmpv6 --icmpv6-type router-advertisement", "-j DROP");
2435         }
2436         if ($ipfilter_ipset) {
2437             ruleset_addrule($ruleset, $chain, "-m set ! --match-set $ipfilter_ipset src", "-j DROP");
2438         }
2439         ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2440     }
2441
2442     my $accept_action = $direction eq 'OUT' ? '-g PVEFW-SET-ACCEPT-MARK' : "-j $accept";
2443     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, $direction, $accept_action);
2444 }
2445
2446 sub ruleset_add_group_rule {
2447     my ($ruleset, $cluster_conf, $chain, $rule, $direction, $action, $ipversion) = @_;
2448
2449     my $group = $rule->{action};
2450     my $group_chain = "GROUP-$group-$direction";
2451     if(!ruleset_chain_exist($ruleset, $group_chain)){
2452         generate_group_rules($ruleset, $cluster_conf, $group, $ipversion);
2453     }
2454
2455     if ($direction eq 'OUT' && $rule->{iface_out}) {
2456         ruleset_addrule($ruleset, $chain, "-o $rule->{iface_out}", "-j $group_chain");
2457     } elsif ($direction eq 'IN' && $rule->{iface_in}) {
2458         ruleset_addrule($ruleset, $chain, "-i $rule->{iface_in}", "-j $group_chain");
2459     } else {
2460         ruleset_addrule($ruleset, $chain, "", "-j $group_chain");
2461     }
2462
2463     ruleset_addrule($ruleset, $chain, "-m mark --mark $FWACCEPTMARK_ON", "-j $action");
2464 }
2465
2466 sub ruleset_generate_vm_rules {
2467     my ($ruleset, $rules, $cluster_conf, $vmfw_conf, $chain, $netid, $direction, $options, $ipversion, $vmid) = @_;
2468
2469     my $lc_direction = lc($direction);
2470
2471     my $in_accept = generate_nfqueue($options);
2472
2473     foreach my $rule (@$rules) {
2474         next if $rule->{iface} && $rule->{iface} ne $netid;
2475         next if !$rule->{enable} || $rule->{errors};
2476         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2477
2478         if ($rule->{type} eq 'group') {
2479             ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, $direction,
2480                                    $direction eq 'OUT' ? 'RETURN' : $in_accept, $ipversion);
2481         } else {
2482             next if $rule->{type} ne $lc_direction;
2483             eval {
2484                 $rule->{logmsg} = "$rule->{action}: ";
2485                 if ($direction eq 'OUT') {
2486                     rule_substitude_action($rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
2487                     ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $vmfw_conf, $vmid);
2488                 } else {
2489                     rule_substitude_action($rule, { ACCEPT => $in_accept , REJECT => "PVEFW-reject" });
2490                     ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $vmfw_conf, $vmid);
2491                 }
2492             };
2493             warn $@ if $@;
2494         }
2495     }
2496 }
2497
2498 sub generate_nfqueue {
2499     my ($options) = @_;
2500
2501     if ($options->{ips}) {
2502         my $action = "NFQUEUE";
2503         if ($options->{ips_queues} && $options->{ips_queues} =~ m/^(\d+)(:(\d+))?$/) {
2504             if (defined($3) && defined($1)) {
2505                 $action .= " --queue-balance $1:$3";
2506             } elsif (defined($1)) {
2507                 $action .= " --queue-num $1";
2508             }
2509         }
2510         $action .= " --queue-bypass" if $feature_ipset_nomatch; #need kernel 3.10
2511         return $action;
2512     } else {
2513         return "ACCEPT";
2514     }
2515 }
2516
2517 sub ruleset_generate_vm_ipsrules {
2518     my ($ruleset, $options, $direction, $iface) = @_;
2519
2520     if ($options->{ips} && $direction eq 'IN') {
2521         my $nfqueue = generate_nfqueue($options);
2522
2523         if (!ruleset_chain_exist($ruleset, "PVEFW-IPS")) {
2524             ruleset_create_chain($ruleset, "PVEFW-IPS");
2525         }
2526
2527         ruleset_addrule($ruleset, "PVEFW-IPS", "-m physdev --physdev-out $iface --physdev-is-bridged", "-j $nfqueue");
2528     }
2529 }
2530
2531 sub generate_tap_rules_direction {
2532     my ($ruleset, $cluster_conf, $iface, $netid, $macaddr, $vmfw_conf, $vmid, $direction, $ipversion) = @_;
2533
2534     my $lc_direction = lc($direction);
2535
2536     my $rules = $vmfw_conf->{rules};
2537
2538     my $options = $vmfw_conf->{options};
2539     my $loglevel = get_option_log_level($options, "log_level_${lc_direction}");
2540
2541     my $tapchain = "$iface-$direction";
2542
2543     my $ipfilter_name = compute_ipfilter_ipset_name($netid);
2544     my $ipfilter_ipset;
2545     $ipfilter_ipset = compute_ipset_chain_name($vmid, $ipfilter_name, $ipversion)
2546         if $options->{ipfilter} || $vmfw_conf->{ipset}->{$ipfilter_name};
2547
2548     if ($options->{enable}) {
2549         # create chain with mac and ip filter
2550         ruleset_create_vm_chain($ruleset, $tapchain, $ipversion, $options, $macaddr, $ipfilter_ipset, $direction);
2551
2552         ruleset_generate_vm_rules($ruleset, $rules, $cluster_conf, $vmfw_conf, $tapchain, $netid, $direction, $options, $ipversion, $vmid);
2553
2554         ruleset_generate_vm_ipsrules($ruleset, $options, $direction, $iface);
2555
2556         # implement policy
2557         my $policy;
2558
2559         if ($direction eq 'OUT') {
2560             $policy = $options->{policy_out} || 'ACCEPT'; # allow everything by default
2561         } else {
2562             $policy = $options->{policy_in} || 'DROP'; # allow nothing by default
2563         }
2564
2565         my $accept = generate_nfqueue($options);
2566         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : $accept;
2567         ruleset_add_chain_policy($ruleset, $tapchain, $ipversion, $vmid, $policy, $loglevel, $accept_action);
2568     } else {
2569         my $accept_action = $direction eq 'OUT' ? "PVEFW-SET-ACCEPT-MARK" : 'ACCEPT';
2570         ruleset_add_chain_policy($ruleset, $tapchain, $ipversion, $vmid, 'ACCEPT', $loglevel, $accept_action);
2571     }
2572
2573     # plug the tap chain to bridge chain
2574     if ($direction eq 'IN') {
2575         ruleset_addrule($ruleset, "PVEFW-FWBR-IN",
2576                         "-m physdev --physdev-is-bridged --physdev-out $iface", "-j $tapchain");
2577     } else {
2578         ruleset_addrule($ruleset, "PVEFW-FWBR-OUT",
2579                         "-m physdev --physdev-is-bridged --physdev-in $iface", "-j $tapchain");
2580     }
2581 }
2582
2583 sub enable_host_firewall {
2584     my ($ruleset, $hostfw_conf, $cluster_conf, $ipversion, $corosync_conf) = @_;
2585
2586     my $options = $hostfw_conf->{options};
2587     my $cluster_options = $cluster_conf->{options};
2588     my $rules = $hostfw_conf->{rules};
2589     my $cluster_rules = $cluster_conf->{rules};
2590
2591     # corosync preparation
2592     my $corosync_rule = "-p udp --dport 5404:5405";
2593     my $corosync_local_addresses = {};
2594     my $multicast_enabled;
2595     my $local_hostname = PVE::INotify::nodename();
2596     if (defined($corosync_conf)) {
2597         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2598             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2599
2600             if ($node_name eq $local_hostname) {
2601                 $corosync_local_addresses->{$key} = $node_ip;
2602             }
2603         });
2604
2605         # allow multicast only if enabled in config
2606         my $corosync_transport = $corosync_conf->{main}->{totem}->{transport};
2607         $multicast_enabled = defined($corosync_transport) && $corosync_transport eq 'udp';
2608     }
2609
2610     # host inbound firewall
2611     my $chain = "PVEFW-HOST-IN";
2612     ruleset_create_chain($ruleset, $chain);
2613
2614     my $loglevel = get_option_log_level($options, "log_level_in");
2615
2616     ruleset_addrule($ruleset, $chain, "-i lo", "-j ACCEPT");
2617
2618     ruleset_chain_add_conn_filters($ruleset, $chain, 0, 'ACCEPT');
2619     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, 'IN', '-j RETURN');
2620     ruleset_chain_add_input_filters($ruleset, $chain, $ipversion, $options, $cluster_conf, $loglevel);
2621
2622     # we use RETURN because we need to check also tap rules
2623     my $accept_action = 'RETURN';
2624
2625     ruleset_addrule($ruleset, $chain, "-p igmp", "-j $accept_action"); # important for multicast
2626
2627     # add host rules first, so that cluster wide rules can be overwritten
2628     foreach my $rule (@$rules, @$cluster_rules) {
2629         next if !$rule->{enable} || $rule->{errors};
2630         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2631
2632         $rule->{iface_in} = $rule->{iface} if $rule->{iface};
2633
2634         eval {
2635             $rule->{logmsg} = "$rule->{action}: ";
2636             if ($rule->{type} eq 'group') {
2637                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'IN', $accept_action, $ipversion);
2638             } elsif ($rule->{type} eq 'in') {
2639                 rule_substitude_action($rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
2640                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $hostfw_conf, 0);
2641             }
2642         };
2643         warn $@ if $@;
2644         delete $rule->{iface_in};
2645     }
2646
2647     # allow standard traffic for management ipset (includes cluster network)
2648     my $mngmnt_ipset_chain = compute_ipset_chain_name(0, "management", $ipversion);
2649     my $mngmntsrc = "-m set --match-set ${mngmnt_ipset_chain} src";
2650     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 8006", "-j $accept_action");  # PVE API
2651     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 5900:5999", "-j $accept_action");  # PVE VNC Console
2652     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 3128", "-j $accept_action");  # SPICE Proxy
2653     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 22", "-j $accept_action");  # SSH
2654     ruleset_addrule($ruleset, $chain, "$mngmntsrc -p tcp --dport 60000:60050", "-j $accept_action");  # Migration
2655
2656     # corosync inbound rules
2657     if (defined($corosync_conf)) {
2658         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule", "-j $accept_action")
2659             if $multicast_enabled;
2660
2661         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2662             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2663             my $destination = $corosync_local_addresses->{$key};
2664
2665             if ($node_name ne $local_hostname && defined($destination)) {
2666                 # accept only traffic on same ring
2667                 ruleset_addrule($ruleset, $chain, "-d $destination -s $node_ip $corosync_rule", "-j $accept_action");
2668             }
2669         });
2670     }
2671
2672     # implement input policy
2673     my $policy = $cluster_options->{policy_in} || 'DROP'; # allow nothing by default
2674     ruleset_add_chain_policy($ruleset, $chain, $ipversion, 0, $policy, $loglevel, $accept_action);
2675
2676     # host outbound firewall
2677     $chain = "PVEFW-HOST-OUT";
2678     ruleset_create_chain($ruleset, $chain);
2679
2680     $loglevel = get_option_log_level($options, "log_level_out");
2681
2682     ruleset_addrule($ruleset, $chain, "-o lo", "-j ACCEPT");
2683
2684     ruleset_chain_add_conn_filters($ruleset, $chain, 0, 'ACCEPT');
2685
2686     # we use RETURN because we may want to check other thigs later
2687     $accept_action = 'RETURN';
2688     ruleset_chain_add_ndp($ruleset, $chain, $ipversion, $options, 'OUT', "-j $accept_action");
2689
2690     ruleset_addrule($ruleset, $chain, "-p igmp", "-j $accept_action"); # important for multicast
2691
2692     # add host rules first, so that cluster wide rules can be overwritten
2693     foreach my $rule (@$rules, @$cluster_rules) {
2694         next if !$rule->{enable} || $rule->{errors};
2695         next if $rule->{ipversion} && ($rule->{ipversion} != $ipversion);
2696
2697         $rule->{iface_out} = $rule->{iface} if $rule->{iface};
2698         eval {
2699             $rule->{logmsg} = "$rule->{action}: ";
2700             if ($rule->{type} eq 'group') {
2701                 ruleset_add_group_rule($ruleset, $cluster_conf, $chain, $rule, 'OUT', $accept_action, $ipversion);
2702             } elsif ($rule->{type} eq 'out') {
2703                 rule_substitude_action($rule, { ACCEPT => $accept_action, REJECT => "PVEFW-reject" });
2704                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf, $hostfw_conf, 0);
2705             }
2706         };
2707         warn $@ if $@;
2708         delete $rule->{iface_out};
2709     }
2710
2711     # allow standard traffic on cluster network
2712     my $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
2713     my $localnet_ver = $cluster_conf->{aliases}->{local_network}->{ipversion};
2714
2715     if ($localnet && ($ipversion == $localnet_ver)) {
2716         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 8006", "-j $accept_action");  # PVE API
2717         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 22", "-j $accept_action");  # SSH
2718         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 5900:5999", "-j $accept_action");  # PVE VNC Console
2719         ruleset_addrule($ruleset, $chain, "-d $localnet -p tcp --dport 3128", "-j $accept_action");  # SPICE Proxy
2720     }
2721
2722     # corosync outbound rules
2723     if (defined($corosync_conf)) {
2724         ruleset_addrule($ruleset, $chain, "-m addrtype --dst-type MULTICAST $corosync_rule", "-j $accept_action")
2725             if $multicast_enabled;
2726
2727         PVE::Corosync::for_all_corosync_addresses($corosync_conf, $ipversion, sub {
2728             my ($node_name, $node_ip, $node_ipversion, $key) = @_;
2729             my $source = $corosync_local_addresses->{$key};
2730
2731             if ($node_name ne $local_hostname && defined($source)) {
2732                 # accept only traffic on same ring
2733                 ruleset_addrule($ruleset, $chain, "-s $source -d $node_ip $corosync_rule", "-j $accept_action");
2734             }
2735         });
2736     }
2737
2738     # implement output policy
2739     $policy = $cluster_options->{policy_out} || 'ACCEPT'; # allow everything by default
2740     ruleset_add_chain_policy($ruleset, $chain, $ipversion, 0, $policy, $loglevel, $accept_action);
2741
2742     ruleset_addrule($ruleset, "PVEFW-OUTPUT", "", "-j PVEFW-HOST-OUT");
2743     ruleset_addrule($ruleset, "PVEFW-INPUT", "", "-j PVEFW-HOST-IN");
2744 }
2745
2746 sub generate_group_rules {
2747     my ($ruleset, $cluster_conf, $group, $ipversion) = @_;
2748
2749     my $rules = $cluster_conf->{groups}->{$group};
2750
2751     if (!$rules) {
2752         warn "no such security group '$group'\n";
2753         $rules = []; # create empty chain
2754     }
2755
2756     my $chain = "GROUP-${group}-IN";
2757
2758     ruleset_create_chain($ruleset, $chain);
2759     ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2760
2761     foreach my $rule (@$rules) {
2762         next if $rule->{type} ne 'in';
2763         next if !$rule->{enable} || $rule->{errors};
2764         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2765         rule_substitude_action($rule, { ACCEPT => "PVEFW-SET-ACCEPT-MARK", REJECT => "PVEFW-reject" });
2766         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf);
2767     }
2768
2769     $chain = "GROUP-${group}-OUT";
2770
2771     ruleset_create_chain($ruleset, $chain);
2772     ruleset_addrule($ruleset, $chain, "", "-j MARK --set-mark $FWACCEPTMARK_OFF"); # clear mark
2773
2774     foreach my $rule (@$rules) {
2775         next if $rule->{type} ne 'out';
2776         next if !$rule->{enable} || $rule->{errors};
2777         next if $rule->{ipversion} && $rule->{ipversion} ne $ipversion;
2778         # we use PVEFW-SET-ACCEPT-MARK (Instead of ACCEPT) because we need to
2779         # check also other tap rules later
2780         rule_substitude_action($rule, { ACCEPT => 'PVEFW-SET-ACCEPT-MARK', REJECT => "PVEFW-reject" });
2781         ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, $cluster_conf);
2782     }
2783 }
2784
2785 my $MAX_NETS = 32;
2786 my $valid_netdev_names = {};
2787 for (my $i = 0; $i < $MAX_NETS; $i++)  {
2788     $valid_netdev_names->{"net$i"} = 1;
2789 }
2790
2791 sub get_mark_values {
2792     my ($value, $mask) = @_;
2793     $value = hex($value) if $value =~ /^0x/;
2794     $mask = hex($mask) if defined($mask) && $mask =~ /^0x/;
2795     $mask = 0xffffffff if !defined($mask);
2796     return ($value, $mask);
2797 }
2798
2799 sub parse_fw_rule {
2800     my ($prefix, $line, $cluster_conf, $fw_conf, $rule_env) = @_;
2801
2802     my $orig_line = $line;
2803
2804     my $rule = {};
2805
2806     # we can add single line comments to the end of the rule
2807     if ($line =~ s/#\s*(.*?)\s*$//) {
2808         $rule->{comment} = decode('utf8', $1);
2809     }
2810
2811     # we can disable a rule when prefixed with '|'
2812
2813     $rule->{enable} = $line =~ s/^\|// ? 0 : 1;
2814
2815     $line =~ s/^(\S+)\s+(\S+)\s*// ||
2816         die "unable to parse rule: $line\n";
2817
2818     $rule->{type} = lc($1);
2819     $rule->{action} = $2;
2820
2821     if ($rule->{type} eq  'in' || $rule->{type} eq 'out') {
2822         if ($rule->{action} =~ m/^(\S+)\((ACCEPT|DROP|REJECT)\)$/) {
2823             $rule->{macro} = $1;
2824             $rule->{action} = $2;
2825         }
2826     }
2827
2828     while (length($line)) {
2829         if ($line =~ s/^-i (\S+)\s*//) {
2830             $rule->{iface} = $1;
2831             next;
2832         }
2833
2834         last if $rule->{type} eq 'group';
2835
2836         if ($line =~ s/^(?:-p|--?proto) (\S+)\s*//) {
2837             $rule->{proto} = $1;
2838             next;
2839         }
2840
2841         if ($line =~ s/^--?dport (\S+)\s*//) {
2842             $rule->{dport} = $1;
2843             next;
2844         }
2845
2846         if ($line =~ s/^--?sport (\S+)\s*//) {
2847             $rule->{sport} = $1;
2848             next;
2849         }
2850         if ($line =~ s/^--?source (\S+)\s*//) {
2851             $rule->{source} = $1;
2852             next;
2853         }
2854         if ($line =~ s/^--?dest (\S+)\s*//) {
2855             $rule->{dest} = $1;
2856             next;
2857         }
2858         if ($line =~ s/^--?log (emerg|alert|crit|err|warning|notice|info|debug|nolog)\s*//) {
2859             $rule->{log} = $1;
2860             next;
2861         }
2862         if ($line =~ s/^--?icmp-type (\S+)\s*//) {
2863             $rule->{'icmp-type'} = $1;
2864             next;
2865         }
2866
2867         last;
2868     }
2869
2870     die "unable to parse rule parameters: $line\n" if length($line);
2871
2872     $rule = verify_rule($rule, $cluster_conf, $fw_conf, $rule_env, 1);
2873     if ($rule->{errors}) {
2874         # The verbose flag really means we're running from the CLI and want
2875         # output on the console - in the other case we really want such errors
2876         # to go into the syslog instead.
2877         my $log = $verbose ? sub { warn @_ } : sub { syslog(err => @_) };
2878         $log->("$prefix - errors in rule parameters: $orig_line\n");
2879         foreach my $p (keys %{$rule->{errors}}) {
2880             $log->("  $p: $rule->{errors}->{$p}\n");
2881         }
2882     }
2883
2884     return $rule;
2885 }
2886
2887 sub verify_ethertype {
2888     my ($value) = @_;
2889     my $types = get_etc_ethertypes();
2890     die "unknown ethernet protocol type: $value\n"
2891         if !defined($types->{byname}->{$value}) &&
2892            !defined($types->{byid}->{$value});
2893 }
2894
2895 sub parse_vmfw_option {
2896     my ($line) = @_;
2897
2898     my ($opt, $value);
2899
2900     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2901
2902     if ($line =~ m/^(enable|dhcp|ndp|radv|macfilter|ipfilter|ips):\s*(0|1)\s*$/i) {
2903         $opt = lc($1);
2904         $value = int($2);
2905     } elsif ($line =~ m/^(log_level_in|log_level_out):\s*(($loglevels)\s*)?$/i) {
2906         $opt = lc($1);
2907         $value = $2 ? lc($3) : '';
2908     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2909         $opt = lc($1);
2910         $value = uc($3);
2911     } elsif ($line =~ m/^(ips_queues):\s*((\d+)(:(\d+))?)\s*$/i) {
2912         $opt = lc($1);
2913         $value = $2;
2914     } elsif ($line =~ m/^(layer2_protocols):\s*(((\S+)[,]?)+)\s*$/i) {
2915         $opt = lc($1);
2916         $value = $2;
2917         verify_ethertype($_) foreach split(/\s*,\s*/, $value);
2918     } else {
2919         die "can't parse option '$line'\n"
2920     }
2921
2922     return ($opt, $value);
2923 }
2924
2925 sub parse_hostfw_option {
2926     my ($line) = @_;
2927
2928     my ($opt, $value);
2929
2930     my $loglevels = "emerg|alert|crit|err|warning|notice|info|debug|nolog";
2931
2932     if ($line =~ m/^(enable|nosmurfs|tcpflags|ndp|log_nf_conntrack|nf_conntrack_allow_invalid|protection_synflood):\s*(0|1)\s*$/i) {
2933         $opt = lc($1);
2934         $value = int($2);
2935     } elsif ($line =~ m/^(log_level_in|log_level_out|tcp_flags_log_level|smurf_log_level):\s*(($loglevels)\s*)?$/i) {
2936         $opt = lc($1);
2937         $value = $2 ? lc($3) : '';
2938     } elsif ($line =~ m/^(nf_conntrack_helpers):\s*(((\S+)[,]?)+)\s*$/i) {
2939         $opt = lc($1);
2940         $value = lc($2);
2941         pve_fw_verify_conntrack_helper($value);
2942     } elsif ($line =~ m/^(nf_conntrack_max|nf_conntrack_tcp_timeout_established|nf_conntrack_tcp_timeout_syn_recv|protection_synflood_rate|protection_synflood_burst|protection_limit):\s*(\d+)\s*$/i) {
2943         $opt = lc($1);
2944         $value = int($2);
2945     } else {
2946         die "can't parse option '$line'\n"
2947     }
2948
2949     return ($opt, $value);
2950 }
2951
2952 sub parse_clusterfw_option {
2953     my ($line) = @_;
2954
2955     my ($opt, $value);
2956
2957     if ($line =~ m/^(enable):\s*(\d+)\s*$/i) {
2958         $opt = lc($1);
2959         $value = int($2);
2960         if (($value > 1) && ((time() - $value) > 60)) {
2961             $value = 0
2962         }
2963     } elsif ($line =~ m/^(ebtables):\s*(0|1)\s*$/i) {
2964         $opt = lc($1);
2965         $value = int($2);
2966     } elsif ($line =~ m/^(policy_(in|out)):\s*(ACCEPT|DROP|REJECT)\s*$/i) {
2967         $opt = lc($1);
2968         $value = uc($3);
2969     } elsif ($line =~ m/^(log_ratelimit):\s*(\S+)\s*$/) {
2970         $opt = lc($1);
2971         $value = $2;
2972     } else {
2973         die "can't parse option '$line'\n"
2974     }
2975
2976     return ($opt, $value);
2977 }
2978
2979 sub resolve_alias {
2980     my ($clusterfw_conf, $fw_conf, $cidr, $scope) = @_;
2981
2982     my $alias = lc($cidr);
2983     my $e;
2984     if ($scope ne 'dc/' && $fw_conf) {
2985         $e = $fw_conf->{aliases}->{$alias};
2986     }
2987     if ($scope ne 'guest/' && !$e && $clusterfw_conf) {
2988         $e = $clusterfw_conf->{aliases}->{$alias};
2989     }
2990
2991     die "no such alias '$cidr'\n" if !$e;;
2992
2993     return wantarray ? ($e->{cidr}, $e->{ipversion}) : $e->{cidr};
2994 }
2995
2996 sub parse_ip_or_cidr {
2997     my ($cidr) = @_;
2998
2999     my $ipversion;
3000
3001     if ($cidr =~ m!^(?:$IPV6RE)(/(\d+))?$!) {
3002         $cidr =~ s|/128$||;
3003         $ipversion = 6;
3004     } elsif ($cidr =~ m!^(?:$IPV4RE)(/(\d+))?$!) {
3005         $cidr =~ s|/32$||;
3006         $ipversion = 4;
3007     } else {
3008         die "value does not look like a valid IP address or CIDR network\n";
3009     }
3010
3011     return wantarray ? ($cidr, $ipversion) : $cidr;
3012 }
3013
3014 sub parse_alias {
3015     my ($line) = @_;
3016
3017     # we can add single line comments to the end of the line
3018     my $comment = $line =~ s/\s*#\s*(.*?)\s*$// ? decode('utf8', $1) : undef;
3019
3020     if ($line =~ m/^(\S+)\s(\S+)$/) {
3021         my ($name, $cidr) = ($1, $2);
3022         my $ipversion;
3023
3024         ($cidr, $ipversion) = parse_ip_or_cidr($cidr);
3025
3026         my $data = {
3027             name => $name,
3028             cidr => $cidr,
3029             ipversion => $ipversion,
3030         };
3031         $data->{comment} = $comment  if $comment;
3032         return $data;
3033     }
3034
3035     return undef;
3036 }
3037
3038 sub generic_fw_config_parser {
3039     my ($filename, $cluster_conf, $empty_conf, $rule_env) = @_;
3040
3041     my $section;
3042     my $group;
3043
3044     my $res = $empty_conf;
3045
3046     my $raw;
3047     if ($filename =~ m!^/etc/pve/(.*)$!) {
3048         $raw = PVE::Cluster::get_config($1);
3049     } else {
3050         $raw = eval { PVE::Tools::file_get_contents($filename) }; # ignore errors
3051     }
3052     return {} if !$raw;
3053
3054     my $curr_group_keys = {};
3055
3056     my $linenr = 0;
3057     while ($raw =~ /^\h*(.*?)\h*$/gm) {
3058         my $line = $1;
3059         $linenr++;
3060         next if $line =~ m/^#/;
3061         next if $line =~ m/^\s*$/;
3062         chomp $line;
3063
3064         my $prefix = "$filename (line $linenr)";
3065
3066         if ($empty_conf->{options} && ($line =~ m/^\[options\]$/i)) {
3067             $section = 'options';
3068             next;
3069         }
3070
3071         if ($empty_conf->{aliases} && ($line =~ m/^\[aliases\]$/i)) {
3072             $section = 'aliases';
3073             next;
3074         }
3075
3076         if ($empty_conf->{groups} && ($line =~ m/^\[group\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
3077             $section = 'groups';
3078             $group = lc($1);
3079             my $comment = $2;
3080             eval {
3081                 die "security group name too long\n" if length($group) > $max_group_name_length;
3082                 die "invalid security group name '$group'\n" if $group !~ m/^${security_group_name_pattern}$/;
3083             };
3084             if (my $err = $@) {
3085                 ($section, $group, $comment) = undef;
3086                 warn "$prefix: $err";
3087                 next;
3088             }
3089
3090             $res->{$section}->{$group} = [];
3091             $res->{group_comments}->{$group} =  decode('utf8', $comment)
3092                 if $comment;
3093             next;
3094         }
3095
3096         if ($empty_conf->{rules} && ($line =~ m/^\[rules\]$/i)) {
3097             $section = 'rules';
3098             next;
3099         }
3100
3101         if ($empty_conf->{ipset} && ($line =~ m/^\[ipset\s+(\S+)\]\s*(?:#\s*(.*?)\s*)?$/i)) {
3102             $section = 'ipset';
3103             $group = lc($1);
3104             my $comment = $2;
3105             eval {
3106                 die "ipset name too long\n" if length($group) > $max_ipset_name_length;
3107                 die "invalid ipset name '$group'\n" if $group !~ m/^${ipset_name_pattern}$/;
3108             };
3109             if (my $err = $@) {
3110                 ($section, $group, $comment) = undef;
3111                 warn "$prefix: $err";
3112                 next;
3113             }
3114
3115             $res->{$section}->{$group} = [];
3116             $curr_group_keys = {};
3117
3118             $res->{ipset_comments}->{$group} = decode('utf8', $comment)
3119                 if $comment;
3120             next;
3121         }
3122
3123         if (!$section) {
3124             warn "$prefix: skip line - no section\n";
3125             next;
3126         }
3127
3128         if ($section eq 'options') {
3129             eval {
3130                 my ($opt, $value);
3131                 if ($rule_env eq 'cluster') {
3132                     ($opt, $value) = parse_clusterfw_option($line);
3133                 } elsif ($rule_env eq 'host') {
3134                     ($opt, $value) = parse_hostfw_option($line);
3135                 } else {
3136                     ($opt, $value) = parse_vmfw_option($line);
3137                 }
3138                 $res->{options}->{$opt} = $value;
3139             };
3140             warn "$prefix: $@" if $@;
3141         } elsif ($section eq 'aliases') {
3142             eval {
3143                 my $data = parse_alias($line);
3144                 $res->{aliases}->{lc($data->{name})} = $data;
3145             };
3146             warn "$prefix: $@" if $@;
3147         } elsif ($section eq 'rules') {
3148             my $rule;
3149             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, $res, $rule_env); };
3150             if (my $err = $@) {
3151                 warn "$prefix: $err";
3152                 next;
3153             }
3154             push @{$res->{$section}}, $rule;
3155         } elsif ($section eq 'groups') {
3156             my $rule;
3157             eval { $rule = parse_fw_rule($prefix, $line, $cluster_conf, undef, 'group'); };
3158             if (my $err = $@) {
3159                 warn "$prefix: $err";
3160                 next;
3161             }
3162             push @{$res->{$section}->{$group}}, $rule;
3163         } elsif ($section eq 'ipset') {
3164             # we can add single line comments to the end of the rule
3165             my $comment = $line =~ s/#\s*(.*?)\s*$// ? decode('utf8', $1) : undef;
3166
3167             $line =~ m/^(\!)?\s*(\S+)\s*$/;
3168             my $nomatch = $1;
3169             my $cidr = $2;
3170             my $errors;
3171
3172             if ($nomatch && !$feature_ipset_nomatch) {
3173                 $errors->{nomatch} = "nomatch not supported by kernel";
3174             }
3175
3176             eval {
3177                 if ($cidr =~ m@^(dc/|guest/)?(${ip_alias_pattern}$)@) {
3178                     my $scope = $1 // "";
3179                     my $alias = $2;
3180                     resolve_alias($cluster_conf, $res, $alias, $scope); # make sure alias exists
3181                 } else {
3182                     $cidr = parse_ip_or_cidr($cidr);
3183                 }
3184                 die "duplicate ipset entry for '$cidr'\n"
3185                     if defined($curr_group_keys->{$cidr});
3186             };
3187             if (my $err = $@) {
3188                 chomp $err;
3189                 $errors->{cidr} = $err;
3190             }
3191
3192             if ($cidr =~ m!/0+$!) {
3193                 $errors->{cidr} = "a zero prefix is not allowed in ipset entries\n";
3194             }
3195
3196             my $entry = { cidr => $cidr };
3197             $entry->{nomatch} = 1 if $nomatch;
3198             $entry->{comment} = $comment if $comment;
3199             $entry->{errors} =  $errors if $errors;
3200
3201             if ($verbose && $errors) {
3202                 warn "$prefix - errors in ipset '$group': $line\n";
3203                 foreach my $p (keys %{$errors}) {
3204                     warn "  $p: $errors->{$p}\n";
3205                 }
3206             }
3207
3208             push @{$res->{$section}->{$group}}, $entry;
3209             $curr_group_keys->{$cidr} = 1;
3210         } else {
3211             warn "$prefix: skip line - unknown section\n";
3212             next;
3213         }
3214     }
3215
3216     return $res;
3217 }
3218
3219 # this is only used to prevent concurrent runs of rule compilation/application
3220 # see lock_*_conf for cfs locks protectiong config modification
3221 sub run_locked {
3222     my ($code, @param) = @_;
3223
3224     my $timeout = 10;
3225
3226     my $res = lock_file($pve_fw_lock_filename, $timeout, $code, @param);
3227
3228     die $@ if $@;
3229
3230     return $res;
3231 }
3232
3233 sub read_local_vm_config {
3234
3235     my $qemu = {};
3236     my $lxc = {};
3237
3238     my $vmdata = { qemu => $qemu, lxc => $lxc };
3239
3240     my $vmlist = PVE::Cluster::get_vmlist();
3241     return $vmdata if !$vmlist || !$vmlist->{ids};
3242     my $ids = $vmlist->{ids};
3243
3244     foreach my $vmid (keys %$ids) {
3245         next if !$vmid; # skip VE0
3246         my $d = $ids->{$vmid};
3247         next if !$d->{node} || $d->{node} ne $nodename;
3248         next if !$d->{type};
3249         if ($d->{type} eq 'qemu') {
3250             if ($have_qemu_server) {
3251                 my $cfspath = PVE::QemuConfig->cfs_config_path($vmid);
3252                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
3253                     $qemu->{$vmid} = $conf;
3254                 }
3255             }
3256         } elsif ($d->{type} eq 'lxc') {
3257             if ($have_lxc) {
3258                 my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
3259                 if (my $conf = PVE::Cluster::cfs_read_file($cfspath)) {
3260                     $lxc->{$vmid} = $conf;
3261                 }
3262             }
3263         }
3264     }
3265
3266     return $vmdata;
3267 };
3268
3269 # FIXME: move use sites over to moved helper and break older packages, then remove this here
3270 sub lock_vmfw_conf {
3271     return PVE::Firewall::Helpers::lock_vmfw_conf(@_);
3272 }
3273
3274 sub load_vmfw_conf {
3275     my ($cluster_conf, $rule_env, $vmid, $dir) = @_;
3276
3277     $dir = $pvefw_conf_dir if !defined($dir);
3278     my $filename = "$dir/$vmid.fw";
3279
3280     my $empty_conf = {
3281         rules => [],
3282         options => {},
3283         aliases => {},
3284         ipset => {} ,
3285         ipset_comments => {},
3286     };
3287
3288     my $vmfw_conf = generic_fw_config_parser($filename, $cluster_conf, $empty_conf, $rule_env);
3289     $vmfw_conf->{vmid} = $vmid;
3290
3291     return $vmfw_conf;
3292 }
3293
3294 my $format_rules = sub {
3295     my ($rules, $allow_iface) = @_;
3296
3297     my $raw = '';
3298
3299     foreach my $rule (@$rules) {
3300         if ($rule->{type} eq  'in' || $rule->{type} eq 'out' || $rule->{type} eq 'group') {
3301             $raw .= '|' if defined($rule->{enable}) && !$rule->{enable};
3302             $raw .= uc($rule->{type});
3303             if ($rule->{macro}) {
3304                 $raw .= " $rule->{macro}($rule->{action})";
3305             } else {
3306                 $raw .= " " . $rule->{action};
3307             }
3308             if ($allow_iface && $rule->{iface}) {
3309                 $raw .= " -i $rule->{iface}";
3310             }
3311
3312             if ($rule->{type} ne  'group')  {
3313                 $raw .= " -source $rule->{source}" if $rule->{source};
3314                 $raw .= " -dest $rule->{dest}" if $rule->{dest};
3315                 $raw .= " -p $rule->{proto}" if $rule->{proto};
3316                 $raw .= " -dport $rule->{dport}" if $rule->{dport};
3317                 $raw .= " -sport $rule->{sport}" if $rule->{sport};
3318                 $raw .= " -log $rule->{log}" if $rule->{log};
3319                 $raw .= " -icmp-type $rule->{'icmp-type'}" if defined($rule->{'icmp-type'}) && $rule->{'icmp-type'} ne '';
3320             }
3321
3322             $raw .= " # " . encode('utf8', $rule->{comment})
3323                 if $rule->{comment} && $rule->{comment} !~ m/^\s*$/;
3324             $raw .= "\n";
3325         } else {
3326             die "unknown rule type '$rule->{type}'";
3327         }
3328     }
3329
3330     return $raw;
3331 };
3332
3333 my $format_options = sub {
3334     my ($options) = @_;
3335
3336     my $raw = '';
3337
3338     $raw .= "[OPTIONS]\n\n";
3339     foreach my $opt (keys %$options) {
3340         $raw .= "$opt: $options->{$opt}\n";
3341     }
3342     $raw .= "\n";
3343
3344     return $raw;
3345 };
3346
3347 my $format_aliases = sub {
3348     my ($aliases) = @_;
3349
3350     my $raw = '';
3351
3352     $raw .= "[ALIASES]\n\n";
3353     foreach my $k (keys %$aliases) {
3354         my $e = $aliases->{$k};
3355         $raw .= "$e->{name} $e->{cidr}";
3356         $raw .= " # " . encode('utf8', $e->{comment})
3357             if $e->{comment} && $e->{comment} !~ m/^\s*$/;
3358         $raw .= "\n";
3359     }
3360     $raw .= "\n";
3361
3362     return $raw;
3363 };
3364
3365 my $format_ipsets = sub {
3366     my ($fw_conf) = @_;
3367
3368     my $raw = '';
3369
3370     foreach my $ipset (sort keys %{$fw_conf->{ipset}}) {
3371         if (my $comment = $fw_conf->{ipset_comments}->{$ipset}) {
3372             my $utf8comment = encode('utf8', $comment);
3373             $raw .= "[IPSET $ipset] # $utf8comment\n\n";
3374         } else {
3375             $raw .= "[IPSET $ipset]\n\n";
3376         }
3377         my $options = $fw_conf->{ipset}->{$ipset};
3378
3379         my $nethash = {};
3380         foreach my $entry (@$options) {
3381             my $cidr = $entry->{cidr};
3382             if (defined($nethash->{$cidr})) {
3383                 warn "ignoring duplicate ipset entry '$cidr'\n";
3384                 next;
3385             }
3386
3387             $nethash->{$cidr} = $entry;
3388         }
3389
3390         foreach my $cidr (sort keys %$nethash) {
3391             my $entry = $nethash->{$cidr};
3392             my $line = $entry->{nomatch} ? '!' : '';
3393             $line .= $entry->{cidr};
3394             $line .= " # " . encode('utf8', $entry->{comment})
3395                 if $entry->{comment} && $entry->{comment} !~ m/^\s*$/;
3396             $raw .= "$line\n";
3397         }
3398
3399         $raw .= "\n";
3400     }
3401
3402     return $raw;
3403 };
3404
3405 sub save_vmfw_conf {
3406     my ($vmid, $vmfw_conf) = @_;
3407
3408     my $raw = '';
3409
3410     my $options = $vmfw_conf->{options};
3411     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3412
3413     my $aliases = $vmfw_conf->{aliases};
3414     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
3415
3416     $raw .= &$format_ipsets($vmfw_conf) if $vmfw_conf->{ipset};
3417
3418     my $rules = $vmfw_conf->{rules} || [];
3419     if ($rules && scalar(@$rules)) {
3420         $raw .= "[RULES]\n\n";
3421         $raw .= &$format_rules($rules, 1);
3422         $raw .= "\n";
3423     }
3424
3425     my $filename = "$pvefw_conf_dir/$vmid.fw";
3426     if ($raw) {
3427         mkdir $pvefw_conf_dir;
3428         PVE::Tools::file_set_contents($filename, $raw);
3429     } else {
3430         unlink $filename;
3431     }
3432 }
3433
3434 # FIXME: remove with 8.0 and break older qemu-server/pve-container
3435 sub remove_vmfw_conf {
3436     return PVE::Firewall::Helpers::remove_vmfw_conf(@_);
3437 }
3438
3439 # FIXME: remove with 8.0 and break older qemu-server/pve-container
3440 sub clone_vmfw_conf {
3441     return PVE::Firewall::Helpers::clone_vmfw_conf(@_);
3442 }
3443
3444 sub read_vm_firewall_configs {
3445     my ($cluster_conf, $vmdata, $dir) = @_;
3446
3447     my $vmfw_configs = {};
3448
3449     foreach my $vmid (keys %{$vmdata->{qemu}}) {
3450         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'vm', $vmid, $dir);
3451         next if !$vmfw_conf->{options}; # skip if file does not exist
3452         $vmfw_configs->{$vmid} = $vmfw_conf;
3453     }
3454     foreach my $vmid (keys %{$vmdata->{lxc}}) {
3455         my $vmfw_conf = load_vmfw_conf($cluster_conf, 'ct', $vmid, $dir);
3456         next if !$vmfw_conf->{options}; # skip if file does not exist
3457         $vmfw_configs->{$vmid} = $vmfw_conf;
3458     }
3459
3460     return $vmfw_configs;
3461 }
3462
3463 sub get_option_log_level {
3464     my ($options, $k) = @_;
3465
3466     my $v = $options->{$k};
3467     $v = $default_log_level if !defined($v);
3468
3469     return undef if $v eq '' || $v eq 'nolog';
3470
3471     return $v if defined($log_level_hash->{$v});
3472
3473     warn "unknown log level ($k = '$v')\n";
3474
3475     return undef;
3476 }
3477
3478 sub generate_std_chains {
3479     my ($ruleset, $options, $ipversion) = @_;
3480
3481     my $std_chains = $pve_std_chains->{$ipversion} || die "internal error";
3482
3483     my $loglevel = get_option_log_level($options, 'smurf_log_level');
3484     my $chain = 'PVEFW-smurflog';
3485     if ( $std_chains->{$chain} ) {
3486         foreach my $r (@{$std_chains->{$chain}}) {
3487           $r->{log} = $loglevel;
3488         }
3489     }
3490
3491     # same as shorewall logflags action.
3492     $loglevel = get_option_log_level($options, 'tcp_flags_log_level');
3493     $chain = 'PVEFW-logflags';
3494     if ( $std_chains->{$chain} ) {
3495         foreach my $r (@{$std_chains->{$chain}}) {
3496           $r->{log} = $loglevel;
3497         }
3498     }
3499
3500     foreach my $chain (keys %$std_chains) {
3501         ruleset_create_chain($ruleset, $chain);
3502         foreach my $rule (@{$std_chains->{$chain}}) {
3503             if (ref($rule)) {
3504                 ruleset_generate_rule($ruleset, $chain, $ipversion, $rule, 0);
3505             } else {
3506                 die "rule $rule as string - should not happen";
3507             }
3508         }
3509     }
3510 }
3511
3512 sub generate_ipset_chains {
3513     my ($ipset_ruleset, $clusterfw_conf, $fw_conf, $device_ips, $ipsets) = @_;
3514
3515     foreach my $ipset (keys %{$ipsets}) {
3516
3517         my $options = $ipsets->{$ipset};
3518
3519         if ($device_ips && $ipset =~ /^ipfilter-(net\d+)$/) {
3520             if (my $ips = $device_ips->{$1}) {
3521                 $options = [@$options, @$ips];
3522             }
3523         }
3524
3525         # remove duplicates
3526         my $nethash = {};
3527         foreach my $entry (@$options) {
3528             next if $entry->{errors}; # skip entries with errors
3529             eval {
3530                 my ($cidr, $ver);
3531                 if ($entry->{cidr} =~ m@^(dc/|guest/)?(${ip_alias_pattern})$@) {
3532                     my $scope = $1 // "";
3533                     my $alias = $2;
3534                     ($cidr, $ver) = resolve_alias($clusterfw_conf, $fw_conf, $alias, $scope);
3535                 } else {
3536                     ($cidr, $ver) = parse_ip_or_cidr($entry->{cidr});
3537                 }
3538                 #http://backreference.org/2013/03/01/ipv6-address-normalization/
3539                 if ($ver == 6) {
3540                     # ip_compress_address takes an address only, no CIDR
3541                     my ($addr, $prefix_len) = ($cidr =~ m@^([^/]*)(/.*)?$@);
3542                     $cidr = lc(Net::IP::ip_compress_address($addr, 6));
3543                     $cidr .= $prefix_len if defined($prefix_len);
3544                     $cidr =~ s|/128$||;
3545                 } else {
3546                     $cidr =~ s|/32$||;
3547                 }
3548
3549                 $nethash->{$ver}->{$cidr} = { cidr => $cidr, nomatch => $entry->{nomatch} };
3550             };
3551             warn $@ if $@;
3552         }
3553
3554         foreach my $ipversion (4, 6) {
3555             my $data = $nethash->{$ipversion};
3556
3557             my $name = compute_ipset_chain_name($fw_conf->{vmid}, $ipset, $ipversion);
3558
3559             my $hashsize = scalar(@$options);
3560             if ($hashsize <= 64) {
3561                 $hashsize = 64;
3562             } else {
3563                 $hashsize = round_powerof2($hashsize);
3564             }
3565
3566             my $bucketsize = 12; # lower than the default of 14, faster but slightly more memory use
3567
3568             my $family = $ipversion == "6" ? "inet6" : "inet";
3569
3570             $ipset_ruleset->{$name} = [
3571                 "create $name hash:net family $family hashsize $hashsize maxelem $hashsize bucketsize $bucketsize"
3572             ];
3573
3574             foreach my $cidr (sort keys %$data) {
3575                 my $entry = $data->{$cidr};
3576
3577                 my $cmd = "add $name $cidr";
3578                 if ($entry->{nomatch}) {
3579                     if ($feature_ipset_nomatch) {
3580                         push @{$ipset_ruleset->{$name}}, "$cmd nomatch";
3581                     } else {
3582                         warn "ignore !$cidr - nomatch not supported by kernel\n";
3583                     }
3584                 } else {
3585                     push @{$ipset_ruleset->{$name}}, $cmd;
3586                 }
3587             }
3588         }
3589     }
3590 }
3591
3592 sub round_powerof2 {
3593     my ($int) = @_;
3594
3595     $int--;
3596     $int |= $int >> $_ foreach (1,2,4,8,16);
3597     return ++$int;
3598 }
3599
3600 my $set_global_log_ratelimit = sub {
3601     my $cluster_opts = shift;
3602
3603     $global_log_ratelimit = '--limit 1/sec';
3604     if (defined(my $log_rlimit = $cluster_opts->{log_ratelimit})) {
3605         my $ll_format = $cluster_option_properties->{log_ratelimit}->{format};
3606         my $limit = PVE::JSONSchema::parse_property_string($ll_format, $log_rlimit);
3607
3608         if ($limit->{enable}) {
3609             if (my $rate = $limit->{rate}) {
3610                 $global_log_ratelimit = "--limit $rate";
3611             }
3612             if (my $burst = $limit->{burst}) {
3613                 $global_log_ratelimit .= " --limit-burst $burst";
3614             }
3615         } else {
3616             $global_log_ratelimit = undef;
3617         }
3618     }
3619 };
3620
3621 sub lock_clusterfw_conf {
3622     my ($timeout, $code, @param) = @_;
3623
3624     my $res = PVE::Cluster::cfs_lock_firewall("cluster", $timeout, $code, @param);
3625     die $@ if $@;
3626
3627     return $res;
3628 }
3629
3630 sub load_clusterfw_conf {
3631     my ($filename) = @_;
3632
3633     $filename = $clusterfw_conf_filename if !defined($filename);
3634     my $empty_conf = {
3635         rules => [],
3636         options => {},
3637         aliases => {},
3638         groups => {},
3639         group_comments => {},
3640         ipset => {} ,
3641         ipset_comments => {},
3642     };
3643
3644     my $cluster_conf = generic_fw_config_parser($filename, $empty_conf, $empty_conf, 'cluster');
3645     $set_global_log_ratelimit->($cluster_conf->{options});
3646
3647     return $cluster_conf;
3648 }
3649
3650 sub save_clusterfw_conf {
3651     my ($cluster_conf) = @_;
3652
3653     my $raw = '';
3654
3655     my $options = $cluster_conf->{options};
3656     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3657
3658     my $aliases = $cluster_conf->{aliases};
3659     $raw .= &$format_aliases($aliases) if $aliases && scalar(keys %$aliases);
3660
3661     $raw .= &$format_ipsets($cluster_conf) if $cluster_conf->{ipset};
3662
3663     my $rules = $cluster_conf->{rules};
3664     if ($rules && scalar(@$rules)) {
3665         $raw .= "[RULES]\n\n";
3666         $raw .= &$format_rules($rules, 1);
3667         $raw .= "\n";
3668     }
3669
3670     if ($cluster_conf->{groups}) {
3671         foreach my $group (sort keys %{$cluster_conf->{groups}}) {
3672             my $rules = $cluster_conf->{groups}->{$group};
3673             if (my $comment = $cluster_conf->{group_comments}->{$group}) {
3674                 my $utf8comment = encode('utf8', $comment);
3675                 $raw .= "[group $group] # $utf8comment\n\n";
3676             } else {
3677                 $raw .= "[group $group]\n\n";
3678             }
3679
3680             $raw .= &$format_rules($rules, 0);
3681             $raw .= "\n";
3682         }
3683     }
3684
3685     if ($raw) {
3686         mkdir $pvefw_conf_dir;
3687         PVE::Tools::file_set_contents($clusterfw_conf_filename, $raw);
3688     } else {
3689         unlink $clusterfw_conf_filename;
3690     }
3691 }
3692
3693 sub lock_hostfw_conf : prototype($$$@) {
3694     my ($node, $timeout, $code, @param) = @_;
3695
3696     $node = $nodename if !defined($node);
3697
3698     my $res = PVE::Cluster::cfs_lock_firewall("host-$node", $timeout, $code, @param);
3699     die $@ if $@;
3700
3701     return $res;
3702 }
3703
3704 sub load_hostfw_conf {
3705     my ($cluster_conf, $filename) = @_;
3706
3707     $filename = $hostfw_conf_filename if !defined($filename);
3708
3709     my $empty_conf = { rules => [], options => {}};
3710     return generic_fw_config_parser($filename, $cluster_conf, $empty_conf, 'host');
3711 }
3712
3713 sub save_hostfw_conf {
3714     my ($hostfw_conf, $filename) = @_;
3715
3716     $filename = $hostfw_conf_filename if !defined($filename);
3717
3718     my $raw = '';
3719
3720     my $options = $hostfw_conf->{options};
3721     $raw .= &$format_options($options) if $options && scalar(keys %$options);
3722
3723     my $rules = $hostfw_conf->{rules};
3724     if ($rules && scalar(@$rules)) {
3725         $raw .= "[RULES]\n\n";
3726         $raw .= &$format_rules($rules, 1);
3727         $raw .= "\n";
3728     }
3729
3730     if ($raw) {
3731         PVE::Tools::file_set_contents($filename, $raw);
3732     } else {
3733         unlink $filename;
3734     }
3735 }
3736
3737 sub compile {
3738     my ($cluster_conf, $hostfw_conf, $vmdata, $corosync_conf) = @_;
3739
3740     my $vmfw_configs;
3741
3742     # fixme: once we read standard chains from config this needs to be put in test/standard cases below
3743     $pve_std_chains = dclone($pve_std_chains_conf);
3744
3745     if ($vmdata) { # test mode
3746         my $testdir = $vmdata->{testdir} || die "no test directory specified";
3747         my $filename = "$testdir/cluster.fw";
3748         $cluster_conf = load_clusterfw_conf($filename);
3749
3750         $filename = "$testdir/host.fw";
3751         $hostfw_conf = load_hostfw_conf($cluster_conf, $filename);
3752
3753         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, $testdir);
3754     } else { # normal operation
3755         $cluster_conf = load_clusterfw_conf(undef) if !$cluster_conf;
3756
3757         $hostfw_conf = load_hostfw_conf($cluster_conf, undef) if !$hostfw_conf;
3758
3759         # cfs_update is handled by daemon or API
3760         $corosync_conf = PVE::Cluster::cfs_read_file("corosync.conf")
3761             if !defined($corosync_conf) && PVE::Corosync::check_conf_exists(1);
3762
3763         $vmdata = read_local_vm_config();
3764         $vmfw_configs = read_vm_firewall_configs($cluster_conf, $vmdata, undef);
3765     }
3766
3767     return ({},{},{},{}) if !$cluster_conf->{options}->{enable};
3768
3769     my $localnet;
3770     if ($cluster_conf->{aliases}->{local_network}) {
3771         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
3772     } else {
3773         my $localnet_ver;
3774         ($localnet, $localnet_ver) = parse_ip_or_cidr(local_network() || '127.0.0.0/8');
3775
3776         $cluster_conf->{aliases}->{local_network} = {
3777             name => 'local_network', cidr => $localnet, ipversion => $localnet_ver };
3778     }
3779
3780     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
3781
3782     my $ruleset = {};
3783     my $rulesetv6 = {};
3784     $ruleset->{filter} = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 4);
3785     $ruleset->{raw} = compile_iptables_raw($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 4);
3786     $rulesetv6->{filter} = compile_iptables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 6);
3787     $rulesetv6->{raw} = compile_iptables_raw($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, 6);
3788     my $ebtables_ruleset = compile_ebtables_filter($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata);
3789     my $ipset_ruleset = compile_ipsets($cluster_conf, $vmfw_configs, $vmdata);
3790
3791     return ($ruleset, $ipset_ruleset, $rulesetv6, $ebtables_ruleset);
3792 }
3793
3794 sub compile_iptables_raw {
3795     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, $ipversion) = @_;
3796
3797     my $ruleset = {};
3798
3799     my $hostfw_options = $hostfw_conf->{options} || {};
3800     my $protection_synflood = $hostfw_options->{protection_synflood} || 0;
3801     my $conntrack_helpers = $hostfw_options->{nf_conntrack_helpers} || '';
3802
3803     ruleset_create_chain($ruleset, "PVEFW-PREROUTING") if $protection_synflood != 0 || $conntrack_helpers ne '';
3804
3805     if($protection_synflood) {
3806
3807         my $protection_synflood_rate = $hostfw_options->{protection_synflood_rate} ? $hostfw_options->{protection_synflood_rate} : 200;
3808         my $protection_synflood_burst = $hostfw_options->{protection_synflood_burst} ? $hostfw_options->{protection_synflood_burst} : 1000;
3809         my $protection_synflood_limit = $hostfw_options->{protection_synflood_limit} ? $hostfw_options->{protection_synflood_limit} : 3000;
3810         my $protection_synflood_expire = $hostfw_options->{nf_conntrack_tcp_timeout_syn_recv} ? $hostfw_options->{nf_conntrack_tcp_timeout_syn_recv} : 60;
3811         $protection_synflood_expire = $protection_synflood_expire * 1000;
3812         my $protection_synflood_mask = $ipversion == 4 ? 32 : 64;
3813
3814         ruleset_addrule($ruleset, "PVEFW-PREROUTING", "-p tcp -m tcp --tcp-flags FIN,SYN,RST,ACK SYN -m hashlimit --hashlimit-above $protection_synflood_rate/sec --hashlimit-burst $protection_synflood_burst --hashlimit-mode srcip --hashlimit-name syn --hashlimit-htable-size 2097152 --hashlimit-srcmask $protection_synflood_mask --hashlimit-htable-expire $protection_synflood_expire", "-j DROP");
3815     }
3816
3817     foreach my $conntrack_helper (split(/,/, $conntrack_helpers)) {
3818         my $helper = $pve_fw_helpers->{$conntrack_helper};
3819         ruleset_addrule($ruleset, "PVEFW-PREROUTING", "-p $helper->{proto} -m $helper->{proto} --dport $helper->{dport} -j CT", "--helper $conntrack_helper") if $helper && $helper->{"v$ipversion"};
3820     }
3821
3822     return $ruleset;
3823 }
3824
3825 sub compile_iptables_filter {
3826     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata, $corosync_conf, $ipversion) = @_;
3827
3828     my $ruleset = {};
3829
3830     ruleset_create_chain($ruleset, "PVEFW-INPUT");
3831     ruleset_create_chain($ruleset, "PVEFW-OUTPUT");
3832
3833     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
3834
3835     my $hostfw_options = $hostfw_conf->{options} || {};
3836
3837     # fixme: what log level should we use here?
3838     my $loglevel = get_option_log_level($hostfw_options, "log_level_out");
3839
3840     my $conn_allow_invalid = $hostfw_options->{nf_conntrack_allow_invalid} // 0;
3841     ruleset_chain_add_conn_filters($ruleset, "PVEFW-FORWARD", $conn_allow_invalid, "ACCEPT");
3842
3843     ruleset_create_chain($ruleset, "PVEFW-FWBR-IN");
3844     ruleset_chain_add_input_filters($ruleset, "PVEFW-FWBR-IN", $ipversion, $hostfw_options, $cluster_conf, $loglevel);
3845
3846     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-in fwln+", "-j PVEFW-FWBR-IN");
3847
3848     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
3849     ruleset_addrule($ruleset, "PVEFW-FORWARD", "-m physdev --physdev-is-bridged --physdev-out fwln+", "-j PVEFW-FWBR-OUT");
3850
3851     generate_std_chains($ruleset, $hostfw_options, $ipversion);
3852
3853     my $hostfw_enable = !(defined($hostfw_options->{enable}) && ($hostfw_options->{enable} == 0));
3854
3855     if ($hostfw_enable) {
3856         eval { enable_host_firewall($ruleset, $hostfw_conf, $cluster_conf, $ipversion, $corosync_conf); };
3857         warn $@ if $@; # just to be sure - should not happen
3858     }
3859
3860     # generate firewall rules for QEMU VMs
3861     foreach my $vmid (sort keys %{$vmdata->{qemu}}) {
3862         eval {
3863             my $conf = $vmdata->{qemu}->{$vmid};
3864             my $vmfw_conf = $vmfw_configs->{$vmid};
3865             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
3866
3867             foreach my $netid (sort keys %$conf) {
3868                 next if $netid !~ m/^net(\d+)$/;
3869                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3870                 next if !$net->{firewall};
3871
3872                 my $iface = "tap${vmid}i$1";
3873                 my $macaddr = $net->{macaddr};
3874                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3875                                              $vmfw_conf, $vmid, 'IN', $ipversion);
3876                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3877                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
3878             }
3879         };
3880         warn $@ if $@; # just to be sure - should not happen
3881     }
3882
3883     # generate firewall rules for LXC containers
3884     foreach my $vmid (sort keys %{$vmdata->{lxc}}) {
3885         eval {
3886             my $conf = $vmdata->{lxc}->{$vmid};
3887             my $vmfw_conf = $vmfw_configs->{$vmid};
3888             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
3889
3890             foreach my $netid (sort keys %$conf) {
3891                 next if $netid !~ m/^net(\d+)$/;
3892                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
3893                 next if !$net->{firewall};
3894
3895                 my $iface = "veth${vmid}i$1";
3896                 my $macaddr = $net->{hwaddr};
3897                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3898                                              $vmfw_conf, $vmid, 'IN', $ipversion);
3899                 generate_tap_rules_direction($ruleset, $cluster_conf, $iface, $netid, $macaddr,
3900                                              $vmfw_conf, $vmid, 'OUT', $ipversion);
3901             }
3902         };
3903         warn $@ if $@; # just to be sure - should not happen
3904     }
3905
3906     if (ruleset_chain_exist($ruleset, "PVEFW-IPS")){
3907         ruleset_insertrule($ruleset, "PVEFW-FORWARD", "-m conntrack --ctstate RELATED,ESTABLISHED", "-j PVEFW-IPS");
3908     }
3909
3910     return $ruleset;
3911 }
3912
3913 sub mac_to_linklocal {
3914     my ($macaddr) = @_;
3915     my @parts = split(/:/, $macaddr);
3916     # The standard link local address uses the fe80::/64 prefix with the
3917     # modified EUI-64 identifier derived from the MAC address by flipping the
3918     # universal/local bit and inserting FF:FE in the middle.
3919     # See RFC 4291.
3920     $parts[0] = sprintf("%02x", hex($parts[0]) ^ 0x02);
3921     my @meui64 = (@parts[0,1,2], 'ff', 'fe', @parts[3,4,5]);
3922     return "fe80::$parts[0]$parts[1]:$parts[2]FF:FE$parts[3]:$parts[4]$parts[5]";
3923 }
3924
3925 sub compile_ipsets {
3926     my ($cluster_conf, $vmfw_configs, $vmdata) = @_;
3927
3928     my $localnet;
3929     if ($cluster_conf->{aliases}->{local_network}) {
3930         $localnet = $cluster_conf->{aliases}->{local_network}->{cidr};
3931     } else {
3932         my $localnet_ver;
3933         ($localnet, $localnet_ver) = parse_ip_or_cidr(local_network() || '127.0.0.0/8');
3934
3935         $cluster_conf->{aliases}->{local_network} = {
3936             name => 'local_network', cidr => $localnet, ipversion => $localnet_ver };
3937     }
3938
3939     push @{$cluster_conf->{ipset}->{management}}, { cidr => $localnet };
3940
3941
3942     my $ipset_ruleset = {};
3943
3944     # generate ipsets for QEMU VMs
3945     foreach my $vmid (keys %{$vmdata->{qemu}}) {
3946         eval {
3947             my $conf = $vmdata->{qemu}->{$vmid};
3948             my $vmfw_conf = $vmfw_configs->{$vmid};
3949             return if !$vmfw_conf;
3950
3951             # When the 'ipfilter' option is enabled every device for which there
3952             # is no 'ipfilter-netX' ipset defined gets an implicit empty default
3953             # ipset.
3954             # The reason is that ipfilter ipsets are always filled with standard
3955             # IPv6 link-local filters.
3956             my $ipsets = $vmfw_conf->{ipset};
3957             my $implicit_sets = {};
3958
3959             my $device_ips = {};
3960             foreach my $netid (keys %$conf) {
3961                 next if $netid !~ m/^net(\d+)$/;
3962                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
3963                 next if !$net->{firewall};
3964
3965                 if ($vmfw_conf->{options}->{ipfilter} && !$ipsets->{"ipfilter-$netid"}) {
3966                     $implicit_sets->{"ipfilter-$netid"} = [];
3967                 }
3968
3969                 my $macaddr = $net->{macaddr};
3970                 my $linklocal = mac_to_linklocal($macaddr);
3971                 $device_ips->{$netid} = [
3972                     { cidr => $linklocal },
3973                     { cidr => 'fe80::/10', nomatch => 1 }
3974                 ];
3975             }
3976
3977             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $ipsets);
3978             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $implicit_sets);
3979         };
3980         warn $@ if $@; # just to be sure - should not happen
3981     }
3982
3983     # generate firewall rules for LXC containers
3984     foreach my $vmid (keys %{$vmdata->{lxc}}) {
3985         eval {
3986             my $conf = $vmdata->{lxc}->{$vmid};
3987             my $vmfw_conf = $vmfw_configs->{$vmid};
3988             return if !$vmfw_conf;
3989
3990             # When the 'ipfilter' option is enabled every device for which there
3991             # is no 'ipfilter-netX' ipset defined gets an implicit empty default
3992             # ipset.
3993             # The reason is that ipfilter ipsets are always filled with standard
3994             # IPv6 link-local filters, as well as the IP addresses configured
3995             # for the container.
3996             my $ipsets = $vmfw_conf->{ipset};
3997             my $implicit_sets = {};
3998
3999             my $device_ips = {};
4000             foreach my $netid (keys %$conf) {
4001                 next if $netid !~ m/^net(\d+)$/;
4002                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
4003                 next if !$net->{firewall};
4004
4005                 if ($vmfw_conf->{options}->{ipfilter} && !$ipsets->{"ipfilter-$netid"}) {
4006                     $implicit_sets->{"ipfilter-$netid"} = [];
4007                 }
4008
4009                 my $macaddr = $net->{hwaddr};
4010                 my $linklocal = mac_to_linklocal($macaddr);
4011                 my $set = $device_ips->{$netid} = [
4012                     { cidr => $linklocal },
4013                     { cidr => 'fe80::/10', nomatch => 1 }
4014                 ];
4015                 if (defined($net->{ip}) && $net->{ip} =~ m!^($IPV4RE)(?:/\d+)?$!) {
4016                     push @$set, { cidr => $1 };
4017                 }
4018                 if (defined($net->{ip6}) && $net->{ip6} =~ m!^($IPV6RE)(?:/\d+)?$!) {
4019                     push @$set, { cidr => $1 };
4020                 }
4021             }
4022
4023             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $ipsets);
4024             generate_ipset_chains($ipset_ruleset, $cluster_conf, $vmfw_conf, $device_ips, $implicit_sets);
4025         };
4026         warn $@ if $@; # just to be sure - should not happen
4027     }
4028
4029     generate_ipset_chains($ipset_ruleset, undef, $cluster_conf, undef, $cluster_conf->{ipset});
4030
4031     return $ipset_ruleset;
4032 }
4033
4034 sub compile_ebtables_filter {
4035     my ($cluster_conf, $hostfw_conf, $vmfw_configs, $vmdata) = @_;
4036
4037     if (!($cluster_conf->{options}->{ebtables} // 1)) {
4038         return {};
4039     }
4040
4041     my $ruleset = {};
4042
4043     ruleset_create_chain($ruleset, "PVEFW-FORWARD");
4044
4045     ruleset_create_chain($ruleset, "PVEFW-FWBR-OUT");
4046     #for ipv4 and ipv6, check macaddress in iptables, so we use conntrack 'ESTABLISHED', to speedup rules
4047     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-p IPv4', '-j ACCEPT');
4048     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-p IPv6', '-j ACCEPT');
4049     ruleset_addrule($ruleset, 'PVEFW-FORWARD', '-o fwln+', '-j PVEFW-FWBR-OUT');
4050
4051     # generate firewall rules for QEMU VMs
4052     foreach my $vmid (sort keys %{$vmdata->{qemu}}) {
4053         eval {
4054             my $conf = $vmdata->{qemu}->{$vmid};
4055             my $vmfw_conf = $vmfw_configs->{$vmid};
4056             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
4057             my $ipsets = $vmfw_conf->{ipset};
4058
4059             foreach my $netid (sort keys %$conf) {
4060                 next if $netid !~ m/^net(\d+)$/;
4061                 my $net = PVE::QemuServer::parse_net($conf->{$netid});
4062                 next if !$net->{firewall};
4063                 my $iface = "tap${vmid}i$1";
4064                 my $macaddr = $net->{macaddr};
4065                 my $arpfilter = [];
4066                 if (defined(my $ipset = $ipsets->{"ipfilter-$netid"})) {
4067                     foreach my $ipaddr (@$ipset) {
4068                         my($ip, $version) = parse_ip_or_cidr($ipaddr->{cidr});
4069                         next if !$ip || ($version && $version != 4);
4070                         push(@$arpfilter, $ip);
4071                     }
4072                 }
4073                 generate_tap_layer2filter($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter);
4074             }
4075         };
4076         warn $@ if $@; # just to be sure - should not happen
4077     }
4078
4079     # generate firewall rules for LXC containers
4080     foreach my $vmid (sort keys %{$vmdata->{lxc}}) {
4081         eval {
4082             my $conf = $vmdata->{lxc}->{$vmid};
4083
4084             my $vmfw_conf = $vmfw_configs->{$vmid};
4085             return if !$vmfw_conf || !$vmfw_conf->{options}->{enable};
4086             my $ipsets = $vmfw_conf->{ipset};
4087
4088             foreach my $netid (sort keys %$conf) {
4089                 next if $netid !~ m/^net(\d+)$/;
4090                 my $net = PVE::LXC::Config->parse_lxc_network($conf->{$netid});
4091                 next if !$net->{firewall};
4092                 my $iface = "veth${vmid}i$1";
4093                 my $macaddr = $net->{hwaddr};
4094                 my $arpfilter = [];
4095                 if (defined(my $ipset = $ipsets->{"ipfilter-$netid"})) {
4096                     foreach my $ipaddr (@$ipset) {
4097                         my($ip, $version) = parse_ip_or_cidr($ipaddr->{cidr});
4098                         next if !$ip || ($version && $version != 4);
4099                         push(@$arpfilter, $ip);
4100                     }
4101                 }
4102                 if (defined(my $ip = $net->{ip}) && $vmfw_conf->{options}->{ipfilter}) {
4103                     # ebtables changes this to a .0/MASK network but we just
4104                     # want the address here, no network - see #2193
4105                     $ip =~ s|/(\d+)$||;
4106                     if ($ip ne 'dhcp') {
4107                         push @$arpfilter, $ip;
4108                     }
4109                 }
4110                 generate_tap_layer2filter($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter);
4111             }
4112         };
4113         warn $@ if $@; # just to be sure - should not happen
4114     }
4115
4116     return $ruleset;
4117 }
4118
4119 sub generate_tap_layer2filter {
4120     my ($ruleset, $iface, $macaddr, $vmfw_conf, $vmid, $arpfilter) = @_;
4121     my $options = $vmfw_conf->{options};
4122
4123     my $tapchain = $iface."-OUT";
4124
4125     # ebtables remove zeros from mac pairs
4126     $macaddr =~ s/0([0-9a-f])/$1/ig;
4127     $macaddr = lc($macaddr);
4128
4129     ruleset_create_chain($ruleset, $tapchain);
4130
4131     if (defined($macaddr) && !(defined($options->{macfilter}) && $options->{macfilter} == 0)) {
4132         ruleset_addrule($ruleset, $tapchain, "-s ! $macaddr", '-j DROP');
4133     }
4134
4135     if (@$arpfilter){
4136         my $arpchain = $tapchain."-ARP";
4137         ruleset_addrule($ruleset, $tapchain, "-p ARP", "-j $arpchain");
4138         ruleset_create_chain($ruleset, $arpchain);
4139
4140         foreach my $ip (@{$arpfilter}) {
4141             ruleset_addrule($ruleset, $arpchain, "-p ARP --arp-ip-src $ip", '-j RETURN');
4142         }
4143         ruleset_addrule($ruleset, $arpchain, '', '-j DROP');
4144     }
4145
4146     if (defined($options->{layer2_protocols})){
4147         my $protochain = $tapchain."-PROTO";
4148         ruleset_addrule($ruleset, $tapchain, '', "-j $protochain");
4149         ruleset_create_chain($ruleset, $protochain);
4150
4151         foreach my $proto (split(/,/, $options->{layer2_protocols})) {
4152             ruleset_addrule($ruleset, $protochain, "-p $proto", '-j RETURN');
4153         }
4154         ruleset_addrule($ruleset, $protochain, '', '-j DROP');
4155     }
4156
4157     ruleset_addrule($ruleset, $tapchain, '', '-j ACCEPT');
4158
4159     ruleset_addrule($ruleset, 'PVEFW-FWBR-OUT', "-i $iface", "-j $tapchain");
4160 }
4161
4162 # the parameter $change_only_regex changes two things if defined:
4163 # * all chains not matching it will be left intact
4164 # * both the $active_chains hash and the returned status_hash have different
4165 #   structure (they contain a key named 'rules').
4166 sub get_ruleset_status {
4167     my ($ruleset, $active_chains, $digest_fn, $change_only_regex) = @_;
4168
4169     my $statushash = {};
4170
4171     foreach my $chain (sort keys %$ruleset) {
4172         my $rules = $ruleset->{$chain};
4173         my $sig = &$digest_fn($rules);
4174         my $oldsig;
4175
4176         $statushash->{$chain}->{sig} = $sig;
4177         if (defined($change_only_regex)) {
4178             $oldsig = $active_chains->{$chain}->{sig};
4179             $statushash->{$chain}->{rules} = $rules;
4180         } else {
4181             $oldsig = $active_chains->{$chain};
4182         }
4183         if (!defined($oldsig)) {
4184             $statushash->{$chain}->{action} = 'create';
4185         } else {
4186             if ($oldsig eq $sig) {
4187                 $statushash->{$chain}->{action} = 'exists';
4188             } else {
4189                 $statushash->{$chain}->{action} = 'update';
4190             }
4191         }
4192         if ($verbose) {
4193             print "$statushash->{$chain}->{action} $chain ($sig)\n";
4194             foreach my $cmd (@{$rules}) {
4195                 print "\t$cmd\n";
4196             }
4197         }
4198     }
4199
4200     foreach my $chain (sort keys %$active_chains) {
4201         next if defined($ruleset->{$chain});
4202         my $action = 'delete';
4203         my $sig = $active_chains->{$chain};
4204         if (defined($change_only_regex)) {
4205             $action = 'ignore' if ($chain !~ m/$change_only_regex/);
4206             $statushash->{$chain}->{rules} = $active_chains->{$chain}->{rules};
4207             $statushash->{$chain}->{policy} = $active_chains->{$chain}->{policy};
4208             $sig = $sig->{sig};
4209         }
4210         $statushash->{$chain}->{action} = $action;
4211         $statushash->{$chain}->{sig} = $sig;
4212         print "$action $chain ($sig)\n" if $verbose;
4213     }
4214
4215     return $statushash;
4216 }
4217
4218 sub print_sig_rule {
4219     my ($chain, $sig) = @_;
4220
4221     # We just use this to store a SHA1 checksum used to detect changes
4222     return "-A $chain -m comment --comment \"PVESIG:$sig\"\n";
4223 }
4224
4225 sub get_ruleset_cmdlist {
4226     my ($ruleset, $iptablescmd, $table) = @_;
4227
4228     $table = 'filter' if !$table;
4229
4230     my $cmdlist = "*$table\n"; # we pass this to iptables-restore;
4231
4232     my ($active_chains, $hooks) = iptables_get_chains($iptablescmd, $table);
4233     my $statushash = get_ruleset_status($ruleset, $active_chains, \&iptables_chain_digest);
4234
4235     # create missing chains first
4236     foreach my $chain (sort keys %$ruleset) {
4237         my $stat = $statushash->{$chain};
4238         die "internal error" if !$stat;
4239         next if $stat->{action} ne 'create';
4240
4241         $cmdlist .= ":$chain - [0:0]\n";
4242     }
4243
4244     foreach my $h (qw(INPUT OUTPUT FORWARD PREROUTING)) {
4245         my $chain = "PVEFW-$h";
4246         if ($ruleset->{$chain} && !$hooks->{$h}) {
4247             $cmdlist .= "-A $h -j $chain\n";
4248         }
4249     }
4250
4251     foreach my $chain (sort keys %$ruleset) {
4252         my $stat = $statushash->{$chain};
4253         die "internal error" if !$stat;
4254
4255         if ($stat->{action} eq 'update' || $stat->{action} eq 'create') {
4256             $cmdlist .= "-F $chain\n";
4257             foreach my $cmd (@{$ruleset->{$chain}}) {
4258                 $cmdlist .= "$cmd\n";
4259             }
4260             $cmdlist .= print_sig_rule($chain, $stat->{sig});
4261         } elsif ($stat->{action} eq 'delete') {
4262             die "internal error"; # this should not happen
4263         } elsif ($stat->{action} eq 'exists') {
4264             # do nothing
4265         } else {
4266             die "internal error - unknown status '$stat->{action}'";
4267         }
4268     }
4269
4270     foreach my $chain (keys %$statushash) {
4271         next if $statushash->{$chain}->{action} ne 'delete';
4272         $cmdlist .= "-F $chain\n";
4273     }
4274     foreach my $chain (keys %$statushash) {
4275         next if $statushash->{$chain}->{action} ne 'delete';
4276         next if $chain eq 'PVEFW-INPUT';
4277         next if $chain eq 'PVEFW-OUTPUT';
4278         next if $chain eq 'PVEFW-FORWARD';
4279         next if $chain eq 'PVEFW-PREROUTING';
4280         $cmdlist .= "-X $chain\n";
4281     }
4282
4283     my $changes = $cmdlist ne "*$table\n" ? 1 : 0;
4284
4285     $cmdlist .= "COMMIT\n";
4286
4287     return wantarray ? ($cmdlist, $changes) : $cmdlist;
4288 }
4289
4290 my $pve_ebtables_chainname_regex = qr/PVEFW-\S+|(?:tap|veth)\d+i\d+-(?:IN|OUT)/;
4291
4292 sub get_ebtables_cmdlist {
4293     my ($ruleset) = @_;
4294
4295     my $changes = 0;
4296     my $cmdlist = "*filter\n";
4297
4298     my $active_chains = ebtables_get_chains();
4299     my $statushash = get_ruleset_status($ruleset, $active_chains,
4300                                         \&iptables_chain_digest,
4301                                         $pve_ebtables_chainname_regex);
4302
4303     # create chains first and make sure PVE rules are evaluated if active
4304     my $append_pve_to_forward = '-A FORWARD -j PVEFW-FORWARD';
4305     my $pve_include = 0;
4306     foreach my $chain (sort keys %$statushash) {
4307         next if ($statushash->{$chain}->{action} eq 'delete');
4308         my $policy = $statushash->{$chain}->{policy} // 'ACCEPT';
4309         $cmdlist .= ":$chain $policy\n";
4310         $pve_include = 1 if ($chain eq 'PVEFW-FORWARD');
4311     }
4312
4313     foreach my $chain (sort keys %$statushash) {
4314         my $stat = $statushash->{$chain};
4315         $changes = 1 if ($stat->{action} !~ 'ignore|exists');
4316         next if ($stat->{action} eq 'delete');
4317
4318         foreach my $cmd (@{$statushash->{$chain}->{'rules'}}) {
4319             if ($chain eq 'FORWARD' && $cmd eq $append_pve_to_forward) {
4320                 next if ! $pve_include;
4321                 $pve_include = 0;
4322             }
4323             $cmdlist .= "$cmd\n";
4324         }
4325     }
4326     $cmdlist .= "$append_pve_to_forward\n" if $pve_include;
4327
4328     return wantarray ? ($cmdlist, $changes) : $cmdlist;
4329 }
4330
4331 sub get_ipset_cmdlist {
4332     my ($ruleset) = @_;
4333
4334     my $cmdlist = "";
4335
4336     my $delete_cmdlist = "";
4337
4338     my $active_chains = ipset_get_chains();
4339     my $statushash = get_ruleset_status($ruleset, $active_chains, \&ipset_chain_digest);
4340
4341     # remove stale _swap chains
4342     foreach my $chain (keys %$active_chains) {
4343         if ($chain =~ m/^PVEFW-\S+_swap$/) {
4344             $cmdlist .= "destroy $chain\n";
4345         }
4346     }
4347
4348     foreach my $chain (keys %$ruleset) {
4349         my $stat = $statushash->{$chain};
4350         die "internal error" if !$stat;
4351
4352         if ($stat->{action} eq 'create') {
4353             foreach my $cmd (@{$ruleset->{$chain}}) {
4354                 $cmdlist .= "$cmd\n";
4355             }
4356         }
4357     }
4358
4359     foreach my $chain (keys %$ruleset) {
4360         my $stat = $statushash->{$chain};
4361         die "internal error" if !$stat;
4362
4363         if ($stat->{action} eq 'update') {
4364             my $chain_swap = $chain."_swap";
4365
4366             foreach my $cmd (@{$ruleset->{$chain}}) {
4367                 $cmd =~ s/$chain/$chain_swap/;
4368                 $cmdlist .= "$cmd\n";
4369             }
4370             $cmdlist .= "swap $chain_swap $chain\n";
4371             $cmdlist .= "flush $chain_swap\n";
4372             $cmdlist .= "destroy $chain_swap\n";
4373         }
4374     }
4375
4376      # the remove unused chains
4377     foreach my $chain (keys %$statushash) {
4378         next if $statushash->{$chain}->{action} ne 'delete';
4379
4380         $delete_cmdlist .= "flush $chain\n";
4381         $delete_cmdlist .= "destroy $chain\n";
4382     }
4383
4384     my $changes = ($cmdlist || $delete_cmdlist) ? 1 : 0;
4385
4386     return ($cmdlist, $delete_cmdlist, $changes);
4387 }
4388
4389 sub apply_ruleset {
4390     my ($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6, $ebtables_ruleset) = @_;
4391
4392     enable_bridge_firewall();
4393
4394     my ($ipset_create_cmdlist, $ipset_delete_cmdlist, $ipset_changes) =
4395         get_ipset_cmdlist($ipset_ruleset);
4396
4397     my ($cmdlist, $changes) = get_ruleset_cmdlist($ruleset->{filter});
4398     my ($cmdlistv6, $changesv6) = get_ruleset_cmdlist($rulesetv6->{filter}, "ip6tables");
4399     my ($ebtables_cmdlist, $ebtables_changes) = get_ebtables_cmdlist($ebtables_ruleset);
4400     my ($cmdlist_raw, $changes_raw) = get_ruleset_cmdlist($ruleset->{raw}, undef, 'raw');
4401     my ($cmdlistv6_raw, $changesv6_raw) = get_ruleset_cmdlist($rulesetv6->{raw}, "ip6tables", 'raw');
4402
4403     if ($verbose) {
4404         if ($ipset_changes) {
4405             print "ipset changes:\n";
4406             print $ipset_create_cmdlist if $ipset_create_cmdlist;
4407             print $ipset_delete_cmdlist if $ipset_delete_cmdlist;
4408         }
4409
4410         if ($changes) {
4411             print "iptables changes:\n";
4412             print $cmdlist;
4413         }
4414
4415         if ($changesv6) {
4416             print "ip6tables changes:\n";
4417             print $cmdlistv6;
4418         }
4419
4420         if ($changes_raw) {
4421             print "iptables table raw changes:\n";
4422             print $cmdlist_raw;
4423         }
4424
4425         if ($changesv6_raw) {
4426             print "ip6tables table raw changes:\n";
4427             print $cmdlistv6_raw;
4428         }
4429
4430         if ($ebtables_changes) {
4431             print "ebtables changes:\n";
4432             print $ebtables_cmdlist;
4433         }
4434     }
4435
4436     my $tmpfile = "$pve_fw_status_dir/ipsetcmdlist1";
4437     PVE::Tools::file_set_contents($tmpfile, $ipset_create_cmdlist || '');
4438
4439     ipset_restore_cmdlist($ipset_create_cmdlist);
4440
4441     $tmpfile = "$pve_fw_status_dir/ip4cmdlist";
4442     PVE::Tools::file_set_contents($tmpfile, $cmdlist || '');
4443
4444     iptables_restore_cmdlist($cmdlist);
4445
4446     $tmpfile = "$pve_fw_status_dir/ip4cmdlistraw";
4447     PVE::Tools::file_set_contents($tmpfile, $cmdlist_raw || '');
4448
4449     iptables_restore_cmdlist($cmdlist_raw, 'raw');
4450
4451     $tmpfile = "$pve_fw_status_dir/ip6cmdlist";
4452     PVE::Tools::file_set_contents($tmpfile, $cmdlistv6 || '');
4453
4454     ip6tables_restore_cmdlist($cmdlistv6);
4455
4456     $tmpfile = "$pve_fw_status_dir/ip6cmdlistraw";
4457     PVE::Tools::file_set_contents($tmpfile, $cmdlistv6_raw || '');
4458
4459     ip6tables_restore_cmdlist($cmdlistv6_raw, 'raw');
4460
4461     $tmpfile = "$pve_fw_status_dir/ipsetcmdlist2";
4462     PVE::Tools::file_set_contents($tmpfile, $ipset_delete_cmdlist || '');
4463
4464     ipset_restore_cmdlist($ipset_delete_cmdlist) if $ipset_delete_cmdlist;
4465
4466     ebtables_restore_cmdlist($ebtables_cmdlist);
4467
4468     $tmpfile = "$pve_fw_status_dir/ebtablescmdlist";
4469     PVE::Tools::file_set_contents($tmpfile, $ebtables_cmdlist || '');
4470
4471     # test: re-read status and check if everything is up to date
4472     my $ruleset_filter = $ruleset->{filter};
4473     my $active_chains = iptables_get_chains();
4474     my $statushash = get_ruleset_status($ruleset_filter, $active_chains, \&iptables_chain_digest);
4475
4476     my $errors;
4477     foreach my $chain (sort keys %$ruleset_filter) {
4478         my $stat = $statushash->{$chain};
4479         if ($stat->{action} ne 'exists') {
4480             warn "unable to update chain '$chain'\n";
4481             $errors = 1;
4482         }
4483     }
4484
4485     my $rulesetv6_filter = $rulesetv6->{filter};
4486     my $active_chainsv6 = iptables_get_chains("ip6tables");
4487     my $statushashv6 = get_ruleset_status($rulesetv6_filter, $active_chainsv6, \&iptables_chain_digest);
4488
4489     foreach my $chain (sort keys %$rulesetv6_filter) {
4490         my $stat = $statushashv6->{$chain};
4491         if ($stat->{action} ne 'exists') {
4492             warn "unable to update chain '$chain'\n";
4493             $errors = 1;
4494         }
4495     }
4496
4497     my $ruleset_raw = $ruleset->{raw};
4498     my $active_chains_raw = iptables_get_chains(undef, 'raw');
4499     my $statushash_raw = get_ruleset_status($ruleset_raw, $active_chains_raw, \&iptables_chain_digest);
4500
4501     foreach my $chain (sort keys %$ruleset_raw) {
4502         my $stat = $statushash_raw->{$chain};
4503         if ($stat->{action} ne 'exists') {
4504             warn "unable to update chain '$chain'\n";
4505             $errors = 1;
4506         }
4507     }
4508
4509     my $rulesetv6_raw = $rulesetv6->{raw};
4510     my $active_chainsv6_raw = iptables_get_chains("ip6tables", 'raw');
4511     my $statushashv6_raw = get_ruleset_status($rulesetv6_raw, $active_chainsv6_raw, \&iptables_chain_digest);
4512
4513     foreach my $chain (sort keys %$rulesetv6_raw) {
4514         my $stat = $statushashv6_raw->{$chain};
4515         if ($stat->{action} ne 'exists') {
4516             warn "unable to update chain '$chain'\n";
4517             $errors = 1;
4518         }
4519     }
4520
4521     my $active_ebtables_chains = ebtables_get_chains();
4522     my $ebtables_statushash = get_ruleset_status($ebtables_ruleset,
4523                                 $active_ebtables_chains, \&iptables_chain_digest,
4524                                 $pve_ebtables_chainname_regex);
4525
4526     foreach my $chain (sort keys %$ebtables_ruleset) {
4527         my $stat = $ebtables_statushash->{$chain};
4528         if ($stat->{action} ne 'exists') {
4529             warn "ebtables : unable to update chain '$chain'\n";
4530             $errors = 1;
4531         }
4532     }
4533
4534     die "unable to apply firewall changes\n" if $errors;
4535
4536     update_nf_conntrack_max($hostfw_conf);
4537
4538     update_nf_conntrack_tcp_timeout_established($hostfw_conf);
4539
4540     update_nf_conntrack_tcp_timeout_syn_recv($hostfw_conf);
4541
4542     update_nf_conntrack_logging($hostfw_conf);
4543 }
4544
4545 sub update_nf_conntrack_max {
4546     my ($hostfw_conf) = @_;
4547
4548     my $max = 262144; # reasonable default (2^16 * 4), see nf_conntrack-sysctl docs
4549
4550     my $options = $hostfw_conf->{options} || {};
4551
4552     if (defined($options->{nf_conntrack_max}) && ($options->{nf_conntrack_max} > $max)) {
4553         $max = $options->{nf_conntrack_max};
4554         $max = int(($max+ 8191)/8192)*8192; # round to multiples of 8192
4555     }
4556
4557     my $filename_nf_conntrack_max = "/proc/sys/net/nf_conntrack_max";
4558     my $filename_hashsize = "/sys/module/nf_conntrack/parameters/hashsize";
4559
4560     my $current = int(PVE::Tools::file_read_firstline($filename_nf_conntrack_max) || $max);
4561
4562     if ($current != $max) {
4563         my $hashsize = int($max/4);
4564         PVE::ProcFSTools::write_proc_entry($filename_hashsize, $hashsize);
4565         PVE::ProcFSTools::write_proc_entry($filename_nf_conntrack_max, $max);
4566     }
4567 }
4568
4569 sub update_nf_conntrack_tcp_timeout_established {
4570     my ($hostfw_conf) = @_;
4571
4572     my $options = $hostfw_conf->{options} || {};
4573
4574     my $value = defined($options->{nf_conntrack_tcp_timeout_established}) ? $options->{nf_conntrack_tcp_timeout_established} : 432000;
4575
4576     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_established", $value);
4577 }
4578
4579 sub update_nf_conntrack_tcp_timeout_syn_recv {
4580     my ($hostfw_conf) = @_;
4581
4582     my $options = $hostfw_conf->{options} || {};
4583
4584     my $value = defined($options->{nf_conntrack_tcp_timeout_syn_recv}) ? $options->{nf_conntrack_tcp_timeout_syn_recev} : 60;
4585
4586     PVE::ProcFSTools::write_proc_entry("/proc/sys/net/netfilter/nf_conntrack_tcp_timeout_syn_recv", $value);
4587 }
4588
4589 my $log_nf_conntrack_enabled = undef;
4590 sub update_nf_conntrack_logging {
4591     my ($hostfw_conf) = @_;
4592
4593     my $options = $hostfw_conf->{options} || {};
4594     my $value = $options->{log_nf_conntrack} || 0;
4595     if (!defined($log_nf_conntrack_enabled)
4596         || $value != $log_nf_conntrack_enabled)
4597     {
4598         my $tmpfile = "$pve_fw_status_dir/log_nf_conntrack";
4599         PVE::Tools::file_set_contents($tmpfile, $value);
4600
4601         run_command([qw(systemctl try-reload-or-restart pvefw-logger.service)]);
4602         $log_nf_conntrack_enabled = $value;
4603     }
4604 }
4605
4606 sub remove_pvefw_chains {
4607
4608     PVE::Firewall::remove_pvefw_chains_iptables("iptables");
4609     PVE::Firewall::remove_pvefw_chains_iptables("ip6tables");
4610     PVE::Firewall::remove_pvefw_chains_iptables("iptables", "raw");
4611     PVE::Firewall::remove_pvefw_chains_iptables("ip6tables", "raw");
4612     PVE::Firewall::remove_pvefw_chains_ipset();
4613     PVE::Firewall::remove_pvefw_chains_ebtables();
4614
4615 }
4616
4617 sub remove_pvefw_chains_iptables {
4618     my ($iptablescmd, $table) = @_;
4619
4620     $table = 'filter' if !$table;
4621
4622     my ($chash, $hooks) = iptables_get_chains($iptablescmd, $table);
4623     my $cmdlist = "*$table\n";
4624
4625     foreach my $h (qw(INPUT OUTPUT FORWARD PREROUTING)) {
4626         if ($hooks->{$h}) {
4627             $cmdlist .= "-D $h -j PVEFW-$h\n";
4628         }
4629     }
4630
4631     foreach my $chain (keys %$chash) {
4632         $cmdlist .= "-F $chain\n";
4633     }
4634
4635     foreach my $chain (keys %$chash) {
4636         $cmdlist .= "-X $chain\n";
4637     }
4638     $cmdlist .= "COMMIT\n";
4639
4640     if($iptablescmd eq "ip6tables") {
4641         ip6tables_restore_cmdlist($cmdlist, $table);
4642     } else {
4643         iptables_restore_cmdlist($cmdlist, $table);
4644     }
4645 }
4646
4647 sub remove_pvefw_chains_ipset {
4648
4649     my $ipset_chains = ipset_get_chains();
4650
4651     my $cmdlist = "";
4652
4653     foreach my $chain (keys %$ipset_chains) {
4654         $cmdlist .= "flush $chain\n";
4655         $cmdlist .= "destroy $chain\n";
4656     }
4657
4658     ipset_restore_cmdlist($cmdlist) if $cmdlist;
4659 }
4660
4661 sub remove_pvefw_chains_ebtables {
4662     # apply empty ruleset = remove all our chains
4663     ebtables_restore_cmdlist(get_ebtables_cmdlist({}));
4664 }
4665
4666 sub init {
4667     my $cluster_conf = load_clusterfw_conf();
4668     my $cluster_options = $cluster_conf->{options};
4669     my $enable = $cluster_options->{enable};
4670
4671     return if !$enable;
4672
4673     # load required modules here
4674 }
4675
4676 sub update {
4677     my $code = sub {
4678
4679         my $cluster_conf = load_clusterfw_conf();
4680         my $cluster_options = $cluster_conf->{options};
4681
4682         if (!$cluster_options->{enable}) {
4683             PVE::Firewall::remove_pvefw_chains();
4684             return;
4685         }
4686
4687         my $hostfw_conf = load_hostfw_conf($cluster_conf);
4688
4689         my ($ruleset, $ipset_ruleset, $rulesetv6, $ebtables_ruleset) = compile($cluster_conf, $hostfw_conf);
4690
4691         apply_ruleset($ruleset, $hostfw_conf, $ipset_ruleset, $rulesetv6, $ebtables_ruleset);
4692     };
4693
4694     run_locked($code);
4695 }
4696
4697 1;