PVE/APIServer/Utils.pm

   1 package PVE::APIServer::Utils;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Net::IP;
   7
   8 # all settings are used for pveproxy and pmgproxy
   9 # the ALLOW/DENY/POLICY is also used by spiceproxy
  10 sub read_proxy_config {
  11     my ($proxy_name) = @_;
  12
  13     my $conffile = "/etc/default/$proxy_name";
  14
  15     # Note: evaluate with bash
  16     my $shcmd = ". $conffile;\n";
  17     $shcmd .= 'echo \"ALLOW_FROM:\$ALLOW_FROM\";';
  18     $shcmd .= 'echo \"DENY_FROM:\$DENY_FROM\";';
  19     $shcmd .= 'echo \"POLICY:\$POLICY\";';
  20     $shcmd .= 'echo \"CIPHERS:\$CIPHERS\";';
  21     $shcmd .= 'echo \"DHPARAMS:\$DHPARAMS\";';
  22     $shcmd .= 'echo \"HONOR_CIPHER_ORDER:\$HONOR_CIPHER_ORDER\";';
  23     $shcmd .= 'echo \"COMPRESSION:\$COMPRESSION\";';
  24
  25     my $data = -f $conffile ? `bash -c "$shcmd"` : '';
  26
  27     my $res = {};
  28
  29     while ($data =~ s/^(.*)\n//) {
  30         my ($key, $value) = split(/:/, $1, 2);
  31         next if !defined($value) || $value eq '';
  32         if ($key eq 'ALLOW_FROM' || $key eq 'DENY_FROM') {
  33             my $ips = [];
  34             foreach my $ip (split(/,/, $value)) {
  35                 $ip = "0/0" if $ip eq 'all';
  36                 push @$ips, Net::IP->new($ip) || die Net::IP::Error() . "\n";
  37             }
  38             $res->{$key} = $ips;
  39         } elsif ($key eq 'POLICY') {
  40             die "unknown policy '$value'\n" if $value !~ m/^(allow|deny)$/;
  41             $res->{$key} = $value;
  42         } elsif ($key eq 'CIPHERS') {
  43             $res->{$key} = $value;
  44         } elsif ($key eq 'DHPARAMS') {
  45             $res->{$key} = $value;
  46         } elsif ($key eq 'HONOR_CIPHER_ORDER' || $key eq 'COMPRESSION') {
  47             die "unknown value '$value' - use 0 or 1\n" if $value !~ m/^(0|1)$/;
  48             $res->{$key} = $value;
  49         } else {
  50             # silently skip everythin else?
  51         }
  52     }
  53
  54     return $res;
  55 }
  56
  57 1;