src/PVE/HA/Manager.pm

   1 package PVE::HA::Manager;
   2
   3 use strict;
   4 use warnings;
   5 use Digest::MD5 qw(md5_base64);
   6
   7 use PVE::Tools;
   8 use PVE::HA::Tools ':exit_codes';
   9 use PVE::HA::NodeStatus;
  10
  11 sub new {
  12     my ($this, $haenv) = @_;
  13
  14     my $class = ref($this) || $this;
  15
  16     my $self = bless { haenv => $haenv }, $class;
  17
  18     my $old_ms = $haenv->read_manager_status();
  19
  20     # we only copy the state part of the manager which cannot be auto generated
  21
  22     $self->{ns} = PVE::HA::NodeStatus->new($haenv, $old_ms->{node_status} || {});
  23
  24     # fixme: use separate class  PVE::HA::ServiceStatus
  25     $self->{ss} = $old_ms->{service_status} || {};
  26
  27     $self->{ms} = { master_node => $haenv->nodename() };
  28
  29     return $self;
  30 }
  31
  32 sub cleanup {
  33     my ($self) = @_;
  34
  35     # todo: ?
  36 }
  37
  38 sub flush_master_status {
  39     my ($self) = @_;
  40
  41     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
  42
  43     $ms->{node_status} = $ns->{status};
  44     $ms->{service_status} = $ss;
  45     $ms->{timestamp} = $haenv->get_time();
  46
  47     $haenv->write_manager_status($ms);
  48 }
  49
  50 sub get_service_group {
  51     my ($groups, $online_node_usage, $service_conf) = @_;
  52
  53     my $group = {};
  54     # add all online nodes to default group to allow try_next when no group set
  55     foreach my $node (keys %$online_node_usage) {
  56         $group->{nodes}->{$node} = 1;
  57     }
  58
  59     # overwrite default if service is bound to a specific group
  60     $group =  $groups->{ids}->{$service_conf->{group}} if $service_conf->{group} &&
  61         $groups->{ids}->{$service_conf->{group}};
  62
  63     return $group;
  64 }
  65
  66 # groups available nodes with their priority as group index
  67 sub get_node_priority_groups {
  68     my ($group, $online_node_usage) = @_;
  69
  70     my $pri_groups = {};
  71     my $group_members = {};
  72     foreach my $entry (keys %{$group->{nodes}}) {
  73         my ($node, $pri) = ($entry, 0);
  74         if ($entry =~ m/^(\S+):(\d+)$/) {
  75             ($node, $pri) = ($1, $2);
  76         }
  77         next if !defined($online_node_usage->{$node}); # offline
  78         $pri_groups->{$pri}->{$node} = 1;
  79         $group_members->{$node} = $pri;
  80     }
  81
  82     # add non-group members to unrestricted groups (priority -1)
  83     if (!$group->{restricted}) {
  84         my $pri = -1;
  85         foreach my $node (keys %$online_node_usage) {
  86             next if defined($group_members->{$node});
  87             $pri_groups->{$pri}->{$node} = 1;
  88             $group_members->{$node} = -1;
  89         }
  90     }
  91
  92     return ($pri_groups, $group_members);
  93 }
  94
  95 sub select_service_node {
  96     my ($groups, $online_node_usage, $service_conf, $current_node, $try_next, $tried_nodes) = @_;
  97
  98     my $group = get_service_group($groups, $online_node_usage, $service_conf);
  99
 100     my ($pri_groups, $group_members) = get_node_priority_groups($group, $online_node_usage);
 101
 102     my @pri_list = sort {$b <=> $a} keys %$pri_groups;
 103     return undef if !scalar(@pri_list);
 104
 105     # stay on current node if possible (avoids random migrations)
 106     if (!$try_next && $group->{nofailback} && defined($group_members->{$current_node})) {
 107         return $current_node;
 108     }
 109
 110     # select node from top priority node list
 111
 112     my $top_pri = $pri_list[0];
 113
 114     # try to avoid nodes where the service failed already if we want to relocate
 115     if ($try_next) {
 116         foreach my $node (@$tried_nodes) {
 117             delete $pri_groups->{$top_pri}->{$node};
 118         }
 119     }
 120
 121     my @nodes = sort {
 122         $online_node_usage->{$a} <=> $online_node_usage->{$b} || $a cmp $b
 123     } keys %{$pri_groups->{$top_pri}};
 124
 125     my $found;
 126     for (my $i = scalar(@nodes) - 1; $i >= 0; $i--) {
 127         my $node = $nodes[$i];
 128         if ($node eq $current_node) {
 129             $found = $i;
 130             last;
 131         }
 132     }
 133
 134     if ($try_next) {
 135
 136         if (defined($found) && ($found < (scalar(@nodes) - 1))) {
 137             return $nodes[$found + 1];
 138         } else {
 139             return $nodes[0];
 140         }
 141
 142     } else {
 143
 144         return $nodes[$found] if defined($found);
 145
 146         return $nodes[0];
 147
 148     }
 149 }
 150
 151 my $uid_counter = 0;
 152
 153 sub compute_new_uuid {
 154     my ($state) = @_;
 155
 156     $uid_counter++;
 157     return md5_base64($state . $$ . time() . $uid_counter);
 158 }
 159
 160 my $valid_service_states = {
 161     stopped => 1,
 162     request_stop => 1,
 163     started => 1,
 164     fence => 1,
 165     migrate => 1,
 166     relocate => 1,
 167     freeze => 1,
 168     error => 1,
 169 };
 170
 171 sub recompute_online_node_usage {
 172     my ($self) = @_;
 173
 174     my $online_node_usage = {};
 175
 176     my $online_nodes = $self->{ns}->list_online_nodes();
 177
 178     foreach my $node (@$online_nodes) {
 179         $online_node_usage->{$node} = 0;
 180     }
 181
 182     foreach my $sid (keys %{$self->{ss}}) {
 183         my $sd = $self->{ss}->{$sid};
 184         my $state = $sd->{state};
 185         if (defined($online_node_usage->{$sd->{node}})) {
 186             if (($state eq 'started') || ($state eq 'request_stop') ||
 187                 ($state eq 'fence') || ($state eq 'freeze') || ($state eq 'error')) {
 188                 $online_node_usage->{$sd->{node}}++;
 189             } elsif (($state eq 'migrate') || ($state eq 'relocate')) {
 190                 $online_node_usage->{$sd->{target}}++;
 191             } elsif ($state eq 'stopped') {
 192                 # do nothing
 193             } else {
 194                 die "should not be reached";
 195             }
 196         }
 197     }
 198
 199     $self->{online_node_usage} = $online_node_usage;
 200 }
 201
 202 my $change_service_state = sub {
 203     my ($self, $sid, $new_state, %params) = @_;
 204
 205     my ($haenv, $ss) = ($self->{haenv}, $self->{ss});
 206
 207     my $sd = $ss->{$sid} || die "no such service '$sid";
 208
 209     my $old_state = $sd->{state};
 210     my $old_node = $sd->{node};
 211     my $old_failed_nodes = $sd->{failed_nodes};
 212
 213     die "no state change" if $old_state eq $new_state; # just to be sure
 214
 215     die "invalid CRM service state '$new_state'\n" if !$valid_service_states->{$new_state};
 216
 217     foreach my $k (keys %$sd) { delete $sd->{$k}; };
 218
 219     $sd->{state} = $new_state;
 220     $sd->{node} = $old_node;
 221     $sd->{failed_nodes} = $old_failed_nodes if defined($old_failed_nodes);
 222
 223     my $text_state = '';
 224     foreach my $k (sort keys %params) {
 225         my $v = $params{$k};
 226         $text_state .= ", " if $text_state;
 227         $text_state .= "$k = $v";
 228         $sd->{$k} = $v;
 229     }
 230
 231     $self->recompute_online_node_usage();
 232
 233     $sd->{uid} = compute_new_uuid($new_state);
 234
 235     $text_state = "  ($text_state)" if $text_state;
 236     $haenv->log('info', "service '$sid': state changed from '${old_state}'" .
 237                 " to '${new_state}'$text_state");
 238 };
 239
 240 # clean up a possible bad state from a recovered service to allow its start
 241 my $fence_recovery_cleanup = sub {
 242     my ($self, $sid, $fenced_node) = @_;
 243
 244     my $haenv = $self->{haenv};
 245
 246     my (undef, $type, $id) = $haenv->parse_sid($sid);
 247     my $plugin = PVE::HA::Resources->lookup($type);
 248
 249     # should not happen
 250     die "unknown resource type '$type'" if !$plugin;
 251
 252     # locks may block recovery, cleanup those which are safe to remove after fencing
 253     my $removable_locks = ['backup', 'mounted'];
 254     if (my $removed_lock = $plugin->remove_locks($haenv, $id, $removable_locks, $fenced_node)) {
 255         $haenv->log('warning', "removed leftover lock '$removed_lock' from recovered " .
 256                     "service '$sid' to allow its start.");
 257     }
 258 };
 259
 260 # after a node was fenced this recovers the service to a new node
 261 my $recover_fenced_service = sub {
 262     my ($self, $sid, $cd) = @_;
 263
 264     my ($haenv, $ss) = ($self->{haenv}, $self->{ss});
 265
 266     my $sd = $ss->{$sid};
 267
 268     if ($sd->{state} ne 'fence') { # should not happen
 269         $haenv->log('err', "cannot recover service '$sid' from fencing," .
 270                     " wrong state '$sd->{state}'");
 271         return;
 272     }
 273
 274     my $fenced_node = $sd->{node}; # for logging purpose
 275
 276     $self->recompute_online_node_usage(); # we want the most current node state
 277
 278     my $recovery_node = select_service_node($self->{groups},
 279                                             $self->{online_node_usage},
 280                                             $cd, $sd->{node});
 281
 282     if ($recovery_node) {
 283         $haenv->log('info', "recover service '$sid' from fenced node " .
 284                     "'$fenced_node' to node '$recovery_node'");
 285
 286         &$fence_recovery_cleanup($self, $sid, $fenced_node);
 287
 288         $haenv->steal_service($sid, $sd->{node}, $recovery_node);
 289
 290         # $sd *is normally read-only*, fencing is the exception
 291         $cd->{node} = $sd->{node} = $recovery_node;
 292         my $new_state = ($cd->{state} eq 'started') ? 'started' : 'request_stop';
 293         &$change_service_state($self, $sid, $new_state, node => $recovery_node);
 294     } else {
 295         # no possible node found, cannot recover
 296         $haenv->log('err', "recovering service '$sid' from fenced node " .
 297                     "'$fenced_node' failed, no recovery node found");
 298         &$change_service_state($self, $sid, 'error');
 299     }
 300 };
 301
 302 # read LRM status for all nodes
 303 sub read_lrm_status {
 304     my ($self) = @_;
 305
 306     my $nodes = $self->{ns}->list_nodes();
 307     my $haenv = $self->{haenv};
 308
 309     my $results = {};
 310     my $modes = {};
 311     foreach my $node (@$nodes) {
 312         my $lrm_status = $haenv->read_lrm_status($node);
 313         $modes->{$node} = $lrm_status->{mode} || 'active';
 314         foreach my $uid (keys %{$lrm_status->{results}}) {
 315             next if $results->{$uid}; # should not happen
 316             $results->{$uid} = $lrm_status->{results}->{$uid};
 317         }
 318     }
 319
 320
 321     return ($results, $modes);
 322 }
 323
 324 # read new crm commands and save them into crm master status
 325 sub update_crm_commands {
 326     my ($self) = @_;
 327
 328     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 329
 330     my $cmdlist = $haenv->read_crm_commands();
 331
 332     foreach my $cmd (split(/\n/, $cmdlist)) {
 333         chomp $cmd;
 334
 335         if ($cmd =~ m/^(migrate|relocate)\s+(\S+)\s+(\S+)$/) {
 336             my ($task, $sid, $node) = ($1, $2, $3);
 337             if (my $sd = $ss->{$sid}) {
 338                 if (!$ns->node_is_online($node)) {
 339                     $haenv->log('err', "crm command error - node not online: $cmd");
 340                 } else {
 341                     if ($node eq $sd->{node}) {
 342                         $haenv->log('info', "ignore crm command - service already on target node: $cmd");
 343                     } else {
 344                         $haenv->log('info', "got crm command: $cmd");
 345                         $ss->{$sid}->{cmd} = [ $task, $node ];
 346                     }
 347                 }
 348             } else {
 349                 $haenv->log('err', "crm command error - no such service: $cmd");
 350             }
 351
 352         } elsif ($cmd =~ m/^stop\s+(\S+)\s+(\S+)$/) {
 353             my ($sid, $timeout) = ($1, $2);
 354             if (my $sd = $ss->{$sid}) {
 355                 $haenv->log('info', "got crm command: $cmd");
 356                 $ss->{$sid}->{cmd} = [ 'stop', $timeout ];
 357             } else {
 358                 $haenv->log('err', "crm command error - no such service: $cmd");
 359             }
 360         } else {
 361             $haenv->log('err', "unable to parse crm command: $cmd");
 362         }
 363     }
 364
 365 }
 366
 367 sub manage {
 368     my ($self) = @_;
 369
 370     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 371
 372     $ns->update($haenv->get_node_info());
 373
 374     if (!$ns->node_is_online($haenv->nodename())) {
 375         $haenv->log('info', "master seems offline");
 376         return;
 377     }
 378
 379     my ($lrm_results, $lrm_modes) = $self->read_lrm_status();
 380
 381     my $sc = $haenv->read_service_config();
 382
 383     $self->{groups} = $haenv->read_group_config(); # update
 384
 385     # compute new service status
 386
 387     # add new service
 388     foreach my $sid (sort keys %$sc) {
 389         next if $ss->{$sid}; # already there
 390         my $cd = $sc->{$sid};
 391         next if $cd->{state} eq 'ignored';
 392
 393         $haenv->log('info', "adding new service '$sid' on node '$cd->{node}'");
 394         # assume we are running to avoid relocate running service at add
 395         my $state = ($cd->{state} eq 'started') ? 'started' : 'request_stop';
 396         $ss->{$sid} = { state => $state, node => $cd->{node},
 397                         uid => compute_new_uuid('started') };
 398     }
 399
 400     # remove stale or ignored services from manager state
 401     foreach my $sid (keys %$ss) {
 402         next if $sc->{$sid} && $sc->{$sid}->{state} ne 'ignored';
 403
 404         my $reason =  defined($sc->{$sid}) ? 'ignored state requested' : 'no config';
 405         $haenv->log('info', "removing stale service '$sid' ($reason)");
 406
 407         # remove all service related state information
 408         delete $ss->{$sid};
 409     }
 410
 411     $self->update_crm_commands();
 412
 413     for (;;) {
 414         my $repeat = 0;
 415
 416         $self->recompute_online_node_usage();
 417
 418         foreach my $sid (sort keys %$ss) {
 419             my $sd = $ss->{$sid};
 420             my $cd = $sc->{$sid} || { state => 'disabled' };
 421
 422             my $lrm_res = $sd->{uid} ? $lrm_results->{$sd->{uid}} : undef;
 423
 424             my $last_state = $sd->{state};
 425
 426             if ($last_state eq 'stopped') {
 427
 428                 $self->next_state_stopped($sid, $cd, $sd, $lrm_res);
 429
 430             } elsif ($last_state eq 'started') {
 431
 432                 $self->next_state_started($sid, $cd, $sd, $lrm_res);
 433
 434             } elsif ($last_state eq 'migrate' || $last_state eq 'relocate') {
 435
 436                 $self->next_state_migrate_relocate($sid, $cd, $sd, $lrm_res);
 437
 438             } elsif ($last_state eq 'fence') {
 439
 440                 # do nothing here - wait until fenced
 441
 442             } elsif ($last_state eq 'request_stop') {
 443
 444                 $self->next_state_request_stop($sid, $cd, $sd, $lrm_res);
 445
 446             } elsif ($last_state eq 'freeze') {
 447
 448                 my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 449                 # unfreeze
 450                 my $state = ($cd->{state} eq 'started') ? 'started' : 'request_stop';
 451                 &$change_service_state($self, $sid, $state)
 452                     if $lrm_mode && $lrm_mode eq 'active';
 453
 454             } elsif ($last_state eq 'error') {
 455
 456                 $self->next_state_error($sid, $cd, $sd, $lrm_res);
 457
 458             } else {
 459
 460                 die "unknown service state '$last_state'";
 461             }
 462
 463             my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 464             if ($lrm_mode && $lrm_mode eq 'restart') {
 465                 if (($sd->{state} eq 'started' || $sd->{state} eq 'stopped' ||
 466                      $sd->{state} eq 'request_stop')) {
 467                     &$change_service_state($self, $sid, 'freeze');
 468                 }
 469             }
 470
 471             $repeat = 1 if $sd->{state} ne $last_state;
 472         }
 473
 474         # handle fencing
 475         my $fenced_nodes = {};
 476         foreach my $sid (sort keys %$ss) {
 477             my $sd = $ss->{$sid};
 478             next if $sd->{state} ne 'fence';
 479
 480             if (!defined($fenced_nodes->{$sd->{node}})) {
 481                 $fenced_nodes->{$sd->{node}} = $ns->fence_node($sd->{node}) || 0;
 482             }
 483
 484             next if !$fenced_nodes->{$sd->{node}};
 485
 486             # node fence was successful - recover service
 487             &$recover_fenced_service($self, $sid, $sc->{$sid});
 488         }
 489
 490         last if !$repeat;
 491     }
 492
 493     $self->flush_master_status();
 494 }
 495
 496 # functions to compute next service states
 497 # $cd: service configuration data (read only)
 498 # $sd: service status data (read only)
 499 #
 500 # Note: use change_service_state() to alter state
 501 #
 502
 503 sub next_state_request_stop {
 504     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 505
 506     my $haenv = $self->{haenv};
 507     my $ns = $self->{ns};
 508
 509     # check result from LRM daemon
 510     if ($lrm_res) {
 511         my $exit_code = $lrm_res->{exit_code};
 512         if ($exit_code == SUCCESS) {
 513             &$change_service_state($self, $sid, 'stopped');
 514             return;
 515         } else {
 516             $haenv->log('err', "service '$sid' stop failed (exit code $exit_code)");
 517             &$change_service_state($self, $sid, 'error'); # fixme: what state?
 518             return;
 519         }
 520     }
 521
 522     if ($ns->node_is_offline_delayed($sd->{node})) {
 523         &$change_service_state($self, $sid, 'fence');
 524         return;
 525     }
 526 }
 527
 528 sub next_state_migrate_relocate {
 529     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 530
 531     my $haenv = $self->{haenv};
 532     my $ns = $self->{ns};
 533
 534     # check result from LRM daemon
 535     if ($lrm_res) {
 536         my $exit_code = $lrm_res->{exit_code};
 537         my $req_state = $cd->{state} eq 'started' ? 'started' : 'request_stop';
 538         if ($exit_code == SUCCESS) {
 539             &$change_service_state($self, $sid, $req_state, node => $sd->{target});
 540             return;
 541         } elsif ($exit_code == EWRONG_NODE) {
 542             $haenv->log('err', "service '$sid' - migration failed: service" .
 543                         " registered on wrong node!");
 544             &$change_service_state($self, $sid, 'error');
 545         } else {
 546             $haenv->log('err', "service '$sid' - migration failed (exit code $exit_code)");
 547             &$change_service_state($self, $sid, $req_state, node => $sd->{node});
 548             return;
 549         }
 550     }
 551
 552     if ($ns->node_is_offline_delayed($sd->{node})) {
 553         &$change_service_state($self, $sid, 'fence');
 554         return;
 555     }
 556 }
 557
 558 sub next_state_stopped {
 559     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 560
 561     my $haenv = $self->{haenv};
 562     my $ns = $self->{ns};
 563
 564     if ($sd->{node} ne $cd->{node}) {
 565         # this can happen if we fence a node with active migrations
 566         # hack: modify $sd (normally this should be considered read-only)
 567         $haenv->log('info', "fixup service '$sid' location ($sd->{node} => $cd->{node})");
 568         $sd->{node} = $cd->{node};
 569     }
 570
 571     if ($sd->{cmd}) {
 572         my $cmd = shift @{$sd->{cmd}};
 573
 574         if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 575             my $target = shift @{$sd->{cmd}};
 576             if (!$ns->node_is_online($target)) {
 577                 $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 578             } elsif ($sd->{node} eq $target) {
 579                 $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 580             } else {
 581                 &$change_service_state($self, $sid, $cmd, node => $sd->{node},
 582                                        target => $target);
 583                 return;
 584             }
 585         } elsif ($cmd eq 'stop') {
 586                 $haenv->log('info', "ignore service '$sid' $cmd request - service already stopped");
 587         } else {
 588             $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 589         }
 590         delete $sd->{cmd};
 591     }
 592
 593     if ($cd->{state} eq 'disabled') {
 594         # NOTE: do nothing here, the stop state is an exception as we do not
 595         # process the LRM result here, thus the LRM always tries to stop the
 596         # service (protection for the case no CRM is active)
 597         return;
 598     }
 599
 600     if ($ns->node_is_offline_delayed($sd->{node})) {
 601         &$change_service_state($self, $sid, 'fence');
 602         return;
 603     }
 604
 605     if ($cd->{state} eq 'stopped') {
 606         # almost the same as 'disabled' state but the service will also get recovered
 607         return;
 608     }
 609
 610     if ($cd->{state} eq 'started') {
 611         # simply mark it started, if it's on the wrong node
 612         # next_state_started will fix that for us
 613         &$change_service_state($self, $sid, 'started', node => $sd->{node});
 614         return;
 615     }
 616
 617     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 618 }
 619
 620 sub record_service_failed_on_node {
 621     my ($self, $sid, $node) = @_;
 622
 623     if (!defined($self->{ss}->{$sid}->{failed_nodes})) {
 624         $self->{ss}->{$sid}->{failed_nodes} = [];
 625     }
 626
 627     push @{$self->{ss}->{$sid}->{failed_nodes}}, $node;
 628 }
 629
 630 sub next_state_started {
 631     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 632
 633     my $haenv = $self->{haenv};
 634     my $master_status = $self->{ms};
 635     my $ns = $self->{ns};
 636
 637     if (!$ns->node_is_online($sd->{node})) {
 638         if ($ns->node_is_offline_delayed($sd->{node})) {
 639             &$change_service_state($self, $sid, 'fence');
 640         }
 641         return;
 642     }
 643
 644     if ($cd->{state} eq 'disabled' || $cd->{state} eq 'stopped') {
 645         &$change_service_state($self, $sid, 'request_stop');
 646         return;
 647     }
 648
 649     if ($cd->{state} eq 'started') {
 650
 651         if ($sd->{cmd}) {
 652             my $cmd = shift @{$sd->{cmd}};
 653
 654             if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 655                 my $target = shift @{$sd->{cmd}};
 656                 if (!$ns->node_is_online($target)) {
 657                     $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 658                 } elsif ($sd->{node} eq $target) {
 659                     $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 660                 } else {
 661                     $haenv->log('info', "$cmd service '$sid' to node '$target'");
 662                     &$change_service_state($self, $sid, $cmd, node => $sd->{node}, target => $target);
 663                 }
 664             } elsif ($cmd eq 'stop') {
 665                 my $timeout = shift @{$sd->{cmd}};
 666                 if ($timeout == 0) {
 667                     $haenv->log('info', "request immediate service hard-stop for service '$sid'");
 668                 } else {
 669                     $haenv->log('info', "request graceful stop with timeout '$timeout' for service '$sid'");
 670                 }
 671                 &$change_service_state($self, $sid, 'request_stop', timeout => $timeout);
 672                 $haenv->update_service_config($sid, {'state' => 'stopped'});
 673             } else {
 674                 $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 675             }
 676
 677             delete $sd->{cmd};
 678
 679         } else {
 680
 681             my $try_next = 0;
 682
 683             if ($lrm_res) {
 684
 685                 my $ec = $lrm_res->{exit_code};
 686                 if ($ec == SUCCESS) {
 687
 688                     if (defined($sd->{failed_nodes})) {
 689                         $haenv->log('info', "relocation policy successful for '$sid' on node '$sd->{node}'," .
 690                                     " failed nodes: " . join(', ', @{$sd->{failed_nodes}}) );
 691                     }
 692
 693                     delete $sd->{failed_nodes};
 694
 695                     # store flag to indicate successful start - only valid while state == 'started'
 696                     $sd->{running} = 1;
 697
 698                 } elsif ($ec == ERROR) {
 699
 700                     delete $sd->{running};
 701
 702                     # apply our relocate policy if we got ERROR from the LRM
 703                     $self->record_service_failed_on_node($sid, $sd->{node});
 704
 705                     if (scalar(@{$sd->{failed_nodes}}) <= $cd->{max_relocate}) {
 706
 707                         # tell select_service_node to relocate if possible
 708                         $try_next = 1;
 709
 710                         $haenv->log('warning', "starting service $sid on node".
 711                                    " '$sd->{node}' failed, relocating service.");
 712
 713                     } else {
 714
 715                         $haenv->log('err', "recovery policy for service $sid " .
 716                                     "failed, entering error state. Failed nodes: ".
 717                                     join(', ', @{$sd->{failed_nodes}}));
 718                         &$change_service_state($self, $sid, 'error');
 719                         return;
 720
 721                     }
 722                 } else {
 723                     $self->record_service_failed_on_node($sid, $sd->{node});
 724
 725                     $haenv->log('err', "service '$sid' got unrecoverable error" .
 726                                 " (exit code $ec))");
 727                     # we have no save way out (yet) for other errors
 728                     &$change_service_state($self, $sid, 'error');
 729                     return;
 730                 }
 731             }
 732
 733             my $node = select_service_node($self->{groups}, $self->{online_node_usage},
 734                                            $cd, $sd->{node}, $try_next, $sd->{failed_nodes});
 735
 736             if ($node && ($sd->{node} ne $node)) {
 737                 if ($cd->{type} eq 'vm') {
 738                     $haenv->log('info', "migrate service '$sid' to node '$node' (running)");
 739                     &$change_service_state($self, $sid, 'migrate', node => $sd->{node}, target => $node);
 740                 } else {
 741                     $haenv->log('info', "relocate service '$sid' to node '$node'");
 742                     &$change_service_state($self, $sid, 'relocate', node => $sd->{node}, target => $node);
 743                 }
 744             } else {
 745                 if ($try_next && !defined($node)) {
 746                     $haenv->log('warning', "Start Error Recovery: Tried all available " .
 747                                 " nodes for service '$sid', retry start on current node. " .
 748                                 "Tried nodes: " . join(', ', @{$sd->{failed_nodes}}));
 749                 }
 750                 # ensure service get started again if it went unexpected down
 751                 # but ensure also no LRM result gets lost
 752                 $sd->{uid} = compute_new_uuid($sd->{state}) if defined($lrm_res);
 753             }
 754         }
 755
 756         return;
 757     }
 758
 759     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 760 }
 761
 762 sub next_state_error {
 763     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 764
 765     my $ns = $self->{ns};
 766     my $ms = $self->{ms};
 767
 768     if ($cd->{state} eq 'disabled') {
 769         # clean up on error recovery
 770         delete $sd->{failed_nodes};
 771
 772         &$change_service_state($self, $sid, 'stopped');
 773         return;
 774     }
 775
 776 }
 777
 778 1;