PVE/AbstractConfig.pm

   1 package PVE::AbstractConfig;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Tools qw(lock_file lock_file_full);
   7 use PVE::INotify;
   8 use PVE::Cluster;
   9 use PVE::Storage;
  10
  11 use PVE::GuestHelpers qw(typesafe_ne);
  12 use PVE::ReplicationConfig;
  13 use PVE::Replication;
  14
  15 my $nodename = PVE::INotify::nodename();
  16
  17 # Printable string, currently either "VM" or "CT"
  18 sub guest_type {
  19     my ($class) = @_;
  20     die "abstract method - implement me ";
  21 }
  22
  23 sub __config_max_unused_disks {
  24     my ($class) = @_;
  25
  26     die "implement me - abstract method\n";
  27 }
  28
  29 # Path to the flock file for this VM/CT
  30 sub config_file_lock {
  31     my ($class, $vmid) = @_;
  32     die "abstract method - implement me";
  33 }
  34
  35 # Relative config file path for this VM/CT in CFS
  36 sub cfs_config_path {
  37     my ($class, $vmid, $node) = @_;
  38     die "abstract method - implement me";
  39 }
  40
  41 # Absolute config file path for this VM/CT
  42 sub config_file {
  43     my ($class, $vmid, $node) = @_;
  44
  45     my $cfspath = $class->cfs_config_path($vmid, $node);
  46     return "/etc/pve/$cfspath";
  47 }
  48
  49 # Read and parse config file for this VM/CT
  50 sub load_config {
  51     my ($class, $vmid, $node) = @_;
  52
  53     $node = $nodename if !$node;
  54     my $cfspath = $class->cfs_config_path($vmid, $node);
  55
  56     my $conf = PVE::Cluster::cfs_read_file($cfspath);
  57     die "Configuration file '$cfspath' does not exist\n"
  58         if !defined($conf);
  59
  60     return $conf;
  61 }
  62
  63 # Generate and write config file for this VM/CT
  64 sub write_config {
  65     my ($class, $vmid, $conf) = @_;
  66
  67     my $cfspath = $class->cfs_config_path($vmid);
  68
  69     PVE::Cluster::cfs_write_file($cfspath, $conf);
  70 }
  71
  72 # Pending changes related
  73
  74 sub parse_pending_delete {
  75     my ($class, $data) = @_;
  76
  77     return {} if !$data;
  78
  79     $data =~ s/[,;]/ /g;
  80     $data =~ s/^\s+//;
  81
  82     my $pending_deletions = {};
  83     for my $entry (split(/\s+/, $data)) {
  84         my ($force, $key) = $entry =~ /^(!?)(.*)$/;
  85
  86         $pending_deletions->{$key} = {
  87             force => $force ? 1 : 0,
  88         };
  89     }
  90
  91     return $pending_deletions;
  92 }
  93
  94 sub print_pending_delete {
  95     my ($class, $delete_hash) = @_;
  96
  97     my $render_key = sub {
  98         my $key = shift;
  99         $key = "!$key" if $delete_hash->{$key}->{force};
 100         return $key;
 101     };
 102
 103     join (',', map { $render_key->($_) } sort keys %$delete_hash);
 104 }
 105
 106 sub add_to_pending_delete {
 107     my ($class, $conf, $key, $force) = @_;
 108
 109     $conf->{pending} //= {};
 110     my $pending = $conf->{pending};
 111     my $pending_delete_hash = $class->parse_pending_delete($pending->{delete});
 112
 113     $pending_delete_hash->{$key} = { force => $force };
 114
 115     $pending->{delete} = $class->print_pending_delete($pending_delete_hash);
 116
 117     return $conf;
 118 }
 119
 120 sub remove_from_pending_delete {
 121     my ($class, $conf, $key) = @_;
 122
 123     my $pending = $conf->{pending};
 124     my $pending_delete_hash = $class->parse_pending_delete($pending->{delete});
 125
 126     return $conf if ! exists $pending_delete_hash->{$key};
 127
 128     delete $pending_delete_hash->{$key};
 129
 130     if (%$pending_delete_hash) {
 131         $pending->{delete} = $class->print_pending_delete($pending_delete_hash);
 132     } else {
 133         delete $pending->{delete};
 134     }
 135
 136     return $conf;
 137 }
 138
 139 sub cleanup_pending {
 140     my ($class, $conf) = @_;
 141
 142     my $pending = $conf->{pending};
 143     # remove pending changes when nothing changed
 144     my $changes;
 145     foreach my $opt (keys %{$conf->{pending}}) {
 146         next if $opt eq 'delete'; # just to be sure
 147         if (defined($conf->{$opt}) && ($pending->{$opt} eq $conf->{$opt})) {
 148             $changes = 1;
 149             delete $pending->{$opt};
 150         }
 151     }
 152
 153     my $current_delete_hash = $class->parse_pending_delete($pending->{delete});
 154     my $pending_delete_hash = {};
 155     for my $opt (keys %$current_delete_hash) {
 156         if (defined($conf->{$opt})) {
 157             $pending_delete_hash->{$opt} = $current_delete_hash->{$opt};
 158         } else {
 159             $changes = 1;
 160         }
 161     }
 162
 163     if (%$pending_delete_hash) {
 164         $pending->{delete} = $class->print_pending_delete($pending_delete_hash);
 165     } else {
 166         delete $pending->{delete};
 167     }
 168
 169     return $changes;
 170 }
 171
 172 sub get_partial_fast_plug_option {
 173     my ($class) = @_;
 174
 175     die "abstract method - implement me ";
 176 }
 177
 178 sub partial_fast_plug {
 179     my ($class, $conf, $opt) = @_;
 180
 181     my $partial_fast_plug_option = $class->get_partial_fast_plug_option();
 182     return 0 if !$partial_fast_plug_option->{$opt};
 183
 184     my $format = $partial_fast_plug_option->{$opt}->{fmt};
 185     my $fast_pluggable = $partial_fast_plug_option->{$opt}->{properties};
 186
 187     my $configured = {};
 188     if (exists($conf->{$opt})) {
 189         $configured = PVE::JSONSchema::parse_property_string($format, $conf->{$opt});
 190     }
 191     my $pending = PVE::JSONSchema::parse_property_string($format, $conf->{pending}->{$opt});
 192
 193     my $changes = 0;
 194
 195     # merge configured and pending opts to iterate
 196     my @all_keys = keys %{{ %$pending, %$configured }};
 197
 198     foreach my $subopt (@all_keys) {
 199         my $type = $format->{$subopt}->{type};
 200         if (typesafe_ne($configured->{$subopt}, $pending->{$subopt}, $type)) {
 201             if ($fast_pluggable->{$subopt}) {
 202                 $configured->{$subopt} = $pending->{$subopt};
 203                 $changes = 1
 204             }
 205         }
 206     }
 207
 208     # if there're no keys in $configured (after merge) there shouldn't be anything to change
 209     if (keys %$configured) {
 210         $conf->{$opt} = PVE::JSONSchema::print_property_string($configured, $format);
 211     }
 212
 213     return $changes;
 214 }
 215
 216
 217 sub load_snapshot_config {
 218     my ($class, $vmid, $snapname) = @_;
 219
 220     my $conf = $class->load_config($vmid);
 221
 222     my $snapshot = $conf->{snapshots}->{$snapname};
 223     die "snapshot '$snapname' does not exist\n" if !defined($snapshot);
 224
 225     $snapshot->{digest} = $conf->{digest};
 226
 227     return $snapshot;
 228
 229 }
 230
 231 sub load_current_config {
 232     my ($class, $vmid, $current) = @_;
 233
 234     my $conf = $class->load_config($vmid);
 235
 236     # take pending changes in
 237     if (!$current) {
 238         foreach my $opt (keys %{$conf->{pending}}) {
 239             next if $opt eq 'delete';
 240             my $value = $conf->{pending}->{$opt};
 241             next if ref($value); # just to be sure
 242             $conf->{$opt} = $value;
 243         }
 244         my $pending_delete_hash = $class->parse_pending_delete($conf->{pending}->{delete});
 245         foreach my $opt (keys %$pending_delete_hash) {
 246             delete $conf->{$opt} if $conf->{$opt};
 247         }
 248     }
 249
 250     delete $conf->{snapshots};
 251     delete $conf->{pending};
 252
 253     return $conf;
 254 }
 255
 256
 257 # Lock config file using flock, run $code with @param, unlock config file.
 258 # $timeout is the maximum time to acquire the flock
 259 sub lock_config_full {
 260     my ($class, $vmid, $timeout, $code, @param) = @_;
 261
 262     my $filename = $class->config_file_lock($vmid);
 263
 264     my $res = lock_file($filename, $timeout, $code, @param);
 265
 266     die $@ if $@;
 267
 268     return $res;
 269 }
 270
 271 sub create_and_lock_config {
 272     my ($class, $vmid, $allow_existing, $lock) = @_;
 273
 274     $class->lock_config_full($vmid, 5, sub {
 275         PVE::Cluster::check_vmid_unused($vmid, $allow_existing);
 276
 277         my $conf = eval { $class->load_config($vmid) } || {};
 278         $class->check_lock($conf);
 279         $conf->{lock} = $lock // 'create';
 280         $class->write_config($vmid, $conf);
 281     });
 282 }
 283
 284 # destroys configuration, only applicable for configs owned by the callers node.
 285 # dies if removal fails, e.g., when inquorate.
 286 sub destroy_config {
 287     my ($class, $vmid) = @_;
 288
 289     my $config_fn = $class->config_file($vmid, $nodename);
 290     unlink $config_fn or die "failed to remove config file: $!\n";
 291 }
 292
 293 # Lock config file using flock, run $code with @param, unlock config file.
 294 # $timeout is the maximum time to acquire the flock
 295 # $shared eq 1 creates a non-exclusive ("read") flock
 296 sub lock_config_mode {
 297     my ($class, $vmid, $timeout, $shared, $code, @param) = @_;
 298
 299     my $filename = $class->config_file_lock($vmid);
 300
 301     my $res = lock_file_full($filename, $timeout, $shared, $code, @param);
 302
 303     die $@ if $@;
 304
 305     return $res;
 306 }
 307
 308 # Lock config file using flock, run $code with @param, unlock config file.
 309 sub lock_config {
 310     my ($class, $vmid, $code, @param) = @_;
 311
 312     return $class->lock_config_full($vmid, 10, $code, @param);
 313 }
 314
 315 # Checks whether the config is locked with the lock parameter
 316 sub check_lock {
 317     my ($class, $conf) = @_;
 318
 319     die $class->guest_type()." is locked ($conf->{lock})\n" if $conf->{lock};
 320 }
 321
 322 # Returns whether the config is locked with the lock parameter, also checks
 323 # whether the lock value is correct if the optional $lock is set.
 324 sub has_lock {
 325     my ($class, $conf, $lock) = @_;
 326
 327     return $conf->{lock} && (!defined($lock) || $lock eq $conf->{lock});
 328 }
 329
 330 # Sets the lock parameter for this VM/CT's config to $lock.
 331 sub set_lock {
 332     my ($class, $vmid, $lock) = @_;
 333
 334     my $conf;
 335     $class->lock_config($vmid, sub {
 336         $conf = $class->load_config($vmid);
 337         $class->check_lock($conf);
 338         $conf->{lock} = $lock;
 339         $class->write_config($vmid, $conf);
 340     });
 341     return $conf;
 342 }
 343
 344 # Removes the lock parameter for this VM/CT's config, also checks whether
 345 # the lock value is correct if the optional $lock is set.
 346 sub remove_lock {
 347     my ($class, $vmid, $lock) = @_;
 348
 349     $class->lock_config($vmid, sub {
 350         my $conf = $class->load_config($vmid);
 351         if (!$conf->{lock}) {
 352             my $lockstring = defined($lock) ? "'$lock' " : "any";
 353             die "no lock found trying to remove $lockstring lock\n";
 354         } elsif (defined($lock) && $conf->{lock} ne $lock) {
 355             die "found lock '$conf->{lock}' trying to remove '$lock' lock\n";
 356         }
 357         delete $conf->{lock};
 358         $class->write_config($vmid, $conf);
 359     });
 360 }
 361
 362 # Checks whether protection mode is enabled for this VM/CT.
 363 sub check_protection {
 364     my ($class, $conf, $err_msg) = @_;
 365
 366     if ($conf->{protection}) {
 367         die "$err_msg - protection mode enabled\n";
 368     }
 369 }
 370
 371 # Returns a list of keys where used volumes can be located
 372 sub valid_volume_keys {
 373     my ($class, $reverse) = @_;
 374
 375     die "implement me - abstract method\n";
 376 }
 377
 378 # Returns a hash with the information from $volume_string
 379 # $key is used to determine the format of the string
 380 sub parse_volume {
 381     my ($class, $key, $volume_string, $noerr) = @_;
 382
 383     die "implement me - abstract method\n";
 384 }
 385
 386 # Returns a string with the information from $volume
 387 # $key is used to determine the format of the string
 388 sub print_volume {
 389     my ($class, $key, $volume) = @_;
 390
 391     die "implement me - abstract method\n";
 392 }
 393
 394 # The key under which the volume ID is located in volume hashes
 395 sub volid_key {
 396     my ($class) = @_;
 397
 398     die "implement me - abstract method\n";
 399 }
 400
 401 # Adds an unused volume to $config, if possible.
 402 sub add_unused_volume {
 403     my ($class, $config, $volid) = @_;
 404
 405     my $key;
 406     for (my $ind = $class->__config_max_unused_disks() - 1; $ind >= 0; $ind--) {
 407         my $test = "unused$ind";
 408         if (my $vid = $config->{$test}) {
 409             return if $vid eq $volid; # do not add duplicates
 410         } else {
 411             $key = $test;
 412         }
 413     }
 414
 415     die "Too many unused volumes - please delete them first.\n" if !$key;
 416
 417     $config->{$key} = $volid;
 418
 419     return $key;
 420 }
 421
 422 # Iterate over all unused volumes, calling $func for each key/value pair
 423 # with additional parameters @param.
 424 sub foreach_unused_volume {
 425     my ($class, $conf, $func, @param) = @_;
 426
 427     foreach my $key (keys %{$conf}) {
 428         if ($key =~ m/^unused\d+$/) {
 429             my $volume = $class->parse_volume($key, $conf->{$key});
 430             $func->($key, $volume, @param);
 431         }
 432     }
 433 }
 434
 435 # Returns whether the template parameter is set in $conf.
 436 sub is_template {
 437     my ($class, $conf) = @_;
 438
 439     return 1 if defined $conf->{template} && $conf->{template} == 1;
 440 }
 441
 442 # Checks whether $feature is available for the referenced volumes in $conf.
 443 # Note: depending on the parameters, some volumes may be skipped!
 444 sub has_feature {
 445     my ($class, $feature, $conf, $storecfg, $snapname, $running, $backup_only) = @_;
 446     die "implement me - abstract method\n";
 447 }
 448
 449 # get all replicatable volume (hash $res->{$volid} = 1)
 450 # $cleanup: for cleanup - simply ignores volumes without replicate feature
 451 # $norerr: never raise exceptions - return undef instead
 452 sub get_replicatable_volumes {
 453     my ($class, $storecfg, $vmid, $conf, $cleanup, $noerr) = @_;
 454
 455     die "implement me - abstract method\n";
 456 }
 457
 458 # Returns all the guests volumes which would be included in a vzdump job
 459 # Return Format (array-ref with hash-refs as elements):
 460 # [
 461 #   {
 462 #     key,        key in the config, e.g. mp0, scsi0,...
 463 #     included,   boolean
 464 #     reason,     string
 465 #     data        volume object as returned from foreach_drive/foreach_mountpoint
 466 #   },
 467 # ]
 468 sub get_backup_volumes {
 469     my ($class, $conf) = @_;
 470
 471     die "implement me - abstract method\n";
 472 }
 473
 474 # Internal snapshots
 475
 476 # NOTE: Snapshot create/delete involves several non-atomic
 477 # actions, and can take a long time.
 478 # So we try to avoid locking the file and use the 'lock' variable
 479 # inside the config file instead.
 480
 481 # Save the vmstate (RAM).
 482 sub __snapshot_save_vmstate {
 483     my ($class, $vmid, $conf, $snapname, $storecfg) = @_;
 484     die "implement me - abstract method\n";
 485 }
 486
 487 # Check whether the VM/CT is running.
 488 sub __snapshot_check_running {
 489     my ($class, $vmid) = @_;
 490     die "implement me - abstract method\n";
 491 }
 492
 493 # Check whether we need to freeze the VM/CT
 494 sub __snapshot_check_freeze_needed {
 495     my ($sself, $vmid, $config, $save_vmstate) = @_;
 496     die "implement me - abstract method\n";
 497 }
 498
 499 # Freeze or unfreeze the VM/CT.
 500 sub __snapshot_freeze {
 501     my ($class, $vmid, $unfreeze) = @_;
 502
 503     die "abstract method - implement me\n";
 504 }
 505
 506 # Code run before and after creating all the volume snapshots
 507 # base: noop
 508 sub __snapshot_create_vol_snapshots_hook {
 509     my ($class, $vmid, $snap, $running, $hook) = @_;
 510
 511     return;
 512 }
 513
 514 # Create the volume snapshots for the VM/CT.
 515 sub __snapshot_create_vol_snapshot {
 516     my ($class, $vmid, $vs, $volume, $snapname) = @_;
 517
 518     die "abstract method - implement me\n";
 519 }
 520
 521 # Remove a drive from the snapshot config.
 522 sub __snapshot_delete_remove_drive {
 523     my ($class, $snap, $drive) = @_;
 524
 525     die "abstract method - implement me\n";
 526 }
 527
 528 # Delete the vmstate file/drive
 529 sub __snapshot_delete_vmstate_file {
 530     my ($class, $snap, $force) = @_;
 531
 532     die "abstract method - implement me\n";
 533 }
 534
 535 # Delete a volume snapshot
 536 sub __snapshot_delete_vol_snapshot {
 537     my ($class, $vmid, $vs, $volume, $snapname) = @_;
 538
 539     die "abstract method - implement me\n";
 540 }
 541
 542 # called during rollback prepare, and between config rollback and starting guest
 543 # can change config, e.g. for vmgenid
 544 # $data is shared across calls and passed to vm_start
 545 sub __snapshot_rollback_hook {
 546     my ($class, $vmid, $conf, $snap, $prepare, $data) = @_;
 547
 548     return;
 549 }
 550
 551 # Checks whether a volume snapshot is possible for this volume.
 552 sub __snapshot_rollback_vol_possible {
 553     my ($class, $volume, $snapname) = @_;
 554
 555     die "abstract method - implement me\n";
 556 }
 557
 558 # Rolls back this volume.
 559 sub __snapshot_rollback_vol_rollback {
 560     my ($class, $volume, $snapname) = @_;
 561
 562     die "abstract method - implement me\n";
 563 }
 564
 565 # Stops the VM/CT for a rollback.
 566 sub __snapshot_rollback_vm_stop {
 567     my ($class, $vmid) = @_;
 568
 569     die "abstract method - implement me\n";
 570 }
 571
 572 # Start the VM/CT after a rollback with restored vmstate.
 573 sub __snapshot_rollback_vm_start {
 574     my ($class, $vmid, $vmstate, $data);
 575
 576     die "abstract method - implement me\n";
 577 }
 578
 579 # Get list of volume IDs which are referenced in $conf, but not in $snap.
 580 sub __snapshot_rollback_get_unused {
 581     my ($class, $conf, $snap) = @_;
 582
 583     die "abstract method - implement me\n";
 584 }
 585
 586 # Iterate over all configured volumes, calling $func for each key/value pair.
 587 sub __snapshot_foreach_volume {
 588     my ($class, $conf, $func) = @_;
 589
 590     die "abstract method - implement me\n";
 591 }
 592
 593 # Copy the current config $source to the snapshot config $dest
 594 sub __snapshot_copy_config {
 595     my ($class, $source, $dest) = @_;
 596
 597     foreach my $k (keys %$source) {
 598         next if $k eq 'snapshots';
 599         next if $k eq 'snapstate';
 600         next if $k eq 'snaptime';
 601         next if $k eq 'vmstate';
 602         next if $k eq 'lock';
 603         next if $k eq 'digest';
 604         next if $k eq 'description';
 605         next if $k =~ m/^unused\d+$/;
 606
 607         $dest->{$k} = $source->{$k};
 608     }
 609 };
 610
 611 # Apply the snapshot config $snap to the config $conf (rollback)
 612 sub __snapshot_apply_config {
 613     my ($class, $conf, $snap) = @_;
 614
 615     # copy snapshot list
 616     my $newconf = {
 617         snapshots => $conf->{snapshots},
 618     };
 619
 620     # keep description and list of unused disks
 621     foreach my $k (keys %$conf) {
 622         next if !($k =~ m/^unused\d+$/ || $k eq 'description');
 623
 624         $newconf->{$k} = $conf->{$k};
 625     }
 626
 627     $class->__snapshot_copy_config($snap, $newconf);
 628
 629     return $newconf;
 630 }
 631
 632 # Prepares the configuration for snapshotting.
 633 sub __snapshot_prepare {
 634     my ($class, $vmid, $snapname, $save_vmstate, $comment) = @_;
 635
 636     my $snap;
 637
 638     my $updatefn =  sub {
 639
 640         my $conf = $class->load_config($vmid);
 641
 642         die "you can't take a snapshot if it's a template\n"
 643             if $class->is_template($conf);
 644
 645         $class->check_lock($conf);
 646
 647         $conf->{lock} = 'snapshot';
 648
 649         die "snapshot name '$snapname' already used\n"
 650             if defined($conf->{snapshots}->{$snapname});
 651
 652         my $storecfg = PVE::Storage::config();
 653         die "snapshot feature is not available\n"
 654             if !$class->has_feature('snapshot', $conf, $storecfg, undef, undef, $snapname eq 'vzdump');
 655
 656         $snap = $conf->{snapshots}->{$snapname} = {};
 657
 658         if ($save_vmstate && $class->__snapshot_check_running($vmid)) {
 659             $class->__snapshot_save_vmstate($vmid, $conf, $snapname, $storecfg);
 660         }
 661
 662         $class->__snapshot_copy_config($conf, $snap);
 663
 664         $snap->{snapstate} = "prepare";
 665         $snap->{snaptime} = time();
 666         $snap->{description} = $comment if $comment;
 667
 668         $class->write_config($vmid, $conf);
 669     };
 670
 671     $class->lock_config($vmid, $updatefn);
 672
 673     return $snap;
 674 }
 675
 676 # Commits the configuration after snapshotting.
 677 sub __snapshot_commit {
 678     my ($class, $vmid, $snapname) = @_;
 679
 680     my $updatefn = sub {
 681
 682         my $conf = $class->load_config($vmid);
 683
 684         die "missing snapshot lock\n"
 685             if !($conf->{lock} && $conf->{lock} eq 'snapshot');
 686
 687         my $snap = $conf->{snapshots}->{$snapname};
 688         die "snapshot '$snapname' does not exist\n" if !defined($snap);
 689
 690         die "wrong snapshot state\n"
 691             if !($snap->{snapstate} && $snap->{snapstate} eq "prepare");
 692
 693         delete $snap->{snapstate};
 694         delete $conf->{lock};
 695
 696         $conf->{parent} = $snapname;
 697
 698         $class->write_config($vmid, $conf);
 699     };
 700
 701     $class->lock_config($vmid, $updatefn);
 702 }
 703
 704 # Creates a snapshot for the VM/CT.
 705 sub snapshot_create {
 706     my ($class, $vmid, $snapname, $save_vmstate, $comment) = @_;
 707
 708     my $snap = $class->__snapshot_prepare($vmid, $snapname, $save_vmstate, $comment);
 709
 710     $save_vmstate = 0 if !$snap->{vmstate};
 711
 712     my $conf = $class->load_config($vmid);
 713
 714     my ($running, $freezefs) = $class->__snapshot_check_freeze_needed($vmid, $conf, $snap->{vmstate});
 715
 716     my $drivehash = {};
 717
 718     eval {
 719         if ($freezefs) {
 720             $class->__snapshot_freeze($vmid, 0);
 721         }
 722
 723         $class->__snapshot_create_vol_snapshots_hook($vmid, $snap, $running, "before");
 724
 725         $class->__snapshot_foreach_volume($snap, sub {
 726             my ($vs, $volume) = @_;
 727
 728             $class->__snapshot_create_vol_snapshot($vmid, $vs, $volume, $snapname);
 729             $drivehash->{$vs} = 1;
 730         });
 731     };
 732     my $err = $@;
 733
 734     if ($running) {
 735         $class->__snapshot_create_vol_snapshots_hook($vmid, $snap, $running, "after");
 736         if ($freezefs) {
 737             $class->__snapshot_freeze($vmid, 1);
 738         }
 739         $class->__snapshot_create_vol_snapshots_hook($vmid, $snap, $running, "after-unfreeze");
 740     }
 741
 742     if ($err) {
 743         warn "snapshot create failed: starting cleanup\n";
 744         eval { $class->snapshot_delete($vmid, $snapname, 1, $drivehash); };
 745         warn "$@" if $@;
 746         die "$err\n";
 747     }
 748
 749     $class->__snapshot_commit($vmid, $snapname);
 750 }
 751
 752 # Deletes a snapshot.
 753 # Note: $drivehash is only set when called from snapshot_create.
 754 sub snapshot_delete {
 755     my ($class, $vmid, $snapname, $force, $drivehash) = @_;
 756
 757     my $prepare = 1;
 758
 759     my $unused = [];
 760
 761     my $conf = $class->load_config($vmid);
 762     my $snap = $conf->{snapshots}->{$snapname};
 763
 764     die "snapshot '$snapname' does not exist\n" if !defined($snap);
 765
 766     $class->set_lock($vmid, 'snapshot-delete')
 767         if (!$drivehash); # doesn't already have a 'snapshot' lock
 768
 769     my $unlink_parent = sub {
 770         my ($confref, $new_parent) = @_;
 771
 772         if ($confref->{parent} && $confref->{parent} eq $snapname) {
 773             if ($new_parent) {
 774                 $confref->{parent} = $new_parent;
 775             } else {
 776                 delete $confref->{parent};
 777             }
 778         }
 779     };
 780
 781     my $remove_drive = sub {
 782         my ($drive) = @_;
 783
 784         my $conf = $class->load_config($vmid);
 785         $snap = $conf->{snapshots}->{$snapname};
 786         die "snapshot '$snapname' does not exist\n" if !defined($snap);
 787
 788         $class->__snapshot_delete_remove_drive($snap, $drive);
 789
 790         $class->write_config($vmid, $conf);
 791     };
 792
 793     #prepare
 794     $class->lock_config($vmid, sub {
 795         my $conf = $class->load_config($vmid);
 796
 797         die "you can't delete a snapshot if vm is a template\n"
 798             if $class->is_template($conf);
 799
 800         $snap = $conf->{snapshots}->{$snapname};
 801         die "snapshot '$snapname' does not exist\n" if !defined($snap);
 802
 803         $snap->{snapstate} = 'delete';
 804
 805         $class->write_config($vmid, $conf);
 806     });
 807
 808     # now remove vmstate file
 809     if ($snap->{vmstate}) {
 810         $class->__snapshot_delete_vmstate_file($snap, $force);
 811
 812         # save changes (remove vmstate from snapshot)
 813         $class->lock_config($vmid, $remove_drive, 'vmstate') if !$force;
 814     };
 815
 816     # now remove all volume snapshots
 817     $class->__snapshot_foreach_volume($snap, sub {
 818         my ($vs, $volume) = @_;
 819
 820         return if $snapname eq 'vzdump' && $vs ne 'rootfs' && !$volume->{backup};
 821         if (!$drivehash || $drivehash->{$vs}) {
 822             eval { $class->__snapshot_delete_vol_snapshot($vmid, $vs, $volume, $snapname, $unused); };
 823             if (my $err = $@) {
 824                 die $err if !$force;
 825                 warn $err;
 826             }
 827         }
 828
 829         # save changes (remove drive from snapshot)
 830         $class->lock_config($vmid, $remove_drive, $vs) if !$force;
 831     });
 832
 833     # now cleanup config
 834     $class->lock_config($vmid, sub {
 835         my $conf = $class->load_config($vmid);
 836         $snap = $conf->{snapshots}->{$snapname};
 837         die "snapshot '$snapname' does not exist\n" if !defined($snap);
 838
 839         # remove parent refs
 840         &$unlink_parent($conf, $snap->{parent});
 841         foreach my $sn (keys %{$conf->{snapshots}}) {
 842             next if $sn eq $snapname;
 843             &$unlink_parent($conf->{snapshots}->{$sn}, $snap->{parent});
 844         }
 845
 846
 847         delete $conf->{snapshots}->{$snapname};
 848         delete $conf->{lock};
 849         foreach my $volid (@$unused) {
 850             $class->add_unused_volume($conf, $volid);
 851         }
 852
 853         $class->write_config($vmid, $conf);
 854     });
 855 }
 856
 857 # Rolls back to a given snapshot.
 858 sub snapshot_rollback {
 859     my ($class, $vmid, $snapname) = @_;
 860
 861     my $prepare = 1;
 862
 863     my $storecfg = PVE::Storage::config();
 864
 865     my $conf = $class->load_config($vmid);
 866
 867     my $get_snapshot_config = sub {
 868
 869         die "you can't rollback if vm is a template\n" if $class->is_template($conf);
 870
 871         my $res = $conf->{snapshots}->{$snapname};
 872
 873         die "snapshot '$snapname' does not exist\n" if !defined($res);
 874
 875         return $res;
 876     };
 877
 878     my $repl_conf = PVE::ReplicationConfig->new();
 879     if ($repl_conf->check_for_existing_jobs($vmid, 1)) {
 880         # remove all replication snapshots
 881         my $volumes = $class->get_replicatable_volumes($storecfg, $vmid, $conf, 1);
 882         my $sorted_volids = [ sort keys %$volumes ];
 883
 884         # remove all local replication snapshots (jobid => undef)
 885         my $logfunc = sub { my $line = shift; chomp $line; print "$line\n"; };
 886         PVE::Replication::prepare($storecfg, $sorted_volids, undef, 0, undef, $logfunc);
 887     }
 888
 889     my $snap = &$get_snapshot_config();
 890
 891     $class->__snapshot_foreach_volume($snap, sub {
 892         my ($vs, $volume) = @_;
 893
 894         $class->__snapshot_rollback_vol_possible($volume, $snapname);
 895     });
 896
 897     my $data = {};
 898
 899     my $updatefn = sub {
 900
 901         $conf = $class->load_config($vmid);
 902
 903         $snap = &$get_snapshot_config();
 904
 905         die "unable to rollback to incomplete snapshot (snapstate = $snap->{snapstate})\n"
 906             if $snap->{snapstate};
 907
 908         if ($prepare) {
 909             $class->check_lock($conf);
 910             $class->__snapshot_rollback_vm_stop($vmid);
 911         }
 912
 913         die "unable to rollback vm $vmid: vm is running\n"
 914             if $class->__snapshot_check_running($vmid);
 915
 916         if ($prepare) {
 917             $conf->{lock} = 'rollback';
 918         } else {
 919             die "got wrong lock\n" if !($conf->{lock} && $conf->{lock} eq 'rollback');
 920             delete $conf->{lock};
 921
 922             my $unused = $class->__snapshot_rollback_get_unused($conf, $snap);
 923
 924             foreach my $volid (@$unused) {
 925                 $class->add_unused_volume($conf, $volid);
 926             }
 927
 928             # copy snapshot config to current config
 929             $conf = $class->__snapshot_apply_config($conf, $snap);
 930             $conf->{parent} = $snapname;
 931         }
 932
 933         $class->__snapshot_rollback_hook($vmid, $conf, $snap, $prepare, $data);
 934
 935         $class->write_config($vmid, $conf);
 936
 937         if (!$prepare && $snap->{vmstate}) {
 938             $class->__snapshot_rollback_vm_start($vmid, $snap->{vmstate}, $data);
 939         }
 940     };
 941
 942     $class->lock_config($vmid, $updatefn);
 943
 944     $class->__snapshot_foreach_volume($snap, sub {
 945         my ($vs, $volume) = @_;
 946
 947         $class->__snapshot_rollback_vol_rollback($volume, $snapname);
 948     });
 949
 950     $prepare = 0;
 951     $class->lock_config($vmid, $updatefn);
 952 }
 953
 954 # bash completion helper
 955
 956 sub snapshot_list {
 957     my ($class, $vmid) = @_;
 958
 959     my $snapshot = eval {
 960         my $conf = $class->load_config($vmid);
 961         my $snapshots = $conf->{snapshots} || [];
 962         [ sort keys %$snapshots ]
 963     } || [];
 964
 965     return $snapshot;
 966 }
 967
 968 1;