PVE/ReplicationState.pm

   1 package PVE::ReplicationState;
   2
   3 use warnings;
   4 use strict;
   5 use JSON;
   6
   7 use PVE::INotify;
   8 use PVE::ProcFSTools;
   9 use PVE::Tools;
  10 use PVE::CalendarEvent;
  11 use PVE::Cluster;
  12 use PVE::GuestHelpers;
  13 use PVE::ReplicationConfig;
  14
  15 # Note: regression tests can overwrite $state_path for testing
  16 our $state_path = "/var/lib/pve-manager/pve-replication-state.json";
  17 our $state_lock = "/var/lib/pve-manager/pve-replication-state.lck";
  18 our $replicate_logdir = "/var/log/pve/replicate";
  19
  20 # regression tests should overwrite this
  21 sub job_logfile_name {
  22     my ($jobid) = @_;
  23
  24     return "${replicate_logdir}/$jobid";
  25 }
  26
  27 # Note: We use PVE::Tools::file_set_contents to write state file atomically,
  28 # so read_state() always returns an consistent copy (even when not locked).
  29
  30 sub read_state {
  31
  32     return {} if ! -e $state_path;
  33
  34     my $raw = PVE::Tools::file_get_contents($state_path);
  35
  36     return {} if $raw eq '';
  37
  38     # untaint $raw
  39     if ($raw =~ m/^({.*})$/) {
  40         return decode_json($1);
  41     }
  42
  43     die "invalid json data in '$state_path'\n";
  44 }
  45
  46 sub extract_job_state {
  47     my ($stateobj, $jobcfg) = @_;
  48
  49     my $plugin = PVE::ReplicationConfig->lookup($jobcfg->{type});
  50
  51     my $vmid = $jobcfg->{guest};
  52     my $tid = $plugin->get_unique_target_id($jobcfg);
  53     my $state = $stateobj->{$vmid}->{$tid};
  54
  55     $state = {} if !$state;
  56
  57     $state->{last_iteration} //= 0;
  58     $state->{last_try} //= 0; # last sync start time
  59     $state->{last_sync} //= 0; # last successful sync start time
  60     $state->{fail_count} //= 0;
  61
  62     return $state;
  63 }
  64
  65 sub extract_vmid_tranfer_state {
  66     my ($stateobj, $vmid, $old_target, $new_target) = @_;
  67
  68     my $oldid = PVE::ReplicationConfig::Cluster->get_unique_target_id({ target => $old_target });
  69     my $newid = PVE::ReplicationConfig::Cluster->get_unique_target_id({ target => $new_target });
  70
  71     if (defined(my $vmstate = $stateobj->{$vmid})) {
  72         $vmstate->{$newid} = delete($vmstate->{$oldid}) if defined($vmstate->{$oldid});
  73         return $vmstate;
  74     }
  75
  76     return {};
  77 }
  78
  79 sub read_job_state {
  80     my ($jobcfg) = @_;
  81
  82     my $stateobj = read_state();
  83     return extract_job_state($stateobj, $jobcfg);
  84 }
  85
  86 # update state for a single job
  87 # pass $state = undef to delete the job state completely
  88 sub write_job_state {
  89     my ($jobcfg, $state) = @_;
  90
  91     my $plugin = PVE::ReplicationConfig->lookup($jobcfg->{type});
  92
  93     my $vmid = $jobcfg->{guest};
  94     my $tid = $plugin->get_unique_target_id($jobcfg);
  95
  96     my $update = sub {
  97
  98         my $stateobj = read_state();
  99         # Note: tuple ($vmid, $tid) is unique
 100         if (defined($state)) {
 101             $stateobj->{$vmid}->{$tid} = $state;
 102         } else {
 103             delete $stateobj->{$vmid}->{$tid};
 104             delete $stateobj->{$vmid} if !%{$stateobj->{$vmid}};
 105         }
 106         PVE::Tools::file_set_contents($state_path, encode_json($stateobj));
 107     };
 108
 109     my $code = sub {
 110         PVE::Tools::lock_file($state_lock, 10, $update);
 111         die $@ if $@;
 112     };
 113
 114     # make sure we have guest_migration_lock during update
 115     PVE::GuestHelpers::guest_migration_lock($vmid, undef, $code);
 116 }
 117
 118 # update all job states related to a specific $vmid
 119 sub write_vmid_job_states {
 120     my ($vmid_state, $vmid) = @_;
 121
 122     my $update = sub {
 123         my $stateobj = read_state();
 124         $stateobj->{$vmid} = $vmid_state;
 125         PVE::Tools::file_set_contents($state_path, encode_json($stateobj));
 126     };
 127
 128     my $code = sub {
 129         PVE::Tools::lock_file($state_lock, 10, $update);
 130         die $@ if $@;
 131     };
 132
 133     # make sure we have guest_migration_lock during update
 134     PVE::GuestHelpers::guest_migration_lock($vmid, undef, $code);
 135 }
 136
 137 sub record_job_start {
 138     my ($jobcfg, $state, $start_time, $iteration) = @_;
 139
 140     $state->{pid} = $$;
 141     $state->{ptime} = PVE::ProcFSTools::read_proc_starttime($state->{pid});
 142     $state->{last_node} = PVE::INotify::nodename();
 143     $state->{last_try} = $start_time;
 144     $state->{last_iteration} = $iteration;
 145     $state->{storeid_list} //= [];
 146
 147     write_job_state($jobcfg, $state);
 148 }
 149
 150 sub record_job_end {
 151     my ($jobcfg, $state, $start_time, $duration, $err) = @_;
 152
 153     $state->{duration} = $duration;
 154     delete $state->{pid};
 155     delete $state->{ptime};
 156
 157     if ($err) {
 158         chomp $err;
 159         $state->{fail_count}++;
 160         $state->{error} = "$err";
 161     } else {
 162         $state->{last_sync} = $start_time;
 163         $state->{fail_count} = 0;
 164         delete $state->{error};
 165     }
 166     write_job_state($jobcfg,  $state);
 167 }
 168
 169 sub replication_snapshot_name {
 170     my ($jobid, $last_sync) = @_;
 171
 172     my $prefix = "__replicate_${jobid}_";
 173     my $snapname = "${prefix}${last_sync}__";
 174
 175     wantarray ? ($prefix, $snapname) : $snapname;
 176 }
 177
 178 sub purge_old_states {
 179
 180     my $local_node = PVE::INotify::nodename();
 181
 182     my $cfg = PVE::ReplicationConfig->new();
 183     my $vms = PVE::Cluster::get_vmlist();
 184
 185     my $used_tids = {};
 186
 187     foreach my $jobid (sort keys %{$cfg->{ids}}) {
 188         my $jobcfg = $cfg->{ids}->{$jobid};
 189         my $plugin = PVE::ReplicationConfig->lookup($jobcfg->{type});
 190         my $tid = $plugin->get_unique_target_id($jobcfg);
 191         my $vmid = $jobcfg->{guest};
 192         $used_tids->{$vmid}->{$tid} = 1
 193             if defined($vms->{ids}->{$vmid}); # && $vms->{ids}->{$vmid}->{node} eq $local_node;
 194     }
 195
 196     my $purge_state = sub {
 197         my $stateobj = read_state();
 198         my $next_stateobj = {};
 199
 200         foreach my $vmid (keys %$stateobj) {
 201             foreach my $tid (keys %{$stateobj->{$vmid}}) {
 202                 $next_stateobj->{$vmid}->{$tid} = $stateobj->{$vmid}->{$tid} if $used_tids->{$vmid}->{$tid};
 203             }
 204         }
 205         PVE::Tools::file_set_contents($state_path, encode_json($next_stateobj));
 206     };
 207
 208     PVE::Tools::lock_file($state_lock, 10, $purge_state);
 209     die $@ if $@;
 210 }
 211
 212 sub job_status {
 213
 214     my $local_node = PVE::INotify::nodename();
 215
 216     my $jobs = {};
 217
 218     my $stateobj = read_state();
 219
 220     my $cfg = PVE::ReplicationConfig->new();
 221
 222     my $vms = PVE::Cluster::get_vmlist();
 223
 224     foreach my $jobid (sort keys %{$cfg->{ids}}) {
 225         my $jobcfg = $cfg->{ids}->{$jobid};
 226         my $vmid = $jobcfg->{guest};
 227
 228         die "internal error - not implemented" if $jobcfg->{type} ne 'local';
 229
 230         # skip non existing vms
 231         next if !$vms->{ids}->{$vmid};
 232
 233         # only consider guest on local node
 234         next if $vms->{ids}->{$vmid}->{node} ne $local_node;
 235
 236         if (!$jobcfg->{remove_job}) {
 237             # never sync to local node
 238             next if $jobcfg->{target} eq $local_node;
 239
 240             next if $jobcfg->{disable};
 241         }
 242
 243         my $state = extract_job_state($stateobj, $jobcfg);
 244         $jobcfg->{state} = $state;
 245         $jobcfg->{id} = $jobid;
 246         $jobcfg->{vmtype} = $vms->{ids}->{$vmid}->{type};
 247
 248         my $next_sync = 0;
 249
 250         if ($jobcfg->{remove_job}) {
 251             $next_sync = 1; # lowest possible value
 252             # todo: consider fail_count? How many retries?
 253         } else  {
 254             if (my $fail_count = $state->{fail_count}) {
 255                 if ($fail_count < 3) {
 256                     $next_sync = $state->{last_try} + 5*60*$fail_count;
 257                 }
 258             } else {
 259                 my $schedule =  $jobcfg->{schedule} || '*/15';
 260                 my $calspec = PVE::CalendarEvent::parse_calendar_event($schedule);
 261                 $next_sync = PVE::CalendarEvent::compute_next_event($calspec, $state->{last_try}) // 0;
 262             }
 263         }
 264
 265         $jobcfg->{next_sync} = $next_sync;
 266
 267         $jobs->{$jobid} = $jobcfg;
 268     }
 269
 270     return $jobs;
 271 }
 272
 273 sub get_next_job {
 274     my ($iteration, $start_time) = @_;
 275
 276     my $jobs = job_status();
 277
 278     my $sort_func = sub {
 279         my $joba = $jobs->{$a};
 280         my $jobb = $jobs->{$b};
 281         my $sa =  $joba->{state};
 282         my $sb =  $jobb->{state};
 283         my $res = $sa->{last_iteration} cmp $sb->{last_iteration};
 284         return $res if $res != 0;
 285         $res = $joba->{next_sync} <=> $jobb->{next_sync};
 286         return $res if $res != 0;
 287         return  $joba->{guest} <=> $jobb->{guest};
 288     };
 289
 290     foreach my $jobid (sort $sort_func keys %$jobs) {
 291         my $jobcfg = $jobs->{$jobid};
 292         next if $jobcfg->{state}->{last_iteration} >= $iteration;
 293         if ($jobcfg->{next_sync} && ($start_time >= $jobcfg->{next_sync})) {
 294             return $jobcfg;
 295         }
 296     }
 297
 298     return undef;
 299 }
 300
 301 1;