PVE/API2/Network/SDN/Vnets.pm

   1 package PVE::API2::Network::SDN::Vnets;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Tools qw(extract_param);
   8 use PVE::Cluster qw(cfs_read_file cfs_write_file);
   9 use PVE::Network::SDN;
  10 use PVE::Network::SDN::Zones;
  11 use PVE::Network::SDN::Zones::Plugin;
  12 use PVE::Network::SDN::Vnets;
  13 use PVE::Network::SDN::VnetPlugin;
  14 use PVE::Network::SDN::Subnets;
  15 use PVE::API2::Network::SDN::Subnets;
  16
  17 use Storable qw(dclone);
  18 use PVE::JSONSchema qw(get_standard_option);
  19 use PVE::RPCEnvironment;
  20 use PVE::Exception qw(raise raise_param_exc);
  21
  22 use PVE::RESTHandler;
  23
  24 use base qw(PVE::RESTHandler);
  25
  26 __PACKAGE__->register_method ({
  27     subclass => "PVE::API2::Network::SDN::Subnets",
  28     path => '{vnet}/subnets',
  29 });
  30
  31 my $api_sdn_vnets_config = sub {
  32     my ($cfg, $id) = @_;
  33
  34     my $scfg = dclone(PVE::Network::SDN::Vnets::sdn_vnets_config($cfg, $id));
  35     $scfg->{vnet} = $id;
  36     $scfg->{digest} = $cfg->{digest};
  37
  38     return $scfg;
  39 };
  40
  41 my $api_sdn_vnets_deleted_config = sub {
  42     my ($cfg, $running_cfg, $id) = @_;
  43
  44     if (!$cfg->{ids}->{$id}) {
  45
  46         my $vnet_cfg = dclone(PVE::Network::SDN::Vnets::sdn_vnets_config($running_cfg->{vnets}, $id));
  47         $vnet_cfg->{state} = "deleted";
  48         $vnet_cfg->{vnet} = $id;
  49         return $vnet_cfg;
  50     }
  51 };
  52
  53 __PACKAGE__->register_method ({
  54     name => 'index',
  55     path => '',
  56     method => 'GET',
  57     description => "SDN vnets index.",
  58     permissions => {
  59         description => "Only list entries where you have 'SDN.Audit' or 'SDN.Allocate'"
  60             ." permissions on '/sdn/vnets/<vnet>'",
  61         user => 'all',
  62     },
  63     parameters => {
  64         additionalProperties => 0,
  65         properties => {
  66             running => {
  67                 type => 'boolean',
  68                 optional => 1,
  69                 description => "Display running config.",
  70             },
  71             pending => {
  72                 type => 'boolean',
  73                 optional => 1,
  74                 description => "Display pending config.",
  75             },
  76         },
  77     },
  78     returns => {
  79         type => 'array',
  80         items => {
  81             type => "object",
  82             properties => {},
  83         },
  84         links => [ { rel => 'child', href => "{vnet}" } ],
  85     },
  86     code => sub {
  87         my ($param) = @_;
  88
  89         my $rpcenv = PVE::RPCEnvironment::get();
  90         my $authuser = $rpcenv->get_user();
  91
  92         my $cfg = {};
  93         if($param->{pending}) {
  94             my $running_cfg = PVE::Network::SDN::config();
  95             my $config = PVE::Network::SDN::Vnets::config();
  96             $cfg = PVE::Network::SDN::pending_config($running_cfg, $config, 'vnets');
  97         } elsif ($param->{running}) {
  98             my $running_cfg = PVE::Network::SDN::config();
  99             $cfg = $running_cfg->{vnets};
 100         } else {
 101             $cfg = PVE::Network::SDN::Vnets::config();
 102         }
 103
 104         my @sids = PVE::Network::SDN::Vnets::sdn_vnets_ids($cfg);
 105         my $res = [];
 106         foreach my $id (@sids) {
 107             my $privs = [ 'SDN.Audit', 'SDN.Allocate' ];
 108             next if !$rpcenv->check_any($authuser, "/sdn/vnets/$id", $privs, 1);
 109
 110             my $scfg = &$api_sdn_vnets_config($cfg, $id);
 111             push @$res, $scfg;
 112         }
 113
 114         return $res;
 115     }});
 116
 117 __PACKAGE__->register_method ({
 118     name => 'read',
 119     path => '{vnet}',
 120     method => 'GET',
 121     description => "Read sdn vnet configuration.",
 122     permissions => {
 123         check => ['perm', '/sdn/vnets/{vnet}', ['SDN.Allocate']],
 124    },
 125     parameters => {
 126         additionalProperties => 0,
 127         properties => {
 128             vnet => get_standard_option('pve-sdn-vnet-id', {
 129                 completion => \&PVE::Network::SDN::Vnets::complete_sdn_vnets,
 130             }),
 131             running => {
 132                 type => 'boolean',
 133                 optional => 1,
 134                 description => "Display running config.",
 135             },
 136             pending => {
 137                 type => 'boolean',
 138                 optional => 1,
 139                 description => "Display pending config.",
 140             },
 141         },
 142     },
 143     returns => { type => 'object' },
 144     code => sub {
 145         my ($param) = @_;
 146
 147         my $cfg = {};
 148         if($param->{pending}) {
 149             my $running_cfg = PVE::Network::SDN::config();
 150             my $config = PVE::Network::SDN::Vnets::config();
 151             $cfg = PVE::Network::SDN::pending_config($running_cfg, $config, 'vnets');
 152         } elsif ($param->{running}) {
 153             my $running_cfg = PVE::Network::SDN::config();
 154             $cfg = $running_cfg->{vnets};
 155         } else {
 156             $cfg = PVE::Network::SDN::Vnets::config();
 157         }
 158
 159         return $api_sdn_vnets_config->($cfg, $param->{vnet});
 160     }});
 161
 162 __PACKAGE__->register_method ({
 163     name => 'create',
 164     protected => 1,
 165     path => '',
 166     method => 'POST',
 167     description => "Create a new sdn vnet object.",
 168     permissions => {
 169         check => ['perm', '/sdn/vnets', ['SDN.Allocate']],
 170     },
 171     parameters => PVE::Network::SDN::VnetPlugin->createSchema(),
 172     returns => { type => 'null' },
 173     code => sub {
 174         my ($param) = @_;
 175
 176         my $type = extract_param($param, 'type');
 177         my $id = extract_param($param, 'vnet');
 178
 179         PVE::Cluster::check_cfs_quorum();
 180         mkdir("/etc/pve/sdn");
 181
 182         PVE::Network::SDN::lock_sdn_config(sub {
 183             my $cfg = PVE::Network::SDN::Vnets::config();
 184             my $opts = PVE::Network::SDN::VnetPlugin->check_config($id, $param, 1, 1);
 185
 186             if (PVE::Network::SDN::Vnets::sdn_vnets_config($cfg, $id, 1)) {
 187                 die "sdn vnet object ID '$id' already defined\n";
 188             }
 189             $cfg->{ids}->{$id} = $opts;
 190
 191             my $zone_cfg = PVE::Network::SDN::Zones::config();
 192             my $zoneid = $cfg->{ids}->{$id}->{zone};
 193             my $plugin_config = $zone_cfg->{ids}->{$zoneid};
 194             my $plugin = PVE::Network::SDN::Zones::Plugin->lookup($plugin_config->{type});
 195             $plugin->vnet_update_hook($cfg, $id, $zone_cfg);
 196
 197             PVE::Network::SDN::VnetPlugin->on_update_hook($id, $cfg);
 198
 199             PVE::Network::SDN::Vnets::write_config($cfg);
 200
 201         }, "create sdn vnet object failed");
 202
 203         return undef;
 204     }});
 205
 206 __PACKAGE__->register_method ({
 207     name => 'update',
 208     protected => 1,
 209     path => '{vnet}',
 210     method => 'PUT',
 211     description => "Update sdn vnet object configuration.",
 212     permissions => {
 213         check => ['perm', '/sdn/vnets', ['SDN.Allocate']],
 214     },
 215     parameters => PVE::Network::SDN::VnetPlugin->updateSchema(),
 216     returns => { type => 'null' },
 217     code => sub {
 218         my ($param) = @_;
 219
 220         my $id = extract_param($param, 'vnet');
 221         my $digest = extract_param($param, 'digest');
 222
 223         PVE::Network::SDN::lock_sdn_config(sub {
 224             my $cfg = PVE::Network::SDN::Vnets::config();
 225
 226             PVE::SectionConfig::assert_if_modified($cfg, $digest);
 227
 228
 229             my $opts = PVE::Network::SDN::VnetPlugin->check_config($id, $param, 0, 1);
 230             raise_param_exc({ zone => "missing zone"}) if !$opts->{zone};
 231             my $subnets = PVE::Network::SDN::Vnets::get_subnets($id);
 232             raise_param_exc({ zone => "can't change zone if subnets exists"}) if($subnets && $opts->{zone} ne $cfg->{ids}->{$id}->{zone});
 233
 234             $cfg->{ids}->{$id} = $opts;
 235
 236             my $zone_cfg = PVE::Network::SDN::Zones::config();
 237             my $zoneid = $cfg->{ids}->{$id}->{zone};
 238             my $plugin_config = $zone_cfg->{ids}->{$zoneid};
 239             my $plugin = PVE::Network::SDN::Zones::Plugin->lookup($plugin_config->{type});
 240             $plugin->vnet_update_hook($cfg, $id, $zone_cfg);
 241
 242             PVE::Network::SDN::VnetPlugin->on_update_hook($id, $cfg);
 243
 244             PVE::Network::SDN::Vnets::write_config($cfg);
 245
 246         }, "update sdn vnet object failed");
 247
 248         return undef;
 249     }
 250 });
 251
 252 __PACKAGE__->register_method ({
 253     name => 'delete',
 254     protected => 1,
 255     path => '{vnet}',
 256     method => 'DELETE',
 257     description => "Delete sdn vnet object configuration.",
 258     permissions => {
 259         check => ['perm', '/sdn/vnets', ['SDN.Allocate']],
 260     },
 261     parameters => {
 262         additionalProperties => 0,
 263         properties => {
 264             vnet => get_standard_option('pve-sdn-vnet-id', {
 265                 completion => \&PVE::Network::SDN::Vnets::complete_sdn_vnets,
 266             }),
 267         },
 268     },
 269     returns => { type => 'null' },
 270     code => sub {
 271         my ($param) = @_;
 272
 273         my $id = extract_param($param, 'vnet');
 274
 275         PVE::Network::SDN::lock_sdn_config(sub {
 276             my $cfg = PVE::Network::SDN::Vnets::config();
 277             my $scfg = PVE::Network::SDN::Vnets::sdn_vnets_config($cfg, $id); # check if exists
 278             my $vnet_cfg = PVE::Network::SDN::Vnets::config();
 279
 280             PVE::Network::SDN::VnetPlugin->on_delete_hook($id, $vnet_cfg);
 281
 282             delete $cfg->{ids}->{$id};
 283             PVE::Network::SDN::Vnets::write_config($cfg);
 284
 285         }, "delete sdn vnet object failed");
 286
 287
 288         return undef;
 289     }
 290 });
 291
 292 1;