PVE/Network/SDN/Zones.pm

   1 package PVE::Network::SDN::Zones;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Data::Dumper;
   7 use JSON;
   8
   9 use PVE::Tools qw(extract_param dir_glob_regex run_command);
  10 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  11 use PVE::Network;
  12
  13 use PVE::Network::SDN::Vnets;
  14 use PVE::Network::SDN::Zones::VlanPlugin;
  15 use PVE::Network::SDN::Zones::QinQPlugin;
  16 use PVE::Network::SDN::Zones::VxlanPlugin;
  17 use PVE::Network::SDN::Zones::EvpnPlugin;
  18 use PVE::Network::SDN::Zones::FaucetPlugin;
  19 use PVE::Network::SDN::Zones::Plugin;
  20
  21 PVE::Network::SDN::Zones::VlanPlugin->register();
  22 PVE::Network::SDN::Zones::QinQPlugin->register();
  23 PVE::Network::SDN::Zones::VxlanPlugin->register();
  24 PVE::Network::SDN::Zones::EvpnPlugin->register();
  25 PVE::Network::SDN::Zones::FaucetPlugin->register();
  26 PVE::Network::SDN::Zones::Plugin->init();
  27
  28 my $local_network_sdn_file = "/etc/network/interfaces.d/sdn";
  29
  30 sub sdn_zones_config {
  31     my ($cfg, $id, $noerr) = @_;
  32
  33     die "no sdn zone ID specified\n" if !$id;
  34
  35     my $scfg = $cfg->{ids}->{$id};
  36     die "sdn '$id' does not exist\n" if (!$noerr && !$scfg);
  37
  38     return $scfg;
  39 }
  40
  41 sub config {
  42     my $config = cfs_read_file("sdn/zones.cfg");
  43     return $config;
  44 }
  45
  46 sub get_plugin_config {
  47     my ($vnet) = @_;
  48     my $zoneid = $vnet->{zone};
  49     my $zone_cfg = PVE::Network::SDN::Zones::config();
  50     return $zone_cfg->{ids}->{$zoneid};
  51 }
  52
  53 sub write_config {
  54     my ($cfg) = @_;
  55
  56     cfs_write_file("sdn/zones.cfg", $cfg);
  57 }
  58
  59 sub sdn_zones_ids {
  60     my ($cfg) = @_;
  61
  62     return keys %{$cfg->{ids}};
  63 }
  64
  65 sub complete_sdn_zone {
  66     my ($cmdname, $pname, $cvalue) = @_;
  67
  68     my $cfg = PVE::Network::SDN::config();
  69
  70     return  $cmdname eq 'add' ? [] : [ PVE::Network::SDN::sdn_zones_ids($cfg) ];
  71 }
  72
  73
  74 sub generate_etc_network_config {
  75
  76     my $version = PVE::Cluster::cfs_read_file('sdn/.version');
  77     my $vnet_cfg = PVE::Cluster::cfs_read_file('sdn/vnets.cfg');
  78     my $zone_cfg = PVE::Cluster::cfs_read_file('sdn/zones.cfg');
  79     my $controller_cfg = PVE::Cluster::cfs_read_file('sdn/controllers.cfg');
  80     return if !$vnet_cfg && !$zone_cfg;
  81
  82     my $interfaces_config = PVE::INotify::read_file('interfaces');
  83
  84     #generate configuration
  85     my $config = {};
  86     my $nodename = PVE::INotify::nodename();
  87
  88     for my $id (sort keys %{$vnet_cfg->{ids}}) {
  89         my $vnet = $vnet_cfg->{ids}->{$id};
  90         my $zone = $vnet->{zone};
  91
  92         if (!$zone) {
  93             warn "can't generate vnet '$id': no zone assigned!\n";
  94             next;
  95         }
  96
  97         my $plugin_config = $zone_cfg->{ids}->{$zone};
  98
  99         if (!defined($plugin_config)) {
 100             warn "can't generate vnet '$id': zone $zone don't exist\n";
 101             next;
 102         }
 103
 104         next if defined($plugin_config->{nodes}) && !$plugin_config->{nodes}->{$nodename};
 105
 106         my $controller;
 107         if (my $controllerid = $plugin_config->{controller}) {
 108             $controller = $controller_cfg->{ids}->{$controllerid};
 109         }
 110
 111         my $plugin = PVE::Network::SDN::Zones::Plugin->lookup($plugin_config->{type});
 112         eval {
 113             $plugin->generate_sdn_config($plugin_config, $zone, $id, $vnet, $controller, $interfaces_config, $config);
 114         };
 115         if($@) {
 116             warn "zone $zone : vnet $id : $@";
 117             next;
 118         }
 119     }
 120
 121     my $raw_network_config = "\#version:$version\n";
 122     foreach my $iface (sort keys %$config) {
 123         $raw_network_config .= "\n";
 124         $raw_network_config .= "auto $iface\n";
 125         $raw_network_config .= "iface $iface\n";
 126         foreach my $option (@{$config->{$iface}}) {
 127             $raw_network_config .= "\t$option\n";
 128         }
 129     }
 130
 131     return $raw_network_config;
 132 }
 133
 134 sub write_etc_network_config {
 135     my ($rawconfig) = @_;
 136
 137     return if !$rawconfig;
 138
 139     my $writefh = IO::File->new($local_network_sdn_file,">");
 140     print $writefh $rawconfig;
 141     $writefh->close();
 142 }
 143
 144 sub read_etc_network_config_version {
 145     my $versionstr = PVE::Tools::file_read_firstline($local_network_sdn_file);
 146
 147     return if !defined($versionstr);
 148
 149     if ($versionstr =~ m/^\#version:(\d+)$/) {
 150         return $1;
 151     }
 152 }
 153
 154 sub ifquery_check {
 155
 156     my $cmd = ['ifquery', '-a', '-c', '-o','json'];
 157
 158     my $result = '';
 159     my $reader = sub { $result .= shift };
 160
 161     eval {
 162         run_command($cmd, outfunc => $reader);
 163     };
 164
 165     my $resultjson = decode_json($result);
 166     my $interfaces = {};
 167
 168     foreach my $interface (@$resultjson) {
 169         my $name = $interface->{name};
 170         $interfaces->{$name} = {
 171             status => $interface->{status},
 172             config => $interface->{config},
 173             config_status => $interface->{config_status},
 174         };
 175     }
 176
 177     return $interfaces;
 178 }
 179
 180 # improve me : move status code inside plugins ?
 181 sub status {
 182
 183     my $err_config = undef;
 184
 185     my $local_version = PVE::Network::SDN::Zones::read_etc_network_config_version();
 186     my $sdn_version = PVE::Cluster::cfs_read_file('sdn/.version');
 187
 188     return if !$sdn_version;
 189
 190     if (!$local_version) {
 191         $err_config = "local sdn network configuration is not yet generated, please reload";
 192         warn "$err_config\n";
 193     } elsif ($local_version < $sdn_version) {
 194         $err_config = "local sdn network configuration is too old, please reload";
 195         warn "$err_config\n";
 196     }
 197
 198     my $status = ifquery_check();
 199
 200     my $vnet_cfg = PVE::Cluster::cfs_read_file('sdn/vnets.cfg');
 201     my $zone_cfg = PVE::Cluster::cfs_read_file('sdn/zones.cfg');
 202     my $nodename = PVE::INotify::nodename();
 203
 204
 205     my $vnet_status = {};
 206     my $zone_status = {};
 207
 208     foreach my $id (sort keys %{$vnet_cfg->{ids}}) {
 209         my $vnet = $vnet_cfg->{ids}->{$id};
 210         my $zone = $vnet->{zone};
 211         next if !$zone;
 212
 213         my $plugin_config = $zone_cfg->{ids}->{$zone};
 214         next if defined($plugin_config->{nodes}) && !$plugin_config->{nodes}->{$nodename};
 215
 216         my $plugin = PVE::Network::SDN::Zones::Plugin->lookup($plugin_config->{type});
 217         $plugin->status($plugin_config, $zone, $id, $vnet, $err_config, $status, $vnet_status, $zone_status);
 218     }
 219
 220     return($zone_status, $vnet_status);
 221 }
 222
 223 sub tap_create {
 224     my ($iface, $bridge) = @_;
 225
 226     my $vnet = PVE::Network::SDN::Vnets::get_vnet($bridge);
 227     if (!$vnet) { # fallback for classic bridge
 228         PVE::Network::tap_create($iface, $bridge);
 229         return;
 230     }
 231
 232     my $plugin_config = get_plugin_config($vnet);
 233     my $plugin = PVE::Network::SDN::Zones::Plugin->lookup($plugin_config->{type});
 234     $plugin->tap_create($plugin_config, $vnet, $iface, $bridge);
 235 }
 236
 237 sub veth_create {
 238     my ($veth, $vethpeer, $bridge, $hwaddr) = @_;
 239
 240     my $vnet = PVE::Network::SDN::Vnets::get_vnet($bridge);
 241     if (!$vnet) { # fallback for classic bridge
 242         PVE::Network::veth_create($veth, $vethpeer, $bridge, $hwaddr);
 243         return;
 244     }
 245
 246     my $plugin_config = get_plugin_config($vnet);
 247     my $plugin = PVE::Network::SDN::Zones::Plugin->lookup($plugin_config->{type});
 248     $plugin->veth_create($plugin_config, $vnet, $veth, $vethpeer, $bridge, $hwaddr);
 249 }
 250
 251 sub tap_plug {
 252     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 253
 254     my $vnet = PVE::Network::SDN::Vnets::get_vnet($bridge);
 255     if (!$vnet) { # fallback for classic bridge
 256         PVE::Network::tap_plug($iface, $bridge, $tag, $firewall, $trunks, $rate);
 257         return;
 258     }
 259
 260     my $plugin_config = get_plugin_config($vnet);
 261     my $nodename = PVE::INotify::nodename();
 262
 263     die "vnet $bridge is not allowed on this node\n"
 264         if $plugin_config->{nodes} && !defined($plugin_config->{nodes}->{$nodename});
 265
 266     my $plugin = PVE::Network::SDN::Zones::Plugin->lookup($plugin_config->{type});
 267     $plugin->tap_plug($plugin_config, $vnet, $tag, $iface, $bridge, $firewall, $trunks, $rate);
 268 }
 269
 270 1;
 271