src/PVE/HA/Manager.pm

   1 package PVE::HA::Manager;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Digest::MD5 qw(md5_base64);
   7
   8 use PVE::Tools;
   9 use PVE::HA::Tools ':exit_codes';
  10 use PVE::HA::NodeStatus;
  11 use PVE::HA::Usage::Basic;
  12 use PVE::HA::Usage::Static;
  13
  14 ## Variable Name & Abbreviations Convention
  15 #
  16 # The HA stack has some variables it uses frequently and thus abbreviates it such that it may be
  17 # confusing for new readers. Here's a short list of the most common used.
  18 #
  19 # NOTE: variables should be assumed to be read only if not otherwise stated, only use the specific
  20 # methods to re-compute/read/alter them.
  21 #
  22 # - $haenv -> HA environment, the main interface to the simulator/test/real world
  23 # - $sid -> Service ID, unique identifier for a service, `type:vmid` is common
  24 #
  25 # - $ms -> Master/Manager Status, contains runtime info from the current active manager
  26 # - $ns -> Node Status, hash holding online/offline status about all nodes
  27 #
  28 # - $ss -> Service Status, hash holding the current state (last LRM cmd result, failed starts
  29 #          or migrates, maintenance fallback node, for *all* services ...
  30 # - $sd -> Service Data, the service status of a *single* service, iow. $ss->{$sid}
  31 #
  32 # - $sc -> Service Configuration, hash for all services including target state, group, ...
  33 # - $cd -> Configuration Data, the service config of a *single* service, iow. $sc->{$sid}
  34 #
  35 # Try to avoid adding new two letter (or similar over abbreviated) names, but also don't send
  36 # patches for changing above, as that set is mostly sensible and should be easy to remember once
  37 # spending a bit time in the HA code base.
  38
  39 sub new {
  40     my ($this, $haenv) = @_;
  41
  42     my $class = ref($this) || $this;
  43
  44     my $self = bless { haenv => $haenv, crs => {} }, $class;
  45
  46     my $old_ms = $haenv->read_manager_status();
  47
  48     # we only copy the state part of the manager which cannot be auto generated
  49
  50     $self->{ns} = PVE::HA::NodeStatus->new($haenv, $old_ms->{node_status} || {});
  51
  52     # fixme: use separate class  PVE::HA::ServiceStatus
  53     $self->{ss} = $old_ms->{service_status} || {};
  54
  55     $self->{ms} = { master_node => $haenv->nodename() };
  56
  57     # take over node request state to ensure a node in (manual) maintenance mode stays that way
  58     # on change of active master.
  59     $self->{ms}->{node_request} = $old_ms->{node_request} if defined($old_ms->{node_request});
  60
  61     $self->update_crs_scheduler_mode(); # initial set, we update it once every loop
  62
  63     return $self;
  64 }
  65
  66 sub update_crs_scheduler_mode {
  67     my ($self) = @_;
  68
  69     my $haenv = $self->{haenv};
  70     my $dc_cfg = $haenv->get_datacenter_settings();
  71
  72     $self->{crs}->{rebalance_on_request_start} = !!$dc_cfg->{crs}->{'ha-rebalance-on-start'};
  73
  74     my $old_mode = $self->{crs}->{scheduler};
  75     my $new_mode = $dc_cfg->{crs}->{ha} || 'basic';
  76
  77     if (!defined($old_mode)) {
  78         $haenv->log('info', "using scheduler mode '$new_mode'") if $new_mode ne 'basic';
  79     } elsif ($new_mode eq $old_mode) {
  80         return; # nothing to do
  81     } else {
  82         $haenv->log('info', "switching scheduler mode from '$old_mode' to '$new_mode'");
  83     }
  84
  85     $self->{crs}->{scheduler} = $new_mode;
  86
  87     return;
  88 }
  89
  90 sub cleanup {
  91     my ($self) = @_;
  92
  93     # todo: ?
  94 }
  95
  96 sub flush_master_status {
  97     my ($self) = @_;
  98
  99     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 100
 101     $ms->{node_status} = $ns->{status};
 102     $ms->{service_status} = $ss;
 103     $ms->{timestamp} = $haenv->get_time();
 104
 105     $haenv->write_manager_status($ms);
 106 }
 107
 108 sub get_service_group {
 109     my ($groups, $online_node_usage, $service_conf) = @_;
 110
 111     my $group = {};
 112     # add all online nodes to default group to allow try_next when no group set
 113     $group->{nodes}->{$_} = 1 for $online_node_usage->list_nodes();
 114
 115     # overwrite default if service is bound to a specific group
 116     if (my $group_id = $service_conf->{group}) {
 117         $group = $groups->{ids}->{$group_id} if $groups->{ids}->{$group_id};
 118     }
 119
 120     return $group;
 121 }
 122
 123 # groups available nodes with their priority as group index
 124 sub get_node_priority_groups {
 125     my ($group, $online_node_usage) = @_;
 126
 127     my $pri_groups = {};
 128     my $group_members = {};
 129     foreach my $entry (keys %{$group->{nodes}}) {
 130         my ($node, $pri) = ($entry, 0);
 131         if ($entry =~ m/^(\S+):(\d+)$/) {
 132             ($node, $pri) = ($1, $2);
 133         }
 134         next if !$online_node_usage->contains_node($node); # offline
 135         $pri_groups->{$pri}->{$node} = 1;
 136         $group_members->{$node} = $pri;
 137     }
 138
 139     # add non-group members to unrestricted groups (priority -1)
 140     if (!$group->{restricted}) {
 141         my $pri = -1;
 142         for my $node ($online_node_usage->list_nodes()) {
 143             next if defined($group_members->{$node});
 144             $pri_groups->{$pri}->{$node} = 1;
 145             $group_members->{$node} = -1;
 146         }
 147     }
 148
 149     return ($pri_groups, $group_members);
 150 }
 151
 152 sub select_service_node {
 153     my ($groups, $online_node_usage, $sid, $service_conf, $current_node, $try_next, $tried_nodes, $maintenance_fallback, $best_scored) = @_;
 154
 155     my $group = get_service_group($groups, $online_node_usage, $service_conf);
 156
 157     my ($pri_groups, $group_members) = get_node_priority_groups($group, $online_node_usage);
 158
 159     my @pri_list = sort {$b <=> $a} keys %$pri_groups;
 160     return undef if !scalar(@pri_list);
 161
 162     # stay on current node if possible (avoids random migrations)
 163     if ((!$try_next && !$best_scored) && $group->{nofailback} && defined($group_members->{$current_node})) {
 164         return $current_node;
 165     }
 166
 167     # select node from top priority node list
 168
 169     my $top_pri = $pri_list[0];
 170
 171     # try to avoid nodes where the service failed already if we want to relocate
 172     if ($try_next) {
 173         foreach my $node (@$tried_nodes) {
 174             delete $pri_groups->{$top_pri}->{$node};
 175         }
 176     }
 177
 178     return $maintenance_fallback
 179         if defined($maintenance_fallback) && $pri_groups->{$top_pri}->{$maintenance_fallback};
 180
 181     return $current_node if (!$try_next && !$best_scored) && $pri_groups->{$top_pri}->{$current_node};
 182
 183     my $scores = $online_node_usage->score_nodes_to_start_service($sid, $current_node);
 184     my @nodes = sort {
 185         $scores->{$a} <=> $scores->{$b} || $a cmp $b
 186     } keys %{$pri_groups->{$top_pri}};
 187
 188     my $found;
 189     for (my $i = scalar(@nodes) - 1; $i >= 0; $i--) {
 190         my $node = $nodes[$i];
 191         if ($node eq $current_node) {
 192             $found = $i;
 193         }
 194     }
 195
 196     if ($try_next) {
 197         if (!$best_scored && defined($found) && ($found < (scalar(@nodes) - 1))) {
 198             return $nodes[$found + 1];
 199         } else {
 200             return $nodes[0];
 201         }
 202     } else {
 203         return $nodes[0];
 204     }
 205 }
 206
 207 my $uid_counter = 0;
 208
 209 sub compute_new_uuid {
 210     my ($state) = @_;
 211
 212     $uid_counter++;
 213     return md5_base64($state . $$ . time() . $uid_counter);
 214 }
 215
 216 my $valid_service_states = {
 217     stopped => 1,
 218     request_stop => 1,
 219     request_start => 1,
 220     request_start_balance => 1,
 221     started => 1,
 222     fence => 1,
 223     recovery => 1,
 224     migrate => 1,
 225     relocate => 1,
 226     freeze => 1,
 227     error => 1,
 228 };
 229
 230 # FIXME with 'static' mode and thousands of services, the overhead can be noticable and the fact
 231 # that this function is called for each state change and upon recovery doesn't help.
 232 sub recompute_online_node_usage {
 233     my ($self) = @_;
 234
 235     my $haenv = $self->{haenv};
 236
 237     my $online_nodes = $self->{ns}->list_online_nodes();
 238
 239     my $online_node_usage;
 240
 241     if (my $mode = $self->{crs}->{scheduler}) {
 242         if ($mode eq 'static') {
 243             $online_node_usage = eval {
 244                 my $scheduler = PVE::HA::Usage::Static->new($haenv);
 245                 $scheduler->add_node($_) for $online_nodes->@*;
 246                 return $scheduler;
 247             };
 248             $haenv->log('warning', "fallback to 'basic' scheduler mode, init for 'static' failed - $@")
 249                 if $@;
 250         } elsif ($mode eq 'basic') {
 251             # handled below in the general fall-back case
 252         } else {
 253             $haenv->log('warning', "got unknown scheduler mode '$mode', using 'basic'");
 254         }
 255     }
 256
 257     # fallback to the basic algorithm in any case
 258     if (!$online_node_usage) {
 259         $online_node_usage = PVE::HA::Usage::Basic->new($haenv);
 260         $online_node_usage->add_node($_) for $online_nodes->@*;
 261     }
 262
 263     foreach my $sid (sort keys %{$self->{ss}}) {
 264         my $sd = $self->{ss}->{$sid};
 265         my $state = $sd->{state};
 266         my $target = $sd->{target}; # optional
 267         if ($online_node_usage->contains_node($sd->{node})) {
 268             if (
 269                 $state eq 'started' || $state eq 'request_stop' || $state eq 'fence'
 270                 || $state eq 'freeze' || $state eq 'error' || $state eq 'recovery'
 271             ) {
 272                 $online_node_usage->add_service_usage_to_node($sd->{node}, $sid, $sd->{node});
 273             } elsif ($state eq 'migrate' || $state eq 'relocate' || $state eq 'request_start_balance') {
 274                 my $source = $sd->{node};
 275                 # count it for both, source and target as load is put on both
 276                 $online_node_usage->add_service_usage_to_node($source, $sid, $source, $target)
 277                     if $state ne 'request_start_balance';
 278                 $online_node_usage->add_service_usage_to_node($target, $sid, $source, $target);
 279             } elsif ($state eq 'stopped' || $state eq 'request_start') {
 280                 # do nothing
 281             } else {
 282                 die "should not be reached (sid = '$sid', state = '$state')";
 283             }
 284         } elsif (defined($target) && $online_node_usage->contains_node($target)) {
 285             if ($state eq 'migrate' || $state eq 'relocate') {
 286                 # to correctly track maintenance modi and also consider the target as used for the
 287                 # case a node dies, as we cannot really know if the to-be-aborted incoming migration
 288                 # has already cleaned up all used resources
 289                 $online_node_usage->add_service_usage_to_node($target, $sid, $sd->{node}, $target);
 290             }
 291         }
 292     }
 293
 294     $self->{online_node_usage} = $online_node_usage;
 295 }
 296
 297 my $change_service_state = sub {
 298     my ($self, $sid, $new_state, %params) = @_;
 299
 300     my ($haenv, $ss) = ($self->{haenv}, $self->{ss});
 301
 302     my $sd = $ss->{$sid} || die "no such service '$sid";
 303
 304     my $old_state = $sd->{state};
 305     my $old_node = $sd->{node};
 306     my $old_failed_nodes = $sd->{failed_nodes};
 307     my $old_maintenance_node = $sd->{maintenance_node};
 308
 309     die "no state change" if $old_state eq $new_state; # just to be sure
 310
 311     die "invalid CRM service state '$new_state'\n" if !$valid_service_states->{$new_state};
 312
 313     foreach my $k (keys %$sd) { delete $sd->{$k}; };
 314
 315     $sd->{state} = $new_state;
 316     $sd->{node} = $old_node;
 317     $sd->{failed_nodes} = $old_failed_nodes if defined($old_failed_nodes);
 318     $sd->{maintenance_node} = $old_maintenance_node if defined($old_maintenance_node);
 319
 320     my $text_state = '';
 321     foreach my $k (sort keys %params) {
 322         my $v = $params{$k};
 323         $text_state .= ", " if $text_state;
 324         $text_state .= "$k = $v";
 325         $sd->{$k} = $v;
 326     }
 327
 328     $self->recompute_online_node_usage();
 329
 330     $sd->{uid} = compute_new_uuid($new_state);
 331
 332     $text_state = "  ($text_state)" if $text_state;
 333     $haenv->log('info', "service '$sid': state changed from '${old_state}' to '${new_state}'$text_state");
 334 };
 335
 336 # clean up a possible bad state from a recovered service to allow its start
 337 my $fence_recovery_cleanup = sub {
 338     my ($self, $sid, $fenced_node) = @_;
 339
 340     my $haenv = $self->{haenv};
 341
 342     my (undef, $type, $id) = $haenv->parse_sid($sid);
 343     my $plugin = PVE::HA::Resources->lookup($type);
 344
 345     # should not happen
 346     die "unknown resource type '$type'" if !$plugin;
 347
 348     # locks may block recovery, cleanup those which are safe to remove after fencing,
 349     # i.e., after the original node was reset and thus all it's state
 350     my $removable_locks = [
 351         'backup',
 352         'mounted',
 353         'migrate',
 354         'clone',
 355         'rollback',
 356         'snapshot',
 357         'snapshot-delete',
 358         'suspending',
 359         'suspended',
 360     ];
 361     if (my $removed_lock = $plugin->remove_locks($haenv, $id, $removable_locks, $fenced_node)) {
 362         $haenv->log('warning', "removed leftover lock '$removed_lock' from recovered " .
 363                     "service '$sid' to allow its start.");
 364     }
 365 };
 366
 367 # read LRM status for all nodes
 368 sub read_lrm_status {
 369     my ($self) = @_;
 370
 371     my $nodes = $self->{ns}->list_nodes();
 372     my $haenv = $self->{haenv};
 373
 374     my $results = {};
 375     my $modes = {};
 376     foreach my $node (@$nodes) {
 377         my $lrm_status = $haenv->read_lrm_status($node);
 378         $modes->{$node} = $lrm_status->{mode} || 'active';
 379         foreach my $uid (keys %{$lrm_status->{results}}) {
 380             next if $results->{$uid}; # should not happen
 381             $results->{$uid} = $lrm_status->{results}->{$uid};
 382         }
 383     }
 384
 385     return ($results, $modes);
 386 }
 387
 388 # read new crm commands and save them into crm master status
 389 sub update_crm_commands {
 390     my ($self) = @_;
 391
 392     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 393
 394     my $cmdlist = $haenv->read_crm_commands();
 395
 396     foreach my $cmd (split(/\n/, $cmdlist)) {
 397         chomp $cmd;
 398
 399         if ($cmd =~ m/^(migrate|relocate)\s+(\S+)\s+(\S+)$/) {
 400             my ($task, $sid, $node) = ($1, $2, $3);
 401             if (my $sd = $ss->{$sid}) {
 402                 if (!$ns->node_is_online($node)) {
 403                     $haenv->log('err', "crm command error - node not online: $cmd");
 404                 } else {
 405                     if ($node eq $sd->{node}) {
 406                         $haenv->log('info', "ignore crm command - service already on target node: $cmd");
 407                     } else {
 408                         $haenv->log('info', "got crm command: $cmd");
 409                         $ss->{$sid}->{cmd} = [ $task, $node ];
 410                     }
 411                 }
 412             } else {
 413                 $haenv->log('err', "crm command error - no such service: $cmd");
 414             }
 415
 416         } elsif ($cmd =~ m/^stop\s+(\S+)\s+(\S+)$/) {
 417             my ($sid, $timeout) = ($1, $2);
 418             if (my $sd = $ss->{$sid}) {
 419                 $haenv->log('info', "got crm command: $cmd");
 420                 $ss->{$sid}->{cmd} = [ 'stop', $timeout ];
 421             } else {
 422                 $haenv->log('err', "crm command error - no such service: $cmd");
 423             }
 424         } elsif ($cmd =~ m/^enable-node-maintenance\s+(\S+)$/) {
 425             my $node = $1;
 426
 427             my $state = $ns->get_node_state($node);
 428             if ($state eq 'online') {
 429                 $ms->{node_request}->{$node}->{maintenance} = 1;
 430             } elsif ($state eq 'maintenance') {
 431                 $haenv->log('info', "ignoring crm command - node $node is already in maintenance state");
 432             } else {
 433                 $haenv->log('err', "crm command error - node not online: $cmd");
 434             }
 435         } elsif ($cmd =~ m/^disable-node-maintenance\s+(\S+)$/) {
 436             my $node = $1;
 437
 438             my $state = $ns->get_node_state($node);
 439             if ($state ne 'maintenance') {
 440                 $haenv->log(
 441                     'warn', "clearing maintenance of node $node requested, but it's in state $state");
 442             }
 443             delete $ms->{node_request}->{$node}->{maintenance}; # gets flushed out at the end of the CRM loop
 444         } else {
 445             $haenv->log('err', "unable to parse crm command: $cmd");
 446         }
 447     }
 448
 449 }
 450
 451 sub manage {
 452     my ($self) = @_;
 453
 454     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 455
 456     my ($node_info) = $haenv->get_node_info();
 457     my ($lrm_results, $lrm_modes) = $self->read_lrm_status();
 458
 459     $ns->update($node_info, $lrm_modes);
 460
 461     if (!$ns->node_is_operational($haenv->nodename())) {
 462         $haenv->log('info', "master seems offline");
 463         return;
 464     }
 465
 466     $self->update_crs_scheduler_mode();
 467
 468     my $sc = $haenv->read_service_config();
 469
 470     $self->{groups} = $haenv->read_group_config(); # update
 471
 472     # compute new service status
 473
 474     # add new service
 475     foreach my $sid (sort keys %$sc) {
 476         next if $ss->{$sid}; # already there
 477         my $cd = $sc->{$sid};
 478         next if $cd->{state} eq 'ignored';
 479
 480         $haenv->log('info', "adding new service '$sid' on node '$cd->{node}'");
 481         # assume we are running to avoid relocate running service at add
 482         my $state = ($cd->{state} eq 'started') ? 'request_start' : 'request_stop';
 483         $ss->{$sid} = {
 484             state => $state, node => $cd->{node}, uid => compute_new_uuid('started'),
 485         };
 486     }
 487
 488     # remove stale or ignored services from manager state
 489     foreach my $sid (keys %$ss) {
 490         next if $sc->{$sid} && $sc->{$sid}->{state} ne 'ignored';
 491
 492         my $reason =  defined($sc->{$sid}) ? 'ignored state requested' : 'no config';
 493         $haenv->log('info', "removing stale service '$sid' ($reason)");
 494
 495         # remove all service related state information
 496         delete $ss->{$sid};
 497     }
 498
 499     $self->update_crm_commands();
 500
 501     for (;;) {
 502         my $repeat = 0;
 503
 504         $self->recompute_online_node_usage();
 505
 506         foreach my $sid (sort keys %$ss) {
 507             my $sd = $ss->{$sid};
 508             my $cd = $sc->{$sid} || { state => 'disabled' };
 509
 510             my $lrm_res = $sd->{uid} ? $lrm_results->{$sd->{uid}} : undef;
 511
 512             my $last_state = $sd->{state};
 513
 514             if ($last_state eq 'stopped') {
 515
 516                 $self->next_state_stopped($sid, $cd, $sd, $lrm_res);
 517
 518             } elsif ($last_state eq 'started') {
 519
 520                 $self->next_state_started($sid, $cd, $sd, $lrm_res);
 521
 522             } elsif ($last_state eq 'request_start') {
 523
 524                 $self->next_state_request_start($sid, $cd, $sd, $lrm_res);
 525
 526             } elsif ($last_state eq 'migrate' || $last_state eq 'relocate' || $last_state eq 'request_start_balance') {
 527
 528                 $self->next_state_migrate_relocate($sid, $cd, $sd, $lrm_res);
 529
 530             } elsif ($last_state eq 'fence') {
 531
 532                 # do nothing here - wait until fenced
 533
 534             } elsif ($last_state eq 'recovery') {
 535
 536                 $self->next_state_recovery($sid, $cd, $sd, $lrm_res);
 537
 538             } elsif ($last_state eq 'request_stop') {
 539
 540                 $self->next_state_request_stop($sid, $cd, $sd, $lrm_res);
 541
 542             } elsif ($last_state eq 'freeze') {
 543
 544                 my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 545                 if ($lrm_mode && $lrm_mode eq 'active') { # unfreeze if active again
 546                     my $state = ($cd->{state} eq 'started') ? 'started' : 'request_stop';
 547                     $change_service_state->($self, $sid, $state);
 548                 }
 549
 550             } elsif ($last_state eq 'error') {
 551
 552                 $self->next_state_error($sid, $cd, $sd, $lrm_res);
 553
 554             } else {
 555
 556                 die "unknown service state '$last_state'";
 557             }
 558
 559             my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 560             if ($lrm_mode && $lrm_mode eq 'restart') {
 561                 my $state = $sd->{state};
 562                 if ($state eq 'started' || $state eq 'stopped'|| $state eq 'request_stop') {
 563                     $change_service_state->($self, $sid, 'freeze');
 564                 }
 565             }
 566
 567             $repeat = 1 if $sd->{state} ne $last_state;
 568         }
 569
 570         # handle fencing
 571         my $fenced_nodes = {};
 572         foreach my $sid (sort keys %$ss) {
 573             my ($service_state, $service_node) = $ss->{$sid}->@{'state', 'node'};
 574             next if $service_state ne 'fence';
 575
 576             if (!defined($fenced_nodes->{$service_node})) {
 577                 $fenced_nodes->{$service_node} = $ns->fence_node($service_node) || 0;
 578             }
 579
 580             next if !$fenced_nodes->{$service_node};
 581
 582             # node fence was successful - recover service
 583             $change_service_state->($self, $sid, 'recovery');
 584             $repeat = 1; # for faster recovery execution
 585         }
 586
 587         # Avoid that a node without services in 'fence' state (e.g., removed
 588         # manually by admin) is stuck with the 'fence' node state.
 589         for my $node (sort grep { !defined($fenced_nodes->{$_}) } keys $ns->{status}->%*) {
 590             next if $ns->get_node_state($node) ne 'fence';
 591
 592             $haenv->log('notice', "node '$node' in fence state but no services to-fence! admin interference?!");
 593             $repeat = 1 if $ns->fence_node($node);
 594         }
 595
 596         last if !$repeat;
 597     }
 598
 599     $self->flush_master_status();
 600 }
 601
 602 # functions to compute next service states
 603 # $cd: service configuration data (read only)
 604 # $sd: service status data (read only)
 605 #
 606 # Note: use change_service_state() to alter state
 607 #
 608
 609 sub next_state_request_stop {
 610     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 611
 612     my $haenv = $self->{haenv};
 613     my $ns = $self->{ns};
 614
 615     # check result from LRM daemon
 616     if ($lrm_res) {
 617         my $exit_code = $lrm_res->{exit_code};
 618         if ($exit_code == SUCCESS) {
 619             &$change_service_state($self, $sid, 'stopped');
 620             return;
 621         } else {
 622             $haenv->log('err', "service '$sid' stop failed (exit code $exit_code)");
 623             &$change_service_state($self, $sid, 'error'); # fixme: what state?
 624             return;
 625         }
 626     }
 627
 628     if ($ns->node_is_offline_delayed($sd->{node})) {
 629         &$change_service_state($self, $sid, 'fence');
 630         return;
 631     }
 632 }
 633
 634 sub next_state_migrate_relocate {
 635     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 636
 637     my $haenv = $self->{haenv};
 638     my $ns = $self->{ns};
 639
 640     # check result from LRM daemon
 641     if ($lrm_res) {
 642         my $exit_code = $lrm_res->{exit_code};
 643         my $req_state = $cd->{state} eq 'started' ? 'started' : 'request_stop';
 644         if ($exit_code == SUCCESS) {
 645             &$change_service_state($self, $sid, $req_state, node => $sd->{target});
 646             return;
 647         } elsif ($exit_code == EWRONG_NODE) {
 648             $haenv->log('err', "service '$sid' - migration failed: service" .
 649                         " registered on wrong node!");
 650             &$change_service_state($self, $sid, 'error');
 651         } elsif ($exit_code == IGNORED) {
 652             $haenv->log(
 653                 "info",
 654                 "service '$sid' - rebalance-on-start request ignored - service already running",
 655             );
 656             $change_service_state->($self, $sid, $req_state, node => $sd->{node});
 657         } else {
 658             $haenv->log('err', "service '$sid' - migration failed (exit code $exit_code)");
 659             &$change_service_state($self, $sid, $req_state, node => $sd->{node});
 660             return;
 661         }
 662     }
 663
 664     if ($ns->node_is_offline_delayed($sd->{node})) {
 665         &$change_service_state($self, $sid, 'fence');
 666         return;
 667     }
 668 }
 669
 670 sub next_state_stopped {
 671     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 672
 673     my $haenv = $self->{haenv};
 674     my $ns = $self->{ns};
 675
 676     if ($sd->{node} ne $cd->{node}) {
 677         # this can happen if we fence a node with active migrations
 678         # hack: modify $sd (normally this should be considered read-only)
 679         $haenv->log('info', "fixup service '$sid' location ($sd->{node} => $cd->{node})");
 680         $sd->{node} = $cd->{node};
 681     }
 682
 683     if ($sd->{cmd}) {
 684         my $cmd = shift @{$sd->{cmd}};
 685
 686         if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 687             my $target = shift @{$sd->{cmd}};
 688             if (!$ns->node_is_online($target)) {
 689                 $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 690             } elsif ($sd->{node} eq $target) {
 691                 $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 692             } else {
 693                 &$change_service_state($self, $sid, $cmd, node => $sd->{node}, target => $target);
 694                 return;
 695             }
 696         } elsif ($cmd eq 'stop') {
 697                 $haenv->log('info', "ignore service '$sid' $cmd request - service already stopped");
 698         } else {
 699             $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 700         }
 701         delete $sd->{cmd};
 702     }
 703
 704     if ($cd->{state} eq 'disabled') {
 705         # NOTE: do nothing here, the stop state is an exception as we do not
 706         # process the LRM result here, thus the LRM always tries to stop the
 707         # service (protection for the case no CRM is active)
 708         return;
 709     }
 710
 711     if ($ns->node_is_offline_delayed($sd->{node}) && $ns->get_node_state($sd->{node}) ne 'maintenance') {
 712         &$change_service_state($self, $sid, 'fence');
 713         return;
 714     }
 715
 716     if ($cd->{state} eq 'stopped') {
 717         # almost the same as 'disabled' state but the service will also get recovered
 718         return;
 719     }
 720
 721     if ($cd->{state} eq 'started') {
 722         # simply mark it started, if it's on the wrong node next_state_started will fix that for us
 723         $change_service_state->($self, $sid, 'request_start', node => $sd->{node});
 724         return;
 725     }
 726
 727     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 728 }
 729
 730 sub next_state_request_start {
 731     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 732
 733     my $haenv = $self->{haenv};
 734     my $current_node = $sd->{node};
 735
 736     if ($self->{crs}->{rebalance_on_request_start}) {
 737         my $selected_node = select_service_node(
 738             $self->{groups},
 739             $self->{online_node_usage},
 740             $sid,
 741             $cd,
 742             $sd->{node},
 743             0, # try_next
 744             $sd->{failed_nodes},
 745             $sd->{maintenance_node},
 746             1, # best_score
 747         );
 748         my $select_text = $selected_node ne $current_node ? 'new' : 'current';
 749         $haenv->log('info', "service $sid: re-balance selected $select_text node $selected_node for startup");
 750
 751         if ($selected_node ne $current_node) {
 752             $change_service_state->($self, $sid, 'request_start_balance', node => $current_node, target => $selected_node);
 753             return;
 754         }
 755     }
 756
 757     $change_service_state->($self, $sid, 'started', node => $current_node);
 758 }
 759
 760 sub record_service_failed_on_node {
 761     my ($self, $sid, $node) = @_;
 762
 763     if (!defined($self->{ss}->{$sid}->{failed_nodes})) {
 764         $self->{ss}->{$sid}->{failed_nodes} = [];
 765     }
 766
 767     push @{$self->{ss}->{$sid}->{failed_nodes}}, $node;
 768 }
 769
 770 sub next_state_started {
 771     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 772
 773     my $haenv = $self->{haenv};
 774     my $master_status = $self->{ms};
 775     my $ns = $self->{ns};
 776
 777     if (!$ns->node_is_online($sd->{node})) {
 778         if ($ns->node_is_offline_delayed($sd->{node})) {
 779             &$change_service_state($self, $sid, 'fence');
 780         }
 781         if ($ns->get_node_state($sd->{node}) ne 'maintenance') {
 782             return;
 783         } else {
 784             # save current node as fallback for when it comes out of maintenance
 785             $sd->{maintenance_node} = $sd->{node};
 786         }
 787     }
 788
 789     if ($cd->{state} eq 'disabled' || $cd->{state} eq 'stopped') {
 790         &$change_service_state($self, $sid, 'request_stop');
 791         return;
 792     }
 793
 794     if ($cd->{state} eq 'started') {
 795
 796         if ($sd->{cmd}) {
 797             my $cmd = shift @{$sd->{cmd}};
 798
 799             if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 800                 my $target = shift @{$sd->{cmd}};
 801                 if (!$ns->node_is_online($target)) {
 802                     $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 803                 } elsif ($sd->{node} eq $target) {
 804                     $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 805                 } else {
 806                     $haenv->log('info', "$cmd service '$sid' to node '$target'");
 807                     &$change_service_state($self, $sid, $cmd, node => $sd->{node}, target => $target);
 808                 }
 809             } elsif ($cmd eq 'stop') {
 810                 my $timeout = shift @{$sd->{cmd}};
 811                 if ($timeout == 0) {
 812                     $haenv->log('info', "request immediate service hard-stop for service '$sid'");
 813                 } else {
 814                     $haenv->log('info', "request graceful stop with timeout '$timeout' for service '$sid'");
 815                 }
 816                 &$change_service_state($self, $sid, 'request_stop', timeout => $timeout);
 817                 $haenv->update_service_config($sid, {'state' => 'stopped'});
 818             } else {
 819                 $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 820             }
 821
 822             delete $sd->{cmd};
 823
 824         } else {
 825
 826             my $try_next = 0;
 827
 828             if ($lrm_res) {
 829
 830                 my $ec = $lrm_res->{exit_code};
 831                 if ($ec == SUCCESS) {
 832
 833                     if (defined($sd->{failed_nodes})) {
 834                         $haenv->log('info', "relocation policy successful for '$sid' on node '$sd->{node}'," .
 835                                     " failed nodes: " . join(', ', @{$sd->{failed_nodes}}) );
 836                     }
 837
 838                     delete $sd->{failed_nodes};
 839
 840                     # store flag to indicate successful start - only valid while state == 'started'
 841                     $sd->{running} = 1;
 842
 843                 } elsif ($ec == ERROR || $ec == EWRONG_NODE) {
 844
 845                     delete $sd->{running};
 846
 847                     # apply our relocate policy if we got ERROR from the LRM
 848                     $self->record_service_failed_on_node($sid, $sd->{node});
 849
 850                     if (scalar(@{$sd->{failed_nodes}}) <= $cd->{max_relocate}) {
 851
 852                         # tell select_service_node to relocate if possible
 853                         $try_next = 1;
 854
 855                         $haenv->log('warning', "starting service $sid on node".
 856                                    " '$sd->{node}' failed, relocating service.");
 857
 858                     } else {
 859
 860                         $haenv->log('err', "recovery policy for service $sid " .
 861                                     "failed, entering error state. Failed nodes: ".
 862                                     join(', ', @{$sd->{failed_nodes}}));
 863                         &$change_service_state($self, $sid, 'error');
 864                         return;
 865
 866                     }
 867                 } else {
 868                     $self->record_service_failed_on_node($sid, $sd->{node});
 869
 870                     $haenv->log('err', "service '$sid' got unrecoverable error (exit code $ec))");
 871                     # we have no save way out (yet) for other errors
 872                     &$change_service_state($self, $sid, 'error');
 873                     return;
 874                 }
 875             }
 876
 877             my $node = select_service_node(
 878                 $self->{groups},
 879                 $self->{online_node_usage},
 880                 $sid,
 881                 $cd,
 882                 $sd->{node},
 883                 $try_next,
 884                 $sd->{failed_nodes},
 885                 $sd->{maintenance_node},
 886             );
 887
 888             if ($node && ($sd->{node} ne $node)) {
 889                 $self->{online_node_usage}->add_service_usage_to_node($node, $sid, $sd->{node});
 890
 891                 if (defined(my $fallback = $sd->{maintenance_node})) {
 892                     if ($node eq $fallback) {
 893                         $haenv->log(
 894                             'info',
 895                             "moving service '$sid' back to '$fallback', node came back from maintenance.",
 896                         );
 897                         delete $sd->{maintenance_node};
 898                     } elsif ($sd->{node} ne $fallback) {
 899                         $haenv->log('info', "dropping maintenance fallback node '$fallback' for '$sid'");
 900                         delete $sd->{maintenance_node};
 901                     }
 902                 }
 903
 904                 if ($cd->{type} eq 'vm') {
 905                     $haenv->log('info', "migrate service '$sid' to node '$node' (running)");
 906                     &$change_service_state($self, $sid, 'migrate', node => $sd->{node}, target => $node);
 907                 } else {
 908                     $haenv->log('info', "relocate service '$sid' to node '$node'");
 909                     &$change_service_state($self, $sid, 'relocate', node => $sd->{node}, target => $node);
 910                 }
 911             } else {
 912                 if ($try_next && !defined($node)) {
 913                     $haenv->log(
 914                         'warning',
 915                         "Start Error Recovery: Tried all available nodes for service '$sid', retry"
 916                             ." start on current node. Tried nodes: " . join(', ', @{$sd->{failed_nodes}},
 917                         )
 918                     );
 919                 }
 920
 921                 if ($sd->{maintenance_node} && $sd->{node} eq $sd->{maintenance_node}) {
 922                     my $node_state = $ns->get_node_state($sd->{node});
 923                     if ($node_state eq 'online') {
 924                         # Having the maintenance node set here means that the service was never
 925                         # started on a different node since it was set. This can happen in the edge
 926                         # case that the whole cluster is shut down at the same time while the
 927                         # 'migrate' policy was configured. Node is not in maintenance mode anymore
 928                         # and service is started on this node, so it's fine to clear the setting.
 929                         $haenv->log(
 930                             'info',
 931                             "service '$sid': clearing stale maintenance node "
 932                                 ."'$sd->{maintenance_node}' setting (is current node)",
 933                         );
 934                         delete $sd->{maintenance_node};
 935                     }
 936                 }
 937
 938                 # ensure service get started again if it went unexpected down
 939                 # but ensure also no LRM result gets lost
 940                 $sd->{uid} = compute_new_uuid($sd->{state}) if defined($lrm_res);
 941             }
 942         }
 943
 944         return;
 945     }
 946
 947     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 948 }
 949
 950 sub next_state_error {
 951     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 952
 953     my $ns = $self->{ns};
 954     my $ms = $self->{ms};
 955
 956     if ($cd->{state} eq 'disabled') {
 957         # clean up on error recovery
 958         delete $sd->{failed_nodes};
 959
 960         &$change_service_state($self, $sid, 'stopped');
 961         return;
 962     }
 963
 964 }
 965
 966 # after a node was fenced this recovers the service to a new node
 967 sub next_state_recovery {
 968     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 969
 970     my ($haenv, $ss) = ($self->{haenv}, $self->{ss});
 971     my $ns = $self->{ns};
 972     my $ms = $self->{ms};
 973
 974     if ($sd->{state} ne 'recovery') { # should not happen
 975         $haenv->log('err', "cannot recover service '$sid' from fencing, wrong state '$sd->{state}'");
 976         return;
 977     }
 978
 979     my $fenced_node = $sd->{node}; # for logging purpose
 980
 981     $self->recompute_online_node_usage(); # we want the most current node state
 982
 983     my $recovery_node = select_service_node(
 984         $self->{groups},
 985         $self->{online_node_usage},
 986         $sid,
 987         $cd,
 988         $sd->{node},
 989     );
 990
 991     if ($recovery_node) {
 992         my $msg = "recover service '$sid' from fenced node '$fenced_node' to node '$recovery_node'";
 993         if ($recovery_node eq $fenced_node) {
 994             # can happen if restriced groups and the node came up again OK
 995             $msg = "recover service '$sid' to previous failed and fenced node '$fenced_node' again";
 996         }
 997         $haenv->log('info', "$msg");
 998
 999         $fence_recovery_cleanup->($self, $sid, $fenced_node);
1000
1001         $haenv->steal_service($sid, $sd->{node}, $recovery_node);
1002         $self->{online_node_usage}->add_service_usage_to_node($recovery_node, $sid, $recovery_node);
1003
1004         # NOTE: $sd *is normally read-only*, fencing is the exception
1005         $cd->{node} = $sd->{node} = $recovery_node;
1006         my $new_state = ($cd->{state} eq 'started') ? 'started' : 'request_stop';
1007         $change_service_state->($self, $sid, $new_state, node => $recovery_node);
1008     } else {
1009         # no possible node found, cannot recover - but retry later, as we always try to make it available
1010         $haenv->log('err', "recovering service '$sid' from fenced node '$fenced_node' failed, no recovery node found");
1011
1012         if ($cd->{state} eq 'disabled') {
1013             # allow getting a service out of recovery manually if an admin disables it.
1014             delete $sd->{failed_nodes}; # clean up on recovery to stopped
1015             $change_service_state->($self, $sid, 'stopped'); # must NOT go through request_stop
1016             return;
1017         }
1018     }
1019 }
1020
1021 1;