src/PVE/APIServer/AnyEvent.pm

   1 package PVE::APIServer::AnyEvent;
   2
   3 # Note 1: interactions with Crypt::OpenSSL::RSA
   4 #
   5 # Some handlers (auth_handler) use Crypt::OpenSSL::RSA, which seems to
   6 # set the openssl error variable. We need to clear that here, else
   7 # AnyEvent::TLS aborts the connection.
   8 # Net::SSLeay::ERR_clear_error();
   9
  10 use strict;
  11 use warnings;
  12
  13 use AnyEvent::HTTP;
  14 use AnyEvent::Handle;
  15 use AnyEvent::IO;
  16 use AnyEvent::Socket;
  17 # use AnyEvent::Strict; # only use this for debugging
  18 use AnyEvent::TLS;
  19 use AnyEvent::Util qw(guard fh_nonblocking WSAEWOULDBLOCK WSAEINPROGRESS);
  20
  21 use Compress::Zlib;
  22 use Digest::MD5;
  23 use Digest::SHA;
  24 use Encode;
  25 use Fcntl ();
  26 use Fcntl;
  27 use File::Find;
  28 use File::stat qw();
  29 use IO::File;
  30 use MIME::Base64;
  31 use Net::SSLeay;
  32 use POSIX qw(strftime EINTR EAGAIN);
  33 use Socket qw(IPPROTO_TCP TCP_NODELAY SOMAXCONN);
  34 use Time::HiRes qw(usleep ualarm gettimeofday tv_interval);
  35
  36 #use Data::Dumper; # FIXME: remove, just use: print to_json([$var], {pretty => 1}) ."\n";
  37 use HTTP::Date;
  38 use HTTP::Headers;
  39 use HTTP::Request;
  40 use HTTP::Response;
  41 use HTTP::Status qw(:constants);
  42 use JSON;
  43 use Net::IP;
  44 use URI::Escape;
  45 use URI;
  46
  47 use PVE::INotify;
  48 use PVE::SafeSyslog;
  49 use PVE::Tools qw(trim);
  50
  51 use PVE::APIServer::Formatter;
  52 use PVE::APIServer::Utils;
  53
  54 my $limit_max_headers = 64;
  55 my $limit_max_header_size = 8*1024;
  56 my $limit_max_post = 64*1024;
  57
  58 my $known_methods = {
  59     GET => 1,
  60     POST => 1,
  61     PUT => 1,
  62     DELETE => 1,
  63 };
  64
  65 my $split_abs_uri = sub {
  66     my ($abs_uri, $base_uri) = @_;
  67
  68     my ($format, $rel_uri) = $abs_uri =~ m/^\Q$base_uri\E\/+([a-z][a-z0-9]+)(\/.*)?$/;
  69     $rel_uri = '/' if !$rel_uri;
  70
  71     return wantarray ? ($rel_uri, $format) : $rel_uri;
  72 };
  73
  74 sub dprint {
  75     my ($self, $message) = @_;
  76
  77     return if !$self->{debug};
  78
  79     my ($pkg, $pkgfile, $line, $sub) = caller(1);
  80     $sub =~ s/^(?:.+::)+//;
  81     print "worker[$$]: $pkg +$line: $sub: $message\n";
  82 }
  83
  84 sub log_request {
  85     my ($self, $reqstate) = @_;
  86
  87     my $loginfo = $reqstate->{log};
  88
  89     # like apache2 common log format
  90     # LogFormat "%h %l %u %t \"%r\" %>s %b \"%{Referer}i\" \"%{User-agent}i\""
  91
  92     return if $loginfo->{written}; # avoid duplicate logs
  93     $loginfo->{written} = 1;
  94
  95     my $peerip = $reqstate->{peer_host} || '-';
  96     my $userid = $loginfo->{userid} || '-';
  97     my $content_length = defined($loginfo->{content_length}) ? $loginfo->{content_length} : '-';
  98     my $code =  $loginfo->{code} || 500;
  99     my $requestline = $loginfo->{requestline} || '-';
 100     my $timestr = strftime("%d/%m/%Y:%H:%M:%S %z", localtime());
 101
 102     my $msg = "$peerip - $userid [$timestr] \"$requestline\" $code $content_length\n";
 103
 104     $self->write_log($msg);
 105 }
 106
 107 sub log_aborted_request {
 108     my ($self, $reqstate, $error) = @_;
 109
 110     my $r = $reqstate->{request};
 111     return if !$r; # no active request
 112
 113     if ($error) {
 114         syslog("err", "problem with client $reqstate->{peer_host}; $error");
 115     }
 116
 117     $self->log_request($reqstate);
 118 }
 119
 120 sub cleanup_reqstate {
 121     my ($reqstate, $deletetmpfile) = @_;
 122
 123     delete $reqstate->{log};
 124     delete $reqstate->{request};
 125     delete $reqstate->{proto};
 126     delete $reqstate->{accept_gzip};
 127     delete $reqstate->{starttime};
 128
 129     if ($reqstate->{tmpfilename}) {
 130         unlink $reqstate->{tmpfilename} if $deletetmpfile;
 131         delete $reqstate->{tmpfilename};
 132     }
 133 }
 134
 135 sub client_do_disconnect {
 136     my ($self, $reqstate) = @_;
 137
 138     cleanup_reqstate($reqstate, 1);
 139
 140     my $shutdown_hdl = sub {
 141         my $hdl = shift;
 142
 143         shutdown($hdl->{fh}, 1);
 144         # clear all handlers
 145         $hdl->on_drain(undef);
 146         $hdl->on_read(undef);
 147         $hdl->on_eof(undef);
 148     };
 149
 150     if (my $proxyhdl = delete $reqstate->{proxyhdl}) {
 151         &$shutdown_hdl($proxyhdl)
 152                 if !$proxyhdl->{block_disconnect};
 153     }
 154
 155     my $hdl = delete $reqstate->{hdl};
 156
 157     if (!$hdl) {
 158         syslog('err', "detected empty handle");
 159         return;
 160     }
 161
 162     $self->dprint("close connection $hdl");
 163
 164     &$shutdown_hdl($hdl);
 165
 166     warn "connection count <= 0!\n" if $self->{conn_count} <= 0;
 167
 168     $self->{conn_count}--;
 169
 170     $self->dprint("CLOSE FH" .  $hdl->{fh}->fileno() . " CONN$self->{conn_count}");
 171 }
 172
 173 sub finish_response {
 174     my ($self, $reqstate) = @_;
 175
 176     cleanup_reqstate($reqstate, 0);
 177
 178     my $hdl = $reqstate->{hdl};
 179     return if !$hdl; # already disconnected
 180
 181     if (!$self->{end_loop} && $reqstate->{keep_alive} > 0) {
 182         # print "KEEPALIVE $reqstate->{keep_alive}\n" if $self->{debug};
 183         $hdl->on_read(sub {
 184             eval { $self->push_request_header($reqstate); };
 185             warn $@ if $@;
 186         });
 187     } else {
 188         $hdl->on_drain (sub {
 189             eval {
 190                 $self->client_do_disconnect($reqstate);
 191             };
 192             warn $@ if $@;
 193         });
 194     }
 195 }
 196
 197 sub response_stream {
 198     my ($self, $reqstate, $stream_fh) = @_;
 199
 200     # disable timeout, we don't know how big the data is
 201     $reqstate->{hdl}->timeout(0);
 202
 203     my $buf_size = 4*1024*1024;
 204
 205     my $on_read;
 206     $on_read = sub {
 207         my ($hdl) = @_;
 208         my $reqhdl = $reqstate->{hdl};
 209         return if !$reqhdl;
 210
 211         my $wbuf_len = length($reqhdl->{wbuf});
 212         my $rbuf_len = length($hdl->{rbuf});
 213         # TODO: Take into account $reqhdl->{wbuf_max} ? Right now
 214         # that's unbounded, so just assume $buf_size
 215         my $to_read = $buf_size - $wbuf_len;
 216         $to_read = $rbuf_len if $rbuf_len < $to_read;
 217         if ($to_read > 0) {
 218             my $data = substr($hdl->{rbuf}, 0, $to_read, '');
 219             $reqhdl->push_write($data);
 220             $rbuf_len -= $to_read;
 221         } elsif ($hdl->{_eof}) {
 222             # workaround: AnyEvent gives us a fake EPIPE if we don't consume
 223             # any data when called at EOF, so unregister ourselves - data is
 224             # flushed by on_eof anyway
 225             # see: https://sources.debian.org/src/libanyevent-perl/7.170-2/lib/AnyEvent/Handle.pm/#L1329
 226             $hdl->on_read();
 227             return;
 228         }
 229
 230         # apply backpressure so we don't accept any more data into
 231         # buffer if the client isn't downloading fast enough
 232         # note: read_size can double upon read, and we also need to
 233         # account for one more read after start_read, so *4
 234         if ($rbuf_len + $hdl->{read_size}*4 > $buf_size) {
 235             # stop reading until write buffer is empty
 236             $hdl->on_read();
 237             my $prev_on_drain = $reqhdl->{on_drain};
 238             $reqhdl->on_drain(sub {
 239                 my ($wrhdl) = @_;
 240                 # on_drain called because write buffer is empty, continue reading
 241                 $hdl->on_read($on_read);
 242                 if ($prev_on_drain) {
 243                     $wrhdl->on_drain($prev_on_drain);
 244                     $prev_on_drain->($wrhdl);
 245                 }
 246             });
 247         }
 248     };
 249
 250     $reqstate->{proxyhdl} = AnyEvent::Handle->new(
 251         fh => $stream_fh,
 252         rbuf_max => $buf_size,
 253         timeout => 0,
 254         on_read => $on_read,
 255         on_eof => sub {
 256             my ($hdl) = @_;
 257             eval {
 258                 if (my $reqhdl = $reqstate->{hdl}) {
 259                     $self->log_aborted_request($reqstate);
 260                     # write out any remaining data
 261                     $reqhdl->push_write($hdl->{rbuf}) if length($hdl->{rbuf}) > 0;
 262                     $hdl->{rbuf} = "";
 263                     $reqhdl->push_shutdown();
 264                     $self->finish_response($reqstate);
 265                 }
 266             };
 267             if (my $err = $@) { syslog('err', "$err"); }
 268             $on_read = undef;
 269         },
 270         on_error => sub {
 271             my ($hdl, $fatal, $message) = @_;
 272             eval {
 273                 $self->log_aborted_request($reqstate, $message);
 274                 $self->client_do_disconnect($reqstate);
 275             };
 276             if (my $err = $@) { syslog('err', "$err"); }
 277             $on_read = undef;
 278         },
 279     );
 280 }
 281
 282 sub response {
 283     my ($self, $reqstate, $resp, $mtime, $nocomp, $delay, $stream_fh) = @_;
 284
 285     #print "$$: send response: " . Dumper($resp);
 286
 287     # activate timeout
 288     $reqstate->{hdl}->timeout_reset();
 289     $reqstate->{hdl}->timeout($self->{timeout});
 290
 291     $nocomp = 1 if !$self->{compression};
 292     $nocomp = 1 if !$reqstate->{accept_gzip};
 293
 294     my $code = $resp->code;
 295     my $msg = $resp->message || HTTP::Status::status_message($code);
 296     my $content = $resp->content;
 297
 298     # multiline mode only checks \n for $, so explicitly check for any \n or \r afterwards
 299     ($msg) = $msg =~ m/^(.*)$/m;
 300     if ($msg =~ /[\r\n]/) {
 301         $code = 400; # bad request from user
 302         $msg = HTTP::Status::status_message($code);
 303         $content = '';
 304     }
 305
 306     if ($code =~ /^(1\d\d|[23]04)$/) {
 307         # make sure informational, no content and not modified response send no content
 308         $content = "";
 309     }
 310
 311     $reqstate->{keep_alive} = 0 if ($code >= 400) || $self->{end_loop};
 312
 313     $reqstate->{log}->{code} = $code;
 314
 315     my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.0';
 316     my $res = "$proto $code $msg\015\012";
 317
 318     my $ctime = time();
 319     my $date = HTTP::Date::time2str($ctime);
 320     $resp->header('Date' => $date);
 321     if ($mtime) {
 322         $resp->header('Last-Modified' => HTTP::Date::time2str($mtime));
 323     } else {
 324         $resp->header('Expires' => $date);
 325         $resp->header('Cache-Control' => "max-age=0");
 326         $resp->header("Pragma", "no-cache");
 327     }
 328
 329     $resp->header('Server' => "pve-api-daemon/3.0");
 330
 331     my $content_length;
 332     if ($content && !$stream_fh) {
 333
 334         $content_length = length($content);
 335
 336         if (!$nocomp && ($content_length > 1024)) {
 337             my $comp = Compress::Zlib::memGzip($content);
 338             $resp->header('Content-Encoding', 'gzip');
 339             $content = $comp;
 340             $content_length = length($content);
 341         }
 342         $resp->header("Content-Length" => $content_length);
 343         $reqstate->{log}->{content_length} = $content_length;
 344
 345     } else {
 346         $resp->remove_header("Content-Length");
 347     }
 348
 349     if ($reqstate->{keep_alive} > 0) {
 350         $resp->push_header('Connection' => 'Keep-Alive');
 351     } else {
 352         $resp->header('Connection' => 'close');
 353     }
 354
 355     $res .= $resp->headers_as_string("\015\012");
 356     #print "SEND(without content) $res\n" if $self->{debug};
 357
 358     $res .= "\015\012";
 359     $res .= $content if $content && !$stream_fh;
 360
 361     $self->log_request($reqstate, $reqstate->{request});
 362
 363     if ($stream_fh) {
 364         # write headers and preamble...
 365         $reqstate->{hdl}->push_write($res);
 366         # ...then stream data via an AnyEvent::Handle
 367         $self->response_stream($reqstate, $stream_fh);
 368     } elsif ($delay && $delay > 0) {
 369         my $w; $w = AnyEvent->timer(after => $delay, cb => sub {
 370             undef $w; # delete reference
 371             return if !$reqstate->{hdl}; # already disconnected
 372             $reqstate->{hdl}->push_write($res);
 373             $self->finish_response($reqstate);
 374         });
 375     } else {
 376         $reqstate->{hdl}->push_write($res);
 377         $self->finish_response($reqstate);
 378     }
 379 }
 380
 381 sub error {
 382     my ($self, $reqstate, $code, $msg, $hdr, $content) = @_;
 383
 384     eval {
 385         my $resp = HTTP::Response->new($code, $msg, $hdr, $content);
 386         $self->response($reqstate, $resp);
 387     };
 388     warn $@ if $@;
 389 }
 390
 391 my $file_extension_info = {
 392     css   => { ct => 'text/css' },
 393     html  => { ct => 'text/html' },
 394     js    => { ct => 'application/javascript' },
 395     json  => { ct => 'application/json' },
 396     map   => { ct => 'application/json' },
 397     png   => { ct => 'image/png' , nocomp => 1 },
 398     ico   => { ct => 'image/x-icon', nocomp => 1},
 399     gif   => { ct => 'image/gif', nocomp => 1},
 400     svg   => { ct => 'image/svg+xml' },
 401     jar   => { ct => 'application/java-archive', nocomp => 1},
 402     woff  => { ct => 'application/font-woff', nocomp => 1},
 403     woff2 => { ct => 'application/font-woff2', nocomp => 1},
 404     ttf   => { ct => 'application/font-snft', nocomp => 1},
 405     pdf   => { ct => 'application/pdf', nocomp => 1},
 406     epub  => { ct => 'application/epub+zip', nocomp => 1},
 407     mp3   => { ct => 'audio/mpeg', nocomp => 1},
 408     oga   => { ct => 'audio/ogg', nocomp => 1},
 409     tgz   => { ct => 'application/x-compressed-tar', nocomp => 1},
 410 };
 411
 412 sub send_file_start {
 413     my ($self, $reqstate, $download) = @_;
 414
 415     eval {
 416         # print "SEND FILE $filename\n";
 417         # Note: aio_load() this is not really async unless we use IO::AIO!
 418         eval {
 419
 420             my $r = $reqstate->{request};
 421
 422             my $fh;
 423             my $nocomp;
 424             my $mime;
 425
 426             if (ref($download) eq 'HASH') {
 427                 $mime = $download->{'content-type'};
 428                 my $encoding = $download->{'content-encoding'};
 429                 my $disposition = $download->{'content-disposition'};
 430
 431                 if ($download->{path} && $download->{stream} &&
 432                     $reqstate->{request}->header('PVEDisableProxy'))
 433                 {
 434                     # avoid double stream from a file, let the proxy handle it
 435                     die "internal error: file proxy streaming only available for pvedaemon\n"
 436                         if !$self->{trusted_env};
 437                     my $header = HTTP::Headers->new(
 438                         pvestreamfile => $download->{path},
 439                         Content_Type => $mime,
 440                     );
 441                     $header->header('Content-Encoding' => $encoding) if defined($encoding);
 442                     $header->header('Content-Disposition' => $disposition) if defined($disposition);
 443                     # we need some data so Content-Length gets set correctly and
 444                     # the proxy doesn't wait for more data - place a canary
 445                     my $resp = HTTP::Response->new(200, "OK", $header, "error canary");
 446                     $self->response($reqstate, $resp);
 447                     return;
 448                 }
 449
 450                 if (!($fh = $download->{fh})) {
 451                     my $path = $download->{path};
 452                     die "internal error: {download} returned but neither fh not path given\n"
 453                         if !$path;
 454                     sysopen($fh, "$path", O_NONBLOCK | O_RDONLY)
 455                         or die "open stream path '$path' for reading failed: $!\n";
 456                 }
 457
 458                 if ($download->{stream}) {
 459                     my $header = HTTP::Headers->new(Content_Type => $mime);
 460                     $header->header('Content-Encoding' => $encoding) if defined($encoding);
 461                     $header->header('Content-Disposition' => $disposition) if defined($disposition);
 462                     my $resp = HTTP::Response->new(200, "OK", $header);
 463                     $self->response($reqstate, $resp, undef, 1, 0, $fh);
 464                     return;
 465                 }
 466             } else {
 467                 my $filename = $download;
 468                 $fh = IO::File->new($filename, '<') ||
 469                     die "unable to open file '$filename' - $!\n";
 470
 471                 my ($ext) = $filename =~ m/\.([^.]*)$/;
 472                 my $ext_info = $file_extension_info->{$ext};
 473
 474                 die "unable to detect content type" if !$ext_info;
 475                 $mime = $ext_info->{ct};
 476                 $nocomp = $ext_info->{nocomp};
 477             }
 478
 479             my $stat = File::stat::stat($fh) ||
 480                 die "$!\n";
 481
 482             my $mtime = $stat->mtime;
 483
 484             if (my $ifmod = $r->header('if-modified-since')) {
 485                 my $iftime = HTTP::Date::str2time($ifmod);
 486                 if ($mtime <= $iftime) {
 487                     my $resp = HTTP::Response->new(304, "NOT MODIFIED");
 488                     $self->response($reqstate, $resp, $mtime);
 489                     return;
 490                 }
 491             }
 492
 493             my $data;
 494             my $len = sysread($fh, $data,  $stat->size);
 495             die "got short file\n" if !defined($len) || $len != $stat->size;
 496
 497             my $header = HTTP::Headers->new(Content_Type => $mime);
 498             my $resp = HTTP::Response->new(200, "OK", $header, $data);
 499             $self->response($reqstate, $resp, $mtime, $nocomp);
 500         };
 501         if (my $err = $@) {
 502             $self->error($reqstate, 501, $err);
 503         }
 504     };
 505
 506     warn $@ if $@;
 507 }
 508
 509 sub websocket_proxy {
 510     my ($self, $reqstate, $wsaccept, $wsproto, $param) = @_;
 511
 512     eval {
 513         my $remhost;
 514         my $remport;
 515
 516         my $max_payload_size = 128*1024;
 517
 518         if ($param->{port}) {
 519             $remhost = 'localhost';
 520             $remport = $param->{port};
 521         } elsif ($param->{socket}) {
 522             $remhost = 'unix/';
 523             $remport = $param->{socket};
 524         } else {
 525             die "websocket_proxy: missing port or socket\n";
 526         }
 527
 528         my $encode = sub {
 529             my ($data, $opcode) = @_;
 530
 531             my $string;
 532             my $payload;
 533
 534             $string = $opcode ? $opcode : "\x82"; # binary frame
 535             $payload = $$data;
 536
 537             my $payload_len = length($payload);
 538             if ($payload_len <= 125) {
 539                 $string .= pack 'C', $payload_len;
 540             } elsif ($payload_len <= 0xffff) {
 541                 $string .= pack 'C', 126;
 542                 $string .= pack 'n', $payload_len;
 543             } else {
 544                 $string .= pack 'C', 127;
 545                 $string .= pack 'Q>', $payload_len;
 546             }
 547             $string .= $payload;
 548             return $string;
 549         };
 550
 551         tcp_connect $remhost, $remport, sub {
 552             my ($fh) = @_
 553                 or die "connect to '$remhost:$remport' failed: $!";
 554
 555             $self->dprint("CONNECTed to '$remhost:$remport'");
 556
 557             $reqstate->{proxyhdl} = AnyEvent::Handle->new(
 558                 fh => $fh,
 559                 rbuf_max => $max_payload_size,
 560                 wbuf_max => $max_payload_size*5,
 561                 timeout => 5,
 562                 on_eof => sub {
 563                     my ($hdl) = @_;
 564                     eval {
 565                         $self->log_aborted_request($reqstate);
 566                         $self->client_do_disconnect($reqstate);
 567                     };
 568                     if (my $err = $@) { syslog('err', $err); }
 569                 },
 570                 on_error => sub {
 571                     my ($hdl, $fatal, $message) = @_;
 572                     eval {
 573                         $self->log_aborted_request($reqstate, $message);
 574                         $self->client_do_disconnect($reqstate);
 575                     };
 576                     if (my $err = $@) { syslog('err', "$err"); }
 577                 });
 578
 579             my $proxyhdlreader = sub {
 580                 my ($hdl) = @_;
 581
 582                 my $len = length($hdl->{rbuf});
 583                 my $data = substr($hdl->{rbuf}, 0, $len > $max_payload_size ? $max_payload_size : $len, '');
 584
 585                 my $string = $encode->(\$data);
 586
 587                 $reqstate->{hdl}->push_write($string) if $reqstate->{hdl};
 588             };
 589
 590             my $hdlreader = sub {
 591                 my ($hdl) = @_;
 592
 593                 while (my $len = length($hdl->{rbuf})) {
 594                     return if $len < 2;
 595
 596                     my $hdr = unpack('C', substr($hdl->{rbuf}, 0, 1));
 597                     my $opcode = $hdr & 0b00001111;
 598                     my $fin = $hdr & 0b10000000;
 599
 600                     die "received fragmented websocket frame\n" if !$fin;
 601
 602                     my $rsv = $hdr & 0b01110000;
 603                     die "received websocket frame with RSV flags\n" if $rsv;
 604
 605                     my $payload_len = unpack 'C', substr($hdl->{rbuf}, 1, 1);
 606
 607                     my $masked = $payload_len & 0b10000000;
 608                     die "received unmasked websocket frame from client\n" if !$masked;
 609
 610                     my $offset = 2;
 611                     $payload_len = $payload_len & 0b01111111;
 612                     if ($payload_len == 126) {
 613                         return if $len < 4;
 614                         $payload_len = unpack('n', substr($hdl->{rbuf}, $offset, 2));
 615                         $offset += 2;
 616                     } elsif ($payload_len == 127) {
 617                         return if $len < 10;
 618                         $payload_len = unpack('Q>', substr($hdl->{rbuf}, $offset, 8));
 619                         $offset += 8;
 620                     }
 621
 622                     die "received too large websocket frame (len = $payload_len)\n"
 623                         if ($payload_len > $max_payload_size) || ($payload_len < 0);
 624
 625                     return if $len < ($offset + 4 + $payload_len);
 626
 627                     my $data = substr($hdl->{rbuf}, 0, $offset + 4 + $payload_len, ''); # now consume data
 628
 629                     my $mask = substr($data, $offset, 4);
 630                     $offset += 4;
 631
 632                     my $payload = substr($data, $offset, $payload_len);
 633
 634                     # NULL-mask might be used over TLS, skip to increase performance
 635                     if ($mask ne pack('N', 0)) {
 636                         # repeat 4 byte mask to payload length + up to 4 byte
 637                         $mask = $mask x (int($payload_len / 4) + 1);
 638                         # truncate mask to payload length
 639                         substr($mask, $payload_len) = "";
 640                         # (un-)apply mask
 641                         $payload ^= $mask;
 642                     }
 643
 644                     if ($opcode == 1 || $opcode == 2) {
 645                         $reqstate->{proxyhdl}->push_write($payload) if $reqstate->{proxyhdl};
 646                     } elsif ($opcode == 8) {
 647                         my $statuscode = unpack ("n", $payload);
 648                         $self->dprint("websocket received close. status code: '$statuscode'");
 649                         if (my $proxyhdl = $reqstate->{proxyhdl}) {
 650                             $proxyhdl->{block_disconnect} = 1 if length $proxyhdl->{wbuf};
 651
 652                             $proxyhdl->push_shutdown();
 653                         }
 654                         $hdl->push_shutdown();
 655                     } elsif ($opcode == 9) {
 656                         # ping received, schedule pong
 657                         $reqstate->{hdl}->push_write($encode->(\$payload, "\x8A")) if $reqstate->{hdl};
 658                     } elsif ($opcode == 0xA) {
 659                         # pong received, continue
 660                     } else {
 661                         die "received unhandled websocket opcode $opcode\n";
 662                     }
 663                 }
 664             };
 665
 666             my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.1';
 667
 668             $reqstate->{proxyhdl}->timeout(0);
 669             $reqstate->{proxyhdl}->on_read($proxyhdlreader);
 670             $reqstate->{hdl}->on_read($hdlreader);
 671
 672             # todo: use stop_read/start_read if write buffer grows to much
 673
 674             # FIXME: remove protocol in PVE/PMG 8.x
 675             #
 676             # for backwards, compatibility,  we have to reply with the websocket
 677             # subprotocol from the request
 678             my $res = "$proto 101 Switching Protocols\015\012" .
 679                 "Upgrade: websocket\015\012" .
 680                 "Connection: upgrade\015\012" .
 681                 "Sec-WebSocket-Accept: $wsaccept\015\012" .
 682                 ($wsproto ne "" ? "Sec-WebSocket-Protocol: $wsproto\015\012" : "") .
 683                 "\015\012";
 684
 685             $self->dprint($res);
 686
 687             $reqstate->{hdl}->push_write($res);
 688
 689             # log early
 690             $reqstate->{log}->{code} = 101;
 691             $self->log_request($reqstate);
 692         };
 693
 694     };
 695     if (my $err = $@) {
 696         warn $err;
 697         $self->log_aborted_request($reqstate, $err);
 698         $self->client_do_disconnect($reqstate);
 699     }
 700 }
 701
 702 sub proxy_request {
 703     my ($self, $reqstate, $clientip, $host, $node, $method, $uri, $auth, $params) = @_;
 704
 705     eval {
 706         my $target;
 707         my $keep_alive = 1;
 708
 709         # stringify URI object and verify it starts with a slash
 710         $uri = "$uri";
 711         if ($uri !~ m@^/@) {
 712             $self->error($reqstate, 400, "invalid proxy uri");
 713             return;
 714         }
 715
 716         my $may_stream_file;
 717         if ($host eq 'localhost') {
 718             $target = "http://$host:85$uri";
 719             # keep alive for localhost is not worth (connection setup is about 0.2ms)
 720             $keep_alive = 0;
 721             $may_stream_file = 1;
 722         } elsif (Net::IP::ip_is_ipv6($host)) {
 723             $target = "https://[$host]:8006$uri";
 724         } else {
 725             $target = "https://$host:8006$uri";
 726         }
 727
 728         my $headers = {
 729             PVEDisableProxy => 'true',
 730             PVEClientIP => $clientip,
 731         };
 732
 733         $headers->{'cookie'} = PVE::APIServer::Formatter::create_auth_cookie($auth->{ticket}, $self->{cookie_name})
 734             if $auth->{ticket};
 735         $headers->{'Authorization'} = PVE::APIServer::Formatter::create_auth_header($auth->{api_token}, $self->{apitoken_name})
 736             if $auth->{api_token};
 737         $headers->{'CSRFPreventionToken'} = $auth->{token}
 738             if $auth->{token};
 739         $headers->{'Accept-Encoding'} = 'gzip' if ($reqstate->{accept_gzip} && $self->{compression});
 740
 741         if (defined(my $host = $reqstate->{request}->header('Host'))) {
 742             $headers->{Host} = $host;
 743         }
 744
 745         my $content;
 746
 747         if  ($method eq 'POST' || $method eq 'PUT') {
 748             $headers->{'Content-Type'} = 'application/x-www-form-urlencoded';
 749             # use URI object to format application/x-www-form-urlencoded content.
 750             my $url = URI->new('http:');
 751             $url->query_form(%$params);
 752             $content = $url->query;
 753             if (defined($content)) {
 754                 $headers->{'Content-Length'} = length($content);
 755             }
 756         }
 757
 758         my $tls = {
 759             # TLS 1.x only, with certificate pinning
 760             method => 'any',
 761             sslv2 => 0,
 762             sslv3 => 0,
 763             verify => 1,
 764             verify_cb => sub {
 765                 my (undef, undef, undef, $depth, undef, undef, $cert) = @_;
 766                 # we don't care about intermediate or root certificates
 767                 return 1 if $depth != 0;
 768                 # check server certificate against cache of pinned FPs
 769                 return $self->check_cert_fingerprint($cert);
 770             },
 771         };
 772
 773         # load and cache cert fingerprint if first time we proxy to this node
 774         $self->initialize_cert_cache($node);
 775
 776         my $w; $w = http_request(
 777             $method => $target,
 778             headers => $headers,
 779             timeout => 30,
 780             recurse => 0,
 781             proxy => undef, # avoid use of $ENV{HTTP_PROXY}
 782             keepalive => $keep_alive,
 783             body => $content,
 784             tls_ctx => AnyEvent::TLS->new(%{$tls}),
 785             sub {
 786                 my ($body, $hdr) = @_;
 787
 788                 undef $w;
 789
 790                 if (!$reqstate->{hdl}) {
 791                     warn "proxy detected vanished client connection\n";
 792                     return;
 793                 }
 794
 795                 eval {
 796                     my $code = delete $hdr->{Status};
 797                     my $msg = delete $hdr->{Reason};
 798                     my $stream = delete $hdr->{pvestreamfile};
 799                     delete $hdr->{URL};
 800                     delete $hdr->{HTTPVersion};
 801                     my $header = HTTP::Headers->new(%$hdr);
 802                     if (my $location = $header->header('Location')) {
 803                         $location =~ s|^http://localhost:85||;
 804                         $header->header(Location => $location);
 805                     }
 806                     if ($stream) {
 807                         if (!$may_stream_file) {
 808                             $self->error($reqstate, 403, 'streaming denied');
 809                             return;
 810                         }
 811                         sysopen(my $fh, "$stream", O_NONBLOCK | O_RDONLY)
 812                             or die "open stream path '$stream' for forwarding failed: $!\n";
 813                         my $resp = HTTP::Response->new($code, $msg, $header, undef);
 814                         $self->response($reqstate, $resp, undef, 1, 0, $fh);
 815                     } else {
 816                         my $resp = HTTP::Response->new($code, $msg, $header, $body);
 817                         # Note: disable compression, because body is already compressed
 818                         $self->response($reqstate, $resp, undef, 1);
 819                     }
 820                 };
 821                 warn $@ if $@;
 822             });
 823     };
 824     warn $@ if $@;
 825 }
 826
 827 # return arrays as \0 separated strings (like CGI.pm)
 828 # assume data is UTF8 encoded
 829 sub decode_urlencoded {
 830     my ($data) = @_;
 831
 832     my $res = {};
 833
 834     return $res if !$data;
 835
 836     foreach my $kv (split(/[\&\;]/, $data)) {
 837         my ($k, $v) = split(/=/, $kv);
 838         $k =~s/\+/ /g;
 839         $k =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr(hex($1))/eg;
 840
 841         if (defined($v)) {
 842             $v =~s/\+/ /g;
 843             $v =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr(hex($1))/eg;
 844
 845             $v = Encode::decode('utf8', $v);
 846
 847             if (defined(my $old = $res->{$k})) {
 848                 $v = "$old\0$v";
 849             }
 850         }
 851
 852         $res->{$k} = $v;
 853     }
 854     return $res;
 855 }
 856
 857 sub extract_params {
 858     my ($r, $method) = @_;
 859
 860     my $params = {};
 861
 862     if ($method eq 'PUT' || $method eq 'POST') {
 863         my $ct;
 864         if (my $ctype = $r->header('Content-Type')) {
 865             $ct = parse_content_type($ctype);
 866         }
 867         if (defined($ct) && $ct eq 'application/json')  {
 868             $params = decode_json($r->content);
 869         } else {
 870             $params = decode_urlencoded($r->content);
 871         }
 872     }
 873
 874     my $query_params = decode_urlencoded($r->url->query());
 875
 876     foreach my $k (keys %{$query_params}) {
 877         $params->{$k} = $query_params->{$k};
 878     }
 879
 880     return $params;
 881 }
 882
 883 sub handle_api2_request {
 884     my ($self, $reqstate, $auth, $method, $path, $upload_state) = @_;
 885
 886     eval {
 887         my $r = $reqstate->{request};
 888
 889         my ($rel_uri, $format) = &$split_abs_uri($path, $self->{base_uri});
 890
 891         my $formatter = PVE::APIServer::Formatter::get_formatter($format, $method, $rel_uri);
 892
 893         if (!defined($formatter)) {
 894             $self->error($reqstate, HTTP_NOT_IMPLEMENTED, "no formatter for uri $rel_uri, $format");
 895             return;
 896         }
 897
 898         #print Dumper($upload_state) if $upload_state;
 899
 900         my $params;
 901
 902         if ($upload_state) {
 903             $params = $upload_state->{params};
 904         } else {
 905             $params = extract_params($r, $method);
 906         }
 907
 908         delete $params->{_dc} if $params; # remove disable cache parameter
 909
 910         my $clientip = $reqstate->{peer_host};
 911
 912         my $res = $self->rest_handler($clientip, $method, $rel_uri, $auth, $params, $format);
 913
 914         # HACK: see Note 1
 915         Net::SSLeay::ERR_clear_error();
 916
 917         AnyEvent->now_update(); # in case somebody called sleep()
 918
 919         my $upgrade = $r->header('upgrade');
 920         $upgrade = lc($upgrade) if $upgrade;
 921
 922         if (my $host = $res->{proxy}) {
 923
 924             if ($self->{trusted_env}) {
 925                 $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy not allowed");
 926                 return;
 927             }
 928
 929             if ($host ne 'localhost' && $r->header('PVEDisableProxy')) {
 930                 $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy loop detected");
 931                 return;
 932             }
 933
 934             $res->{proxy_params}->{tmpfilename} = $reqstate->{tmpfilename} if $upload_state;
 935
 936             $self->proxy_request($reqstate, $clientip, $host, $res->{proxynode}, $method,
 937                                  $r->uri, $auth, $res->{proxy_params});
 938             return;
 939
 940         } elsif ($upgrade && ($method eq 'GET') && ($path =~ m|websocket$|)) {
 941             die "unable to upgrade to protocol '$upgrade'\n" if !$upgrade || ($upgrade ne 'websocket');
 942             my $wsver = $r->header('sec-websocket-version');
 943             die "unsupported websocket-version '$wsver'\n" if !$wsver || ($wsver ne '13');
 944             my $wsproto = $r->header('sec-websocket-protocol') // "";
 945             my $wskey = $r->header('sec-websocket-key');
 946             die "missing websocket-key\n" if !$wskey;
 947             # Note: Digest::SHA::sha1_base64 has wrong padding
 948             my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
 949             if ($res->{status} == HTTP_OK) {
 950                 $self->websocket_proxy($reqstate, $wsaccept, $wsproto, $res->{data});
 951                 return;
 952             }
 953         }
 954
 955         my $delay = 0;
 956         if ($res->{status} == HTTP_UNAUTHORIZED) {
 957             # always delay unauthorized calls by 3 seconds
 958             $delay = 3 - tv_interval($reqstate->{starttime});
 959             $delay = 0 if $delay < 0;
 960         }
 961
 962         my $download = $res->{download};
 963         $download //= $res->{data}->{download}
 964             if defined($res->{data}) && ref($res->{data}) eq 'HASH';
 965         if (defined($download)) {
 966             send_file_start($self, $reqstate, $download);
 967             return;
 968         }
 969
 970         my ($raw, $ct, $nocomp) = $formatter->($res, $res->{data}, $params, $path,
 971                                                $auth, $self->{formatter_config});
 972
 973         my $resp;
 974         if (ref($raw) && (ref($raw) eq 'HTTP::Response')) {
 975             $resp = $raw;
 976         } else {
 977             $resp = HTTP::Response->new($res->{status}, $res->{message});
 978             $resp->header("Content-Type" => $ct);
 979             $resp->content($raw);
 980         }
 981         $self->response($reqstate, $resp, undef, $nocomp, $delay);
 982     };
 983     if (my $err = $@) {
 984         $self->error($reqstate, 501, $err);
 985     }
 986 }
 987
 988 sub handle_spice_proxy_request {
 989     my ($self, $reqstate, $connect_str, $vmid, $node, $spiceport) = @_;
 990
 991     eval {
 992
 993         my ($minport, $maxport) = PVE::Tools::spice_port_range();
 994         if ($spiceport < $minport || $spiceport > $maxport) {
 995             die "SPICE Port $spiceport is not in allowed range ($minport, $maxport)\n";
 996         }
 997
 998         my $clientip = $reqstate->{peer_host};
 999         my $r = $reqstate->{request};
1000
1001         my $remip;
1002
1003         if ($node ne 'localhost' && PVE::INotify::nodename() !~ m/^$node$/i) {
1004             $remip = $self->remote_node_ip($node);
1005             $self->dprint("REMOTE CONNECT $vmid, $remip, $connect_str");
1006         } else {
1007             $self->dprint("CONNECT $vmid, $node, $spiceport");
1008         }
1009
1010         if ($remip && $r->header('PVEDisableProxy')) {
1011             $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy loop detected");
1012             return;
1013         }
1014
1015         $reqstate->{hdl}->timeout(0);
1016         $reqstate->{hdl}->wbuf_max(64*10*1024);
1017
1018         my $remhost = $remip ? $remip : "localhost";
1019         my $remport = $remip ? 3128 : $spiceport;
1020
1021         tcp_connect $remhost, $remport, sub {
1022             my ($fh) = @_
1023                 or die "connect to '$remhost:$remport' failed: $!";
1024
1025             $self->dprint("CONNECTed to '$remhost:$remport'");
1026             $reqstate->{proxyhdl} = AnyEvent::Handle->new(
1027                 fh => $fh,
1028                 rbuf_max => 64*1024,
1029                 wbuf_max => 64*10*1024,
1030                 timeout => 5,
1031                 on_eof => sub {
1032                     my ($hdl) = @_;
1033                     eval {
1034                         $self->log_aborted_request($reqstate);
1035                         $self->client_do_disconnect($reqstate);
1036                     };
1037                     if (my $err = $@) { syslog('err', $err); }
1038                 },
1039                 on_error => sub {
1040                     my ($hdl, $fatal, $message) = @_;
1041                     eval {
1042                         $self->log_aborted_request($reqstate, $message);
1043                         $self->client_do_disconnect($reqstate);
1044                     };
1045                     if (my $err = $@) { syslog('err', "$err"); }
1046                 });
1047
1048
1049             my $proxyhdlreader = sub {
1050                 my ($hdl) = @_;
1051
1052                 my $len = length($hdl->{rbuf});
1053                 my $data = substr($hdl->{rbuf}, 0, $len, '');
1054
1055                 #print "READ1 $len\n";
1056                 $reqstate->{hdl}->push_write($data) if $reqstate->{hdl};
1057             };
1058
1059             my $hdlreader = sub {
1060                 my ($hdl) = @_;
1061
1062                 my $len = length($hdl->{rbuf});
1063                 my $data = substr($hdl->{rbuf}, 0, $len, '');
1064
1065                 #print "READ0 $len\n";
1066                 $reqstate->{proxyhdl}->push_write($data) if $reqstate->{proxyhdl};
1067             };
1068
1069             my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.0';
1070
1071             my $startproxy = sub {
1072                 $reqstate->{proxyhdl}->timeout(0);
1073                 $reqstate->{proxyhdl}->on_read($proxyhdlreader);
1074                 $reqstate->{hdl}->on_read($hdlreader);
1075
1076                 # todo: use stop_read/start_read if write buffer grows to much
1077
1078                 # a response must be followed by an empty line
1079                 my $res = "$proto 200 OK\015\012\015\012";
1080                 $reqstate->{hdl}->push_write($res);
1081
1082                 # log early
1083                 $reqstate->{log}->{code} = 200;
1084                 $self->log_request($reqstate);
1085             };
1086
1087             if ($remip) {
1088                 my $header = "CONNECT ${connect_str} $proto\015\012" .
1089                     "Host: ${connect_str}\015\012" .
1090                     "Proxy-Connection: keep-alive\015\012" .
1091                     "User-Agent: spiceproxy\015\012" .
1092                     "PVEDisableProxy: true\015\012" .
1093                     "PVEClientIP: $clientip\015\012" .
1094                     "\015\012";
1095
1096                 $reqstate->{proxyhdl}->push_write($header);
1097                 $reqstate->{proxyhdl}->push_read(line => sub {
1098                     my ($hdl, $line) = @_;
1099
1100                     if ($line =~ m!^$proto 200 OK$!) {
1101                         # read the empty line after the 200 OK
1102                         $reqstate->{proxyhdl}->unshift_read(line => sub{
1103                             &$startproxy();
1104                         });
1105                     } else {
1106                         $reqstate->{hdl}->push_write($line);
1107                         $self->client_do_disconnect($reqstate);
1108                     }
1109                 });
1110             } else {
1111                 &$startproxy();
1112             }
1113
1114         };
1115     };
1116     if (my $err = $@) {
1117         warn $err;
1118         $self->log_aborted_request($reqstate, $err);
1119         $self->client_do_disconnect($reqstate);
1120     }
1121 }
1122
1123 sub handle_request {
1124     my ($self, $reqstate, $auth, $method, $path) = @_;
1125
1126     my $base_uri = $self->{base_uri};
1127
1128     eval {
1129         my $r = $reqstate->{request};
1130
1131         # disable timeout on handle (we already have all data we need)
1132         # we re-enable timeout in response()
1133         $reqstate->{hdl}->timeout(0);
1134
1135         if ($path =~ m/^\Q$base_uri\E/) {
1136             $self->handle_api2_request($reqstate, $auth, $method, $path);
1137             return;
1138         }
1139
1140         if ($self->{pages} && ($method eq 'GET') && (my $handler = $self->{pages}->{$path})) {
1141             if (ref($handler) eq 'CODE') {
1142                 my $params = decode_urlencoded($r->url->query());
1143                 my ($resp, $userid) = &$handler($self, $reqstate->{request}, $params);
1144                 # HACK: see Note 1
1145                 Net::SSLeay::ERR_clear_error();
1146                 $self->response($reqstate, $resp);
1147             } elsif (ref($handler) eq 'HASH') {
1148                 if (my $filename = $handler->{file}) {
1149                     my $fh = IO::File->new($filename) ||
1150                         die "unable to open file '$filename' - $!\n";
1151                     send_file_start($self, $reqstate, $filename);
1152                 } else {
1153                     die "internal error - no handler";
1154                 }
1155             } else {
1156                 die "internal error - no handler";
1157             }
1158             return;
1159         }
1160
1161         if ($self->{dirs} && ($method eq 'GET')) {
1162             # we only allow simple names
1163             if ($path =~ m!^(/\S+/)([a-zA-Z0-9\-\_\.]+)$!) {
1164                 my ($subdir, $file) = ($1, $2);
1165                 if (my $dir = $self->{dirs}->{$subdir}) {
1166                     my $filename = "$dir$file";
1167                     my $fh = IO::File->new($filename) ||
1168                         die "unable to open file '$filename' - $!\n";
1169                     send_file_start($self, $reqstate, $filename);
1170                     return;
1171                 }
1172             }
1173         }
1174
1175         die "no such file '$path'\n";
1176     };
1177     if (my $err = $@) {
1178         $self->error($reqstate, 501, $err);
1179     }
1180 }
1181
1182 my sub assert_form_disposition {
1183     die "wrong Content-Disposition '$_[0]' in multipart, expected 'form-data'\n" if $_[0] ne 'form-data';
1184 }
1185
1186 sub file_upload_multipart {
1187     my ($self, $reqstate, $auth, $method, $path, $rstate) = @_;
1188
1189     eval {
1190         my $boundary = $rstate->{boundary};
1191         my $hdl = $reqstate->{hdl};
1192         my $startlen = length($hdl->{rbuf});
1193
1194         my $newline_re = qr/\015?\012/;
1195         my $delim_re = qr/--\Q$boundary\E${newline_re}/;
1196         my $close_delim_re = qr/--\Q$boundary\E--${newline_re}/;
1197
1198         # Phase 0 - preserve boundary, but remove everything before
1199         if ($rstate->{phase} == 0 && $hdl->{rbuf} =~ s/^.*?($delim_re)/$1/s) {
1200             $rstate->{read} += $startlen - length($hdl->{rbuf});
1201             $rstate->{phase} = 1;
1202         }
1203
1204         my $extract_form_disposition = sub {
1205             my ($name) = @_;
1206             if ($hdl->{rbuf} =~ s/^${delim_re}Content-Disposition: (.*?); name="$name"(.*?)($delim_re)/$3/s) {
1207                 assert_form_disposition($1);
1208                 $rstate->{params}->{$name} = trim($2);
1209             }
1210         };
1211
1212         if ($rstate->{phase} == 1) { # Phase 1 - parse payload without file data
1213             $extract_form_disposition->('content');
1214             $extract_form_disposition->('checksum-algorithm');
1215             $extract_form_disposition->('checksum');
1216
1217             if ($hdl->{rbuf} =~
1218                 s/^${delim_re}
1219                 Content-Disposition:\ (.*?);\ name="(.*?)";\ filename="([^"]+)"${newline_re}
1220                 Content-Type:\ \S*\s+
1221                 //sxx
1222             ) {
1223                 assert_form_disposition($1);
1224                 die "wrong field name '$2' for file upload, expected 'filename'" if $2 ne "filename";
1225                 $rstate->{phase} = 2;
1226                 $rstate->{params}->{filename} = trim($3);
1227             }
1228         }
1229
1230         if ($rstate->{phase} == 2) { # Phase 2 - dump content into file
1231             my ($data, $write_length);
1232             if ($hdl->{rbuf} =~ s/^(.*?)${newline_re}?+${close_delim_re}.*$//s) {
1233                 $data = $1;
1234                 $write_length = length($data);
1235                 $rstate->{phase} =  100;
1236             } else {
1237                 $write_length = length($hdl->{rbuf}) - $rstate->{boundlen};
1238                 $data = substr($hdl->{rbuf}, 0, $write_length, '') if $write_length > 0;
1239             }
1240
1241             if ($write_length > 0) {
1242                 syswrite($rstate->{outfh}, $data) == $write_length or die "write to temporary file failed - $!\n";
1243                 $rstate->{bytes} += $write_length;
1244                 $rstate->{ctx}->add($data);
1245             }
1246         }
1247
1248         if ($rstate->{phase} == 100) { # Phase 100 - transfer finished
1249             $rstate->{md5sum} = $rstate->{ctx}->hexdigest;
1250             my $elapsed = tv_interval($rstate->{starttime});
1251             syslog('info', "multipart upload complete (size: %dB time: %.3fs rate: %.2fMiB/s md5sum: %s)",
1252                 $rstate->{bytes}, $elapsed, $rstate->{bytes} / ($elapsed * 1024 * 1024), $rstate->{md5sum}
1253             );
1254             $self->handle_api2_request($reqstate, $auth, $method, $path, $rstate);
1255         }
1256
1257         $rstate->{read} += $startlen - length($hdl->{rbuf});
1258
1259         if ($rstate->{read} + length($hdl->{rbuf}) >= $rstate->{size} && $rstate->{phase} != 100) {
1260             die "upload failed";
1261         }
1262     };
1263     if (my $err = $@) {
1264         syslog('err', $err);
1265         $self->error($reqstate, 501, $err);
1266     }
1267 }
1268
1269 sub parse_content_type {
1270     my ($ctype) = @_;
1271
1272     my ($ct, @params) = split(/\s*[;,]\s*/o, $ctype);
1273
1274     foreach my $v (@params) {
1275         if ($v =~ m/^\s*boundary\s*=\s*(\S+?)\s*$/o) {
1276             return wantarray ? ($ct, $1) : $ct;
1277         }
1278     }
1279
1280     return  wantarray ? ($ct) : $ct;
1281 }
1282
1283 sub parse_content_disposition {
1284     my ($line) = @_;
1285
1286     my ($disp, @params) = split(/\s*[;,]\s*/o, $line);
1287     my $name;
1288     my $filename;
1289
1290     foreach my $v (@params) {
1291         if ($v =~ m/^\s*name\s*=\s*(\S+?)\s*$/o) {
1292             $name = $1;
1293             $name =~ s/^"(.*)"$/$1/;
1294         } elsif ($v =~ m/^\s*filename\s*=\s*(.+?)\s*$/o) {
1295             $filename = $1;
1296             $filename =~ s/^"(.*)"$/$1/;
1297         }
1298     }
1299
1300     return  wantarray ? ($disp, $name, $filename) : $disp;
1301 }
1302
1303 my $tmpfile_seq_no = 0;
1304
1305 sub get_upload_filename {
1306     # choose unpredictable tmpfile name
1307
1308     $tmpfile_seq_no++;
1309     return "/var/tmp/pveupload-" . Digest::MD5::md5_hex($tmpfile_seq_no . time() . $$);
1310 }
1311
1312 sub unshift_read_header {
1313     my ($self, $reqstate, $state) = @_;
1314
1315     $state = { size => 0, count => 0 } if !$state;
1316
1317     $reqstate->{hdl}->unshift_read(line => sub {
1318         my ($hdl, $line) = @_;
1319
1320         eval {
1321             # print "$$: got header: $line\n" if $self->{debug};
1322
1323             die "too many http header lines (> $limit_max_headers)\n" if ++$state->{count} >= $limit_max_headers;
1324             die "http header too large\n" if ($state->{size} += length($line)) >= $limit_max_header_size;
1325
1326             my $r = $reqstate->{request};
1327             if ($line eq '') {
1328
1329                 my $path = uri_unescape($r->uri->path());
1330                 my $method = $r->method();
1331
1332                 $r->push_header($state->{key}, $state->{val})
1333                     if $state->{key};
1334
1335                 if (!$known_methods->{$method}) {
1336                     my $resp = HTTP::Response->new(HTTP_NOT_IMPLEMENTED, "method '$method' not available");
1337                     $self->response($reqstate, $resp);
1338                     return;
1339                 }
1340
1341                 my $conn = $r->header('Connection');
1342                 my $accept_enc = $r->header('Accept-Encoding');
1343                 $reqstate->{accept_gzip} = ($accept_enc && $accept_enc =~ m/gzip/) ? 1 : 0;
1344
1345                 if ($conn) {
1346                     $reqstate->{keep_alive} = 0 if $conn =~ m/close/oi;
1347                 } else {
1348                     if ($reqstate->{proto}->{ver} < 1001) {
1349                         $reqstate->{keep_alive} = 0;
1350                     }
1351                 }
1352
1353                 my $te  = $r->header('Transfer-Encoding');
1354                 if ($te && lc($te) eq 'chunked') {
1355                     # Handle chunked transfer encoding
1356                     $self->error($reqstate, 501, "chunked transfer encoding not supported");
1357                     return;
1358                 } elsif ($te) {
1359                     $self->error($reqstate, 501, "Unknown transfer encoding '$te'");
1360                     return;
1361                 }
1362
1363                 my $pveclientip = $r->header('PVEClientIP');
1364                 my $base_uri = $self->{base_uri};
1365
1366                 # fixme: how can we make PVEClientIP header trusted?
1367                 if ($self->{trusted_env} && $pveclientip) {
1368                     $reqstate->{peer_host} = $pveclientip;
1369                 } else {
1370                     $r->header('PVEClientIP', $reqstate->{peer_host});
1371                 }
1372
1373                 my $len = $r->header('Content-Length');
1374
1375                 my $host_header = $r->header('Host');
1376                 if (my $rpcenv = $self->{rpcenv}) {
1377                     $rpcenv->set_request_host($host_header);
1378                 }
1379
1380                 # header processing complete - authenticate now
1381
1382                 my $auth = {};
1383                 if ($self->{spiceproxy}) {
1384                     my $connect_str = $host_header;
1385                     my ($vmid, $node, $port) = $self->verify_spice_connect_url($connect_str);
1386                     if (!(defined($vmid) && $node && $port)) {
1387                         $self->error($reqstate, HTTP_UNAUTHORIZED, "invalid ticket");
1388                         return;
1389                     }
1390                     $self->handle_spice_proxy_request($reqstate, $connect_str, $vmid, $node, $port);
1391                     return;
1392                 } elsif ($path =~ m/^\Q$base_uri\E/) {
1393                     my $token = $r->header('CSRFPreventionToken');
1394                     my $cookie = $r->header('Cookie');
1395                     my $auth_header = $r->header('Authorization');
1396
1397                     # prefer actual cookie
1398                     my $ticket = PVE::APIServer::Formatter::extract_auth_value($cookie, $self->{cookie_name});
1399
1400                     # fallback to cookie in 'Authorization' header
1401                     $ticket = PVE::APIServer::Formatter::extract_auth_value($auth_header, $self->{cookie_name})
1402                         if !$ticket;
1403
1404                     # finally, fallback to API token if no ticket has been provided so far
1405                     my $api_token;
1406                     $api_token = PVE::APIServer::Formatter::extract_auth_value($auth_header, $self->{apitoken_name})
1407                         if !$ticket;
1408
1409                     my ($rel_uri, $format) = &$split_abs_uri($path, $self->{base_uri});
1410                     if (!$format) {
1411                         $self->error($reqstate, HTTP_NOT_IMPLEMENTED, "no such uri");
1412                         return;
1413                     }
1414
1415                     eval {
1416                         $auth = $self->auth_handler($method, $rel_uri, $ticket, $token, $api_token,
1417                                                     $reqstate->{peer_host});
1418                     };
1419                     if (my $err = $@) {
1420                         # HACK: see Note 1
1421                         Net::SSLeay::ERR_clear_error();
1422                         # always delay unauthorized calls by 3 seconds
1423                         my $delay = 3;
1424
1425                         if (ref($err) eq "PVE::Exception") {
1426
1427                             $err->{code} ||= HTTP_INTERNAL_SERVER_ERROR,
1428                             my $resp = HTTP::Response->new($err->{code}, $err->{msg});
1429                             $self->response($reqstate, $resp, undef, 0, $delay);
1430
1431                         } elsif (my $formatter = PVE::APIServer::Formatter::get_login_formatter($format)) {
1432                             my ($raw, $ct, $nocomp) =
1433                                 $formatter->($path, $auth, $self->{formatter_config});
1434                             my $resp;
1435                             if (ref($raw) && (ref($raw) eq 'HTTP::Response')) {
1436                                 $resp = $raw;
1437                             } else {
1438                                 $resp = HTTP::Response->new(HTTP_UNAUTHORIZED, "Login Required");
1439                                 $resp->header("Content-Type" => $ct);
1440                                 $resp->content($raw);
1441                             }
1442                             $self->response($reqstate, $resp, undef, $nocomp, $delay);
1443                         } else {
1444                             my $resp = HTTP::Response->new(HTTP_UNAUTHORIZED, $err);
1445                             $self->response($reqstate, $resp, undef, 0, $delay);
1446                         }
1447                         return;
1448                     }
1449                 }
1450
1451                 $reqstate->{log}->{userid} = $auth->{userid};
1452
1453                 if ($len) {
1454
1455                     if (!($method eq 'PUT' || $method eq 'POST')) {
1456                         $self->error($reqstate, 501, "Unexpected content for method '$method'");
1457                         return;
1458                     }
1459
1460                     my $ctype = $r->header('Content-Type');
1461                     my ($ct, $boundary) = $ctype ? parse_content_type($ctype) : ();
1462
1463                     if ($auth->{isUpload} && !$self->{trusted_env}) {
1464                         die "upload 'Content-Type '$ctype' not implemented\n"
1465                             if !($boundary && $ct && ($ct eq 'multipart/form-data'));
1466
1467                         die "upload without content length header not supported" if !$len;
1468
1469                         die "upload without content length header not supported" if !$len;
1470
1471                         $self->dprint("start upload $path $ct $boundary");
1472
1473                         my $tmpfilename = get_upload_filename();
1474                         my $outfh = IO::File->new($tmpfilename, O_RDWR|O_CREAT|O_EXCL, 0600) ||
1475                             die "unable to create temporary upload file '$tmpfilename'";
1476
1477                         $reqstate->{keep_alive} = 0;
1478
1479                         my $boundlen = length($boundary) + 8; # \015?\012--$boundary--\015?\012
1480
1481                         my $state = {
1482                             size => $len,
1483                             boundary => $boundary,
1484                             ctx => Digest::MD5->new,
1485                             boundlen =>  $boundlen,
1486                             maxheader => 2048 + $boundlen, # should be large enough
1487                             params => decode_urlencoded($r->url->query()),
1488                             phase => 0,
1489                             read => 0,
1490                             post_size => 0,
1491                             starttime => [gettimeofday],
1492                             outfh => $outfh,
1493                         };
1494                         $reqstate->{tmpfilename} = $tmpfilename;
1495                         $reqstate->{hdl}->on_read(sub {
1496                             $self->file_upload_multipart($reqstate, $auth, $method, $path, $state);
1497                         });
1498                         return;
1499                     }
1500
1501                     if ($len > $limit_max_post) {
1502                         $self->error($reqstate, 501, "for data too large");
1503                         return;
1504                     }
1505
1506                     if (!$ct || $ct eq 'application/x-www-form-urlencoded' || $ct eq 'application/json') {
1507                         $reqstate->{hdl}->unshift_read(chunk => $len, sub {
1508                             my ($hdl, $data) = @_;
1509                             $r->content($data);
1510                             $self->handle_request($reqstate, $auth, $method, $path);
1511                         });
1512                     } else {
1513                         $self->error($reqstate, 506, "upload 'Content-Type '$ctype' not implemented");
1514                     }
1515                 } else {
1516                     $self->handle_request($reqstate, $auth, $method, $path);
1517                 }
1518             } elsif ($line =~ /^([^:\s]+)\s*:\s*(.*)/) {
1519                 $r->push_header($state->{key}, $state->{val}) if $state->{key};
1520                 ($state->{key}, $state->{val}) = ($1, $2);
1521                 $self->unshift_read_header($reqstate, $state);
1522             } elsif ($line =~ /^\s+(.*)/) {
1523                 $state->{val} .= " $1";
1524                 $self->unshift_read_header($reqstate, $state);
1525             } else {
1526                 $self->error($reqstate, 506, "unable to parse request header");
1527             }
1528         };
1529         warn $@ if $@;
1530     });
1531 };
1532
1533 sub push_request_header {
1534     my ($self, $reqstate) = @_;
1535
1536     eval {
1537         $reqstate->{hdl}->push_read(line => sub {
1538             my ($hdl, $line) = @_;
1539
1540             eval {
1541                 # print "got request header: $line\n" if $self->{debug};
1542
1543                 $reqstate->{keep_alive}--;
1544
1545                 if ($line =~ /(\S+)\040(\S+)\040HTTP\/(\d+)\.(\d+)/o) {
1546                     my ($method, $url, $maj, $min) = ($1, $2, $3, $4);
1547
1548                     if ($maj != 1) {
1549                         $self->error($reqstate, 506, "http protocol version $maj.$min not supported");
1550                         return;
1551                     }
1552                     if ($url =~ m|^[^/]*@|) {
1553                         # if an '@' comes before the first slash proxy forwarding might consider
1554                         # the frist part of the url to be part of an authority...
1555                         $self->error($reqstate, 400, "invalid url");
1556                         return;
1557                     }
1558
1559                     $self->{request_count}++; # only count valid request headers
1560                     if ($self->{request_count} >= $self->{max_requests}) {
1561                         $self->{end_loop} = 1;
1562                     }
1563                     $reqstate->{log} = { requestline => $line };
1564                     $reqstate->{proto}->{str} = "HTTP/$maj.$min";
1565                     $reqstate->{proto}->{maj} = $maj;
1566                     $reqstate->{proto}->{min} = $min;
1567                     $reqstate->{proto}->{ver} = $maj*1000+$min;
1568                     $reqstate->{request} = HTTP::Request->new($method, $url);
1569                     $reqstate->{starttime} = [gettimeofday],
1570
1571                     $self->unshift_read_header($reqstate);
1572                 } elsif ($line eq '') {
1573                     # ignore empty lines before requests (browser bugs?)
1574                     $self->push_request_header($reqstate);
1575                 } else {
1576                     $self->error($reqstate, 400, 'bad request');
1577                 }
1578             };
1579             warn $@ if $@;
1580         });
1581     };
1582     warn $@ if $@;
1583 }
1584
1585 sub accept {
1586     my ($self) = @_;
1587
1588     my $clientfh;
1589
1590     return if $self->{end_loop};
1591
1592     # we need to m make sure that only one process calls accept
1593     while (!flock($self->{lockfh}, Fcntl::LOCK_EX())) {
1594         next if $! == EINTR;
1595         die "could not get lock on file '$self->{lockfile}' -  $!\n";
1596     }
1597
1598     my $again = 0;
1599     my $errmsg;
1600     eval {
1601         while (!$self->{end_loop} &&
1602                !defined($clientfh = $self->{socket}->accept()) &&
1603                ($! == EINTR)) {};
1604
1605         if ($self->{end_loop}) {
1606             $again = 0;
1607         } else {
1608             $again = ($! == EAGAIN || $! == WSAEWOULDBLOCK);
1609             if (!defined($clientfh)) {
1610                 $errmsg = "failed to accept connection: $!\n";
1611             }
1612         }
1613     };
1614     warn $@ if $@;
1615
1616     flock($self->{lockfh}, Fcntl::LOCK_UN());
1617
1618     if (!defined($clientfh)) {
1619         return if $again;
1620         die $errmsg if $errmsg;
1621     }
1622
1623     fh_nonblocking $clientfh, 1;
1624
1625     return $clientfh;
1626 }
1627
1628 sub wait_end_loop {
1629     my ($self) = @_;
1630
1631     $self->{end_loop} = 1;
1632
1633     undef $self->{socket_watch};
1634
1635     $0 = "$0 (shutdown)" if $0 !~ m/\(shutdown\)$/;
1636
1637     if ($self->{conn_count} <= 0) {
1638         $self->{end_cond}->send(1);
1639         return;
1640     }
1641
1642     # fork and exit, so that parent starts a new worker
1643     if (fork()) {
1644         exit(0);
1645     }
1646
1647     # else we need to wait until all open connections gets closed
1648     my $w; $w = AnyEvent->timer (after => 1, interval => 1, cb => sub {
1649         eval {
1650             # todo: test for active connections instead (we can abort idle connections)
1651             if ($self->{conn_count} <= 0) {
1652                 undef $w;
1653                 $self->{end_cond}->send(1);
1654             }
1655         };
1656         warn $@ if $@;
1657     });
1658 }
1659
1660
1661 sub check_host_access {
1662     my ($self, $clientip) = @_;
1663
1664     $clientip = PVE::APIServer::Utils::normalize_v4_in_v6($clientip);
1665     my $cip = Net::IP->new($clientip);
1666
1667     if (!$cip) {
1668         $self->dprint("client IP not parsable: $@");
1669         return 0;
1670     }
1671
1672     my $match_allow = 0;
1673     my $match_deny = 0;
1674
1675     if ($self->{allow_from}) {
1676         foreach my $t (@{$self->{allow_from}}) {
1677             if ($t->overlaps($cip)) {
1678                 $match_allow = 1;
1679                 $self->dprint("client IP allowed: ". $t->prefix());
1680                 last;
1681             }
1682         }
1683     }
1684
1685     if ($self->{deny_from}) {
1686         foreach my $t (@{$self->{deny_from}}) {
1687             if ($t->overlaps($cip)) {
1688                 $self->dprint("client IP denied: ". $t->prefix());
1689                 $match_deny = 1;
1690                 last;
1691             }
1692         }
1693     }
1694
1695     if ($match_allow == $match_deny) {
1696         # match both allow and deny, or no match
1697         return $self->{policy} && $self->{policy} eq 'allow' ? 1 : 0;
1698     }
1699
1700     return $match_allow;
1701 }
1702
1703 sub accept_connections {
1704     my ($self) = @_;
1705
1706     my ($clientfh, $handle_creation);
1707     eval {
1708
1709         while ($clientfh = $self->accept()) {
1710
1711             my $reqstate = { keep_alive => $self->{keep_alive} };
1712
1713             # stop keep-alive when there are many open connections
1714             if ($self->{conn_count} + 1 >= $self->{max_conn_soft_limit}) {
1715                 $reqstate->{keep_alive} = 0;
1716             }
1717
1718             if (my $sin = getpeername($clientfh)) {
1719                 my ($pfamily, $pport, $phost) = PVE::Tools::unpack_sockaddr_in46($sin);
1720                 ($reqstate->{peer_port}, $reqstate->{peer_host}) = ($pport,  Socket::inet_ntop($pfamily, $phost));
1721             } else {
1722                 $self->dprint("getpeername failed: $!");
1723                 close($clientfh);
1724                 next;
1725             }
1726
1727             if (!$self->{trusted_env} && !$self->check_host_access($reqstate->{peer_host})) {
1728                 $self->dprint("ABORT request from $reqstate->{peer_host} - access denied");
1729                 $reqstate->{log}->{code} = 403;
1730                 $self->log_request($reqstate);
1731                 close($clientfh);
1732                 next;
1733             }
1734
1735             # Increment conn_count before creating new handle, since creation
1736             # triggers callbacks, which can potentialy decrement (e.g.
1737             # on_error) conn_count before AnyEvent::Handle->new() returns.
1738             $handle_creation = 1;
1739             $self->{conn_count}++;
1740             $reqstate->{hdl} = AnyEvent::Handle->new(
1741                 fh => $clientfh,
1742                 rbuf_max => 64*1024,
1743                 timeout => $self->{timeout},
1744                 linger => 0, # avoid problems with ssh - really needed ?
1745                 on_eof   => sub {
1746                     my ($hdl) = @_;
1747                     eval {
1748                         $self->log_aborted_request($reqstate);
1749                         $self->client_do_disconnect($reqstate);
1750                     };
1751                     if (my $err = $@) { syslog('err', $err); }
1752                 },
1753                 on_error => sub {
1754                     my ($hdl, $fatal, $message) = @_;
1755                     eval {
1756                         $self->log_aborted_request($reqstate, $message);
1757                         $self->client_do_disconnect($reqstate);
1758                     };
1759                     if (my $err = $@) { syslog('err', "$err"); }
1760                 },
1761                 ($self->{tls_ctx} ? (tls => "accept", tls_ctx => $self->{tls_ctx}) : ()));
1762             $handle_creation = 0;
1763
1764             $self->dprint("ACCEPT FH" .  $clientfh->fileno() . " CONN$self->{conn_count}");
1765
1766             $self->push_request_header($reqstate);
1767         }
1768     };
1769
1770     if (my $err = $@) {
1771         syslog('err', $err);
1772         $self->dprint("connection accept error: $err");
1773         close($clientfh);
1774         if ($handle_creation) {
1775             if ($self->{conn_count} <= 0) {
1776                 warn "connection count <= 0 not decrementing!\n";
1777             } else {
1778                 $self->{conn_count}--;
1779             }
1780         }
1781         $self->{end_loop} = 1;
1782     }
1783
1784     $self->wait_end_loop() if $self->{end_loop};
1785 }
1786
1787 # Note: We can't open log file in non-blocking mode and use AnyEvent::Handle,
1788 # because we write from multiple processes, and that would arbitrarily mix output
1789 # of all processes.
1790 sub open_access_log {
1791     my ($self, $filename) = @_;
1792
1793     my $old_mask = umask(0137);;
1794     my $logfh = IO::File->new($filename, ">>") ||
1795         die "unable to open log file '$filename' - $!\n";
1796     umask($old_mask);
1797
1798     $logfh->autoflush(1);
1799
1800     $self->{logfh} = $logfh;
1801 }
1802
1803 sub write_log {
1804     my ($self, $data) = @_;
1805
1806     return if !defined($self->{logfh}) || !$data;
1807
1808     my $res = $self->{logfh}->print($data);
1809
1810     if (!$res) {
1811         delete $self->{logfh};
1812         syslog('err', "error writing access log");
1813         $self->{end_loop} = 1; # terminate asap
1814     }
1815 }
1816
1817 sub atfork_handler {
1818     my ($self) = @_;
1819
1820     eval {
1821         # something else do to ?
1822         close($self->{socket});
1823     };
1824     warn $@ if $@;
1825 }
1826
1827 sub run {
1828     my ($self) = @_;
1829
1830     $self->{end_cond}->recv;
1831 }
1832
1833 sub new {
1834     my ($this, %args) = @_;
1835
1836     my $class = ref($this) || $this;
1837
1838     foreach my $req (qw(socket lockfh lockfile)) {
1839         die "misssing required argument '$req'" if !defined($args{$req});
1840     }
1841
1842     my $self = bless { %args }, $class;
1843
1844     $self->{cookie_name} //= 'PVEAuthCookie';
1845     $self->{apitoken_name} //= 'PVEAPIToken';
1846     $self->{base_uri} //= "/api2";
1847     $self->{dirs} //= {};
1848     $self->{title} //= 'API Inspector';
1849     $self->{compression} //= 1;
1850
1851     # formatter_config: we pass some configuration values to the Formatter
1852     $self->{formatter_config} = {};
1853     foreach my $p (qw(apitoken_name cookie_name base_uri title)) {
1854         $self->{formatter_config}->{$p} = $self->{$p};
1855     }
1856     $self->{formatter_config}->{csrfgen_func} =
1857         $self->can('generate_csrf_prevention_token');
1858
1859     # add default dirs which includes jquery and bootstrap
1860     my $jsbase = '/usr/share/javascript';
1861     add_dirs($self->{dirs}, '/js/' => "$jsbase/");
1862     # libjs-bootstrap uses symlinks for this, which we do not want to allow..
1863     my $glyphicons = '/usr/share/fonts/truetype/glyphicons/';
1864     add_dirs($self->{dirs}, '/js/bootstrap/fonts/' => "$glyphicons");
1865
1866     # init inotify
1867     PVE::INotify::inotify_init();
1868
1869     fh_nonblocking($self->{socket}, 1);
1870
1871     $self->{end_loop} = 0;
1872     $self->{conn_count} = 0;
1873     $self->{request_count} = 0;
1874     $self->{timeout} = 5 if !$self->{timeout};
1875     $self->{keep_alive} = 0 if !defined($self->{keep_alive});
1876     $self->{max_conn} = 800 if !$self->{max_conn};
1877     $self->{max_requests} = 8000 if !$self->{max_requests};
1878
1879     $self->{policy} = 'allow' if !$self->{policy};
1880
1881     $self->{end_cond} = AnyEvent->condvar;
1882
1883     if ($self->{ssl}) {
1884         my $ssl_defaults = {
1885             # Note: older versions are considered insecure, for example
1886             # search for "Poodle"-Attack
1887             method => 'any',
1888             sslv2 => 0,
1889             sslv3 => 0,
1890             cipher_list => 'ECDHE-ECDSA-AES256-GCM-SHA384:ECDHE-RSA-AES256-GCM-SHA384:ECDHE-ECDSA-CHACHA20-POLY1305:ECDHE-RSA-CHACHA20-POLY1305:ECDHE-ECDSA-AES128-GCM-SHA256:ECDHE-RSA-AES128-GCM-SHA256:ECDHE-ECDSA-AES256-SHA384:ECDHE-RSA-AES256-SHA384:ECDHE-ECDSA-AES128-SHA256:ECDHE-RSA-AES128-SHA256',
1891             honor_cipher_order => 1,
1892         };
1893
1894         # workaround until anyevent supports TLS 1.3 ciphersuites directly
1895         my $ciphersuites = delete $self->{ssl}->{ciphersuites};
1896
1897         foreach my $k (keys %$ssl_defaults) {
1898             $self->{ssl}->{$k} //= $ssl_defaults->{$k};
1899         }
1900
1901         if (!defined($self->{ssl}->{dh_file})) {
1902             $self->{ssl}->{dh} = 'skip2048';
1903         }
1904
1905         my $tls_ctx_flags = 0;
1906         $tls_ctx_flags |= &Net::SSLeay::OP_NO_COMPRESSION;
1907         $tls_ctx_flags |= &Net::SSLeay::OP_SINGLE_ECDH_USE;
1908         $tls_ctx_flags |= &Net::SSLeay::OP_SINGLE_DH_USE;
1909         $tls_ctx_flags |= &Net::SSLeay::OP_NO_RENEGOTIATION;
1910         if (delete $self->{ssl}->{honor_cipher_order}) {
1911             $tls_ctx_flags |= &Net::SSLeay::OP_CIPHER_SERVER_PREFERENCE;
1912         }
1913         # workaround until anyevent supports disabling TLS 1.3 directly
1914         if (exists($self->{ssl}->{tlsv1_3}) && !$self->{ssl}->{tlsv1_3}) {
1915             $tls_ctx_flags |= &Net::SSLeay::OP_NO_TLSv1_3;
1916         }
1917
1918
1919         $self->{tls_ctx} = AnyEvent::TLS->new(%{$self->{ssl}});
1920         Net::SSLeay::CTX_set_options($self->{tls_ctx}->{ctx}, $tls_ctx_flags);
1921         if (defined($ciphersuites)) {
1922             warn "Failed to set TLS 1.3 ciphersuites '$ciphersuites'\n"
1923                 if !Net::SSLeay::CTX_set_ciphersuites($self->{tls_ctx}->{ctx}, $ciphersuites);
1924         }
1925     }
1926
1927     if ($self->{spiceproxy}) {
1928         $known_methods = { CONNECT => 1 };
1929     }
1930
1931     $self->open_access_log($self->{logfile}) if $self->{logfile};
1932
1933     $self->{max_conn_soft_limit} = $self->{max_conn} > 100 ? $self->{max_conn} - 20 : $self->{max_conn};
1934
1935     $self->{socket_watch} = AnyEvent->io(fh => $self->{socket}, poll => 'r', cb => sub {
1936         eval {
1937             if ($self->{conn_count} >= $self->{max_conn}) {
1938                 my $w; $w = AnyEvent->timer (after => 1, interval => 1, cb => sub {
1939                     if ($self->{conn_count} < $self->{max_conn}) {
1940                         undef $w;
1941                         $self->accept_connections();
1942                     }
1943                 });
1944             } else {
1945                 $self->accept_connections();
1946             }
1947         };
1948         warn $@ if $@;
1949     });
1950
1951     $self->{term_watch} = AnyEvent->signal(signal => "TERM", cb => sub {
1952         undef $self->{term_watch};
1953         $self->wait_end_loop();
1954     });
1955
1956     $self->{quit_watch} = AnyEvent->signal(signal => "QUIT", cb => sub {
1957         undef $self->{quit_watch};
1958         $self->wait_end_loop();
1959     });
1960
1961     $self->{inotify_poll} = AnyEvent->timer(after => 5, interval => 5, cb => sub {
1962         PVE::INotify::poll(); # read inotify events
1963     });
1964
1965     return $self;
1966 }
1967
1968 # static helper to add directory including all subdirs
1969 # This can be used to setup $self->{dirs}
1970 sub add_dirs {
1971     my ($result_hash, $alias, $subdir) = @_;
1972
1973     $result_hash->{$alias} = $subdir;
1974
1975     my $wanted = sub {
1976         my $dir = $File::Find::dir;
1977         if ($dir =~m!^$subdir(.*)$!) {
1978             my $name = "$alias$1/";
1979             $result_hash->{$name} = "$dir/";
1980         }
1981     };
1982
1983     find({wanted => $wanted, follow => 0, no_chdir => 1}, $subdir);
1984 }
1985
1986 # abstract functions - subclass should overwrite/implement them
1987
1988 sub verify_spice_connect_url {
1989     my ($self, $connect_str) = @_;
1990
1991     die "implement me";
1992
1993     #return ($vmid, $node, $port);
1994 }
1995
1996 # formatters can call this when the generate a new page
1997 sub generate_csrf_prevention_token {
1998     my ($username) = @_;
1999
2000     return undef; # do nothing by default
2001 }
2002
2003 sub auth_handler {
2004     my ($self, $method, $rel_uri, $ticket, $token, $api_token, $peer_host) = @_;
2005
2006     die "implement me";
2007
2008     # return {
2009     #    ticket => $ticket,
2010     #    token => $token,
2011     #    userid => $username,
2012     #    age => $age,
2013     #    isUpload => $isUpload,
2014     #    api_token => $api_token,
2015     #};
2016 }
2017
2018 sub rest_handler {
2019     my ($self, $clientip, $method, $rel_uri, $auth, $params, $format) = @_;
2020
2021     # please do not raise exceptions here (always return a result).
2022
2023     return {
2024         status => HTTP_NOT_IMPLEMENTED,
2025         message => "Method '$method $rel_uri' not implemented",
2026     };
2027
2028     # this should return the following properties, which
2029     # are then passed to the Formatter
2030
2031     # status: HTTP status code
2032     # message: Error message
2033     # errors: more detailed error hash (per parameter)
2034     # info: reference to JSON schema definition - useful to format output
2035     # data: result data
2036
2037     # total: additional info passed to output
2038     # changes:  additional info passed to output
2039
2040     # if you want to proxy the request to another node return this
2041     # { proxy => $remip, proxynode => $node, proxy_params => $params };
2042
2043     # to pass the request to the local priviledged daemon use:
2044     # { proxy => 'localhost' , proxy_params => $params };
2045
2046     # to download aspecific file use:
2047     # { download => "/path/to/file" };
2048 }
2049
2050 sub check_cert_fingerprint {
2051     my ($self, $cert) = @_;
2052
2053      die "implement me";
2054  }
2055
2056 sub initialize_cert_cache {
2057     my ($self, $node) = @_;
2058
2059     die "implement me";
2060 }
2061
2062 sub remote_node_ip {
2063     my ($self, $node) = @_;
2064
2065     die "implement me";
2066
2067     # return $remip;
2068 }
2069
2070
2071 1;