PVE/Network/SDN/Zones/VlanPlugin.pm

   1 package PVE::Network::SDN::Zones::VlanPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::Network::SDN::Zones::Plugin;
   6 use PVE::Exception qw(raise raise_param_exc);
   7
   8 use base('PVE::Network::SDN::Zones::Plugin');
   9
  10 sub type {
  11     return 'vlan';
  12 }
  13
  14 PVE::JSONSchema::register_format('pve-sdn-vlanrange', \&pve_verify_sdn_vlanrange);
  15 sub pve_verify_sdn_vlanrange {
  16    my ($vlanstr) = @_;
  17
  18    PVE::Network::SDN::Zones::Plugin::parse_tag_number_or_range($vlanstr, '4096');
  19
  20    return $vlanstr;
  21 }
  22
  23 sub properties {
  24     return {
  25         'bridge' => {
  26             type => 'string',
  27         },
  28     };
  29 }
  30
  31 sub options {
  32
  33     return {
  34         nodes => { optional => 1},
  35         'bridge' => { optional => 0 },
  36         mtu => { optional => 1 },
  37         dns => { optional => 1 },
  38         reversedns => { optional => 1 },
  39         dnszone => { optional => 1 },
  40     };
  41 }
  42
  43 # Plugin implementation
  44 sub generate_sdn_config {
  45     my ($class, $plugin_config, $zoneid, $vnetid, $vnet, $controller, $subnet_cfg, $interfaces_config, $config) = @_;
  46
  47     my $bridge = $plugin_config->{bridge};
  48     die "can't find bridge $bridge" if !-d "/sys/class/net/$bridge";
  49
  50     my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
  51     my $is_ovs = !-d "/sys/class/net/$bridge/brif";
  52
  53     my $tag = $vnet->{tag};
  54     my $alias = $vnet->{alias};
  55     my $mtu = $plugin_config->{mtu};
  56
  57     my $vnet_uplink = "ln_".$vnetid;
  58     my $vnet_uplinkpeer = "pr_".$vnetid;
  59
  60     my @iface_config = ();
  61
  62     if($is_ovs) {
  63
  64         # keep vmbrXvY for compatibility with existing network
  65         # eth0----ovs vmbr0--(ovsintport tag)---->vnet---->vm
  66
  67         @iface_config = ();
  68         push @iface_config, "ovs_type OVSIntPort";
  69         push @iface_config, "ovs_bridge $bridge";
  70         push @iface_config, "ovs_mtu $mtu" if $mtu;
  71         if($vnet->{vlanaware}) {
  72             push @iface_config, "ovs_options vlan_mode=dot1q-tunnel other_config:qinq-ethtype=802.1q tag=$tag";
  73         } else {
  74             push @iface_config, "ovs_options tag=$tag";
  75         }
  76         push(@{$config->{$vnet_uplink}}, @iface_config) if !$config->{$vnet_uplink};
  77
  78         #redefine main ovs bridge, ifupdown2 will merge ovs_ports
  79         @iface_config = ();
  80         push @iface_config, "ovs_ports $vnet_uplink";
  81         push(@{$config->{$bridge}}, @iface_config);
  82
  83     } elsif ($vlan_aware) {
  84         # eth0----vlanaware bridge vmbr0--(vmbr0.X tag)---->vnet---->vm
  85         $vnet_uplink = "$bridge.$tag";
  86     } else {
  87
  88         # keep vmbrXvY for compatibility with existing network
  89         # eth0<---->eth0.X----vmbr0v10------vnet---->vm
  90
  91         my $bridgevlan = $bridge."v".$tag;
  92
  93         my @bridge_ifaces = ();
  94         my $dir = "/sys/class/net/$bridge/brif";
  95         PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
  96             push @bridge_ifaces, $_[0];
  97         });
  98
  99         my $bridge_ports = "";
 100         foreach my $bridge_iface (@bridge_ifaces) {
 101             $bridge_ports .= " $bridge_iface.$tag";
 102         }
 103
 104         @iface_config = ();
 105         push @iface_config, "link-type veth";
 106         push @iface_config, "veth-peer-name $vnet_uplinkpeer";
 107         push(@{$config->{$vnet_uplink}}, @iface_config) if !$config->{$vnet_uplink};
 108
 109         @iface_config = ();
 110         push @iface_config, "link-type veth";
 111         push @iface_config, "veth-peer-name $vnet_uplink";
 112         push(@{$config->{$vnet_uplinkpeer}}, @iface_config) if !$config->{$vnet_uplinkpeer};
 113
 114         @iface_config = ();
 115         push @iface_config, "bridge_ports $bridge_ports $vnet_uplinkpeer";
 116         push @iface_config, "bridge_stp off";
 117         push @iface_config, "bridge_fd 0";
 118         push(@{$config->{$bridgevlan}}, @iface_config) if !$config->{$bridgevlan};
 119     }
 120
 121     #vnet bridge
 122     @iface_config = ();
 123     push @iface_config, "bridge_ports $vnet_uplink";
 124     push @iface_config, "bridge_stp off";
 125     push @iface_config, "bridge_fd 0";
 126     if($vnet->{vlanaware}) {
 127         push @iface_config, "bridge-vlan-aware yes";
 128         push @iface_config, "bridge-vids 2-4094";
 129     }
 130     push @iface_config, "mtu $mtu" if $mtu;
 131     push @iface_config, "alias $alias" if $alias;
 132     push(@{$config->{$vnetid}}, @iface_config) if !$config->{$vnetid};
 133
 134     return $config;
 135 }
 136
 137 sub status {
 138     my ($class, $plugin_config, $zone, $vnetid, $vnet, $status) = @_;
 139
 140     my $bridge = $plugin_config->{bridge};
 141
 142     my $err_msg = [];
 143     if (!-d "/sys/class/net/$bridge") {
 144         push @$err_msg, "missing $bridge";
 145         return $err_msg;
 146     }
 147
 148     my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 149     my $is_ovs = !-d "/sys/class/net/$bridge/brif";
 150
 151     my $tag = $vnet->{tag};
 152     my $vnet_uplink = "ln_".$vnetid;
 153     my $vnet_uplinkpeer = "pr_".$vnetid;
 154
 155     # ifaces to check
 156     my $ifaces = [ $vnetid, $bridge ];
 157     if($is_ovs) {
 158         push @$ifaces, $vnet_uplink;
 159     } elsif (!$vlan_aware) {
 160         my $bridgevlan = $bridge."v".$tag;
 161         push @$ifaces, $bridgevlan;
 162         push @$ifaces, $vnet_uplink;
 163         push @$ifaces, $vnet_uplinkpeer;
 164     }
 165
 166     foreach my $iface (@{$ifaces}) {
 167         if (!$status->{$iface}->{status}) {
 168             push @$err_msg, "missing $iface";
 169         } elsif ($status->{$iface}->{status} ne 'pass') {
 170             push @$err_msg, "error iface $iface";
 171         }
 172     }
 173     return $err_msg;
 174 }
 175
 176 sub vnet_update_hook {
 177     my ($class, $vnet) = @_;
 178
 179     raise_param_exc({ tag => "missing vlan tag"}) if !defined($vnet->{tag});
 180     raise_param_exc({ tag => "vlan tag max value is 4096"}) if $vnet->{tag} > 4096;
 181 }
 182
 183 1;
 184
 185