PVE/Network/SDN/Plugin.pm

   1 package PVE::Network::SDN::Plugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Tools;
   7 use PVE::JSONSchema;
   8 use PVE::Cluster;
   9
  10 use Data::Dumper;
  11 use PVE::JSONSchema qw(get_standard_option);
  12 use base qw(PVE::SectionConfig);
  13
  14 PVE::Cluster::cfs_register_file('sdn.cfg',
  15                                  sub { __PACKAGE__->parse_config(@_); });
  16
  17 PVE::Cluster::cfs_register_file('sdn.cfg.new',
  18                                  sub { __PACKAGE__->parse_config(@_); },
  19                                  sub { __PACKAGE__->write_config(@_); });
  20
  21 PVE::JSONSchema::register_standard_option('pve-sdn-id', {
  22     description => "The SDN object identifier.",
  23     type => 'string', format => 'pve-sdn-id',
  24 });
  25
  26 PVE::JSONSchema::register_format('pve-sdn-id', \&parse_sdn_id);
  27 sub parse_sdn_id {
  28     my ($sdnid, $noerr) = @_;
  29
  30     if ($sdnid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
  31         return undef if $noerr;
  32         die "SDN object ID '$sdnid' contains illegal characters\n";
  33     }
  34     return $sdnid;
  35 }
  36
  37 my $defaultData = {
  38
  39     propertyList => {
  40         type => {
  41             description => "Plugin type.",
  42             type => 'string', format => 'pve-configid',
  43             type => 'string',
  44         },
  45         sdn => get_standard_option('pve-sdn-id',
  46             { completion => \&PVE::Network::SDN::complete_sdn }),
  47     },
  48 };
  49
  50 sub private {
  51     return $defaultData;
  52 }
  53
  54 sub parse_section_header {
  55     my ($class, $line) = @_;
  56
  57     if ($line =~ m/^(\S+):\s*(\S+)\s*$/) {
  58         my ($type, $sdnid) = (lc($1), $2);
  59         my $errmsg = undef; # set if you want to skip whole section
  60         eval { PVE::JSONSchema::pve_verify_configid($type); };
  61         $errmsg = $@ if $@;
  62         my $config = {}; # to return additional attributes
  63         return ($type, $sdnid, $errmsg, $config);
  64     }
  65     return undef;
  66 }
  67
  68 sub generate_sdn_config {
  69     my ($class, $plugin_config, $node, $data, $ctime) = @_;
  70
  71     die "please implement inside plugin";
  72 }
  73
  74 sub on_delete_hook {
  75     my ($class, $sndid, $scfg) = @_;
  76
  77     # do nothing by default
  78 }
  79
  80 sub on_update_hook {
  81     my ($class, $sdnid, $scfg) = @_;
  82
  83     # do nothing by default
  84 }
  85
  86 #helpers
  87 sub parse_tag_number_or_range {
  88     my ($str, $max, $tag) = @_;
  89
  90     my @elements = split(/,/, $str);
  91     my $count = 0;
  92     my $allowed = undef;
  93
  94     die "extraneous commas in list\n" if $str ne join(',', @elements);
  95     foreach my $item (@elements) {
  96         if ($item =~ m/^([0-9]+)-([0-9]+)$/) {
  97             $count += 2;
  98             my ($port1, $port2) = ($1, $2);
  99             die "invalid port '$port1'\n" if $port1 > $max;
 100             die "invalid port '$port2'\n" if $port2 > $max;
 101             die "backwards range '$port1:$port2' not allowed, did you mean '$port2:$port1'?\n" if $port1 > $port2;
 102
 103             if ($tag && $tag >= $port1 && $tag <= $port2){
 104                 $allowed = 1;
 105                 last;
 106             }
 107
 108         } elsif ($item =~ m/^([0-9]+)$/) {
 109             $count += 1;
 110             my $port = $1;
 111             die "invalid port '$port'\n" if $port > $max;
 112
 113             if ($tag && $tag == $port){
 114                 $allowed = 1;
 115                 last;
 116             }
 117         }
 118     }
 119     die "tag $tag is not allowed" if $tag && !$allowed;
 120
 121     return (scalar(@elements) > 1);
 122 }
 123
 124 1;