src/PVE/HA/LRM.pm

   1 package PVE::HA::LRM;
   2
   3 # Local Resource Manager
   4
   5 use strict;
   6 use warnings;
   7 use POSIX qw(:sys_wait_h);
   8
   9 use PVE::SafeSyslog;
  10 use PVE::Tools;
  11 use PVE::HA::Tools ':exit_codes';
  12 use PVE::HA::Resources;
  13
  14 # Server can have several states:
  15
  16 my $valid_states = {
  17     wait_for_agent_lock => "waiting for agent lock",
  18     active => "got agent_lock",
  19     maintenance => "going into maintenance",
  20     lost_agent_lock => "lost agent_lock",
  21 };
  22
  23 # we sleep ~10s per 'active' round, so if no services is available for >= 10 min we'd go in wait
  24 # state giving up the watchdog and the LRM lock voluntary, ensuring the WD can do no harm
  25 my $max_active_idle_rounds = 60;
  26
  27 sub new {
  28     my ($this, $haenv) = @_;
  29
  30     my $class = ref($this) || $this;
  31
  32     my $self = bless {
  33         haenv => $haenv,
  34         status => { state => 'startup' },
  35         workers => {},
  36         results => {},
  37         restart_tries => {},
  38         shutdown_request => 0,
  39         shutdown_errors => 0,
  40         # mode can be: active, reboot, shutdown, restart
  41         mode => 'active',
  42         cluster_state_update => 0,
  43         active_idle_rounds => 0,
  44     }, $class;
  45
  46     $self->set_local_status({ state =>  'wait_for_agent_lock' });
  47
  48     return $self;
  49 }
  50
  51 sub shutdown_request {
  52     my ($self) = @_;
  53
  54     return if $self->{shutdown_request}; # already in shutdown mode
  55
  56     my $haenv = $self->{haenv};
  57
  58     my $nodename = $haenv->nodename();
  59
  60     my ($shutdown, $reboot) = $haenv->is_node_shutdown();
  61
  62     my $dc_ha_cfg = $haenv->get_ha_settings();
  63     my $shutdown_policy = $dc_ha_cfg->{shutdown_policy} // 'conditional';
  64
  65     if ($shutdown) { # don't log this on service restart, only on node shutdown
  66         $haenv->log('info', "got shutdown request with shutdown policy '$shutdown_policy'");
  67     }
  68
  69     my $freeze_all;
  70     my $maintenance;
  71     if ($shutdown_policy eq 'conditional') {
  72         $freeze_all = $reboot;
  73     } elsif ($shutdown_policy eq 'freeze') {
  74         $freeze_all = 1;
  75     } elsif ($shutdown_policy eq 'failover') {
  76         $freeze_all = 0;
  77     } elsif ($shutdown_policy eq 'migrate') {
  78         $maintenance = 1;
  79     } else {
  80         $haenv->log('err', "unknown shutdown policy '$shutdown_policy', fall back to conditional");
  81         $freeze_all = $reboot;
  82     }
  83
  84     if ($maintenance) {
  85         # we get marked as unaivalable by the manager, then all services will
  86         # be migrated away, we'll still have the same "can we exit" clause than
  87         # a normal shutdown -> no running service on this node
  88         # FIXME: after X minutes, add shutdown command for remaining services,
  89         # e.g., if they have no alternative node???
  90     } elsif ($shutdown) {
  91         # *always* queue stop jobs for all services if the node shuts down,
  92         # independent if it's a reboot or a poweroff, else we may corrupt
  93         # services or hinder node shutdown
  94         my $ss = $self->{service_status};
  95
  96         foreach my $sid (keys %$ss) {
  97             my $sd = $ss->{$sid};
  98             next if !$sd->{node};
  99             next if $sd->{node} ne $nodename;
 100             # Note: use undef uid to mark shutdown/stop jobs
 101             $self->queue_resource_command($sid, undef, 'request_stop');
 102         }
 103     }
 104
 105     if ($shutdown) {
 106         my $shutdown_type = $reboot ? 'reboot' : 'shutdown';
 107         if ($maintenance) {
 108             $haenv->log('info', "$shutdown_type LRM, doing maintenance, removing this node from active list");
 109             $self->{mode} = 'maintenance';
 110         } elsif ($freeze_all) {
 111             $haenv->log('info', "$shutdown_type LRM, stop and freeze all services");
 112             $self->{mode} = 'restart';
 113         } else {
 114             $haenv->log('info', "shutdown LRM, stop all services");
 115             $self->{mode} = 'shutdown';
 116         }
 117     } else {
 118         $haenv->log('info', "restart LRM, freeze all services");
 119         $self->{mode} = 'restart';
 120     }
 121
 122     $self->{shutdown_request} = $haenv->get_time();
 123
 124     eval { $self->update_lrm_status() or die "not quorate?\n"; };
 125     if (my $err = $@) {
 126         $haenv->log('err', "unable to update lrm status file - $err");
 127     }
 128 }
 129
 130 sub get_local_status {
 131     my ($self) = @_;
 132
 133     return $self->{status};
 134 }
 135
 136 sub set_local_status {
 137     my ($self, $new) = @_;
 138
 139     die "invalid state '$new->{state}'" if !$valid_states->{$new->{state}};
 140
 141     my $haenv = $self->{haenv};
 142
 143     my $old = $self->{status};
 144
 145     # important: only update if if really changed
 146     return if $old->{state} eq $new->{state};
 147
 148     $haenv->log('info', "status change $old->{state} => $new->{state}");
 149
 150     $new->{state_change_time} = $haenv->get_time();
 151
 152     $self->{status} = $new;
 153 }
 154
 155 sub update_lrm_status {
 156     my ($self) = @_;
 157
 158     my $haenv = $self->{haenv};
 159
 160     return 0 if !$haenv->quorate();
 161
 162     my $lrm_status = {
 163         state => $self->{status}->{state},
 164         mode => $self->{mode},
 165         results => $self->{results},
 166         timestamp => $haenv->get_time(),
 167     };
 168
 169     eval { $haenv->write_lrm_status($lrm_status); };
 170     if (my $err = $@) {
 171         $haenv->log('err', "unable to write lrm status file - $err");
 172         return 0;
 173     }
 174
 175     return 1;
 176 }
 177
 178 sub update_service_status {
 179     my ($self) = @_;
 180
 181     my $haenv = $self->{haenv};
 182
 183     my $ms = eval { $haenv->read_manager_status(); };
 184     if (my $err = $@) {
 185         $haenv->log('err', "updating service status from manager failed: $err");
 186         return undef;
 187     } else {
 188         $self->{service_status} = $ms->{service_status} || {};
 189         my $nodename = $haenv->nodename();
 190         $self->{node_status} = $ms->{node_status}->{$nodename} || 'unknown';
 191         return 1;
 192     }
 193 }
 194
 195 sub get_protected_ha_agent_lock {
 196     my ($self) = @_;
 197
 198     my $haenv = $self->{haenv};
 199
 200     my $count = 0;
 201     my $starttime = $haenv->get_time();
 202
 203     for (;;) {
 204
 205         if ($haenv->get_ha_agent_lock()) {
 206             if ($self->{ha_agent_wd}) {
 207                 $haenv->watchdog_update($self->{ha_agent_wd});
 208             } else {
 209                 my $wfh = $haenv->watchdog_open();
 210                 $self->{ha_agent_wd} = $wfh;
 211             }
 212             return 1;
 213         }
 214
 215         last if ++$count > 5; # try max 5 time
 216
 217         my $delay = $haenv->get_time() - $starttime;
 218         last if $delay > 5; # for max 5 seconds
 219
 220         $haenv->sleep(1);
 221     }
 222
 223     return 0;
 224 }
 225
 226 # only cares if any service has the local node as their node, independent of which req.state it is
 227 sub has_configured_service_on_local_node {
 228     my ($self) = @_;
 229
 230     my $haenv = $self->{haenv};
 231     my $nodename = $haenv->nodename();
 232
 233     my $ss = $self->{service_status};
 234     foreach my $sid (keys %$ss) {
 235         my $sd = $ss->{$sid};
 236         next if !$sd->{node} || $sd->{node} ne $nodename;
 237
 238         return 1;
 239     }
 240     return 0;
 241 }
 242
 243 sub is_fence_requested {
 244     my ($self) = @_;
 245
 246     my $haenv = $self->{haenv};
 247
 248     my $nodename = $haenv->nodename();
 249     my $ss = $self->{service_status};
 250
 251     my $fenced_services = PVE::HA::Tools::count_fenced_services($ss, $nodename);
 252
 253     return $fenced_services || $self->{node_status} eq 'fence';
 254 }
 255
 256 sub active_service_count {
 257     my ($self) = @_;
 258
 259     my $haenv = $self->{haenv};
 260     my $nodename = $haenv->nodename();
 261
 262     my $ss = $self->{service_status};
 263
 264     my $count = 0;
 265     foreach my $sid (keys %$ss) {
 266         my $sd = $ss->{$sid};
 267         next if !$sd->{node};
 268         next if $sd->{node} ne $nodename;
 269         my $req_state = $sd->{state};
 270         next if !defined($req_state);
 271         next if $req_state eq 'stopped';
 272         # NOTE: 'ignored' ones are already dropped by the manager from service_status
 273         next if $req_state eq 'freeze';
 274         # erroneous services are not managed by HA, don't count them as active
 275         next if $req_state eq 'error';
 276
 277         $count++;
 278     }
 279
 280     return $count;
 281 }
 282
 283 my $wrote_lrm_status_at_startup = 0;
 284
 285 sub do_one_iteration {
 286     my ($self) = @_;
 287
 288     my $haenv = $self->{haenv};
 289
 290     $haenv->loop_start_hook();
 291
 292     $self->{cluster_state_update} = $haenv->cluster_state_update();
 293
 294     my $res = $self->work();
 295
 296     $haenv->loop_end_hook();
 297
 298     return $res;
 299 }
 300
 301 # NOTE: this is disabling the self-fence mechanism, so it must NOT be called with active services
 302 # It's normally *only* OK on graceful shutdown (with no services, or all services frozen)
 303 my sub give_up_watchdog_protection {
 304     my ($self) = @_;
 305
 306     if ($self->{ha_agent_wd}) {
 307         $self->{haenv}->watchdog_close($self->{ha_agent_wd});
 308         delete $self->{ha_agent_wd}; # only delete after close!
 309     }
 310 }
 311
 312 sub work {
 313     my ($self) = @_;
 314
 315     my $haenv = $self->{haenv};
 316
 317     if (!$wrote_lrm_status_at_startup) {
 318         if ($self->update_lrm_status()) {
 319             $wrote_lrm_status_at_startup = 1;
 320         } else {
 321             # do nothing
 322             $haenv->sleep(5);
 323             return $self->{shutdown_request} ? 0 : 1;
 324         }
 325     }
 326
 327     my $status = $self->get_local_status();
 328     my $state = $status->{state};
 329
 330     $self->update_service_status();
 331
 332     my $fence_request = $self->is_fence_requested();
 333
 334     # do state changes first
 335
 336     my $ctime = $haenv->get_time();
 337
 338     if ($state eq 'wait_for_agent_lock') {
 339
 340         my $service_count = $self->active_service_count();
 341
 342         if (!$fence_request && $service_count && $haenv->quorate()) {
 343             if ($self->get_protected_ha_agent_lock()) {
 344                 $self->set_local_status({ state => 'active' });
 345             }
 346         }
 347
 348     } elsif ($state eq 'lost_agent_lock') {
 349
 350         if (!$fence_request && $haenv->quorate()) {
 351             if ($self->get_protected_ha_agent_lock()) {
 352                 $self->set_local_status({ state => 'active' });
 353             }
 354         }
 355
 356     } elsif ($state eq 'active') {
 357
 358         if ($fence_request) {
 359             $haenv->log('err', "node need to be fenced - releasing agent_lock\n");
 360             $self->set_local_status({ state => 'lost_agent_lock'});
 361         } elsif (!$self->get_protected_ha_agent_lock()) {
 362             $self->set_local_status({ state => 'lost_agent_lock'});
 363         } elsif ($self->{mode} eq 'maintenance') {
 364             $self->set_local_status({ state => 'maintenance'});
 365         } else {
 366             if (!$self->has_configured_service_on_local_node() && !$self->run_workers()) {
 367                 # no active service configured for this node and all (old) workers are done
 368                 $self->{active_idle_rounds}++;
 369                 if ($self->{active_idle_rounds} > $max_active_idle_rounds) {
 370                     $haenv->log('info', "node had no service configured for $max_active_idle_rounds rounds, going idle.\n");
 371                     # safety: no active service & no running worker for quite some time -> OK
 372                     $haenv->release_ha_agent_lock();
 373                     give_up_watchdog_protection($self);
 374                     $self->set_local_status({ state => 'wait_for_agent_lock'});
 375                     $self->{active_idle_rounds} = 0;
 376                 }
 377             } elsif ($self->{active_idle_rounds}) {
 378                 $self->{active_idle_rounds} = 0;
 379             }
 380         }
 381     } elsif ($state eq 'maintenance') {
 382
 383         if ($fence_request) {
 384             $haenv->log('err', "node need to be fenced during maintenance mode - releasing agent_lock\n");
 385             $self->set_local_status({ state => 'lost_agent_lock'});
 386         } elsif (!$self->get_protected_ha_agent_lock()) {
 387             $self->set_local_status({ state => 'lost_agent_lock'});
 388         }
 389     }
 390
 391     $status = $self->get_local_status();
 392     $state = $status->{state};
 393
 394     # do work
 395
 396     if ($state eq 'wait_for_agent_lock') {
 397
 398         return 0 if $self->{shutdown_request};
 399
 400         $self->update_lrm_status();
 401
 402         $haenv->sleep(5);
 403
 404     } elsif ($state eq 'active') {
 405
 406         my $startime = $haenv->get_time();
 407
 408         my $max_time = 10;
 409
 410         my $shutdown = 0;
 411
 412         # do work (max_time seconds)
 413         eval {
 414             # fixme: set alert timer
 415
 416             # if we could not get the current service status there's no point
 417             # in doing anything, try again next round.
 418             return if !$self->update_service_status();
 419
 420             if ($self->{shutdown_request}) {
 421
 422                 if ($self->{mode} eq 'restart') {
 423
 424                     my $service_count = $self->active_service_count();
 425
 426                     if ($service_count == 0) {
 427                         if ($self->run_workers() == 0) {
 428                             # safety: no active services or workers -> OK
 429                             give_up_watchdog_protection($self);
 430                             $shutdown = 1;
 431
 432                             # restart with no or freezed services, release the lock
 433                             $haenv->release_ha_agent_lock();
 434                         }
 435                     }
 436                 } else {
 437
 438                     if ($self->run_workers() == 0) {
 439                         if ($self->{shutdown_errors} == 0) {
 440                             # safety: no active services and LRM shutdown -> OK
 441                             give_up_watchdog_protection($self);
 442
 443                             # shutdown with all services stopped thus release the lock
 444                             $haenv->release_ha_agent_lock();
 445                         }
 446
 447                         $shutdown = 1;
 448                     }
 449                 }
 450             } else {
 451                 if (!$self->{cluster_state_update}) {
 452                     # update failed but we could still renew our lock (cfs restart?),
 453                     # safely skip manage and expect to update just fine next round
 454                     $haenv->log('notice', "temporary inconsistent cluster state " .
 455                                 "(cfs restart?), skip round");
 456                     return;
 457                 }
 458
 459                 $self->manage_resources();
 460
 461             }
 462         };
 463         if (my $err = $@) {
 464             $haenv->log('err', "got unexpected error - $err");
 465         }
 466
 467         $self->update_lrm_status();
 468
 469         return 0 if $shutdown;
 470
 471         $haenv->sleep_until($startime + $max_time);
 472
 473     } elsif ($state eq 'lost_agent_lock') {
 474
 475         # NOTE: watchdog is active an will trigger soon!
 476         # so we hope to get the lock back soon!
 477         if ($self->{shutdown_request}) {
 478
 479             my $service_count = $self->active_service_count();
 480
 481             if ($service_count > 0) {
 482                 $haenv->log('err', "get shutdown request in state 'lost_agent_lock' - " .
 483                             "detected $service_count running services");
 484
 485                 if ($self->{mode} eq 'restart') {
 486                     my $state_mt = $self->{status}->{state_change_time};
 487
 488                     # watchdog should have already triggered, so either it's set
 489                     # set to noboot or it failed. As we are in restart mode, and
 490                     # have infinity stoptimeout -> exit now - we don't touch  services
 491                     # or change state, so this is save, relatively speaking
 492                     if (($haenv->get_time() - $state_mt) > 90) {
 493                         $haenv->log('err', "lost agent lock and restart request for over 90 seconds - giving up!");
 494                         return 0;
 495                     }
 496                 }
 497             } else {
 498                 # safety: all services are stopped, so we can close the watchdog
 499                 give_up_watchdog_protection($self);
 500
 501                 return 0;
 502             }
 503         }
 504
 505         $haenv->sleep(5);
 506
 507     } elsif ($state eq 'maintenance') {
 508
 509         my $startime = $haenv->get_time();
 510         return if !$self->update_service_status();
 511
 512         # wait until all active services moved away
 513         my $service_count = $self->active_service_count();
 514
 515         my $exit_lrm = 0;
 516
 517         if ($self->{shutdown_request}) {
 518             if ($service_count == 0 && $self->run_workers() == 0) {
 519                 # safety: going into maintenance and all active services got moved -> OK
 520                 give_up_watchdog_protection($self);
 521
 522                 $exit_lrm = 1;
 523
 524                 # restart with no or freezed services, release the lock
 525                 $haenv->release_ha_agent_lock();
 526             }
 527         }
 528
 529         $self->manage_resources() if !$exit_lrm;
 530
 531         $self->update_lrm_status();
 532
 533         return 0 if $exit_lrm;
 534
 535         $haenv->sleep_until($startime + 5);
 536
 537     } else {
 538
 539         die "got unexpected status '$state'\n";
 540
 541     }
 542
 543     return 1;
 544 }
 545
 546 sub run_workers {
 547     my ($self) = @_;
 548
 549     my $haenv = $self->{haenv};
 550
 551     my $starttime = $haenv->get_time();
 552
 553     # number of workers to start, if 0 we exec the command directly witouth forking
 554     my $max_workers = $haenv->get_max_workers();
 555
 556     my $sc = $haenv->read_service_config();
 557
 558     while (($haenv->get_time() - $starttime) < 5) {
 559         my $count = $self->check_active_workers();
 560
 561         foreach my $sid (sort keys %{$self->{workers}}) {
 562             last if $count >= $max_workers && $max_workers > 0;
 563
 564             my $w = $self->{workers}->{$sid};
 565             next if $w->{pid};
 566
 567             # only fork if we may, else call exec_resource_agent directly (e.g. for tests)
 568             if ($max_workers > 0) {
 569                 my $pid = fork();
 570                 if (!defined($pid)) {
 571                     $haenv->log('err', "forking worker failed - $!");
 572                     $count = 0; last; # abort, try later
 573                 } elsif ($pid == 0) {
 574                     $haenv->after_fork(); # cleanup
 575
 576                     # do work
 577                     my $res = -1;
 578                     eval {
 579                         $res = $self->exec_resource_agent($sid, $sc->{$sid}, $w->{state}, $w->{params});
 580                     };
 581                     if (my $err = $@) {
 582                         $haenv->log('err', $err);
 583                         POSIX::_exit(-1);
 584                     }
 585                     POSIX::_exit($res);
 586                 } else {
 587                     $count++;
 588                     $w->{pid} = $pid;
 589                 }
 590             } else {
 591                 my $res = -1;
 592                 eval {
 593                     $res = $self->exec_resource_agent($sid, $sc->{$sid}, $w->{state}, $w->{params});
 594                     $res = $res << 8 if $res > 0;
 595                 };
 596                 if (my $err = $@) {
 597                     $haenv->log('err', $err);
 598                 }
 599                 if (defined($w->{uid})) {
 600                     $self->resource_command_finished($sid, $w->{uid}, $res);
 601                 } else {
 602                     $self->stop_command_finished($sid, $res);
 603                 }
 604             }
 605         }
 606
 607         last if !$count;
 608
 609         $haenv->sleep(1);
 610     }
 611
 612     return scalar(keys %{$self->{workers}});
 613 }
 614
 615 sub manage_resources {
 616     my ($self) = @_;
 617
 618     my $haenv = $self->{haenv};
 619
 620     my $nodename = $haenv->nodename();
 621
 622     my $ss = $self->{service_status};
 623
 624     foreach my $sid (keys %{$self->{restart_tries}}) {
 625         delete $self->{restart_tries}->{$sid} if !$ss->{$sid};
 626     }
 627
 628     foreach my $sid (keys %$ss) {
 629         my $sd = $ss->{$sid};
 630         next if !$sd->{node};
 631         next if !$sd->{uid};
 632         next if $sd->{node} ne $nodename;
 633         my $req_state = $sd->{state};
 634         next if !defined($req_state);
 635         # can only happen for restricted groups where the failed node itself needs to be the
 636         # reocvery target. Always let the master first do so, it will then marked as 'stopped' and
 637         # we can just continue normally. But we must NOT do anything with it while still in recovery
 638         next if $req_state eq 'recovery';
 639         next if $req_state eq 'freeze';
 640
 641         $self->queue_resource_command($sid, $sd->{uid}, $req_state, {
 642             'target' => $sd->{target},
 643             'timeout' => $sd->{timeout},
 644         });
 645     }
 646
 647     return $self->run_workers();
 648 }
 649
 650 sub queue_resource_command {
 651     my ($self, $sid, $uid, $state, $params) = @_;
 652
 653     # do not queue the excatly same command twice as this may lead to
 654     # an inconsistent HA state when the first command fails but the CRM
 655     # does not process its failure right away and the LRM starts a second
 656     # try, without the CRM knowing of it (race condition)
 657     # The 'stopped' command is an exception as we do not process its result
 658     # in the CRM and we want to execute it always (even with no active CRM)
 659     return if $state ne 'stopped' && $uid && defined($self->{results}->{$uid});
 660
 661     if (my $w = $self->{workers}->{$sid}) {
 662         return if $w->{pid}; # already started
 663         # else, delete and overwrite queue entry with new command
 664         delete $self->{workers}->{$sid};
 665     }
 666
 667     $self->{workers}->{$sid} = {
 668         sid => $sid,
 669         uid => $uid,
 670         state => $state,
 671     };
 672
 673     $self->{workers}->{$sid}->{params} = $params if $params;
 674 }
 675
 676 sub check_active_workers {
 677     my ($self) = @_;
 678
 679     # finish/count workers
 680     my $count = 0;
 681     foreach my $sid (keys %{$self->{workers}}) {
 682         my $w = $self->{workers}->{$sid};
 683         if (my $pid = $w->{pid}) {
 684             # check status
 685             my $waitpid = waitpid($pid, WNOHANG);
 686             if (defined($waitpid) && ($waitpid == $pid)) {
 687                 if (defined($w->{uid})) {
 688                     $self->resource_command_finished($sid, $w->{uid}, $?);
 689                 } else {
 690                     $self->stop_command_finished($sid, $?);
 691                 }
 692             } else {
 693                 $count++;
 694             }
 695         }
 696     }
 697
 698     return $count;
 699 }
 700
 701 sub stop_command_finished {
 702     my ($self, $sid, $status) = @_;
 703
 704     my $haenv = $self->{haenv};
 705
 706     my $w = delete $self->{workers}->{$sid};
 707     return if !$w; # should not happen
 708
 709     my $exit_code = -1;
 710
 711     if ($status == -1) {
 712         $haenv->log('err', "resource agent $sid finished - failed to execute");
 713     }  elsif (my $sig = ($status & 127)) {
 714         $haenv->log('err', "resource agent $sid finished - got signal $sig");
 715     } else {
 716         $exit_code = ($status >> 8);
 717     }
 718
 719     if ($exit_code != 0) {
 720         $self->{shutdown_errors}++;
 721     }
 722 }
 723
 724 sub resource_command_finished {
 725     my ($self, $sid, $uid, $status) = @_;
 726
 727     my $haenv = $self->{haenv};
 728
 729     my $w = delete $self->{workers}->{$sid};
 730     return if !$w; # should not happen
 731
 732     my $exit_code = -1;
 733
 734     if ($status == -1) {
 735         $haenv->log('err', "resource agent $sid finished - failed to execute");
 736     }  elsif (my $sig = ($status & 127)) {
 737         $haenv->log('err', "resource agent $sid finished - got signal $sig");
 738     } else {
 739         $exit_code = ($status >> 8);
 740     }
 741
 742     $exit_code = $self->handle_service_exitcode($sid, $w->{state}, $exit_code);
 743
 744     return if $exit_code == ETRY_AGAIN; # tell nobody, simply retry
 745
 746     $self->{results}->{$uid} = {
 747         sid => $w->{sid},
 748         state => $w->{state},
 749         exit_code => $exit_code,
 750     };
 751
 752     my $ss = $self->{service_status};
 753
 754     # compute hash of valid/existing uids
 755     my $valid_uids = {};
 756     foreach my $sid (keys %$ss) {
 757         my $sd = $ss->{$sid};
 758         next if !$sd->{uid};
 759         $valid_uids->{$sd->{uid}} = 1;
 760     }
 761
 762     my $results = {};
 763     foreach my $id (keys %{$self->{results}}) {
 764         next if !$valid_uids->{$id};
 765         $results->{$id} = $self->{results}->{$id};
 766     }
 767     $self->{results} = $results;
 768 }
 769
 770 # processes the exit code from a finished resource agent, so that the CRM knows
 771 # if the LRM wants to retry an action based on the current recovery policies for
 772 # the failed service, or the CRM itself must try to recover from the failure.
 773 sub handle_service_exitcode {
 774     my ($self, $sid, $cmd, $exit_code) = @_;
 775
 776     my $haenv = $self->{haenv};
 777     my $tries = $self->{restart_tries};
 778
 779     my $sc = $haenv->read_service_config();
 780
 781     my $max_restart = 0;
 782
 783     if (my $cd = $sc->{$sid}) {
 784         $max_restart = $cd->{max_restart};
 785     }
 786
 787     if ($cmd eq 'started') {
 788
 789         if ($exit_code == SUCCESS) {
 790
 791             $tries->{$sid} = 0;
 792
 793             return $exit_code;
 794
 795         } elsif ($exit_code == ERROR) {
 796
 797             $tries->{$sid} = 0 if !defined($tries->{$sid});
 798
 799             if ($tries->{$sid} >= $max_restart) {
 800                 $haenv->log('err', "unable to start service $sid on local node".
 801                            " after $tries->{$sid} retries");
 802                 $tries->{$sid} = 0;
 803                 return ERROR;
 804             }
 805
 806             $tries->{$sid}++;
 807
 808             $haenv->log('warning', "restart policy: retry number $tries->{$sid}" .
 809                         " for service '$sid'");
 810             # tell CRM that we retry the start
 811             return ETRY_AGAIN;
 812         }
 813     }
 814
 815     return $exit_code;
 816
 817 }
 818
 819 sub exec_resource_agent {
 820     my ($self, $sid, $service_config, $cmd, $params) = @_;
 821
 822     # setup execution environment
 823
 824     $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
 825
 826     my $haenv = $self->{haenv};
 827
 828     my $nodename = $haenv->nodename();
 829
 830     my (undef, $service_type, $service_name) = $haenv->parse_sid($sid);
 831
 832     my $plugin = PVE::HA::Resources->lookup($service_type);
 833     if (!$plugin) {
 834         $haenv->log('err', "service type '$service_type' not implemented");
 835         return EUNKNOWN_SERVICE_TYPE;
 836     }
 837
 838     if (!$service_config) {
 839         $haenv->log('err', "missing resource configuration for '$sid'");
 840         return EUNKNOWN_SERVICE;
 841     }
 842
 843     # process error state early
 844     if ($cmd eq 'error') {
 845         $haenv->log('err', "service $sid is in an error state and needs manual " .
 846                     "intervention. Look up 'ERROR RECOVERY' in the documentation.");
 847
 848         return SUCCESS; # error always succeeds
 849     }
 850
 851     if ($service_config->{node} ne $nodename) {
 852         $haenv->log('err', "service '$sid' not on this node");
 853         return EWRONG_NODE;
 854     }
 855
 856     my $id = $service_name;
 857
 858     my $running = $plugin->check_running($haenv, $id);
 859
 860     if ($cmd eq 'started') {
 861
 862         return SUCCESS if $running;
 863
 864         $haenv->log("info", "starting service $sid");
 865
 866         $plugin->start($haenv, $id);
 867
 868         $running = $plugin->check_running($haenv, $id);
 869
 870         if ($running) {
 871             $haenv->log("info", "service status $sid started");
 872             return SUCCESS;
 873         } else {
 874             $haenv->log("warning", "unable to start service $sid");
 875             return ERROR;
 876         }
 877
 878     } elsif ($cmd eq 'request_stop' || $cmd eq 'stopped') {
 879
 880         return SUCCESS if !$running;
 881
 882         if (defined($params->{timeout})) {
 883             $haenv->log("info", "stopping service $sid (timeout=$params->{timeout})");
 884         } else {
 885             $haenv->log("info", "stopping service $sid");
 886         }
 887
 888         $plugin->shutdown($haenv, $id, $params->{timeout});
 889
 890         $running = $plugin->check_running($haenv, $id);
 891
 892         if (!$running) {
 893             $haenv->log("info", "service status $sid stopped");
 894             return SUCCESS;
 895         } else {
 896             $haenv->log("info", "unable to stop stop service $sid (still running)");
 897             return ERROR;
 898         }
 899
 900     } elsif ($cmd eq 'migrate' || $cmd eq 'relocate') {
 901
 902         my $target = $params->{target};
 903         if (!defined($target)) {
 904             die "$cmd '$sid' failed - missing target\n" if !defined($target);
 905             return EINVALID_PARAMETER;
 906         }
 907
 908         if ($service_config->{node} eq $target) {
 909             # already there
 910             return SUCCESS;
 911         }
 912
 913         my $online = ($cmd eq 'migrate') ? 1 : 0;
 914
 915         my $res = $plugin->migrate($haenv, $id, $target, $online);
 916
 917         # something went wrong if service is still on this node
 918         if (!$res) {
 919             $haenv->log("err", "service $sid not moved (migration error)");
 920             return ERROR;
 921         }
 922
 923         return SUCCESS;
 924
 925     }
 926
 927     $haenv->log("err", "implement me (cmd '$cmd')");
 928     return EUNKNOWN_COMMAND;
 929 }
 930
 931
 932 1;