PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use POSIX;
   5 use IO::Select;
   6 use IO::File;
   7 use File::Basename;
   8 use File::Path;
   9 use Cwd 'abs_path';
  10 use Socket;
  11
  12 use PVE::Tools qw(run_command file_read_firstline);
  13 use PVE::Cluster qw(cfs_read_file cfs_lock_file);
  14 use PVE::Exception qw(raise_param_exc);
  15 use PVE::JSONSchema;
  16 use PVE::INotify;
  17 use PVE::RPCEnvironment;
  18
  19 use PVE::Storage::Plugin;
  20 use PVE::Storage::DirPlugin;
  21 use PVE::Storage::LVMPlugin;
  22 use PVE::Storage::NFSPlugin;
  23 use PVE::Storage::ISCSIPlugin;
  24 use PVE::Storage::RBDPlugin;
  25 use PVE::Storage::SheepdogPlugin;
  26 use PVE::Storage::ISCSIDirectPlugin;
  27 use PVE::Storage::NexentaPlugin;
  28
  29 # load and initialize all plugins
  30 PVE::Storage::DirPlugin->register();
  31 PVE::Storage::LVMPlugin->register();
  32 PVE::Storage::NFSPlugin->register();
  33 PVE::Storage::ISCSIPlugin->register();
  34 PVE::Storage::RBDPlugin->register();
  35 PVE::Storage::SheepdogPlugin->register();
  36 PVE::Storage::ISCSIDirectPlugin->register();
  37 PVE::Storage::NexentaPlugin->register();
  38 PVE::Storage::Plugin->init();
  39
  40 my $UDEVADM = '/sbin/udevadm';
  41
  42 #  PVE::Storage utility functions
  43
  44 sub config {
  45     return cfs_read_file("storage.cfg");
  46 }
  47
  48 sub lock_storage_config {
  49     my ($code, $errmsg) = @_;
  50
  51     cfs_lock_file("storage.cfg", undef, $code);
  52     my $err = $@;
  53     if ($err) {
  54         $errmsg ? die "$errmsg: $err" : die $err;
  55     }
  56 }
  57
  58 sub storage_config {
  59     my ($cfg, $storeid, $noerr) = @_;
  60
  61     die "no storage id specified\n" if !$storeid;
  62
  63     my $scfg = $cfg->{ids}->{$storeid};
  64
  65     die "storage '$storeid' does not exists\n" if (!$noerr && !$scfg);
  66
  67     return $scfg;
  68 }
  69
  70 sub storage_check_node {
  71     my ($cfg, $storeid, $node, $noerr) = @_;
  72
  73     my $scfg = storage_config($cfg, $storeid);
  74
  75     if ($scfg->{nodes}) {
  76         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
  77         if (!$scfg->{nodes}->{$node}) {
  78             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
  79             return undef;
  80         }
  81     }
  82
  83     return $scfg;
  84 }
  85
  86 sub storage_check_enabled {
  87     my ($cfg, $storeid, $node, $noerr) = @_;
  88
  89     my $scfg = storage_config($cfg, $storeid);
  90
  91     if ($scfg->{disable}) {
  92         die "storage '$storeid' is disabled\n" if !$noerr;
  93         return undef;
  94     }
  95
  96     return storage_check_node($cfg, $storeid, $node, $noerr);
  97 }
  98
  99 sub storage_ids {
 100     my ($cfg) = @_;
 101
 102     return keys %{$cfg->{ids}};
 103 }
 104
 105 sub file_size_info {
 106     my ($filename, $timeout) = @_;
 107
 108     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 109 }
 110
 111 sub volume_size_info {
 112     my ($cfg, $volid, $timeout) = @_;
 113
 114     my ($storeid, $volname) = parse_volume_id($volid, 1);
 115     if ($storeid) {
 116         my $scfg = storage_config($cfg, $storeid);
 117         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 118         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 119     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 120         return file_size_info($volid, $timeout);
 121     } else {
 122         return 0;
 123     }
 124 }
 125
 126 sub volume_resize {
 127     my ($cfg, $volid, $size, $running) = @_;
 128
 129     my ($storeid, $volname) = parse_volume_id($volid, 1);
 130     if ($storeid) {
 131         my $scfg = storage_config($cfg, $storeid);
 132         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 133         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 134     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 135         die "resize device is not possible";
 136     } else {
 137         die "can't resize";
 138     }
 139 }
 140
 141 sub volume_snapshot {
 142     my ($cfg, $volid, $snap, $running) = @_;
 143
 144     my ($storeid, $volname) = parse_volume_id($volid, 1);
 145     if ($storeid) {
 146         my $scfg = storage_config($cfg, $storeid);
 147         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 148         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap, $running);
 149     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 150         die "snapshot device is not possible";
 151     } else {
 152         die "can't snapshot";
 153     }
 154 }
 155
 156 sub volume_snapshot_rollback {
 157     my ($cfg, $volid, $snap) = @_;
 158
 159     my ($storeid, $volname) = parse_volume_id($volid, 1);
 160     if ($storeid) {
 161         my $scfg = storage_config($cfg, $storeid);
 162         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 163         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 164     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 165         die "snapshot rollback device is not possible";
 166     } else {
 167         die "can't snapshot";
 168     }
 169 }
 170
 171 sub volume_snapshot_delete {
 172     my ($cfg, $volid, $snap, $running) = @_;
 173
 174     my ($storeid, $volname) = parse_volume_id($volid, 1);
 175     if ($storeid) {
 176         my $scfg = storage_config($cfg, $storeid);
 177         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 178         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 179     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 180         die "snapshot delete device is not possible";
 181     } else {
 182         die "can't delete snapshot";
 183     }
 184 }
 185
 186 sub volume_has_feature {
 187     my ($cfg, $feature, $volid, $snap, $running) = @_;
 188
 189     my ($storeid, $volname) = parse_volume_id($volid, 1);
 190     if ($storeid) {
 191         my $scfg = storage_config($cfg, $storeid);
 192         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 193         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running);
 194     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 195         return undef;
 196     } else {
 197         return undef;
 198     }
 199 }
 200
 201 sub get_image_dir {
 202     my ($cfg, $storeid, $vmid) = @_;
 203
 204     my $scfg = storage_config($cfg, $storeid);
 205     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 206
 207     my $path = $plugin->get_subdir($scfg, 'images');
 208
 209     return $vmid ? "$path/$vmid" : $path;
 210 }
 211
 212 sub get_private_dir {
 213     my ($cfg, $storeid, $vmid) = @_;
 214
 215     my $scfg = storage_config($cfg, $storeid);
 216     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 217
 218     my $path = $plugin->get_subdir($scfg, 'rootdir');
 219
 220     return $vmid ? "$path/$vmid" : $path;
 221 }
 222
 223 sub get_iso_dir {
 224     my ($cfg, $storeid) = @_;
 225
 226     my $scfg = storage_config($cfg, $storeid);
 227     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 228
 229     return $plugin->get_subdir($scfg, 'iso');
 230 }
 231
 232 sub get_vztmpl_dir {
 233     my ($cfg, $storeid) = @_;
 234
 235     my $scfg = storage_config($cfg, $storeid);
 236     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 237
 238     return $plugin->get_subdir($scfg, 'vztmpl');
 239 }
 240
 241 sub get_backup_dir {
 242     my ($cfg, $storeid) = @_;
 243
 244     my $scfg = storage_config($cfg, $storeid);
 245     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 246
 247     return $plugin->get_subdir($scfg, 'backup');
 248 }
 249
 250 # library implementation
 251
 252 sub parse_vmid {
 253     my $vmid = shift;
 254
 255     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 256
 257     return int($vmid);
 258 }
 259
 260 sub parse_volume_id {
 261     my ($volid, $noerr) = @_;
 262
 263     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 264 }
 265
 266 sub volume_is_base {
 267     my ($cfg, $volid) = @_;
 268
 269     my ($sid, $volname) = parse_volume_id($volid, 1);
 270     return 0 if !$sid;
 271
 272     if (my $scfg = $cfg->{ids}->{$sid}) {
 273         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 274         my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 275             $plugin->parse_volname($volname);
 276         return $isBase ? 1 : 0;
 277     } else {
 278         # stale volid with undefined storage - so we can just guess
 279         if ($volid =~ m/base-/) {
 280             return 1;
 281         }
 282     }
 283
 284     return 0;
 285 }
 286
 287 # try to map a filesystem path to a volume identifier
 288 sub path_to_volume_id {
 289     my ($cfg, $path) = @_;
 290
 291     my $ids = $cfg->{ids};
 292
 293     my ($sid, $volname) = parse_volume_id($path, 1);
 294     if ($sid) {
 295         if (my $scfg = $ids->{$sid}) {
 296             if ($scfg->{path}) {
 297                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 298                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 299                 return ($vtype, $path);
 300             }
 301         }
 302         return ('');
 303     }
 304
 305     # Note: abs_path() return undef if $path doesn not exist
 306     # for example when nfs storage is not mounted
 307     $path = abs_path($path) || $path;
 308
 309     foreach my $sid (keys %$ids) {
 310         my $scfg = $ids->{$sid};
 311         next if !$scfg->{path};
 312         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 313         my $imagedir = $plugin->get_subdir($scfg, 'images');
 314         my $isodir = $plugin->get_subdir($scfg, 'iso');
 315         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 316         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 317         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 318
 319         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 320             my $vmid = $1;
 321             my $name = $2;
 322
 323             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 324             foreach my $info (@$vollist) {
 325                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 326                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 327                 if ($volpath eq $path) {
 328                     return ('images', $info->{volid});
 329                 }
 330             }
 331         } elsif ($path =~ m!^$isodir/([^/]+\.[Ii][Ss][Oo])$!) {
 332             my $name = $1;
 333             return ('iso', "$sid:iso/$name");
 334         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 335             my $name = $1;
 336             return ('vztmpl', "$sid:vztmpl/$name");
 337         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 338             my $vmid = $1;
 339             return ('rootdir', "$sid:rootdir/$vmid");
 340         } elsif ($path =~ m!^$backupdir/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!) {
 341             my $name = $1;
 342             return ('iso', "$sid:backup/$name");
 343         }
 344     }
 345
 346     # can't map path to volume id
 347     return ('');
 348 }
 349
 350 sub path {
 351     my ($cfg, $volid) = @_;
 352
 353     my ($storeid, $volname) = parse_volume_id($volid);
 354
 355     my $scfg = storage_config($cfg, $storeid);
 356
 357     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 358     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid);
 359     return wantarray ? ($path, $owner, $vtype) : $path;
 360 }
 361
 362 sub storage_migrate {
 363     my ($cfg, $volid, $target_host, $target_storeid, $target_volname) = @_;
 364
 365     my ($storeid, $volname) = parse_volume_id($volid);
 366     $target_volname = $volname if !$target_volname;
 367
 368     my $scfg = storage_config($cfg, $storeid);
 369
 370     # no need to migrate shared content
 371     return if $storeid eq $target_storeid && $scfg->{shared};
 372
 373     my $tcfg = storage_config($cfg, $target_storeid);
 374
 375     my $target_volid = "${target_storeid}:${target_volname}";
 376
 377     my $errstr = "unable to migrate '$volid' to '${target_volid}' on host '$target_host'";
 378
 379     my $sshoptions = "-o 'BatchMode=yes'";
 380     my $ssh = "/usr/bin/ssh $sshoptions";
 381
 382     local $ENV{RSYNC_RSH} = $ssh;
 383
 384     # only implemented for file system based storage
 385     if ($scfg->{path}) {
 386         if ($tcfg->{path}) {
 387
 388             my $src_plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 389             my $dst_plugin = PVE::Storage::Plugin->lookup($tcfg->{type});
 390             my $src = $src_plugin->path($scfg, $volname, $storeid);
 391             my $dst = $dst_plugin->path($tcfg, $target_volname, $target_storeid);
 392
 393             my $dirname = dirname($dst);
 394
 395             if ($tcfg->{shared}) { # we can do a local copy
 396
 397                 run_command(['/bin/mkdir', '-p', $dirname]);
 398
 399                 run_command(['/bin/cp', $src, $dst]);
 400
 401             } else {
 402
 403                 run_command(['/usr/bin/ssh', "root\@${target_host}",
 404                              '/bin/mkdir', '-p', $dirname]);
 405
 406                 # we use rsync with --sparse, so we can't use --inplace,
 407                 # so we remove file on the target if it already exists to
 408                 # save space
 409                 my ($size, $format) = PVE::Storage::Plugin::file_size_info($src);
 410                 if ($format && ($format eq 'raw') && $size) {
 411                     run_command(['/usr/bin/ssh', "root\@${target_host}",
 412                                  'rm', '-f', $dst],
 413                                 outfunc => sub {});
 414                 }
 415
 416                 my $cmd = ['/usr/bin/rsync', '--progress', '--sparse', '--whole-file',
 417                            $src, "root\@${target_host}:$dst"];
 418
 419                 my $percent = -1;
 420
 421                 run_command($cmd, outfunc => sub {
 422                     my $line = shift;
 423
 424                     if ($line =~ m/^\s*(\d+\s+(\d+)%\s.*)$/) {
 425                         if ($2 > $percent) {
 426                             $percent = $2;
 427                             print "rsync status: $1\n";
 428                             *STDOUT->flush();
 429                         }
 430                     } else {
 431                         print "$line\n";
 432                         *STDOUT->flush();
 433                     }
 434                 });
 435             }
 436         } else {
 437             die "$errstr - target type '$tcfg->{type}' not implemented\n";
 438         }
 439     } else {
 440         die "$errstr - source type '$scfg->{type}' not implemented\n";
 441     }
 442 }
 443
 444 sub vdisk_clone {
 445     my ($cfg, $volid, $vmid) = @_;
 446
 447     my ($storeid, $volname) = parse_volume_id($volid);
 448
 449     my $scfg = storage_config($cfg, $storeid);
 450
 451     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 452
 453     activate_storage($cfg, $storeid);
 454
 455     # lock shared storage
 456     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 457         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid);
 458         return "$storeid:$volname";
 459     });
 460 }
 461
 462 sub vdisk_create_base {
 463     my ($cfg, $volid) = @_;
 464
 465     my ($storeid, $volname) = parse_volume_id($volid);
 466
 467     my $scfg = storage_config($cfg, $storeid);
 468
 469     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 470
 471     activate_storage($cfg, $storeid);
 472
 473     # lock shared storage
 474     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 475         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 476         return "$storeid:$volname";
 477     });
 478 }
 479
 480 sub vdisk_alloc {
 481     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 482
 483     die "no storage id specified\n" if !$storeid;
 484
 485     PVE::JSONSchema::parse_storage_id($storeid);
 486
 487     my $scfg = storage_config($cfg, $storeid);
 488
 489     die "no VMID specified\n" if !$vmid;
 490
 491     $vmid = parse_vmid($vmid);
 492
 493     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 494
 495     $fmt = $defformat if !$fmt;
 496
 497     activate_storage($cfg, $storeid);
 498
 499     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 500
 501     # lock shared storage
 502     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 503         my $volname = $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size);
 504         return "$storeid:$volname";
 505     });
 506 }
 507
 508 sub vdisk_free {
 509     my ($cfg, $volid) = @_;
 510
 511     my ($storeid, $volname) = parse_volume_id($volid);
 512
 513     my $scfg = storage_config($cfg, $storeid);
 514
 515     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 516
 517     activate_storage($cfg, $storeid);
 518
 519     my $cleanup_worker;
 520
 521     # lock shared storage
 522     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 523
 524         my ($vtype, $name, $vmid, undef, undef, $isBase) =
 525             $plugin->parse_volname($volname);
 526
 527         if ($isBase) {
 528             my $vollist = $plugin->list_images($storeid, $scfg);
 529             foreach my $info (@$vollist) {
 530                 my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 531                 my $basename = undef;
 532                 my $basevmid = undef;
 533
 534                 eval{
 535                     (undef, undef, undef, $basename, $basevmid) =
 536                         $plugin->parse_volname($tmpvolname);
 537                 };
 538
 539                 if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 540                     die "base volume '$volname' is still in use " .
 541                         "(use by '$tmpvolname')\n";
 542                 }
 543             }
 544         }
 545
 546         my $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase);
 547     });
 548
 549     return if !$cleanup_worker;
 550
 551     my $rpcenv = PVE::RPCEnvironment::get();
 552     my $authuser = $rpcenv->get_user();
 553
 554     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 555 }
 556
 557 #list iso or openvz template ($tt = <iso|vztmpl|backup>)
 558 sub template_list {
 559     my ($cfg, $storeid, $tt) = @_;
 560
 561     die "unknown template type '$tt'\n"
 562         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup');
 563
 564     my $ids = $cfg->{ids};
 565
 566     storage_check_enabled($cfg, $storeid) if ($storeid);
 567
 568     my $res = {};
 569
 570     # query the storage
 571
 572     foreach my $sid (keys %$ids) {
 573         next if $storeid && $storeid ne $sid;
 574
 575         my $scfg = $ids->{$sid};
 576         my $type = $scfg->{type};
 577
 578         next if !storage_check_enabled($cfg, $sid, undef, 1);
 579
 580         next if $tt eq 'iso' && !$scfg->{content}->{iso};
 581         next if $tt eq 'vztmpl' && !$scfg->{content}->{vztmpl};
 582         next if $tt eq 'backup' && !$scfg->{content}->{backup};
 583
 584         activate_storage($cfg, $sid);
 585
 586         if ($scfg->{path}) {
 587             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 588
 589             my $path = $plugin->get_subdir($scfg, $tt);
 590
 591             foreach my $fn (<$path/*>) {
 592
 593                 my $info;
 594
 595                 if ($tt eq 'iso') {
 596                     next if $fn !~ m!/([^/]+\.[Ii][Ss][Oo])$!;
 597
 598                     $info = { volid => "$sid:iso/$1", format => 'iso' };
 599
 600                 } elsif ($tt eq 'vztmpl') {
 601                     next if $fn !~ m!/([^/]+\.tar\.gz)$!;
 602
 603                     $info = { volid => "$sid:vztmpl/$1", format => 'tgz' };
 604
 605                 } elsif ($tt eq 'backup') {
 606                     next if $fn !~ m!/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!;
 607
 608                     $info = { volid => "$sid:backup/$1", format => $2 };
 609                 }
 610
 611                 $info->{size} = -s $fn;
 612
 613                 push @{$res->{$sid}}, $info;
 614             }
 615
 616         }
 617
 618         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 619     }
 620
 621     return $res;
 622 }
 623
 624
 625 sub vdisk_list {
 626     my ($cfg, $storeid, $vmid, $vollist) = @_;
 627
 628     my $ids = $cfg->{ids};
 629
 630     storage_check_enabled($cfg, $storeid) if ($storeid);
 631
 632     my $res = {};
 633
 634     # prepare/activate/refresh all storages
 635
 636     my $storage_list = [];
 637     if ($vollist) {
 638         foreach my $volid (@$vollist) {
 639             my ($sid, undef) = parse_volume_id($volid);
 640             next if !defined($ids->{$sid});
 641             next if !storage_check_enabled($cfg, $sid, undef, 1);
 642             push @$storage_list, $sid;
 643         }
 644     } else {
 645         foreach my $sid (keys %$ids) {
 646             next if $storeid && $storeid ne $sid;
 647             next if !storage_check_enabled($cfg, $sid, undef, 1);
 648             push @$storage_list, $sid;
 649         }
 650     }
 651
 652     my $cache = {};
 653
 654     activate_storage_list($cfg, $storage_list, $cache);
 655
 656     foreach my $sid (keys %$ids) {
 657         next if $storeid && $storeid ne $sid;
 658         next if !storage_check_enabled($cfg, $sid, undef, 1);
 659
 660         my $scfg = $ids->{$sid};
 661         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 662         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 663         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 664     }
 665
 666     return $res;
 667 }
 668
 669 sub uevent_seqnum {
 670
 671     my $filename = "/sys/kernel/uevent_seqnum";
 672
 673     my $seqnum = 0;
 674     if (my $fh = IO::File->new($filename, "r")) {
 675         my $line = <$fh>;
 676         if ($line =~ m/^(\d+)$/) {
 677             $seqnum = int($1);
 678         }
 679         close ($fh);
 680     }
 681     return $seqnum;
 682 }
 683
 684 sub activate_storage {
 685     my ($cfg, $storeid, $cache) = @_;
 686
 687     $cache = {} if !$cache;
 688
 689     my $scfg = storage_check_enabled($cfg, $storeid);
 690
 691     return if $cache->{activated}->{$storeid};
 692
 693     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 694
 695     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 696
 697     if ($scfg->{base}) {
 698         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 699         activate_storage($cfg, $baseid, $cache);
 700     }
 701
 702     if (!$plugin->check_connection($storeid, $scfg)) {
 703         die "storage '$storeid' is not online\n";
 704     }
 705
 706     $plugin->activate_storage($storeid, $scfg, $cache);
 707
 708     my $newseq = uevent_seqnum ();
 709
 710     # only call udevsettle if there are events
 711     if ($newseq > $cache->{uevent_seqnum}) {
 712         my $timeout = 30;
 713         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
 714         $cache->{uevent_seqnum} = $newseq;
 715     }
 716
 717     $cache->{activated}->{$storeid} = 1;
 718 }
 719
 720 sub activate_storage_list {
 721     my ($cfg, $storeid_list, $cache) = @_;
 722
 723     $cache = {} if !$cache;
 724
 725     foreach my $storeid (@$storeid_list) {
 726         activate_storage($cfg, $storeid, $cache);
 727     }
 728 }
 729
 730 sub deactivate_storage {
 731     my ($cfg, $storeid) = @_;
 732
 733     my $scfg = storage_config ($cfg, $storeid);
 734     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 735
 736     my $cache = {};
 737     $plugin->deactivate_storage($storeid, $scfg, $cache);
 738 }
 739
 740 sub activate_volumes {
 741     my ($cfg, $vollist, $exclusive) = @_;
 742
 743     return if !($vollist && scalar(@$vollist));
 744
 745     my $storagehash = {};
 746     foreach my $volid (@$vollist) {
 747         my ($storeid, undef) = parse_volume_id($volid);
 748         $storagehash->{$storeid} = 1;
 749     }
 750
 751     my $cache = {};
 752
 753     activate_storage_list($cfg, [keys %$storagehash], $cache);
 754
 755     foreach my $volid (@$vollist) {
 756         my ($storeid, $volname) = parse_volume_id($volid);
 757         my $scfg = storage_config($cfg, $storeid);
 758         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 759         $plugin->activate_volume($storeid, $scfg, $volname, $exclusive, $cache);
 760     }
 761 }
 762
 763 sub deactivate_volumes {
 764     my ($cfg, $vollist) = @_;
 765
 766     return if !($vollist && scalar(@$vollist));
 767
 768     my $cache = {};
 769
 770     my @errlist = ();
 771     foreach my $volid (@$vollist) {
 772         my ($storeid, $volname) = parse_volume_id($volid);
 773
 774         my $scfg = storage_config($cfg, $storeid);
 775         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 776
 777         eval {
 778             $plugin->deactivate_volume($storeid, $scfg, $volname, $cache);
 779         };
 780         if (my $err = $@) {
 781             warn $err;
 782             push @errlist, $volid;
 783         }
 784     }
 785
 786     die "volume deativation failed: " . join(' ', @errlist)
 787         if scalar(@errlist);
 788 }
 789
 790 sub storage_info {
 791     my ($cfg, $content) = @_;
 792
 793     my $ids = $cfg->{ids};
 794
 795     my $info = {};
 796
 797     my $slist = [];
 798     foreach my $storeid (keys %$ids) {
 799
 800         next if $content && !$ids->{$storeid}->{content}->{$content};
 801
 802         next if !storage_check_enabled($cfg, $storeid, undef, 1);
 803
 804         my $type = $ids->{$storeid}->{type};
 805
 806         $info->{$storeid} = {
 807             type => $type,
 808             total => 0,
 809             avail => 0,
 810             used => 0,
 811             shared => $ids->{$storeid}->{shared} ? 1 : 0,
 812             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
 813             active => 0,
 814         };
 815
 816         push @$slist, $storeid;
 817     }
 818
 819     my $cache = {};
 820
 821     foreach my $storeid (keys %$ids) {
 822         my $scfg = $ids->{$storeid};
 823         next if !$info->{$storeid};
 824
 825         eval { activate_storage($cfg, $storeid, $cache); };
 826         if (my $err = $@) {
 827             warn $err;
 828             next;
 829         }
 830
 831         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 832         my ($total, $avail, $used, $active);
 833         eval { ($total, $avail, $used, $active) = $plugin->status($storeid, $scfg, $cache); };
 834         warn $@ if $@;
 835         next if !$active;
 836         $info->{$storeid}->{total} = $total;
 837         $info->{$storeid}->{avail} = $avail;
 838         $info->{$storeid}->{used} = $used;
 839         $info->{$storeid}->{active} = $active;
 840     }
 841
 842     return $info;
 843 }
 844
 845 sub resolv_server {
 846     my ($server) = @_;
 847
 848     my $packed_ip = gethostbyname($server);
 849     if (defined $packed_ip) {
 850         return inet_ntoa($packed_ip);
 851     }
 852     return undef;
 853 }
 854
 855 sub scan_nfs {
 856     my ($server_in) = @_;
 857
 858     my $server;
 859     if (!($server = resolv_server ($server_in))) {
 860         die "unable to resolve address for server '${server_in}'\n";
 861     }
 862
 863     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
 864
 865     my $res = {};
 866     run_command($cmd, outfunc => sub {
 867         my $line = shift;
 868
 869         # note: howto handle white spaces in export path??
 870         if ($line =~ m!^(/\S+)\s+(.+)$!) {
 871             $res->{$1} = $2;
 872         }
 873     });
 874
 875     return $res;
 876 }
 877
 878 sub resolv_portal {
 879     my ($portal, $noerr) = @_;
 880
 881     if ($portal =~ m/^([^:]+)(:(\d+))?$/) {
 882         my $server = $1;
 883         my $port = $3;
 884
 885         if (my $ip = resolv_server($server)) {
 886             $server = $ip;
 887             return $port ? "$server:$port" : $server;
 888         }
 889     }
 890     return undef if $noerr;
 891
 892     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
 893 }
 894
 895 # idea is from usbutils package (/usr/bin/usb-devices) script
 896 sub __scan_usb_device {
 897     my ($res, $devpath, $parent, $level) = @_;
 898
 899     return if ! -d $devpath;
 900     return if $level && $devpath !~ m/^.*[-.](\d+)$/;
 901     my $port = $level ? int($1 - 1) : 0;
 902
 903     my $busnum = int(file_read_firstline("$devpath/busnum"));
 904     my $devnum = int(file_read_firstline("$devpath/devnum"));
 905
 906     my $d = {
 907         port => $port,
 908         level => $level,
 909         busnum => $busnum,
 910         devnum => $devnum,
 911         speed => file_read_firstline("$devpath/speed"),
 912         class => hex(file_read_firstline("$devpath/bDeviceClass")),
 913         vendid => file_read_firstline("$devpath/idVendor"),
 914         prodid => file_read_firstline("$devpath/idProduct"),
 915     };
 916
 917     if ($level) {
 918         my $usbpath = $devpath;
 919         $usbpath =~ s|^.*/\d+\-||;
 920         $d->{usbpath} = $usbpath;
 921     }
 922
 923     my $product = file_read_firstline("$devpath/product");
 924     $d->{product} = $product if $product;
 925
 926     my $manu = file_read_firstline("$devpath/manufacturer");
 927     $d->{manufacturer} = $manu if $manu;
 928
 929     my $serial => file_read_firstline("$devpath/serial");
 930     $d->{serial} = $serial if $serial;
 931
 932     push @$res, $d;
 933
 934     foreach my $subdev (<$devpath/$busnum-*>) {
 935         next if $subdev !~ m|/$busnum-[0-9]+(\.[0-9]+)*$|;
 936         __scan_usb_device($res, $subdev, $devnum, $level + 1);
 937     }
 938
 939 };
 940
 941 sub scan_usb {
 942
 943     my $devlist = [];
 944
 945     foreach my $device (</sys/bus/usb/devices/usb*>) {
 946         __scan_usb_device($devlist, $device, 0, 0);
 947     }
 948
 949     return $devlist;
 950 }
 951
 952 sub scan_iscsi {
 953     my ($portal_in) = @_;
 954
 955     my $portal;
 956     if (!($portal = resolv_portal($portal_in))) {
 957         die "unable to parse/resolve portal address '${portal_in}'\n";
 958     }
 959
 960     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
 961 }
 962
 963 sub storage_default_format {
 964     my ($cfg, $storeid) = @_;
 965
 966     my $scfg = storage_config ($cfg, $storeid);
 967
 968     return PVE::Storage::Plugin::default_format($scfg);
 969 }
 970
 971 sub vgroup_is_used {
 972     my ($cfg, $vgname) = @_;
 973
 974     foreach my $storeid (keys %{$cfg->{ids}}) {
 975         my $scfg = storage_config($cfg, $storeid);
 976         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
 977             return 1;
 978         }
 979     }
 980
 981     return undef;
 982 }
 983
 984 sub target_is_used {
 985     my ($cfg, $target) = @_;
 986
 987     foreach my $storeid (keys %{$cfg->{ids}}) {
 988         my $scfg = storage_config($cfg, $storeid);
 989         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
 990             return 1;
 991         }
 992     }
 993
 994     return undef;
 995 }
 996
 997 sub volume_is_used {
 998     my ($cfg, $volid) = @_;
 999
1000     foreach my $storeid (keys %{$cfg->{ids}}) {
1001         my $scfg = storage_config($cfg, $storeid);
1002         if ($scfg->{base} && $scfg->{base} eq $volid) {
1003             return 1;
1004         }
1005     }
1006
1007     return undef;
1008 }
1009
1010 sub storage_is_used {
1011     my ($cfg, $storeid) = @_;
1012
1013     foreach my $sid (keys %{$cfg->{ids}}) {
1014         my $scfg = storage_config($cfg, $sid);
1015         next if !$scfg->{base};
1016         my ($st) = parse_volume_id($scfg->{base});
1017         return 1 if $st && $st eq $storeid;
1018     }
1019
1020     return undef;
1021 }
1022
1023 sub foreach_volid {
1024     my ($list, $func) = @_;
1025
1026     return if !$list;
1027
1028     foreach my $sid (keys %$list) {
1029        foreach my $info (@{$list->{$sid}}) {
1030            my $volid = $info->{volid};
1031            my ($sid1, $volname) = parse_volume_id($volid, 1);
1032            if ($sid1 && $sid1 eq $sid) {
1033                &$func ($volid, $sid, $info);
1034            } else {
1035                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1036            }
1037        }
1038     }
1039 }
1040
1041 1;