PVE/Network/SDN/VnetPlugin.pm

   1 package PVE::Network::SDN::VnetPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
   7 use base qw(PVE::SectionConfig);
   8 use PVE::JSONSchema qw(get_standard_option);
   9 use PVE::Exception qw(raise raise_param_exc);
  10
  11 PVE::Cluster::cfs_register_file('sdn/vnets.cfg',
  12                                  sub { __PACKAGE__->parse_config(@_); },
  13                                  sub { __PACKAGE__->write_config(@_); });
  14
  15 PVE::JSONSchema::register_standard_option('pve-sdn-vnet-id', {
  16     description => "The SDN vnet object identifier.",
  17     type => 'string', format => 'pve-sdn-vnet-id',
  18 });
  19
  20 PVE::JSONSchema::register_format('pve-sdn-vnet-id', \&parse_sdn_vnet_id);
  21 sub parse_sdn_vnet_id {
  22     my ($id, $noerr) = @_;
  23
  24     if ($id !~ m/^[a-z][a-z0-9]*[a-z0-9]$/i) {
  25         return undef if $noerr;
  26         die "vnet ID '$id' contains illegal characters\n";
  27     }
  28     die "vnet ID '$id' can't be more length than 8 characters\n" if length($id) > 8;
  29     return $id;
  30 }
  31
  32 my $defaultData = {
  33
  34     propertyList => {
  35         vnet => get_standard_option('pve-sdn-vnet-id',
  36             { completion => \&PVE::Network::SDN::Vnets::complete_sdn_vnet }),
  37     },
  38 };
  39
  40 sub type {
  41     return 'vnet';
  42 }
  43
  44 sub private {
  45     return $defaultData;
  46 }
  47
  48 sub properties {
  49     return {
  50         zone => {
  51             type => 'string',
  52             description => "zone id",
  53         },
  54         type => {
  55             description => "Type",
  56             optional => 1,
  57         },
  58         tag => {
  59             type => 'integer',
  60             description => "vlan or vxlan id",
  61         },
  62         vlanaware => {
  63             type => 'boolean',
  64             description => 'Allow vm VLANs to pass through this vnet.',
  65         },
  66         alias => {
  67             type => 'string',
  68             description => "alias name of the vnet",
  69             optional => 1,
  70         },
  71         subnets => {
  72             type => 'string',
  73             description => "Subnets list",
  74             optional => 1,
  75         },
  76         mac => {
  77             type => 'string',
  78             description => "Anycast router mac address",
  79             optional => 1, format => 'mac-addr'
  80         }
  81     };
  82 }
  83
  84 sub options {
  85     return {
  86         zone => { optional => 0},
  87         tag => { optional => 1},
  88         alias => { optional => 1 },
  89         subnets => { optional => 1 },
  90         mac => { optional => 1 },
  91         vlanaware => { optional => 1 },
  92     };
  93 }
  94
  95 sub on_delete_hook {
  96     my ($class, $sdnid, $vnet_cfg) = @_;
  97
  98     return;
  99 }
 100
 101 sub on_update_hook {
 102     my ($class, $vnetid, $vnet_cfg, $subnet_cfg) = @_;
 103     # verify that tag is not already defined in another vnet
 104     if (defined($vnet_cfg->{ids}->{$vnetid}->{tag})) {
 105         my $tag = $vnet_cfg->{ids}->{$vnetid}->{tag};
 106         foreach my $id (keys %{$vnet_cfg->{ids}}) {
 107             next if $id eq $vnetid;
 108             my $vnet = $vnet_cfg->{ids}->{$id};
 109             if ($vnet->{type} eq 'vnet' && defined($vnet->{tag})) {
 110                 raise_param_exc({ tag => "tag $tag already exist in vnet $id"}) if $tag eq $vnet->{tag};
 111             }
 112         }
 113     }
 114
 115     #verify subnet
 116     my @subnets = PVE::Tools::split_list($vnet_cfg->{ids}->{$vnetid}->{subnets}) if $vnet_cfg->{ids}->{$vnetid}->{subnets};
 117     foreach my $subnet (@subnets) {
 118         my $id = $subnet =~ s/\//-/r;
 119         raise_param_exc({ subnet => "$subnet not existing"}) if !$subnet_cfg->{ids}->{$id};
 120     }
 121 }
 122
 123 1;