PVE/API2/Network/SDN/Controllers.pm

   1 package PVE::API2::Network::SDN::Controllers;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Tools qw(extract_param);
   8 use PVE::Cluster qw(cfs_read_file cfs_write_file);
   9 use PVE::Network::SDN;
  10 use PVE::Network::SDN::Zones;
  11 use PVE::Network::SDN::Controllers;
  12 use PVE::Network::SDN::Controllers::Plugin;
  13 use PVE::Network::SDN::Controllers::EvpnPlugin;
  14 use PVE::Network::SDN::Controllers::FaucetPlugin;
  15
  16 use Storable qw(dclone);
  17 use PVE::JSONSchema qw(get_standard_option);
  18 use PVE::RPCEnvironment;
  19
  20 use PVE::RESTHandler;
  21
  22 use base qw(PVE::RESTHandler);
  23
  24 my $sdn_controllers_type_enum = PVE::Network::SDN::Controllers::Plugin->lookup_types();
  25
  26 my $api_sdn_controllers_config = sub {
  27     my ($cfg, $id) = @_;
  28
  29     my $scfg = dclone(PVE::Network::SDN::Controllers::sdn_controllers_config($cfg, $id));
  30     $scfg->{controller} = $id;
  31     $scfg->{digest} = $cfg->{digest};
  32
  33     return $scfg;
  34 };
  35
  36 __PACKAGE__->register_method ({
  37     name => 'index',
  38     path => '',
  39     method => 'GET',
  40     description => "SDN controllers index.",
  41     permissions => {
  42         description => "Only list entries where you have 'SDN.Audit' or 'SDN.Allocate' permissions on '/sdn/controllers/<controller>'",
  43         user => 'all',
  44     },
  45     parameters => {
  46         additionalProperties => 0,
  47         properties => {
  48             type => {
  49                 description => "Only list sdn controllers of specific type",
  50                 type => 'string',
  51                 enum => $sdn_controllers_type_enum,
  52                 optional => 1,
  53             },
  54             running => {
  55                 type => 'boolean',
  56                 optional => 1,
  57                 description => "Display running config.",
  58             },
  59             pending => {
  60                 type => 'boolean',
  61                 optional => 1,
  62                 description => "Display pending config.",
  63             },
  64         },
  65     },
  66     returns => {
  67         type => 'array',
  68         items => {
  69             type => "object",
  70             properties => { controller => { type => 'string' },
  71                             type => { type => 'string' },
  72                             state => { type => 'string', optional => 1 },
  73                             pending => { optional => 1},
  74             },
  75         },
  76         links => [ { rel => 'child', href => "{controller}" } ],
  77     },
  78     code => sub {
  79         my ($param) = @_;
  80
  81         my $rpcenv = PVE::RPCEnvironment::get();
  82         my $authuser = $rpcenv->get_user();
  83
  84         my $cfg = {};
  85         if($param->{pending}) {
  86             my $running_cfg = PVE::Network::SDN::config();
  87             my $config = PVE::Network::SDN::Controllers::config();
  88             $cfg = PVE::Network::SDN::pending_config($running_cfg, $config, 'controllers');
  89         } elsif ($param->{running}) {
  90             my $running_cfg = PVE::Network::SDN::config();
  91             $cfg = $running_cfg->{controllers};
  92         } else {
  93             $cfg = PVE::Network::SDN::Controllers::config();
  94         }
  95
  96         my @sids = PVE::Network::SDN::Controllers::sdn_controllers_ids($cfg);
  97         my $res = [];
  98         foreach my $id (@sids) {
  99             my $privs = [ 'SDN.Audit', 'SDN.Allocate' ];
 100             next if !$rpcenv->check_any($authuser, "/sdn/controllers/$id", $privs, 1);
 101
 102             my $scfg = &$api_sdn_controllers_config($cfg, $id);
 103             next if $param->{type} && $param->{type} ne $scfg->{type};
 104
 105             my $plugin_config = $cfg->{ids}->{$id};
 106             my $plugin = PVE::Network::SDN::Controllers::Plugin->lookup($plugin_config->{type});
 107             push @$res, $scfg;
 108         }
 109
 110         return $res;
 111     }});
 112
 113 __PACKAGE__->register_method ({
 114     name => 'read',
 115     path => '{controller}',
 116     method => 'GET',
 117     description => "Read sdn controller configuration.",
 118     permissions => {
 119         check => ['perm', '/sdn/controllers/{controller}', ['SDN.Allocate']],
 120    },
 121
 122     parameters => {
 123         additionalProperties => 0,
 124         properties => {
 125             controller => get_standard_option('pve-sdn-controller-id'),
 126             running => {
 127                 type => 'boolean',
 128                 optional => 1,
 129                 description => "Display running config.",
 130             },
 131             pending => {
 132                 type => 'boolean',
 133                 optional => 1,
 134                 description => "Display pending config.",
 135             },
 136         },
 137     },
 138     returns => { type => 'object' },
 139     code => sub {
 140         my ($param) = @_;
 141
 142         my $cfg = {};
 143         if($param->{pending}) {
 144             my $running_cfg = PVE::Network::SDN::config();
 145             my $config = PVE::Network::SDN::Controllers::config();
 146             $cfg = PVE::Network::SDN::pending_config($running_cfg, $config, 'controllers');
 147         } elsif ($param->{running}) {
 148             my $running_cfg = PVE::Network::SDN::config();
 149             $cfg = $running_cfg->{controllers};
 150         } else {
 151             $cfg = PVE::Network::SDN::Controllers::config();
 152         }
 153
 154         return &$api_sdn_controllers_config($cfg, $param->{controller});
 155     }});
 156
 157 __PACKAGE__->register_method ({
 158     name => 'create',
 159     protected => 1,
 160     path => '',
 161     method => 'POST',
 162     description => "Create a new sdn controller object.",
 163     permissions => {
 164         check => ['perm', '/sdn/controllers', ['SDN.Allocate']],
 165     },
 166     parameters => PVE::Network::SDN::Controllers::Plugin->createSchema(),
 167     returns => { type => 'null' },
 168     code => sub {
 169         my ($param) = @_;
 170
 171         my $type = extract_param($param, 'type');
 172         my $id = extract_param($param, 'controller');
 173
 174         my $plugin = PVE::Network::SDN::Controllers::Plugin->lookup($type);
 175         my $opts = $plugin->check_config($id, $param, 1, 1);
 176
 177         # create /etc/pve/sdn directory
 178         PVE::Cluster::check_cfs_quorum();
 179         mkdir("/etc/pve/sdn");
 180
 181         PVE::Network::SDN::lock_sdn_config(
 182             sub {
 183
 184                 my $controller_cfg = PVE::Network::SDN::Controllers::config();
 185
 186                 my $scfg = undef;
 187                 if ($scfg = PVE::Network::SDN::Controllers::sdn_controllers_config($controller_cfg, $id, 1)) {
 188                     die "sdn controller object ID '$id' already defined\n";
 189                 }
 190
 191                 $controller_cfg->{ids}->{$id} = $opts;
 192                 $plugin->on_update_hook($id, $controller_cfg);
 193
 194                 PVE::Network::SDN::Controllers::write_config($controller_cfg);
 195
 196             }, "create sdn controller object failed");
 197
 198         return undef;
 199     }});
 200
 201 __PACKAGE__->register_method ({
 202     name => 'update',
 203     protected => 1,
 204     path => '{controller}',
 205     method => 'PUT',
 206     description => "Update sdn controller object configuration.",
 207     permissions => {
 208         check => ['perm', '/sdn/controllers', ['SDN.Allocate']],
 209     },
 210     parameters => PVE::Network::SDN::Controllers::Plugin->updateSchema(),
 211     returns => { type => 'null' },
 212     code => sub {
 213         my ($param) = @_;
 214
 215         my $id = extract_param($param, 'controller');
 216         my $digest = extract_param($param, 'digest');
 217
 218         PVE::Network::SDN::lock_sdn_config(
 219          sub {
 220
 221             my $controller_cfg = PVE::Network::SDN::Controllers::config();
 222
 223             PVE::SectionConfig::assert_if_modified($controller_cfg, $digest);
 224
 225             my $scfg = PVE::Network::SDN::Controllers::sdn_controllers_config($controller_cfg, $id);
 226
 227             my $plugin = PVE::Network::SDN::Controllers::Plugin->lookup($scfg->{type});
 228             my $opts = $plugin->check_config($id, $param, 0, 1);
 229
 230             foreach my $k (%$opts) {
 231                 $scfg->{$k} = $opts->{$k};
 232             }
 233
 234             $plugin->on_update_hook($id, $controller_cfg);
 235
 236             PVE::Network::SDN::Controllers::write_config($controller_cfg);
 237
 238
 239             }, "update sdn controller object failed");
 240
 241         return undef;
 242     }});
 243
 244 __PACKAGE__->register_method ({
 245     name => 'delete',
 246     protected => 1,
 247     path => '{controller}',
 248     method => 'DELETE',
 249     description => "Delete sdn controller object configuration.",
 250     permissions => {
 251         check => ['perm', '/sdn/controllers', ['SDN.Allocate']],
 252     },
 253     parameters => {
 254         additionalProperties => 0,
 255         properties => {
 256             controller => get_standard_option('pve-sdn-controller-id', {
 257                 completion => \&PVE::Network::SDN::Controllers::complete_sdn_controllers,
 258             }),
 259         },
 260     },
 261     returns => { type => 'null' },
 262     code => sub {
 263         my ($param) = @_;
 264
 265         my $id = extract_param($param, 'controller');
 266
 267         PVE::Network::SDN::lock_sdn_config(
 268             sub {
 269
 270                 my $cfg = PVE::Network::SDN::Controllers::config();
 271
 272                 my $scfg = PVE::Network::SDN::Controllers::sdn_controllers_config($cfg, $id);
 273
 274                 my $plugin = PVE::Network::SDN::Controllers::Plugin->lookup($scfg->{type});
 275
 276                 my $zone_cfg = PVE::Network::SDN::Zones::config();
 277
 278                 $plugin->on_delete_hook($id, $zone_cfg);
 279
 280                 delete $cfg->{ids}->{$id};
 281                 PVE::Network::SDN::Controllers::write_config($cfg);
 282
 283             }, "delete sdn controller object failed");
 284
 285
 286         return undef;
 287     }});
 288
 289 1;