PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use IO::Socket::IP;
  11 use IPC::Open3;
  12 use File::Basename;
  13 use File::Path;
  14 use Cwd 'abs_path';
  15 use Socket;
  16 use Time::Local qw(timelocal);
  17
  18 use PVE::Tools qw(run_command file_read_firstline dir_glob_foreach $IPV6RE);
  19 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  20 use PVE::DataCenterConfig;
  21 use PVE::Exception qw(raise_param_exc raise);
  22 use PVE::JSONSchema;
  23 use PVE::INotify;
  24 use PVE::RPCEnvironment;
  25 use PVE::SSHInfo;
  26
  27 use PVE::Storage::Plugin;
  28 use PVE::Storage::DirPlugin;
  29 use PVE::Storage::LVMPlugin;
  30 use PVE::Storage::LvmThinPlugin;
  31 use PVE::Storage::NFSPlugin;
  32 use PVE::Storage::CIFSPlugin;
  33 use PVE::Storage::ISCSIPlugin;
  34 use PVE::Storage::RBDPlugin;
  35 use PVE::Storage::CephFSPlugin;
  36 use PVE::Storage::ISCSIDirectPlugin;
  37 use PVE::Storage::GlusterfsPlugin;
  38 use PVE::Storage::ZFSPoolPlugin;
  39 use PVE::Storage::ZFSPlugin;
  40 use PVE::Storage::DRBDPlugin;
  41 use PVE::Storage::PBSPlugin;
  42
  43 # Storage API version. Increment it on changes in storage API interface.
  44 use constant APIVER => 8;
  45 # Age is the number of versions we're backward compatible with.
  46 # This is like having 'current=APIVER' and age='APIAGE' in libtool,
  47 # see https://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  48 use constant APIAGE => 7;
  49
  50 # load standard plugins
  51 PVE::Storage::DirPlugin->register();
  52 PVE::Storage::LVMPlugin->register();
  53 PVE::Storage::LvmThinPlugin->register();
  54 PVE::Storage::NFSPlugin->register();
  55 PVE::Storage::CIFSPlugin->register();
  56 PVE::Storage::ISCSIPlugin->register();
  57 PVE::Storage::RBDPlugin->register();
  58 PVE::Storage::CephFSPlugin->register();
  59 PVE::Storage::ISCSIDirectPlugin->register();
  60 PVE::Storage::GlusterfsPlugin->register();
  61 PVE::Storage::ZFSPoolPlugin->register();
  62 PVE::Storage::ZFSPlugin->register();
  63 PVE::Storage::DRBDPlugin->register();
  64 PVE::Storage::PBSPlugin->register();
  65
  66 # load third-party plugins
  67 if ( -d '/usr/share/perl5/PVE/Storage/Custom' ) {
  68     dir_glob_foreach('/usr/share/perl5/PVE/Storage/Custom', '.*\.pm$', sub {
  69         my ($file) = @_;
  70         my $modname = 'PVE::Storage::Custom::' . $file;
  71         $modname =~ s!\.pm$!!;
  72         $file = 'PVE/Storage/Custom/' . $file;
  73
  74         eval {
  75             require $file;
  76
  77             # Check perl interface:
  78             die "not derived from PVE::Storage::Plugin\n"
  79                 if !$modname->isa('PVE::Storage::Plugin');
  80             die "does not provide an api() method\n"
  81                 if !$modname->can('api');
  82             # Check storage API version and that file is really storage plugin.
  83             my $version = $modname->api();
  84             die "implements an API version newer than current ($version > " . APIVER . ")\n"
  85                 if $version > APIVER;
  86             my $min_version = (APIVER - APIAGE);
  87             die "API version too old, please update the plugin ($version < $min_version)\n"
  88                 if $version < $min_version;
  89             import $file;
  90             $modname->register();
  91
  92             # If we got this far and the API version is not the same, make some
  93             # noise:
  94             warn "Plugin \"$modname\" is implementing an older storage API, an upgrade is recommended\n"
  95                 if $version != APIVER;
  96         };
  97         if ($@) {
  98             warn "Error loading storage plugin \"$modname\": $@";
  99         }
 100     });
 101 }
 102
 103 # initialize all plugins
 104 PVE::Storage::Plugin->init();
 105
 106 our $iso_extension_re = qr/\.(?:iso|img)/i;
 107
 108 #  PVE::Storage utility functions
 109
 110 sub config {
 111     return cfs_read_file("storage.cfg");
 112 }
 113
 114 sub write_config {
 115     my ($cfg) = @_;
 116
 117     cfs_write_file('storage.cfg', $cfg);
 118 }
 119
 120 sub lock_storage_config {
 121     my ($code, $errmsg) = @_;
 122
 123     cfs_lock_file("storage.cfg", undef, $code);
 124     my $err = $@;
 125     if ($err) {
 126         $errmsg ? die "$errmsg: $err" : die $err;
 127     }
 128 }
 129
 130 # FIXME remove maxfiles for PVE 7.0
 131 my $convert_maxfiles_to_prune_backups = sub {
 132     my ($scfg) = @_;
 133
 134     return if !$scfg;
 135
 136     my $maxfiles = delete $scfg->{maxfiles};
 137
 138     if (!defined($scfg->{'prune-backups'}) && defined($maxfiles)) {
 139         my $prune_backups;
 140         if ($maxfiles) {
 141             $prune_backups = { 'keep-last' => $maxfiles };
 142         } else { # maxfiles 0 means no limit
 143             $prune_backups = { 'keep-all' => 1 };
 144         }
 145         $scfg->{'prune-backups'} = PVE::JSONSchema::print_property_string(
 146             $prune_backups,
 147             'prune-backups'
 148         );
 149     }
 150 };
 151
 152 sub storage_config {
 153     my ($cfg, $storeid, $noerr) = @_;
 154
 155     die "no storage ID specified\n" if !$storeid;
 156
 157     my $scfg = $cfg->{ids}->{$storeid};
 158
 159     die "storage '$storeid' does not exist\n" if (!$noerr && !$scfg);
 160
 161     $convert_maxfiles_to_prune_backups->($scfg);
 162
 163     return $scfg;
 164 }
 165
 166 sub storage_check_node {
 167     my ($cfg, $storeid, $node, $noerr) = @_;
 168
 169     my $scfg = storage_config($cfg, $storeid);
 170
 171     if ($scfg->{nodes}) {
 172         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
 173         if (!$scfg->{nodes}->{$node}) {
 174             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
 175             return undef;
 176         }
 177     }
 178
 179     return $scfg;
 180 }
 181
 182 sub storage_check_enabled {
 183     my ($cfg, $storeid, $node, $noerr) = @_;
 184
 185     my $scfg = storage_config($cfg, $storeid);
 186
 187     if ($scfg->{disable}) {
 188         die "storage '$storeid' is disabled\n" if !$noerr;
 189         return undef;
 190     }
 191
 192     return storage_check_node($cfg, $storeid, $node, $noerr);
 193 }
 194
 195 # storage_can_replicate:
 196 # return true if storage supports replication
 197 # (volumes alocated with vdisk_alloc() has replication feature)
 198 sub storage_can_replicate {
 199     my ($cfg, $storeid, $format) = @_;
 200
 201     my $scfg = storage_config($cfg, $storeid);
 202     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 203     return $plugin->storage_can_replicate($scfg, $storeid, $format);
 204 }
 205
 206 sub storage_ids {
 207     my ($cfg) = @_;
 208
 209     return keys %{$cfg->{ids}};
 210 }
 211
 212 sub file_size_info {
 213     my ($filename, $timeout) = @_;
 214
 215     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 216 }
 217
 218 sub get_volume_notes {
 219     my ($cfg, $volid, $timeout) = @_;
 220
 221     my ($storeid, $volname) = parse_volume_id($volid);
 222     my $scfg = storage_config($cfg, $storeid);
 223     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 224
 225     return $plugin->get_volume_notes($scfg, $storeid, $volname, $timeout);
 226 }
 227
 228 sub update_volume_notes {
 229     my ($cfg, $volid, $notes, $timeout) = @_;
 230
 231     my ($storeid, $volname) = parse_volume_id($volid);
 232     my $scfg = storage_config($cfg, $storeid);
 233     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 234
 235     $plugin->update_volume_notes($scfg, $storeid, $volname, $notes, $timeout);
 236 }
 237
 238 sub volume_size_info {
 239     my ($cfg, $volid, $timeout) = @_;
 240
 241     my ($storeid, $volname) = parse_volume_id($volid, 1);
 242     if ($storeid) {
 243         my $scfg = storage_config($cfg, $storeid);
 244         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 245         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 246     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 247         return file_size_info($volid, $timeout);
 248     } else {
 249         return 0;
 250     }
 251 }
 252
 253 sub volume_resize {
 254     my ($cfg, $volid, $size, $running) = @_;
 255
 256     my $padding = (1024 - $size % 1024) % 1024;
 257     $size = $size + $padding;
 258
 259     my ($storeid, $volname) = parse_volume_id($volid, 1);
 260     if ($storeid) {
 261         my $scfg = storage_config($cfg, $storeid);
 262         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 263         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 264     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 265         die "resize file/device '$volid' is not possible\n";
 266     } else {
 267         die "unable to parse volume ID '$volid'\n";
 268     }
 269 }
 270
 271 sub volume_rollback_is_possible {
 272     my ($cfg, $volid, $snap) = @_;
 273
 274     my ($storeid, $volname) = parse_volume_id($volid, 1);
 275     if ($storeid) {
 276         my $scfg = storage_config($cfg, $storeid);
 277         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 278         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 279     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 280         die "snapshot rollback file/device '$volid' is not possible\n";
 281     } else {
 282         die "unable to parse volume ID '$volid'\n";
 283     }
 284 }
 285
 286 sub volume_snapshot {
 287     my ($cfg, $volid, $snap) = @_;
 288
 289     my ($storeid, $volname) = parse_volume_id($volid, 1);
 290     if ($storeid) {
 291         my $scfg = storage_config($cfg, $storeid);
 292         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 293         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 294     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 295         die "snapshot file/device '$volid' is not possible\n";
 296     } else {
 297         die "unable to parse volume ID '$volid'\n";
 298     }
 299 }
 300
 301 sub volume_snapshot_rollback {
 302     my ($cfg, $volid, $snap) = @_;
 303
 304     my ($storeid, $volname) = parse_volume_id($volid, 1);
 305     if ($storeid) {
 306         my $scfg = storage_config($cfg, $storeid);
 307         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 308         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 309         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 310     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 311         die "snapshot rollback file/device '$volid' is not possible\n";
 312     } else {
 313         die "unable to parse volume ID '$volid'\n";
 314     }
 315 }
 316
 317 sub volume_snapshot_delete {
 318     my ($cfg, $volid, $snap, $running) = @_;
 319
 320     my ($storeid, $volname) = parse_volume_id($volid, 1);
 321     if ($storeid) {
 322         my $scfg = storage_config($cfg, $storeid);
 323         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 324         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 325     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 326         die "snapshot delete file/device '$volid' is not possible\n";
 327     } else {
 328         die "unable to parse volume ID '$volid'\n";
 329     }
 330 }
 331
 332 # check if a filesystem on top of a volume needs to flush its journal for
 333 # consistency (see fsfreeze(8)) before a snapshot is taken - needed for
 334 # container mountpoints
 335 sub volume_snapshot_needs_fsfreeze {
 336     my ($cfg, $volid) = @_;
 337
 338     my ($storeid, $volname) = parse_volume_id($volid);
 339     my $scfg = storage_config($cfg, $storeid);
 340     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 341     return $plugin->volume_snapshot_needs_fsfreeze();
 342 }
 343
 344 # check if a volume or snapshot supports a given feature
 345 # $feature - one of:
 346 #            clone - linked clone is possible
 347 #            copy  - full clone is possible
 348 #            replicate - replication is possible
 349 #            snapshot - taking a snapshot is possible
 350 #            sparseinit - volume is sparsely initialized
 351 #            template - conversion to base image is possible
 352 # $snap - check if the feature is supported for a given snapshot
 353 # $running - if the guest owning the volume is running
 354 # $opts - hash with further options:
 355 #         valid_target_formats - list of formats for the target of a copy/clone
 356 #                                operation that the caller could work with. The
 357 #                                format of $volid is always considered valid and if
 358 #                                no list is specified, all formats are considered valid.
 359 sub volume_has_feature {
 360     my ($cfg, $feature, $volid, $snap, $running, $opts) = @_;
 361
 362     my ($storeid, $volname) = parse_volume_id($volid, 1);
 363     if ($storeid) {
 364         my $scfg = storage_config($cfg, $storeid);
 365         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 366         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running, $opts);
 367     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 368         return undef;
 369     } else {
 370         return undef;
 371     }
 372 }
 373
 374 sub volume_snapshot_list {
 375     my ($cfg, $volid) = @_;
 376
 377     my ($storeid, $volname) = parse_volume_id($volid, 1);
 378     if ($storeid) {
 379         my $scfg = storage_config($cfg, $storeid);
 380         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 381         return $plugin->volume_snapshot_list($scfg, $storeid, $volname);
 382     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 383         die "send file/device '$volid' is not possible\n";
 384     } else {
 385         die "unable to parse volume ID '$volid'\n";
 386     }
 387     # return an empty array if dataset does not exist.
 388 }
 389
 390 sub get_image_dir {
 391     my ($cfg, $storeid, $vmid) = @_;
 392
 393     my $scfg = storage_config($cfg, $storeid);
 394     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 395
 396     my $path = $plugin->get_subdir($scfg, 'images');
 397
 398     return $vmid ? "$path/$vmid" : $path;
 399 }
 400
 401 sub get_private_dir {
 402     my ($cfg, $storeid, $vmid) = @_;
 403
 404     my $scfg = storage_config($cfg, $storeid);
 405     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 406
 407     my $path = $plugin->get_subdir($scfg, 'rootdir');
 408
 409     return $vmid ? "$path/$vmid" : $path;
 410 }
 411
 412 sub get_iso_dir {
 413     my ($cfg, $storeid) = @_;
 414
 415     my $scfg = storage_config($cfg, $storeid);
 416     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 417
 418     return $plugin->get_subdir($scfg, 'iso');
 419 }
 420
 421 sub get_vztmpl_dir {
 422     my ($cfg, $storeid) = @_;
 423
 424     my $scfg = storage_config($cfg, $storeid);
 425     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 426
 427     return $plugin->get_subdir($scfg, 'vztmpl');
 428 }
 429
 430 sub get_backup_dir {
 431     my ($cfg, $storeid) = @_;
 432
 433     my $scfg = storage_config($cfg, $storeid);
 434     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 435
 436     return $plugin->get_subdir($scfg, 'backup');
 437 }
 438
 439 # library implementation
 440
 441 sub parse_vmid {
 442     my $vmid = shift;
 443
 444     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 445
 446     return int($vmid);
 447 }
 448
 449 # NOTE: basename and basevmid are always undef for LVM-thin, where the
 450 # clone -> base reference is not encoded in the volume ID.
 451 # see note in PVE::Storage::LvmThinPlugin for details.
 452 sub parse_volname {
 453     my ($cfg, $volid) = @_;
 454
 455     my ($storeid, $volname) = parse_volume_id($volid);
 456
 457     my $scfg = storage_config($cfg, $storeid);
 458
 459     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 460
 461     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 462
 463     return $plugin->parse_volname($volname);
 464 }
 465
 466 sub parse_volume_id {
 467     my ($volid, $noerr) = @_;
 468
 469     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 470 }
 471
 472 # test if we have read access to volid
 473 sub check_volume_access {
 474     my ($rpcenv, $user, $cfg, $vmid, $volid) = @_;
 475
 476     my ($sid, $volname) = parse_volume_id($volid, 1);
 477     if ($sid) {
 478         my ($vtype, undef, $ownervm) = parse_volname($cfg, $volid);
 479         if ($vtype eq 'iso' || $vtype eq 'vztmpl') {
 480             # require at least read access to storage, (custom) templates/ISOs could be sensitive
 481             $rpcenv->check_any($user, "/storage/$sid", ['Datastore.AllocateSpace', 'Datastore.Audit']);
 482         } elsif (defined($ownervm) && defined($vmid) && ($ownervm == $vmid)) {
 483             # we are owner - allow access
 484         } elsif ($vtype eq 'backup' && $ownervm) {
 485             $rpcenv->check($user, "/storage/$sid", ['Datastore.AllocateSpace']);
 486             $rpcenv->check($user, "/vms/$ownervm", ['VM.Backup']);
 487         } else {
 488             # allow if we are Datastore administrator
 489             $rpcenv->check($user, "/storage/$sid", ['Datastore.Allocate']);
 490         }
 491     } else {
 492         die "Only root can pass arbitrary filesystem paths."
 493             if $user ne 'root@pam';
 494     }
 495
 496     return undef;
 497 }
 498
 499 # NOTE: this check does not work for LVM-thin, where the clone -> base
 500 # reference is not encoded in the volume ID.
 501 # see note in PVE::Storage::LvmThinPlugin for details.
 502 sub volume_is_base_and_used {
 503     my ($cfg, $volid) = @_;
 504
 505     my ($storeid, $volname) = parse_volume_id($volid);
 506     my $scfg = storage_config($cfg, $storeid);
 507     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 508
 509     my ($vtype, $name, $vmid, undef, undef, $isBase, undef) =
 510         $plugin->parse_volname($volname);
 511
 512     if ($isBase) {
 513         my $vollist = $plugin->list_images($storeid, $scfg);
 514         foreach my $info (@$vollist) {
 515             my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 516             my $basename = undef;
 517             my $basevmid = undef;
 518
 519             eval{
 520                 (undef, undef, undef, $basename, $basevmid) =
 521                     $plugin->parse_volname($tmpvolname);
 522             };
 523
 524             if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 525                 return 1;
 526             }
 527         }
 528     }
 529     return 0;
 530 }
 531
 532 # try to map a filesystem path to a volume identifier
 533 sub path_to_volume_id {
 534     my ($cfg, $path) = @_;
 535
 536     my $ids = $cfg->{ids};
 537
 538     my ($sid, $volname) = parse_volume_id($path, 1);
 539     if ($sid) {
 540         if (my $scfg = $ids->{$sid}) {
 541             if ($scfg->{path}) {
 542                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 543                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 544                 return ($vtype, $path);
 545             }
 546         }
 547         return ('');
 548     }
 549
 550     # Note: abs_path() return undef if $path doesn not exist
 551     # for example when nfs storage is not mounted
 552     $path = abs_path($path) || $path;
 553
 554     foreach my $sid (keys %$ids) {
 555         my $scfg = $ids->{$sid};
 556         next if !$scfg->{path};
 557         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 558         my $imagedir = $plugin->get_subdir($scfg, 'images');
 559         my $isodir = $plugin->get_subdir($scfg, 'iso');
 560         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 561         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 562         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 563         my $snippetsdir = $plugin->get_subdir($scfg, 'snippets');
 564
 565         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 566             my $vmid = $1;
 567             my $name = $2;
 568
 569             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 570             foreach my $info (@$vollist) {
 571                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 572                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 573                 if ($volpath eq $path) {
 574                     return ('images', $info->{volid});
 575                 }
 576             }
 577         } elsif ($path =~ m!^$isodir/([^/]+$iso_extension_re)$!) {
 578             my $name = $1;
 579             return ('iso', "$sid:iso/$name");
 580         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 581             my $name = $1;
 582             return ('vztmpl', "$sid:vztmpl/$name");
 583         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 584             my $vmid = $1;
 585             return ('rootdir', "$sid:rootdir/$vmid");
 586         } elsif ($path =~ m!^$backupdir/([^/]+\.(?:tgz|(?:(?:tar|vma)(?:\.(?:${\PVE::Storage::Plugin::COMPRESSOR_RE}))?)))$!) {
 587             my $name = $1;
 588             return ('backup', "$sid:backup/$name");
 589         } elsif ($path =~ m!^$snippetsdir/([^/]+)$!) {
 590             my $name = $1;
 591             return ('snippets', "$sid:snippets/$name");
 592         }
 593     }
 594
 595     # can't map path to volume id
 596     return ('');
 597 }
 598
 599 sub path {
 600     my ($cfg, $volid, $snapname) = @_;
 601
 602     my ($storeid, $volname) = parse_volume_id($volid);
 603
 604     my $scfg = storage_config($cfg, $storeid);
 605
 606     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 607     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 608     return wantarray ? ($path, $owner, $vtype) : $path;
 609 }
 610
 611 sub abs_filesystem_path {
 612     my ($cfg, $volid) = @_;
 613
 614     my $path;
 615     if (parse_volume_id ($volid, 1)) {
 616         activate_volumes($cfg, [ $volid ]);
 617         $path = PVE::Storage::path($cfg, $volid);
 618     } else {
 619         if (-f $volid) {
 620             my $abspath = abs_path($volid);
 621             if ($abspath && $abspath =~ m|^(/.+)$|) {
 622                 $path = $1; # untaint any path
 623             }
 624         }
 625     }
 626
 627     die "can't find file '$volid'\n" if !($path && -f $path);
 628
 629     return $path;
 630 }
 631
 632 my $volname_for_storage = sub {
 633     my ($cfg, $volid, $target_storeid) = @_;
 634
 635     my (undef, $name, $vmid, undef, undef, undef, $format) = parse_volname($cfg, $volid);
 636     my $target_scfg = storage_config($cfg, $target_storeid);
 637
 638     my (undef, $valid_formats) = PVE::Storage::Plugin::default_format($target_scfg);
 639     my $format_is_valid = grep { $_ eq $format } @$valid_formats;
 640     die "unsupported format '$format' for storage type $target_scfg->{type}\n" if !$format_is_valid;
 641
 642     (my $name_without_extension = $name) =~ s/\.$format$//;
 643
 644     if ($target_scfg->{path}) {
 645        return "$vmid/$name_without_extension.$format";
 646     } else {
 647        return "$name_without_extension";
 648     }
 649 };
 650
 651 sub storage_migrate {
 652     my ($cfg, $volid, $target_sshinfo, $target_storeid, $opts, $logfunc) = @_;
 653
 654     my $base_snapshot = $opts->{base_snapshot};
 655     my $snapshot = $opts->{snapshot};
 656     my $ratelimit_bps = $opts->{ratelimit_bps};
 657     my $insecure = $opts->{insecure};
 658     my $with_snapshots = $opts->{with_snapshots} ? 1 : 0;
 659     my $allow_rename = $opts->{allow_rename} ? 1 : 0;
 660
 661     my ($storeid, $volname) = parse_volume_id($volid);
 662
 663     my $scfg = storage_config($cfg, $storeid);
 664
 665     # no need to migrate shared content
 666     return $volid if $storeid eq $target_storeid && $scfg->{shared};
 667
 668     my $tcfg = storage_config($cfg, $target_storeid);
 669
 670     my $target_volname;
 671     if ($opts->{target_volname}) {
 672         $target_volname = $opts->{target_volname};
 673     } elsif ($scfg->{type} eq $tcfg->{type}) {
 674         $target_volname = $volname;
 675     } else {
 676         $target_volname = $volname_for_storage->($cfg, $volid, $target_storeid);
 677     }
 678
 679     my $target_volid = "${target_storeid}:${target_volname}";
 680
 681     my $target_ip = $target_sshinfo->{ip};
 682
 683     my $ssh = PVE::SSHInfo::ssh_info_to_command($target_sshinfo);
 684     my $ssh_base = PVE::SSHInfo::ssh_info_to_command_base($target_sshinfo);
 685     local $ENV{RSYNC_RSH} = PVE::Tools::cmd2string($ssh_base);
 686
 687     my @cstream;
 688     if (defined($ratelimit_bps)) {
 689         @cstream = ([ '/usr/bin/cstream', '-t', $ratelimit_bps ]);
 690         $logfunc->("using a bandwidth limit of $ratelimit_bps bps for transferring '$volid'") if $logfunc;
 691     }
 692
 693     my $migration_snapshot;
 694     if (!defined($snapshot)) {
 695         if ($scfg->{type} eq 'zfspool') {
 696             $migration_snapshot = 1;
 697             $snapshot = '__migration__';
 698         }
 699     }
 700
 701     my @formats = volume_transfer_formats($cfg, $volid, $target_volid, $snapshot, $base_snapshot, $with_snapshots);
 702     die "cannot migrate from storage type '$scfg->{type}' to '$tcfg->{type}'\n" if !@formats;
 703     my $format = $formats[0];
 704
 705     my $import_fn = '-'; # let pvesm import read from stdin per default
 706     if ($insecure) {
 707         my $net = $target_sshinfo->{network} // $target_sshinfo->{ip};
 708         $import_fn = "tcp://$net";
 709     }
 710
 711     my $target_apiver = 1; # if there is no apiinfo call, assume 1
 712     my $get_api_version = [@$ssh, 'pvesm', 'apiinfo'];
 713     my $match_api_version = sub { $target_apiver = $1 if $_[0] =~ m!^APIVER (\d+)$!; };
 714     eval { run_command($get_api_version, logfunc => $match_api_version); };
 715
 716     my $send = ['pvesm', 'export', $volid, $format, '-', '-with-snapshots', $with_snapshots];
 717     my $recv = [@$ssh, '--', 'pvesm', 'import', $target_volid, $format, $import_fn, '-with-snapshots', $with_snapshots];
 718     if (defined($snapshot)) {
 719         push @$send, '-snapshot', $snapshot
 720     }
 721     if ($migration_snapshot) {
 722         push @$recv, '-delete-snapshot', $snapshot;
 723     }
 724     push @$recv, '-allow-rename', $allow_rename if $target_apiver >= 5;
 725
 726     if (defined($base_snapshot)) {
 727         # Check if the snapshot exists on the remote side:
 728         push @$send, '-base', $base_snapshot;
 729         push @$recv, '-base', $base_snapshot;
 730     }
 731
 732     my $new_volid;
 733     my $pattern = volume_imported_message(undef, 1);
 734     my $match_volid_and_log = sub {
 735         my $line = shift;
 736
 737         $new_volid = $1 if ($line =~ $pattern);
 738
 739         if ($logfunc) {
 740             chomp($line);
 741             $logfunc->($line);
 742         }
 743     };
 744
 745     volume_snapshot($cfg, $volid, $snapshot) if $migration_snapshot;
 746
 747     if (defined($snapshot)) {
 748         activate_volumes($cfg, [$volid], $snapshot);
 749     } else {
 750         activate_volumes($cfg, [$volid]);
 751     }
 752
 753     eval {
 754         if ($insecure) {
 755             my $input = IO::File->new();
 756             my $info = IO::File->new();
 757             open3($input, $info, $info, @{$recv})
 758                 or die "receive command failed: $!\n";
 759             close($input);
 760
 761             my $try_ip = <$info> // '';
 762             my ($ip) = $try_ip =~ /^($PVE::Tools::IPRE)$/ # untaint
 763                 or die "no tunnel IP received, got '$try_ip'\n";
 764
 765             my $try_port = <$info> // '';
 766             my ($port) = $try_port =~ /^(\d+)$/ # untaint
 767                 or die "no tunnel port received, got '$try_port'\n";
 768
 769             my $socket = IO::Socket::IP->new(PeerHost => $ip, PeerPort => $port, Type => SOCK_STREAM)
 770                 or die "failed to connect to tunnel at $ip:$port\n";
 771             # we won't be reading from the socket
 772             shutdown($socket, 0);
 773
 774             eval { run_command([$send, @cstream], output => '>&'.fileno($socket), errfunc => $logfunc); };
 775             my $send_error = $@;
 776
 777             # don't close the connection entirely otherwise the receiving end
 778             # might not get all buffered data (and fails with 'connection reset by peer')
 779             shutdown($socket, 1);
 780
 781             # wait for the remote process to finish
 782             while (my $line = <$info>) {
 783                 $match_volid_and_log->("[$target_sshinfo->{name}] $line");
 784             }
 785
 786             # now close the socket
 787             close($socket);
 788             if (!close($info)) { # does waitpid()
 789                 die "import failed: $!\n" if $!;
 790                 die "import failed: exit code ".($?>>8)."\n";
 791             }
 792
 793             die $send_error if $send_error;
 794         } else {
 795             run_command([$send, @cstream, $recv], logfunc => $match_volid_and_log);
 796         }
 797
 798         die "unable to get ID of the migrated volume\n"
 799             if !defined($new_volid) && $target_apiver >= 5;
 800     };
 801     my $err = $@;
 802     warn "send/receive failed, cleaning up snapshot(s)..\n" if $err;
 803     if ($migration_snapshot) {
 804         eval { volume_snapshot_delete($cfg, $volid, $snapshot, 0) };
 805         warn "could not remove source snapshot: $@\n" if $@;
 806     }
 807     die $err if $err;
 808
 809     return $new_volid // $target_volid;
 810 }
 811
 812 sub vdisk_clone {
 813     my ($cfg, $volid, $vmid, $snap) = @_;
 814
 815     my ($storeid, $volname) = parse_volume_id($volid);
 816
 817     my $scfg = storage_config($cfg, $storeid);
 818
 819     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 820
 821     activate_storage($cfg, $storeid);
 822
 823     # lock shared storage
 824     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 825         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 826         return "$storeid:$volname";
 827     });
 828 }
 829
 830 sub vdisk_create_base {
 831     my ($cfg, $volid) = @_;
 832
 833     my ($storeid, $volname) = parse_volume_id($volid);
 834
 835     my $scfg = storage_config($cfg, $storeid);
 836
 837     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 838
 839     activate_storage($cfg, $storeid);
 840
 841     # lock shared storage
 842     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 843         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 844         return "$storeid:$volname";
 845     });
 846 }
 847
 848 sub map_volume {
 849     my ($cfg, $volid, $snapname) = @_;
 850
 851     my ($storeid, $volname) = parse_volume_id($volid);
 852
 853     my $scfg = storage_config($cfg, $storeid);
 854
 855     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 856
 857     return $plugin->map_volume($storeid, $scfg, $volname, $snapname);
 858 }
 859
 860 sub unmap_volume {
 861     my ($cfg, $volid, $snapname) = @_;
 862
 863     my ($storeid, $volname) = parse_volume_id($volid);
 864
 865     my $scfg = storage_config($cfg, $storeid);
 866
 867     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 868
 869     return $plugin->unmap_volume($storeid, $scfg, $volname, $snapname);
 870 }
 871
 872 sub vdisk_alloc {
 873     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 874
 875     die "no storage ID specified\n" if !$storeid;
 876
 877     PVE::JSONSchema::parse_storage_id($storeid);
 878
 879     my $scfg = storage_config($cfg, $storeid);
 880
 881     die "no VMID specified\n" if !$vmid;
 882
 883     $vmid = parse_vmid($vmid);
 884
 885     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 886
 887     $fmt = $defformat if !$fmt;
 888
 889     activate_storage($cfg, $storeid);
 890
 891     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 892
 893     # lock shared storage
 894     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 895         my $old_umask = umask(umask|0037);
 896         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 897         my $err = $@;
 898         umask $old_umask;
 899         die $err if $err;
 900         return "$storeid:$volname";
 901     });
 902 }
 903
 904 sub vdisk_free {
 905     my ($cfg, $volid) = @_;
 906
 907     my ($storeid, $volname) = parse_volume_id($volid);
 908     my $scfg = storage_config($cfg, $storeid);
 909     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 910
 911     activate_storage($cfg, $storeid);
 912
 913     my $cleanup_worker;
 914
 915     # lock shared storage
 916     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 917         # LVM-thin allows deletion of still referenced base volumes!
 918         die "base volume '$volname' is still in use by linked clones\n"
 919             if volume_is_base_and_used($cfg, $volid);
 920
 921         my (undef, undef, undef, undef, undef, $isBase, $format) =
 922             $plugin->parse_volname($volname);
 923         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 924     });
 925
 926     return if !$cleanup_worker;
 927
 928     my $rpcenv = PVE::RPCEnvironment::get();
 929     my $authuser = $rpcenv->get_user();
 930
 931     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 932 }
 933
 934 sub vdisk_list {
 935     my ($cfg, $storeid, $vmid, $vollist) = @_;
 936
 937     my $ids = $cfg->{ids};
 938
 939     storage_check_enabled($cfg, $storeid) if ($storeid);
 940
 941     my $res = {};
 942
 943     # prepare/activate/refresh all storages
 944
 945     my $storage_list = [];
 946     if ($vollist) {
 947         foreach my $volid (@$vollist) {
 948             my ($sid, undef) = parse_volume_id($volid);
 949             next if !defined($ids->{$sid});
 950             next if !storage_check_enabled($cfg, $sid, undef, 1);
 951             push @$storage_list, $sid;
 952         }
 953     } else {
 954         foreach my $sid (keys %$ids) {
 955             next if $storeid && $storeid ne $sid;
 956             next if !storage_check_enabled($cfg, $sid, undef, 1);
 957             my $content = $ids->{$sid}->{content};
 958             next if !($content->{rootdir} || $content->{images});
 959             push @$storage_list, $sid;
 960         }
 961     }
 962
 963     my $cache = {};
 964
 965     activate_storage_list($cfg, $storage_list, $cache);
 966
 967     # FIXME PVE 7.0: only scan storages with the correct content types
 968     foreach my $sid (keys %$ids) {
 969         next if $storeid && $storeid ne $sid;
 970         next if !storage_check_enabled($cfg, $sid, undef, 1);
 971
 972         my $scfg = $ids->{$sid};
 973         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 974         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 975         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 976     }
 977
 978     return $res;
 979 }
 980
 981 sub template_list {
 982     my ($cfg, $storeid, $tt) = @_;
 983
 984     die "unknown template type '$tt'\n"
 985         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup' || $tt eq 'snippets');
 986
 987     my $ids = $cfg->{ids};
 988
 989     storage_check_enabled($cfg, $storeid) if ($storeid);
 990
 991     my $res = {};
 992
 993     # query the storage
 994     foreach my $sid (keys %$ids) {
 995         next if $storeid && $storeid ne $sid;
 996
 997         my $scfg = $ids->{$sid};
 998         my $type = $scfg->{type};
 999
1000         next if !$scfg->{content}->{$tt};
1001
1002         next if !storage_check_enabled($cfg, $sid, undef, 1);
1003
1004         $res->{$sid} = volume_list($cfg, $sid, undef, $tt);
1005     }
1006
1007     return $res;
1008 }
1009
1010 sub volume_list {
1011     my ($cfg, $storeid, $vmid, $content) = @_;
1012
1013     my @ctypes = qw(rootdir images vztmpl iso backup snippets);
1014
1015     my $cts = $content ? [ $content ] : [ @ctypes ];
1016
1017     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
1018
1019     $cts = [ grep { defined($scfg->{content}->{$_}) } @$cts ];
1020
1021     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1022
1023     activate_storage($cfg, $storeid);
1024
1025     my $res = $plugin->list_volumes($storeid, $scfg, $vmid, $cts);
1026
1027     @$res = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @$res;
1028
1029     return $res;
1030 }
1031
1032 sub uevent_seqnum {
1033
1034     my $filename = "/sys/kernel/uevent_seqnum";
1035
1036     my $seqnum = 0;
1037     if (my $fh = IO::File->new($filename, "r")) {
1038         my $line = <$fh>;
1039         if ($line =~ m/^(\d+)$/) {
1040             $seqnum = int($1);
1041         }
1042         close ($fh);
1043     }
1044     return $seqnum;
1045 }
1046
1047 sub activate_storage {
1048     my ($cfg, $storeid, $cache) = @_;
1049
1050     $cache = {} if !$cache;
1051
1052     my $scfg = storage_check_enabled($cfg, $storeid);
1053
1054     return if $cache->{activated}->{$storeid};
1055
1056     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
1057
1058     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1059
1060     if ($scfg->{base}) {
1061         my ($baseid, undef) = parse_volume_id ($scfg->{base});
1062         activate_storage($cfg, $baseid, $cache);
1063     }
1064
1065     if (!$plugin->check_connection($storeid, $scfg)) {
1066         die "storage '$storeid' is not online\n";
1067     }
1068
1069     $plugin->activate_storage($storeid, $scfg, $cache);
1070
1071     my $newseq = uevent_seqnum ();
1072
1073     # only call udevsettle if there are events
1074     if ($newseq > $cache->{uevent_seqnum}) {
1075         system ("udevadm settle --timeout=30"); # ignore errors
1076         $cache->{uevent_seqnum} = $newseq;
1077     }
1078
1079     $cache->{activated}->{$storeid} = 1;
1080 }
1081
1082 sub activate_storage_list {
1083     my ($cfg, $storeid_list, $cache) = @_;
1084
1085     $cache = {} if !$cache;
1086
1087     foreach my $storeid (@$storeid_list) {
1088         activate_storage($cfg, $storeid, $cache);
1089     }
1090 }
1091
1092 sub deactivate_storage {
1093     my ($cfg, $storeid) = @_;
1094
1095     my $scfg = storage_config ($cfg, $storeid);
1096     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1097
1098     my $cache = {};
1099     $plugin->deactivate_storage($storeid, $scfg, $cache);
1100 }
1101
1102 sub activate_volumes {
1103     my ($cfg, $vollist, $snapname) = @_;
1104
1105     return if !($vollist && scalar(@$vollist));
1106
1107     my $storagehash = {};
1108     foreach my $volid (@$vollist) {
1109         my ($storeid, undef) = parse_volume_id($volid);
1110         $storagehash->{$storeid} = 1;
1111     }
1112
1113     my $cache = {};
1114
1115     activate_storage_list($cfg, [keys %$storagehash], $cache);
1116
1117     foreach my $volid (@$vollist) {
1118         my ($storeid, $volname) = parse_volume_id($volid);
1119         my $scfg = storage_config($cfg, $storeid);
1120         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1121         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
1122     }
1123 }
1124
1125 sub deactivate_volumes {
1126     my ($cfg, $vollist, $snapname) = @_;
1127
1128     return if !($vollist && scalar(@$vollist));
1129
1130     my $cache = {};
1131
1132     my @errlist = ();
1133     foreach my $volid (@$vollist) {
1134         my ($storeid, $volname) = parse_volume_id($volid);
1135
1136         my $scfg = storage_config($cfg, $storeid);
1137         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1138
1139         eval {
1140             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
1141         };
1142         if (my $err = $@) {
1143             warn $err;
1144             push @errlist, $volid;
1145         }
1146     }
1147
1148     die "volume deactivation failed: " . join(' ', @errlist)
1149         if scalar(@errlist);
1150 }
1151
1152 sub storage_info {
1153     my ($cfg, $content, $includeformat) = @_;
1154
1155     my $ids = $cfg->{ids};
1156
1157     my $info = {};
1158
1159     my @ctypes = PVE::Tools::split_list($content);
1160
1161     my $slist = [];
1162     foreach my $storeid (keys %$ids) {
1163         my $storage_enabled = defined(storage_check_enabled($cfg, $storeid, undef, 1));
1164
1165         if (defined($content)) {
1166             my $want_ctype = 0;
1167             foreach my $ctype (@ctypes) {
1168                 if ($ids->{$storeid}->{content}->{$ctype}) {
1169                     $want_ctype = 1;
1170                     last;
1171                 }
1172             }
1173             next if !$want_ctype || !$storage_enabled;
1174         }
1175
1176         my $type = $ids->{$storeid}->{type};
1177
1178         $info->{$storeid} = {
1179             type => $type,
1180             total => 0,
1181             avail => 0,
1182             used => 0,
1183             shared => $ids->{$storeid}->{shared} ? 1 : 0,
1184             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
1185             active => 0,
1186             enabled => $storage_enabled ? 1 : 0,
1187         };
1188
1189         push @$slist, $storeid;
1190     }
1191
1192     my $cache = {};
1193
1194     foreach my $storeid (keys %$ids) {
1195         my $scfg = $ids->{$storeid};
1196
1197         next if !$info->{$storeid};
1198         next if !$info->{$storeid}->{enabled};
1199
1200         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1201         if ($includeformat) {
1202             my $pd = $plugin->plugindata();
1203             $info->{$storeid}->{format} = $pd->{format}
1204                 if $pd->{format};
1205             $info->{$storeid}->{select_existing} = $pd->{select_existing}
1206                 if $pd->{select_existing};
1207         }
1208
1209         eval { activate_storage($cfg, $storeid, $cache); };
1210         if (my $err = $@) {
1211             warn $err;
1212             next;
1213         }
1214
1215         my ($total, $avail, $used, $active) = eval { $plugin->status($storeid, $scfg, $cache); };
1216         warn $@ if $@;
1217         next if !$active;
1218         $info->{$storeid}->{total} = int($total);
1219         $info->{$storeid}->{avail} = int($avail);
1220         $info->{$storeid}->{used} = int($used);
1221         $info->{$storeid}->{active} = $active;
1222     }
1223
1224     return $info;
1225 }
1226
1227 sub resolv_server {
1228     my ($server) = @_;
1229
1230     my ($packed_ip, $family);
1231     eval {
1232         my @res = PVE::Tools::getaddrinfo_all($server);
1233         $family = $res[0]->{family};
1234         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1235     };
1236     if (defined $packed_ip) {
1237         return Socket::inet_ntop($family, $packed_ip);
1238     }
1239     return undef;
1240 }
1241
1242 sub scan_nfs {
1243     my ($server_in) = @_;
1244
1245     my $server;
1246     if (!($server = resolv_server ($server_in))) {
1247         die "unable to resolve address for server '${server_in}'\n";
1248     }
1249
1250     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1251
1252     my $res = {};
1253     run_command($cmd, outfunc => sub {
1254         my $line = shift;
1255
1256         # note: howto handle white spaces in export path??
1257         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1258             $res->{$1} = $2;
1259         }
1260     });
1261
1262     return $res;
1263 }
1264
1265 sub scan_cifs {
1266     my ($server_in, $user, $password, $domain) = @_;
1267
1268     my $server = resolv_server($server_in);
1269     die "unable to resolve address for server '${server_in}'\n" if !$server;
1270
1271     # we only support Windows 2012 and newer, so just use smb3
1272     my $cmd = ['/usr/bin/smbclient', '-m', 'smb3', '-d', '0', '-L', $server];
1273     push @$cmd, '-W', $domain if defined($domain);
1274
1275     push @$cmd, '-N' if !defined($password);
1276     local $ENV{USER} = $user if defined($user);
1277     local $ENV{PASSWD} = $password if defined($password);
1278
1279     my $res = {};
1280     my $err = '';
1281     run_command($cmd,
1282         noerr => 1,
1283         errfunc => sub {
1284             $err .= "$_[0]\n"
1285         },
1286         outfunc => sub {
1287             my $line = shift;
1288             if ($line =~ m/(\S+)\s*Disk\s*(\S*)/) {
1289                 $res->{$1} = $2;
1290             } elsif ($line =~ m/(NT_STATUS_(\S+))/) {
1291                 my $status = $1;
1292                 $err .= "unexpected status: $1\n" if uc($1) ne 'SUCCESS';
1293             }
1294         },
1295     );
1296     # only die if we got no share, else it's just some followup check error
1297     # (like workgroup querying)
1298     raise($err) if $err && !%$res;
1299
1300     return $res;
1301 }
1302
1303 sub scan_zfs {
1304
1305     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-Hp', '-o', 'name,avail,used'];
1306
1307     my $res = [];
1308     run_command($cmd, outfunc => sub {
1309         my $line = shift;
1310
1311         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1312             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1313             my $size = $size_str + 0;
1314             my $used = $used_str + 0;
1315             # ignore subvolumes generated by our ZFSPoolPlugin
1316             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1317             return if $pool =~ m!/basevol-\d+-[^/]+$!;
1318             push @$res, { pool => $pool, size => $size, free => $size-$used };
1319         }
1320     });
1321
1322     return $res;
1323 }
1324
1325 sub resolv_portal {
1326     my ($portal, $noerr) = @_;
1327
1328     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1329     if ($server) {
1330         if (my $ip = resolv_server($server)) {
1331             $server = $ip;
1332             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1333             return $port ? "$server:$port" : $server;
1334         }
1335     }
1336     return undef if $noerr;
1337
1338     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1339 }
1340
1341
1342 sub scan_iscsi {
1343     my ($portal_in) = @_;
1344
1345     my $portal;
1346     if (!($portal = resolv_portal($portal_in))) {
1347         die "unable to parse/resolve portal address '${portal_in}'\n";
1348     }
1349
1350     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1351 }
1352
1353 sub storage_default_format {
1354     my ($cfg, $storeid) = @_;
1355
1356     my $scfg = storage_config ($cfg, $storeid);
1357
1358     return PVE::Storage::Plugin::default_format($scfg);
1359 }
1360
1361 sub vgroup_is_used {
1362     my ($cfg, $vgname) = @_;
1363
1364     foreach my $storeid (keys %{$cfg->{ids}}) {
1365         my $scfg = storage_config($cfg, $storeid);
1366         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1367             return 1;
1368         }
1369     }
1370
1371     return undef;
1372 }
1373
1374 sub target_is_used {
1375     my ($cfg, $target) = @_;
1376
1377     foreach my $storeid (keys %{$cfg->{ids}}) {
1378         my $scfg = storage_config($cfg, $storeid);
1379         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1380             return 1;
1381         }
1382     }
1383
1384     return undef;
1385 }
1386
1387 sub volume_is_used {
1388     my ($cfg, $volid) = @_;
1389
1390     foreach my $storeid (keys %{$cfg->{ids}}) {
1391         my $scfg = storage_config($cfg, $storeid);
1392         if ($scfg->{base} && $scfg->{base} eq $volid) {
1393             return 1;
1394         }
1395     }
1396
1397     return undef;
1398 }
1399
1400 sub storage_is_used {
1401     my ($cfg, $storeid) = @_;
1402
1403     foreach my $sid (keys %{$cfg->{ids}}) {
1404         my $scfg = storage_config($cfg, $sid);
1405         next if !$scfg->{base};
1406         my ($st) = parse_volume_id($scfg->{base});
1407         return 1 if $st && $st eq $storeid;
1408     }
1409
1410     return undef;
1411 }
1412
1413 sub foreach_volid {
1414     my ($list, $func) = @_;
1415
1416     return if !$list;
1417
1418     foreach my $sid (keys %$list) {
1419        foreach my $info (@{$list->{$sid}}) {
1420            my $volid = $info->{volid};
1421            my ($sid1, $volname) = parse_volume_id($volid, 1);
1422            if ($sid1 && $sid1 eq $sid) {
1423                &$func ($volid, $sid, $info);
1424            } else {
1425                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1426            }
1427        }
1428     }
1429 }
1430
1431 sub decompressor_info {
1432     my ($format, $comp) = @_;
1433
1434     if ($format eq 'tgz' && !defined($comp)) {
1435         ($format, $comp) = ('tar', 'gz');
1436     }
1437
1438     my $decompressor = {
1439         tar => {
1440             gz => ['tar', '-z'],
1441             lzo => ['tar', '--lzop'],
1442             zst => ['tar', '--zstd'],
1443         },
1444         vma => {
1445             gz => ['zcat'],
1446             lzo => ['lzop', '-d', '-c'],
1447             zst => ['zstd', '-q', '-d', '-c'],
1448         },
1449     };
1450
1451     die "ERROR: archive format not defined\n"
1452         if !defined($decompressor->{$format});
1453
1454     my $decomp;
1455     $decomp = $decompressor->{$format}->{$comp} if $comp;
1456
1457     my $info = {
1458         format => $format,
1459         compression => $comp,
1460         decompressor => $decomp,
1461     };
1462
1463     return $info;
1464 }
1465
1466 sub archive_info {
1467     my ($archive) = shift;
1468     my $info;
1469
1470     my $volid = basename($archive);
1471     if ($volid =~ /^(vzdump-(lxc|openvz|qemu)-.+\.(tgz$|tar|vma)(?:\.(${\PVE::Storage::Plugin::COMPRESSOR_RE}))?)$/) {
1472         my $filename = "$1"; # untaint
1473         my ($type, $format, $comp) = ($2, $3, $4);
1474         my $format_re = defined($comp) ? "$format.$comp" : "$format";
1475         $info = decompressor_info($format, $comp);
1476         $info->{filename} = $filename;
1477         $info->{type} = $type;
1478
1479         if ($volid =~ /^(vzdump-${type}-([1-9][0-9]{2,8})-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2}))\.${format_re}$/) {
1480             $info->{logfilename} = "$1.log";
1481             $info->{vmid} = int($2);
1482             $info->{ctime} = timelocal($8, $7, $6, $5, $4 - 1, $3);
1483             $info->{is_std_name} = 1;
1484         } else {
1485             $info->{is_std_name} = 0;
1486         }
1487     } else {
1488         die "ERROR: couldn't determine archive info from '$archive'\n";
1489     }
1490
1491     return $info;
1492 }
1493
1494 sub archive_remove {
1495     my ($archive_path) = @_;
1496
1497     my $dirname = dirname($archive_path);
1498     my $archive_info = eval { archive_info($archive_path) } // {};
1499     my $logfn = $archive_info->{logfilename};
1500
1501     unlink $archive_path or die "removing archive $archive_path failed: $!\n";
1502
1503     if (defined($logfn)) {
1504         my $logpath = "$dirname/$logfn";
1505         if (-e $logpath) {
1506             unlink $logpath or warn "removing log file $logpath failed: $!\n";
1507         }
1508     }
1509 }
1510
1511 sub extract_vzdump_config_tar {
1512     my ($archive, $conf_re) = @_;
1513
1514     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
1515
1516     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
1517        die "unable to open file '$archive'\n";
1518
1519     my $file;
1520     while (defined($file = <$fh>)) {
1521         if ($file =~ $conf_re) {
1522             $file = $1; # untaint
1523             last;
1524         }
1525     }
1526
1527     kill 15, $pid;
1528     waitpid $pid, 0;
1529     close $fh;
1530
1531     die "ERROR: archive contains no configuration file\n" if !$file;
1532     chomp $file;
1533
1534     my $raw = '';
1535     my $out = sub {
1536         my $output = shift;
1537         $raw .= "$output\n";
1538     };
1539
1540     run_command(['tar', '-xpOf', $archive, $file, '--occurrence'], outfunc => $out);
1541
1542     return wantarray ? ($raw, $file) : $raw;
1543 }
1544
1545 sub extract_vzdump_config_vma {
1546     my ($archive, $comp) = @_;
1547
1548     my $raw = '';
1549     my $out = sub { $raw .= "$_[0]\n"; };
1550
1551     my $info = archive_info($archive);
1552     $comp //= $info->{compression};
1553     my $decompressor = $info->{decompressor};
1554
1555     if ($comp) {
1556         my $cmd = [ [@$decompressor, $archive], ["vma", "config", "-"] ];
1557
1558         # lzop/zcat exits with 1 when the pipe is closed early by vma, detect this and ignore the exit code later
1559         my $broken_pipe;
1560         my $errstring;
1561         my $err = sub {
1562             my $output = shift;
1563             if ($output =~ m/lzop: Broken pipe: <stdout>/ || $output =~ m/gzip: stdout: Broken pipe/ || $output =~ m/zstd: error 70 : Write error : Broken pipe/) {
1564                 $broken_pipe = 1;
1565             } elsif (!defined ($errstring) && $output !~ m/^\s*$/) {
1566                 $errstring = "Failed to extract config from VMA archive: $output\n";
1567             }
1568         };
1569
1570         my $rc = eval { run_command($cmd, outfunc => $out, errfunc => $err, noerr => 1) };
1571         my $rerr = $@;
1572
1573         $broken_pipe ||= $rc == 141; # broken pipe from vma POV
1574
1575         if (!$errstring && !$broken_pipe && $rc != 0) {
1576             die "$rerr\n" if $rerr;
1577             die "config extraction failed with exit code $rc\n";
1578         }
1579         die "$errstring\n" if $errstring;
1580     } else {
1581         run_command(["vma", "config", $archive], outfunc => $out);
1582     }
1583
1584     return wantarray ? ($raw, undef) : $raw;
1585 }
1586
1587 sub extract_vzdump_config {
1588     my ($cfg, $volid) = @_;
1589
1590     my ($storeid, $volname) = parse_volume_id($volid);
1591     if (defined($storeid)) {
1592         my $scfg = storage_config($cfg, $storeid);
1593         if ($scfg->{type} eq 'pbs') {
1594             storage_check_enabled($cfg, $storeid);
1595             return PVE::Storage::PBSPlugin->extract_vzdump_config($scfg, $volname, $storeid);
1596         }
1597     }
1598
1599     my $archive = abs_filesystem_path($cfg, $volid);
1600     my $info = archive_info($archive);
1601     my $format = $info->{format};
1602     my $comp = $info->{compression};
1603     my $type = $info->{type};
1604
1605     if ($type eq 'lxc' || $type eq 'openvz') {
1606         return extract_vzdump_config_tar($archive, qr!^(\./etc/vzdump/(pct|vps)\.conf)$!);
1607     } elsif ($type eq 'qemu') {
1608         if ($format eq 'tar') {
1609             return extract_vzdump_config_tar($archive, qr!\(\./qemu-server\.conf\)!);
1610         } else {
1611             return extract_vzdump_config_vma($archive, $comp);
1612         }
1613     } else {
1614         die "cannot determine backup guest type for backup archive '$volid'\n";
1615     }
1616 }
1617
1618 sub prune_backups {
1619     my ($cfg, $storeid, $keep, $vmid, $type, $dryrun, $logfunc) = @_;
1620
1621     my $scfg = storage_config($cfg, $storeid);
1622     die "storage '$storeid' does not support backups\n" if !$scfg->{content}->{backup};
1623
1624     if (!defined($keep)) {
1625         die "no prune-backups options configured for storage '$storeid'\n"
1626             if !defined($scfg->{'prune-backups'});
1627         $keep = PVE::JSONSchema::parse_property_string('prune-backups', $scfg->{'prune-backups'});
1628     }
1629
1630     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1631     return $plugin->prune_backups($scfg, $storeid, $keep, $vmid, $type, $dryrun, $logfunc);
1632 }
1633
1634 my $prune_mark = sub {
1635     my ($prune_entries, $keep_count, $id_func) = @_;
1636
1637     return if !$keep_count;
1638
1639     my $already_included = {};
1640     my $newly_included = {};
1641
1642     foreach my $prune_entry (@{$prune_entries}) {
1643         my $mark = $prune_entry->{mark};
1644         my $id = $id_func->($prune_entry->{ctime});
1645         $already_included->{$id} = 1 if defined($mark) && $mark eq 'keep';
1646     }
1647
1648     foreach my $prune_entry (@{$prune_entries}) {
1649         my $mark = $prune_entry->{mark};
1650         my $id = $id_func->($prune_entry->{ctime});
1651
1652         next if defined($mark) || $already_included->{$id};
1653
1654         if (!$newly_included->{$id}) {
1655             last if scalar(keys %{$newly_included}) >= $keep_count;
1656             $newly_included->{$id} = 1;
1657             $prune_entry->{mark} = 'keep';
1658         } else {
1659             $prune_entry->{mark} = 'remove';
1660         }
1661     }
1662 };
1663
1664 sub prune_mark_backup_group {
1665     my ($backup_group, $keep) = @_;
1666
1667     my $keep_all = delete $keep->{'keep-all'};
1668
1669     if ($keep_all || !scalar(grep {$_ > 0} values %{$keep})) {
1670         $keep = { 'keep-all' => 1 } if $keep_all;
1671         foreach my $prune_entry (@{$backup_group}) {
1672             $prune_entry->{mark} = 'keep';
1673         }
1674         return;
1675     }
1676
1677     my $prune_list = [ sort { $b->{ctime} <=> $a->{ctime} } @{$backup_group} ];
1678
1679     $prune_mark->($prune_list, $keep->{'keep-last'}, sub {
1680         my ($ctime) = @_;
1681         return $ctime;
1682     });
1683     $prune_mark->($prune_list, $keep->{'keep-hourly'}, sub {
1684         my ($ctime) = @_;
1685         my (undef, undef, $hour, $day, $month, $year) = localtime($ctime);
1686         return "$hour/$day/$month/$year";
1687     });
1688     $prune_mark->($prune_list, $keep->{'keep-daily'}, sub {
1689         my ($ctime) = @_;
1690         my (undef, undef, undef, $day, $month, $year) = localtime($ctime);
1691         return "$day/$month/$year";
1692     });
1693     $prune_mark->($prune_list, $keep->{'keep-weekly'}, sub {
1694         my ($ctime) = @_;
1695         my ($sec, $min, $hour, $day, $month, $year) = localtime($ctime);
1696         my $iso_week = int(strftime("%V", $sec, $min, $hour, $day, $month, $year));
1697         my $iso_week_year = int(strftime("%G", $sec, $min, $hour, $day, $month, $year));
1698         return "$iso_week/$iso_week_year";
1699     });
1700     $prune_mark->($prune_list, $keep->{'keep-monthly'}, sub {
1701         my ($ctime) = @_;
1702         my (undef, undef, undef, undef, $month, $year) = localtime($ctime);
1703         return "$month/$year";
1704     });
1705     $prune_mark->($prune_list, $keep->{'keep-yearly'}, sub {
1706         my ($ctime) = @_;
1707         my $year = (localtime($ctime))[5];
1708         return "$year";
1709     });
1710
1711     foreach my $prune_entry (@{$prune_list}) {
1712         $prune_entry->{mark} //= 'remove';
1713     }
1714 }
1715
1716 sub volume_export {
1717     my ($cfg, $fh, $volid, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
1718
1719     my ($storeid, $volname) = parse_volume_id($volid, 1);
1720     die "cannot export volume '$volid'\n" if !$storeid;
1721     my $scfg = storage_config($cfg, $storeid);
1722     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1723     return $plugin->volume_export($scfg, $storeid, $fh, $volname, $format,
1724                                   $snapshot, $base_snapshot, $with_snapshots);
1725 }
1726
1727 sub volume_import {
1728     my ($cfg, $fh, $volid, $format, $base_snapshot, $with_snapshots, $allow_rename) = @_;
1729
1730     my ($storeid, $volname) = parse_volume_id($volid, 1);
1731     die "cannot import into volume '$volid'\n" if !$storeid;
1732     my $scfg = storage_config($cfg, $storeid);
1733     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1734     return $plugin->volume_import($scfg, $storeid, $fh, $volname, $format,
1735                                   $base_snapshot, $with_snapshots, $allow_rename) // $volid;
1736 }
1737
1738 sub volume_export_formats {
1739     my ($cfg, $volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1740
1741     my ($storeid, $volname) = parse_volume_id($volid, 1);
1742     return if !$storeid;
1743     my $scfg = storage_config($cfg, $storeid);
1744     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1745     return $plugin->volume_export_formats($scfg, $storeid, $volname,
1746                                           $snapshot, $base_snapshot,
1747                                           $with_snapshots);
1748 }
1749
1750 sub volume_import_formats {
1751     my ($cfg, $volid, $base_snapshot, $with_snapshots) = @_;
1752
1753     my ($storeid, $volname) = parse_volume_id($volid, 1);
1754     return if !$storeid;
1755     my $scfg = storage_config($cfg, $storeid);
1756     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1757     return $plugin->volume_import_formats($scfg, $storeid, $volname,
1758                                           $base_snapshot, $with_snapshots);
1759 }
1760
1761 sub volume_transfer_formats {
1762     my ($cfg, $src_volid, $dst_volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1763     my @export_formats = volume_export_formats($cfg, $src_volid, $snapshot, $base_snapshot, $with_snapshots);
1764     my @import_formats = volume_import_formats($cfg, $dst_volid, $base_snapshot, $with_snapshots);
1765     my %import_hash = map { $_ => 1 } @import_formats;
1766     my @common = grep { $import_hash{$_} } @export_formats;
1767     return @common;
1768 }
1769
1770 sub volume_imported_message {
1771     my ($volid, $want_pattern) = @_;
1772
1773     if ($want_pattern) {
1774         return qr/successfully imported '([^']*)'$/;
1775     } else {
1776         return "successfully imported '$volid'\n";
1777     }
1778 }
1779
1780 # bash completion helper
1781
1782 sub complete_storage {
1783     my ($cmdname, $pname, $cvalue) = @_;
1784
1785     my $cfg = PVE::Storage::config();
1786
1787     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1788 }
1789
1790 sub complete_storage_enabled {
1791     my ($cmdname, $pname, $cvalue) = @_;
1792
1793     my $res = [];
1794
1795     my $cfg = PVE::Storage::config();
1796     foreach my $sid (keys %{$cfg->{ids}}) {
1797         next if !storage_check_enabled($cfg, $sid, undef, 1);
1798         push @$res, $sid;
1799     }
1800     return $res;
1801 }
1802
1803 sub complete_content_type {
1804     my ($cmdname, $pname, $cvalue) = @_;
1805
1806     return [qw(rootdir images vztmpl iso backup snippets)];
1807 }
1808
1809 sub complete_volume {
1810     my ($cmdname, $pname, $cvalue) = @_;
1811
1812     my $cfg = config();
1813
1814     my $storage_list = complete_storage_enabled();
1815
1816     if ($cvalue =~ m/^([^:]+):/) {
1817         $storage_list = [ $1 ];
1818     } else {
1819         if (scalar(@$storage_list) > 1) {
1820             # only list storage IDs to avoid large listings
1821             my $res = [];
1822             foreach my $storeid (@$storage_list) {
1823                 # Hack: simply return 2 artificial values, so that
1824                 # completions does not finish
1825                 push @$res, "$storeid:volname", "$storeid:...";
1826             }
1827             return $res;
1828         }
1829     }
1830
1831     my $res = [];
1832     foreach my $storeid (@$storage_list) {
1833         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1834
1835         foreach my $item (@$vollist) {
1836             push @$res, $item->{volid};
1837         }
1838     }
1839
1840     return $res;
1841 }
1842
1843 # Various io-heavy operations require io/bandwidth limits which can be
1844 # configured on multiple levels: The global defaults in datacenter.cfg, and
1845 # per-storage overrides. When we want to do a restore from storage A to storage
1846 # B, we should take the smaller limit defined for storages A and B, and if no
1847 # such limit was specified, use the one from datacenter.cfg.
1848 sub get_bandwidth_limit {
1849     my ($operation, $storage_list, $override) = @_;
1850
1851     # called for each limit (global, per-storage) with the 'default' and the
1852     # $operation limit and should udpate $override for every limit affecting
1853     # us.
1854     my $use_global_limits = 0;
1855     my $apply_limit = sub {
1856         my ($bwlimit) = @_;
1857         if (defined($bwlimit)) {
1858             my $limits = PVE::JSONSchema::parse_property_string('bwlimit', $bwlimit);
1859             my $limit = $limits->{$operation} // $limits->{default};
1860             if (defined($limit)) {
1861                 if (!$override || $limit < $override) {
1862                     $override = $limit;
1863                 }
1864                 return;
1865             }
1866         }
1867         # If there was no applicable limit, try to apply the global ones.
1868         $use_global_limits = 1;
1869     };
1870
1871     my ($rpcenv, $authuser);
1872     if (defined($override)) {
1873         $rpcenv = PVE::RPCEnvironment->get();
1874         $authuser = $rpcenv->get_user();
1875     }
1876
1877     # Apply per-storage limits - if there are storages involved.
1878     if (defined($storage_list) && @$storage_list) {
1879         my $config = config();
1880
1881         # The Datastore.Allocate permission allows us to modify the per-storage
1882         # limits, therefore it also allows us to override them.
1883         # Since we have most likely multiple storages to check, do a quick check on
1884         # the general '/storage' path to see if we can skip the checks entirely:
1885         return $override if $rpcenv && $rpcenv->check($authuser, '/storage', ['Datastore.Allocate'], 1);
1886
1887         my %done;
1888         foreach my $storage (@$storage_list) {
1889             next if !defined($storage);
1890             # Avoid duplicate checks:
1891             next if $done{$storage};
1892             $done{$storage} = 1;
1893
1894             # Otherwise we may still have individual /storage/$ID permissions:
1895             if (!$rpcenv || !$rpcenv->check($authuser, "/storage/$storage", ['Datastore.Allocate'], 1)) {
1896                 # And if not: apply the limits.
1897                 my $storecfg = storage_config($config, $storage);
1898                 $apply_limit->($storecfg->{bwlimit});
1899             }
1900         }
1901
1902         # Storage limits take precedence over the datacenter defaults, so if
1903         # a limit was applied:
1904         return $override if !$use_global_limits;
1905     }
1906
1907     # Sys.Modify on '/' means we can change datacenter.cfg which contains the
1908     # global default limits.
1909     if (!$rpcenv || !$rpcenv->check($authuser, '/', ['Sys.Modify'], 1)) {
1910         # So if we cannot modify global limits, apply them to our currently
1911         # requested override.
1912         my $dc = cfs_read_file('datacenter.cfg');
1913         $apply_limit->($dc->{bwlimit});
1914     }
1915
1916     return $override;
1917 }
1918
1919 # checks if the storage id is available and dies if not
1920 sub assert_sid_unused {
1921     my ($sid) = @_;
1922
1923     my $cfg = config();
1924     if (my $scfg = storage_config($cfg, $sid, 1)) {
1925         die "storage ID '$sid' already defined\n";
1926     }
1927
1928     return undef;
1929 }
1930
1931 1;