PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use File::Basename;
  11 use File::Path;
  12 use Cwd 'abs_path';
  13 use Socket;
  14
  15 use PVE::Tools qw(run_command file_read_firstline $IPV6RE);
  16 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  17 use PVE::Exception qw(raise_param_exc);
  18 use PVE::JSONSchema;
  19 use PVE::INotify;
  20 use PVE::RPCEnvironment;
  21
  22 use PVE::Storage::Plugin;
  23 use PVE::Storage::DirPlugin;
  24 use PVE::Storage::LVMPlugin;
  25 use PVE::Storage::LvmThinPlugin;
  26 use PVE::Storage::NFSPlugin;
  27 use PVE::Storage::ISCSIPlugin;
  28 use PVE::Storage::RBDPlugin;
  29 use PVE::Storage::SheepdogPlugin;
  30 use PVE::Storage::ISCSIDirectPlugin;
  31 use PVE::Storage::GlusterfsPlugin;
  32 use PVE::Storage::ZFSPoolPlugin;
  33 use PVE::Storage::ZFSPlugin;
  34 use PVE::Storage::DRBDPlugin;
  35
  36 # load and initialize all plugins
  37 PVE::Storage::DirPlugin->register();
  38 PVE::Storage::LVMPlugin->register();
  39 PVE::Storage::LvmThinPlugin->register();
  40 PVE::Storage::NFSPlugin->register();
  41 PVE::Storage::ISCSIPlugin->register();
  42 PVE::Storage::RBDPlugin->register();
  43 PVE::Storage::SheepdogPlugin->register();
  44 PVE::Storage::ISCSIDirectPlugin->register();
  45 PVE::Storage::GlusterfsPlugin->register();
  46 PVE::Storage::ZFSPoolPlugin->register();
  47 PVE::Storage::ZFSPlugin->register();
  48 PVE::Storage::DRBDPlugin->register();
  49 PVE::Storage::Plugin->init();
  50
  51 my $UDEVADM = '/sbin/udevadm';
  52
  53 #  PVE::Storage utility functions
  54
  55 sub config {
  56     return cfs_read_file("storage.cfg");
  57 }
  58
  59 sub write_config {
  60     my ($cfg) = @_;
  61
  62     cfs_write_file('storage.cfg', $cfg);
  63 }
  64
  65 sub lock_storage_config {
  66     my ($code, $errmsg) = @_;
  67
  68     cfs_lock_file("storage.cfg", undef, $code);
  69     my $err = $@;
  70     if ($err) {
  71         $errmsg ? die "$errmsg: $err" : die $err;
  72     }
  73 }
  74
  75 sub storage_config {
  76     my ($cfg, $storeid, $noerr) = @_;
  77
  78     die "no storage id specified\n" if !$storeid;
  79
  80     my $scfg = $cfg->{ids}->{$storeid};
  81
  82     die "storage '$storeid' does not exists\n" if (!$noerr && !$scfg);
  83
  84     return $scfg;
  85 }
  86
  87 sub storage_check_node {
  88     my ($cfg, $storeid, $node, $noerr) = @_;
  89
  90     my $scfg = storage_config($cfg, $storeid);
  91
  92     if ($scfg->{nodes}) {
  93         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
  94         if (!$scfg->{nodes}->{$node}) {
  95             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
  96             return undef;
  97         }
  98     }
  99
 100     return $scfg;
 101 }
 102
 103 sub storage_check_enabled {
 104     my ($cfg, $storeid, $node, $noerr) = @_;
 105
 106     my $scfg = storage_config($cfg, $storeid);
 107
 108     if ($scfg->{disable}) {
 109         die "storage '$storeid' is disabled\n" if !$noerr;
 110         return undef;
 111     }
 112
 113     return storage_check_node($cfg, $storeid, $node, $noerr);
 114 }
 115
 116 sub storage_ids {
 117     my ($cfg) = @_;
 118
 119     return keys %{$cfg->{ids}};
 120 }
 121
 122 sub file_size_info {
 123     my ($filename, $timeout) = @_;
 124
 125     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 126 }
 127
 128 sub volume_size_info {
 129     my ($cfg, $volid, $timeout) = @_;
 130
 131     my ($storeid, $volname) = parse_volume_id($volid, 1);
 132     if ($storeid) {
 133         my $scfg = storage_config($cfg, $storeid);
 134         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 135         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 136     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 137         return file_size_info($volid, $timeout);
 138     } else {
 139         return 0;
 140     }
 141 }
 142
 143 sub volume_resize {
 144     my ($cfg, $volid, $size, $running) = @_;
 145
 146     my ($storeid, $volname) = parse_volume_id($volid, 1);
 147     if ($storeid) {
 148         my $scfg = storage_config($cfg, $storeid);
 149         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 150         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 151     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 152         die "resize file/device '$volid' is not possible\n";
 153     } else {
 154         die "unable to parse volume ID '$volid'\n";
 155     }
 156 }
 157
 158 sub volume_rollback_is_possible {
 159     my ($cfg, $volid, $snap) = @_;
 160
 161     my ($storeid, $volname) = parse_volume_id($volid, 1);
 162     if ($storeid) {
 163         my $scfg = storage_config($cfg, $storeid);
 164         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 165         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 166     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 167         die "snapshot rollback file/device '$volid' is not possible\n";
 168     } else {
 169         die "unable to parse volume ID '$volid'\n";
 170     }
 171 }
 172
 173 sub volume_snapshot {
 174     my ($cfg, $volid, $snap) = @_;
 175
 176     my ($storeid, $volname) = parse_volume_id($volid, 1);
 177     if ($storeid) {
 178         my $scfg = storage_config($cfg, $storeid);
 179         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 180         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 181     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 182         die "snapshot file/device '$volid' is not possible\n";
 183     } else {
 184         die "unable to parse volume ID '$volid'\n";
 185     }
 186 }
 187
 188 sub volume_snapshot_rollback {
 189     my ($cfg, $volid, $snap) = @_;
 190
 191     my ($storeid, $volname) = parse_volume_id($volid, 1);
 192     if ($storeid) {
 193         my $scfg = storage_config($cfg, $storeid);
 194         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 195         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 196         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 197     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 198         die "snapshot rollback file/device '$volid' is not possible\n";
 199     } else {
 200         die "unable to parse volume ID '$volid'\n";
 201     }
 202 }
 203
 204 sub volume_snapshot_delete {
 205     my ($cfg, $volid, $snap, $running) = @_;
 206
 207     my ($storeid, $volname) = parse_volume_id($volid, 1);
 208     if ($storeid) {
 209         my $scfg = storage_config($cfg, $storeid);
 210         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 211         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 212     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 213         die "snapshot delete file/device '$volid' is not possible\n";
 214     } else {
 215         die "unable to parse volume ID '$volid'\n";
 216     }
 217 }
 218
 219 sub volume_has_feature {
 220     my ($cfg, $feature, $volid, $snap, $running) = @_;
 221
 222     my ($storeid, $volname) = parse_volume_id($volid, 1);
 223     if ($storeid) {
 224         my $scfg = storage_config($cfg, $storeid);
 225         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 226         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running);
 227     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 228         return undef;
 229     } else {
 230         return undef;
 231     }
 232 }
 233
 234 sub get_image_dir {
 235     my ($cfg, $storeid, $vmid) = @_;
 236
 237     my $scfg = storage_config($cfg, $storeid);
 238     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 239
 240     my $path = $plugin->get_subdir($scfg, 'images');
 241
 242     return $vmid ? "$path/$vmid" : $path;
 243 }
 244
 245 sub get_private_dir {
 246     my ($cfg, $storeid, $vmid) = @_;
 247
 248     my $scfg = storage_config($cfg, $storeid);
 249     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 250
 251     my $path = $plugin->get_subdir($scfg, 'rootdir');
 252
 253     return $vmid ? "$path/$vmid" : $path;
 254 }
 255
 256 sub get_iso_dir {
 257     my ($cfg, $storeid) = @_;
 258
 259     my $scfg = storage_config($cfg, $storeid);
 260     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 261
 262     return $plugin->get_subdir($scfg, 'iso');
 263 }
 264
 265 sub get_vztmpl_dir {
 266     my ($cfg, $storeid) = @_;
 267
 268     my $scfg = storage_config($cfg, $storeid);
 269     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 270
 271     return $plugin->get_subdir($scfg, 'vztmpl');
 272 }
 273
 274 sub get_backup_dir {
 275     my ($cfg, $storeid) = @_;
 276
 277     my $scfg = storage_config($cfg, $storeid);
 278     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 279
 280     return $plugin->get_subdir($scfg, 'backup');
 281 }
 282
 283 # library implementation
 284
 285 sub parse_vmid {
 286     my $vmid = shift;
 287
 288     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 289
 290     return int($vmid);
 291 }
 292
 293 sub parse_volname {
 294     my ($cfg, $volid) = @_;
 295
 296     my ($storeid, $volname) = parse_volume_id($volid);
 297
 298     my $scfg = storage_config($cfg, $storeid);
 299
 300     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 301
 302     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 303
 304     return $plugin->parse_volname($volname);
 305 }
 306
 307 sub parse_volume_id {
 308     my ($volid, $noerr) = @_;
 309
 310     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 311 }
 312
 313 sub volume_is_base {
 314     my ($cfg, $volid) = @_;
 315
 316     my ($sid, $volname) = parse_volume_id($volid, 1);
 317     return 0 if !$sid;
 318
 319     if (my $scfg = $cfg->{ids}->{$sid}) {
 320         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 321         my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 322             $plugin->parse_volname($volname);
 323         return $isBase ? 1 : 0;
 324     } else {
 325         # stale volid with undefined storage - so we can just guess
 326         if ($volid =~ m/base-/) {
 327             return 1;
 328         }
 329     }
 330
 331     return 0;
 332 }
 333
 334 # try to map a filesystem path to a volume identifier
 335 sub path_to_volume_id {
 336     my ($cfg, $path) = @_;
 337
 338     my $ids = $cfg->{ids};
 339
 340     my ($sid, $volname) = parse_volume_id($path, 1);
 341     if ($sid) {
 342         if (my $scfg = $ids->{$sid}) {
 343             if ($scfg->{path}) {
 344                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 345                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 346                 return ($vtype, $path);
 347             }
 348         }
 349         return ('');
 350     }
 351
 352     # Note: abs_path() return undef if $path doesn not exist
 353     # for example when nfs storage is not mounted
 354     $path = abs_path($path) || $path;
 355
 356     foreach my $sid (keys %$ids) {
 357         my $scfg = $ids->{$sid};
 358         next if !$scfg->{path};
 359         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 360         my $imagedir = $plugin->get_subdir($scfg, 'images');
 361         my $isodir = $plugin->get_subdir($scfg, 'iso');
 362         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 363         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 364         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 365
 366         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 367             my $vmid = $1;
 368             my $name = $2;
 369
 370             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 371             foreach my $info (@$vollist) {
 372                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 373                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 374                 if ($volpath eq $path) {
 375                     return ('images', $info->{volid});
 376                 }
 377             }
 378         } elsif ($path =~ m!^$isodir/([^/]+\.[Ii][Ss][Oo])$!) {
 379             my $name = $1;
 380             return ('iso', "$sid:iso/$name");
 381         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 382             my $name = $1;
 383             return ('vztmpl', "$sid:vztmpl/$name");
 384         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 385             my $vmid = $1;
 386             return ('rootdir', "$sid:rootdir/$vmid");
 387         } elsif ($path =~ m!^$backupdir/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!) {
 388             my $name = $1;
 389             return ('iso', "$sid:backup/$name");
 390         }
 391     }
 392
 393     # can't map path to volume id
 394     return ('');
 395 }
 396
 397 sub path {
 398     my ($cfg, $volid, $snapname) = @_;
 399
 400     my ($storeid, $volname) = parse_volume_id($volid);
 401
 402     my $scfg = storage_config($cfg, $storeid);
 403
 404     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 405     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 406     return wantarray ? ($path, $owner, $vtype) : $path;
 407 }
 408
 409 sub abs_filesystem_path {
 410     my ($cfg, $volid) = @_;
 411
 412     my $path;
 413     if (PVE::Storage::parse_volume_id ($volid, 1)) {
 414         PVE::Storage::activate_volumes($cfg, [ $volid ]);
 415         $path = PVE::Storage::path($cfg, $volid);
 416     } else {
 417         if (-f $volid) {
 418             my $abspath = abs_path($volid);
 419             if ($abspath && $abspath =~ m|^(/.+)$|) {
 420                 $path = $1; # untaint any path
 421             }
 422         }
 423     }
 424
 425     die "can't find file '$volid'\n" if !($path && -f $path);
 426
 427     return $path;
 428 }
 429
 430 sub storage_migrate {
 431     my ($cfg, $volid, $target_host, $target_storeid, $target_volname) = @_;
 432
 433     my ($storeid, $volname) = parse_volume_id($volid);
 434     $target_volname = $volname if !$target_volname;
 435
 436     my $scfg = storage_config($cfg, $storeid);
 437
 438     # no need to migrate shared content
 439     return if $storeid eq $target_storeid && $scfg->{shared};
 440
 441     my $tcfg = storage_config($cfg, $target_storeid);
 442
 443     my $target_volid = "${target_storeid}:${target_volname}";
 444
 445     my $errstr = "unable to migrate '$volid' to '${target_volid}' on host '$target_host'";
 446
 447     my $sshoptions = "-o 'BatchMode=yes'";
 448     my $ssh = "/usr/bin/ssh $sshoptions";
 449
 450     local $ENV{RSYNC_RSH} = $ssh;
 451
 452     # only implemented for file system based storage
 453     if ($scfg->{path}) {
 454         if ($tcfg->{path}) {
 455
 456             my $src_plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 457             my $dst_plugin = PVE::Storage::Plugin->lookup($tcfg->{type});
 458             my $src = $src_plugin->path($scfg, $volname, $storeid);
 459             my $dst = $dst_plugin->path($tcfg, $target_volname, $target_storeid);
 460
 461             my $dirname = dirname($dst);
 462
 463             if ($tcfg->{shared}) { # we can do a local copy
 464
 465                 run_command(['/bin/mkdir', '-p', $dirname]);
 466
 467                 run_command(['/bin/cp', $src, $dst]);
 468
 469             } else {
 470                 run_command(['/usr/bin/ssh', "root\@${target_host}",
 471                              '/bin/mkdir', '-p', $dirname]);
 472
 473                 # we use rsync with --sparse, so we can't use --inplace,
 474                 # so we remove file on the target if it already exists to
 475                 # save space
 476                 my ($size, $format) = PVE::Storage::Plugin::file_size_info($src);
 477                 if ($format && ($format eq 'raw') && $size) {
 478                     run_command(['/usr/bin/ssh', "root\@${target_host}",
 479                                  'rm', '-f', $dst],
 480                                 outfunc => sub {});
 481                 }
 482
 483                 my $cmd;
 484                 if ($format eq 'subvol') {
 485                     $cmd = ['/usr/bin/rsync', '--progress', '-X', '-A', '--numeric-ids',
 486                             '-aH', '--delete', '--no-whole-file', '--inplace',
 487                             '--one-file-system', "$src/", "[root\@${target_host}]:$dst"];
 488                 } else {
 489                     $cmd = ['/usr/bin/rsync', '--progress', '--sparse', '--whole-file',
 490                             $src, "[root\@${target_host}]:$dst"];
 491                 }
 492
 493                 my $percent = -1;
 494
 495                 run_command($cmd, outfunc => sub {
 496                     my $line = shift;
 497
 498                     if ($line =~ m/^\s*(\d+\s+(\d+)%\s.*)$/) {
 499                         if ($2 > $percent) {
 500                             $percent = $2;
 501                             print "rsync status: $1\n";
 502                             *STDOUT->flush();
 503                         }
 504                     } else {
 505                         print "$line\n";
 506                         *STDOUT->flush();
 507                     }
 508                 });
 509             }
 510         } else {
 511             die "$errstr - target type '$tcfg->{type}' not implemented\n";
 512         }
 513
 514     } elsif ($scfg->{type} eq 'zfspool') {
 515
 516         if ($tcfg->{type} eq 'zfspool') {
 517
 518             die "$errstr - pool on target has not same name as source!"
 519                 if $tcfg->{pool} ne $scfg->{pool};
 520
 521             my (undef, $volname) = parse_volname($cfg, $volid);
 522
 523             my $zfspath = "$scfg->{pool}\/$volname";
 524
 525             my $snap = ['zfs', 'snapshot', "$zfspath\@__migration__"];
 526
 527             my $send = [['zfs', 'send', '-Rpv', "$zfspath\@__migration__"], ['ssh', "root\@$target_host",
 528                         'zfs', 'recv', $zfspath]];
 529
 530             my $destroy_target = ['ssh', "root\@$target_host", 'zfs', 'destroy', "$zfspath\@__migration__"];
 531             run_command($snap);
 532             eval{
 533                 run_command($send);
 534             };
 535             my $err;
 536             if ($err = $@){
 537                 run_command(['zfs', 'destroy', "$zfspath\@__migration__"]);
 538                 die $err;
 539             }
 540             run_command($destroy_target);
 541
 542         } else {
 543             die "$errstr - target type $tcfg->{type} is not valid\n";
 544         }
 545
 546     } elsif ($scfg->{type} eq 'lvmthin' || $scfg->{type} eq 'lvm') {
 547
 548         if ($tcfg->{type} eq 'lvmthin' || $tcfg->{type} eq 'lvm') {
 549
 550             die "$errstr - pool on target has not same name as source!"
 551                 if $tcfg->{type} ne $scfg->{type};
 552
 553             my (undef, $volname) = parse_volname($cfg, $volid);
 554             my $size = volume_size_info($cfg, $volid, 5);
 555             my $path = path($cfg, $volid);
 556
 557             $volname =~ m/^vm-(\d+)-/;
 558             my $vmid = $1;
 559
 560             run_command(['/usr/bin/ssh', "root\@${target_host}",
 561                          'pvesm', 'alloc', $target_storeid, $vmid,
 562                          $volname, $size/1024]);
 563
 564             eval {
 565                 run_command([["dd", "if=$path"],
 566                              ["/usr/bin/ssh", "root\@${target_host}", "-C",
 567                               "dd", 'conv=sparse', "of=$path"]]);
 568             };
 569             if (my $err = $@) {
 570                 run_command(['/usr/bin/ssh', "root\@${target_host}",
 571                          'pvesm', 'free', $volid]);
 572             } else {
 573                 vdisk_free($cfg, $volid);
 574             }
 575         } else {
 576             die "$errstr - target type $tcfg->{type} is not valid\n";
 577         }
 578     } else {
 579         die "$errstr - source type '$scfg->{type}' not implemented\n";
 580     }
 581 }
 582
 583 sub vdisk_clone {
 584     my ($cfg, $volid, $vmid, $snap) = @_;
 585
 586     my ($storeid, $volname) = parse_volume_id($volid);
 587
 588     my $scfg = storage_config($cfg, $storeid);
 589
 590     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 591
 592     activate_storage($cfg, $storeid);
 593
 594     # lock shared storage
 595     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 596         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 597         return "$storeid:$volname";
 598     });
 599 }
 600
 601 sub vdisk_create_base {
 602     my ($cfg, $volid) = @_;
 603
 604     my ($storeid, $volname) = parse_volume_id($volid);
 605
 606     my $scfg = storage_config($cfg, $storeid);
 607
 608     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 609
 610     activate_storage($cfg, $storeid);
 611
 612     # lock shared storage
 613     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 614         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 615         return "$storeid:$volname";
 616     });
 617 }
 618
 619 sub vdisk_alloc {
 620     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 621
 622     die "no storage id specified\n" if !$storeid;
 623
 624     PVE::JSONSchema::parse_storage_id($storeid);
 625
 626     my $scfg = storage_config($cfg, $storeid);
 627
 628     die "no VMID specified\n" if !$vmid;
 629
 630     $vmid = parse_vmid($vmid);
 631
 632     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 633
 634     $fmt = $defformat if !$fmt;
 635
 636     activate_storage($cfg, $storeid);
 637
 638     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 639
 640     # lock shared storage
 641     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 642         my $old_umask = umask(umask|0037);
 643         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 644         my $err = $@;
 645         umask $old_umask;
 646         die $err if $err;
 647         return "$storeid:$volname";
 648     });
 649 }
 650
 651 sub vdisk_free {
 652     my ($cfg, $volid) = @_;
 653
 654     my ($storeid, $volname) = parse_volume_id($volid);
 655
 656     my $scfg = storage_config($cfg, $storeid);
 657
 658     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 659
 660     activate_storage($cfg, $storeid);
 661
 662     my $cleanup_worker;
 663
 664     # lock shared storage
 665     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 666
 667         my ($vtype, $name, $vmid, undef, undef, $isBase, $format) =
 668             $plugin->parse_volname($volname);
 669         if ($isBase) {
 670             my $vollist = $plugin->list_images($storeid, $scfg);
 671             foreach my $info (@$vollist) {
 672                 my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 673                 my $basename = undef;
 674                 my $basevmid = undef;
 675
 676                 eval{
 677                     (undef, undef, undef, $basename, $basevmid) =
 678                         $plugin->parse_volname($tmpvolname);
 679                 };
 680
 681                 if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 682                     die "base volume '$volname' is still in use " .
 683                         "(use by '$tmpvolname')\n";
 684                 }
 685             }
 686         }
 687         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 688     });
 689
 690     return if !$cleanup_worker;
 691
 692     my $rpcenv = PVE::RPCEnvironment::get();
 693     my $authuser = $rpcenv->get_user();
 694
 695     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 696 }
 697
 698 #list iso or openvz template ($tt = <iso|vztmpl|backup>)
 699 sub template_list {
 700     my ($cfg, $storeid, $tt) = @_;
 701
 702     die "unknown template type '$tt'\n"
 703         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup');
 704
 705     my $ids = $cfg->{ids};
 706
 707     storage_check_enabled($cfg, $storeid) if ($storeid);
 708
 709     my $res = {};
 710
 711     # query the storage
 712
 713     foreach my $sid (keys %$ids) {
 714         next if $storeid && $storeid ne $sid;
 715
 716         my $scfg = $ids->{$sid};
 717         my $type = $scfg->{type};
 718
 719         next if !storage_check_enabled($cfg, $sid, undef, 1);
 720
 721         next if $tt eq 'iso' && !$scfg->{content}->{iso};
 722         next if $tt eq 'vztmpl' && !$scfg->{content}->{vztmpl};
 723         next if $tt eq 'backup' && !$scfg->{content}->{backup};
 724
 725         activate_storage($cfg, $sid);
 726
 727         if ($scfg->{path}) {
 728             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 729
 730             my $path = $plugin->get_subdir($scfg, $tt);
 731
 732             foreach my $fn (<$path/*>) {
 733
 734                 my $info;
 735
 736                 if ($tt eq 'iso') {
 737                     next if $fn !~ m!/([^/]+\.[Ii][Ss][Oo])$!;
 738
 739                     $info = { volid => "$sid:iso/$1", format => 'iso' };
 740
 741                 } elsif ($tt eq 'vztmpl') {
 742                     next if $fn !~ m!/([^/]+\.tar\.([gx]z))$!;
 743
 744                     $info = { volid => "$sid:vztmpl/$1", format => "t$2" };
 745
 746                 } elsif ($tt eq 'backup') {
 747                     next if $fn !~ m!/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!;
 748
 749                     $info = { volid => "$sid:backup/$1", format => $2 };
 750                 }
 751
 752                 $info->{size} = -s $fn;
 753
 754                 push @{$res->{$sid}}, $info;
 755             }
 756
 757         }
 758
 759         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 760     }
 761
 762     return $res;
 763 }
 764
 765
 766 sub vdisk_list {
 767     my ($cfg, $storeid, $vmid, $vollist) = @_;
 768
 769     my $ids = $cfg->{ids};
 770
 771     storage_check_enabled($cfg, $storeid) if ($storeid);
 772
 773     my $res = {};
 774
 775     # prepare/activate/refresh all storages
 776
 777     my $storage_list = [];
 778     if ($vollist) {
 779         foreach my $volid (@$vollist) {
 780             my ($sid, undef) = parse_volume_id($volid);
 781             next if !defined($ids->{$sid});
 782             next if !storage_check_enabled($cfg, $sid, undef, 1);
 783             push @$storage_list, $sid;
 784         }
 785     } else {
 786         foreach my $sid (keys %$ids) {
 787             next if $storeid && $storeid ne $sid;
 788             next if !storage_check_enabled($cfg, $sid, undef, 1);
 789             push @$storage_list, $sid;
 790         }
 791     }
 792
 793     my $cache = {};
 794
 795     activate_storage_list($cfg, $storage_list, $cache);
 796
 797     foreach my $sid (keys %$ids) {
 798         next if $storeid && $storeid ne $sid;
 799         next if !storage_check_enabled($cfg, $sid, undef, 1);
 800
 801         my $scfg = $ids->{$sid};
 802         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 803         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 804         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 805     }
 806
 807     return $res;
 808 }
 809
 810 sub volume_list {
 811     my ($cfg, $storeid, $vmid, $content) = @_;
 812
 813     my @ctypes = qw(images vztmpl iso backup);
 814
 815     my $cts = $content ? [ $content ] : [ @ctypes ];
 816
 817     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 818
 819     my $res = [];
 820     foreach my $ct (@$cts) {
 821         my $data;
 822         if ($ct eq 'images') {
 823             $data = vdisk_list($cfg, $storeid, $vmid);
 824         } elsif ($ct eq 'iso' && !defined($vmid)) {
 825             $data = template_list($cfg, $storeid, 'iso');
 826         } elsif ($ct eq 'vztmpl'&& !defined($vmid)) {
 827             $data = template_list ($cfg, $storeid, 'vztmpl');
 828         } elsif ($ct eq 'backup') {
 829             $data = template_list ($cfg, $storeid, 'backup');
 830             foreach my $item (@{$data->{$storeid}}) {
 831                 if (defined($vmid)) {
 832                     @{$data->{$storeid}} = grep { $_->{volid} =~ m/\S+-$vmid-\S+/ } @{$data->{$storeid}};
 833                 }
 834             }
 835         }
 836
 837         next if !$data || !$data->{$storeid};
 838
 839         foreach my $item (@{$data->{$storeid}}) {
 840             $item->{content} = $ct;
 841             push @$res, $item;
 842         }
 843     }
 844
 845     return $res;
 846 }
 847
 848 sub uevent_seqnum {
 849
 850     my $filename = "/sys/kernel/uevent_seqnum";
 851
 852     my $seqnum = 0;
 853     if (my $fh = IO::File->new($filename, "r")) {
 854         my $line = <$fh>;
 855         if ($line =~ m/^(\d+)$/) {
 856             $seqnum = int($1);
 857         }
 858         close ($fh);
 859     }
 860     return $seqnum;
 861 }
 862
 863 sub activate_storage {
 864     my ($cfg, $storeid, $cache) = @_;
 865
 866     $cache = {} if !$cache;
 867
 868     my $scfg = storage_check_enabled($cfg, $storeid);
 869
 870     return if $cache->{activated}->{$storeid};
 871
 872     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 873
 874     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 875
 876     if ($scfg->{base}) {
 877         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 878         activate_storage($cfg, $baseid, $cache);
 879     }
 880
 881     if (!$plugin->check_connection($storeid, $scfg)) {
 882         die "storage '$storeid' is not online\n";
 883     }
 884
 885     $plugin->activate_storage($storeid, $scfg, $cache);
 886
 887     my $newseq = uevent_seqnum ();
 888
 889     # only call udevsettle if there are events
 890     if ($newseq > $cache->{uevent_seqnum}) {
 891         my $timeout = 30;
 892         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
 893         $cache->{uevent_seqnum} = $newseq;
 894     }
 895
 896     $cache->{activated}->{$storeid} = 1;
 897 }
 898
 899 sub activate_storage_list {
 900     my ($cfg, $storeid_list, $cache) = @_;
 901
 902     $cache = {} if !$cache;
 903
 904     foreach my $storeid (@$storeid_list) {
 905         activate_storage($cfg, $storeid, $cache);
 906     }
 907 }
 908
 909 sub deactivate_storage {
 910     my ($cfg, $storeid) = @_;
 911
 912     my $scfg = storage_config ($cfg, $storeid);
 913     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 914
 915     my $cache = {};
 916     $plugin->deactivate_storage($storeid, $scfg, $cache);
 917 }
 918
 919 sub activate_volumes {
 920     my ($cfg, $vollist, $snapname) = @_;
 921
 922     return if !($vollist && scalar(@$vollist));
 923
 924     my $storagehash = {};
 925     foreach my $volid (@$vollist) {
 926         my ($storeid, undef) = parse_volume_id($volid);
 927         $storagehash->{$storeid} = 1;
 928     }
 929
 930     my $cache = {};
 931
 932     activate_storage_list($cfg, [keys %$storagehash], $cache);
 933
 934     foreach my $volid (@$vollist) {
 935         my ($storeid, $volname) = parse_volume_id($volid);
 936         my $scfg = storage_config($cfg, $storeid);
 937         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 938         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
 939     }
 940 }
 941
 942 sub deactivate_volumes {
 943     my ($cfg, $vollist, $snapname) = @_;
 944
 945     return if !($vollist && scalar(@$vollist));
 946
 947     my $cache = {};
 948
 949     my @errlist = ();
 950     foreach my $volid (@$vollist) {
 951         my ($storeid, $volname) = parse_volume_id($volid);
 952
 953         my $scfg = storage_config($cfg, $storeid);
 954         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 955
 956         eval {
 957             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
 958         };
 959         if (my $err = $@) {
 960             warn $err;
 961             push @errlist, $volid;
 962         }
 963     }
 964
 965     die "volume deativation failed: " . join(' ', @errlist)
 966         if scalar(@errlist);
 967 }
 968
 969 sub storage_info {
 970     my ($cfg, $content) = @_;
 971
 972     my $ids = $cfg->{ids};
 973
 974     my $info = {};
 975
 976     my @ctypes = PVE::Tools::split_list($content);
 977
 978     my $slist = [];
 979     foreach my $storeid (keys %$ids) {
 980
 981         next if !storage_check_enabled($cfg, $storeid, undef, 1);
 982
 983         if (defined($content)) {
 984             my $want_ctype = 0;
 985             foreach my $ctype (@ctypes) {
 986                 if ($ids->{$storeid}->{content}->{$ctype}) {
 987                     $want_ctype = 1;
 988                     last;
 989                 }
 990             }
 991             next if !$want_ctype;
 992         }
 993
 994         my $type = $ids->{$storeid}->{type};
 995
 996         $info->{$storeid} = {
 997             type => $type,
 998             total => 0,
 999             avail => 0,
1000             used => 0,
1001             shared => $ids->{$storeid}->{shared} ? 1 : 0,
1002             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
1003             active => 0,
1004         };
1005
1006         push @$slist, $storeid;
1007     }
1008
1009     my $cache = {};
1010
1011     foreach my $storeid (keys %$ids) {
1012         my $scfg = $ids->{$storeid};
1013         next if !$info->{$storeid};
1014
1015         eval { activate_storage($cfg, $storeid, $cache); };
1016         if (my $err = $@) {
1017             warn $err;
1018             next;
1019         }
1020
1021         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1022         my ($total, $avail, $used, $active);
1023         eval { ($total, $avail, $used, $active) = $plugin->status($storeid, $scfg, $cache); };
1024         warn $@ if $@;
1025         next if !$active;
1026         $info->{$storeid}->{total} = $total;
1027         $info->{$storeid}->{avail} = $avail;
1028         $info->{$storeid}->{used} = $used;
1029         $info->{$storeid}->{active} = $active;
1030     }
1031
1032     return $info;
1033 }
1034
1035 sub resolv_server {
1036     my ($server) = @_;
1037
1038     my ($packed_ip, $family);
1039     eval {
1040         my @res = PVE::Tools::getaddrinfo_all($server);
1041         $family = $res[0]->{family};
1042         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1043     };
1044     if (defined $packed_ip) {
1045         return Socket::inet_ntop($family, $packed_ip);
1046     }
1047     return undef;
1048 }
1049
1050 sub scan_nfs {
1051     my ($server_in) = @_;
1052
1053     my $server;
1054     if (!($server = resolv_server ($server_in))) {
1055         die "unable to resolve address for server '${server_in}'\n";
1056     }
1057
1058     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1059
1060     my $res = {};
1061     run_command($cmd, outfunc => sub {
1062         my $line = shift;
1063
1064         # note: howto handle white spaces in export path??
1065         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1066             $res->{$1} = $2;
1067         }
1068     });
1069
1070     return $res;
1071 }
1072
1073 sub scan_zfs {
1074
1075     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-H', '-o', 'name,avail,used'];
1076
1077     my $res = [];
1078     run_command($cmd, outfunc => sub {
1079         my $line = shift;
1080
1081         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1082             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1083             my $size = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($size_str);
1084             my $used = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($used_str);
1085             # ignore subvolumes generated by our ZFSPoolPlugin
1086             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1087             return if $pool =~ m!/basevol-\d+-[^/]+$!;
1088             push @$res, { pool => $pool, size => $size, free => $size-$used };
1089         }
1090     });
1091
1092     return $res;
1093 }
1094
1095 sub resolv_portal {
1096     my ($portal, $noerr) = @_;
1097
1098     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1099     if ($server) {
1100         if (my $ip = resolv_server($server)) {
1101             $server = $ip;
1102             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1103             return $port ? "$server:$port" : $server;
1104         }
1105     }
1106     return undef if $noerr;
1107
1108     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1109 }
1110
1111 # idea is from usbutils package (/usr/bin/usb-devices) script
1112 sub __scan_usb_device {
1113     my ($res, $devpath, $parent, $level) = @_;
1114
1115     return if ! -d $devpath;
1116     return if $level && $devpath !~ m/^.*[-.](\d+)$/;
1117     my $port = $level ? int($1 - 1) : 0;
1118
1119     my $busnum = int(file_read_firstline("$devpath/busnum"));
1120     my $devnum = int(file_read_firstline("$devpath/devnum"));
1121
1122     my $d = {
1123         port => $port,
1124         level => $level,
1125         busnum => $busnum,
1126         devnum => $devnum,
1127         speed => file_read_firstline("$devpath/speed"),
1128         class => hex(file_read_firstline("$devpath/bDeviceClass")),
1129         vendid => file_read_firstline("$devpath/idVendor"),
1130         prodid => file_read_firstline("$devpath/idProduct"),
1131     };
1132
1133     if ($level) {
1134         my $usbpath = $devpath;
1135         $usbpath =~ s|^.*/\d+\-||;
1136         $d->{usbpath} = $usbpath;
1137     }
1138
1139     my $product = file_read_firstline("$devpath/product");
1140     $d->{product} = $product if $product;
1141
1142     my $manu = file_read_firstline("$devpath/manufacturer");
1143     $d->{manufacturer} = $manu if $manu;
1144
1145     my $serial => file_read_firstline("$devpath/serial");
1146     $d->{serial} = $serial if $serial;
1147
1148     push @$res, $d;
1149
1150     foreach my $subdev (<$devpath/$busnum-*>) {
1151         next if $subdev !~ m|/$busnum-[0-9]+(\.[0-9]+)*$|;
1152         __scan_usb_device($res, $subdev, $devnum, $level + 1);
1153     }
1154
1155 };
1156
1157 sub scan_usb {
1158
1159     my $devlist = [];
1160
1161     foreach my $device (</sys/bus/usb/devices/usb*>) {
1162         __scan_usb_device($devlist, $device, 0, 0);
1163     }
1164
1165     return $devlist;
1166 }
1167
1168 sub scan_iscsi {
1169     my ($portal_in) = @_;
1170
1171     my $portal;
1172     if (!($portal = resolv_portal($portal_in))) {
1173         die "unable to parse/resolve portal address '${portal_in}'\n";
1174     }
1175
1176     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1177 }
1178
1179 sub storage_default_format {
1180     my ($cfg, $storeid) = @_;
1181
1182     my $scfg = storage_config ($cfg, $storeid);
1183
1184     return PVE::Storage::Plugin::default_format($scfg);
1185 }
1186
1187 sub vgroup_is_used {
1188     my ($cfg, $vgname) = @_;
1189
1190     foreach my $storeid (keys %{$cfg->{ids}}) {
1191         my $scfg = storage_config($cfg, $storeid);
1192         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1193             return 1;
1194         }
1195     }
1196
1197     return undef;
1198 }
1199
1200 sub target_is_used {
1201     my ($cfg, $target) = @_;
1202
1203     foreach my $storeid (keys %{$cfg->{ids}}) {
1204         my $scfg = storage_config($cfg, $storeid);
1205         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1206             return 1;
1207         }
1208     }
1209
1210     return undef;
1211 }
1212
1213 sub volume_is_used {
1214     my ($cfg, $volid) = @_;
1215
1216     foreach my $storeid (keys %{$cfg->{ids}}) {
1217         my $scfg = storage_config($cfg, $storeid);
1218         if ($scfg->{base} && $scfg->{base} eq $volid) {
1219             return 1;
1220         }
1221     }
1222
1223     return undef;
1224 }
1225
1226 sub storage_is_used {
1227     my ($cfg, $storeid) = @_;
1228
1229     foreach my $sid (keys %{$cfg->{ids}}) {
1230         my $scfg = storage_config($cfg, $sid);
1231         next if !$scfg->{base};
1232         my ($st) = parse_volume_id($scfg->{base});
1233         return 1 if $st && $st eq $storeid;
1234     }
1235
1236     return undef;
1237 }
1238
1239 sub foreach_volid {
1240     my ($list, $func) = @_;
1241
1242     return if !$list;
1243
1244     foreach my $sid (keys %$list) {
1245        foreach my $info (@{$list->{$sid}}) {
1246            my $volid = $info->{volid};
1247            my ($sid1, $volname) = parse_volume_id($volid, 1);
1248            if ($sid1 && $sid1 eq $sid) {
1249                &$func ($volid, $sid, $info);
1250            } else {
1251                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1252            }
1253        }
1254     }
1255 }
1256
1257 sub extract_vzdump_config_tar {
1258     my ($archive, $conf_re) = @_;
1259
1260     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
1261
1262     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
1263        die "unable to open file '$archive'\n";
1264
1265     my $file;
1266     while (defined($file = <$fh>)) {
1267         if ($file =~ m!$conf_re!) {
1268             $file = $1; # untaint
1269             last;
1270         }
1271     }
1272
1273     kill 15, $pid;
1274     waitpid $pid, 0;
1275     close $fh;
1276
1277     die "ERROR: archive contains no configuration file\n" if !$file;
1278     chomp $file;
1279
1280     my $raw = '';
1281     my $out = sub {
1282         my $output = shift;
1283         $raw .= "$output\n";
1284     };
1285
1286     PVE::Tools::run_command(['tar', '-xpOf', $archive, $file, '--occurrence'], outfunc => $out);
1287
1288     return wantarray ? ($raw, $file) : $raw;
1289 }
1290
1291 sub extract_vzdump_config_vma {
1292     my ($archive, $comp) = @_;
1293
1294     my $cmd;
1295     my $raw = '';
1296     my $out = sub {
1297         my $output = shift;
1298         $raw .= "$output\n";
1299     };
1300
1301
1302     if ($comp) {
1303         my $uncomp;
1304         if ($comp eq 'gz') {
1305             $uncomp = ["zcat", $archive];
1306         } elsif ($comp eq 'lzo') {
1307             $uncomp = ["lzop", "-d", "-c", $archive];
1308         } else {
1309             die "unknown compression method '$comp'\n";
1310         }
1311         $cmd = [$uncomp, ["vma", "config", "-"]];
1312
1313         # in some cases, lzop/zcat exits with 1 when its stdout pipe is
1314         # closed early by vma, detect this and ignore the exit code later
1315         my $broken_pipe;
1316         my $errstring;
1317         my $err = sub {
1318             my $output = shift;
1319             if ($output =~ m/lzop: Broken pipe: <stdout>/ || $output =~ m/gzip: stdout: Broken pipe/) {
1320                 $broken_pipe = 1;
1321             } elsif (!defined ($errstring) && $output !~ m/^\s*$/) {
1322                 $errstring = "Failed to extract config from VMA archive: $output\n";
1323             }
1324         };
1325
1326         # in other cases, the pipeline will exit with exit code 141
1327         # because of the broken pipe, handle / ignore this as well
1328         my $rc;
1329         eval {
1330             $rc = PVE::Tools::run_command($cmd, outfunc => $out, errfunc => $err, noerr => 1);
1331         };
1332         my $rerr = $@;
1333
1334         # use exit code if no stderr output and not just broken pipe
1335         if (!$errstring && !$broken_pipe && $rc > 0 && $rc != 141) {
1336             die "$rerr\n" if $rerr;
1337             die "config extraction failed with exit code $rc\n";
1338         }
1339         die "$errstring\n" if $errstring;
1340     } else {
1341         # simple case without compression and weird piping behaviour
1342         PVE::Tools::run_command(["vma", "config", $archive], outfunc => $out);
1343     }
1344
1345     return wantarray ? ($raw, undef) : $raw;
1346 }
1347
1348 sub extract_vzdump_config {
1349     my ($cfg, $volid) = @_;
1350
1351     my $archive = abs_filesystem_path($cfg, $volid);
1352
1353     if ($volid =~ /\/vzdump-(lxc|openvz)-\d+-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2})\.(tgz|(tar(\.(gz|lzo))?))$/) {
1354         return extract_vzdump_config_tar($archive,'^(\./etc/vzdump/(pct|vps)\.conf)$');
1355     } elsif ($volid =~ /\/vzdump-qemu-\d+-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2})\.(tgz|((tar|vma)(\.(gz|lzo))?))$/) {
1356         my $format;
1357         my $comp;
1358         if ($7 eq 'tgz') {
1359             $format = 'tar';
1360             $comp = 'gz';
1361         } else {
1362             $format = $9;
1363             $comp = $11 if defined($11);
1364         }
1365
1366         if ($format eq 'tar') {
1367             return extract_vzdump_config_tar($archive, qr!\(\./qemu-server\.conf\)!);
1368         } else {
1369             return extract_vzdump_config_vma($archive, $comp);
1370         }
1371     } else {
1372         die "cannot determine backup guest type for backup archive '$volid'\n";
1373     }
1374 }
1375
1376 # bash completion helper
1377
1378 sub complete_storage {
1379     my ($cmdname, $pname, $cvalue) = @_;
1380
1381     my $cfg = PVE::Storage::config();
1382
1383     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1384 }
1385
1386 sub complete_storage_enabled {
1387     my ($cmdname, $pname, $cvalue) = @_;
1388
1389     my $res = [];
1390
1391     my $cfg = PVE::Storage::config();
1392     foreach my $sid (keys %{$cfg->{ids}}) {
1393         next if !storage_check_enabled($cfg, $sid, undef, 1);
1394         push @$res, $sid;
1395     }
1396     return $res;
1397 }
1398
1399 sub complete_content_type {
1400     my ($cmdname, $pname, $cvalue) = @_;
1401
1402     return [qw(rootdir images vztmpl iso backup)];
1403 }
1404
1405 sub complete_volume {
1406     my ($cmdname, $pname, $cvalue) = @_;
1407
1408     my $cfg = config();
1409
1410     my $storage_list = complete_storage_enabled();
1411
1412     if ($cvalue =~ m/^([^:]+):/) {
1413         $storage_list = [ $1 ];
1414     } else {
1415         if (scalar(@$storage_list) > 1) {
1416             # only list storage IDs to avoid large listings
1417             my $res = [];
1418             foreach my $storeid (@$storage_list) {
1419                 # Hack: simply return 2 artificial values, so that
1420                 # completions does not finish
1421                 push @$res, "$storeid:volname", "$storeid:...";
1422             }
1423             return $res;
1424         }
1425     }
1426
1427     my $res = [];
1428     foreach my $storeid (@$storage_list) {
1429         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1430
1431         foreach my $item (@$vollist) {
1432             push @$res, $item->{volid};
1433         }
1434     }
1435
1436     return $res;
1437 }
1438
1439 1;