proxmox-low-level-installer

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use lib '.'; # FIXME
   7
   8 use File::Path qw(make_path);
   9 use Getopt::Long;
  10 use JSON;
  11 use Time::HiRes qw(usleep);
  12
  13 {
  14     my $test_image;
  15     GetOptions(
  16         'test-image|t=s' => \$test_image
  17     ) or die "usage error\n";
  18
  19     Proxmox::Install::ISOEnv::set_test_image($test_image) if $test_image;
  20 }
  21
  22 use Proxmox::Install::ISOEnv;
  23 use Proxmox::Install::RunEnv;
  24
  25 use Proxmox::Sys::File qw(file_write_all);
  26
  27 use Proxmox::Log;
  28 use Proxmox::Install;
  29 use Proxmox::Install::Config;
  30 use Proxmox::UI;
  31
  32 my $commands = {
  33     'dump-env' => 'Dump the current ISO and Hardware environment to base the installer UI on.',
  34     'start-session' => 'Start an installation session, with command and result transmitted via stdin/out',
  35     'start-session-test' => 'Start an installation TEST session, with command and result transmitted via stdin/out',
  36     'help' => 'Output this usage help.',
  37 };
  38
  39 sub usage {
  40     my ($cmd) = @_;
  41
  42     if (!$cmd) {
  43         printf("ERROR: missing command\n\n");
  44     } elsif (!exists($commands->{$cmd})) {
  45         printf("ERROR: unknown command '$cmd'\n\n");
  46     }
  47
  48     print "USAGE: $0 <cmd>\n";
  49     for my $cmd (sort keys $commands->%*) {
  50         printf("  %-20s - %s\n", $cmd, $commands->{$cmd});
  51     }
  52
  53     exit($cmd ne 'help' ? 1 : 0);
  54 }
  55
  56 sub read_and_merge_config {
  57     my $config_raw;
  58     while (my $line = <>) {
  59         if ($line =~ /^\s*\{/) {
  60             $config_raw = $line;
  61             last;
  62         }
  63     }
  64
  65     my $config =  eval { from_json($config_raw, { utf8 => 1 }) };
  66     die "failed to parse config from stdin - $@\n" if $@;
  67
  68     Proxmox::Install::Config::merge($config);
  69     log_info("got installation config: ". to_json(Proxmox::Install::Config::get(), { utf8 => 1, canonical => 1 }) ."\n");
  70 }
  71
  72 sub send_reboot_ui_message {
  73     if (Proxmox::Install::Config::get_autoreboot()) {
  74         my $secs = 5;
  75         while ($secs > 0) {
  76             Proxmox::UI::finished(1, "Installation finished - auto-rebooting in $secs seconds ..");
  77             sleep 1;
  78             $secs -= 1;
  79         }
  80     } else {
  81         Proxmox::UI::finished(1, "Installation complete - reboot now?");
  82     }
  83 }
  84
  85 my $cmd = shift;
  86 if (!$cmd || $cmd eq 'help' || !exists($commands->{$cmd})) {
  87     usage($cmd // '');
  88 }
  89
  90 Proxmox::Log::init("/tmp/install-low-level-${cmd}.log");
  91
  92 my $env = Proxmox::Install::ISOEnv::get();
  93 if ($cmd eq 'dump-env') {
  94
  95     my $out_dir = $env->{locations}->{run};
  96     make_path($out_dir);
  97     die "failed to create output directory '$out_dir'\n" if !-d $out_dir;
  98
  99     my $locales_serialized = to_json($env->{locales}, {canonical => 1, utf8 => 1}) ."\n";
 100     file_write_all("$out_dir/locales.json", $locales_serialized);
 101
 102     my $iso_info = {
 103         'iso-info' => $env->{iso},
 104         'product' => $env->{product},
 105         'product-cfg' => $env->{cfg},
 106         'run-env-cache-file' => $env->{'run-env-cache-file'},
 107         'locations' => $env->{locations},
 108     };
 109     my $iso_serialized = to_json($iso_info, {canonical => 1, utf8 => 1}) ."\n";
 110     file_write_all("$out_dir/iso-info.json", $iso_serialized);
 111
 112     my $run_env_file = Proxmox::Install::ISOEnv::get('run-env-cache-file');
 113
 114     my $run_env = Proxmox::Install::RunEnv::query_installation_environment();
 115     my $run_env_serialized = to_json($run_env, {canonical => 1, utf8 => 1}) ."\n";
 116     file_write_all($run_env_file, $run_env_serialized);
 117 } elsif ($cmd eq 'start-session') {
 118     Proxmox::UI::init_stdio({}, $env);
 119     read_and_merge_config();
 120
 121     eval { Proxmox::Install::extract_data() };
 122     if (my $err = $@) {
 123         # suppress "empty" error as we got some case where the user choose to abort on a prompt,
 124         # there it doesn't make sense to show them an error again, they "caused" it after all.
 125         if ($err ne "\n") {
 126             warn "installation failed - $err\n";
 127             log_error("installation failed: $err");
 128             Proxmox::UI::finished(0, $err);
 129         }
 130     } else {
 131         send_reboot_ui_message();
 132     }
 133 } elsif ($cmd eq 'start-session-test') {
 134     Proxmox::UI::init_stdio({}, $env);
 135     read_and_merge_config();
 136
 137     my $res = Proxmox::UI::prompt("Reply anything?") ? 'ok' : 'not ok';
 138     Proxmox::UI::message("Test Message - got $res");
 139
 140     for (my $i = 1; $i <= 1000; $i += 3) {
 141         Proxmox::UI::progress($i/100000, 0, 100, "foo $i");
 142         if ($i > 500 && $i < 600) {
 143             usleep(50 * 1000);
 144         } else {
 145             usleep(10 * 1000);
 146         }
 147     }
 148
 149     send_reboot_ui_message();
 150 }
 151
 152 exit(0);