src/PVE/VZDump/Common.pm

   1 package PVE::VZDump::Common;
   2
   3 use strict;
   4 use warnings;
   5 use Digest::SHA;
   6
   7 use PVE::Tools;
   8 use PVE::SafeSyslog qw(syslog);
   9 use PVE::Storage;
  10 use PVE::Cluster qw(cfs_register_file);
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 cfs_register_file('vzdump.cron',
  14                   \&parse_vzdump_cron_config,
  15                   \&write_vzdump_cron_config);
  16
  17 my $dowhash_to_dow = sub {
  18     my ($d, $num) = @_;
  19
  20     my @da = ();
  21     push @da, $num ? 1 : 'mon' if $d->{mon};
  22     push @da, $num ? 2 : 'tue' if $d->{tue};
  23     push @da, $num ? 3 : 'wed' if $d->{wed};
  24     push @da, $num ? 4 : 'thu' if $d->{thu};
  25     push @da, $num ? 5 : 'fri' if $d->{fri};
  26     push @da, $num ? 6 : 'sat' if $d->{sat};
  27     push @da, $num ? 7 : 'sun' if $d->{sun};
  28
  29     return join ',', @da;
  30 };
  31
  32 my $fixup_prune_backups_option = sub {
  33     my ($opts) = @_;
  34
  35     return if !defined($opts->{'prune-backups'});
  36
  37     $opts->{'prune-backups'} = PVE::JSONSchema::parse_property_string(
  38         'prune-backups',
  39         $opts->{'prune-backups'}
  40     );
  41 };
  42
  43 # parse crontab style day of week
  44 sub parse_dow {
  45     my ($dowstr, $noerr) = @_;
  46
  47     my $dowmap = {mon => 1, tue => 2, wed => 3, thu => 4,
  48                   fri => 5, sat => 6, sun => 7};
  49     my $rdowmap = { '1' => 'mon', '2' => 'tue', '3' => 'wed', '4' => 'thu',
  50                     '5' => 'fri', '6' => 'sat', '7' => 'sun', '0' => 'sun'};
  51
  52     my $res = {};
  53
  54     $dowstr = '1,2,3,4,5,6,7' if $dowstr eq '*';
  55
  56     foreach my $day (PVE::Tools::split_list($dowstr)) {
  57         if ($day =~ m/^(mon|tue|wed|thu|fri|sat|sun)-(mon|tue|wed|thu|fri|sat|sun)$/i) {
  58             for (my $i = $dowmap->{lc($1)}; $i <= $dowmap->{lc($2)}; $i++) {
  59                 my $r = $rdowmap->{$i};
  60                 $res->{$r} = 1;
  61             }
  62         } elsif ($day =~ m/^(mon|tue|wed|thu|fri|sat|sun|[0-7])$/i) {
  63             $day = $rdowmap->{$day} if $day =~ m/\d/;
  64             $res->{lc($day)} = 1;
  65         } else {
  66             return undef if $noerr;
  67             die "unable to parse day of week '$dowstr'\n";
  68         }
  69     }
  70
  71     return $res;
  72 };
  73
  74 my $confdesc = {
  75     vmid => {
  76         type => 'string', format => 'pve-vmid-list',
  77         description => "The ID of the guest system you want to backup.",
  78         completion => \&PVE::Cluster::complete_local_vmid,
  79         optional => 1,
  80     },
  81     node => get_standard_option('pve-node', {
  82         description => "Only run if executed on this node.",
  83         completion => \&PVE::Cluster::get_nodelist,
  84         optional => 1,
  85     }),
  86     all => {
  87         type => 'boolean',
  88         description => "Backup all known guest systems on this host.",
  89         optional => 1,
  90         default => 0,
  91     },
  92     stdexcludes => {
  93         type => 'boolean',
  94         description => "Exclude temporary files and logs.",
  95         optional => 1,
  96         default => 1,
  97     },
  98     compress => {
  99         type => 'string',
 100         description => "Compress dump file.",
 101         optional => 1,
 102         enum => ['0', '1', 'gzip', 'lzo', 'zstd'],
 103         default => '0',
 104     },
 105     pigz=> {
 106         type => "integer",
 107         description => "Use pigz instead of gzip when N>0.".
 108             " N=1 uses half of cores, N>1 uses N as thread count.",
 109         optional => 1,
 110         default => 0,
 111     },
 112     zstd => {
 113         type => "integer",
 114         description => "Zstd threads. N=0 uses half of the available cores,".
 115             " N>0 uses N as thread count.",
 116         optional => 1,
 117         default => 1,
 118     },
 119     quiet => {
 120         type => 'boolean',
 121         description => "Be quiet.",
 122         optional => 1,
 123         default => 0,
 124     },
 125     mode => {
 126         type => 'string',
 127         description => "Backup mode.",
 128         optional => 1,
 129         default => 'snapshot',
 130         enum => [ 'snapshot', 'suspend', 'stop' ],
 131     },
 132     exclude => {
 133         type => 'string', format => 'pve-vmid-list',
 134         description => "Exclude specified guest systems (assumes --all)",
 135         optional => 1,
 136     },
 137     'exclude-path' => {
 138         type => 'string', format => 'string-alist',
 139         description => "Exclude certain files/directories (shell globs)." .
 140             " Paths starting with '/' are anchored to the container's root, " .
 141             " other paths match relative to each subdirectory.",
 142         optional => 1,
 143     },
 144     mailto => {
 145         type => 'string',
 146         format => 'email-or-username-list',
 147         description => "Comma-separated list of email addresses or users that should" .
 148             " receive email notifications.",
 149         optional => 1,
 150     },
 151     mailnotification => {
 152         type => 'string',
 153         description => "Specify when to send an email",
 154         optional => 1,
 155         enum => [ 'always', 'failure' ],
 156         default => 'always',
 157     },
 158     tmpdir => {
 159         type => 'string',
 160         description => "Store temporary files to specified directory.",
 161         optional => 1,
 162     },
 163     dumpdir => {
 164         type => 'string',
 165         description => "Store resulting files to specified directory.",
 166         optional => 1,
 167     },
 168     script => {
 169         type => 'string',
 170         description => "Use specified hook script.",
 171         optional => 1,
 172     },
 173     storage => get_standard_option('pve-storage-id', {
 174         description => "Store resulting file to this storage.",
 175         completion => \&complete_backup_storage,
 176         optional => 1,
 177     }),
 178     stop => {
 179         type => 'boolean',
 180         description => "Stop running backup jobs on this host.",
 181         optional => 1,
 182         default => 0,
 183     },
 184     bwlimit => {
 185         type => 'integer',
 186         description => "Limit I/O bandwidth (KBytes per second).",
 187         optional => 1,
 188         minimum => 0,
 189         default => 0,
 190     },
 191     ionice => {
 192         type => 'integer',
 193         description => "Set CFQ ionice priority.",
 194         optional => 1,
 195         minimum => 0,
 196         maximum => 8,
 197         default => 7,
 198     },
 199     lockwait => {
 200         type => 'integer',
 201         description => "Maximal time to wait for the global lock (minutes).",
 202         optional => 1,
 203         minimum => 0,
 204         default => 3*60, # 3 hours
 205     },
 206     stopwait => {
 207         type => 'integer',
 208         description => "Maximal time to wait until a guest system is stopped (minutes).",
 209         optional => 1,
 210         minimum => 0,
 211         default => 10, # 10 minutes
 212     },
 213     # FIXME remove with PVE 8.0 or PVE 9.0
 214     maxfiles => {
 215         type => 'integer',
 216         description => "Deprecated: use 'prune-backups' instead. " .
 217             "Maximal number of backup files per guest system.",
 218         optional => 1,
 219         minimum => 1,
 220     },
 221     'prune-backups' => get_standard_option('prune-backups', {
 222         description => "Use these retention options instead of those from the storage configuration.",
 223         optional => 1,
 224         default => "keep-all=1",
 225     }),
 226     remove => {
 227         type => 'boolean',
 228         description => "Prune older backups according to 'prune-backups'.",
 229         optional => 1,
 230         default => 1,
 231     },
 232     pool => {
 233         type => 'string',
 234         description => 'Backup all known guest systems included in the specified pool.',
 235         optional => 1,
 236     }
 237 };
 238
 239 sub get_confdesc {
 240     return $confdesc;
 241 }
 242
 243 # add JSON properties for create and set function
 244 sub json_config_properties {
 245     my $prop = shift;
 246
 247     foreach my $opt (keys %$confdesc) {
 248         $prop->{$opt} = $confdesc->{$opt};
 249     }
 250
 251     return $prop;
 252 }
 253
 254 my $vzdump_properties = {
 255     additionalProperties => 0,
 256     properties => json_config_properties({}),
 257 };
 258
 259 sub parse_vzdump_cron_config {
 260     my ($filename, $raw) = @_;
 261
 262     my $jobs = []; # correct jobs
 263
 264     my $ejobs = []; # mailfomerd lines
 265
 266     my $jid = 1; # we start at 1
 267
 268     my $digest = Digest::SHA::sha1_hex(defined($raw) ? $raw : '');
 269
 270     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
 271         my $line = $1;
 272
 273         next if $line =~ m/^\#/;
 274         next if $line =~ m/^\s*$/;
 275         next if $line =~ m/^PATH\s*=/; # we always overwrite path
 276
 277         if ($line =~ m|^(\d+)\s+(\d+)\s+\*\s+\*\s+(\S+)\s+root\s+(/\S+/)?(#)?vzdump(\s+(.*))?$|) {
 278             eval {
 279                 my $minute = int($1);
 280                 my $hour = int($2);
 281                 my $dow = $3;
 282                 my $param = $7;
 283                 my $enabled = $5;
 284
 285                 my $dowhash = parse_dow($dow, 1);
 286                 die "unable to parse day of week '$dow' in '$filename'\n" if !$dowhash;
 287
 288                 my $args = PVE::Tools::split_args($param);
 289                 my $opts = PVE::JSONSchema::get_options($vzdump_properties, $args, 'vmid');
 290
 291                 $opts->{enabled} = !defined($enabled);
 292                 $opts->{id} = "$digest:$jid";
 293                 $jid++;
 294                 $opts->{starttime} = sprintf "%02d:%02d", $hour, $minute;
 295                 $opts->{dow} = &$dowhash_to_dow($dowhash);
 296
 297                 $fixup_prune_backups_option->($opts); # parse the property string
 298
 299                 push @$jobs, $opts;
 300             };
 301             my $err = $@;
 302             if ($err) {
 303                 syslog ('err', "parse error in '$filename': $err");
 304                 push @$ejobs, { line => $line };
 305             }
 306         } elsif ($line =~ m|^\S+\s+(\S+)\s+\S+\s+\S+\s+\S+\s+\S+\s+(\S.*)$|) {
 307             syslog ('err', "warning: malformed line in '$filename'");
 308             push @$ejobs, { line => $line };
 309         } else {
 310             syslog ('err', "ignoring malformed line in '$filename'");
 311         }
 312     }
 313
 314     my $res = {};
 315     $res->{digest} = $digest;
 316     $res->{jobs} = $jobs;
 317     $res->{ejobs} = $ejobs;
 318
 319     return $res;
 320 }
 321
 322 sub write_vzdump_cron_config {
 323     my ($filename, $cfg) = @_;
 324
 325     my $out = "# cluster wide vzdump cron schedule\n";
 326     $out .= "# Automatically generated file - do not edit\n\n";
 327     $out .= "PATH=\"/usr/sbin:/usr/bin:/sbin:/bin\"\n\n";
 328
 329     my $jobs = $cfg->{jobs} || [];
 330     foreach my $job (@$jobs) {
 331         my $enabled = ($job->{enabled}) ? '' : '#';
 332         my $dh = parse_dow($job->{dow});
 333         my $dow;
 334         if ($dh->{mon} && $dh->{tue} && $dh->{wed} && $dh->{thu} &&
 335             $dh->{fri} && $dh->{sat} && $dh->{sun}) {
 336             $dow = '*';
 337         } else {
 338             $dow = &$dowhash_to_dow($dh, 1);
 339             $dow = '*' if !$dow;
 340         }
 341
 342         my ($hour, $minute);
 343
 344         die "no job start time specified\n" if !$job->{starttime};
 345         if ($job->{starttime} =~ m/^(\d{1,2}):(\d{1,2})$/) {
 346             ($hour, $minute) = (int($1), int($2));
 347             die "hour '$hour' out of range\n" if $hour < 0 || $hour > 23;
 348             die "minute '$minute' out of range\n" if $minute < 0 || $minute > 59;
 349         } else {
 350             die "unable to parse job start time\n";
 351         }
 352
 353         $job->{quiet} = 1; # we do not want messages from cron
 354
 355         my $cmd = command_line($job);
 356
 357         $out .= sprintf "$minute $hour * * %-11s root $enabled$cmd\n", $dow;
 358     }
 359
 360     my $ejobs = $cfg->{ejobs} || [];
 361     foreach my $job (@$ejobs) {
 362         $out .= "$job->{line}\n" if $job->{line};
 363     }
 364
 365     return $out;
 366 }
 367
 368 sub command_line {
 369     my ($param) = @_;
 370
 371     my $cmd = "vzdump";
 372
 373     if ($param->{vmid}) {
 374         $cmd .= " " . join(' ', PVE::Tools::split_list($param->{vmid}));
 375     }
 376
 377     foreach my $p (keys %$param) {
 378         next if $p eq 'id' || $p eq 'vmid' || $p eq 'starttime' ||
 379                 $p eq 'dow' || $p eq 'stdout' || $p eq 'enabled';
 380         my $v = $param->{$p};
 381         my $pd = $confdesc->{$p} || die "no such vzdump option '$p'\n";
 382         if ($p eq 'exclude-path') {
 383             foreach my $path (split(/\0/, $v || '')) {
 384                 $cmd .= " --$p " . PVE::Tools::shellquote($path);
 385             }
 386         } else {
 387             $v = join(",", PVE::Tools::split_list($v)) if $p eq 'mailto';
 388             $v = PVE::JSONSchema::print_property_string($v, 'prune-backups')
 389                 if $p eq 'prune-backups';
 390
 391             $cmd .= " --$p " . PVE::Tools::shellquote($v) if defined($v) && $v ne '';
 392         }
 393     }
 394
 395     return $cmd;
 396 }
 397
 398 # bash completion helpers
 399 sub complete_backup_storage {
 400
 401     my $cfg = PVE::Storage::config();
 402     my $ids = $cfg->{ids};
 403
 404     my $nodename = PVE::INotify::nodename();
 405
 406     my $res = [];
 407     foreach my $sid (keys %$ids) {
 408         my $scfg = $ids->{$sid};
 409         next if !PVE::Storage::storage_check_enabled($cfg, $sid, $nodename, 1);
 410         next if !$scfg->{content}->{backup};
 411         push @$res, $sid;
 412     }
 413
 414     return $res;
 415 }
 416
 417 1;