PVE/Network/SDN/Subnets.pm

   1 package PVE::Network::SDN::Subnets;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Net::Subnet qw(subnet_matcher);
   7 use Net::IP;
   8 use NetAddr::IP qw(:lower);
   9
  10 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  11 use PVE::Network::SDN::Dns;
  12 use PVE::Network::SDN::Ipams;
  13
  14 use PVE::Network::SDN::SubnetPlugin;
  15 PVE::Network::SDN::SubnetPlugin->register();
  16 PVE::Network::SDN::SubnetPlugin->init();
  17
  18 sub sdn_subnets_config {
  19     my ($cfg, $id, $noerr) = @_;
  20
  21     die "no sdn subnet ID specified\n" if !$id;
  22
  23     my $scfg = $cfg->{ids}->{$id};
  24     die "sdn subnet '$id' does not exist\n" if (!$noerr && !$scfg);
  25
  26     if($scfg) {
  27         my ($zone, $network, $mask) = split(/-/, $id);
  28         $scfg->{cidr} = "$network/$mask";
  29         $scfg->{zone} = $zone;
  30         $scfg->{network} = $network;
  31         $scfg->{mask} = $mask;
  32     }
  33
  34     return $scfg;
  35 }
  36
  37 sub config {
  38     my $config = cfs_read_file("sdn/subnets.cfg");
  39 }
  40
  41 sub write_config {
  42     my ($cfg) = @_;
  43
  44     cfs_write_file("sdn/subnets.cfg", $cfg);
  45 }
  46
  47 sub sdn_subnets_ids {
  48     my ($cfg) = @_;
  49
  50     return sort keys %{$cfg->{ids}};
  51 }
  52
  53 sub complete_sdn_subnet {
  54     my ($cmdname, $pname, $cvalue) = @_;
  55
  56     my $cfg = PVE::Network::SDN::Subnets::config();
  57
  58     return  $cmdname eq 'add' ? [] : [ PVE::Network::SDN::Subnets::sdn_subnets_ids($cfg) ];
  59 }
  60
  61 sub get_subnet {
  62     my ($subnetid, $running) = @_;
  63
  64     my $cfg = {};
  65     if($running) {
  66         my $cfg = PVE::Network::SDN::running_config();
  67         $cfg = $cfg->{subnets};
  68     } else {
  69         $cfg = PVE::Network::SDN::Subnets::config();
  70     }
  71
  72     my $subnet = PVE::Network::SDN::Subnets::sdn_subnets_config($cfg, $subnetid, 1);
  73     return $subnet;
  74 }
  75
  76 sub find_ip_subnet {
  77     my ($ip, $mask, $subnets) = @_;
  78
  79     my $subnet = undef;
  80     my $subnetid = undef;
  81
  82     foreach my $id (sort keys %{$subnets}) {
  83
  84         next if $mask ne $subnets->{$id}->{mask};
  85         my $cidr = $subnets->{$id}->{cidr};
  86         my $subnet_matcher = subnet_matcher($cidr);
  87         next if !$subnet_matcher->($ip);
  88         $subnet = $subnets->{$id};
  89         $subnetid = $id;
  90         last;
  91     }
  92     die  "can't find any subnet for ip $ip" if !$subnet;
  93
  94     return ($subnetid, $subnet);
  95 }
  96
  97 sub verify_dns_zone {
  98     my ($zone, $dns) = @_;
  99
 100     return if !$zone || !$dns;
 101
 102     my $dns_cfg = PVE::Network::SDN::Dns::config();
 103     my $plugin_config = $dns_cfg->{ids}->{$dns};
 104     my $plugin = PVE::Network::SDN::Dns::Plugin->lookup($plugin_config->{type});
 105     $plugin->verify_zone($plugin_config, $zone);
 106 }
 107
 108 sub get_reversedns_zone {
 109     my ($subnetid, $subnet, $dns, $ip) = @_;
 110
 111     return if !$subnetid || !$dns || !$ip;
 112
 113     my $dns_cfg = PVE::Network::SDN::Dns::config();
 114     my $plugin_config = $dns_cfg->{ids}->{$dns};
 115     my $plugin = PVE::Network::SDN::Dns::Plugin->lookup($plugin_config->{type});
 116     $plugin->get_reversedns_zone($plugin_config, $subnetid, $subnet, $ip);
 117 }
 118
 119 sub add_dns_record {
 120     my ($zone, $dns, $hostname, $ip) = @_;
 121     return if !$zone || !$dns || !$hostname || !$ip;
 122
 123     my $dns_cfg = PVE::Network::SDN::Dns::config();
 124     my $plugin_config = $dns_cfg->{ids}->{$dns};
 125     my $plugin = PVE::Network::SDN::Dns::Plugin->lookup($plugin_config->{type});
 126     $plugin->add_a_record($plugin_config, $zone, $hostname, $ip);
 127
 128 }
 129
 130 sub add_dns_ptr_record {
 131     my ($reversezone, $zone, $dns, $hostname, $ip) = @_;
 132
 133     return if !$zone || !$reversezone || !$dns || !$hostname || !$ip;
 134
 135     $hostname .= ".$zone";
 136     my $dns_cfg = PVE::Network::SDN::Dns::config();
 137     my $plugin_config = $dns_cfg->{ids}->{$dns};
 138     my $plugin = PVE::Network::SDN::Dns::Plugin->lookup($plugin_config->{type});
 139     $plugin->add_ptr_record($plugin_config, $reversezone, $hostname, $ip);
 140 }
 141
 142 sub del_dns_record {
 143     my ($zone, $dns, $hostname, $ip) = @_;
 144
 145     return if !$zone || !$dns || !$hostname || !$ip;
 146
 147     my $dns_cfg = PVE::Network::SDN::Dns::config();
 148     my $plugin_config = $dns_cfg->{ids}->{$dns};
 149     my $plugin = PVE::Network::SDN::Dns::Plugin->lookup($plugin_config->{type});
 150     $plugin->del_a_record($plugin_config, $zone, $hostname, $ip);
 151 }
 152
 153 sub del_dns_ptr_record {
 154     my ($reversezone, $dns, $ip) = @_;
 155
 156     return if !$reversezone || !$dns || !$ip;
 157
 158     my $dns_cfg = PVE::Network::SDN::Dns::config();
 159     my $plugin_config = $dns_cfg->{ids}->{$dns};
 160     my $plugin = PVE::Network::SDN::Dns::Plugin->lookup($plugin_config->{type});
 161     $plugin->del_ptr_record($plugin_config, $reversezone, $ip);
 162 }
 163
 164 sub add_subnet {
 165     my ($zone, $subnetid, $subnet) = @_;
 166
 167     my $ipam = $zone->{ipam};
 168     return if !$ipam;
 169     my $ipam_cfg = PVE::Network::SDN::Ipams::config();
 170     my $plugin_config = $ipam_cfg->{ids}->{$ipam};
 171     my $plugin = PVE::Network::SDN::Ipams::Plugin->lookup($plugin_config->{type});
 172     $plugin->add_subnet($plugin_config, $subnetid, $subnet);
 173 }
 174
 175 sub del_subnet {
 176     my ($zone, $subnetid, $subnet) = @_;
 177
 178     my $ipam = $zone->{ipam};
 179     return if !$ipam;
 180     my $ipam_cfg = PVE::Network::SDN::Ipams::config();
 181     my $plugin_config = $ipam_cfg->{ids}->{$ipam};
 182     my $plugin = PVE::Network::SDN::Ipams::Plugin->lookup($plugin_config->{type});
 183     $plugin->del_subnet($plugin_config, $subnetid, $subnet);
 184 }
 185
 186 sub next_free_ip {
 187     my ($zone, $subnetid, $subnet, $hostname, $mac, $description, $skipdns) = @_;
 188
 189     my $cidr = undef;
 190     my $ip = undef;
 191     $description = '' if !$description;
 192
 193     my $ipamid = $zone->{ipam};
 194     my $dns = $zone->{dns};
 195     my $dnszone = $zone->{dnszone};
 196     my $reversedns = $zone->{reversedns};
 197     my $dnszoneprefix = $subnet->{dnszoneprefix};
 198
 199     $hostname .= ".$dnszoneprefix" if $dnszoneprefix;
 200
 201     #verify dns zones before ipam
 202     verify_dns_zone($dnszone, $dns) if !$skipdns;
 203
 204     if($ipamid) {
 205         my $ipam_cfg = PVE::Network::SDN::Ipams::config();
 206         my $plugin_config = $ipam_cfg->{ids}->{$ipamid};
 207         my $plugin = PVE::Network::SDN::Ipams::Plugin->lookup($plugin_config->{type});
 208         eval {
 209             $cidr = $plugin->add_next_freeip($plugin_config, $subnetid, $subnet, $hostname, $mac, $description);
 210             ($ip, undef) = split(/\//, $cidr);
 211         };
 212         die $@ if $@;
 213     }
 214
 215     eval {
 216         my $reversednszone = get_reversedns_zone($subnetid, $subnet, $reversedns, $ip);
 217
 218         if(!$skipdns) {
 219             #add dns
 220             add_dns_record($dnszone, $dns, $hostname, $ip);
 221             #add reverse dns
 222             add_dns_ptr_record($reversednszone, $dnszone, $reversedns, $hostname, $ip);
 223         }
 224     };
 225     if ($@) {
 226         #rollback
 227         my $err = $@;
 228         eval {
 229             PVE::Network::SDN::Subnets::del_ip($zone, $subnetid, $subnet, $ip, $hostname)
 230         };
 231         die $err;
 232     }
 233     return $cidr;
 234 }
 235
 236 sub add_ip {
 237     my ($zone, $subnetid, $subnet, $ip, $hostname, $mac, $description, $is_gateway, $skipdns) = @_;
 238
 239     return if !$subnet || !$ip;
 240
 241     my $ipaddr = NetAddr::IP->new($ip);
 242     $ip = $ipaddr->canon();
 243
 244     my $ipamid = $zone->{ipam};
 245     my $dns = $zone->{dns};
 246     my $dnszone = $zone->{dnszone};
 247     my $reversedns = $zone->{reversedns};
 248     my $reversednszone = get_reversedns_zone($subnetid, $subnet, $reversedns, $ip);
 249     my $dnszoneprefix = $subnet->{dnszoneprefix};
 250
 251     $hostname .= ".$dnszoneprefix" if $dnszoneprefix;
 252
 253     #verify dns zones before ipam
 254     if(!$skipdns) {
 255         verify_dns_zone($dnszone, $dns);
 256         verify_dns_zone($reversednszone, $reversedns);
 257     }
 258
 259     if ($ipamid) {
 260
 261         my $ipam_cfg = PVE::Network::SDN::Ipams::config();
 262         my $plugin_config = $ipam_cfg->{ids}->{$ipamid};
 263         my $plugin = PVE::Network::SDN::Ipams::Plugin->lookup($plugin_config->{type});
 264
 265         eval {
 266             $plugin->add_ip($plugin_config, $subnetid, $subnet, $ip, $hostname, $mac, $description, $is_gateway);
 267         };
 268         die $@ if $@;
 269     }
 270
 271     eval {
 272         if(!$skipdns) {
 273             #add dns
 274             add_dns_record($dnszone, $dns, $hostname, $ip);
 275             #add reverse dns
 276             add_dns_ptr_record($reversednszone, $dnszone, $reversedns, $hostname, $ip);
 277         }
 278     };
 279     if ($@) {
 280         #rollback
 281         my $err = $@;
 282         eval {
 283             PVE::Network::SDN::Subnets::del_ip($zone, $subnetid, $subnet, $ip, $hostname)
 284         };
 285         die $err;
 286     }
 287 }
 288
 289 sub update_ip {
 290     my ($zone, $subnetid, $subnet, $ip, $hostname, $oldhostname, $mac, $description, $skipdns) = @_;
 291
 292     return if !$subnet || !$ip;
 293
 294     my $ipaddr = NetAddr::IP->new($ip);
 295     $ip = $ipaddr->canon();
 296
 297     my $ipamid = $zone->{ipam};
 298     my $dns = $zone->{dns};
 299     my $dnszone = $zone->{dnszone};
 300     my $reversedns = $zone->{reversedns};
 301     my $reversednszone = get_reversedns_zone($subnetid, $subnet, $reversedns, $ip);
 302     my $dnszoneprefix = $subnet->{dnszoneprefix};
 303
 304     $hostname .= ".$dnszoneprefix" if $dnszoneprefix;
 305
 306     #verify dns zones before ipam
 307     if(!$skipdns) {
 308         verify_dns_zone($dnszone, $dns);
 309         verify_dns_zone($reversednszone, $reversedns);
 310     }
 311
 312     if ($ipamid) {
 313         my $ipam_cfg = PVE::Network::SDN::Ipams::config();
 314         my $plugin_config = $ipam_cfg->{ids}->{$ipamid};
 315         my $plugin = PVE::Network::SDN::Ipams::Plugin->lookup($plugin_config->{type});
 316         eval {
 317             $plugin->update_ip($plugin_config, $subnetid, $subnet, $ip, $hostname, $mac, $description);
 318         };
 319         die $@ if $@;
 320     }
 321
 322     return if $hostname eq $oldhostname;
 323
 324     eval {
 325         if(!$skipdns) {
 326             #add dns
 327             del_dns_record($dnszone, $dns, $oldhostname, $ip);
 328             add_dns_record($dnszone, $dns, $hostname, $ip);
 329             #add reverse dns
 330             del_dns_ptr_record($reversednszone, $reversedns, $ip);
 331             add_dns_ptr_record($reversednszone, $dnszone, $reversedns, $hostname, $ip);
 332         }
 333     };
 334 }
 335
 336 sub del_ip {
 337     my ($zone, $subnetid, $subnet, $ip, $hostname, $skipdns) = @_;
 338
 339     return if !$subnet || !$ip;
 340
 341     my $ipaddr = NetAddr::IP->new($ip);
 342     $ip = $ipaddr->canon();
 343
 344     my $ipamid = $zone->{ipam};
 345     my $dns = $zone->{dns};
 346     my $dnszone = $zone->{dnszone};
 347     my $reversedns = $zone->{reversedns};
 348     my $reversednszone = get_reversedns_zone($subnetid, $subnet, $reversedns, $ip);
 349     my $dnszoneprefix = $subnet->{dnszoneprefix};
 350     $hostname .= ".$dnszoneprefix" if $dnszoneprefix;
 351
 352     if(!$skipdns) {
 353         verify_dns_zone($dnszone, $dns);
 354         verify_dns_zone($reversednszone, $reversedns);
 355     }
 356
 357     if ($ipamid) {
 358         my $ipam_cfg = PVE::Network::SDN::Ipams::config();
 359         my $plugin_config = $ipam_cfg->{ids}->{$ipamid};
 360         my $plugin = PVE::Network::SDN::Ipams::Plugin->lookup($plugin_config->{type});
 361         $plugin->del_ip($plugin_config, $subnetid, $subnet, $ip);
 362     }
 363
 364     eval {
 365         if(!$skipdns) {
 366             del_dns_record($dnszone, $dns, $hostname, $ip);
 367             del_dns_ptr_record($reversednszone, $reversedns, $ip);
 368         }
 369     };
 370     if ($@) {
 371         warn $@;
 372     }
 373 }
 374
 375 1;