src/PVE/APIServer/AnyEvent.pm

   1 package PVE::APIServer::AnyEvent;
   2
   3 # Note 1: interactions with Crypt::OpenSSL::RSA
   4 #
   5 # Some handlers (auth_handler) use Crypt::OpenSSL::RSA, which seems to
   6 # set the openssl error variable. We need to clear that here, else
   7 # AnyEvent::TLS aborts the connection.
   8 # Net::SSLeay::ERR_clear_error();
   9
  10 use strict;
  11 use warnings;
  12
  13 use AnyEvent::HTTP;
  14 use AnyEvent::Handle;
  15 use AnyEvent::IO;
  16 use AnyEvent::Socket;
  17 # use AnyEvent::Strict; # only use this for debugging
  18 use AnyEvent::TLS;
  19 use AnyEvent::Util qw(guard fh_nonblocking WSAEWOULDBLOCK WSAEINPROGRESS);
  20
  21 use Compress::Zlib;
  22 use Digest::MD5;
  23 use Digest::SHA;
  24 use Encode;
  25 use Fcntl ();
  26 use Fcntl;
  27 use File::Find;
  28 use File::stat qw();
  29 use IO::File;
  30 use MIME::Base64;
  31 use Net::SSLeay;
  32 use POSIX qw(strftime EINTR EAGAIN);
  33 use Socket qw(IPPROTO_TCP TCP_NODELAY SOMAXCONN);
  34 use Time::HiRes qw(usleep ualarm gettimeofday tv_interval);
  35
  36 #use Data::Dumper; # FIXME: remove, just use: print to_json([$var], {pretty => 1}) ."\n";
  37 use HTTP::Date;
  38 use HTTP::Headers;
  39 use HTTP::Request;
  40 use HTTP::Response;
  41 use HTTP::Status qw(:constants);
  42 use JSON;
  43 use Net::IP;
  44 use URI::Escape;
  45 use URI;
  46
  47 use PVE::INotify;
  48 use PVE::SafeSyslog;
  49 use PVE::Tools qw(trim);
  50
  51 use PVE::APIServer::Formatter;
  52 use PVE::APIServer::Utils;
  53
  54 my $limit_max_headers = 64;
  55 my $limit_max_header_size = 8*1024;
  56 my $limit_max_post = 64*1024;
  57
  58 my $known_methods = {
  59     GET => 1,
  60     POST => 1,
  61     PUT => 1,
  62     DELETE => 1,
  63 };
  64
  65 my $split_abs_uri = sub {
  66     my ($abs_uri, $base_uri) = @_;
  67
  68     my ($format, $rel_uri) = $abs_uri =~ m/^\Q$base_uri\E\/+([a-z][a-z0-9]+)(\/.*)?$/;
  69     $rel_uri = '/' if !$rel_uri;
  70
  71     return wantarray ? ($rel_uri, $format) : $rel_uri;
  72 };
  73
  74 sub dprint {
  75     my ($self, $message) = @_;
  76
  77     return if !$self->{debug};
  78
  79     my ($pkg, $pkgfile, $line, $sub) = caller(1);
  80     $sub =~ s/^(?:.+::)+//;
  81     print "worker[$$]: $pkg +$line: $sub: $message\n";
  82 }
  83
  84 sub log_request {
  85     my ($self, $reqstate) = @_;
  86
  87     my $loginfo = $reqstate->{log};
  88
  89     # like apache2 common log format
  90     # LogFormat "%h %l %u %t \"%r\" %>s %b \"%{Referer}i\" \"%{User-agent}i\""
  91
  92     return if $loginfo->{written}; # avoid duplicate logs
  93     $loginfo->{written} = 1;
  94
  95     my $peerip = $reqstate->{peer_host} || '-';
  96     my $userid = $loginfo->{userid} || '-';
  97     my $content_length = defined($loginfo->{content_length}) ? $loginfo->{content_length} : '-';
  98     my $code =  $loginfo->{code} || 500;
  99     my $requestline = $loginfo->{requestline} || '-';
 100     my $timestr = strftime("%d/%m/%Y:%H:%M:%S %z", localtime());
 101
 102     my $msg = "$peerip - $userid [$timestr] \"$requestline\" $code $content_length\n";
 103
 104     $self->write_log($msg);
 105 }
 106
 107 sub log_aborted_request {
 108     my ($self, $reqstate, $error) = @_;
 109
 110     my $r = $reqstate->{request};
 111     return if !$r; # no active request
 112
 113     if ($error) {
 114         syslog("err", "problem with client $reqstate->{peer_host}; $error");
 115     }
 116
 117     $self->log_request($reqstate);
 118 }
 119
 120 sub cleanup_reqstate {
 121     my ($reqstate, $deletetmpfile) = @_;
 122
 123     delete $reqstate->{log};
 124     delete $reqstate->{request};
 125     delete $reqstate->{proto};
 126     delete $reqstate->{accept_gzip};
 127     delete $reqstate->{starttime};
 128
 129     if ($reqstate->{tmpfilename}) {
 130         unlink $reqstate->{tmpfilename} if $deletetmpfile;
 131         delete $reqstate->{tmpfilename};
 132     }
 133 }
 134
 135 sub client_do_disconnect {
 136     my ($self, $reqstate) = @_;
 137
 138     cleanup_reqstate($reqstate, 1);
 139
 140     my $shutdown_hdl = sub {
 141         my $hdl = shift;
 142
 143         shutdown($hdl->{fh}, 1);
 144         # clear all handlers
 145         $hdl->on_drain(undef);
 146         $hdl->on_read(undef);
 147         $hdl->on_eof(undef);
 148     };
 149
 150     if (my $proxyhdl = delete $reqstate->{proxyhdl}) {
 151         &$shutdown_hdl($proxyhdl)
 152                 if !$proxyhdl->{block_disconnect};
 153     }
 154
 155     my $hdl = delete $reqstate->{hdl};
 156
 157     if (!$hdl) {
 158         syslog('err', "detected empty handle");
 159         return;
 160     }
 161
 162     $self->dprint("close connection $hdl");
 163
 164     &$shutdown_hdl($hdl);
 165
 166     warn "connection count <= 0!\n" if $self->{conn_count} <= 0;
 167
 168     $self->{conn_count}--;
 169
 170     $self->dprint("CLOSE FH" .  $hdl->{fh}->fileno() . " CONN$self->{conn_count}");
 171 }
 172
 173 sub finish_response {
 174     my ($self, $reqstate) = @_;
 175
 176     cleanup_reqstate($reqstate, 0);
 177
 178     my $hdl = $reqstate->{hdl};
 179     return if !$hdl; # already disconnected
 180
 181     if (!$self->{end_loop} && $reqstate->{keep_alive} > 0) {
 182         # print "KEEPALIVE $reqstate->{keep_alive}\n" if $self->{debug};
 183         $hdl->on_read(sub {
 184             eval { $self->push_request_header($reqstate); };
 185             warn $@ if $@;
 186         });
 187     } else {
 188         $hdl->on_drain (sub {
 189             eval {
 190                 $self->client_do_disconnect($reqstate);
 191             };
 192             warn $@ if $@;
 193         });
 194     }
 195 }
 196
 197 sub response_stream {
 198     my ($self, $reqstate, $stream_fh) = @_;
 199
 200     # disable timeout, we don't know how big the data is
 201     $reqstate->{hdl}->timeout(0);
 202
 203     my $buf_size = 4*1024*1024;
 204
 205     my $on_read;
 206     $on_read = sub {
 207         my ($hdl) = @_;
 208         my $reqhdl = $reqstate->{hdl};
 209         return if !$reqhdl;
 210
 211         my $wbuf_len = length($reqhdl->{wbuf});
 212         my $rbuf_len = length($hdl->{rbuf});
 213         # TODO: Take into account $reqhdl->{wbuf_max} ? Right now
 214         # that's unbounded, so just assume $buf_size
 215         my $to_read = $buf_size - $wbuf_len;
 216         $to_read = $rbuf_len if $rbuf_len < $to_read;
 217         if ($to_read > 0) {
 218             my $data = substr($hdl->{rbuf}, 0, $to_read, '');
 219             $reqhdl->push_write($data);
 220             $rbuf_len -= $to_read;
 221         } elsif ($hdl->{_eof}) {
 222             # workaround: AnyEvent gives us a fake EPIPE if we don't consume
 223             # any data when called at EOF, so unregister ourselves - data is
 224             # flushed by on_eof anyway
 225             # see: https://sources.debian.org/src/libanyevent-perl/7.170-2/lib/AnyEvent/Handle.pm/#L1329
 226             $hdl->on_read();
 227             return;
 228         }
 229
 230         # apply backpressure so we don't accept any more data into
 231         # buffer if the client isn't downloading fast enough
 232         # note: read_size can double upon read, and we also need to
 233         # account for one more read after start_read, so *4
 234         if ($rbuf_len + $hdl->{read_size}*4 > $buf_size) {
 235             # stop reading until write buffer is empty
 236             $hdl->on_read();
 237             my $prev_on_drain = $reqhdl->{on_drain};
 238             $reqhdl->on_drain(sub {
 239                 my ($wrhdl) = @_;
 240                 # on_drain called because write buffer is empty, continue reading
 241                 $hdl->on_read($on_read);
 242                 if ($prev_on_drain) {
 243                     $wrhdl->on_drain($prev_on_drain);
 244                     $prev_on_drain->($wrhdl);
 245                 }
 246             });
 247         }
 248     };
 249
 250     $reqstate->{proxyhdl} = AnyEvent::Handle->new(
 251         fh => $stream_fh,
 252         rbuf_max => $buf_size,
 253         timeout => 0,
 254         on_read => $on_read,
 255         on_eof => sub {
 256             my ($hdl) = @_;
 257             eval {
 258                 if (my $reqhdl = $reqstate->{hdl}) {
 259                     $self->log_aborted_request($reqstate);
 260                     # write out any remaining data
 261                     $reqhdl->push_write($hdl->{rbuf}) if length($hdl->{rbuf}) > 0;
 262                     $hdl->{rbuf} = "";
 263                     $reqhdl->push_shutdown();
 264                     $self->finish_response($reqstate);
 265                 }
 266             };
 267             if (my $err = $@) { syslog('err', "$err"); }
 268             $on_read = undef;
 269         },
 270         on_error => sub {
 271             my ($hdl, $fatal, $message) = @_;
 272             eval {
 273                 $self->log_aborted_request($reqstate, $message);
 274                 $self->client_do_disconnect($reqstate);
 275             };
 276             if (my $err = $@) { syslog('err', "$err"); }
 277             $on_read = undef;
 278         },
 279     );
 280 }
 281
 282 sub response {
 283     my ($self, $reqstate, $resp, $mtime, $nocomp, $delay, $stream_fh) = @_;
 284
 285     #print "$$: send response: " . Dumper($resp);
 286
 287     # activate timeout
 288     $reqstate->{hdl}->timeout_reset();
 289     $reqstate->{hdl}->timeout($self->{timeout});
 290
 291     $nocomp = 1 if !$self->{compression};
 292     $nocomp = 1 if !$reqstate->{accept_gzip};
 293
 294     my $code = $resp->code;
 295     my $msg = $resp->message || HTTP::Status::status_message($code);
 296     my $content = $resp->content;
 297
 298     # multiline mode only checks \n for $, so explicitly check for any \n or \r afterwards
 299     ($msg) = $msg =~ m/^(.*)$/m;
 300     if ($msg =~ /[\r\n]/) {
 301         $code = 400; # bad request from user
 302         $msg = HTTP::Status::status_message($code);
 303         $content = '';
 304     }
 305
 306     if ($code =~ /^(1\d\d|[23]04)$/) {
 307         # make sure informational, no content and not modified response send no content
 308         $content = "";
 309     }
 310
 311     $reqstate->{keep_alive} = 0 if ($code >= 400) || $self->{end_loop};
 312
 313     $reqstate->{log}->{code} = $code;
 314
 315     my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.0';
 316     my $res = "$proto $code $msg\015\012";
 317
 318     my $ctime = time();
 319     my $date = HTTP::Date::time2str($ctime);
 320     $resp->header('Date' => $date);
 321     if ($mtime) {
 322         $resp->header('Last-Modified' => HTTP::Date::time2str($mtime));
 323     } else {
 324         $resp->header('Expires' => $date);
 325         $resp->header('Cache-Control' => "max-age=0");
 326         $resp->header("Pragma", "no-cache");
 327     }
 328
 329     $resp->header('Server' => "pve-api-daemon/3.0");
 330
 331     my $content_length;
 332     if ($content && !$stream_fh) {
 333
 334         $content_length = length($content);
 335
 336         if (!$nocomp && ($content_length > 1024)) {
 337             my $comp = Compress::Zlib::memGzip($content);
 338             $resp->header('Content-Encoding', 'gzip');
 339             $content = $comp;
 340             $content_length = length($content);
 341         }
 342         $resp->header("Content-Length" => $content_length);
 343         $reqstate->{log}->{content_length} = $content_length;
 344
 345     } else {
 346         $resp->remove_header("Content-Length");
 347     }
 348
 349     if ($reqstate->{keep_alive} > 0) {
 350         $resp->push_header('Connection' => 'Keep-Alive');
 351     } else {
 352         $resp->header('Connection' => 'close');
 353     }
 354
 355     $res .= $resp->headers_as_string("\015\012");
 356     #print "SEND(without content) $res\n" if $self->{debug};
 357
 358     $res .= "\015\012";
 359     $res .= $content if $content && !$stream_fh;
 360
 361     $self->log_request($reqstate, $reqstate->{request});
 362
 363     if ($stream_fh) {
 364         # write headers and preamble...
 365         $reqstate->{hdl}->push_write($res);
 366         # ...then stream data via an AnyEvent::Handle
 367         $self->response_stream($reqstate, $stream_fh);
 368     } elsif ($delay && $delay > 0) {
 369         my $w; $w = AnyEvent->timer(after => $delay, cb => sub {
 370             undef $w; # delete reference
 371             return if !$reqstate->{hdl}; # already disconnected
 372             $reqstate->{hdl}->push_write($res);
 373             $self->finish_response($reqstate);
 374         });
 375     } else {
 376         $reqstate->{hdl}->push_write($res);
 377         $self->finish_response($reqstate);
 378     }
 379 }
 380
 381 sub error {
 382     my ($self, $reqstate, $code, $msg, $hdr, $content) = @_;
 383
 384     eval {
 385         my $resp = HTTP::Response->new($code, $msg, $hdr, $content);
 386         $self->response($reqstate, $resp);
 387     };
 388     warn $@ if $@;
 389 }
 390
 391 my $file_extension_info = {
 392     css   => { ct => 'text/css' },
 393     html  => { ct => 'text/html' },
 394     js    => { ct => 'application/javascript' },
 395     json  => { ct => 'application/json' },
 396     map   => { ct => 'application/json' },
 397     png   => { ct => 'image/png' , nocomp => 1 },
 398     ico   => { ct => 'image/x-icon', nocomp => 1},
 399     gif   => { ct => 'image/gif', nocomp => 1},
 400     svg   => { ct => 'image/svg+xml' },
 401     jar   => { ct => 'application/java-archive', nocomp => 1},
 402     woff  => { ct => 'application/font-woff', nocomp => 1},
 403     woff2 => { ct => 'application/font-woff2', nocomp => 1},
 404     ttf   => { ct => 'application/font-snft', nocomp => 1},
 405     pdf   => { ct => 'application/pdf', nocomp => 1},
 406     epub  => { ct => 'application/epub+zip', nocomp => 1},
 407     mp3   => { ct => 'audio/mpeg', nocomp => 1},
 408     oga   => { ct => 'audio/ogg', nocomp => 1},
 409     tgz   => { ct => 'application/x-compressed-tar', nocomp => 1},
 410 };
 411
 412 sub send_file_start {
 413     my ($self, $reqstate, $download) = @_;
 414
 415     eval {
 416         # print "SEND FILE $filename\n";
 417         # Note: aio_load() this is not really async unless we use IO::AIO!
 418         eval {
 419
 420             my $r = $reqstate->{request};
 421
 422             my $fh;
 423             my $nocomp;
 424             my $mime;
 425
 426             if (ref($download) eq 'HASH') {
 427                 $mime = $download->{'content-type'};
 428                 my $encoding = $download->{'content-encoding'};
 429                 my $disposition = $download->{'content-disposition'};
 430
 431                 if ($download->{path} && $download->{stream} &&
 432                     $reqstate->{request}->header('PVEDisableProxy'))
 433                 {
 434                     # avoid double stream from a file, let the proxy handle it
 435                     die "internal error: file proxy streaming only available for pvedaemon\n"
 436                         if !$self->{trusted_env};
 437                     my $header = HTTP::Headers->new(
 438                         pvestreamfile => $download->{path},
 439                         Content_Type => $mime,
 440                     );
 441                     $header->header('Content-Encoding' => $encoding) if defined($encoding);
 442                     $header->header('Content-Disposition' => $disposition) if defined($disposition);
 443                     # we need some data so Content-Length gets set correctly and
 444                     # the proxy doesn't wait for more data - place a canary
 445                     my $resp = HTTP::Response->new(200, "OK", $header, "error canary");
 446                     $self->response($reqstate, $resp);
 447                     return;
 448                 }
 449
 450                 if (!($fh = $download->{fh})) {
 451                     my $path = $download->{path};
 452                     die "internal error: {download} returned but neither fh not path given\n"
 453                         if !$path;
 454                     sysopen($fh, "$path", O_NONBLOCK | O_RDONLY)
 455                         or die "open stream path '$path' for reading failed: $!\n";
 456                 }
 457
 458                 if ($download->{stream}) {
 459                     my $header = HTTP::Headers->new(Content_Type => $mime);
 460                     $header->header('Content-Encoding' => $encoding) if defined($encoding);
 461                     $header->header('Content-Disposition' => $disposition) if defined($disposition);
 462                     my $resp = HTTP::Response->new(200, "OK", $header);
 463                     $self->response($reqstate, $resp, undef, 1, 0, $fh);
 464                     return;
 465                 }
 466             } else {
 467                 my $filename = $download;
 468                 $fh = IO::File->new($filename, '<') ||
 469                     die "unable to open file '$filename' - $!\n";
 470
 471                 my ($ext) = $filename =~ m/\.([^.]*)$/;
 472                 my $ext_info = $file_extension_info->{$ext};
 473
 474                 die "unable to detect content type" if !$ext_info;
 475                 $mime = $ext_info->{ct};
 476                 $nocomp = $ext_info->{nocomp};
 477             }
 478
 479             my $stat = File::stat::stat($fh) ||
 480                 die "$!\n";
 481
 482             my $mtime = $stat->mtime;
 483
 484             if (my $ifmod = $r->header('if-modified-since')) {
 485                 my $iftime = HTTP::Date::str2time($ifmod);
 486                 if ($mtime <= $iftime) {
 487                     my $resp = HTTP::Response->new(304, "NOT MODIFIED");
 488                     $self->response($reqstate, $resp, $mtime);
 489                     return;
 490                 }
 491             }
 492
 493             my $data;
 494             my $len = sysread($fh, $data,  $stat->size);
 495             die "got short file\n" if !defined($len) || $len != $stat->size;
 496
 497             my $header = HTTP::Headers->new(Content_Type => $mime);
 498             my $resp = HTTP::Response->new(200, "OK", $header, $data);
 499             $self->response($reqstate, $resp, $mtime, $nocomp);
 500         };
 501         if (my $err = $@) {
 502             $self->error($reqstate, 501, $err);
 503         }
 504     };
 505
 506     warn $@ if $@;
 507 }
 508
 509 sub websocket_proxy {
 510     my ($self, $reqstate, $wsaccept, $wsproto, $param) = @_;
 511
 512     eval {
 513         my $remhost;
 514         my $remport;
 515
 516         my $max_payload_size = 128*1024;
 517
 518         if ($param->{port}) {
 519             $remhost = 'localhost';
 520             $remport = $param->{port};
 521         } elsif ($param->{socket}) {
 522             $remhost = 'unix/';
 523             $remport = $param->{socket};
 524         } else {
 525             die "websocket_proxy: missing port or socket\n";
 526         }
 527
 528         my $encode = sub {
 529             my ($data, $opcode) = @_;
 530
 531             my $string;
 532             my $payload;
 533
 534             $string = $opcode ? $opcode : "\x82"; # binary frame
 535             $payload = $$data;
 536
 537             my $payload_len = length($payload);
 538             if ($payload_len <= 125) {
 539                 $string .= pack 'C', $payload_len;
 540             } elsif ($payload_len <= 0xffff) {
 541                 $string .= pack 'C', 126;
 542                 $string .= pack 'n', $payload_len;
 543             } else {
 544                 $string .= pack 'C', 127;
 545                 $string .= pack 'Q>', $payload_len;
 546             }
 547             $string .= $payload;
 548             return $string;
 549         };
 550
 551         tcp_connect $remhost, $remport, sub {
 552             my ($fh) = @_
 553                 or die "connect to '$remhost:$remport' failed: $!";
 554
 555             $self->dprint("CONNECTed to '$remhost:$remport'");
 556
 557             $reqstate->{proxyhdl} = AnyEvent::Handle->new(
 558                 fh => $fh,
 559                 rbuf_max => $max_payload_size,
 560                 wbuf_max => $max_payload_size*5,
 561                 timeout => 5,
 562                 on_eof => sub {
 563                     my ($hdl) = @_;
 564                     eval {
 565                         $self->log_aborted_request($reqstate);
 566                         $self->client_do_disconnect($reqstate);
 567                     };
 568                     if (my $err = $@) { syslog('err', $err); }
 569                 },
 570                 on_error => sub {
 571                     my ($hdl, $fatal, $message) = @_;
 572                     eval {
 573                         $self->log_aborted_request($reqstate, $message);
 574                         $self->client_do_disconnect($reqstate);
 575                     };
 576                     if (my $err = $@) { syslog('err', "$err"); }
 577                 });
 578
 579             my $proxyhdlreader = sub {
 580                 my ($hdl) = @_;
 581
 582                 my $len = length($hdl->{rbuf});
 583                 my $data = substr($hdl->{rbuf}, 0, $len > $max_payload_size ? $max_payload_size : $len, '');
 584
 585                 my $string = $encode->(\$data);
 586
 587                 $reqstate->{hdl}->push_write($string) if $reqstate->{hdl};
 588             };
 589
 590             my $hdlreader = sub {
 591                 my ($hdl) = @_;
 592
 593                 while (my $len = length($hdl->{rbuf})) {
 594                     return if $len < 2;
 595
 596                     my $hdr = unpack('C', substr($hdl->{rbuf}, 0, 1));
 597                     my $opcode = $hdr & 0b00001111;
 598                     my $fin = $hdr & 0b10000000;
 599
 600                     die "received fragmented websocket frame\n" if !$fin;
 601
 602                     my $rsv = $hdr & 0b01110000;
 603                     die "received websocket frame with RSV flags\n" if $rsv;
 604
 605                     my $payload_len = unpack 'C', substr($hdl->{rbuf}, 1, 1);
 606
 607                     my $masked = $payload_len & 0b10000000;
 608                     die "received unmasked websocket frame from client\n" if !$masked;
 609
 610                     my $offset = 2;
 611                     $payload_len = $payload_len & 0b01111111;
 612                     if ($payload_len == 126) {
 613                         return if $len < 4;
 614                         $payload_len = unpack('n', substr($hdl->{rbuf}, $offset, 2));
 615                         $offset += 2;
 616                     } elsif ($payload_len == 127) {
 617                         return if $len < 10;
 618                         $payload_len = unpack('Q>', substr($hdl->{rbuf}, $offset, 8));
 619                         $offset += 8;
 620                     }
 621
 622                     die "received too large websocket frame (len = $payload_len)\n"
 623                         if ($payload_len > $max_payload_size) || ($payload_len < 0);
 624
 625                     return if $len < ($offset + 4 + $payload_len);
 626
 627                     my $data = substr($hdl->{rbuf}, 0, $offset + 4 + $payload_len, ''); # now consume data
 628
 629                     my $mask = substr($data, $offset, 4);
 630                     $offset += 4;
 631
 632                     my $payload = substr($data, $offset, $payload_len);
 633
 634                     # NULL-mask might be used over TLS, skip to increase performance
 635                     if ($mask ne pack('N', 0)) {
 636                         # repeat 4 byte mask to payload length + up to 4 byte
 637                         $mask = $mask x (int($payload_len / 4) + 1);
 638                         # truncate mask to payload length
 639                         substr($mask, $payload_len) = "";
 640                         # (un-)apply mask
 641                         $payload ^= $mask;
 642                     }
 643
 644                     if ($opcode == 1 || $opcode == 2) {
 645                         $reqstate->{proxyhdl}->push_write($payload) if $reqstate->{proxyhdl};
 646                     } elsif ($opcode == 8) {
 647                         my $statuscode = unpack ("n", $payload);
 648                         $self->dprint("websocket received close. status code: '$statuscode'");
 649                         if (my $proxyhdl = $reqstate->{proxyhdl}) {
 650                             $proxyhdl->{block_disconnect} = 1 if length $proxyhdl->{wbuf};
 651
 652                             $proxyhdl->push_shutdown();
 653                         }
 654                         $hdl->push_shutdown();
 655                     } elsif ($opcode == 9) {
 656                         # ping received, schedule pong
 657                         $reqstate->{hdl}->push_write($encode->(\$payload, "\x8A")) if $reqstate->{hdl};
 658                     } elsif ($opcode == 0xA) {
 659                         # pong received, continue
 660                     } else {
 661                         die "received unhandled websocket opcode $opcode\n";
 662                     }
 663                 }
 664             };
 665
 666             my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.1';
 667
 668             $reqstate->{proxyhdl}->timeout(0);
 669             $reqstate->{proxyhdl}->on_read($proxyhdlreader);
 670             $reqstate->{hdl}->on_read($hdlreader);
 671
 672             # todo: use stop_read/start_read if write buffer grows to much
 673
 674             # FIXME: remove protocol in PVE/PMG 8.x
 675             #
 676             # for backwards, compatibility,  we have to reply with the websocket
 677             # subprotocol from the request
 678             my $res = "$proto 101 Switching Protocols\015\012" .
 679                 "Upgrade: websocket\015\012" .
 680                 "Connection: upgrade\015\012" .
 681                 "Sec-WebSocket-Accept: $wsaccept\015\012" .
 682                 ($wsproto ne "" ? "Sec-WebSocket-Protocol: $wsproto\015\012" : "") .
 683                 "\015\012";
 684
 685             $self->dprint($res);
 686
 687             $reqstate->{hdl}->push_write($res);
 688
 689             # log early
 690             $reqstate->{log}->{code} = 101;
 691             $self->log_request($reqstate);
 692         };
 693
 694     };
 695     if (my $err = $@) {
 696         warn $err;
 697         $self->log_aborted_request($reqstate, $err);
 698         $self->client_do_disconnect($reqstate);
 699     }
 700 }
 701
 702 sub proxy_request {
 703     my ($self, $reqstate, $clientip, $host, $node, $method, $uri, $auth, $params) = @_;
 704
 705     eval {
 706         my $target;
 707         my $keep_alive = 1;
 708
 709         # stringify URI object and verify it starts with a slash
 710         $uri = "$uri";
 711         if ($uri !~ m@^/@) {
 712             $self->error($reqstate, 400, "invalid proxy uri");
 713             return;
 714         }
 715
 716         my $may_stream_file;
 717         if ($host eq 'localhost') {
 718             $target = "http://$host:85$uri";
 719             # keep alive for localhost is not worth (connection setup is about 0.2ms)
 720             $keep_alive = 0;
 721             $may_stream_file = 1;
 722         } elsif (Net::IP::ip_is_ipv6($host)) {
 723             $target = "https://[$host]:8006$uri";
 724         } else {
 725             $target = "https://$host:8006$uri";
 726         }
 727
 728         my $headers = {
 729             PVEDisableProxy => 'true',
 730             PVEClientIP => $clientip,
 731         };
 732
 733         $headers->{'cookie'} = PVE::APIServer::Formatter::create_auth_cookie($auth->{ticket}, $self->{cookie_name})
 734             if $auth->{ticket};
 735         $headers->{'Authorization'} = PVE::APIServer::Formatter::create_auth_header($auth->{api_token}, $self->{apitoken_name})
 736             if $auth->{api_token};
 737         $headers->{'CSRFPreventionToken'} = $auth->{token}
 738             if $auth->{token};
 739         $headers->{'Accept-Encoding'} = 'gzip' if ($reqstate->{accept_gzip} && $self->{compression});
 740
 741         if (defined(my $host = $reqstate->{request}->header('Host'))) {
 742             $headers->{Host} = $host;
 743         }
 744
 745         my $content;
 746
 747         if  ($method eq 'POST' || $method eq 'PUT') {
 748             $headers->{'Content-Type'} = 'application/x-www-form-urlencoded';
 749             # use URI object to format application/x-www-form-urlencoded content.
 750             my $url = URI->new('http:');
 751             $url->query_form(%$params);
 752             $content = $url->query;
 753             if (defined($content)) {
 754                 $headers->{'Content-Length'} = length($content);
 755             }
 756         }
 757
 758         my $tls = {
 759             # TLS 1.x only, with certificate pinning
 760             method => 'any',
 761             sslv2 => 0,
 762             sslv3 => 0,
 763             verify => 1,
 764             verify_cb => sub {
 765                 my (undef, undef, undef, $depth, undef, undef, $cert) = @_;
 766                 # we don't care about intermediate or root certificates
 767                 return 1 if $depth != 0;
 768                 # check server certificate against cache of pinned FPs
 769                 return $self->check_cert_fingerprint($cert);
 770             },
 771         };
 772
 773         # load and cache cert fingerprint if first time we proxy to this node
 774         $self->initialize_cert_cache($node);
 775
 776         my $w; $w = http_request(
 777             $method => $target,
 778             headers => $headers,
 779             timeout => 30,
 780             recurse => 0,
 781             proxy => undef, # avoid use of $ENV{HTTP_PROXY}
 782             keepalive => $keep_alive,
 783             body => $content,
 784             tls_ctx => AnyEvent::TLS->new(%{$tls}),
 785             sub {
 786                 my ($body, $hdr) = @_;
 787
 788                 undef $w;
 789
 790                 if (!$reqstate->{hdl}) {
 791                     warn "proxy detected vanished client connection\n";
 792                     return;
 793                 }
 794
 795                 eval {
 796                     my $code = delete $hdr->{Status};
 797                     my $msg = delete $hdr->{Reason};
 798                     my $stream = delete $hdr->{pvestreamfile};
 799                     delete $hdr->{URL};
 800                     delete $hdr->{HTTPVersion};
 801                     my $header = HTTP::Headers->new(%$hdr);
 802                     if (my $location = $header->header('Location')) {
 803                         $location =~ s|^http://localhost:85||;
 804                         $header->header(Location => $location);
 805                     }
 806                     if ($stream) {
 807                         if (!$may_stream_file) {
 808                             $self->error($reqstate, 403, 'streaming denied');
 809                             return;
 810                         }
 811                         sysopen(my $fh, "$stream", O_NONBLOCK | O_RDONLY)
 812                             or die "open stream path '$stream' for forwarding failed: $!\n";
 813                         my $resp = HTTP::Response->new($code, $msg, $header, undef);
 814                         $self->response($reqstate, $resp, undef, 1, 0, $fh);
 815                     } else {
 816                         my $resp = HTTP::Response->new($code, $msg, $header, $body);
 817                         # Note: disable compression, because body is already compressed
 818                         $self->response($reqstate, $resp, undef, 1);
 819                     }
 820                 };
 821                 warn $@ if $@;
 822             });
 823     };
 824     warn $@ if $@;
 825 }
 826
 827 # return arrays as \0 separated strings (like CGI.pm)
 828 # assume data is UTF8 encoded
 829 sub decode_urlencoded {
 830     my ($data) = @_;
 831
 832     my $res = {};
 833
 834     return $res if !$data;
 835
 836     foreach my $kv (split(/[\&\;]/, $data)) {
 837         my ($k, $v) = split(/=/, $kv);
 838         $k =~s/\+/ /g;
 839         $k =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr(hex($1))/eg;
 840
 841         if (defined($v)) {
 842             $v =~s/\+/ /g;
 843             $v =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr(hex($1))/eg;
 844
 845             $v = Encode::decode('utf8', $v);
 846
 847             if (defined(my $old = $res->{$k})) {
 848                 $v = "$old\0$v";
 849             }
 850         }
 851
 852         $res->{$k} = $v;
 853     }
 854     return $res;
 855 }
 856
 857 sub extract_params {
 858     my ($r, $method) = @_;
 859
 860     my $params = {};
 861
 862     if ($method eq 'PUT' || $method eq 'POST') {
 863         my $ct;
 864         if (my $ctype = $r->header('Content-Type')) {
 865             $ct = parse_content_type($ctype);
 866         }
 867         if (defined($ct) && $ct eq 'application/json')  {
 868             $params = decode_json($r->content);
 869         } else {
 870             $params = decode_urlencoded($r->content);
 871         }
 872     }
 873
 874     my $query_params = decode_urlencoded($r->url->query());
 875
 876     foreach my $k (keys %{$query_params}) {
 877         $params->{$k} = $query_params->{$k};
 878     }
 879
 880     return $params;
 881 }
 882
 883 sub handle_api2_request {
 884     my ($self, $reqstate, $auth, $method, $path, $upload_state) = @_;
 885
 886     eval {
 887         my $r = $reqstate->{request};
 888
 889         my ($rel_uri, $format) = &$split_abs_uri($path, $self->{base_uri});
 890
 891         my $formatter = PVE::APIServer::Formatter::get_formatter($format, $method, $rel_uri);
 892
 893         if (!defined($formatter)) {
 894             $self->error($reqstate, HTTP_NOT_IMPLEMENTED, "no formatter for uri $rel_uri, $format");
 895             return;
 896         }
 897
 898         #print Dumper($upload_state) if $upload_state;
 899
 900         my $params;
 901
 902         if ($upload_state) {
 903             $params = $upload_state->{params};
 904         } else {
 905             $params = extract_params($r, $method);
 906         }
 907
 908         delete $params->{_dc} if $params; # remove disable cache parameter
 909
 910         my $clientip = $reqstate->{peer_host};
 911
 912         my $res = $self->rest_handler($clientip, $method, $rel_uri, $auth, $params, $format);
 913
 914         # HACK: see Note 1
 915         Net::SSLeay::ERR_clear_error();
 916
 917         AnyEvent->now_update(); # in case somebody called sleep()
 918
 919         my $upgrade = $r->header('upgrade');
 920         $upgrade = lc($upgrade) if $upgrade;
 921
 922         if (my $host = $res->{proxy}) {
 923
 924             if ($self->{trusted_env}) {
 925                 $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy not allowed");
 926                 return;
 927             }
 928
 929             if ($host ne 'localhost' && $r->header('PVEDisableProxy')) {
 930                 $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy loop detected");
 931                 return;
 932             }
 933
 934             $res->{proxy_params}->{tmpfilename} = $reqstate->{tmpfilename} if $upload_state;
 935
 936             $self->proxy_request($reqstate, $clientip, $host, $res->{proxynode}, $method,
 937                                  $r->uri, $auth, $res->{proxy_params});
 938             return;
 939
 940         } elsif ($upgrade && ($method eq 'GET') && ($path =~ m|websocket$|)) {
 941             die "unable to upgrade to protocol '$upgrade'\n" if !$upgrade || ($upgrade ne 'websocket');
 942             my $wsver = $r->header('sec-websocket-version');
 943             die "unsupported websocket-version '$wsver'\n" if !$wsver || ($wsver ne '13');
 944             my $wsproto = $r->header('sec-websocket-protocol') // "";
 945             my $wskey = $r->header('sec-websocket-key');
 946             die "missing websocket-key\n" if !$wskey;
 947             # Note: Digest::SHA::sha1_base64 has wrong padding
 948             my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
 949             if ($res->{status} == HTTP_OK) {
 950                 $self->websocket_proxy($reqstate, $wsaccept, $wsproto, $res->{data});
 951                 return;
 952             }
 953         }
 954
 955         my $delay = 0;
 956         if ($res->{status} == HTTP_UNAUTHORIZED) {
 957             # always delay unauthorized calls by 3 seconds
 958             $delay = 3 - tv_interval($reqstate->{starttime});
 959             $delay = 0 if $delay < 0;
 960         }
 961
 962         my $download = $res->{download};
 963         $download //= $res->{data}->{download}
 964             if defined($res->{data}) && ref($res->{data}) eq 'HASH';
 965         if (defined($download)) {
 966             send_file_start($self, $reqstate, $download);
 967             return;
 968         }
 969
 970         my ($raw, $ct, $nocomp) = $formatter->($res, $res->{data}, $params, $path,
 971                                                $auth, $self->{formatter_config});
 972
 973         my $resp;
 974         if (ref($raw) && (ref($raw) eq 'HTTP::Response')) {
 975             $resp = $raw;
 976         } else {
 977             $resp = HTTP::Response->new($res->{status}, $res->{message});
 978             $resp->header("Content-Type" => $ct);
 979             $resp->content($raw);
 980         }
 981         $self->response($reqstate, $resp, undef, $nocomp, $delay);
 982     };
 983     if (my $err = $@) {
 984         $self->error($reqstate, 501, $err);
 985     }
 986 }
 987
 988 sub handle_spice_proxy_request {
 989     my ($self, $reqstate, $connect_str, $vmid, $node, $spiceport) = @_;
 990
 991     eval {
 992
 993         my ($minport, $maxport) = PVE::Tools::spice_port_range();
 994         if ($spiceport < $minport || $spiceport > $maxport) {
 995             die "SPICE Port $spiceport is not in allowed range ($minport, $maxport)\n";
 996         }
 997
 998         my $clientip = $reqstate->{peer_host};
 999         my $r = $reqstate->{request};
1000
1001         my $remip;
1002
1003         if ($node ne 'localhost' && PVE::INotify::nodename() !~ m/^$node$/i) {
1004             $remip = $self->remote_node_ip($node);
1005             $self->dprint("REMOTE CONNECT $vmid, $remip, $connect_str");
1006         } else {
1007             $self->dprint("CONNECT $vmid, $node, $spiceport");
1008         }
1009
1010         if ($remip && $r->header('PVEDisableProxy')) {
1011             $self->error($reqstate, HTTP_INTERNAL_SERVER_ERROR, "proxy loop detected");
1012             return;
1013         }
1014
1015         $reqstate->{hdl}->timeout(0);
1016         $reqstate->{hdl}->wbuf_max(64*10*1024);
1017
1018         my $remhost = $remip ? $remip : "localhost";
1019         my $remport = $remip ? 3128 : $spiceport;
1020
1021         tcp_connect $remhost, $remport, sub {
1022             my ($fh) = @_
1023                 or die "connect to '$remhost:$remport' failed: $!";
1024
1025             $self->dprint("CONNECTed to '$remhost:$remport'");
1026             $reqstate->{proxyhdl} = AnyEvent::Handle->new(
1027                 fh => $fh,
1028                 rbuf_max => 64*1024,
1029                 wbuf_max => 64*10*1024,
1030                 timeout => 5,
1031                 on_eof => sub {
1032                     my ($hdl) = @_;
1033                     eval {
1034                         $self->log_aborted_request($reqstate);
1035                         $self->client_do_disconnect($reqstate);
1036                     };
1037                     if (my $err = $@) { syslog('err', $err); }
1038                 },
1039                 on_error => sub {
1040                     my ($hdl, $fatal, $message) = @_;
1041                     eval {
1042                         $self->log_aborted_request($reqstate, $message);
1043                         $self->client_do_disconnect($reqstate);
1044                     };
1045                     if (my $err = $@) { syslog('err', "$err"); }
1046                 });
1047
1048
1049             my $proxyhdlreader = sub {
1050                 my ($hdl) = @_;
1051
1052                 my $len = length($hdl->{rbuf});
1053                 my $data = substr($hdl->{rbuf}, 0, $len, '');
1054
1055                 #print "READ1 $len\n";
1056                 $reqstate->{hdl}->push_write($data) if $reqstate->{hdl};
1057             };
1058
1059             my $hdlreader = sub {
1060                 my ($hdl) = @_;
1061
1062                 my $len = length($hdl->{rbuf});
1063                 my $data = substr($hdl->{rbuf}, 0, $len, '');
1064
1065                 #print "READ0 $len\n";
1066                 $reqstate->{proxyhdl}->push_write($data) if $reqstate->{proxyhdl};
1067             };
1068
1069             my $proto = $reqstate->{proto} ? $reqstate->{proto}->{str} : 'HTTP/1.0';
1070
1071             my $startproxy = sub {
1072                 $reqstate->{proxyhdl}->timeout(0);
1073                 $reqstate->{proxyhdl}->on_read($proxyhdlreader);
1074                 $reqstate->{hdl}->on_read($hdlreader);
1075
1076                 # todo: use stop_read/start_read if write buffer grows to much
1077
1078                 # a response must be followed by an empty line
1079                 my $res = "$proto 200 OK\015\012\015\012";
1080                 $reqstate->{hdl}->push_write($res);
1081
1082                 # log early
1083                 $reqstate->{log}->{code} = 200;
1084                 $self->log_request($reqstate);
1085             };
1086
1087             if ($remip) {
1088                 my $header = "CONNECT ${connect_str} $proto\015\012" .
1089                     "Host: ${connect_str}\015\012" .
1090                     "Proxy-Connection: keep-alive\015\012" .
1091                     "User-Agent: spiceproxy\015\012" .
1092                     "PVEDisableProxy: true\015\012" .
1093                     "PVEClientIP: $clientip\015\012" .
1094                     "\015\012";
1095
1096                 $reqstate->{proxyhdl}->push_write($header);
1097                 $reqstate->{proxyhdl}->push_read(line => sub {
1098                     my ($hdl, $line) = @_;
1099
1100                     if ($line =~ m!^$proto 200 OK$!) {
1101                         # read the empty line after the 200 OK
1102                         $reqstate->{proxyhdl}->unshift_read(line => sub{
1103                             &$startproxy();
1104                         });
1105                     } else {
1106                         $reqstate->{hdl}->push_write($line);
1107                         $self->client_do_disconnect($reqstate);
1108                     }
1109                 });
1110             } else {
1111                 &$startproxy();
1112             }
1113
1114         };
1115     };
1116     if (my $err = $@) {
1117         warn $err;
1118         $self->log_aborted_request($reqstate, $err);
1119         $self->client_do_disconnect($reqstate);
1120     }
1121 }
1122
1123 sub handle_request {
1124     my ($self, $reqstate, $auth, $method, $path) = @_;
1125
1126     my $base_uri = $self->{base_uri};
1127
1128     eval {
1129         my $r = $reqstate->{request};
1130
1131         # disable timeout on handle (we already have all data we need)
1132         # we re-enable timeout in response()
1133         $reqstate->{hdl}->timeout(0);
1134
1135         if ($path =~ m/^\Q$base_uri\E/) {
1136             $self->handle_api2_request($reqstate, $auth, $method, $path);
1137             return;
1138         }
1139
1140         if ($self->{pages} && ($method eq 'GET') && (my $handler = $self->{pages}->{$path})) {
1141             if (ref($handler) eq 'CODE') {
1142                 my $params = decode_urlencoded($r->url->query());
1143                 my ($resp, $userid) = &$handler($self, $reqstate->{request}, $params);
1144                 # HACK: see Note 1
1145                 Net::SSLeay::ERR_clear_error();
1146                 $self->response($reqstate, $resp);
1147             } elsif (ref($handler) eq 'HASH') {
1148                 if (my $filename = $handler->{file}) {
1149                     my $fh = IO::File->new($filename) ||
1150                         die "unable to open file '$filename' - $!\n";
1151                     send_file_start($self, $reqstate, $filename);
1152                 } else {
1153                     die "internal error - no handler";
1154                 }
1155             } else {
1156                 die "internal error - no handler";
1157             }
1158             return;
1159         }
1160
1161         if ($self->{dirs} && ($method eq 'GET')) {
1162             # we only allow simple names
1163             if ($path =~ m!^(/\S+/)([a-zA-Z0-9\-\_\.]+)$!) {
1164                 my ($subdir, $file) = ($1, $2);
1165                 if (my $dir = $self->{dirs}->{$subdir}) {
1166                     my $filename = "$dir$file";
1167                     my $fh = IO::File->new($filename) ||
1168                         die "unable to open file '$filename' - $!\n";
1169                     send_file_start($self, $reqstate, $filename);
1170                     return;
1171                 }
1172             }
1173         }
1174
1175         die "no such file '$path'\n";
1176     };
1177     if (my $err = $@) {
1178         $self->error($reqstate, 501, $err);
1179     }
1180 }
1181
1182 my sub assert_form_disposition {
1183     die "wrong Content-Disposition '$_[0]' in multipart, expected 'form-data'\n" if $_[0] ne 'form-data';
1184 }
1185
1186 sub file_upload_multipart {
1187     my ($self, $reqstate, $auth, $method, $path, $rstate) = @_;
1188
1189     eval {
1190         my $boundary = $rstate->{boundary};
1191         my $hdl = $reqstate->{hdl};
1192         my $startlen = length($hdl->{rbuf});
1193
1194         my $newline_re = qr/\015?\012/;
1195         my $delim_re = qr/--\Q$boundary\E${newline_re}/;
1196         my $close_delim_re = qr/--\Q$boundary\E--/;
1197
1198         # Phase 0 - preserve boundary, but remove everything before
1199         if ($rstate->{phase} == 0 && $hdl->{rbuf} =~ s/^.*?($delim_re)/$1/s) {
1200             $rstate->{read} += $startlen - length($hdl->{rbuf});
1201             $rstate->{phase} = 1;
1202         }
1203
1204         my $remove_until_data = sub {
1205             my ($hdl) = @_;
1206             # remove any remaining multipart "headers" like Content-Type
1207             $hdl->{rbuf} =~ s/^.*?${newline_re}{2}//s;
1208         };
1209
1210         my $extract_form_disposition = sub {
1211             my ($name) = @_;
1212             if ($hdl->{rbuf} =~ s/^${delim_re}.*?Content-Disposition: (.*?); name="$name"(.*?${delim_re})/$2/s) {
1213                 assert_form_disposition($1);
1214                 $remove_until_data->($hdl);
1215                 $hdl->{rbuf} =~ s/^(.*?)(${delim_re})/$2/s;
1216                 $rstate->{params}->{$name} = trim($1);
1217             }
1218         };
1219
1220         if ($rstate->{phase} == 1) { # Phase 1 - parse payload without file data
1221             $extract_form_disposition->('content');
1222             $extract_form_disposition->('checksum-algorithm');
1223             $extract_form_disposition->('checksum');
1224
1225             if ($hdl->{rbuf} =~ s/^${delim_re}Content-Disposition: (.*?); name="(.*?)"; filename="([^"]+)"//s) {
1226                 assert_form_disposition($1);
1227                 die "wrong field name '$2' for file upload, expected 'filename'" if $2 ne "filename";
1228                 $rstate->{phase} = 2;
1229                 $rstate->{params}->{filename} = trim($3);
1230                 $remove_until_data->($hdl); # any remaining multipart "headers" like Content-Type
1231             }
1232         }
1233
1234         if ($rstate->{phase} == 2) { # Phase 2 - dump content into file
1235             my ($data, $write_length);
1236             if ($hdl->{rbuf} =~ s/^(.*?)${newline_re}?+${close_delim_re}.*$//s) {
1237                 $data = $1;
1238                 $write_length = length($data);
1239                 $rstate->{phase} =  100;
1240             } else {
1241                 $write_length = length($hdl->{rbuf}) - $rstate->{boundlen};
1242                 $data = substr($hdl->{rbuf}, 0, $write_length, '') if $write_length > 0;
1243             }
1244
1245             if ($write_length > 0) {
1246                 syswrite($rstate->{outfh}, $data) == $write_length or die "write to temporary file failed - $!\n";
1247                 $rstate->{bytes} += $write_length;
1248             }
1249         }
1250
1251         if ($rstate->{phase} == 100) { # Phase 100 - transfer finished
1252             my $elapsed = tv_interval($rstate->{starttime});
1253             syslog('info', "multipart upload complete (size: %dB time: %.3fs rate: %.2fMiB/s filename: %s)",
1254                 $rstate->{bytes}, $elapsed, $rstate->{bytes} / ($elapsed * 1024 * 1024),
1255                 $rstate->{params}->{filename}
1256             );
1257             $self->handle_api2_request($reqstate, $auth, $method, $path, $rstate);
1258         }
1259
1260         $rstate->{read} += $startlen - length($hdl->{rbuf});
1261
1262         if ($rstate->{read} + length($hdl->{rbuf}) >= $rstate->{size} && $rstate->{phase} != 100) {
1263             die "upload failed";
1264         }
1265     };
1266     if (my $err = $@) {
1267         syslog('err', $err);
1268         $self->error($reqstate, 501, $err);
1269     }
1270 }
1271
1272 sub parse_content_type {
1273     my ($ctype) = @_;
1274
1275     my ($ct, @params) = split(/\s*[;,]\s*/o, $ctype);
1276
1277     foreach my $v (@params) {
1278         if ($v =~ m/^\s*boundary\s*=\s*(\S+?)\s*$/o) {
1279             return wantarray ? ($ct, $1) : $ct;
1280         }
1281     }
1282
1283     return  wantarray ? ($ct) : $ct;
1284 }
1285
1286 my $tmpfile_seq_no = 0;
1287
1288 sub get_upload_filename {
1289     # choose unpredictable tmpfile name
1290
1291     $tmpfile_seq_no++;
1292     return "/var/tmp/pveupload-" . Digest::MD5::md5_hex($tmpfile_seq_no . time() . $$);
1293 }
1294
1295 sub unshift_read_header {
1296     my ($self, $reqstate, $state) = @_;
1297
1298     $state = { size => 0, count => 0 } if !$state;
1299
1300     $reqstate->{hdl}->unshift_read(line => sub {
1301         my ($hdl, $line) = @_;
1302
1303         eval {
1304             # print "$$: got header: $line\n" if $self->{debug};
1305
1306             die "too many http header lines (> $limit_max_headers)\n" if ++$state->{count} >= $limit_max_headers;
1307             die "http header too large\n" if ($state->{size} += length($line)) >= $limit_max_header_size;
1308
1309             my $r = $reqstate->{request};
1310             if ($line eq '') {
1311
1312                 $r->push_header($state->{key}, $state->{val})
1313                     if $state->{key};
1314
1315                 return if !$self->process_header($reqstate);
1316                 return if !$self->ensure_tls_connection($reqstate);
1317
1318                 $self->authenticate_and_handle_request($reqstate);
1319
1320             } elsif ($line =~ /^([^:\s]+)\s*:\s*(.*)/) {
1321                 $r->push_header($state->{key}, $state->{val}) if $state->{key};
1322                 ($state->{key}, $state->{val}) = ($1, $2);
1323                 $self->unshift_read_header($reqstate, $state);
1324             } elsif ($line =~ /^\s+(.*)/) {
1325                 $state->{val} .= " $1";
1326                 $self->unshift_read_header($reqstate, $state);
1327             } else {
1328                 $self->error($reqstate, 506, "unable to parse request header");
1329             }
1330         };
1331         warn $@ if $@;
1332     });
1333 };
1334
1335 # sends an (error) response and returns 0 in case of errors
1336 sub process_header {
1337     my ($self, $reqstate) = @_;
1338
1339     my $request = $reqstate->{request};
1340
1341     my $path = uri_unescape($request->uri->path());
1342     my $method = $request->method();
1343
1344     if (!$known_methods->{$method}) {
1345         my $resp = HTTP::Response->new(HTTP_NOT_IMPLEMENTED, "method '$method' not available");
1346         $self->response($reqstate, $resp);
1347         return 0;
1348     }
1349
1350     my $conn = $request->header('Connection');
1351     my $accept_enc = $request->header('Accept-Encoding');
1352     $reqstate->{accept_gzip} = ($accept_enc && $accept_enc =~ m/gzip/) ? 1 : 0;
1353
1354     if ($conn) {
1355         $reqstate->{keep_alive} = 0 if $conn =~ m/close/oi;
1356     } else {
1357         if ($reqstate->{proto}->{ver} < 1001) {
1358             $reqstate->{keep_alive} = 0;
1359         }
1360     }
1361
1362     my $te  = $request->header('Transfer-Encoding');
1363     if ($te && lc($te) eq 'chunked') {
1364         # Handle chunked transfer encoding
1365         $self->error($reqstate, 501, "chunked transfer encoding not supported");
1366         return 0;
1367     } elsif ($te) {
1368         $self->error($reqstate, 501, "Unknown transfer encoding '$te'");
1369         return 0;
1370     }
1371
1372     my $pveclientip = $request->header('PVEClientIP');
1373
1374     # fixme: how can we make PVEClientIP header trusted?
1375     if ($self->{trusted_env} && $pveclientip) {
1376         $reqstate->{peer_host} = $pveclientip;
1377     } else {
1378         $request->header('PVEClientIP', $reqstate->{peer_host});
1379     }
1380
1381     if (my $rpcenv = $self->{rpcenv}) {
1382         $rpcenv->set_request_host($request->header('Host'));
1383     }
1384
1385     return 1;
1386 }
1387
1388 # sends an (redirect) response, disconnects the client and returns 0 if
1389 # connection is not TLS-protected
1390 sub ensure_tls_connection {
1391     my ($self, $reqstate) = @_;
1392
1393     # Skip if server doesn't use TLS
1394     if (!$self->{tls_ctx}) {
1395         return 1;
1396     }
1397
1398     # TLS session exists, so the handshake has succeeded
1399     if ($reqstate->{hdl}->{tls}) {
1400         return 1;
1401     }
1402
1403     my $request = $reqstate->{request};
1404     my $method = $request->method();
1405
1406     my $h_host = $reqstate->{request}->header('Host');
1407
1408     die "Header field 'Host' not found in request\n"
1409         if !$h_host;
1410
1411     my $secure_host = "https://" . ($h_host =~ s/^http(s)?:\/\///r);
1412
1413     my $header = HTTP::Headers->new('Location' => $secure_host . $request->uri());
1414
1415     if ($method eq 'GET' || $method eq 'HEAD') {
1416         $self->error($reqstate, 301, 'Moved Permanently', $header);
1417     } else {
1418         $self->error($reqstate, 308, 'Permanent Redirect', $header);
1419     }
1420
1421     # disconnect the client so they may immediately connect again via HTTPS
1422     $self->client_do_disconnect($reqstate);
1423
1424     return 0;
1425 }
1426
1427 sub authenticate_and_handle_request {
1428     my ($self, $reqstate) = @_;
1429
1430     my $request = $reqstate->{request};
1431     my $method = $request->method();
1432
1433     my $path = uri_unescape($request->uri->path());
1434     my $base_uri = $self->{base_uri};
1435
1436     my $auth = {};
1437
1438     if ($self->{spiceproxy}) {
1439         my $connect_str = $request->header('Host');
1440         my ($vmid, $node, $port) = $self->verify_spice_connect_url($connect_str);
1441
1442         if (!(defined($vmid) && $node && $port)) {
1443             $self->error($reqstate, HTTP_UNAUTHORIZED, "invalid ticket");
1444             return;
1445         }
1446
1447         $self->handle_spice_proxy_request($reqstate, $connect_str, $vmid, $node, $port);
1448         return;
1449
1450     } elsif ($path =~ m/^\Q$base_uri\E/) {
1451         my $token = $request->header('CSRFPreventionToken');
1452         my $cookie = $request->header('Cookie');
1453         my $auth_header = $request->header('Authorization');
1454
1455         # prefer actual cookie
1456         my $ticket = PVE::APIServer::Formatter::extract_auth_value(
1457             $cookie,
1458             $self->{cookie_name}
1459         );
1460
1461         # fallback to cookie in 'Authorization' header
1462         if (!$ticket) {
1463             $ticket = PVE::APIServer::Formatter::extract_auth_value(
1464                 $auth_header,
1465                 $self->{cookie_name}
1466             );
1467         }
1468
1469         # finally, fallback to API token if no ticket has been provided so far
1470         my $api_token;
1471         if (!$ticket) {
1472             $api_token = PVE::APIServer::Formatter::extract_auth_value(
1473                 $auth_header,
1474                 $self->{apitoken_name}
1475             );
1476         }
1477
1478         my ($rel_uri, $format) = &$split_abs_uri($path, $self->{base_uri});
1479         if (!$format) {
1480             $self->error($reqstate, HTTP_NOT_IMPLEMENTED, "no such uri");
1481             return;
1482         }
1483
1484         eval {
1485             $auth = $self->auth_handler(
1486                 $method,
1487                 $rel_uri,
1488                 $ticket,
1489                 $token,
1490                 $api_token,
1491                 $reqstate->{peer_host}
1492             );
1493         };
1494         if (my $err = $@) {
1495             # HACK: see Note 1
1496             Net::SSLeay::ERR_clear_error();
1497             # always delay unauthorized calls by 3 seconds
1498             my $delay = 3;
1499
1500             if (ref($err) eq "PVE::Exception") {
1501
1502                 $err->{code} ||= HTTP_INTERNAL_SERVER_ERROR,
1503                 my $resp = HTTP::Response->new($err->{code}, $err->{msg});
1504                 $self->response($reqstate, $resp, undef, 0, $delay);
1505
1506             } elsif (my $formatter = PVE::APIServer::Formatter::get_login_formatter($format)) {
1507                 my ($raw, $ct, $nocomp) =
1508                     $formatter->($path, $auth, $self->{formatter_config});
1509
1510                 my $resp;
1511                 if (ref($raw) && (ref($raw) eq 'HTTP::Response')) {
1512                     $resp = $raw;
1513
1514                 } else {
1515                     $resp = HTTP::Response->new(HTTP_UNAUTHORIZED, "Login Required");
1516                     $resp->header("Content-Type" => $ct);
1517                     $resp->content($raw);
1518                 }
1519
1520                 $self->response($reqstate, $resp, undef, $nocomp, $delay);
1521
1522             } else {
1523                 my $resp = HTTP::Response->new(HTTP_UNAUTHORIZED, $err);
1524                 $self->response($reqstate, $resp, undef, 0, $delay);
1525             }
1526
1527             return;
1528         }
1529     }
1530
1531     $reqstate->{log}->{userid} = $auth->{userid};
1532     my $len = $request->header('Content-Length');
1533
1534     if ($len) {
1535
1536         if (!($method eq 'PUT' || $method eq 'POST')) {
1537             $self->error($reqstate, 501, "Unexpected content for method '$method'");
1538             return;
1539         }
1540
1541         my $ctype = $request->header('Content-Type');
1542         my ($ct, $boundary) = $ctype ? parse_content_type($ctype) : ();
1543
1544         if ($auth->{isUpload} && !$self->{trusted_env}) {
1545             die "upload 'Content-Type '$ctype' not implemented\n"
1546                 if !($boundary && $ct && ($ct eq 'multipart/form-data'));
1547
1548             die "upload without content length header not supported" if !$len;
1549
1550             die "upload without content length header not supported" if !$len;
1551
1552             $self->dprint("start upload $path $ct $boundary");
1553
1554             my $tmpfilename = get_upload_filename();
1555             my $outfh = IO::File->new($tmpfilename, O_RDWR|O_CREAT|O_EXCL, 0600) ||
1556                 die "unable to create temporary upload file '$tmpfilename'";
1557
1558             $reqstate->{keep_alive} = 0;
1559
1560             my $boundlen = length($boundary) + 8; # \015?\012--$boundary--\015?\012
1561
1562             my $state = {
1563                 size => $len,
1564                 boundary => $boundary,
1565                 boundlen =>  $boundlen,
1566                 maxheader => 2048 + $boundlen, # should be large enough
1567                 params => decode_urlencoded($request->url->query()),
1568                 phase => 0,
1569                 read => 0,
1570                 post_size => 0,
1571                 starttime => [gettimeofday],
1572                 outfh => $outfh,
1573             };
1574
1575             die "'tmpfilename' query parameter is not allowed for file uploads\n"
1576                 if exists $state->{params}->{tmpfilename};
1577
1578             $reqstate->{tmpfilename} = $tmpfilename;
1579             $reqstate->{hdl}->on_read(sub {
1580                 $self->file_upload_multipart($reqstate, $auth, $method, $path, $state);
1581             });
1582
1583             return;
1584         }
1585
1586         if ($len > $limit_max_post) {
1587             $self->error($reqstate, 501, "for data too large");
1588             return;
1589         }
1590
1591         if (!$ct || $ct eq 'application/x-www-form-urlencoded' || $ct eq 'application/json') {
1592             $reqstate->{hdl}->unshift_read(chunk => $len, sub {
1593                 my ($hdl, $data) = @_;
1594                 $request->content($data);
1595                 $self->handle_request($reqstate, $auth, $method, $path);
1596             });
1597
1598         } else {
1599             $self->error($reqstate, 506, "upload 'Content-Type '$ctype' not implemented");
1600         }
1601
1602     } else {
1603         $self->handle_request($reqstate, $auth, $method, $path);
1604     }
1605 }
1606
1607 sub push_request_header {
1608     my ($self, $reqstate) = @_;
1609
1610     eval {
1611         $reqstate->{hdl}->push_read(line => sub {
1612             my ($hdl, $line) = @_;
1613
1614             eval {
1615                 # print "got request header: $line\n" if $self->{debug};
1616
1617                 $reqstate->{keep_alive}--;
1618
1619                 if ($line =~ /(\S+)\040(\S+)\040HTTP\/(\d+)\.(\d+)/o) {
1620                     my ($method, $url, $maj, $min) = ($1, $2, $3, $4);
1621
1622                     if ($maj != 1) {
1623                         $self->error($reqstate, 506, "http protocol version $maj.$min not supported");
1624                         return;
1625                     }
1626                     if ($url =~ m|^[^/]*@|) {
1627                         # if an '@' comes before the first slash proxy forwarding might consider
1628                         # the frist part of the url to be part of an authority...
1629                         $self->error($reqstate, 400, "invalid url");
1630                         return;
1631                     }
1632
1633                     $self->{request_count}++; # only count valid request headers
1634                     if ($self->{request_count} >= $self->{max_requests}) {
1635                         $self->{end_loop} = 1;
1636                     }
1637                     $reqstate->{log} = { requestline => $line };
1638                     $reqstate->{proto}->{str} = "HTTP/$maj.$min";
1639                     $reqstate->{proto}->{maj} = $maj;
1640                     $reqstate->{proto}->{min} = $min;
1641                     $reqstate->{proto}->{ver} = $maj*1000+$min;
1642                     $reqstate->{request} = HTTP::Request->new($method, $url);
1643                     $reqstate->{starttime} = [gettimeofday];
1644
1645                     $self->unshift_read_header($reqstate);
1646                 } elsif ($line eq '') {
1647                     # ignore empty lines before requests (browser bugs?)
1648                     $self->push_request_header($reqstate);
1649                 } else {
1650                     $self->error($reqstate, 400, 'bad request');
1651                 }
1652             };
1653             warn $@ if $@;
1654         });
1655     };
1656     warn $@ if $@;
1657 }
1658
1659 sub accept {
1660     my ($self) = @_;
1661
1662     my $clientfh;
1663
1664     return if $self->{end_loop};
1665
1666     # we need to m make sure that only one process calls accept
1667     while (!flock($self->{lockfh}, Fcntl::LOCK_EX())) {
1668         next if $! == EINTR;
1669         die "could not get lock on file '$self->{lockfile}' -  $!\n";
1670     }
1671
1672     my $again = 0;
1673     my $errmsg;
1674     eval {
1675         while (!$self->{end_loop} &&
1676                !defined($clientfh = $self->{socket}->accept()) &&
1677                ($! == EINTR)) {};
1678
1679         if ($self->{end_loop}) {
1680             $again = 0;
1681         } else {
1682             $again = ($! == EAGAIN || $! == WSAEWOULDBLOCK);
1683             if (!defined($clientfh)) {
1684                 $errmsg = "failed to accept connection: $!\n";
1685             }
1686         }
1687     };
1688     warn $@ if $@;
1689
1690     flock($self->{lockfh}, Fcntl::LOCK_UN());
1691
1692     if (!defined($clientfh)) {
1693         return if $again;
1694         die $errmsg if $errmsg;
1695     }
1696
1697     fh_nonblocking $clientfh, 1;
1698
1699     return $clientfh;
1700 }
1701
1702 sub wait_end_loop {
1703     my ($self) = @_;
1704
1705     $self->{end_loop} = 1;
1706
1707     undef $self->{socket_watch};
1708
1709     $0 = "$0 (shutdown)" if $0 !~ m/\(shutdown\)$/;
1710
1711     if ($self->{conn_count} <= 0) {
1712         $self->{end_cond}->send(1);
1713         return;
1714     }
1715
1716     # fork and exit, so that parent starts a new worker
1717     if (fork()) {
1718         exit(0);
1719     }
1720
1721     # else we need to wait until all open connections gets closed
1722     my $w; $w = AnyEvent->timer (after => 1, interval => 1, cb => sub {
1723         eval {
1724             # todo: test for active connections instead (we can abort idle connections)
1725             if ($self->{conn_count} <= 0) {
1726                 undef $w;
1727                 $self->{end_cond}->send(1);
1728             }
1729         };
1730         warn $@ if $@;
1731     });
1732 }
1733
1734
1735 sub check_host_access {
1736     my ($self, $clientip) = @_;
1737
1738     $clientip = PVE::APIServer::Utils::normalize_v4_in_v6($clientip);
1739     my $cip = Net::IP->new($clientip);
1740
1741     if (!$cip) {
1742         $self->dprint("client IP not parsable: $@");
1743         return 0;
1744     }
1745
1746     my $match_allow = 0;
1747     my $match_deny = 0;
1748
1749     if ($self->{allow_from}) {
1750         foreach my $t (@{$self->{allow_from}}) {
1751             if ($t->overlaps($cip)) {
1752                 $match_allow = 1;
1753                 $self->dprint("client IP allowed: ". $t->prefix());
1754                 last;
1755             }
1756         }
1757     }
1758
1759     if ($self->{deny_from}) {
1760         foreach my $t (@{$self->{deny_from}}) {
1761             if ($t->overlaps($cip)) {
1762                 $self->dprint("client IP denied: ". $t->prefix());
1763                 $match_deny = 1;
1764                 last;
1765             }
1766         }
1767     }
1768
1769     if ($match_allow == $match_deny) {
1770         # match both allow and deny, or no match
1771         return $self->{policy} && $self->{policy} eq 'allow' ? 1 : 0;
1772     }
1773
1774     return $match_allow;
1775 }
1776
1777 sub accept_connections {
1778     my ($self) = @_;
1779
1780     my ($clientfh, $handle_creation);
1781     eval {
1782
1783         while ($clientfh = $self->accept()) {
1784
1785             my $reqstate = { keep_alive => $self->{keep_alive} };
1786
1787             # stop keep-alive when there are many open connections
1788             if ($self->{conn_count} + 1 >= $self->{max_conn_soft_limit}) {
1789                 $reqstate->{keep_alive} = 0;
1790             }
1791
1792             if (my $sin = getpeername($clientfh)) {
1793                 my ($pfamily, $pport, $phost) = PVE::Tools::unpack_sockaddr_in46($sin);
1794                 ($reqstate->{peer_port}, $reqstate->{peer_host}) = ($pport,  Socket::inet_ntop($pfamily, $phost));
1795             } else {
1796                 $self->dprint("getpeername failed: $!");
1797                 close($clientfh);
1798                 next;
1799             }
1800
1801             if (!$self->{trusted_env} && !$self->check_host_access($reqstate->{peer_host})) {
1802                 $self->dprint("ABORT request from $reqstate->{peer_host} - access denied");
1803                 $reqstate->{log}->{code} = 403;
1804                 $self->log_request($reqstate);
1805                 close($clientfh);
1806                 next;
1807             }
1808
1809             # Increment conn_count before creating new handle, since creation
1810             # triggers callbacks, which can potentialy decrement (e.g.
1811             # on_error) conn_count before AnyEvent::Handle->new() returns.
1812             $handle_creation = 1;
1813             $self->{conn_count}++;
1814             $reqstate->{hdl} = AnyEvent::Handle->new(
1815                 fh => $clientfh,
1816                 rbuf_max => 64*1024,
1817                 timeout => $self->{timeout},
1818                 linger => 0, # avoid problems with ssh - really needed ?
1819                 on_eof   => sub {
1820                     my ($hdl) = @_;
1821                     eval {
1822                         $self->log_aborted_request($reqstate);
1823                         $self->client_do_disconnect($reqstate);
1824                     };
1825                     if (my $err = $@) { syslog('err', $err); }
1826                 },
1827                 on_error => sub {
1828                     my ($hdl, $fatal, $message) = @_;
1829                     eval {
1830                         $self->log_aborted_request($reqstate, $message);
1831                         $self->client_do_disconnect($reqstate);
1832                     };
1833                     if (my $err = $@) { syslog('err', "$err"); }
1834                 },
1835             );
1836             $handle_creation = 0;
1837
1838             $self->dprint("ACCEPT FH" .  $clientfh->fileno() . " CONN$self->{conn_count}");
1839
1840             if ($self->{tls_ctx}) {
1841                 $self->dprint("Setting TLS to autostart");
1842                 $reqstate->{hdl}->unshift_read(tls_autostart => $self->{tls_ctx}, "accept");
1843             }
1844
1845             $self->push_request_header($reqstate);
1846         }
1847     };
1848
1849     if (my $err = $@) {
1850         syslog('err', $err);
1851         $self->dprint("connection accept error: $err");
1852         close($clientfh);
1853         if ($handle_creation) {
1854             if ($self->{conn_count} <= 0) {
1855                 warn "connection count <= 0 not decrementing!\n";
1856             } else {
1857                 $self->{conn_count}--;
1858             }
1859         }
1860         $self->{end_loop} = 1;
1861     }
1862
1863     $self->wait_end_loop() if $self->{end_loop};
1864 }
1865
1866 # Note: We can't open log file in non-blocking mode and use AnyEvent::Handle,
1867 # because we write from multiple processes, and that would arbitrarily mix output
1868 # of all processes.
1869 sub open_access_log {
1870     my ($self, $filename) = @_;
1871
1872     my $old_mask = umask(0137);;
1873     my $logfh = IO::File->new($filename, ">>") ||
1874         die "unable to open log file '$filename' - $!\n";
1875     umask($old_mask);
1876
1877     $logfh->autoflush(1);
1878
1879     $self->{logfh} = $logfh;
1880 }
1881
1882 sub write_log {
1883     my ($self, $data) = @_;
1884
1885     return if !defined($self->{logfh}) || !$data;
1886
1887     my $res = $self->{logfh}->print($data);
1888
1889     if (!$res) {
1890         delete $self->{logfh};
1891         syslog('err', "error writing access log");
1892         $self->{end_loop} = 1; # terminate asap
1893     }
1894 }
1895
1896 sub atfork_handler {
1897     my ($self) = @_;
1898
1899     eval {
1900         # something else do to ?
1901         close($self->{socket});
1902     };
1903     warn $@ if $@;
1904 }
1905
1906 sub run {
1907     my ($self) = @_;
1908
1909     $self->{end_cond}->recv;
1910 }
1911
1912 sub new {
1913     my ($this, %args) = @_;
1914
1915     my $class = ref($this) || $this;
1916
1917     foreach my $req (qw(socket lockfh lockfile)) {
1918         die "misssing required argument '$req'" if !defined($args{$req});
1919     }
1920
1921     my $self = bless { %args }, $class;
1922
1923     $self->{cookie_name} //= 'PVEAuthCookie';
1924     $self->{apitoken_name} //= 'PVEAPIToken';
1925     $self->{base_uri} //= "/api2";
1926     $self->{dirs} //= {};
1927     $self->{title} //= 'API Inspector';
1928     $self->{compression} //= 1;
1929
1930     # formatter_config: we pass some configuration values to the Formatter
1931     $self->{formatter_config} = {};
1932     foreach my $p (qw(apitoken_name cookie_name base_uri title)) {
1933         $self->{formatter_config}->{$p} = $self->{$p};
1934     }
1935     $self->{formatter_config}->{csrfgen_func} =
1936         $self->can('generate_csrf_prevention_token');
1937
1938     # add default dirs which includes jquery and bootstrap
1939     my $jsbase = '/usr/share/javascript';
1940     add_dirs($self->{dirs}, '/js/' => "$jsbase/");
1941     # libjs-bootstrap uses symlinks for this, which we do not want to allow..
1942     my $glyphicons = '/usr/share/fonts/truetype/glyphicons/';
1943     add_dirs($self->{dirs}, '/js/bootstrap/fonts/' => "$glyphicons");
1944
1945     # init inotify
1946     PVE::INotify::inotify_init();
1947
1948     fh_nonblocking($self->{socket}, 1);
1949
1950     $self->{end_loop} = 0;
1951     $self->{conn_count} = 0;
1952     $self->{request_count} = 0;
1953     $self->{timeout} = 5 if !$self->{timeout};
1954     $self->{keep_alive} = 0 if !defined($self->{keep_alive});
1955     $self->{max_conn} = 800 if !$self->{max_conn};
1956     $self->{max_requests} = 8000 if !$self->{max_requests};
1957
1958     $self->{policy} = 'allow' if !$self->{policy};
1959
1960     $self->{end_cond} = AnyEvent->condvar;
1961
1962     if ($self->{ssl}) {
1963         my $ssl_defaults = {
1964             # Note: older versions are considered insecure, for example
1965             # search for "Poodle"-Attack
1966             method => 'any',
1967             sslv2 => 0,
1968             sslv3 => 0,
1969             cipher_list => 'ECDHE-ECDSA-AES256-GCM-SHA384:ECDHE-RSA-AES256-GCM-SHA384:ECDHE-ECDSA-CHACHA20-POLY1305:ECDHE-RSA-CHACHA20-POLY1305:ECDHE-ECDSA-AES128-GCM-SHA256:ECDHE-RSA-AES128-GCM-SHA256:ECDHE-ECDSA-AES256-SHA384:ECDHE-RSA-AES256-SHA384:ECDHE-ECDSA-AES128-SHA256:ECDHE-RSA-AES128-SHA256',
1970             honor_cipher_order => 1,
1971         };
1972
1973         # workaround until anyevent supports TLS 1.3 ciphersuites directly
1974         my $ciphersuites = delete $self->{ssl}->{ciphersuites};
1975
1976         foreach my $k (keys %$ssl_defaults) {
1977             $self->{ssl}->{$k} //= $ssl_defaults->{$k};
1978         }
1979
1980         if (!defined($self->{ssl}->{dh_file})) {
1981             $self->{ssl}->{dh} = 'skip2048';
1982         }
1983
1984         my $tls_ctx_flags = 0;
1985         $tls_ctx_flags |= &Net::SSLeay::OP_NO_COMPRESSION;
1986         $tls_ctx_flags |= &Net::SSLeay::OP_SINGLE_ECDH_USE;
1987         $tls_ctx_flags |= &Net::SSLeay::OP_SINGLE_DH_USE;
1988         $tls_ctx_flags |= &Net::SSLeay::OP_NO_RENEGOTIATION;
1989         if (delete $self->{ssl}->{honor_cipher_order}) {
1990             $tls_ctx_flags |= &Net::SSLeay::OP_CIPHER_SERVER_PREFERENCE;
1991         }
1992         # workaround until anyevent supports disabling TLS 1.3 directly
1993         if (exists($self->{ssl}->{tlsv1_3}) && !$self->{ssl}->{tlsv1_3}) {
1994             $tls_ctx_flags |= &Net::SSLeay::OP_NO_TLSv1_3;
1995         }
1996
1997
1998         $self->{tls_ctx} = AnyEvent::TLS->new(%{$self->{ssl}});
1999         Net::SSLeay::CTX_set_options($self->{tls_ctx}->{ctx}, $tls_ctx_flags);
2000         if (defined($ciphersuites)) {
2001             warn "Failed to set TLS 1.3 ciphersuites '$ciphersuites'\n"
2002                 if !Net::SSLeay::CTX_set_ciphersuites($self->{tls_ctx}->{ctx}, $ciphersuites);
2003         }
2004     }
2005
2006     if ($self->{spiceproxy}) {
2007         $known_methods = { CONNECT => 1 };
2008     }
2009
2010     $self->open_access_log($self->{logfile}) if $self->{logfile};
2011
2012     $self->{max_conn_soft_limit} = $self->{max_conn} > 100 ? $self->{max_conn} - 20 : $self->{max_conn};
2013
2014     $self->{socket_watch} = AnyEvent->io(fh => $self->{socket}, poll => 'r', cb => sub {
2015         eval {
2016             if ($self->{conn_count} >= $self->{max_conn}) {
2017                 my $w; $w = AnyEvent->timer (after => 1, interval => 1, cb => sub {
2018                     if ($self->{conn_count} < $self->{max_conn}) {
2019                         undef $w;
2020                         $self->accept_connections();
2021                     }
2022                 });
2023             } else {
2024                 $self->accept_connections();
2025             }
2026         };
2027         warn $@ if $@;
2028     });
2029
2030     $self->{term_watch} = AnyEvent->signal(signal => "TERM", cb => sub {
2031         undef $self->{term_watch};
2032         $self->wait_end_loop();
2033     });
2034
2035     $self->{quit_watch} = AnyEvent->signal(signal => "QUIT", cb => sub {
2036         undef $self->{quit_watch};
2037         $self->wait_end_loop();
2038     });
2039
2040     $self->{inotify_poll} = AnyEvent->timer(after => 5, interval => 5, cb => sub {
2041         PVE::INotify::poll(); # read inotify events
2042     });
2043
2044     return $self;
2045 }
2046
2047 # static helper to add directory including all subdirs
2048 # This can be used to setup $self->{dirs}
2049 sub add_dirs {
2050     my ($result_hash, $alias, $subdir) = @_;
2051
2052     $result_hash->{$alias} = $subdir;
2053
2054     my $wanted = sub {
2055         my $dir = $File::Find::dir;
2056         if ($dir =~m!^$subdir(.*)$!) {
2057             my $name = "$alias$1/";
2058             $result_hash->{$name} = "$dir/";
2059         }
2060     };
2061
2062     find({wanted => $wanted, follow => 0, no_chdir => 1}, $subdir);
2063 }
2064
2065 # abstract functions - subclass should overwrite/implement them
2066
2067 sub verify_spice_connect_url {
2068     my ($self, $connect_str) = @_;
2069
2070     die "implement me";
2071
2072     #return ($vmid, $node, $port);
2073 }
2074
2075 # formatters can call this when the generate a new page
2076 sub generate_csrf_prevention_token {
2077     my ($username) = @_;
2078
2079     return undef; # do nothing by default
2080 }
2081
2082 sub auth_handler {
2083     my ($self, $method, $rel_uri, $ticket, $token, $api_token, $peer_host) = @_;
2084
2085     die "implement me";
2086
2087     # return {
2088     #    ticket => $ticket,
2089     #    token => $token,
2090     #    userid => $username,
2091     #    age => $age,
2092     #    isUpload => $isUpload,
2093     #    api_token => $api_token,
2094     #};
2095 }
2096
2097 sub rest_handler {
2098     my ($self, $clientip, $method, $rel_uri, $auth, $params, $format) = @_;
2099
2100     # please do not raise exceptions here (always return a result).
2101
2102     return {
2103         status => HTTP_NOT_IMPLEMENTED,
2104         message => "Method '$method $rel_uri' not implemented",
2105     };
2106
2107     # this should return the following properties, which
2108     # are then passed to the Formatter
2109
2110     # status: HTTP status code
2111     # message: Error message
2112     # errors: more detailed error hash (per parameter)
2113     # info: reference to JSON schema definition - useful to format output
2114     # data: result data
2115
2116     # total: additional info passed to output
2117     # changes:  additional info passed to output
2118
2119     # if you want to proxy the request to another node return this
2120     # { proxy => $remip, proxynode => $node, proxy_params => $params };
2121
2122     # to pass the request to the local priviledged daemon use:
2123     # { proxy => 'localhost' , proxy_params => $params };
2124
2125     # to download aspecific file use:
2126     # { download => "/path/to/file" };
2127 }
2128
2129 sub check_cert_fingerprint {
2130     my ($self, $cert) = @_;
2131
2132      die "implement me";
2133  }
2134
2135 sub initialize_cert_cache {
2136     my ($self, $node) = @_;
2137
2138     die "implement me";
2139 }
2140
2141 sub remote_node_ip {
2142     my ($self, $node) = @_;
2143
2144     die "implement me";
2145
2146     # return $remip;
2147 }
2148
2149
2150 1;