]> git.proxmox.com Git - pve-storage.git/blame - PVE/Storage/RBDPlugin.pm
pbs: allow setting up a master key
[pve-storage.git] / PVE / Storage / RBDPlugin.pm
CommitLineData
0509010d
AD
1package PVE::Storage::RBDPlugin;
2
3use strict;
4use warnings;
5102900d 5
0509010d 6use IO::File;
5102900d 7use JSON;
e858048f 8use Net::IP;
5102900d
TL
9
10use PVE::CephConfig;
0509010d 11use PVE::JSONSchema qw(get_standard_option);
0ef8fb9d 12use PVE::ProcFSTools;
41aacc6c 13use PVE::RADOS;
5102900d
TL
14use PVE::Storage::Plugin;
15use PVE::Tools qw(run_command trim);
0509010d
AD
16
17use base qw(PVE::Storage::Plugin);
18
89a8800b
DC
19my $get_parent_image_name = sub {
20 my ($parent) = @_;
21 return undef if !$parent;
22 return $parent->{image} . "@" . $parent->{snapshot};
23};
24
4cf696f6 25my sub get_rbd_path {
aeb007cb 26 my ($scfg, $volume) = @_;
c27fe648
TL
27 my $path = $scfg->{pool} ? $scfg->{pool} : 'rbd';
28 $path .= "/$scfg->{namespace}" if defined($scfg->{namespace});
29 $path .= "/$volume" if defined($volume);
30 return $path;
8897f5dc
SP
31};
32
6cc88e8e
AA
33my $build_cmd = sub {
34 my ($binary, $scfg, $storeid, $op, @options) = @_;
35
4050fcc1 36 my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
6cc88e8e
AA
37 my $pool = $scfg->{pool} ? $scfg->{pool} : 'rbd';
38
39 my $cmd = [$binary, '-p', $pool];
40
92a7826f
TL
41 if (defined(my $namespace = $scfg->{namespace})) {
42 # some subcommands will fail if the --namespace parameter is present
43 my $no_namespace_parameter = {
44 unmap => 1,
45 };
46 push @$cmd, '--namespace', "$namespace" if !$no_namespace_parameter->{$op};
47 }
6cc88e8e
AA
48 push @$cmd, '-c', $cmd_option->{ceph_conf} if ($cmd_option->{ceph_conf});
49 push @$cmd, '-m', $cmd_option->{mon_host} if ($cmd_option->{mon_host});
50 push @$cmd, '--auth_supported', $cmd_option->{auth_supported} if ($cmd_option->{auth_supported});
51 push @$cmd, '-n', "client.$cmd_option->{userid}" if ($cmd_option->{userid});
52 push @$cmd, '--keyring', $cmd_option->{keyring} if ($cmd_option->{keyring});
53
54 push @$cmd, $op;
55
56 push @$cmd, @options if scalar(@options);
57
58 return $cmd;
59};
60
61my $rbd_cmd = sub {
62 my ($scfg, $storeid, $op, @options) = @_;
63
64 return $build_cmd->('/usr/bin/rbd', $scfg, $storeid, $op, @options);
65};
66
67my $rados_cmd = sub {
68 my ($scfg, $storeid, $op, @options) = @_;
69
70 return $build_cmd->('/usr/bin/rados', $scfg, $storeid, $op, @options);
71};
72
41aacc6c
AA
73my $librados_connect = sub {
74 my ($scfg, $storeid, $options) = @_;
75
4050fcc1 76 my $librados_config = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
41aacc6c
AA
77
78 my $rados = PVE::RADOS->new(%$librados_config);
79
80 return $rados;
81};
82
d86fd0a4 83# needed for volumes created using ceph jewel (or higher)
0ef8fb9d 84my $krbd_feature_update = sub {
d86fd0a4
FG
85 my ($scfg, $storeid, $name) = @_;
86
0ef8fb9d
TL
87 my (@disable, @enable);
88 my ($kmajor, $kminor) = PVE::ProcFSTools::kernel_version();
4c3b3085 89
0ef8fb9d
TL
90 if ($kmajor > 5 || $kmajor == 5 && $kminor >= 3) {
91 # 'deep-flatten' can only be disabled, not enabled after image creation
92 push @enable, 'fast-diff', 'object-map';
93 } else {
94 push @disable, 'fast-diff', 'object-map', 'deep-flatten';
95 }
96
97 if ($kmajor >= 5) {
98 push @enable, 'exclusive-lock';
99 } else {
100 push @disable, 'exclusive-lock';
101 }
4c3b3085 102
0ef8fb9d
TL
103 my $active_features_list = (rbd_volume_info($scfg, $storeid, $name))[4];
104 my $active_features = { map { $_ => 1 } @$active_features_list };
105
106 my $to_disable = join(',', grep { $active_features->{$_} } @disable);
107 my $to_enable = join(',', grep { !$active_features->{$_} } @enable );
108
109 if ($to_disable) {
110 print "disable RBD image features this kernel RBD drivers is not compatible with: $to_disable\n";
111 my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'disable', $name, $to_disable);
112 run_rbd_command(
113 $cmd,
114 errmsg => "could not disable krbd-incompatible image features '$to_disable' for rbd image: $name",
115 );
116 }
117 if ($to_enable) {
118 print "enable RBD image features this kernel RBD drivers supports: $to_enable\n";
119 eval {
120 my $cmd = $rbd_cmd->($scfg, $storeid, 'feature', 'enable', $name, $to_enable);
121 run_rbd_command(
122 $cmd,
123 errmsg => "could not enable krbd-compatible image features '$to_enable' for rbd image: $name",
124 );
125 };
126 warn "$@" if $@;
4c3b3085 127 }
d86fd0a4
FG
128};
129
c693f749
SP
130sub run_rbd_command {
131 my ($cmd, %args) = @_;
132
133 my $lasterr;
134 my $errmsg = $args{errmsg} . ": " || "";
c97c5b3b 135 if (!exists($args{errfunc})) {
c693f749
SP
136 # ' error: 2014-02-06 11:51:59.839135 7f09f94d0760 -1 librbd: snap_unprotect: can't unprotect;
137 # at least 1 child(ren) in pool cephstor1
138 $args{errfunc} = sub {
c97c5b3b
DM
139 my $line = shift;
140 if ($line =~ m/^\d{4}-\d{2}-\d{2} \d{2}:\d{2}:\d{2}\.\d+ [0-9a-f]+ [\-\d]+ librbd: (.*)$/) {
141 $lasterr = "$1\n";
142 } else {
143 $lasterr = $line;
144 }
145 print STDERR $lasterr;
146 *STDERR->flush();
147 };
148 }
6d0d0a97 149
c97c5b3b
DM
150 eval { run_command($cmd, %args); };
151 if (my $err = $@) {
152 die $errmsg . $lasterr if length($lasterr);
153 die $err;
c693f749
SP
154 }
155
c97c5b3b 156 return undef;
c693f749
SP
157}
158
411476cd
DM
159sub rbd_ls {
160 my ($scfg, $storeid) = @_;
d70e7f6c 161
1440604a 162 my $pool = $scfg->{pool} ? $scfg->{pool} : 'rbd';
e9bc9931 163 $pool .= "/$scfg->{namespace}" if defined($scfg->{namespace});
d70e7f6c 164
89a8800b 165 my $raw = '';
1be93fe2 166 my $parser = sub { $raw .= shift };
8c3abf12 167
72bbd8a6 168 my $cmd = $rbd_cmd->($scfg, $storeid, 'ls', '-l', '--format', 'json');
8c3abf12 169 eval {
c693f749 170 run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
8c3abf12
DM
171 };
172 my $err = $@;
173
174 die $err if $err && $err !~ m/doesn't contain rbd images/ ;
89a8800b 175
00571710
DM
176 my $result;
177 if ($raw eq '') {
178 $result = [];
179 } elsif ($raw =~ m/^(\[.*\])$/s) { # untaint
180 $result = JSON::decode_json($1);
181 } else {
182 die "got unexpected data from rbd ls: '$raw'\n";
183 }
89a8800b
DC
184
185 my $list = {};
186
187 foreach my $el (@$result) {
188 next if defined($el->{snapshot});
189
190 my $image = $el->{image};
191
192 my ($owner) = $image =~ m/^(?:vm|base)-(\d+)-/;
aa14def4 193 next if !defined($owner);
89a8800b
DC
194
195 $list->{$pool}->{$image} = {
196 name => $image,
197 size => $el->{size},
198 parent => $get_parent_image_name->($el->{parent}),
199 vmid => $owner
200 };
201 }
202
411476cd 203 return $list;
0509010d
AD
204}
205
a573f66a
FG
206sub rbd_ls_snap {
207 my ($scfg, $storeid, $name) = @_;
208
72bbd8a6 209 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'ls', $name, '--format', 'json');
a573f66a
FG
210
211 my $raw = '';
212 run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => sub { $raw .= shift; });
213
214 my $list;
215 if ($raw =~ m/^(\[.*\])$/s) { # untaint
216 $list = eval { JSON::decode_json($1) };
217 die "invalid JSON output from 'rbd snap ls $name': $@\n" if $@;
218 } else {
219 die "got unexpected data from 'rbd snap ls $name': '$raw'\n";
220 }
221
222 $list = [] if !defined($list);
223
224 my $res = {};
225 foreach my $el (@$list) {
226 my $snap = $el->{name};
227 my $protected = defined($el->{protected}) && $el->{protected} eq "true" ? 1 : undef;
228 $res->{$snap} = {
229 name => $snap,
230 id => $el->{id} // undef,
231 size => $el->{size} // 0,
232 protected => $protected,
233 };
234 }
235 return $res;
236}
237
62b98a65 238sub rbd_volume_info {
992e6835
AD
239 my ($scfg, $storeid, $volname, $snap) = @_;
240
241 my $cmd = undef;
242
89a8800b 243 my @options = ('info', $volname, '--format', 'json');
1be93fe2 244 if ($snap) {
89a8800b 245 push @options, '--snap', $snap;
992e6835 246 }
e110213e 247
72bbd8a6 248 $cmd = $rbd_cmd->($scfg, $storeid, @options);
89a8800b 249
89a8800b 250 my $raw = '';
1be93fe2 251 my $parser = sub { $raw .= shift };
e110213e 252
c693f749 253 run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
1be93fe2 254
00571710
DM
255 my $volume;
256 if ($raw eq '') {
257 $volume = {};
258 } elsif ($raw =~ m/^(\{.*\})$/s) { # untaint
259 $volume = JSON::decode_json($1);
260 } else {
261 die "got unexpected data from rbd info: '$raw'\n";
262 }
1be93fe2 263
89a8800b 264 $volume->{parent} = $get_parent_image_name->($volume->{parent});
1be93fe2 265 $volume->{protected} = defined($volume->{protected}) && $volume->{protected} eq "true" ? 1 : undef;
e110213e 266
89a8800b 267 return $volume->@{qw(size parent format protected features)};
e110213e
AD
268}
269
e5427b00 270# Configuration
0509010d 271
0509010d
AD
272sub type {
273 return 'rbd';
274}
275
276sub plugindata {
277 return {
1f79bb07 278 content => [ {images => 1, rootdir => 1}, { images => 1 }],
0509010d
AD
279 };
280}
281
282sub properties {
283 return {
e5427b00 284 monhost => {
0b9ef02e 285 description => "IP addresses of monitors (for external clusters).",
e858048f 286 type => 'string', format => 'pve-storage-portal-dns-list',
0509010d 287 },
e5427b00
AD
288 pool => {
289 description => "Pool.",
0509010d
AD
290 type => 'string',
291 },
6d0d0a97 292 namespace => {
e9bc9931
AL
293 description => "RBD Namespace.",
294 type => 'string',
295 },
e5427b00
AD
296 username => {
297 description => "RBD Id.",
0509010d
AD
298 type => 'string',
299 },
e5427b00 300 authsupported => {
0509010d
AD
301 description => "Authsupported.",
302 type => 'string',
303 },
9f20a8a6 304 krbd => {
40d69893 305 description => "Always access rbd through krbd kernel module.",
9f20a8a6
AD
306 type => 'boolean',
307 },
0509010d
AD
308 };
309}
310
311sub options {
312 return {
35d6dfaf
AD
313 nodes => { optional => 1 },
314 disable => { optional => 1 },
0b9ef02e 315 monhost => { optional => 1},
1440604a 316 pool => { optional => 1 },
e9bc9931 317 namespace => { optional => 1 },
1440604a 318 username => { optional => 1 },
0509010d 319 content => { optional => 1 },
9f20a8a6 320 krbd => { optional => 1 },
9edb99a5 321 bwlimit => { optional => 1 },
0509010d
AD
322 };
323}
324
325# Storage implementation
326
2e109b4b
TL
327sub on_add_hook {
328 my ($class, $storeid, $scfg, %param) = @_;
329
330 return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
331
4050fcc1 332 PVE::CephConfig::ceph_create_keyfile($scfg->{type}, $storeid);
f3ccd0ef
FE
333
334 return;
2e109b4b
TL
335}
336
337sub on_delete_hook {
338 my ($class, $storeid, $scfg) = @_;
339
340 return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
341
4050fcc1 342 PVE::CephConfig::ceph_remove_keyfile($scfg->{type}, $storeid);
f3ccd0ef
FE
343
344 return;
2e109b4b
TL
345}
346
0509010d
AD
347sub parse_volname {
348 my ($class, $volname) = @_;
349
d04c7e55 350 if ($volname =~ m/^((base-(\d+)-\S+)\/)?((base)?(vm)?-(\d+)-\S+)$/) {
7800e84d 351 return ('images', $4, $7, $2, $3, $5, 'raw');
0509010d
AD
352 }
353
354 die "unable to parse rbd volume name '$volname'\n";
355}
356
357sub path {
38e6ec3f 358 my ($class, $scfg, $volname, $storeid, $snapname) = @_;
0509010d 359
4050fcc1 360 my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
0509010d 361 my ($vtype, $name, $vmid) = $class->parse_volname($volname);
38e6ec3f 362 $name .= '@'.$snapname if $snapname;
0509010d 363
4cf696f6 364 my $rbd_path = get_rbd_path($scfg, $name);
aeb007cb 365 return ("/dev/rbd/${rbd_path}", $vmid, $vtype) if $scfg->{krbd};
33cef4c8 366
aeb007cb 367 my $path = "rbd:${rbd_path}";
6eebc4a7 368
5fc02afb
FG
369 $path .= ":conf=$cmd_option->{ceph_conf}" if $cmd_option->{ceph_conf};
370 if (defined($scfg->{monhost})) {
4050fcc1 371 my $monhost = PVE::CephConfig::hostlist($scfg->{monhost}, ';');
6eebc4a7
FG
372 $monhost =~ s/:/\\:/g;
373 $path .= ":mon_host=$monhost";
6cc88e8e 374 $path .= ":auth_supported=$cmd_option->{auth_supported}";
6eebc4a7
FG
375 }
376
6cc88e8e 377 $path .= ":id=$cmd_option->{userid}:keyring=$cmd_option->{keyring}" if ($cmd_option->{keyring});
13417225 378
0509010d
AD
379 return ($path, $vmid, $vtype);
380}
381
a44c0147
FE
382sub find_free_diskname {
383 my ($class, $storeid, $scfg, $vmid, $fmt, $add_fmt_suffix) = @_;
5b9b9b14 384
72bbd8a6 385 my $cmd = $rbd_cmd->($scfg, $storeid, 'ls');
e9bc9931 386
c4a29df4 387 my $disk_list = [];
5b9b9b14 388
53a236f2
FG
389 my $parser = sub {
390 my $line = shift;
dd9e97ed 391 if ($line =~ m/^(.*)$/) { # untaint
00571710
DM
392 push @$disk_list, $1;
393 }
53a236f2
FG
394 };
395
396 eval {
397 run_rbd_command($cmd, errmsg => "rbd error", errfunc => sub {}, outfunc => $parser);
398 };
399 my $err = $@;
400
401 die $err if $err && $err !~ m/doesn't contain rbd images/;
402
c4a29df4 403 return PVE::Storage::Plugin::get_next_vm_diskname($disk_list, $storeid, $vmid, undef, $scfg);
a44c0147 404}
5b9b9b14 405
5eab0272
DM
406sub create_base {
407 my ($class, $storeid, $scfg, $volname) = @_;
408
992e6835
AD
409 my $snap = '__base__';
410
411 my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
412 $class->parse_volname($volname);
413
414 die "create_base not possible with base image\n" if $isBase;
415
416 my ($size, $parent, $format, undef) = rbd_volume_info($scfg, $storeid, $name);
417 die "rbd volume info on '$name' failed\n" if !($size);
418
419 die "rbd image must be at format V2" if $format ne "2";
420
421 die "volname '$volname' contains wrong information about parent $parent $basename\n"
422 if $basename && (!$parent || $parent ne $basename."@".$snap);
423
424 my $newname = $name;
425 $newname =~ s/^vm-/base-/;
426
427 my $newvolname = $basename ? "$basename/$newname" : "$newname";
428
72bbd8a6 429 my $cmd = $rbd_cmd->(
aeb007cb
AL
430 $scfg,
431 $storeid,
432 'rename',
4cf696f6
TL
433 get_rbd_path($scfg, $name),
434 get_rbd_path($scfg, $newname),
aeb007cb 435 );
c693f749 436 run_rbd_command($cmd, errmsg => "rbd rename '$name' error");
992e6835
AD
437
438 my $running = undef; #fixme : is create_base always offline ?
439
440 $class->volume_snapshot($scfg, $storeid, $newname, $snap, $running);
441
442 my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $newname, $snap);
443
444 if (!$protected){
72bbd8a6 445 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'protect', $newname, '--snap', $snap);
2362bc87 446 run_rbd_command($cmd, errmsg => "rbd protect $newname snap '$snap' error");
992e6835
AD
447 }
448
449 return $newvolname;
450
5eab0272
DM
451}
452
453sub clone_image {
f236eaf8 454 my ($class, $scfg, $storeid, $volname, $vmid, $snapname) = @_;
5eab0272 455
f2708285 456 my $snap = '__base__';
f236eaf8 457 $snap = $snapname if length $snapname;
f2708285
AD
458
459 my ($vtype, $basename, $basevmid, undef, undef, $isBase) =
460 $class->parse_volname($volname);
461
63da6d79
DM
462 die "$volname is not a base image and snapname is not provided\n"
463 if !$isBase && !length($snapname);
f2708285 464
a44c0147 465 my $name = $class->find_free_diskname($storeid, $scfg, $vmid);
f2708285 466
f236eaf8
SP
467 warn "clone $volname: $basename snapname $snap to $name\n";
468
63da6d79 469 if (length($snapname)) {
f236eaf8
SP
470 my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $volname, $snapname);
471
63da6d79 472 if (!$protected) {
72bbd8a6 473 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'protect', $volname, '--snap', $snapname);
f236eaf8
SP
474 run_rbd_command($cmd, errmsg => "rbd protect $volname snap $snapname error");
475 }
476 }
f2708285
AD
477
478 my $newvol = "$basename/$name";
63da6d79
DM
479 $newvol = $name if length($snapname);
480
72bbd8a6 481 my $cmd = $rbd_cmd->(
aeb007cb
AL
482 $scfg,
483 $storeid,
484 'clone',
4cf696f6 485 get_rbd_path($scfg, $basename),
aeb007cb
AL
486 '--snap',
487 $snap,
4cf696f6 488 get_rbd_path($scfg, $name),
aeb007cb 489 );
f2708285 490
c693f749 491 run_rbd_command($cmd, errmsg => "rbd clone '$basename' error");
f2708285
AD
492
493 return $newvol;
5eab0272
DM
494}
495
0509010d
AD
496sub alloc_image {
497 my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
498
499
292a33fd 500 die "illegal name '$name' - should be 'vm-$vmid-*'\n"
0509010d 501 if $name && $name !~ m/^vm-$vmid-/;
0509010d 502
a44c0147 503 $name = $class->find_free_diskname($storeid, $scfg, $vmid) if !$name;
0509010d 504
72bbd8a6 505 my $cmd = $rbd_cmd->($scfg, $storeid, 'create', '--image-format' , 2, '--size', int(($size+1023)/1024), $name);
3c931155 506 run_rbd_command($cmd, errmsg => "rbd create '$name' error");
0509010d
AD
507
508 return $name;
509}
510
511sub free_image {
32437ed2 512 my ($class, $storeid, $scfg, $volname, $isBase) = @_;
0509010d 513
42d07b9a
AD
514 my ($vtype, $name, $vmid, undef, undef, undef) =
515 $class->parse_volname($volname);
516
e9bc9931 517
a573f66a
FG
518 my $snaps = rbd_ls_snap($scfg, $storeid, $name);
519 foreach my $snap (keys %$snaps) {
520 if ($snaps->{$snap}->{protected}) {
72bbd8a6 521 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
2362bc87 522 run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
42d07b9a
AD
523 }
524 }
525
515ef80b
WL
526 $class->deactivate_volume($storeid, $scfg, $volname);
527
72bbd8a6 528 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'purge', $name);
c693f749 529 run_rbd_command($cmd, errmsg => "rbd snap purge '$volname' error");
c30470a3 530
72bbd8a6 531 $cmd = $rbd_cmd->($scfg, $storeid, 'rm', $name);
c693f749 532 run_rbd_command($cmd, errmsg => "rbd rm '$volname' error");
0509010d
AD
533
534 return undef;
535}
536
537sub list_images {
538 my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
539
e5427b00 540 $cache->{rbd} = rbd_ls($scfg, $storeid) if !$cache->{rbd};
ed7ea5a3 541
c27fe648 542 my $dat = $cache->{rbd}->{get_rbd_path($scfg)};
ed7ea5a3 543 return [] if !$dat; # nothing found
cfd58f1f 544
ed7ea5a3
TL
545 my $res = [];
546 for my $image (sort keys %$dat) {
547 my $info = $dat->{$image};
548 my ($volname, $parent, $owner) = $info->@{'name', 'parent', 'vmid'};
549
550 if ($parent && $parent =~ m/^(base-\d+-\S+)\@__base__$/) {
551 $info->{volid} = "$storeid:$1/$volname";
552 } else {
553 $info->{volid} = "$storeid:$volname";
554 }
0509010d 555
ed7ea5a3
TL
556 if ($vollist) {
557 my $found = grep { $_ eq $info->{volid} } @$vollist;
558 next if !$found;
559 } else {
560 next if defined ($vmid) && ($owner ne $vmid);
561 }
0509010d 562
ed7ea5a3 563 $info->{format} = 'raw';
0509010d 564
ed7ea5a3 565 push @$res, $info;
0509010d 566 }
ed7ea5a3 567
411476cd 568 return $res;
0509010d
AD
569}
570
0509010d
AD
571sub status {
572 my ($class, $storeid, $scfg, $cache) = @_;
573
72bbd8a6 574 my $rados = $librados_connect->($scfg, $storeid);
41aacc6c 575 my $df = $rados->mon_command({ prefix => 'df', format => 'json' });
69589444 576
41aacc6c 577 my ($d) = grep { $_->{name} eq $scfg->{pool} } @{$df->{pools}};
69589444 578
41aacc6c
AA
579 # max_avail -> max available space for data w/o replication in the pool
580 # bytes_used -> data w/o replication in the pool
581 my $free = $d->{stats}->{max_avail};
e79ab52c 582 my $used = $d->{stats}->{stored} // $d->{stats}->{bytes_used};
41aacc6c 583 my $total = $used + $free;
0509010d 584 my $active = 1;
0509010d 585
411476cd 586 return ($total, $free, $used, $active);
0509010d
AD
587}
588
589sub activate_storage {
590 my ($class, $storeid, $scfg, $cache) = @_;
591 return 1;
592}
593
594sub deactivate_storage {
595 my ($class, $storeid, $scfg, $cache) = @_;
596 return 1;
597}
598
22265bd9 599my sub get_kernel_device_path {
aeb007cb 600 my ($scfg, $name) = @_;
4cf696f6 601 return "/dev/rbd/" . get_rbd_path($scfg, $name);
40d69893 602};
9f20a8a6 603
40d69893
DM
604sub map_volume {
605 my ($class, $storeid, $scfg, $volname, $snapname) = @_;
9f20a8a6 606
518f3908
FG
607 my ($vtype, $img_name, $vmid) = $class->parse_volname($volname);
608
609 my $name = $img_name;
40d69893
DM
610 $name .= '@'.$snapname if $snapname;
611
22265bd9 612 my $kerneldev = get_kernel_device_path($scfg, $name);
40d69893
DM
613
614 return $kerneldev if -b $kerneldev; # already mapped
615
518f3908
FG
616 # features can only be enabled/disabled for image, not for snapshot!
617 $krbd_feature_update->($scfg, $storeid, $img_name);
9f20a8a6 618
72bbd8a6 619 my $cmd = $rbd_cmd->($scfg, $storeid, 'map', $name);
40d69893
DM
620 run_rbd_command($cmd, errmsg => "can't map rbd volume $name");
621
622 return $kerneldev;
623}
624
625sub unmap_volume {
626 my ($class, $storeid, $scfg, $volname, $snapname) = @_;
627
628 my ($vtype, $name, $vmid) = $class->parse_volname($volname);
629 $name .= '@'.$snapname if $snapname;
630
22265bd9 631 my $kerneldev = get_kernel_device_path($scfg, $name);
40d69893
DM
632
633 if (-b $kerneldev) {
72bbd8a6 634 my $cmd = $rbd_cmd->($scfg, $storeid, 'unmap', $kerneldev);
40d69893
DM
635 run_rbd_command($cmd, errmsg => "can't unmap rbd device $kerneldev");
636 }
9f20a8a6 637
0509010d
AD
638 return 1;
639}
640
40d69893 641sub activate_volume {
02e797b8 642 my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
9f20a8a6 643
40d69893 644 $class->map_volume($storeid, $scfg, $volname, $snapname) if $scfg->{krbd};
9f20a8a6 645
40d69893
DM
646 return 1;
647}
9f20a8a6 648
40d69893
DM
649sub deactivate_volume {
650 my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
b50812f9 651
40d69893 652 $class->unmap_volume($storeid, $scfg, $volname, $snapname);
9f20a8a6 653
0509010d
AD
654 return 1;
655}
656
0002d9cc
AD
657sub volume_size_info {
658 my ($class, $scfg, $storeid, $volname, $timeout) = @_;
659
81d1d017
AD
660 my ($vtype, $name, $vmid) = $class->parse_volname($volname);
661 my ($size, undef) = rbd_volume_info($scfg, $storeid, $name);
62b98a65 662 return $size;
0002d9cc
AD
663}
664
e7a42a76
AD
665sub volume_resize {
666 my ($class, $scfg, $storeid, $volname, $size, $running) = @_;
667
40d69893 668 return 1 if $running && !$scfg->{krbd}; # FIXME???
e7a42a76 669
478fc06c
AD
670 my ($vtype, $name, $vmid) = $class->parse_volname($volname);
671
72bbd8a6 672 my $cmd = $rbd_cmd->($scfg, $storeid, 'resize', '--allow-shrink', '--size', ($size/1024/1024), $name);
c693f749 673 run_rbd_command($cmd, errmsg => "rbd resize '$volname' error");
e7a42a76
AD
674 return undef;
675}
676
788dd8e1 677sub volume_snapshot {
f5640e7d 678 my ($class, $scfg, $storeid, $volname, $snap) = @_;
788dd8e1 679
9af33ed0
AD
680 my ($vtype, $name, $vmid) = $class->parse_volname($volname);
681
72bbd8a6 682 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'create', '--snap', $snap, $name);
c693f749 683 run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
788dd8e1
AD
684 return undef;
685}
686
5a2b2e2f
AD
687sub volume_snapshot_rollback {
688 my ($class, $scfg, $storeid, $volname, $snap) = @_;
689
c6ce2cc8
AD
690 my ($vtype, $name, $vmid) = $class->parse_volname($volname);
691
72bbd8a6 692 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'rollback', '--snap', $snap, $name);
2362bc87 693 run_rbd_command($cmd, errmsg => "rbd snapshot $volname to '$snap' error");
5a2b2e2f
AD
694}
695
cce29bcd
AD
696sub volume_snapshot_delete {
697 my ($class, $scfg, $storeid, $volname, $snap, $running) = @_;
698
40d69893 699 return 1 if $running && !$scfg->{krbd}; # FIXME: ????
cce29bcd 700
399581a2
WB
701 $class->deactivate_volume($storeid, $scfg, $volname, $snap, {});
702
c78cb110
AD
703 my ($vtype, $name, $vmid) = $class->parse_volname($volname);
704
f90a0a20
SP
705 my (undef, undef, undef, $protected) = rbd_volume_info($scfg, $storeid, $name, $snap);
706 if ($protected){
72bbd8a6 707 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'unprotect', $name, '--snap', $snap);
f90a0a20
SP
708 run_rbd_command($cmd, errmsg => "rbd unprotect $name snap '$snap' error");
709 }
710
72bbd8a6 711 my $cmd = $rbd_cmd->($scfg, $storeid, 'snap', 'rm', '--snap', $snap, $name);
c693f749
SP
712
713 run_rbd_command($cmd, errmsg => "rbd snapshot '$volname' error");
714
cce29bcd
AD
715 return undef;
716}
717
2c036838 718sub volume_snapshot_needs_fsfreeze {
2c036838
SI
719 return 1;
720}
721
774f21b9
AD
722sub volume_has_feature {
723 my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
724
725 my $features = {
5649ccfe 726 snapshot => { current => 1, snap => 1},
44c3689a 727 clone => { base => 1, snap => 1},
5649ccfe
AD
728 template => { current => 1},
729 copy => { base => 1, current => 1, snap => 1},
baafddbd 730 sparseinit => { base => 1, current => 1},
774f21b9
AD
731 };
732
6d0d0a97 733 my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) = $class->parse_volname($volname);
1e7ae581
AD
734
735 my $key = undef;
6d0d0a97 736 if ($snapname){
2c5a7097 737 $key = 'snap';
6d0d0a97
TL
738 } else {
739 $key = $isBase ? 'base' : 'current';
1e7ae581
AD
740 }
741 return 1 if $features->{$feature}->{$key};
774f21b9
AD
742
743 return undef;
744}
745
0509010d 7461;