PVE/Network/SDN/Controllers/EvpnPlugin.pm

   1 package PVE::Network::SDN::Controllers::EvpnPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::INotify;
   7 use PVE::JSONSchema qw(get_standard_option);
   8 use PVE::Tools qw(run_command file_set_contents file_get_contents);
   9
  10 use PVE::Network::SDN::Controllers::Plugin;
  11 use PVE::Network::SDN::Zones::Plugin;
  12 use Net::IP;
  13
  14 use base('PVE::Network::SDN::Controllers::Plugin');
  15
  16 sub type {
  17     return 'evpn';
  18 }
  19
  20 sub properties {
  21     return {
  22         asn => {
  23             type => 'integer',
  24             description => "autonomous system number",
  25         },
  26         peers => {
  27             description => "peers address list.",
  28             type => 'string', format => 'ip-list'
  29         },
  30     };
  31 }
  32
  33 sub options {
  34     return {
  35         'asn' => { optional => 0 },
  36         'peers' => { optional => 0 },
  37     };
  38 }
  39
  40 # Plugin implementation
  41 sub generate_controller_config {
  42     my ($class, $plugin_config, $controller_cfg, $id, $uplinks, $config) = @_;
  43
  44     my @peers;
  45     @peers = PVE::Tools::split_list($plugin_config->{'peers'}) if $plugin_config->{'peers'};
  46
  47     my $local_node = PVE::INotify::nodename();
  48
  49     my $asn = $plugin_config->{asn};
  50     my $ebgp = undef;
  51     my $loopback = undef;
  52     my $autortas = undef;
  53     my $bgprouter = find_bgp_controller($local_node, $controller_cfg);
  54     if($bgprouter) {
  55         $ebgp = 1 if $plugin_config->{'asn'} ne $bgprouter->{asn};
  56         $loopback = $bgprouter->{loopback} if $bgprouter->{loopback};
  57         $asn = $bgprouter->{asn} if $bgprouter->{asn};
  58         $autortas = $plugin_config->{'asn'} if $ebgp;
  59     }
  60
  61     return if !$asn;
  62
  63     my $bgp = $config->{frr}->{router}->{"bgp $asn"} //= {};
  64
  65     my ($ifaceip, $interface) = PVE::Network::SDN::Zones::Plugin::find_local_ip_interface_peers(\@peers, $loopback);
  66
  67     my $remoteas = $ebgp ? "external" : $asn;
  68
  69     #global options
  70     my @controller_config = (
  71         "bgp router-id $ifaceip",
  72         "no bgp default ipv4-unicast",
  73         "coalesce-time 1000",
  74     );
  75
  76     push(@{$bgp->{""}}, @controller_config) if keys %{$bgp} == 0;
  77
  78     @controller_config = ();
  79
  80     #VTEP neighbors
  81     push @controller_config, "neighbor VTEP peer-group";
  82     push @controller_config, "neighbor VTEP remote-as $remoteas";
  83     push @controller_config, "neighbor VTEP bfd";
  84
  85     if($ebgp && $loopback) {
  86         push @controller_config, "neighbor VTEP ebgp-multihop 10";
  87         push @controller_config, "neighbor VTEP update-source $loopback";
  88     }
  89
  90     # VTEP peers
  91     foreach my $address (@peers) {
  92         next if $address eq $ifaceip;
  93         push @controller_config, "neighbor $address peer-group VTEP";
  94     }
  95
  96     push(@{$bgp->{""}}, @controller_config);
  97
  98     # address-family l2vpn
  99     @controller_config = ();
 100     push @controller_config, "neighbor VTEP activate";
 101     push @controller_config, "advertise-all-vni";
 102     push @controller_config, "autort as $autortas" if $autortas;
 103     push(@{$bgp->{"address-family"}->{"l2vpn evpn"}}, @controller_config);
 104
 105     return $config;
 106 }
 107
 108 sub generate_controller_zone_config {
 109     my ($class, $plugin_config, $controller, $controller_cfg, $id, $uplinks, $config) = @_;
 110
 111     my $local_node = PVE::INotify::nodename();
 112
 113     my $vrf = "vrf_$id";
 114     my $vrfvxlan = $plugin_config->{'vrf-vxlan'};
 115     my $exitnodes = $plugin_config->{'exitnodes'};
 116
 117     my $asn = $controller->{asn};
 118     my $ebgp = undef;
 119     my $loopback = undef;
 120     my $autortas = undef;
 121     my $bgprouter = find_bgp_controller($local_node, $controller_cfg);
 122     if($bgprouter) {
 123         $ebgp = 1 if $controller->{'asn'} ne $bgprouter->{asn};
 124         $loopback = $bgprouter->{loopback} if $bgprouter->{loopback};
 125         $asn = $bgprouter->{asn} if $bgprouter->{asn};
 126         $autortas = $controller->{'asn'} if $ebgp;
 127     }
 128
 129     return if !$vrf || !$vrfvxlan || !$asn;
 130
 131     # vrf
 132     my @controller_config = ();
 133     push @controller_config, "vni $vrfvxlan";
 134     push(@{$config->{frr}->{vrf}->{"$vrf"}}, @controller_config);
 135
 136     #main vrf router
 137     @controller_config = ();
 138     push @controller_config, "no bgp ebgp-requires-policy" if $ebgp;
 139 #    push @controller_config, "!";
 140     push(@{$config->{frr}->{router}->{"bgp $asn vrf $vrf"}->{""}}, @controller_config);
 141
 142     if ($autortas) {
 143         push(@{$config->{frr}->{router}->{"bgp $asn vrf $vrf"}->{"address-family"}->{"l2vpn evpn"}}, "route-target import $autortas:$vrfvxlan");
 144         push(@{$config->{frr}->{router}->{"bgp $asn vrf $vrf"}->{"address-family"}->{"l2vpn evpn"}}, "route-target export $autortas:$vrfvxlan");
 145     }
 146
 147     my $is_gateway = grep { $_ eq $local_node } PVE::Tools::split_list($exitnodes);
 148     if ($is_gateway) {
 149
 150         @controller_config = ();
 151         #import /32 routes of evpn network from vrf1 to default vrf (for packet return)
 152         push @controller_config, "import vrf $vrf";
 153         push(@{$config->{frr}->{router}->{"bgp $asn"}->{"address-family"}->{"ipv4 unicast"}}, @controller_config);
 154         push(@{$config->{frr}->{router}->{"bgp $asn"}->{"address-family"}->{"ipv6 unicast"}}, @controller_config);
 155
 156         @controller_config = ();
 157         #redistribute connected to be able to route to local vms on the gateway
 158         push @controller_config, "redistribute connected";
 159         push(@{$config->{frr}->{router}->{"bgp $asn vrf $vrf"}->{"address-family"}->{"ipv4 unicast"}}, @controller_config);
 160         push(@{$config->{frr}->{router}->{"bgp $asn vrf $vrf"}->{"address-family"}->{"ipv6 unicast"}}, @controller_config);
 161
 162         @controller_config = ();
 163         #add default originate to announce 0.0.0.0/0 type5 route in evpn
 164         push @controller_config, "default-originate ipv4";
 165         push @controller_config, "default-originate ipv6";
 166         push(@{$config->{frr}->{router}->{"bgp $asn vrf $vrf"}->{"address-family"}->{"l2vpn evpn"}}, @controller_config);
 167     }
 168
 169     return $config;
 170 }
 171
 172 sub on_delete_hook {
 173     my ($class, $controllerid, $zone_cfg) = @_;
 174
 175     # verify that zone is associated to this controller
 176     foreach my $id (keys %{$zone_cfg->{ids}}) {
 177         my $zone = $zone_cfg->{ids}->{$id};
 178         die "controller $controllerid is used by $id"
 179             if (defined($zone->{controller}) && $zone->{controller} eq $controllerid);
 180     }
 181 }
 182
 183 sub on_update_hook {
 184     my ($class, $controllerid, $controller_cfg) = @_;
 185
 186     # we can only have 1 evpn controller / 1 asn by server
 187
 188     my $controllernb = 0;
 189     foreach my $id (keys %{$controller_cfg->{ids}}) {
 190         next if $id eq $controllerid;
 191         my $controller = $controller_cfg->{ids}->{$id};
 192         next if $controller->{type} ne "evpn";
 193         $controllernb++;
 194         die "only 1 global evpn controller can be defined" if $controllernb > 1;
 195     }
 196 }
 197
 198 sub find_bgp_controller {
 199     my ($nodename, $controller_cfg) = @_;
 200
 201     my $controller = undef;
 202     foreach my $id  (keys %{$controller_cfg->{ids}}) {
 203         $controller = $controller_cfg->{ids}->{$id};
 204         next if $controller->{type} ne 'bgp';
 205         next if $controller->{node} ne $nodename;
 206         last;
 207     }
 208
 209     return $controller;
 210 }
 211
 212
 213 sub sort_frr_config {
 214     my $order = {};
 215     $order->{''} = 0;
 216     $order->{'vrf'} = 1;
 217     $order->{'ipv4 unicast'} = 1;
 218     $order->{'ipv6 unicast'} = 2;
 219     $order->{'l2vpn evpn'} = 3;
 220
 221     my $a_val = 100;
 222     my $b_val = 100;
 223
 224     $a_val = $order->{$a} if defined($order->{$a});
 225     $b_val = $order->{$b} if defined($order->{$b});
 226
 227     if ($a =~ /bgp (\d+)$/) {
 228         $a_val = 2;
 229     }
 230
 231     if ($b =~ /bgp (\d+)$/) {
 232         $b_val = 2;
 233     }
 234
 235     return $a_val <=> $b_val;
 236 }
 237
 238 sub generate_frr_recurse{
 239    my ($final_config, $content, $parentkey, $level) = @_;
 240
 241    my $keylist = {};
 242    $keylist->{vrf} = 1;
 243    $keylist->{'address-family'} = 1;
 244    $keylist->{router} = 1;
 245
 246    my $exitkeylist = {};
 247    $exitkeylist->{vrf} = 1;
 248    $exitkeylist->{'address-family'} = 1;
 249
 250    # FIXME: make this generic
 251    my $paddinglevel = undef;
 252    if ($level == 1 || $level == 2) {
 253         $paddinglevel = $level - 1;
 254    } elsif ($level == 3 || $level ==  4) {
 255         $paddinglevel = $level - 2;
 256    }
 257
 258    my $padding = "";
 259    $padding = ' ' x ($paddinglevel) if $paddinglevel;
 260
 261    if (ref $content eq  'HASH') {
 262         foreach my $key (sort sort_frr_config keys %$content) {
 263             if ($parentkey && defined($keylist->{$parentkey})) {
 264                 push @{$final_config}, $padding."!";
 265                 push @{$final_config}, $padding."$parentkey $key";
 266             } elsif ($key ne '' && !defined($keylist->{$key})) {
 267                 push @{$final_config}, $padding."$key";
 268             }
 269
 270             my $option = $content->{$key};
 271             generate_frr_recurse($final_config, $option, $key, $level+1);
 272
 273             push @{$final_config}, $padding."exit-$parentkey" if $parentkey && defined($exitkeylist->{$parentkey});
 274         }
 275     }
 276
 277     if (ref $content eq 'ARRAY') {
 278         push @{$final_config}, map { $padding . "$_" } @$content;
 279     }
 280 }
 281
 282 sub write_controller_config {
 283     my ($class, $plugin_config, $config) = @_;
 284
 285     my $nodename = PVE::INotify::nodename();
 286
 287     my $final_config = [];
 288     push @{$final_config}, "log syslog informational";
 289     push @{$final_config}, "ip forwarding";
 290     push @{$final_config}, "ipv6 forwarding";
 291     push @{$final_config}, "frr defaults datacenter";
 292     push @{$final_config}, "service integrated-vtysh-config";
 293     push @{$final_config}, "hostname $nodename";
 294     push @{$final_config}, "!";
 295
 296     if (-e "/etc/frr/frr.conf.local") {
 297         generate_frr_recurse($final_config, $config->{frr}->{vrf}, "vrf", 1);
 298         push @{$final_config}, "!";
 299
 300         my $local_conf = file_get_contents("/etc/frr/frr.conf.local");
 301         chomp ($local_conf);
 302         push @{$final_config}, $local_conf;
 303     } else {
 304         generate_frr_recurse($final_config, $config->{frr}, undef, 0);
 305     }
 306
 307     push @{$final_config}, "!";
 308     push @{$final_config}, "line vty";
 309     push @{$final_config}, "!";
 310
 311     my $rawconfig = join("\n", @{$final_config});
 312
 313     return if !$rawconfig;
 314     return if !-d "/etc/frr";
 315
 316     file_set_contents("/etc/frr/frr.conf", $rawconfig);
 317 }
 318
 319 sub reload_controller {
 320     my ($class) = @_;
 321
 322     my $conf_file = "/etc/frr/frr.conf";
 323     my $bin_path = "/usr/lib/frr/frr-reload.py";
 324
 325     if (!-e $bin_path) {
 326         warn "missing $bin_path. Please install frr-pythontools package";
 327         return;
 328     }
 329
 330     my $err = sub {
 331         my $line = shift;
 332         if ($line =~ /ERROR:/) {
 333             warn "$line \n";
 334         }
 335     };
 336
 337     if (-e $conf_file && -e $bin_path) {
 338         run_command([$bin_path, '--stdout', '--reload', $conf_file], outfunc => {}, errfunc => $err);
 339     }
 340 }
 341
 342 1;
 343
 344