src/PVE/HA/Resources/PVECT.pm

   1 package PVE::HA::Resources::PVECT;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::HA::Tools;
   7
   8 use PVE::LXC;
   9 use PVE::LXC::Config;
  10 use PVE::API2::LXC;
  11 use PVE::API2::LXC::Status;
  12
  13 use base qw(PVE::HA::Resources);
  14
  15 sub type {
  16     return 'ct';
  17 }
  18
  19 sub verify_name {
  20     my ($class, $name) = @_;
  21
  22     die "invalid VMID\n" if $name !~ m/^[1-9][0-9]+$/;
  23 }
  24
  25 sub options {
  26     return {
  27         state => { optional => 1 },
  28         group => { optional => 1 },
  29         comment => { optional => 1 },
  30         max_restart => { optional => 1 },
  31         max_relocate => { optional => 1 },
  32     };
  33 }
  34
  35 sub config_file {
  36     my ($class, $vmid, $nodename) = @_;
  37
  38     return PVE::LXC::Config->config_file($vmid, $nodename);
  39 }
  40
  41 sub exists {
  42     my ($class, $vmid, $noerr) = @_;
  43
  44     my $vmlist = PVE::Cluster::get_vmlist();
  45
  46     if(!defined($vmlist->{ids}->{$vmid})) {
  47         die "resource 'ct:$vmid' does not exists in cluster\n" if !$noerr;
  48         return undef;
  49     } else {
  50         return 1;
  51     }
  52 }
  53
  54 sub start {
  55     my ($class, $haenv, $id) = @_;
  56
  57     my $nodename = $haenv->nodename();
  58
  59     my $params = {
  60         node => $nodename,
  61         vmid => $id
  62     };
  63
  64     my $upid = PVE::API2::LXC::Status->vm_start($params);
  65     PVE::HA::Tools::upid_wait($upid, $haenv);
  66 }
  67
  68 sub shutdown {
  69     my ($class, $haenv, $id) = @_;
  70
  71     my $nodename = $haenv->nodename();
  72     my $shutdown_timeout = 60; # fixme: make this configurable
  73
  74     my $params = {
  75         node => $nodename,
  76         vmid => $id,
  77         timeout => $shutdown_timeout,
  78         forceStop => 1,
  79     };
  80
  81     my $upid = PVE::API2::LXC::Status->vm_shutdown($params);
  82     PVE::HA::Tools::upid_wait($upid, $haenv);
  83 }
  84
  85 sub migrate {
  86     my ($class, $haenv, $id, $target, $online) = @_;
  87
  88     my $nodename = $haenv->nodename();
  89
  90     my $params = {
  91         node => $nodename,
  92         vmid => $id,
  93         target => $target,
  94         online => 0, # we cannot migrate CT (yet) online, only relocate
  95     };
  96
  97     # always relocate container for now
  98     if ($class->check_running($haenv, $id)) {
  99         $class->shutdown($haenv, $id);
 100     }
 101
 102     my $oldconfig = $class->config_file($id, $nodename);
 103
 104     my $upid = PVE::API2::LXC->migrate_vm($params);
 105     PVE::HA::Tools::upid_wait($upid, $haenv);
 106
 107     # check if vm really moved
 108     return !(-f $oldconfig);
 109 }
 110
 111 sub check_running {
 112     my ($class, $haenv, $vmid) = @_;
 113
 114     return PVE::LXC::check_running($vmid);
 115 }
 116
 117 sub remove_locks {
 118     my ($self, $haenv, $id, $locks, $service_node) = @_;
 119
 120     $service_node = $service_node || $haenv->nodename();
 121
 122     my $conf = PVE::LXC::Config->load_config($id, $service_node);
 123
 124     return undef if !defined($conf->{lock});
 125
 126     foreach my $lock (@$locks) {
 127         if ($conf->{lock} eq $lock) {
 128             delete $conf->{lock};
 129
 130             my $cfspath = PVE::LXC::Config->cfs_config_path($id, $service_node);
 131             PVE::Cluster::cfs_write_file($cfspath, $conf);
 132
 133             return $lock;
 134         }
 135     }
 136
 137     return undef;
 138 }
 139
 140 1;