PVE/API2/Storage/Config.pm

   1 package PVE::API2::Storage::Config;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Tools qw(extract_param);
   8 use PVE::Cluster qw(cfs_read_file cfs_write_file);
   9 use PVE::Storage;
  10 use PVE::Storage::Plugin;
  11 use PVE::Storage::LVMPlugin;
  12 use PVE::Storage::CIFSPlugin;
  13 use HTTP::Status qw(:constants);
  14 use Storable qw(dclone);
  15 use PVE::JSONSchema qw(get_standard_option);
  16 use PVE::RPCEnvironment;
  17
  18 use PVE::RESTHandler;
  19
  20 use base qw(PVE::RESTHandler);
  21
  22 my @ctypes = qw(images vztmpl iso backup);
  23
  24 my $storage_type_enum = PVE::Storage::Plugin->lookup_types();
  25
  26 my $api_storage_config = sub {
  27     my ($cfg, $storeid) = @_;
  28
  29     my $scfg = dclone(PVE::Storage::storage_config($cfg, $storeid));
  30     $scfg->{storage} = $storeid;
  31     $scfg->{digest} = $cfg->{digest};
  32     $scfg->{content} = PVE::Storage::Plugin->encode_value($scfg->{type}, 'content', $scfg->{content});
  33
  34     if ($scfg->{nodes}) {
  35         $scfg->{nodes} = PVE::Storage::Plugin->encode_value($scfg->{type}, 'nodes', $scfg->{nodes});
  36     }
  37
  38     return $scfg;
  39 };
  40
  41 __PACKAGE__->register_method ({
  42     name => 'index',
  43     path => '',
  44     method => 'GET',
  45     description => "Storage index.",
  46     permissions => {
  47         description => "Only list entries where you have 'Datastore.Audit' or 'Datastore.AllocateSpace' permissions on '/storage/<storage>'",
  48         user => 'all',
  49     },
  50     parameters => {
  51         additionalProperties => 0,
  52         properties => {
  53             type => {
  54                 description => "Only list storage of specific type",
  55                 type => 'string',
  56                 enum => $storage_type_enum,
  57                 optional => 1,
  58             },
  59         },
  60     },
  61     returns => {
  62         type => 'array',
  63         items => {
  64             type => "object",
  65             properties => { storage => { type => 'string'} },
  66         },
  67         links => [ { rel => 'child', href => "{storage}" } ],
  68     },
  69     code => sub {
  70         my ($param) = @_;
  71
  72         my $rpcenv = PVE::RPCEnvironment::get();
  73         my $authuser = $rpcenv->get_user();
  74
  75         my $cfg = PVE::Storage::config();
  76
  77         my @sids = PVE::Storage::storage_ids($cfg);
  78
  79         my $res = [];
  80         foreach my $storeid (@sids) {
  81             my $privs = [ 'Datastore.Audit', 'Datastore.AllocateSpace' ];
  82             next if !$rpcenv->check_any($authuser, "/storage/$storeid", $privs, 1);
  83
  84             my $scfg = &$api_storage_config($cfg, $storeid);
  85             next if $param->{type} && $param->{type} ne $scfg->{type};
  86             push @$res, $scfg;
  87         }
  88
  89         return $res;
  90     }});
  91
  92 __PACKAGE__->register_method ({
  93     name => 'read',
  94     path => '{storage}',
  95     method => 'GET',
  96     description => "Read storage configuration.",
  97     permissions => {
  98         check => ['perm', '/storage/{storage}', ['Datastore.Allocate']],
  99     },
 100     parameters => {
 101         additionalProperties => 0,
 102         properties => {
 103             storage => get_standard_option('pve-storage-id'),
 104         },
 105     },
 106     returns => { type => 'object' },
 107     code => sub {
 108         my ($param) = @_;
 109
 110         my $cfg = PVE::Storage::config();
 111
 112         return &$api_storage_config($cfg, $param->{storage});
 113     }});
 114
 115 my sub extract_sensitive_params :prototype($$) {
 116     my ($param, $delete_list) = @_;
 117
 118     my $sensitive;
 119
 120     my %delete = map { $_ => 1 } ($delete_list || [])->@*;
 121
 122     # always extract pw and keys, so they don't get written to the www-data readable scfg
 123     for my $opt (qw(password encryption_key)) {
 124         # First handle deletions as explicitly setting `undef`, afterwards new values may override
 125         # it.
 126         if (exists($delete{$opt})) {
 127             $sensitive->{$opt} = undef;
 128         }
 129
 130         if (defined(my $value = extract_param($param, $opt))) {
 131             $sensitive->{$opt} = $value;
 132         }
 133     }
 134
 135     return $sensitive;
 136 }
 137
 138 __PACKAGE__->register_method ({
 139     name => 'create',
 140     protected => 1,
 141     path => '',
 142     method => 'POST',
 143     description => "Create a new storage.",
 144     permissions => {
 145         check => ['perm', '/storage', ['Datastore.Allocate']],
 146     },
 147     parameters => PVE::Storage::Plugin->createSchema(),
 148     returns => { type => 'null' },
 149     code => sub {
 150         my ($param) = @_;
 151
 152         my $type = extract_param($param, 'type');
 153         my $storeid = extract_param($param, 'storage');
 154
 155         # revent an empty nodelist.
 156         # fix me in section config create never need an empty entity.
 157         delete $param->{nodes} if !$param->{nodes};
 158
 159         my $sensitive = extract_sensitive_params($param, []);
 160
 161         my $plugin = PVE::Storage::Plugin->lookup($type);
 162         my $opts = $plugin->check_config($storeid, $param, 1, 1);
 163
 164         PVE::Storage::lock_storage_config(
 165             sub {
 166
 167                 my $cfg = PVE::Storage::config();
 168
 169                 if (my $scfg = PVE::Storage::storage_config($cfg, $storeid, 1)) {
 170                     die "storage ID '$storeid' already defined\n";
 171                 }
 172
 173                 $cfg->{ids}->{$storeid} = $opts;
 174
 175                 $plugin->on_add_hook($storeid, $opts, %$sensitive);
 176
 177                 eval {
 178                     # try to activate if enabled on local node,
 179                     # we only do this to detect errors/problems sooner
 180                     if (PVE::Storage::storage_check_enabled($cfg, $storeid, undef, 1)) {
 181                         PVE::Storage::activate_storage($cfg, $storeid);
 182                     }
 183                 };
 184                 if (my $err = $@) {
 185                     eval { $plugin->on_delete_hook($storeid, $opts) };
 186                     warn "$@\n" if $@;
 187                     die $err;
 188                 }
 189
 190                 PVE::Storage::write_config($cfg);
 191
 192             }, "create storage failed");
 193
 194         return undef;
 195     }});
 196
 197 __PACKAGE__->register_method ({
 198     name => 'update',
 199     protected => 1,
 200     path => '{storage}',
 201     method => 'PUT',
 202     description => "Update storage configuration.",
 203     permissions => {
 204         check => ['perm', '/storage', ['Datastore.Allocate']],
 205     },
 206     parameters => PVE::Storage::Plugin->updateSchema(),
 207     returns => { type => 'null' },
 208     code => sub {
 209         my ($param) = @_;
 210
 211         my $storeid = extract_param($param, 'storage');
 212         my $digest = extract_param($param, 'digest');
 213         my $delete = extract_param($param, 'delete');
 214
 215         if ($delete) {
 216             $delete = [ PVE::Tools::split_list($delete) ];
 217         }
 218
 219         PVE::Storage::lock_storage_config(sub {
 220
 221             my $cfg = PVE::Storage::config();
 222
 223             PVE::SectionConfig::assert_if_modified($cfg, $digest);
 224
 225             my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 226             my $type = $scfg->{type};
 227
 228             my $sensitive = extract_sensitive_params($param, $delete);
 229
 230             my $plugin = PVE::Storage::Plugin->lookup($type);
 231             my $opts = $plugin->check_config($storeid, $param, 0, 1);
 232
 233             if ($delete) {
 234                 my $options = $plugin->private()->{options}->{$type};
 235                 foreach my $k (@$delete) {
 236                     my $d = $options->{$k} || die "no such option '$k'\n";
 237                     die "unable to delete required option '$k'\n" if !$d->{optional};
 238                     die "unable to delete fixed option '$k'\n" if $d->{fixed};
 239                     die "cannot set and delete property '$k' at the same time!\n"
 240                         if defined($opts->{$k});
 241
 242                     delete $scfg->{$k};
 243                 }
 244             }
 245
 246             $plugin->on_update_hook($storeid, $opts, %$sensitive);
 247
 248             for my $k (keys %$opts) {
 249                 $scfg->{$k} = $opts->{$k};
 250             }
 251
 252             PVE::Storage::write_config($cfg);
 253
 254         }, "update storage failed");
 255
 256         return undef;
 257     }});
 258
 259 __PACKAGE__->register_method ({
 260     name => 'delete',
 261     protected => 1,
 262     path => '{storage}', # /storage/config/{storage}
 263     method => 'DELETE',
 264     description => "Delete storage configuration.",
 265     permissions => {
 266         check => ['perm', '/storage', ['Datastore.Allocate']],
 267     },
 268     parameters => {
 269         additionalProperties => 0,
 270         properties => {
 271             storage => get_standard_option('pve-storage-id', {
 272                 completion => \&PVE::Storage::complete_storage,
 273             }),
 274         },
 275     },
 276     returns => { type => 'null' },
 277     code => sub {
 278         my ($param) = @_;
 279
 280         my $storeid = extract_param($param, 'storage');
 281
 282         PVE::Storage::lock_storage_config(
 283             sub {
 284
 285                 my $cfg = PVE::Storage::config();
 286
 287                 my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 288
 289                 die "can't remove storage - storage is used as base of another storage\n"
 290                     if PVE::Storage::storage_is_used($cfg, $storeid);
 291
 292                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 293
 294                 $plugin->on_delete_hook($storeid, $scfg);
 295
 296                 delete $cfg->{ids}->{$storeid};
 297
 298                 PVE::Storage::write_config($cfg);
 299
 300             }, "delete storage failed");
 301
 302         PVE::AccessControl::remove_storage_access($storeid);
 303
 304         return undef;
 305     }});
 306
 307 1;