PVE/Diskmanage.pm

   1 package PVE::Diskmanage;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::ProcFSTools;
   6 use Data::Dumper;
   7 use Cwd qw(abs_path);
   8 use Fcntl ':mode';
   9
  10 use PVE::Tools qw(extract_param run_command file_get_contents file_read_firstline dir_glob_regex dir_glob_foreach trim);
  11
  12 my $SMARTCTL = "/usr/sbin/smartctl";
  13 my $ZPOOL = "/sbin/zpool";
  14 my $SGDISK = "/sbin/sgdisk";
  15 my $PVS = "/sbin/pvs";
  16 my $UDEVADM = "/bin/udevadm";
  17
  18 sub verify_blockdev_path {
  19     my ($rel_path) = @_;
  20
  21     die "missing path" if !$rel_path;
  22     my $path = abs_path($rel_path);
  23     die "failed to get absolute path to $rel_path\n" if !$path;
  24
  25     die "got unusual device path '$path'\n" if $path !~  m|^/dev/(.*)$|;
  26
  27     $path = "/dev/$1"; # untaint
  28
  29     assert_blockdev($path);
  30
  31     return $path;
  32 }
  33
  34 sub assert_blockdev {
  35     my ($dev, $noerr) = @_;
  36
  37     if ($dev !~ m|^/dev/| || !(-b $dev)) {
  38         return undef if $noerr;
  39         die "not a valid block device\n";
  40     }
  41
  42     return 1;
  43 }
  44
  45 sub init_disk {
  46     my ($disk, $uuid) = @_;
  47
  48     assert_blockdev($disk);
  49
  50     # we should already have checked if it is in use in the api call
  51     # but we check again for safety
  52     die "disk $disk is already in use\n" if disk_is_used($disk);
  53
  54     my $id = $uuid || 'R';
  55     run_command([$SGDISK, $disk, '-U', $id]);
  56     return 1;
  57 }
  58
  59 sub disk_is_used {
  60     my ($disk) = @_;
  61
  62     my $dev = $disk;
  63     $dev =~ s|^/dev/||;
  64
  65     my $disklist = get_disks($dev, 1);
  66
  67     die "'$disk' is not a valid local disk\n" if !defined($disklist->{$dev});
  68     return 1 if $disklist->{$dev}->{used};
  69
  70     return 0;
  71 }
  72
  73 sub get_smart_data {
  74     my ($disk, $healthonly) = @_;
  75
  76     assert_blockdev($disk);
  77     my $smartdata = {};
  78     my $type;
  79
  80     my $returncode = 0;
  81
  82     $disk =~ s/n\d+$//
  83         if $disk =~ m!^/dev/nvme\d+n\d+$!;
  84
  85     my $cmd = [$SMARTCTL, '-H'];
  86     push @$cmd, '-A', '-f', 'brief' if !$healthonly;
  87     push @$cmd, $disk;
  88
  89     eval {
  90         $returncode = run_command($cmd, noerr => 1, outfunc => sub{
  91             my ($line) = @_;
  92
  93 # ATA SMART attributes, e.g.:
  94 # ID# ATTRIBUTE_NAME          FLAGS    VALUE WORST THRESH FAIL RAW_VALUE
  95 #   1 Raw_Read_Error_Rate     POSR-K   100   100   000    -    0
  96 #
  97 # SAS and NVME disks, e.g.:
  98 # Data Units Written:                 5,584,952 [2.85 TB]
  99 # Accumulated start-stop cycles:  34
 100
 101             if (defined($type) && $type eq 'ata' && $line =~ m/^([ \d]{2}\d)\s+(\S+)\s+(\S{6})\s+(\d+)\s+(\d+)\s+(\S+)\s+(\S+)\s+(.*)$/) {
 102                 my $entry = {};
 103
 104
 105                 $entry->{name} = $2 if defined $2;
 106                 $entry->{flags} = $3 if defined $3;
 107                 # the +0 makes a number out of the strings
 108                 $entry->{value} = $4+0 if defined $4;
 109                 $entry->{worst} = $5+0 if defined $5;
 110                 # some disks report the default threshold as --- instead of 000
 111                 if (defined($6) && $6 eq '---') {
 112                     $entry->{threshold} = 0;
 113                 } else {
 114                     $entry->{threshold} = $6+0 if defined $6;
 115                 }
 116                 $entry->{fail} = $7 if defined $7;
 117                 $entry->{raw} = $8 if defined $8;
 118                 $entry->{id} = $1 if defined $1;
 119                 push @{$smartdata->{attributes}}, $entry;
 120             } elsif ($line =~ m/(?:Health Status|self\-assessment test result): (.*)$/ ) {
 121                 $smartdata->{health} = $1;
 122             } elsif ($line =~ m/Vendor Specific SMART Attributes with Thresholds:/) {
 123                 $type = 'ata';
 124                 delete $smartdata->{text};
 125             } elsif ($line =~ m/=== START OF (READ )?SMART DATA SECTION ===/) {
 126                 $type = 'text';
 127             } elsif (defined($type) && $type eq 'text') {
 128                 $smartdata->{text} = '' if !defined $smartdata->{text};
 129                 $smartdata->{text} .= "$line\n";
 130             } elsif ($line =~ m/SMART Disabled/) {
 131                 $smartdata->{health} = "SMART Disabled";
 132             }
 133         });
 134     };
 135     my $err = $@;
 136
 137     # bit 0 and 1 mark an severe smartctl error
 138     # all others are for disk status, so ignore them
 139     # see smartctl(8)
 140     if ((defined($returncode) && ($returncode & 0b00000011)) || $err) {
 141         die "Error getting S.M.A.R.T. data: Exit code: $returncode\n";
 142     }
 143
 144     $smartdata->{type} = $type;
 145
 146     return $smartdata;
 147 }
 148
 149 sub get_zfs_devices {
 150     my $list = {};
 151
 152     # use zpool and parttype uuid,
 153     # because log and cache do not have
 154     # zfs type uuid
 155     eval {
 156         run_command([$ZPOOL, 'list', '-HPLv'], outfunc => sub {
 157              my ($line) = @_;
 158
 159              if ($line =~ m|^\t([^\t]+)\t|) {
 160                 $list->{$1} = 1;
 161              }
 162         });
 163     };
 164
 165     # only warn here,
 166     # because maybe zfs tools are not installed
 167     warn "$@\n" if $@;
 168
 169     my $applezfsuuid = "6a898cc3-1dd2-11b2-99a6-080020736631";
 170     my $bsdzfsuuid = "516e7cba-6ecf-11d6-8ff8-00022d09712b";
 171
 172     dir_glob_foreach('/dev/disk/by-parttypeuuid', "($applezfsuuid|$bsdzfsuuid)\..+", sub {
 173         my ($entry) = @_;
 174         my $real_dev = abs_path("/dev/disk/by-parttypeuuid/$entry");
 175         $list->{$real_dev} = 1;
 176     });
 177
 178     return $list;
 179 }
 180
 181 sub get_lvm_devices {
 182     my $list = {};
 183     eval {
 184         run_command([$PVS, '--noheadings', '--readonly', '-o', 'pv_name'], outfunc => sub{
 185             my ($line) = @_;
 186             $line = trim($line);
 187             if ($line =~ m|^/dev/|) {
 188                 $list->{$line} = 1;
 189             }
 190         });
 191     };
 192
 193     # if something goes wrong, we do not want
 194     # to give up, but indicate an error has occured
 195     warn "$@\n" if $@;
 196
 197     my $lvmuuid = "e6d6d379-f507-44c2-a23c-238f2a3df928";
 198
 199     dir_glob_foreach('/dev/disk/by-parttypeuuid', "$lvmuuid\..+", sub {
 200         my ($entry) = @_;
 201         my $real_dev = abs_path("/dev/disk/by-parttypeuuid/$entry");
 202         $list->{$real_dev} = 1;
 203     });
 204
 205     return $list;
 206 }
 207
 208 sub get_ceph_journals {
 209     my $journalhash = {};
 210
 211     my $journal_uuid = '45b0969e-9b03-4f30-b4c6-b4b80ceff106';
 212
 213     dir_glob_foreach('/dev/disk/by-parttypeuuid', "$journal_uuid\..+", sub {
 214         my ($entry) = @_;
 215         my $real_dev = abs_path("/dev/disk/by-parttypeuuid/$entry");
 216         $journalhash->{$real_dev} = 1;
 217     });
 218
 219     return $journalhash;
 220 }
 221
 222 sub get_udev_info {
 223     my ($dev) = @_;
 224
 225     my $info = "";
 226     my $data = {};
 227     eval {
 228         run_command([$UDEVADM, 'info', '-p', $dev, '--query', 'all'], outfunc => sub {
 229             my ($line) = @_;
 230             $info .= "$line\n";
 231         });
 232     };
 233     warn $@ if $@;
 234     return undef if !$info;
 235
 236     return undef if $info !~ m/^E: DEVTYPE=disk$/m;
 237     return undef if $info =~ m/^E: ID_CDROM/m;
 238
 239     # we use this, because some disks are not simply in /dev
 240     # e.g. /dev/cciss/c0d0
 241     if ($info =~ m/^E: DEVNAME=(\S+)$/m) {
 242         $data->{devpath} = $1;
 243     }
 244     return if !defined($data->{devpath});
 245
 246     $data->{serial} = 'unknown';
 247     if ($info =~ m/^E: ID_SERIAL_SHORT=(\S+)$/m) {
 248         $data->{serial} = $1;
 249     }
 250
 251     $data->{gpt} = 0;
 252     if ($info =~ m/^E: ID_PART_TABLE_TYPE=gpt$/m) {
 253         $data->{gpt} = 1;
 254     }
 255
 256     # detect SSD
 257     $data->{rpm} = -1;
 258     if ($info =~ m/^E: ID_ATA_ROTATION_RATE_RPM=(\d+)$/m) {
 259         $data->{rpm} = $1;
 260     }
 261
 262     if ($info =~ m/^E: ID_BUS=usb$/m) {
 263         $data->{usb} = 1;
 264     }
 265
 266     if ($info =~ m/^E: ID_MODEL=(.+)$/m) {
 267         $data->{model} = $1;
 268     }
 269
 270     $data->{wwn} = 'unknown';
 271     if ($info =~ m/^E: ID_WWN=(.*)$/m) {
 272         $data->{wwn} = $1;
 273     }
 274
 275     return $data;
 276 }
 277
 278 sub get_sysdir_info {
 279     my ($sysdir) = @_;
 280
 281     return undef if ! -d "$sysdir/device";
 282
 283     my $data = {};
 284
 285     my $size = file_read_firstline("$sysdir/size");
 286     return undef if !$size;
 287
 288     # linux always considers sectors to be 512 bytes,
 289     # independently of real block size
 290     $data->{size} = $size * 512;
 291
 292     # dir/queue/rotational should be 1 for hdd, 0 for ssd
 293     $data->{rotational} = file_read_firstline("$sysdir/queue/rotational") // -1;
 294
 295     $data->{vendor} = file_read_firstline("$sysdir/device/vendor") || 'unknown';
 296     $data->{model} = file_read_firstline("$sysdir/device/model") || 'unknown';
 297
 298     return $data;
 299 }
 300
 301 sub get_wear_leveling_info {
 302     my ($attributes, $model) = @_;
 303
 304     my $wearout;
 305
 306     my $vendormap = {
 307         'kingston' => 231,
 308         'samsung' => 177,
 309         'intel' => 233,
 310         'sandisk' => 233,
 311         'crucial' => 202,
 312         'default' => 233,
 313     };
 314
 315     # find target attr id
 316
 317     my $attrid;
 318
 319     foreach my $vendor (keys %$vendormap) {
 320         if ($model =~ m/$vendor/i) {
 321             $attrid = $vendormap->{$vendor};
 322             # found the attribute
 323             last;
 324         }
 325     }
 326
 327     if (!$attrid) {
 328         $attrid = $vendormap->{default};
 329     }
 330
 331     foreach my $attr (@$attributes) {
 332         next if $attr->{id} != $attrid;
 333         $wearout = $attr->{value};
 334         last;
 335     }
 336
 337     return $wearout;
 338 }
 339
 340 sub dir_is_empty {
 341     my ($dir) = @_;
 342
 343     my $dh = IO::Dir->new ($dir);
 344     return 1 if !$dh;
 345
 346     while (defined(my $tmp = $dh->read)) {
 347         next if $tmp eq '.' || $tmp eq '..';
 348         $dh->close;
 349         return 0;
 350     }
 351     $dh->close;
 352     return 1;
 353 }
 354
 355 sub get_disks {
 356     my ($disk, $nosmart) = @_;
 357     my $disklist = {};
 358
 359     my $mounted = {};
 360
 361     my $mounts = PVE::ProcFSTools::parse_proc_mounts();
 362
 363     foreach my $mount (@$mounts) {
 364         next if $mount->[0] !~ m|^/dev/|;
 365         $mounted->{abs_path($mount->[0])} = $mount->[1];
 366     };
 367
 368     my $dev_is_mounted = sub {
 369         my ($dev) = @_;
 370         return $mounted->{$dev};
 371     };
 372
 373     my $journalhash = get_ceph_journals();
 374
 375     my $zfslist = get_zfs_devices();
 376
 377     my $lvmlist = get_lvm_devices();
 378
 379     # we get cciss/c0d0 but need cciss!c0d0
 380     if (defined($disk) && $disk =~ m|^cciss/|) {
 381         $disk =~ s|cciss/|cciss!|;
 382     }
 383
 384     dir_glob_foreach('/sys/block', '.*', sub {
 385         my ($dev) = @_;
 386         return if defined($disk) && $disk ne $dev;
 387         # whitelisting following devices
 388         # hdX: ide block device
 389         # sdX: sd block device
 390         # vdX: virtual block device
 391         # xvdX: xen virtual block device
 392         # nvmeXnY: nvme devices
 393         # cciss!cXnY: cciss devices
 394         return if $dev !~ m/^(h|s|x?v)d[a-z]+$/ &&
 395                   $dev !~ m/^nvme\d+n\d+$/ &&
 396                   $dev !~ m/^cciss\!c\d+d\d+$/;
 397
 398         my $data = get_udev_info("/sys/block/$dev");
 399         return if !defined($data);
 400         my $devpath = $data->{devpath};
 401
 402         my $sysdir = "/sys/block/$dev";
 403
 404         # we do not want iscsi devices
 405         return if -l $sysdir && readlink($sysdir) =~ m|host[^/]*/session[^/]*|;
 406
 407         my $sysdata = get_sysdir_info($sysdir);
 408         return if !defined($sysdata);
 409
 410         my $type = 'unknown';
 411
 412         if ($sysdata->{rotational} == 0) {
 413             $type = 'ssd';
 414             $data->{rpm} = 0;
 415         } elsif ($sysdata->{rotational} == 1) {
 416             if ($data->{rpm} != -1) {
 417                 $type = 'hdd';
 418             } elsif ($data->{usb}) {
 419                 $type = 'usb';
 420                 $data->{rpm} = 0;
 421             }
 422         }
 423
 424         my $health = 'UNKNOWN';
 425         my $wearout = 'N/A';
 426
 427         if (!$nosmart) {
 428             eval {
 429                 my $smartdata = get_smart_data($devpath, ($type ne 'ssd'));
 430                 $health = $smartdata->{health} if $smartdata->{health};
 431
 432                 if ($type eq 'ssd') {
 433                     # if we have an ssd we try to get the wearout indicator
 434                     my $wearval = get_wear_leveling_info($smartdata->{attributes}, $data->{model} || $sysdir->{model});
 435                     $wearout = $wearval if $wearval;
 436                 }
 437             };
 438         }
 439
 440         my $used;
 441
 442         $used = 'LVM' if $lvmlist->{$devpath};
 443
 444         $used = 'mounted' if &$dev_is_mounted($devpath);
 445
 446         $used = 'ZFS' if $zfslist->{$devpath};
 447
 448         $disklist->{$dev} = {
 449             vendor => $sysdata->{vendor},
 450             model => $data->{model} || $sysdata->{model},
 451             size => $sysdata->{size},
 452             serial => $data->{serial},
 453             gpt => $data->{gpt},
 454             rpm => $data->{rpm},
 455             type =>  $type,
 456             wwn => $data->{wwn},
 457             health => $health,
 458             devpath => $devpath,
 459             wearout => $wearout,
 460         };
 461
 462         my $osdid = -1;
 463
 464         my $journal_count = 0;
 465
 466         my $found_partitions;
 467         my $found_lvm;
 468         my $found_mountpoints;
 469         my $found_zfs;
 470         my $found_dm;
 471         my $partpath = $devpath;
 472
 473         # remove part after last / to
 474         # get the base path for the partitions
 475         # e.g. from /dev/cciss/c0d0 get /dev/cciss
 476         $partpath =~ s/\/[^\/]+$//;
 477
 478         dir_glob_foreach("$sysdir", "$dev.+", sub {
 479             my ($part) = @_;
 480
 481             $found_partitions = 1;
 482
 483             if (my $mp = &$dev_is_mounted("$partpath/$part")) {
 484                 $found_mountpoints = 1;
 485                 if ($mp =~ m|^/var/lib/ceph/osd/ceph-(\d+)$|) {
 486                     $osdid = $1;
 487                 }
 488             }
 489
 490             if ($lvmlist->{"$partpath/$part"}) {
 491                 $found_lvm = 1;
 492             }
 493
 494             if ($zfslist->{"$partpath/$part"}) {
 495                 $found_zfs = 1;
 496             }
 497
 498             $journal_count++ if $journalhash->{"$partpath/$part"};
 499
 500             if (!dir_is_empty("$sysdir/$part/holders") && !$found_lvm)  {
 501                 $found_dm = 1;
 502             }
 503         });
 504
 505         $used = 'mounted' if $found_mountpoints && !$used;
 506         $used = 'LVM' if $found_lvm && !$used;
 507         $used = 'ZFS' if $found_zfs && !$used;
 508         $used = 'Device Mapper' if $found_dm && !$used;
 509         $used = 'partitions' if $found_partitions && !$used;
 510
 511         # multipath, software raid, etc.
 512         # this check comes in last, to show more specific info
 513         # if we have it
 514         $used = 'Device Mapper' if !$used && !dir_is_empty("$sysdir/holders");
 515
 516         $disklist->{$dev}->{used} = $used if $used;
 517         $disklist->{$dev}->{osdid} = $osdid;
 518         $disklist->{$dev}->{journals} = $journal_count;
 519     });
 520
 521     return $disklist;
 522
 523 }
 524
 525 sub get_partnum {
 526     my ($part_path) = @_;
 527
 528     my ($mode, $rdev) = (stat($part_path))[2,6];
 529
 530     next if !$mode || !S_ISBLK($mode) || !$rdev;
 531     my $major = int($rdev / 0x100);
 532     my $minor = $rdev % 0x100;
 533     my $partnum_path = "/sys/dev/block/$major:$minor/";
 534
 535     my $partnum;
 536
 537     $partnum = file_read_firstline("${partnum_path}partition");
 538
 539     die "Partition does not exists\n" if !defined($partnum);
 540
 541     #untaint and ensure it is a int
 542     if ($partnum =~ m/(\d+)/) {
 543         $partnum = $1;
 544         die "Partition number $partnum is invalid\n" if $partnum > 128;
 545     } else {
 546         die "Failed to get partition number\n";
 547     }
 548
 549     return $partnum;
 550 }
 551
 552 sub get_blockdev {
 553     my ($part_path) = @_;
 554
 555     my $dev = $1 if $part_path =~ m|^/dev/(.*)$|;
 556     my $link = readlink "/sys/class/block/$dev";
 557     my $block_dev = $1 if $link =~ m|([^/]*)/$dev$|;
 558
 559     die "Can't parse parent device\n" if !defined($block_dev);
 560     die "No valid block device\n" if index($dev, $block_dev) == -1;
 561
 562     $block_dev = "/dev/$block_dev";
 563     die "Block device does not exsists\n" if !(-b $block_dev);
 564
 565     return $block_dev;
 566 }
 567
 568 1;