src/PVE/APIServer/AnyEvent.pm

   1 package PVE::APIServer::AnyEvent;
   2
   3 # Note 1: interactions with Crypt::OpenSSL::RSA
   4 #
   5 # Some handlers (auth_handler) use Crypt::OpenSSL::RSA, which seems to
   6 # set the openssl error variable. We need to clear that here, else
   7 # AnyEvent::TLS aborts the connection.
   8 # Net::SSLeay::ERR_clear_error();
   9
  10 use strict;
  11 use warnings;
  12
  13 use AnyEvent::HTTP;
  14 use AnyEvent::Handle;
  15 use AnyEvent::IO;
  16 use AnyEvent::Socket;
  17 # use AnyEvent::Strict; # only use this for debugging
  18 use AnyEvent::TLS;
  19 use AnyEvent::Util qw(guard fh_nonblocking WSAEWOULDBLOCK WSAEINPROGRESS);
  20
  21 use Compress::Zlib;
  22 use Digest::MD5;
  23 use Digest::SHA;
  24 use Encode;
  25 use Fcntl ();
  26 use Fcntl;
  27 use File::Find;
  28 use File::stat qw();
  29 use IO::File;
  30 use MIME::Base64;
  31 use Net::SSLeay;
  32 use POSIX qw(strftime EINTR EAGAIN);
  33 use Socket qw(IPPROTO_TCP TCP_NODELAY SOMAXCONN);
  34 use Time::HiRes qw(usleep ualarm gettimeofday tv_interval);
  35
  36 #use Data::Dumper; # FIXME: remove, just use: print to_json([$var], {pretty => 1}) ."\n";
  37 use HTTP::Date;
  38 use HTTP::Headers;
  39 use HTTP::Request;
  40 use HTTP::Response;
  41 use HTTP::Status qw(:constants);
  42 use JSON;
  43 use Net::IP;
  44 use URI::Escape;
  45 use URI;
  46
  47 use PVE::INotify;
  48 use PVE::SafeSyslog;
  49 use PVE::Tools qw(trim);
  50
  51 use PVE::APIServer::Formatter;
  52 use PVE::APIServer::Utils;
  53
  54 my $limit_max_headers = 64;
  55 my $limit_max_header_size = 8*1024;
  56 my $limit_max_post = 64*1024;
  57
  58 my $known_methods = {
  59     GET => 1,
  60     POST => 1,
  61     PUT => 1,
  62     DELETE => 1,
  63 };
  64
  65 my $split_abs_uri = sub {
  66     my ($abs_uri, $base_uri) = @_;
  67
  68     my ($format, $rel_uri) = $abs_uri =~ m/^\Q$base_uri\E\/+([a-z][a-z0-9]+)(\/.*)?$/;
  69     $rel_uri = '/' if !$rel_uri;
  70
  71     return wantarray ? ($rel_uri, $format) : $rel_uri;
  72 };
  73
  74 sub dprint {
  75     my ($self, $message) = @_;
  76
  77     return if !$self->{debug};
  78
  79     my ($pkg, $pkgfile, $line, $sub) = caller(1);
  80     $sub =~ s/^(?:.+::)+//;
  81     print "worker[$$]: $pkg +$line: $sub: $message\n";
  82 }
  83
  84 sub log_request {
  85     my ($self, $reqstate) = @_;
  86
  87     my $loginfo = $reqstate->{log};
  88
  89     # like apache2 common log format
  90     # LogFormat "%h %l %u %t \"%r\" %>s %b \"%{Referer}i\" \"%{User-agent}i\""
  91
  92     return if $loginfo->{written}; # avoid duplicate logs
  93     $loginfo->{written} = 1;
  94
  95     my $peerip = $reqstate->{peer_host} || '-';
  96     my $userid = $loginfo->{userid} || '-';
  97     my $content_length = defined($loginfo->{content_length}) ? $loginfo->{content_length} : '-';
  98     my $code =  $loginfo->{code} || 500;
  99     my $requestline = $loginfo->{requestline} || '-';
 100     my $timestr = strftime("%d/%m/%Y:%H:%M:%S %z", localtime());
 101
 102     my $msg = "$peerip - $userid [$timestr] \"$requestline\" $code $content_length\n";
 103
 104     $self->write_log($msg);
 105 }
 106
 107 sub log_aborted_request {
 108     my ($self, $reqstate, $error) = @_;
 109
 110     my $r = $reqstate->{request};
 111     return if !$r; # no active request
 112
 113     if ($error) {
 114         syslog("err", "problem with client $reqstate->{peer_host}; $error");
 115     }
 116
 117     $self->log_request($reqstate);
 118 }
 119
 120 sub cleanup_reqstate {
 121     my ($reqstate, $deletetmpfile) = @_;
 122
 123     delete $reqstate->{log};
 124     delete $reqstate->{request};
 125     delete $reqstate->{proto};
 126     delete $reqstate->{accept_gzip};
 127     delete $reqstate->{starttime};
 128
 129     if ($reqstate->{tmpfilename}) {
 130         unlink $reqstate->{tmpfilename} if $deletetmpfile;
 131         delete $reqstate->{tmpfilename};
 132     }
 133 }
 134
 135 sub client_do_disconnect {
 136     my ($self, $reqstate) = @_;
 137
 138     cleanup_reqstate($reqstate, 1);
 139
 140     my $shutdown_hdl = sub {
 141         my $hdl = shift;
 142
 143         shutdown($hdl->{fh}, 1);
 144         # clear all handlers
 145         $hdl->on_drain(undef);
 146         $hdl->on_read(undef);
 147         $hdl->on_eof(undef);
 148     };
 149
 150     if (my $proxyhdl = delete $reqstate->{proxyhdl}) {
 151         &$shutdown_hdl($proxyhdl)
 152                 if !$proxyhdl->{block_disconnect};
 153     }
 154
 155     my $hdl = delete $reqstate->{hdl};
 156
 157     if (!$hdl) {
 158         syslog('err', "detected empty handle");
 159         return;
 160     }
 161
 162     $self->dprint("close connection $hdl");
 163
 164     &$shutdown_hdl($hdl);
 165
 166     warn "connection count <= 0!\n" if $self->{conn_count} <= 0;
 167
 168     $self->{conn_count}--;
 169
 170     $self->dprint("CLOSE FH" .  $hdl->{fh}->fileno() . " CONN$self->{conn_count}");
 171 }
 172
 173 sub finish_response {
 174     my ($self, $reqstate) = @_;
 175
 176     cleanup_reqstate($reqstate, 0);
 177
 178     my $hdl = $reqstate->{hdl};
 179     return if !$hdl; # already disconnected
 180
 181     if (!$self->{end_loop} && $reqstate->{keep_alive} > 0) {
 182         # print "KEEPALIVE $reqstate->{keep_alive}\n" if $self->{debug};
 183         $hdl->on_read(sub {
 184             eval { $self->push_request_header($reqstate); };
 185             warn $@ if $@;
 186         });
 187     } else {
 188         $hdl->on_drain (sub {
 189             eval {
 190                 $self->client_do_disconnect($reqstate);
 191             };
 192             warn $@ if $@;
 193         });
 194     }
 195 }
 196
 197 sub response_stream {
 198     my ($self, $reqstate, $stream_fh) = @_;
 199
 200     # disable timeout, we don't know how big the data is
 201     $reqstate->{hdl}->timeout(0);
 202
 203     my $buf_size = 4*1024*1024;
 204
 205     my $on_read;
 206     $on_read = sub {
 207         my ($hdl) = @_;
 208         my $reqhdl = $reqstate->{hdl};
 209         return if !$reqhdl;
 210
 211         my $wbuf_len = length($reqhdl->{wbuf});
 212         my $rbuf_len = length($hdl->{rbuf});
 213         # TODO: Take into account $reqhdl->{wbuf_max} ? Right now
 214         # that's unbounded, so just assume $buf_size
 215         my $to_read = $buf_size - $wbuf_len;
 216         $to_read = $rbuf_len if $rbuf_len < $to_read;
 217         if ($to_read > 0) {
 218             my $data = substr($hdl->{rbuf}, 0, $to_read, '');
 219             $reqhdl->push_write($data);
 220             $rbuf_len -= $to_read;
 221         } elsif ($hdl->{_eof}) {
 222             # workaround: AnyEvent gives us a fake EPIPE if we don't consume
 223             # any data when called at EOF, so unregister ourselves - data is
 224             # flushed by on_eof anyway
 225             # see: https://sources.debian.org/src/libanyevent-perl/7.170-2/lib/AnyEvent/Handle.pm/#L1329
 226             $hdl->on_read();
 227             return;
 228         }
 229
 230         # apply backpressure so we don't accept any more data into
 231         # buffer if the client isn't downloading fast enough
 232         # note: read_size can double upon read, and we also need to
 233         # account for one more read after start_read, so *4
 234         if ($rbuf_len + $hdl->{read_size}*4 > $buf_size) {
 235             # stop reading until write buffer is empty
 236             $hdl->on_read();
 237             my $prev_on_drain = $reqhdl->{on_drain};
 238             $reqhdl->on_drain(sub {
 239                 my ($wrhdl) = @_;
 240                 # on_drain called because write buffer is empty, continue reading
 241                 $hdl->on_read($on_read);
 242                 if ($prev_on_drain) {
 243                     $wrhdl->on_drain($prev_on_drain);
 244                     $prev_on_drain->($wrhdl);
 245                 }
 246             });
 247         }
 248     };
 249
 250     $reqstate->{proxyhdl} = AnyEvent::Handle->new(
 251         fh => $stream_fh,
 252         rbuf_max => $buf_size,
 253         timeout => 0,
 254         on_read => $on_read,
 255         on_eof => sub {
 256             my ($hdl) = @_;
 257             eval {
 258                 if (my $reqhdl = $reqstate->{hdl}) {
 259                     $self->log_aborted_request($reqstate);
 260                     # write out any remaining data
 261                     $reqhdl->push_write($hdl->{rbuf}) if length($hdl->{rbuf}) > 0;
 262                     $hdl->{rbuf} = "";
 263                     $reqhdl->push_shutdown();
 264                     $self->finish_response($reqstate);
 265                 }
 266             };
 267             if (my $err = $@) { syslog('err', "$err"); }
 268             $on_read = undef;
 269         },
 270         on_error => sub {
 271             my ($hdl, $fatal, $message) = @_;
 272             eval {
 273                 $self->log_aborted_request($reqstate, $message);
 274                 $self->client_do_disconnect($reqstate);
 275             };
 276             if (my $err = $@) { syslog('err', "$err"); }
 277             $on_read = undef;
 278         },
 279     );
 280 }
 281
 282 sub response {
 283     my ($self, $reqstate, $resp, $mtime, $nocomp, $delay, $stream_fh) = @_;
 284
 285     #print "$$: send response: " . Dumper($resp);
 286
 287     # activate timeout
 288     $reqstate->{hdl}->timeout_reset();
 289     $reqstate->{hdl}->timeout($self->{timeout});
 290
 291     $nocomp = 1 if !$self->{compression};
 292     $nocomp = 1 if !$reqstate->{accept_gzip};
 293
 294     my $code = $resp->code;
 295     my $msg = $resp->message || HTTP::Status::status_message($code);
 296     my $content = $resp->content;
 297
 298     # multiline mode only checks \n for $, so explicitly check for any \n or \r afterwards
 299     ($msg) = $msg =~ m/^(.*)$/m;
 300     if ($msg =~ /[\r\n]/) {
 301         $code = 400; # bad request from user
 302         $msg = HTTP::Status::status_message($code);
 303         $content = '';
 304     }
 305
 306     if ($code =~ /^(1\d\d|[23]04)$/) {
 307         # make sure informational, no content and not modified response send no content
 308         $content = "";
 309     }
 310
 311     $reqstate->{keep_alive} = 0 if ($code >= 400) || $self->{end_loop};
 312
 313     $reqstate->{log}->{code} = $code;
 314
 315     my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.0';
 316     my $res = "$proto $code $msg\015\012";
 317
 318     my $ctime = time();
 319     my $date = HTTP::Date::time2str($ctime);
 320     $resp->header('Date' => $date);
 321     if ($mtime) {
 322         $resp->header('Last-Modified' => HTTP::Date::time2str($mtime));
 323     } else {
 324         $resp->header('Expires' => $date);
 325         $resp->header('Cache-Control' => "max-age=0");
 326         $resp->header("Pragma", "no-cache");
 327     }
 328
 329     $resp->header('Server' => "pve-api-daemon/3.0");
 330
 331     my $content_length;
 332     if ($content && !$stream_fh) {
 333
 334         $content_length = length($content);
 335
 336         if (!$nocomp && ($content_length > 1024)) {
 337             my $comp = Compress::Zlib::memGzip($content);
 338             $resp->header('Content-Encoding', 'gzip');
 339             $content = $comp;
 340             $content_length = length($content);
 341         }
 342         $resp->header("Content-Length" => $content_length);
 343         $reqstate->{log}->{content_length} = $content_length;
 344
 345     } else {
 346         $resp->remove_header("Content-Length");
 347     }
 348
 349     if ($reqstate->{keep_alive} > 0) {
 350         $resp->push_header('Connection' => 'Keep-Alive');
 351     } else {
 352         $resp->header('Connection' => 'close');
 353     }
 354
 355     $res .= $resp->headers_as_string("\015\012");
 356     #print "SEND(without content) $res\n" if $self->{debug};
 357
 358     $res .= "\015\012";
 359     $res .= $content if $content && !$stream_fh;
 360
 361     $self->log_request($reqstate, $reqstate->{request});
 362
 363     if ($stream_fh) {
 364         # write headers and preamble...
 365         $reqstate->{hdl}->push_write($res);
 366         # ...then stream data via an AnyEvent::Handle
 367         $self->response_stream($reqstate, $stream_fh);
 368     } elsif ($delay && $delay > 0) {
 369         my $w; $w = AnyEvent->timer(after => $delay, cb => sub {
 370             undef $w; # delete reference
 371             return if !$reqstate->{hdl}; # already disconnected
 372             $reqstate->{hdl}->push_write($res);
 373             $self->finish_response($reqstate);
 374         });
 375     } else {
 376         $reqstate->{hdl}->push_write($res);
 377         $self->finish_response($reqstate);
 378     }
 379 }
 380
 381 sub error {
 382     my ($self, $reqstate, $code, $msg, $hdr, $content) = @_;
 383
 384     eval {
 385         my $resp = HTTP::Response->new($code, $msg, $hdr, $content);
 386         $self->response($reqstate, $resp);
 387     };
 388     warn $@ if $@;
 389 }
 390
 391 my $file_extension_info = {
 392     css   => { ct => 'text/css' },
 393     html  => { ct => 'text/html' },
 394     js    => { ct => 'application/javascript' },
 395     json  => { ct => 'application/json' },
 396     map   => { ct => 'application/json' },
 397     png   => { ct => 'image/png' , nocomp => 1 },
 398     ico   => { ct => 'image/x-icon', nocomp => 1},
 399     gif   => { ct => 'image/gif', nocomp => 1},
 400     svg   => { ct => 'image/svg+xml' },
 401     jar   => { ct => 'application/java-archive', nocomp => 1},
 402     woff  => { ct => 'application/font-woff', nocomp => 1},
 403     woff2 => { ct => 'application/font-woff2', nocomp => 1},
 404     ttf   => { ct => 'application/font-snft', nocomp => 1},
 405     pdf   => { ct => 'application/pdf', nocomp => 1},
 406     epub  => { ct => 'application/epub+zip', nocomp => 1},
 407     mp3   => { ct => 'audio/mpeg', nocomp => 1},
 408     oga   => { ct => 'audio/ogg', nocomp => 1},
 409     tgz   => { ct => 'application/x-compressed-tar', nocomp => 1},
 410 };
 411
 412 sub send_file_start {
 413     my ($self, $reqstate, $download) = @_;
 414
 415     eval {
 416         # print "SEND FILE $filename\n";
 417         # Note: aio_load() this is not really async unless we use IO::AIO!
 418         eval {
 419
 420             my $r = $reqstate->{request};
 421
 422             my $fh;
 423             my $nocomp;
 424             my $mime;
 425
 426             if (ref($download) eq 'HASH') {
 427                 $mime = $download->{'content-type'};
 428                 my $encoding = $download->{'content-encoding'};
 429                 my $disposition = $download->{'content-disposition'};
 430
 431                 if ($download->{path} && $download->{stream} &&
 432                     $reqstate->{request}->header('PVEDisableProxy'))
 433                 {
 434                     # avoid double stream from a file, let the proxy handle it
 435                     die "internal error: file proxy streaming only available for pvedaemon\n"
 436                         if !$self->{trusted_env};
 437                     my $header = HTTP::Headers->new(
 438                         pvestreamfile => $download->{path},
 439                         Content_Type => $mime,
 440                     );
 441                     $header->header('Content-Encoding' => $encoding) if defined($encoding);
 442                     $header->header('Content-Disposition' => $disposition) if defined($disposition);
 443                     # we need some data so Content-Length gets set correctly and
 444                     # the proxy doesn't wait for more data - place a canary
 445                     my $resp = HTTP::Response->new(200, "OK", $header, "error canary");
 446                     $self->response($reqstate, $resp);
 447                     return;
 448                 }
 449
 450                 if (!($fh = $download->{fh})) {
 451                     my $path = $download->{path};
 452                     die "internal error: {download} returned but neither fh not path given\n"
 453                         if !$path;
 454                     sysopen($fh, "$path", O_NONBLOCK | O_RDONLY)
 455                         or die "open stream path '$path' for reading failed: $!\n";
 456                 }
 457
 458                 if ($download->{stream}) {
 459                     my $header = HTTP::Headers->new(Content_Type => $mime);
 460                     $header->header('Content-Encoding' => $encoding) if defined($encoding);
 461                     $header->header('Content-Disposition' => $disposition) if defined($disposition);
 462                     my $resp = HTTP::Response->new(200, "OK", $header);
 463                     $self->response($reqstate, $resp, undef, 1, 0, $fh);
 464                     return;
 465                 }
 466             } else {
 467                 my $filename = $download;
 468                 $fh = IO::File->new($filename, '<') ||
 469                     die "unable to open file '$filename' - $!\n";
 470
 471                 my ($ext) = $filename =~ m/\.([^.]*)$/;
 472                 my $ext_info = $file_extension_info->{$ext};
 473
 474                 die "unable to detect content type" if !$ext_info;
 475                 $mime = $ext_info->{ct};
 476                 $nocomp = $ext_info->{nocomp};
 477             }
 478
 479             my $stat = File::stat::stat($fh) ||
 480                 die "$!\n";
 481
 482             my $mtime = $stat->mtime;
 483
 484             if (my $ifmod = $r->header('if-modified-since')) {
 485                 my $iftime = HTTP::Date::str2time($ifmod);
 486                 if ($mtime <= $iftime) {
 487                     my $resp = HTTP::Response->new(304, "NOT MODIFIED");
 488                     $self->response($reqstate, $resp, $mtime);
 489                     return;
 490                 }
 491             }
 492
 493             my $data;
 494             my $len = sysread($fh, $data,  $stat->size);
 495             die "got short file\n" if !defined($len) || $len != $stat->size;
 496
 497             my $header = HTTP::Headers->new(Content_Type => $mime);
 498             my $resp = HTTP::Response->new(200, "OK", $header, $data);
 499             $self->response($reqstate, $resp, $mtime, $nocomp);
 500         };
 501         if (my $err = $@) {
 502             $self->error($reqstate, 501, $err);
 503         }
 504     };
 505
 506     warn $@ if $@;
 507 }
 508
 509 sub websocket_proxy {
 510     my ($self, $reqstate, $wsaccept, $wsproto, $param) = @_;
 511
 512     eval {
 513         my $remhost;
 514         my $remport;
 515
 516         my $max_payload_size = 128*1024;
 517
 518         if ($param->{port}) {
 519             $remhost = 'localhost';
 520             $remport = $param->{port};
 521         } elsif ($param->{socket}) {
 522             $remhost = 'unix/';
 523             $remport = $param->{socket};
 524         } else {
 525             die "websocket_proxy: missing port or socket\n";
 526         }
 527
 528         my $encode = sub {
 529             my ($data, $opcode) = @_;
 530
 531             my $string;
 532             my $payload;
 533
 534             $string = $opcode ? $opcode : "\x82"; # binary frame
 535             $payload = $$data;
 536
 537             my $payload_len = length($payload);
 538             if ($payload_len <= 125) {
 539                 $string .= pack 'C', $payload_len;
 540             } elsif ($payload_len <= 0xffff) {
 541                 $string .= pack 'C', 126;
 542                 $string .= pack 'n', $payload_len;
 543             } else {
 544                 $string .= pack 'C', 127;
 545                 $string .= pack 'Q>', $payload_len;
 546             }
 547             $string .= $payload;
 548             return $string;
 549         };
 550
 551         tcp_connect $remhost, $remport, sub {
 552             my ($fh) = @_
 553                 or die "connect to '$remhost:$remport' failed: $!";
 554
 555             $self->dprint("CONNECTed to '$remhost:$remport'");
 556
 557             $reqstate->{proxyhdl} = AnyEvent::Handle->new(
 558                 fh => $fh,
 559                 rbuf_max => $max_payload_size,
 560                 wbuf_max => $max_payload_size*5,
 561                 timeout => 5,
 562                 on_eof => sub {
 563                     my ($hdl) = @_;
 564                     eval {
 565                         $self->log_aborted_request($reqstate);
 566                         $self->client_do_disconnect($reqstate);
 567                     };
 568                     if (my $err = $@) { syslog('err', $err); }
 569                 },
 570                 on_error => sub {
 571                     my ($hdl, $fatal, $message) = @_;
 572                     eval {
 573                         $self->log_aborted_request($reqstate, $message);
 574                         $self->client_do_disconnect($reqstate);
 575                     };
 576                     if (my $err = $@) { syslog('err', "$err"); }
 577                 });
 578
 579             my $proxyhdlreader = sub {
 580                 my ($hdl) = @_;
 581
 582                 my $len = length($hdl->{rbuf});
 583                 my $data = substr($hdl->{rbuf}, 0, $len > $max_payload_size ? $max_payload_size : $len, '');
 584
 585                 my $string = $encode->(\$data);
 586
 587                 $reqstate->{hdl}->push_write($string) if $reqstate->{hdl};
 588             };
 589
 590             my $hdlreader = sub {
 591                 my ($hdl) = @_;
 592
 593                 while (my $len = length($hdl->{rbuf})) {
 594                     return if $len < 2;
 595
 596                     my $hdr = unpack('C', substr($hdl->{rbuf}, 0, 1));
 597                     my $opcode = $hdr & 0b00001111;
 598                     my $fin = $hdr & 0b10000000;
 599
 600                     die "received fragmented websocket frame\n" if !$fin;
 601
 602                     my $rsv = $hdr & 0b01110000;
 603                     die "received websocket frame with RSV flags\n" if $rsv;
 604
 605                     my $payload_len = unpack 'C', substr($hdl->{rbuf}, 1, 1);
 606
 607                     my $masked = $payload_len & 0b10000000;
 608                     die "received unmasked websocket frame from client\n" if !$masked;
 609
 610                     my $offset = 2;
 611                     $payload_len = $payload_len & 0b01111111;
 612                     if ($payload_len == 126) {
 613                         return if $len < 4;
 614                         $payload_len = unpack('n', substr($hdl->{rbuf}, $offset, 2));
 615                         $offset += 2;
 616                     } elsif ($payload_len == 127) {
 617                         return if $len < 10;
 618                         $payload_len = unpack('Q>', substr($hdl->{rbuf}, $offset, 8));
 619                         $offset += 8;
 620                     }
 621
 622                     die "received too large websocket frame (len = $payload_len)\n"
 623                         if ($payload_len > $max_payload_size) || ($payload_len < 0);
 624
 625                     return if $len < ($offset + 4 + $payload_len);
 626
 627                     my $data = substr($hdl->{rbuf}, 0, $offset + 4 + $payload_len, ''); # now consume data
 628
 629                     my $mask = substr($data, $offset, 4);
 630                     $offset += 4;
 631
 632                     my $payload = substr($data, $offset, $payload_len);
 633
 634                     # NULL-mask might be used over TLS, skip to increase performance
 635                     if ($mask ne pack('N', 0)) {
 636                         # repeat 4 byte mask to payload length + up to 4 byte
 637                         $mask = $mask x (int($payload_len / 4) + 1);
 638                         # truncate mask to payload length
 639                         substr($mask, $payload_len) = "";
 640                         # (un-)apply mask
 641                         $payload ^= $mask;
 642                     }
 643
 644                     if ($opcode == 1 || $opcode == 2) {
 645                         $reqstate->{proxyhdl}->push_write($payload) if $reqstate->{proxyhdl};
 646                     } elsif ($opcode == 8) {
 647                         my $statuscode = unpack ("n", $payload);
 648                         $self->dprint("websocket received close. status code: '$statuscode'");
 649                         if (my $proxyhdl = $reqstate->{proxyhdl}) {
 650                             $proxyhdl->{block_disconnect} = 1 if length $proxyhdl->{wbuf};
 651
 652                             $proxyhdl->push_shutdown();
 653                         }
 654                         $hdl->push_shutdown();
 655                     } elsif ($opcode == 9) {
 656                         # ping received, schedule pong
 657                         $reqstate->{hdl}->push_write($encode->(\$payload, "\x8A")) if $reqstate->{hdl};
 658                     } elsif ($opcode == 0xA) {
 659                         # pong received, continue
 660                     } else {
 661                         die "received unhandled websocket opcode $opcode\n";
 662                     }
 663                 }
 664             };
 665
 666             my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.1';
 667
 668             $reqstate->{proxyhdl}->timeout(0);
 669             $reqstate->{proxyhdl}->on_read($proxyhdlreader);
 670             $reqstate->{hdl}->on_read($hdlreader);
 671
 672             # todo: use stop_read/start_read if write buffer grows to much
 673
 674             # FIXME: remove protocol in PVE/PMG 8.x
 675             #
 676             # for backwards, compatibility,  we have to reply with the websocket
 677             # subprotocol from the request
 678             my $res = "$proto 101 Switching Protocols\015\012" .
 679                 "Upgrade: websocket\015\012" .
 680                 "Connection: upgrade\015\012" .
 681                 "Sec-WebSocket-Accept: $wsaccept\015\012" .
 682                 ($wsproto ne "" ? "Sec-WebSocket-Protocol: $wsproto\015\012" : "") .
 683                 "\015\012";
 684
 685             $self->dprint($res);
 686
 687             $reqstate->{hdl}->push_write($res);
 688
 689             # log early
 690             $reqstate->{log}->{code} = 101;
 691             $self->log_request($reqstate);
 692         };
 693
 694     };
 695     if (my $err = $@) {
 696         warn $err;
 697         $self->log_aborted_request($reqstate, $err);
 698         $self->client_do_disconnect($reqstate);
 699     }
 700 }
 701
 702 sub proxy_request {
 703     my ($self, $reqstate, $clientip, $host, $node, $method, $uri, $auth, $params) = @_;
 704
 705     eval {
 706         my $target;
 707         my $keep_alive = 1;
 708
 709         # stringify URI object and verify it starts with a slash
 710         $uri = "$uri";
 711         if ($uri !~ m@^/@) {
 712             $self->error($reqstate, 400, "invalid proxy uri");
 713             return;
 714         }
 715
 716         my $may_stream_file;
 717         if ($host eq 'localhost') {
 718             $target = "http://$host:85$uri";
 719             # keep alive for localhost is not worth (connection setup is about 0.2ms)
 720             $keep_alive = 0;
 721             $may_stream_file = 1;
 722         } elsif (Net::IP::ip_is_ipv6($host)) {
 723             $target = "https://[$host]:8006$uri";
 724         } else {
 725             $target = "https://$host:8006$uri";
 726         }
 727
 728         my $headers = {
 729             PVEDisableProxy => 'true',
 730             PVEClientIP => $clientip,
 731         };
 732
 733         $headers->{'cookie'} = PVE::APIServer::Formatter::create_auth_cookie($auth->{ticket}, $self->{cookie_name})
 734             if $auth->{ticket};
 735         $headers->{'Authorization'} = PVE::APIServer::Formatter::create_auth_header($auth->{api_token}, $self->{apitoken_name})
 736             if $auth->{api_token};
 737         $headers->{'CSRFPreventionToken'} = $auth->{token}
 738             if $auth->{token};
 739         $headers->{'Accept-Encoding'} = 'gzip' if ($reqstate->{accept_gzip} && $self->{compression});
 740
 741         if (defined(my $host = $reqstate->{request}->header('Host'))) {
 742             $headers->{Host} = $host;
 743         }
 744
 745         my $content;
 746
 747         if  ($method eq 'POST' || $method eq 'PUT') {
 748             $headers->{'Content-Type'} = 'application/x-www-form-urlencoded';
 749             # use URI object to format application/x-www-form-urlencoded content.
 750             my $url = URI->new('http:');
 751             $url->query_form(%$params);
 752             $content = $url->query;
 753             if (defined($content)) {
 754                 $headers->{'Content-Length'} = length($content);
 755             }
 756         }
 757
 758         my $tls = {
 759             # TLS 1.x only, with certificate pinning
 760             method => 'any',
 761             sslv2 => 0,
 762             sslv3 => 0,
 763             verify => 1,
 764             verify_cb => sub {
 765                 my (undef, undef, undef, $depth, undef, undef, $cert) = @_;
 766                 # we don't care about intermediate or root certificates
 767                 return 1 if $depth != 0;
 768                 # check server certificate against cache of pinned FPs
 769                 return $self->check_cert_fingerprint($cert);
 770             },
 771         };
 772
 773         # load and cache cert fingerprint if first time we proxy to this node
 774         $self->initialize_cert_cache($node);
 775
 776         my $w; $w = http_request(
 777             $method => $target,
 778             headers => $headers,
 779             timeout => 30,
 780             recurse => 0,
 781             proxy => undef, # avoid use of $ENV{HTTP_PROXY}
 782             keepalive => $keep_alive,
 783             body => $content,
 784             tls_ctx => AnyEvent::TLS->new(%{$tls}),
 785             sub {
 786                 my ($body, $hdr) = @_;
 787
 788                 undef $w;
 789
 790                 if (!$reqstate->{hdl}) {
 791                     warn "proxy detected vanished client connection\n";
 792                     return;
 793                 }
 794
 795                 eval {
 796                     my $code = delete $hdr->{Status};
 797                     my $msg = delete $hdr->{Reason};
 798                     my $stream = delete $hdr->{pvestreamfile};
 799                     delete $hdr->{URL};
 800                     delete $hdr->{HTTPVersion};
 801                     my $header = HTTP::Headers->new(%$hdr);
 802                     if (my $location = $header->header('Location')) {
 803                         $location =~ s|^http://localhost:85||;
 804                         $header->header(Location => $location);
 805                     }
 806                     if ($stream) {
 807                         if (!$may_stream_file) {
 808                             $self->error($reqstate, 403, 'streaming denied');
 809                             return;
 810                         }
 811                         sysopen(my $fh, "$stream", O_NONBLOCK | O_RDONLY)
 812                             or die "open stream path '$stream' for forwarding failed: $!\n";
 813                         my $resp = HTTP::Response->new($code, $msg, $header, undef);
 814                         $self->response($reqstate, $resp, undef, 1, 0, $fh);
 815                     } else {
 816                         my $resp = HTTP::Response->new($code, $msg, $header, $body);
 817                         # Note: disable compression, because body is already compressed
 818                         $self->response($reqstate, $resp, undef, 1);
 819                     }
 820                 };
 821                 warn $@ if $@;
 822             });
 823     };
 824     warn $@ if $@;
 825 }
 826
 827 # return arrays as \0 separated strings (like CGI.pm)
 828 # assume data is UTF8 encoded
 829 sub decode_urlencoded {
 830     my ($data) = @_;
 831
 832     my $res = {};
 833
 834     return $res if !$data;
 835
 836     foreach my $kv (split(/[\&\;]/, $data)) {
 837         my ($k, $v) = split(/=/, $kv);
 838         $k =~s/\+/ /g;
 839         $k =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr(hex($1))/eg;
 840
 841         if (defined($v)) {
 842             $v =~s/\+/ /g;
 843             $v =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr(hex($1))/eg;
 844
 845             $v = Encode::decode('utf8', $v);
 846
 847             if (defined(my $old = $res->{$k})) {
 848                 $v = "$old\0$v";
 849             }
 850         }
 851
 852         $res->{$k} = $v;
 853     }
 854     return $res;
 855 }
 856
 857 sub extract_params {
 858     my ($r, $method) = @_;
 859
 860     my $params = {};
 861
 862     if ($method eq 'PUT' || $method eq 'POST') {
 863         my $ct;
 864         if (my $ctype = $r->header('Content-Type')) {
 865             $ct = parse_content_type($ctype);
 866         }
 867         if (defined($ct) && $ct eq 'application/json')  {
 868             $params = decode_json($r->content);
 869         } else {
 870             $params = decode_urlencoded($r->content);
 871         }
 872     }
 873
 874     my $query_params = decode_urlencoded($r->url->query());
 875
 876     foreach my $k (keys %{$query_params}) {
 877         $params->{$k} = $query_params->{$k};
 878     }
 879
 880     return $params;
 881 }
 882
 883 sub handle_api2_request {
 884     my ($self, $reqstate, $auth, $method, $path, $upload_state) = @_;
 885
 886     eval {
 887         my $r = $reqstate->{request};
 888
 889         my ($rel_uri, $format) = &$split_abs_uri($path, $self->{base_uri});
 890
 891         my $formatter = PVE::APIServer::Formatter::get_formatter($format, $method, $rel_uri);
 892
 893         if (!defined($formatter)) {
 894             $self->error($reqstate, HTTP_NOT_IMPLEMENTED, "no formatter for uri $rel_uri, $format");
 895             return;
 896         }
 897
 898         #print Dumper($upload_state) if $upload_state;
 899
 900         my $params;
 901
 902         if ($upload_state) {
 903             $params = $upload_state->{params};
 904         } else {
 905             $params = extract_params($r, $method);
 906         }
 907
 908         delete $params->{_dc} if $params; # remove disable cache parameter
 909
 910         my $clientip = $reqstate->{peer_host};
 911
 912         my $res = $self->rest_handler($clientip, $method, $rel_uri, $auth, $params, $format);
 913
 914         # HACK: see Note 1
 915         Net::SSLeay::ERR_clear_error();
 916
 917         AnyEvent->now_update(); # in case somebody called sleep()
 918
 919         my $upgrade = $r->header('upgrade');
 920         $upgrade = lc($upgrade) if $upgrade;
 921
 922         if (my $host = $res->{proxy}) {
 923
 924             if ($self->{trusted_env}) {
 925                 $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy not allowed");
 926                 return;
 927             }
 928
 929             if ($host ne 'localhost' && $r->header('PVEDisableProxy')) {
 930                 $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy loop detected");
 931                 return;
 932             }
 933
 934             $res->{proxy_params}->{tmpfilename} = $reqstate->{tmpfilename} if $upload_state;
 935
 936             $self->proxy_request($reqstate, $clientip, $host, $res->{proxynode}, $method,
 937                                  $r->uri, $auth, $res->{proxy_params});
 938             return;
 939
 940         } elsif ($upgrade && ($method eq 'GET') && ($path =~ m|websocket$|)) {
 941             die "unable to upgrade to protocol '$upgrade'\n" if !$upgrade || ($upgrade ne 'websocket');
 942             my $wsver = $r->header('sec-websocket-version');
 943             die "unsupported websocket-version '$wsver'\n" if !$wsver || ($wsver ne '13');
 944             my $wsproto = $r->header('sec-websocket-protocol') // "";
 945             my $wskey = $r->header('sec-websocket-key');
 946             die "missing websocket-key\n" if !$wskey;
 947             # Note: Digest::SHA::sha1_base64 has wrong padding
 948             my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
 949             if ($res->{status} == HTTP_OK) {
 950                 $self->websocket_proxy($reqstate, $wsaccept, $wsproto, $res->{data});
 951                 return;
 952             }
 953         }
 954
 955         my $delay = 0;
 956         if ($res->{status} == HTTP_UNAUTHORIZED) {
 957             # always delay unauthorized calls by 3 seconds
 958             $delay = 3 - tv_interval($reqstate->{starttime});
 959             $delay = 0 if $delay < 0;
 960         }
 961
 962         my $download = $res->{download};
 963         $download //= $res->{data}->{download}
 964             if defined($res->{data}) && ref($res->{data}) eq 'HASH';
 965         if (defined($download)) {
 966             send_file_start($self, $reqstate, $download);
 967             return;
 968         }
 969
 970         my ($raw, $ct, $nocomp) = $formatter->($res, $res->{data}, $params, $path,
 971                                                $auth, $self->{formatter_config});
 972
 973         my $resp;
 974         if (ref($raw) && (ref($raw) eq 'HTTP::Response')) {
 975             $resp = $raw;
 976         } else {
 977             $resp = HTTP::Response->new($res->{status}, $res->{message});
 978             $resp->header("Content-Type" => $ct);
 979             $resp->content($raw);
 980         }
 981         $self->response($reqstate, $resp, undef, $nocomp, $delay);
 982     };
 983     if (my $err = $@) {
 984         $self->error($reqstate, 501, $err);
 985     }
 986 }
 987
 988 sub handle_spice_proxy_request {
 989     my ($self, $reqstate, $connect_str, $vmid, $node, $spiceport) = @_;
 990
 991     eval {
 992
 993         my ($minport, $maxport) = PVE::Tools::spice_port_range();
 994         if ($spiceport < $minport || $spiceport > $maxport) {
 995             die "SPICE Port $spiceport is not in allowed range ($minport, $maxport)\n";
 996         }
 997
 998         my $clientip = $reqstate->{peer_host};
 999         my $r = $reqstate->{request};
1000
1001         my $remip;
1002
1003         if ($node ne 'localhost' && PVE::INotify::nodename() !~ m/^$node$/i) {
1004             $remip = $self->remote_node_ip($node);
1005             $self->dprint("REMOTE CONNECT $vmid, $remip, $connect_str");
1006         } else {
1007             $self->dprint("CONNECT $vmid, $node, $spiceport");
1008         }
1009
1010         if ($remip && $r->header('PVEDisableProxy')) {
1011             $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy loop detected");
1012             return;
1013         }
1014
1015         $reqstate->{hdl}->timeout(0);
1016         $reqstate->{hdl}->wbuf_max(64*10*1024);
1017
1018         my $remhost = $remip ? $remip : "localhost";
1019         my $remport = $remip ? 3128 : $spiceport;
1020
1021         tcp_connect $remhost, $remport, sub {
1022             my ($fh) = @_
1023                 or die "connect to '$remhost:$remport' failed: $!";
1024
1025             $self->dprint("CONNECTed to '$remhost:$remport'");
1026             $reqstate->{proxyhdl} = AnyEvent::Handle->new(
1027                 fh => $fh,
1028                 rbuf_max => 64*1024,
1029                 wbuf_max => 64*10*1024,
1030                 timeout => 5,
1031                 on_eof => sub {
1032                     my ($hdl) = @_;
1033                     eval {
1034                         $self->log_aborted_request($reqstate);
1035                         $self->client_do_disconnect($reqstate);
1036                     };
1037                     if (my $err = $@) { syslog('err', $err); }
1038                 },
1039                 on_error => sub {
1040                     my ($hdl, $fatal, $message) = @_;
1041                     eval {
1042                         $self->log_aborted_request($reqstate, $message);
1043                         $self->client_do_disconnect($reqstate);
1044                     };
1045                     if (my $err = $@) { syslog('err', "$err"); }
1046                 });
1047
1048
1049             my $proxyhdlreader = sub {
1050                 my ($hdl) = @_;
1051
1052                 my $len = length($hdl->{rbuf});
1053                 my $data = substr($hdl->{rbuf}, 0, $len, '');
1054
1055                 #print "READ1 $len\n";
1056                 $reqstate->{hdl}->push_write($data) if $reqstate->{hdl};
1057             };
1058
1059             my $hdlreader = sub {
1060                 my ($hdl) = @_;
1061
1062                 my $len = length($hdl->{rbuf});
1063                 my $data = substr($hdl->{rbuf}, 0, $len, '');
1064
1065                 #print "READ0 $len\n";
1066                 $reqstate->{proxyhdl}->push_write($data) if $reqstate->{proxyhdl};
1067             };
1068
1069             my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.0';
1070
1071             my $startproxy = sub {
1072                 $reqstate->{proxyhdl}->timeout(0);
1073                 $reqstate->{proxyhdl}->on_read($proxyhdlreader);
1074                 $reqstate->{hdl}->on_read($hdlreader);
1075
1076                 # todo: use stop_read/start_read if write buffer grows to much
1077
1078                 # a response must be followed by an empty line
1079                 my $res = "$proto 200 OK\015\012\015\012";
1080                 $reqstate->{hdl}->push_write($res);
1081
1082                 # log early
1083                 $reqstate->{log}->{code} = 200;
1084                 $self->log_request($reqstate);
1085             };
1086
1087             if ($remip) {
1088                 my $header = "CONNECT ${connect_str} $proto\015\012" .
1089                     "Host: ${connect_str}\015\012" .
1090                     "Proxy-Connection: keep-alive\015\012" .
1091                     "User-Agent: spiceproxy\015\012" .
1092                     "PVEDisableProxy: true\015\012" .
1093                     "PVEClientIP: $clientip\015\012" .
1094                     "\015\012";
1095
1096                 $reqstate->{proxyhdl}->push_write($header);
1097                 $reqstate->{proxyhdl}->push_read(line => sub {
1098                     my ($hdl, $line) = @_;
1099
1100                     if ($line =~ m!^$proto 200 OK$!) {
1101                         # read the empty line after the 200 OK
1102                         $reqstate->{proxyhdl}->unshift_read(line => sub{
1103                             &$startproxy();
1104                         });
1105                     } else {
1106                         $reqstate->{hdl}->push_write($line);
1107                         $self->client_do_disconnect($reqstate);
1108                     }
1109                 });
1110             } else {
1111                 &$startproxy();
1112             }
1113
1114         };
1115     };
1116     if (my $err = $@) {
1117         warn $err;
1118         $self->log_aborted_request($reqstate, $err);
1119         $self->client_do_disconnect($reqstate);
1120     }
1121 }
1122
1123 sub handle_request {
1124     my ($self, $reqstate, $auth, $method, $path) = @_;
1125
1126     my $base_uri = $self->{base_uri};
1127
1128     eval {
1129         my $r = $reqstate->{request};
1130
1131         # disable timeout on handle (we already have all data we need)
1132         # we re-enable timeout in response()
1133         $reqstate->{hdl}->timeout(0);
1134
1135         if ($path =~ m/^\Q$base_uri\E/) {
1136             $self->handle_api2_request($reqstate, $auth, $method, $path);
1137             return;
1138         }
1139
1140         if ($self->{pages} && ($method eq 'GET') && (my $handler = $self->{pages}->{$path})) {
1141             if (ref($handler) eq 'CODE') {
1142                 my $params = decode_urlencoded($r->url->query());
1143                 my ($resp, $userid) = &$handler($self, $reqstate->{request}, $params);
1144                 # HACK: see Note 1
1145                 Net::SSLeay::ERR_clear_error();
1146                 $self->response($reqstate, $resp);
1147             } elsif (ref($handler) eq 'HASH') {
1148                 if (my $filename = $handler->{file}) {
1149                     my $fh = IO::File->new($filename) ||
1150                         die "unable to open file '$filename' - $!\n";
1151                     send_file_start($self, $reqstate, $filename);
1152                 } else {
1153                     die "internal error - no handler";
1154                 }
1155             } else {
1156                 die "internal error - no handler";
1157             }
1158             return;
1159         }
1160
1161         if ($self->{dirs} && ($method eq 'GET')) {
1162             # we only allow simple names
1163             if ($path =~ m!^(/\S+/)([a-zA-Z0-9\-\_\.]+)$!) {
1164                 my ($subdir, $file) = ($1, $2);
1165                 if (my $dir = $self->{dirs}->{$subdir}) {
1166                     my $filename = "$dir$file";
1167                     my $fh = IO::File->new($filename) ||
1168                         die "unable to open file '$filename' - $!\n";
1169                     send_file_start($self, $reqstate, $filename);
1170                     return;
1171                 }
1172             }
1173         }
1174
1175         die "no such file '$path'\n";
1176     };
1177     if (my $err = $@) {
1178         $self->error($reqstate, 501, $err);
1179     }
1180 }
1181
1182 my sub assert_form_disposition {
1183     die "wrong Content-Disposition '$_[0]' in multipart, expected 'form-data'\n" if $_[0] ne 'form-data';
1184 }
1185
1186 sub file_upload_multipart {
1187     my ($self, $reqstate, $auth, $method, $path, $rstate) = @_;
1188
1189     eval {
1190         my $boundary = $rstate->{boundary};
1191         my $hdl = $reqstate->{hdl};
1192         my $startlen = length($hdl->{rbuf});
1193
1194         my $newline_re = qr/\015?\012/;
1195         my $delim_re = qr/--\Q$boundary\E${newline_re}/;
1196         my $close_delim_re = qr/--\Q$boundary\E--/;
1197
1198         # Phase 0 - preserve boundary, but remove everything before
1199         if ($rstate->{phase} == 0 && $hdl->{rbuf} =~ s/^.*?($delim_re)/$1/s) {
1200             $rstate->{read} += $startlen - length($hdl->{rbuf});
1201             $rstate->{phase} = 1;
1202         }
1203
1204         my $remove_until_data = sub {
1205             my ($hdl) = @_;
1206             # remove any remaining multipart "headers" like Content-Type
1207             $hdl->{rbuf} =~ s/^.*?${newline_re}{2}//s;
1208         };
1209
1210         my $extract_form_disposition = sub {
1211             my ($name) = @_;
1212             if ($hdl->{rbuf} =~ s/^${delim_re}.*?Content-Disposition: (.*?); name="$name"(.*?${delim_re})/$2/s) {
1213                 assert_form_disposition($1);
1214                 $remove_until_data->($hdl);
1215                 $hdl->{rbuf} =~ s/^(.*?)(${delim_re})/$2/s;
1216                 $rstate->{params}->{$name} = trim($1);
1217             }
1218         };
1219
1220         if ($rstate->{phase} == 1) { # Phase 1 - parse payload without file data
1221             $extract_form_disposition->('content');
1222             $extract_form_disposition->('checksum-algorithm');
1223             $extract_form_disposition->('checksum');
1224
1225             if ($hdl->{rbuf} =~
1226                 s/^${delim_re}Content-Disposition:\ (.*?);\ name="(.*?)";\ filename="([^"]+)"${newline_re}//sxx
1227             ) {
1228                 assert_form_disposition($1);
1229                 die "wrong field name '$2' for file upload, expected 'filename'" if $2 ne "filename";
1230                 $rstate->{phase} = 2;
1231                 $rstate->{params}->{filename} = trim($3);
1232
1233                 # remove any remaining multipart "headers" like Content-Type
1234                 $hdl->{rbuf} =~ s/^.*?${newline_re}{2}//s
1235             }
1236         }
1237
1238         if ($rstate->{phase} == 2) { # Phase 2 - dump content into file
1239             my ($data, $write_length);
1240             if ($hdl->{rbuf} =~ s/^(.*?)${newline_re}?+${close_delim_re}.*$//s) {
1241                 $data = $1;
1242                 $write_length = length($data);
1243                 $rstate->{phase} =  100;
1244             } else {
1245                 $write_length = length($hdl->{rbuf}) - $rstate->{boundlen};
1246                 $data = substr($hdl->{rbuf}, 0, $write_length, '') if $write_length > 0;
1247             }
1248
1249             if ($write_length > 0) {
1250                 syswrite($rstate->{outfh}, $data) == $write_length or die "write to temporary file failed - $!\n";
1251                 $rstate->{bytes} += $write_length;
1252                 $rstate->{ctx}->add($data);
1253             }
1254         }
1255
1256         if ($rstate->{phase} == 100) { # Phase 100 - transfer finished
1257             $rstate->{md5sum} = $rstate->{ctx}->hexdigest;
1258             my $elapsed = tv_interval($rstate->{starttime});
1259             syslog('info', "multipart upload complete (size: %dB time: %.3fs rate: %.2fMiB/s md5sum: %s)",
1260                 $rstate->{bytes}, $elapsed, $rstate->{bytes} / ($elapsed * 1024 * 1024), $rstate->{md5sum}
1261             );
1262             $self->handle_api2_request($reqstate, $auth, $method, $path, $rstate);
1263         }
1264
1265         $rstate->{read} += $startlen - length($hdl->{rbuf});
1266
1267         if ($rstate->{read} + length($hdl->{rbuf}) >= $rstate->{size} && $rstate->{phase} != 100) {
1268             die "upload failed";
1269         }
1270     };
1271     if (my $err = $@) {
1272         syslog('err', $err);
1273         $self->error($reqstate, 501, $err);
1274     }
1275 }
1276
1277 sub parse_content_type {
1278     my ($ctype) = @_;
1279
1280     my ($ct, @params) = split(/\s*[;,]\s*/o, $ctype);
1281
1282     foreach my $v (@params) {
1283         if ($v =~ m/^\s*boundary\s*=\s*(\S+?)\s*$/o) {
1284             return wantarray ? ($ct, $1) : $ct;
1285         }
1286     }
1287
1288     return  wantarray ? ($ct) : $ct;
1289 }
1290
1291 my $tmpfile_seq_no = 0;
1292
1293 sub get_upload_filename {
1294     # choose unpredictable tmpfile name
1295
1296     $tmpfile_seq_no++;
1297     return "/var/tmp/pveupload-" . Digest::MD5::md5_hex($tmpfile_seq_no . time() . $$);
1298 }
1299
1300 sub unshift_read_header {
1301     my ($self, $reqstate, $state) = @_;
1302
1303     $state = { size => 0, count => 0 } if !$state;
1304
1305     $reqstate->{hdl}->unshift_read(line => sub {
1306         my ($hdl, $line) = @_;
1307
1308         eval {
1309             # print "$$: got header: $line\n" if $self->{debug};
1310
1311             die "too many http header lines (> $limit_max_headers)\n" if ++$state->{count} >= $limit_max_headers;
1312             die "http header too large\n" if ($state->{size} += length($line)) >= $limit_max_header_size;
1313
1314             my $r = $reqstate->{request};
1315             if ($line eq '') {
1316
1317                 my $path = uri_unescape($r->uri->path());
1318                 my $method = $r->method();
1319
1320                 $r->push_header($state->{key}, $state->{val})
1321                     if $state->{key};
1322
1323                 if (!$known_methods->{$method}) {
1324                     my $resp = HTTP::Response->new(HTTP_NOT_IMPLEMENTED, "method '$method' not available");
1325                     $self->response($reqstate, $resp);
1326                     return;
1327                 }
1328
1329                 my $conn = $r->header('Connection');
1330                 my $accept_enc = $r->header('Accept-Encoding');
1331                 $reqstate->{accept_gzip} = ($accept_enc && $accept_enc =~ m/gzip/) ? 1 : 0;
1332
1333                 if ($conn) {
1334                     $reqstate->{keep_alive} = 0 if $conn =~ m/close/oi;
1335                 } else {
1336                     if ($reqstate->{proto}->{ver} < 1001) {
1337                         $reqstate->{keep_alive} = 0;
1338                     }
1339                 }
1340
1341                 my $te  = $r->header('Transfer-Encoding');
1342                 if ($te && lc($te) eq 'chunked') {
1343                     # Handle chunked transfer encoding
1344                     $self->error($reqstate, 501, "chunked transfer encoding not supported");
1345                     return;
1346                 } elsif ($te) {
1347                     $self->error($reqstate, 501, "Unknown transfer encoding '$te'");
1348                     return;
1349                 }
1350
1351                 my $pveclientip = $r->header('PVEClientIP');
1352                 my $base_uri = $self->{base_uri};
1353
1354                 # fixme: how can we make PVEClientIP header trusted?
1355                 if ($self->{trusted_env} && $pveclientip) {
1356                     $reqstate->{peer_host} = $pveclientip;
1357                 } else {
1358                     $r->header('PVEClientIP', $reqstate->{peer_host});
1359                 }
1360
1361                 my $len = $r->header('Content-Length');
1362
1363                 my $host_header = $r->header('Host');
1364                 if (my $rpcenv = $self->{rpcenv}) {
1365                     $rpcenv->set_request_host($host_header);
1366                 }
1367
1368                 # header processing complete - authenticate now
1369
1370                 my $auth = {};
1371                 if ($self->{spiceproxy}) {
1372                     my $connect_str = $host_header;
1373                     my ($vmid, $node, $port) = $self->verify_spice_connect_url($connect_str);
1374                     if (!(defined($vmid) && $node && $port)) {
1375                         $self->error($reqstate, HTTP_UNAUTHORIZED, "invalid ticket");
1376                         return;
1377                     }
1378                     $self->handle_spice_proxy_request($reqstate, $connect_str, $vmid, $node, $port);
1379                     return;
1380                 } elsif ($path =~ m/^\Q$base_uri\E/) {
1381                     my $token = $r->header('CSRFPreventionToken');
1382                     my $cookie = $r->header('Cookie');
1383                     my $auth_header = $r->header('Authorization');
1384
1385                     # prefer actual cookie
1386                     my $ticket = PVE::APIServer::Formatter::extract_auth_value($cookie, $self->{cookie_name});
1387
1388                     # fallback to cookie in 'Authorization' header
1389                     $ticket = PVE::APIServer::Formatter::extract_auth_value($auth_header, $self->{cookie_name})
1390                         if !$ticket;
1391
1392                     # finally, fallback to API token if no ticket has been provided so far
1393                     my $api_token;
1394                     $api_token = PVE::APIServer::Formatter::extract_auth_value($auth_header, $self->{apitoken_name})
1395                         if !$ticket;
1396
1397                     my ($rel_uri, $format) = &$split_abs_uri($path, $self->{base_uri});
1398                     if (!$format) {
1399                         $self->error($reqstate, HTTP_NOT_IMPLEMENTED, "no such uri");
1400                         return;
1401                     }
1402
1403                     eval {
1404                         $auth = $self->auth_handler($method, $rel_uri, $ticket, $token, $api_token,
1405                                                     $reqstate->{peer_host});
1406                     };
1407                     if (my $err = $@) {
1408                         # HACK: see Note 1
1409                         Net::SSLeay::ERR_clear_error();
1410                         # always delay unauthorized calls by 3 seconds
1411                         my $delay = 3;
1412
1413                         if (ref($err) eq "PVE::Exception") {
1414
1415                             $err->{code} ||= HTTP_INTERNAL_SERVER_ERROR,
1416                             my $resp = HTTP::Response->new($err->{code}, $err->{msg});
1417                             $self->response($reqstate, $resp, undef, 0, $delay);
1418
1419                         } elsif (my $formatter = PVE::APIServer::Formatter::get_login_formatter($format)) {
1420                             my ($raw, $ct, $nocomp) =
1421                                 $formatter->($path, $auth, $self->{formatter_config});
1422                             my $resp;
1423                             if (ref($raw) && (ref($raw) eq 'HTTP::Response')) {
1424                                 $resp = $raw;
1425                             } else {
1426                                 $resp = HTTP::Response->new(HTTP_UNAUTHORIZED, "Login Required");
1427                                 $resp->header("Content-Type" => $ct);
1428                                 $resp->content($raw);
1429                             }
1430                             $self->response($reqstate, $resp, undef, $nocomp, $delay);
1431                         } else {
1432                             my $resp = HTTP::Response->new(HTTP_UNAUTHORIZED, $err);
1433                             $self->response($reqstate, $resp, undef, 0, $delay);
1434                         }
1435                         return;
1436                     }
1437                 }
1438
1439                 $reqstate->{log}->{userid} = $auth->{userid};
1440
1441                 if ($len) {
1442
1443                     if (!($method eq 'PUT' || $method eq 'POST')) {
1444                         $self->error($reqstate, 501, "Unexpected content for method '$method'");
1445                         return;
1446                     }
1447
1448                     my $ctype = $r->header('Content-Type');
1449                     my ($ct, $boundary) = $ctype ? parse_content_type($ctype) : ();
1450
1451                     if ($auth->{isUpload} && !$self->{trusted_env}) {
1452                         die "upload 'Content-Type '$ctype' not implemented\n"
1453                             if !($boundary && $ct && ($ct eq 'multipart/form-data'));
1454
1455                         die "upload without content length header not supported" if !$len;
1456
1457                         die "upload without content length header not supported" if !$len;
1458
1459                         $self->dprint("start upload $path $ct $boundary");
1460
1461                         my $tmpfilename = get_upload_filename();
1462                         my $outfh = IO::File->new($tmpfilename, O_RDWR|O_CREAT|O_EXCL, 0600) ||
1463                             die "unable to create temporary upload file '$tmpfilename'";
1464
1465                         $reqstate->{keep_alive} = 0;
1466
1467                         my $boundlen = length($boundary) + 8; # \015?\012--$boundary--\015?\012
1468
1469                         my $state = {
1470                             size => $len,
1471                             boundary => $boundary,
1472                             ctx => Digest::MD5->new,
1473                             boundlen =>  $boundlen,
1474                             maxheader => 2048 + $boundlen, # should be large enough
1475                             params => decode_urlencoded($r->url->query()),
1476                             phase => 0,
1477                             read => 0,
1478                             post_size => 0,
1479                             starttime => [gettimeofday],
1480                             outfh => $outfh,
1481                         };
1482                         $reqstate->{tmpfilename} = $tmpfilename;
1483                         $reqstate->{hdl}->on_read(sub {
1484                             $self->file_upload_multipart($reqstate, $auth, $method, $path, $state);
1485                         });
1486                         return;
1487                     }
1488
1489                     if ($len > $limit_max_post) {
1490                         $self->error($reqstate, 501, "for data too large");
1491                         return;
1492                     }
1493
1494                     if (!$ct || $ct eq 'application/x-www-form-urlencoded' || $ct eq 'application/json') {
1495                         $reqstate->{hdl}->unshift_read(chunk => $len, sub {
1496                             my ($hdl, $data) = @_;
1497                             $r->content($data);
1498                             $self->handle_request($reqstate, $auth, $method, $path);
1499                         });
1500                     } else {
1501                         $self->error($reqstate, 506, "upload 'Content-Type '$ctype' not implemented");
1502                     }
1503                 } else {
1504                     $self->handle_request($reqstate, $auth, $method, $path);
1505                 }
1506             } elsif ($line =~ /^([^:\s]+)\s*:\s*(.*)/) {
1507                 $r->push_header($state->{key}, $state->{val}) if $state->{key};
1508                 ($state->{key}, $state->{val}) = ($1, $2);
1509                 $self->unshift_read_header($reqstate, $state);
1510             } elsif ($line =~ /^\s+(.*)/) {
1511                 $state->{val} .= " $1";
1512                 $self->unshift_read_header($reqstate, $state);
1513             } else {
1514                 $self->error($reqstate, 506, "unable to parse request header");
1515             }
1516         };
1517         warn $@ if $@;
1518     });
1519 };
1520
1521 sub push_request_header {
1522     my ($self, $reqstate) = @_;
1523
1524     eval {
1525         $reqstate->{hdl}->push_read(line => sub {
1526             my ($hdl, $line) = @_;
1527
1528             eval {
1529                 # print "got request header: $line\n" if $self->{debug};
1530
1531                 $reqstate->{keep_alive}--;
1532
1533                 if ($line =~ /(\S+)\040(\S+)\040HTTP\/(\d+)\.(\d+)/o) {
1534                     my ($method, $url, $maj, $min) = ($1, $2, $3, $4);
1535
1536                     if ($maj != 1) {
1537                         $self->error($reqstate, 506, "http protocol version $maj.$min not supported");
1538                         return;
1539                     }
1540                     if ($url =~ m|^[^/]*@|) {
1541                         # if an '@' comes before the first slash proxy forwarding might consider
1542                         # the frist part of the url to be part of an authority...
1543                         $self->error($reqstate, 400, "invalid url");
1544                         return;
1545                     }
1546
1547                     $self->{request_count}++; # only count valid request headers
1548                     if ($self->{request_count} >= $self->{max_requests}) {
1549                         $self->{end_loop} = 1;
1550                     }
1551                     $reqstate->{log} = { requestline => $line };
1552                     $reqstate->{proto}->{str} = "HTTP/$maj.$min";
1553                     $reqstate->{proto}->{maj} = $maj;
1554                     $reqstate->{proto}->{min} = $min;
1555                     $reqstate->{proto}->{ver} = $maj*1000+$min;
1556                     $reqstate->{request} = HTTP::Request->new($method, $url);
1557                     $reqstate->{starttime} = [gettimeofday],
1558
1559                     $self->unshift_read_header($reqstate);
1560                 } elsif ($line eq '') {
1561                     # ignore empty lines before requests (browser bugs?)
1562                     $self->push_request_header($reqstate);
1563                 } else {
1564                     $self->error($reqstate, 400, 'bad request');
1565                 }
1566             };
1567             warn $@ if $@;
1568         });
1569     };
1570     warn $@ if $@;
1571 }
1572
1573 sub accept {
1574     my ($self) = @_;
1575
1576     my $clientfh;
1577
1578     return if $self->{end_loop};
1579
1580     # we need to m make sure that only one process calls accept
1581     while (!flock($self->{lockfh}, Fcntl::LOCK_EX())) {
1582         next if $! == EINTR;
1583         die "could not get lock on file '$self->{lockfile}' -  $!\n";
1584     }
1585
1586     my $again = 0;
1587     my $errmsg;
1588     eval {
1589         while (!$self->{end_loop} &&
1590                !defined($clientfh = $self->{socket}->accept()) &&
1591                ($! == EINTR)) {};
1592
1593         if ($self->{end_loop}) {
1594             $again = 0;
1595         } else {
1596             $again = ($! == EAGAIN || $! == WSAEWOULDBLOCK);
1597             if (!defined($clientfh)) {
1598                 $errmsg = "failed to accept connection: $!\n";
1599             }
1600         }
1601     };
1602     warn $@ if $@;
1603
1604     flock($self->{lockfh}, Fcntl::LOCK_UN());
1605
1606     if (!defined($clientfh)) {
1607         return if $again;
1608         die $errmsg if $errmsg;
1609     }
1610
1611     fh_nonblocking $clientfh, 1;
1612
1613     return $clientfh;
1614 }
1615
1616 sub wait_end_loop {
1617     my ($self) = @_;
1618
1619     $self->{end_loop} = 1;
1620
1621     undef $self->{socket_watch};
1622
1623     $0 = "$0 (shutdown)" if $0 !~ m/\(shutdown\)$/;
1624
1625     if ($self->{conn_count} <= 0) {
1626         $self->{end_cond}->send(1);
1627         return;
1628     }
1629
1630     # fork and exit, so that parent starts a new worker
1631     if (fork()) {
1632         exit(0);
1633     }
1634
1635     # else we need to wait until all open connections gets closed
1636     my $w; $w = AnyEvent->timer (after => 1, interval => 1, cb => sub {
1637         eval {
1638             # todo: test for active connections instead (we can abort idle connections)
1639             if ($self->{conn_count} <= 0) {
1640                 undef $w;
1641                 $self->{end_cond}->send(1);
1642             }
1643         };
1644         warn $@ if $@;
1645     });
1646 }
1647
1648
1649 sub check_host_access {
1650     my ($self, $clientip) = @_;
1651
1652     $clientip = PVE::APIServer::Utils::normalize_v4_in_v6($clientip);
1653     my $cip = Net::IP->new($clientip);
1654
1655     if (!$cip) {
1656         $self->dprint("client IP not parsable: $@");
1657         return 0;
1658     }
1659
1660     my $match_allow = 0;
1661     my $match_deny = 0;
1662
1663     if ($self->{allow_from}) {
1664         foreach my $t (@{$self->{allow_from}}) {
1665             if ($t->overlaps($cip)) {
1666                 $match_allow = 1;
1667                 $self->dprint("client IP allowed: ". $t->prefix());
1668                 last;
1669             }
1670         }
1671     }
1672
1673     if ($self->{deny_from}) {
1674         foreach my $t (@{$self->{deny_from}}) {
1675             if ($t->overlaps($cip)) {
1676                 $self->dprint("client IP denied: ". $t->prefix());
1677                 $match_deny = 1;
1678                 last;
1679             }
1680         }
1681     }
1682
1683     if ($match_allow == $match_deny) {
1684         # match both allow and deny, or no match
1685         return $self->{policy} && $self->{policy} eq 'allow' ? 1 : 0;
1686     }
1687
1688     return $match_allow;
1689 }
1690
1691 sub accept_connections {
1692     my ($self) = @_;
1693
1694     my ($clientfh, $handle_creation);
1695     eval {
1696
1697         while ($clientfh = $self->accept()) {
1698
1699             my $reqstate = { keep_alive => $self->{keep_alive} };
1700
1701             # stop keep-alive when there are many open connections
1702             if ($self->{conn_count} + 1 >= $self->{max_conn_soft_limit}) {
1703                 $reqstate->{keep_alive} = 0;
1704             }
1705
1706             if (my $sin = getpeername($clientfh)) {
1707                 my ($pfamily, $pport, $phost) = PVE::Tools::unpack_sockaddr_in46($sin);
1708                 ($reqstate->{peer_port}, $reqstate->{peer_host}) = ($pport,  Socket::inet_ntop($pfamily, $phost));
1709             } else {
1710                 $self->dprint("getpeername failed: $!");
1711                 close($clientfh);
1712                 next;
1713             }
1714
1715             if (!$self->{trusted_env} && !$self->check_host_access($reqstate->{peer_host})) {
1716                 $self->dprint("ABORT request from $reqstate->{peer_host} - access denied");
1717                 $reqstate->{log}->{code} = 403;
1718                 $self->log_request($reqstate);
1719                 close($clientfh);
1720                 next;
1721             }
1722
1723             # Increment conn_count before creating new handle, since creation
1724             # triggers callbacks, which can potentialy decrement (e.g.
1725             # on_error) conn_count before AnyEvent::Handle->new() returns.
1726             $handle_creation = 1;
1727             $self->{conn_count}++;
1728             $reqstate->{hdl} = AnyEvent::Handle->new(
1729                 fh => $clientfh,
1730                 rbuf_max => 64*1024,
1731                 timeout => $self->{timeout},
1732                 linger => 0, # avoid problems with ssh - really needed ?
1733                 on_eof   => sub {
1734                     my ($hdl) = @_;
1735                     eval {
1736                         $self->log_aborted_request($reqstate);
1737                         $self->client_do_disconnect($reqstate);
1738                     };
1739                     if (my $err = $@) { syslog('err', $err); }
1740                 },
1741                 on_error => sub {
1742                     my ($hdl, $fatal, $message) = @_;
1743                     eval {
1744                         $self->log_aborted_request($reqstate, $message);
1745                         $self->client_do_disconnect($reqstate);
1746                     };
1747                     if (my $err = $@) { syslog('err', "$err"); }
1748                 },
1749                 ($self->{tls_ctx} ? (tls => "accept", tls_ctx => $self->{tls_ctx}) : ()));
1750             $handle_creation = 0;
1751
1752             $self->dprint("ACCEPT FH" .  $clientfh->fileno() . " CONN$self->{conn_count}");
1753
1754             $self->push_request_header($reqstate);
1755         }
1756     };
1757
1758     if (my $err = $@) {
1759         syslog('err', $err);
1760         $self->dprint("connection accept error: $err");
1761         close($clientfh);
1762         if ($handle_creation) {
1763             if ($self->{conn_count} <= 0) {
1764                 warn "connection count <= 0 not decrementing!\n";
1765             } else {
1766                 $self->{conn_count}--;
1767             }
1768         }
1769         $self->{end_loop} = 1;
1770     }
1771
1772     $self->wait_end_loop() if $self->{end_loop};
1773 }
1774
1775 # Note: We can't open log file in non-blocking mode and use AnyEvent::Handle,
1776 # because we write from multiple processes, and that would arbitrarily mix output
1777 # of all processes.
1778 sub open_access_log {
1779     my ($self, $filename) = @_;
1780
1781     my $old_mask = umask(0137);;
1782     my $logfh = IO::File->new($filename, ">>") ||
1783         die "unable to open log file '$filename' - $!\n";
1784     umask($old_mask);
1785
1786     $logfh->autoflush(1);
1787
1788     $self->{logfh} = $logfh;
1789 }
1790
1791 sub write_log {
1792     my ($self, $data) = @_;
1793
1794     return if !defined($self->{logfh}) || !$data;
1795
1796     my $res = $self->{logfh}->print($data);
1797
1798     if (!$res) {
1799         delete $self->{logfh};
1800         syslog('err', "error writing access log");
1801         $self->{end_loop} = 1; # terminate asap
1802     }
1803 }
1804
1805 sub atfork_handler {
1806     my ($self) = @_;
1807
1808     eval {
1809         # something else do to ?
1810         close($self->{socket});
1811     };
1812     warn $@ if $@;
1813 }
1814
1815 sub run {
1816     my ($self) = @_;
1817
1818     $self->{end_cond}->recv;
1819 }
1820
1821 sub new {
1822     my ($this, %args) = @_;
1823
1824     my $class = ref($this) || $this;
1825
1826     foreach my $req (qw(socket lockfh lockfile)) {
1827         die "misssing required argument '$req'" if !defined($args{$req});
1828     }
1829
1830     my $self = bless { %args }, $class;
1831
1832     $self->{cookie_name} //= 'PVEAuthCookie';
1833     $self->{apitoken_name} //= 'PVEAPIToken';
1834     $self->{base_uri} //= "/api2";
1835     $self->{dirs} //= {};
1836     $self->{title} //= 'API Inspector';
1837     $self->{compression} //= 1;
1838
1839     # formatter_config: we pass some configuration values to the Formatter
1840     $self->{formatter_config} = {};
1841     foreach my $p (qw(apitoken_name cookie_name base_uri title)) {
1842         $self->{formatter_config}->{$p} = $self->{$p};
1843     }
1844     $self->{formatter_config}->{csrfgen_func} =
1845         $self->can('generate_csrf_prevention_token');
1846
1847     # add default dirs which includes jquery and bootstrap
1848     my $jsbase = '/usr/share/javascript';
1849     add_dirs($self->{dirs}, '/js/' => "$jsbase/");
1850     # libjs-bootstrap uses symlinks for this, which we do not want to allow..
1851     my $glyphicons = '/usr/share/fonts/truetype/glyphicons/';
1852     add_dirs($self->{dirs}, '/js/bootstrap/fonts/' => "$glyphicons");
1853
1854     # init inotify
1855     PVE::INotify::inotify_init();
1856
1857     fh_nonblocking($self->{socket}, 1);
1858
1859     $self->{end_loop} = 0;
1860     $self->{conn_count} = 0;
1861     $self->{request_count} = 0;
1862     $self->{timeout} = 5 if !$self->{timeout};
1863     $self->{keep_alive} = 0 if !defined($self->{keep_alive});
1864     $self->{max_conn} = 800 if !$self->{max_conn};
1865     $self->{max_requests} = 8000 if !$self->{max_requests};
1866
1867     $self->{policy} = 'allow' if !$self->{policy};
1868
1869     $self->{end_cond} = AnyEvent->condvar;
1870
1871     if ($self->{ssl}) {
1872         my $ssl_defaults = {
1873             # Note: older versions are considered insecure, for example
1874             # search for "Poodle"-Attack
1875             method => 'any',
1876             sslv2 => 0,
1877             sslv3 => 0,
1878             cipher_list => 'ECDHE-ECDSA-AES256-GCM-SHA384:ECDHE-RSA-AES256-GCM-SHA384:ECDHE-ECDSA-CHACHA20-POLY1305:ECDHE-RSA-CHACHA20-POLY1305:ECDHE-ECDSA-AES128-GCM-SHA256:ECDHE-RSA-AES128-GCM-SHA256:ECDHE-ECDSA-AES256-SHA384:ECDHE-RSA-AES256-SHA384:ECDHE-ECDSA-AES128-SHA256:ECDHE-RSA-AES128-SHA256',
1879             honor_cipher_order => 1,
1880         };
1881
1882         # workaround until anyevent supports TLS 1.3 ciphersuites directly
1883         my $ciphersuites = delete $self->{ssl}->{ciphersuites};
1884
1885         foreach my $k (keys %$ssl_defaults) {
1886             $self->{ssl}->{$k} //= $ssl_defaults->{$k};
1887         }
1888
1889         if (!defined($self->{ssl}->{dh_file})) {
1890             $self->{ssl}->{dh} = 'skip2048';
1891         }
1892
1893         my $tls_ctx_flags = 0;
1894         $tls_ctx_flags |= &Net::SSLeay::OP_NO_COMPRESSION;
1895         $tls_ctx_flags |= &Net::SSLeay::OP_SINGLE_ECDH_USE;
1896         $tls_ctx_flags |= &Net::SSLeay::OP_SINGLE_DH_USE;
1897         $tls_ctx_flags |= &Net::SSLeay::OP_NO_RENEGOTIATION;
1898         if (delete $self->{ssl}->{honor_cipher_order}) {
1899             $tls_ctx_flags |= &Net::SSLeay::OP_CIPHER_SERVER_PREFERENCE;
1900         }
1901         # workaround until anyevent supports disabling TLS 1.3 directly
1902         if (exists($self->{ssl}->{tlsv1_3}) && !$self->{ssl}->{tlsv1_3}) {
1903             $tls_ctx_flags |= &Net::SSLeay::OP_NO_TLSv1_3;
1904         }
1905
1906
1907         $self->{tls_ctx} = AnyEvent::TLS->new(%{$self->{ssl}});
1908         Net::SSLeay::CTX_set_options($self->{tls_ctx}->{ctx}, $tls_ctx_flags);
1909         if (defined($ciphersuites)) {
1910             warn "Failed to set TLS 1.3 ciphersuites '$ciphersuites'\n"
1911                 if !Net::SSLeay::CTX_set_ciphersuites($self->{tls_ctx}->{ctx}, $ciphersuites);
1912         }
1913     }
1914
1915     if ($self->{spiceproxy}) {
1916         $known_methods = { CONNECT => 1 };
1917     }
1918
1919     $self->open_access_log($self->{logfile}) if $self->{logfile};
1920
1921     $self->{max_conn_soft_limit} = $self->{max_conn} > 100 ? $self->{max_conn} - 20 : $self->{max_conn};
1922
1923     $self->{socket_watch} = AnyEvent->io(fh => $self->{socket}, poll => 'r', cb => sub {
1924         eval {
1925             if ($self->{conn_count} >= $self->{max_conn}) {
1926                 my $w; $w = AnyEvent->timer (after => 1, interval => 1, cb => sub {
1927                     if ($self->{conn_count} < $self->{max_conn}) {
1928                         undef $w;
1929                         $self->accept_connections();
1930                     }
1931                 });
1932             } else {
1933                 $self->accept_connections();
1934             }
1935         };
1936         warn $@ if $@;
1937     });
1938
1939     $self->{term_watch} = AnyEvent->signal(signal => "TERM", cb => sub {
1940         undef $self->{term_watch};
1941         $self->wait_end_loop();
1942     });
1943
1944     $self->{quit_watch} = AnyEvent->signal(signal => "QUIT", cb => sub {
1945         undef $self->{quit_watch};
1946         $self->wait_end_loop();
1947     });
1948
1949     $self->{inotify_poll} = AnyEvent->timer(after => 5, interval => 5, cb => sub {
1950         PVE::INotify::poll(); # read inotify events
1951     });
1952
1953     return $self;
1954 }
1955
1956 # static helper to add directory including all subdirs
1957 # This can be used to setup $self->{dirs}
1958 sub add_dirs {
1959     my ($result_hash, $alias, $subdir) = @_;
1960
1961     $result_hash->{$alias} = $subdir;
1962
1963     my $wanted = sub {
1964         my $dir = $File::Find::dir;
1965         if ($dir =~m!^$subdir(.*)$!) {
1966             my $name = "$alias$1/";
1967             $result_hash->{$name} = "$dir/";
1968         }
1969     };
1970
1971     find({wanted => $wanted, follow => 0, no_chdir => 1}, $subdir);
1972 }
1973
1974 # abstract functions - subclass should overwrite/implement them
1975
1976 sub verify_spice_connect_url {
1977     my ($self, $connect_str) = @_;
1978
1979     die "implement me";
1980
1981     #return ($vmid, $node, $port);
1982 }
1983
1984 # formatters can call this when the generate a new page
1985 sub generate_csrf_prevention_token {
1986     my ($username) = @_;
1987
1988     return undef; # do nothing by default
1989 }
1990
1991 sub auth_handler {
1992     my ($self, $method, $rel_uri, $ticket, $token, $api_token, $peer_host) = @_;
1993
1994     die "implement me";
1995
1996     # return {
1997     #    ticket => $ticket,
1998     #    token => $token,
1999     #    userid => $username,
2000     #    age => $age,
2001     #    isUpload => $isUpload,
2002     #    api_token => $api_token,
2003     #};
2004 }
2005
2006 sub rest_handler {
2007     my ($self, $clientip, $method, $rel_uri, $auth, $params, $format) = @_;
2008
2009     # please do not raise exceptions here (always return a result).
2010
2011     return {
2012         status => HTTP_NOT_IMPLEMENTED,
2013         message => "Method '$method $rel_uri' not implemented",
2014     };
2015
2016     # this should return the following properties, which
2017     # are then passed to the Formatter
2018
2019     # status: HTTP status code
2020     # message: Error message
2021     # errors: more detailed error hash (per parameter)
2022     # info: reference to JSON schema definition - useful to format output
2023     # data: result data
2024
2025     # total: additional info passed to output
2026     # changes:  additional info passed to output
2027
2028     # if you want to proxy the request to another node return this
2029     # { proxy => $remip, proxynode => $node, proxy_params => $params };
2030
2031     # to pass the request to the local priviledged daemon use:
2032     # { proxy => 'localhost' , proxy_params => $params };
2033
2034     # to download aspecific file use:
2035     # { download => "/path/to/file" };
2036 }
2037
2038 sub check_cert_fingerprint {
2039     my ($self, $cert) = @_;
2040
2041      die "implement me";
2042  }
2043
2044 sub initialize_cert_cache {
2045     my ($self, $node) = @_;
2046
2047     die "implement me";
2048 }
2049
2050 sub remote_node_ip {
2051     my ($self, $node) = @_;
2052
2053     die "implement me";
2054
2055     # return $remip;
2056 }
2057
2058
2059 1;