src/PVE/HA/Manager.pm

   1 package PVE::HA::Manager;
   2
   3 use strict;
   4 use warnings;
   5 use Digest::MD5 qw(md5_base64);
   6
   7 use PVE::Tools;
   8 use PVE::HA::Tools ':exit_codes';
   9 use PVE::HA::NodeStatus;
  10
  11 sub new {
  12     my ($this, $haenv) = @_;
  13
  14     my $class = ref($this) || $this;
  15
  16     my $self = bless { haenv => $haenv }, $class;
  17
  18     my $old_ms = $haenv->read_manager_status();
  19
  20     # we only copy the state part of the manager which cannot be auto generated
  21
  22     $self->{ns} = PVE::HA::NodeStatus->new($haenv, $old_ms->{node_status} || {});
  23
  24     # fixme: use separate class  PVE::HA::ServiceStatus
  25     $self->{ss} = $old_ms->{service_status} || {};
  26
  27     $self->{ms} = { master_node => $haenv->nodename() };
  28
  29     return $self;
  30 }
  31
  32 sub cleanup {
  33     my ($self) = @_;
  34
  35     # todo: ?
  36 }
  37
  38 sub flush_master_status {
  39     my ($self) = @_;
  40
  41     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
  42
  43     $ms->{node_status} = $ns->{status};
  44     $ms->{service_status} = $ss;
  45     $ms->{timestamp} = $haenv->get_time();
  46
  47     $haenv->write_manager_status($ms);
  48 }
  49
  50 sub get_service_group {
  51     my ($groups, $online_node_usage, $service_conf) = @_;
  52
  53     my $group = {};
  54     # add all online nodes to default group to allow try_next when no group set
  55     foreach my $node (keys %$online_node_usage) {
  56         $group->{nodes}->{$node} = 1;
  57     }
  58
  59     # overwrite default if service is bound to a specific group
  60     $group =  $groups->{ids}->{$service_conf->{group}} if $service_conf->{group} &&
  61         $groups->{ids}->{$service_conf->{group}};
  62
  63     return $group;
  64 }
  65
  66 # groups available nodes with their priority as group index
  67 sub get_node_priority_groups {
  68     my ($group, $online_node_usage) = @_;
  69
  70     my $pri_groups = {};
  71     my $group_members = {};
  72     foreach my $entry (keys %{$group->{nodes}}) {
  73         my ($node, $pri) = ($entry, 0);
  74         if ($entry =~ m/^(\S+):(\d+)$/) {
  75             ($node, $pri) = ($1, $2);
  76         }
  77         next if !defined($online_node_usage->{$node}); # offline
  78         $pri_groups->{$pri}->{$node} = 1;
  79         $group_members->{$node} = $pri;
  80     }
  81
  82     # add non-group members to unrestricted groups (priority -1)
  83     if (!$group->{restricted}) {
  84         my $pri = -1;
  85         foreach my $node (keys %$online_node_usage) {
  86             next if defined($group_members->{$node});
  87             $pri_groups->{$pri}->{$node} = 1;
  88             $group_members->{$node} = -1;
  89         }
  90     }
  91
  92     return ($pri_groups, $group_members);
  93 }
  94
  95 sub select_service_node {
  96     my ($groups, $online_node_usage, $service_conf, $current_node, $try_next, $tried_nodes) = @_;
  97
  98     my $group = get_service_group($groups, $online_node_usage, $service_conf);
  99
 100     my ($pri_groups, $group_members) = get_node_priority_groups($group, $online_node_usage);
 101
 102     my @pri_list = sort {$b <=> $a} keys %$pri_groups;
 103     return undef if !scalar(@pri_list);
 104
 105     # stay on current node if possible (avoids random migrations)
 106     if (!$try_next && $group->{nofailback} && defined($group_members->{$current_node})) {
 107         return $current_node;
 108     }
 109
 110     # select node from top priority node list
 111
 112     my $top_pri = $pri_list[0];
 113
 114     # try to avoid nodes where the service failed already if we want to relocate
 115     if ($try_next) {
 116         foreach my $node (@$tried_nodes) {
 117             delete $pri_groups->{$top_pri}->{$node};
 118         }
 119     }
 120
 121     my @nodes = sort {
 122         $online_node_usage->{$a} <=> $online_node_usage->{$b} || $a cmp $b
 123     } keys %{$pri_groups->{$top_pri}};
 124
 125     my $found;
 126     for (my $i = scalar(@nodes) - 1; $i >= 0; $i--) {
 127         my $node = $nodes[$i];
 128         if ($node eq $current_node) {
 129             $found = $i;
 130             last;
 131         }
 132     }
 133
 134     if ($try_next) {
 135         if (defined($found) && ($found < (scalar(@nodes) - 1))) {
 136             return $nodes[$found + 1];
 137         } else {
 138             return $nodes[0];
 139         }
 140     } elsif (defined($found)) {
 141         return $nodes[$found];
 142     } else {
 143         return $nodes[0];
 144     }
 145 }
 146
 147 my $uid_counter = 0;
 148
 149 sub compute_new_uuid {
 150     my ($state) = @_;
 151
 152     $uid_counter++;
 153     return md5_base64($state . $$ . time() . $uid_counter);
 154 }
 155
 156 my $valid_service_states = {
 157     stopped => 1,
 158     request_stop => 1,
 159     started => 1,
 160     fence => 1,
 161     migrate => 1,
 162     relocate => 1,
 163     freeze => 1,
 164     error => 1,
 165 };
 166
 167 sub recompute_online_node_usage {
 168     my ($self) = @_;
 169
 170     my $online_node_usage = {};
 171
 172     my $online_nodes = $self->{ns}->list_online_nodes();
 173
 174     foreach my $node (@$online_nodes) {
 175         $online_node_usage->{$node} = 0;
 176     }
 177
 178     foreach my $sid (keys %{$self->{ss}}) {
 179         my $sd = $self->{ss}->{$sid};
 180         my $state = $sd->{state};
 181         if (defined($online_node_usage->{$sd->{node}})) {
 182             if (($state eq 'started') || ($state eq 'request_stop') ||
 183                 ($state eq 'fence') || ($state eq 'freeze') || ($state eq 'error')) {
 184                 $online_node_usage->{$sd->{node}}++;
 185             } elsif (($state eq 'migrate') || ($state eq 'relocate')) {
 186                 $online_node_usage->{$sd->{target}}++;
 187             } elsif ($state eq 'stopped') {
 188                 # do nothing
 189             } else {
 190                 die "should not be reached";
 191             }
 192         }
 193     }
 194
 195     $self->{online_node_usage} = $online_node_usage;
 196 }
 197
 198 my $change_service_state = sub {
 199     my ($self, $sid, $new_state, %params) = @_;
 200
 201     my ($haenv, $ss) = ($self->{haenv}, $self->{ss});
 202
 203     my $sd = $ss->{$sid} || die "no such service '$sid";
 204
 205     my $old_state = $sd->{state};
 206     my $old_node = $sd->{node};
 207     my $old_failed_nodes = $sd->{failed_nodes};
 208
 209     die "no state change" if $old_state eq $new_state; # just to be sure
 210
 211     die "invalid CRM service state '$new_state'\n" if !$valid_service_states->{$new_state};
 212
 213     foreach my $k (keys %$sd) { delete $sd->{$k}; };
 214
 215     $sd->{state} = $new_state;
 216     $sd->{node} = $old_node;
 217     $sd->{failed_nodes} = $old_failed_nodes if defined($old_failed_nodes);
 218
 219     my $text_state = '';
 220     foreach my $k (sort keys %params) {
 221         my $v = $params{$k};
 222         $text_state .= ", " if $text_state;
 223         $text_state .= "$k = $v";
 224         $sd->{$k} = $v;
 225     }
 226
 227     $self->recompute_online_node_usage();
 228
 229     $sd->{uid} = compute_new_uuid($new_state);
 230
 231     $text_state = "  ($text_state)" if $text_state;
 232     $haenv->log('info', "service '$sid': state changed from '${old_state}'" .
 233                 " to '${new_state}'$text_state");
 234 };
 235
 236 # clean up a possible bad state from a recovered service to allow its start
 237 my $fence_recovery_cleanup = sub {
 238     my ($self, $sid, $fenced_node) = @_;
 239
 240     my $haenv = $self->{haenv};
 241
 242     my (undef, $type, $id) = $haenv->parse_sid($sid);
 243     my $plugin = PVE::HA::Resources->lookup($type);
 244
 245     # should not happen
 246     die "unknown resource type '$type'" if !$plugin;
 247
 248     # locks may block recovery, cleanup those which are safe to remove after fencing,
 249     # i.e., after the original node was reset and thus all it's state
 250     my $removable_locks = ['backup', 'mounted', 'migrate', 'clone', 'rollback', 'snapshot', 'snapshot-delete', 'suspending', 'suspended'];
 251     if (my $removed_lock = $plugin->remove_locks($haenv, $id, $removable_locks, $fenced_node)) {
 252         $haenv->log('warning', "removed leftover lock '$removed_lock' from recovered " .
 253                     "service '$sid' to allow its start.");
 254     }
 255 };
 256
 257 # after a node was fenced this recovers the service to a new node
 258 my $recover_fenced_service = sub {
 259     my ($self, $sid, $cd) = @_;
 260
 261     my ($haenv, $ss) = ($self->{haenv}, $self->{ss});
 262
 263     my $sd = $ss->{$sid};
 264
 265     if ($sd->{state} ne 'fence') { # should not happen
 266         $haenv->log('err', "cannot recover service '$sid' from fencing," .
 267                     " wrong state '$sd->{state}'");
 268         return;
 269     }
 270
 271     my $fenced_node = $sd->{node}; # for logging purpose
 272
 273     $self->recompute_online_node_usage(); # we want the most current node state
 274
 275     my $recovery_node = select_service_node($self->{groups},
 276                                             $self->{online_node_usage},
 277                                             $cd, $sd->{node});
 278
 279     if ($recovery_node) {
 280         $haenv->log('info', "recover service '$sid' from fenced node " .
 281                     "'$fenced_node' to node '$recovery_node'");
 282
 283         &$fence_recovery_cleanup($self, $sid, $fenced_node);
 284
 285         $haenv->steal_service($sid, $sd->{node}, $recovery_node);
 286
 287         # $sd *is normally read-only*, fencing is the exception
 288         $cd->{node} = $sd->{node} = $recovery_node;
 289         my $new_state = ($cd->{state} eq 'started') ? 'started' : 'request_stop';
 290         &$change_service_state($self, $sid, $new_state, node => $recovery_node);
 291     } else {
 292         # no possible node found, cannot recover
 293         $haenv->log('err', "recovering service '$sid' from fenced node " .
 294                     "'$fenced_node' failed, no recovery node found");
 295         &$change_service_state($self, $sid, 'error');
 296     }
 297 };
 298
 299 # read LRM status for all nodes
 300 sub read_lrm_status {
 301     my ($self) = @_;
 302
 303     my $nodes = $self->{ns}->list_nodes();
 304     my $haenv = $self->{haenv};
 305
 306     my $results = {};
 307     my $modes = {};
 308     foreach my $node (@$nodes) {
 309         my $lrm_status = $haenv->read_lrm_status($node);
 310         $modes->{$node} = $lrm_status->{mode} || 'active';
 311         foreach my $uid (keys %{$lrm_status->{results}}) {
 312             next if $results->{$uid}; # should not happen
 313             $results->{$uid} = $lrm_status->{results}->{$uid};
 314         }
 315     }
 316
 317
 318     return ($results, $modes);
 319 }
 320
 321 # read new crm commands and save them into crm master status
 322 sub update_crm_commands {
 323     my ($self) = @_;
 324
 325     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 326
 327     my $cmdlist = $haenv->read_crm_commands();
 328
 329     foreach my $cmd (split(/\n/, $cmdlist)) {
 330         chomp $cmd;
 331
 332         if ($cmd =~ m/^(migrate|relocate)\s+(\S+)\s+(\S+)$/) {
 333             my ($task, $sid, $node) = ($1, $2, $3);
 334             if (my $sd = $ss->{$sid}) {
 335                 if (!$ns->node_is_online($node)) {
 336                     $haenv->log('err', "crm command error - node not online: $cmd");
 337                 } else {
 338                     if ($node eq $sd->{node}) {
 339                         $haenv->log('info', "ignore crm command - service already on target node: $cmd");
 340                     } else {
 341                         $haenv->log('info', "got crm command: $cmd");
 342                         $ss->{$sid}->{cmd} = [ $task, $node ];
 343                     }
 344                 }
 345             } else {
 346                 $haenv->log('err', "crm command error - no such service: $cmd");
 347             }
 348
 349         } elsif ($cmd =~ m/^stop\s+(\S+)\s+(\S+)$/) {
 350             my ($sid, $timeout) = ($1, $2);
 351             if (my $sd = $ss->{$sid}) {
 352                 $haenv->log('info', "got crm command: $cmd");
 353                 $ss->{$sid}->{cmd} = [ 'stop', $timeout ];
 354             } else {
 355                 $haenv->log('err', "crm command error - no such service: $cmd");
 356             }
 357         } else {
 358             $haenv->log('err', "unable to parse crm command: $cmd");
 359         }
 360     }
 361
 362 }
 363
 364 sub manage {
 365     my ($self) = @_;
 366
 367     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 368
 369     $ns->update($haenv->get_node_info());
 370
 371     if (!$ns->node_is_online($haenv->nodename())) {
 372         $haenv->log('info', "master seems offline");
 373         return;
 374     }
 375
 376     my ($lrm_results, $lrm_modes) = $self->read_lrm_status();
 377
 378     my $sc = $haenv->read_service_config();
 379
 380     $self->{groups} = $haenv->read_group_config(); # update
 381
 382     # compute new service status
 383
 384     # add new service
 385     foreach my $sid (sort keys %$sc) {
 386         next if $ss->{$sid}; # already there
 387         my $cd = $sc->{$sid};
 388         next if $cd->{state} eq 'ignored';
 389
 390         $haenv->log('info', "adding new service '$sid' on node '$cd->{node}'");
 391         # assume we are running to avoid relocate running service at add
 392         my $state = ($cd->{state} eq 'started') ? 'started' : 'request_stop';
 393         $ss->{$sid} = { state => $state, node => $cd->{node},
 394                         uid => compute_new_uuid('started') };
 395     }
 396
 397     # remove stale or ignored services from manager state
 398     foreach my $sid (keys %$ss) {
 399         next if $sc->{$sid} && $sc->{$sid}->{state} ne 'ignored';
 400
 401         my $reason =  defined($sc->{$sid}) ? 'ignored state requested' : 'no config';
 402         $haenv->log('info', "removing stale service '$sid' ($reason)");
 403
 404         # remove all service related state information
 405         delete $ss->{$sid};
 406     }
 407
 408     $self->update_crm_commands();
 409
 410     for (;;) {
 411         my $repeat = 0;
 412
 413         $self->recompute_online_node_usage();
 414
 415         foreach my $sid (sort keys %$ss) {
 416             my $sd = $ss->{$sid};
 417             my $cd = $sc->{$sid} || { state => 'disabled' };
 418
 419             my $lrm_res = $sd->{uid} ? $lrm_results->{$sd->{uid}} : undef;
 420
 421             my $last_state = $sd->{state};
 422
 423             if ($last_state eq 'stopped') {
 424
 425                 $self->next_state_stopped($sid, $cd, $sd, $lrm_res);
 426
 427             } elsif ($last_state eq 'started') {
 428
 429                 $self->next_state_started($sid, $cd, $sd, $lrm_res);
 430
 431             } elsif ($last_state eq 'migrate' || $last_state eq 'relocate') {
 432
 433                 $self->next_state_migrate_relocate($sid, $cd, $sd, $lrm_res);
 434
 435             } elsif ($last_state eq 'fence') {
 436
 437                 # do nothing here - wait until fenced
 438
 439             } elsif ($last_state eq 'request_stop') {
 440
 441                 $self->next_state_request_stop($sid, $cd, $sd, $lrm_res);
 442
 443             } elsif ($last_state eq 'freeze') {
 444
 445                 my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 446                 # unfreeze
 447                 my $state = ($cd->{state} eq 'started') ? 'started' : 'request_stop';
 448                 &$change_service_state($self, $sid, $state)
 449                     if $lrm_mode && $lrm_mode eq 'active';
 450
 451             } elsif ($last_state eq 'error') {
 452
 453                 $self->next_state_error($sid, $cd, $sd, $lrm_res);
 454
 455             } else {
 456
 457                 die "unknown service state '$last_state'";
 458             }
 459
 460             my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 461             if ($lrm_mode && $lrm_mode eq 'restart') {
 462                 if (($sd->{state} eq 'started' || $sd->{state} eq 'stopped' ||
 463                      $sd->{state} eq 'request_stop')) {
 464                     &$change_service_state($self, $sid, 'freeze');
 465                 }
 466             }
 467
 468             $repeat = 1 if $sd->{state} ne $last_state;
 469         }
 470
 471         # handle fencing
 472         my $fenced_nodes = {};
 473         foreach my $sid (sort keys %$ss) {
 474             my $sd = $ss->{$sid};
 475             next if $sd->{state} ne 'fence';
 476
 477             if (!defined($fenced_nodes->{$sd->{node}})) {
 478                 $fenced_nodes->{$sd->{node}} = $ns->fence_node($sd->{node}) || 0;
 479             }
 480
 481             next if !$fenced_nodes->{$sd->{node}};
 482
 483             # node fence was successful - recover service
 484             &$recover_fenced_service($self, $sid, $sc->{$sid});
 485         }
 486
 487         last if !$repeat;
 488     }
 489
 490     $self->flush_master_status();
 491 }
 492
 493 # functions to compute next service states
 494 # $cd: service configuration data (read only)
 495 # $sd: service status data (read only)
 496 #
 497 # Note: use change_service_state() to alter state
 498 #
 499
 500 sub next_state_request_stop {
 501     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 502
 503     my $haenv = $self->{haenv};
 504     my $ns = $self->{ns};
 505
 506     # check result from LRM daemon
 507     if ($lrm_res) {
 508         my $exit_code = $lrm_res->{exit_code};
 509         if ($exit_code == SUCCESS) {
 510             &$change_service_state($self, $sid, 'stopped');
 511             return;
 512         } else {
 513             $haenv->log('err', "service '$sid' stop failed (exit code $exit_code)");
 514             &$change_service_state($self, $sid, 'error'); # fixme: what state?
 515             return;
 516         }
 517     }
 518
 519     if ($ns->node_is_offline_delayed($sd->{node})) {
 520         &$change_service_state($self, $sid, 'fence');
 521         return;
 522     }
 523 }
 524
 525 sub next_state_migrate_relocate {
 526     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 527
 528     my $haenv = $self->{haenv};
 529     my $ns = $self->{ns};
 530
 531     # check result from LRM daemon
 532     if ($lrm_res) {
 533         my $exit_code = $lrm_res->{exit_code};
 534         my $req_state = $cd->{state} eq 'started' ? 'started' : 'request_stop';
 535         if ($exit_code == SUCCESS) {
 536             &$change_service_state($self, $sid, $req_state, node => $sd->{target});
 537             return;
 538         } elsif ($exit_code == EWRONG_NODE) {
 539             $haenv->log('err', "service '$sid' - migration failed: service" .
 540                         " registered on wrong node!");
 541             &$change_service_state($self, $sid, 'error');
 542         } else {
 543             $haenv->log('err', "service '$sid' - migration failed (exit code $exit_code)");
 544             &$change_service_state($self, $sid, $req_state, node => $sd->{node});
 545             return;
 546         }
 547     }
 548
 549     if ($ns->node_is_offline_delayed($sd->{node})) {
 550         &$change_service_state($self, $sid, 'fence');
 551         return;
 552     }
 553 }
 554
 555 sub next_state_stopped {
 556     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 557
 558     my $haenv = $self->{haenv};
 559     my $ns = $self->{ns};
 560
 561     if ($sd->{node} ne $cd->{node}) {
 562         # this can happen if we fence a node with active migrations
 563         # hack: modify $sd (normally this should be considered read-only)
 564         $haenv->log('info', "fixup service '$sid' location ($sd->{node} => $cd->{node})");
 565         $sd->{node} = $cd->{node};
 566     }
 567
 568     if ($sd->{cmd}) {
 569         my $cmd = shift @{$sd->{cmd}};
 570
 571         if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 572             my $target = shift @{$sd->{cmd}};
 573             if (!$ns->node_is_online($target)) {
 574                 $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 575             } elsif ($sd->{node} eq $target) {
 576                 $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 577             } else {
 578                 &$change_service_state($self, $sid, $cmd, node => $sd->{node},
 579                                        target => $target);
 580                 return;
 581             }
 582         } elsif ($cmd eq 'stop') {
 583                 $haenv->log('info', "ignore service '$sid' $cmd request - service already stopped");
 584         } else {
 585             $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 586         }
 587         delete $sd->{cmd};
 588     }
 589
 590     if ($cd->{state} eq 'disabled') {
 591         # NOTE: do nothing here, the stop state is an exception as we do not
 592         # process the LRM result here, thus the LRM always tries to stop the
 593         # service (protection for the case no CRM is active)
 594         return;
 595     }
 596
 597     if ($ns->node_is_offline_delayed($sd->{node})) {
 598         &$change_service_state($self, $sid, 'fence');
 599         return;
 600     }
 601
 602     if ($cd->{state} eq 'stopped') {
 603         # almost the same as 'disabled' state but the service will also get recovered
 604         return;
 605     }
 606
 607     if ($cd->{state} eq 'started') {
 608         # simply mark it started, if it's on the wrong node
 609         # next_state_started will fix that for us
 610         &$change_service_state($self, $sid, 'started', node => $sd->{node});
 611         return;
 612     }
 613
 614     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 615 }
 616
 617 sub record_service_failed_on_node {
 618     my ($self, $sid, $node) = @_;
 619
 620     if (!defined($self->{ss}->{$sid}->{failed_nodes})) {
 621         $self->{ss}->{$sid}->{failed_nodes} = [];
 622     }
 623
 624     push @{$self->{ss}->{$sid}->{failed_nodes}}, $node;
 625 }
 626
 627 sub next_state_started {
 628     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 629
 630     my $haenv = $self->{haenv};
 631     my $master_status = $self->{ms};
 632     my $ns = $self->{ns};
 633
 634     if (!$ns->node_is_online($sd->{node})) {
 635         if ($ns->node_is_offline_delayed($sd->{node})) {
 636             &$change_service_state($self, $sid, 'fence');
 637         }
 638         return;
 639     }
 640
 641     if ($cd->{state} eq 'disabled' || $cd->{state} eq 'stopped') {
 642         &$change_service_state($self, $sid, 'request_stop');
 643         return;
 644     }
 645
 646     if ($cd->{state} eq 'started') {
 647
 648         if ($sd->{cmd}) {
 649             my $cmd = shift @{$sd->{cmd}};
 650
 651             if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 652                 my $target = shift @{$sd->{cmd}};
 653                 if (!$ns->node_is_online($target)) {
 654                     $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 655                 } elsif ($sd->{node} eq $target) {
 656                     $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 657                 } else {
 658                     $haenv->log('info', "$cmd service '$sid' to node '$target'");
 659                     &$change_service_state($self, $sid, $cmd, node => $sd->{node}, target => $target);
 660                 }
 661             } elsif ($cmd eq 'stop') {
 662                 my $timeout = shift @{$sd->{cmd}};
 663                 if ($timeout == 0) {
 664                     $haenv->log('info', "request immediate service hard-stop for service '$sid'");
 665                 } else {
 666                     $haenv->log('info', "request graceful stop with timeout '$timeout' for service '$sid'");
 667                 }
 668                 &$change_service_state($self, $sid, 'request_stop', timeout => $timeout);
 669                 $haenv->update_service_config($sid, {'state' => 'stopped'});
 670             } else {
 671                 $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 672             }
 673
 674             delete $sd->{cmd};
 675
 676         } else {
 677
 678             my $try_next = 0;
 679
 680             if ($lrm_res) {
 681
 682                 my $ec = $lrm_res->{exit_code};
 683                 if ($ec == SUCCESS) {
 684
 685                     if (defined($sd->{failed_nodes})) {
 686                         $haenv->log('info', "relocation policy successful for '$sid' on node '$sd->{node}'," .
 687                                     " failed nodes: " . join(', ', @{$sd->{failed_nodes}}) );
 688                     }
 689
 690                     delete $sd->{failed_nodes};
 691
 692                     # store flag to indicate successful start - only valid while state == 'started'
 693                     $sd->{running} = 1;
 694
 695                 } elsif ($ec == ERROR) {
 696
 697                     delete $sd->{running};
 698
 699                     # apply our relocate policy if we got ERROR from the LRM
 700                     $self->record_service_failed_on_node($sid, $sd->{node});
 701
 702                     if (scalar(@{$sd->{failed_nodes}}) <= $cd->{max_relocate}) {
 703
 704                         # tell select_service_node to relocate if possible
 705                         $try_next = 1;
 706
 707                         $haenv->log('warning', "starting service $sid on node".
 708                                    " '$sd->{node}' failed, relocating service.");
 709
 710                     } else {
 711
 712                         $haenv->log('err', "recovery policy for service $sid " .
 713                                     "failed, entering error state. Failed nodes: ".
 714                                     join(', ', @{$sd->{failed_nodes}}));
 715                         &$change_service_state($self, $sid, 'error');
 716                         return;
 717
 718                     }
 719                 } else {
 720                     $self->record_service_failed_on_node($sid, $sd->{node});
 721
 722                     $haenv->log('err', "service '$sid' got unrecoverable error" .
 723                                 " (exit code $ec))");
 724                     # we have no save way out (yet) for other errors
 725                     &$change_service_state($self, $sid, 'error');
 726                     return;
 727                 }
 728             }
 729
 730             my $node = select_service_node($self->{groups}, $self->{online_node_usage},
 731                                            $cd, $sd->{node}, $try_next, $sd->{failed_nodes});
 732
 733             if ($node && ($sd->{node} ne $node)) {
 734                 if ($cd->{type} eq 'vm') {
 735                     $haenv->log('info', "migrate service '$sid' to node '$node' (running)");
 736                     &$change_service_state($self, $sid, 'migrate', node => $sd->{node}, target => $node);
 737                 } else {
 738                     $haenv->log('info', "relocate service '$sid' to node '$node'");
 739                     &$change_service_state($self, $sid, 'relocate', node => $sd->{node}, target => $node);
 740                 }
 741             } else {
 742                 if ($try_next && !defined($node)) {
 743                     $haenv->log('warning', "Start Error Recovery: Tried all available " .
 744                                 " nodes for service '$sid', retry start on current node. " .
 745                                 "Tried nodes: " . join(', ', @{$sd->{failed_nodes}}));
 746                 }
 747                 # ensure service get started again if it went unexpected down
 748                 # but ensure also no LRM result gets lost
 749                 $sd->{uid} = compute_new_uuid($sd->{state}) if defined($lrm_res);
 750             }
 751         }
 752
 753         return;
 754     }
 755
 756     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 757 }
 758
 759 sub next_state_error {
 760     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 761
 762     my $ns = $self->{ns};
 763     my $ms = $self->{ms};
 764
 765     if ($cd->{state} eq 'disabled') {
 766         # clean up on error recovery
 767         delete $sd->{failed_nodes};
 768
 769         &$change_service_state($self, $sid, 'stopped');
 770         return;
 771     }
 772
 773 }
 774
 775 1;