PVE/Network/SDN.pm

   1 package PVE::Network::SDN;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Data::Dumper;
   7 use JSON;
   8
   9 use PVE::Network::SDN::Vnets;
  10 use PVE::Network::SDN::Zones;
  11 use PVE::Network::SDN::Controllers;
  12 use PVE::Network::SDN::Subnets;
  13
  14 use PVE::Tools qw(extract_param dir_glob_regex run_command);
  15 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  16
  17
  18 my $running_cfg = "sdn/.running-config";
  19
  20 my $parse_running_cfg = sub {
  21     my ($filename, $raw) = @_;
  22
  23     my $cfg = {};
  24
  25     return $cfg if !defined($raw) || $raw eq '';
  26
  27     eval {
  28         $cfg = from_json($raw);
  29     };
  30     return {} if $@;
  31
  32     return $cfg;
  33 };
  34
  35 my $write_running_cfg = sub {
  36     my ($filename, $cfg) = @_;
  37
  38     my $json = to_json($cfg);
  39
  40     return $json;
  41 };
  42
  43 PVE::Cluster::cfs_register_file($running_cfg, $parse_running_cfg, $write_running_cfg);
  44
  45
  46 # improve me : move status code inside plugins ?
  47
  48 sub ifquery_check {
  49
  50     my $cmd = ['ifquery', '-a', '-c', '-o','json'];
  51
  52     my $result = '';
  53     my $reader = sub { $result .= shift };
  54
  55     eval {
  56         run_command($cmd, outfunc => $reader);
  57     };
  58
  59     my $resultjson = decode_json($result);
  60     my $interfaces = {};
  61
  62     foreach my $interface (@$resultjson) {
  63         my $name = $interface->{name};
  64         $interfaces->{$name} = {
  65             status => $interface->{status},
  66             config => $interface->{config},
  67             config_status => $interface->{config_status},
  68         };
  69     }
  70
  71     return $interfaces;
  72 }
  73
  74 sub status {
  75
  76     my ($zone_status, $vnet_status) = PVE::Network::SDN::Zones::status();
  77     return($zone_status, $vnet_status);
  78 }
  79
  80 sub config {
  81     return cfs_read_file($running_cfg);
  82 }
  83
  84 sub pending_config {
  85     my ($running_cfg, $cfg, $type) = @_;
  86
  87     my $pending = {};
  88
  89     my $running_objects = $running_cfg->{$type}->{ids};
  90     my $config_objects = $cfg->{ids};
  91
  92     foreach my $id (sort keys %{$running_objects}) {
  93         my $running_object = $running_objects->{$id};
  94         my $config_object = $config_objects->{$id};
  95         foreach my $key (sort keys %{$running_object}) {
  96             $pending->{$id}->{$key} = $running_object->{$key};
  97             if(!keys %{$config_object}) {
  98                 $pending->{$id}->{state} = "deleted";
  99             } elsif ($running_object->{$key} ne $config_object->{$key}) {
 100                 $pending->{$id}->{state} = "changed";
 101             }
 102         }
 103     }
 104
 105    foreach my $id (sort keys %{$config_objects}) {
 106         my $running_object = $running_objects->{$id};
 107         my $config_object = $config_objects->{$id};
 108
 109         foreach my $key (sort keys %{$config_object}) {
 110             my $config_value = $config_object->{$key} if $config_object->{$key};
 111             my $running_value = $running_object->{$key} if $running_object->{$key};
 112             if($key eq 'type' || $key eq 'vnet') {
 113                 $pending->{$id}->{$key} = $config_value;
 114             } else {
 115                 $pending->{$id}->{"pending"}->{$key} = $config_value if !defined($running_value) || ($config_value ne $running_value);
 116             }
 117             if(!keys %{$running_object}) {
 118                 $pending->{$id}->{state} = "new";
 119             } elsif (!defined($running_value) && defined($config_value)) {
 120                 $pending->{$id}->{state} = "changed";
 121             }
 122         }
 123    }
 124
 125    return {ids => $pending};
 126
 127 }
 128
 129 sub commit_config {
 130
 131     my $cfg = cfs_read_file($running_cfg);
 132     my $version = $cfg->{version};
 133
 134     if ($version) {
 135         $version++;
 136     } else {
 137         $version = 1;
 138     }
 139
 140     my $vnets_cfg = PVE::Network::SDN::Vnets::config();
 141     my $zones_cfg = PVE::Network::SDN::Zones::config();
 142     my $controllers_cfg = PVE::Network::SDN::Controllers::config();
 143     my $subnets_cfg = PVE::Network::SDN::Subnets::config();
 144
 145     my $vnets = { ids => $vnets_cfg->{ids} };
 146     my $zones = { ids => $zones_cfg->{ids} };
 147     my $controllers = { ids => $controllers_cfg->{ids} };
 148     my $subnets = { ids => $subnets_cfg->{ids} };
 149
 150      $cfg = { version => $version, vnets => $vnets, zones => $zones, controllers => $controllers, subnets => $subnets };
 151
 152     cfs_write_file($running_cfg, $cfg);
 153 }
 154
 155 sub lock_sdn_config {
 156     my ($code, $errmsg) = @_;
 157
 158     cfs_lock_file($running_cfg, undef, $code);
 159
 160     if (my $err = $@) {
 161         $errmsg ? die "$errmsg: $err" : die $err;
 162     }
 163 }
 164
 165 sub get_local_vnets {
 166
 167     my $rpcenv = PVE::RPCEnvironment::get();
 168
 169     my $authuser = $rpcenv->get_user();
 170
 171     my $nodename = PVE::INotify::nodename();
 172
 173     my $cfg = PVE::Network::SDN::config();
 174     my $vnets_cfg = $cfg->{vnets};
 175     my $zones_cfg = $cfg->{zones};
 176
 177     my @vnetids = PVE::Network::SDN::Vnets::sdn_vnets_ids($vnets_cfg);
 178
 179     my $vnets = {};
 180
 181     foreach my $vnetid (@vnetids) {
 182
 183         my $vnet = PVE::Network::SDN::Vnets::sdn_vnets_config($vnets_cfg, $vnetid);
 184         my $zoneid = $vnet->{zone};
 185         my $privs = [ 'SDN.Audit', 'SDN.Allocate' ];
 186
 187         next if !$zoneid;
 188         next if !$rpcenv->check_any($authuser, "/sdn/zones/$zoneid", $privs, 1);
 189
 190         my $zone_config = PVE::Network::SDN::Zones::sdn_zones_config($zones_cfg, $zoneid);
 191
 192         next if defined($zone_config->{nodes}) && !$zone_config->{nodes}->{$nodename};
 193         $vnets->{$vnetid} = { type => 'vnet', active => '1' };
 194     }
 195
 196     return $vnets;
 197 }
 198
 199 sub generate_zone_config {
 200     my $raw_config = PVE::Network::SDN::Zones::generate_etc_network_config();
 201     PVE::Network::SDN::Zones::write_etc_network_config($raw_config);
 202 }
 203
 204 sub generate_controller_config {
 205     my ($reload) = @_;
 206
 207     my $raw_config = PVE::Network::SDN::Controllers::generate_controller_config();
 208     PVE::Network::SDN::Controllers::write_controller_config($raw_config);
 209
 210     PVE::Network::SDN::Controllers::reload_controller() if $reload;
 211 }
 212
 213 1;
 214