PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use IO::Socket::IP;
  11 use File::Basename;
  12 use File::Path;
  13 use Cwd 'abs_path';
  14 use Socket;
  15
  16 use PVE::Tools qw(run_command file_read_firstline dir_glob_foreach $IPV6RE);
  17 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  18 use PVE::DataCenterConfig;
  19 use PVE::Exception qw(raise_param_exc);
  20 use PVE::JSONSchema;
  21 use PVE::INotify;
  22 use PVE::RPCEnvironment;
  23
  24 use PVE::Storage::Plugin;
  25 use PVE::Storage::DirPlugin;
  26 use PVE::Storage::LVMPlugin;
  27 use PVE::Storage::LvmThinPlugin;
  28 use PVE::Storage::NFSPlugin;
  29 use PVE::Storage::CIFSPlugin;
  30 use PVE::Storage::ISCSIPlugin;
  31 use PVE::Storage::RBDPlugin;
  32 use PVE::Storage::CephFSPlugin;
  33 use PVE::Storage::ISCSIDirectPlugin;
  34 use PVE::Storage::GlusterfsPlugin;
  35 use PVE::Storage::ZFSPoolPlugin;
  36 use PVE::Storage::ZFSPlugin;
  37 use PVE::Storage::DRBDPlugin;
  38
  39 # Storage API version. Icrement it on changes in storage API interface.
  40 use constant APIVER => 3;
  41 # Age is the number of versions we're backward compatible with.
  42 # This is like having 'current=APIVER' and age='APIAGE' in libtool,
  43 # see https://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  44 use constant APIAGE => 2;
  45
  46 # load standard plugins
  47 PVE::Storage::DirPlugin->register();
  48 PVE::Storage::LVMPlugin->register();
  49 PVE::Storage::LvmThinPlugin->register();
  50 PVE::Storage::NFSPlugin->register();
  51 PVE::Storage::CIFSPlugin->register();
  52 PVE::Storage::ISCSIPlugin->register();
  53 PVE::Storage::RBDPlugin->register();
  54 PVE::Storage::CephFSPlugin->register();
  55 PVE::Storage::ISCSIDirectPlugin->register();
  56 PVE::Storage::GlusterfsPlugin->register();
  57 PVE::Storage::ZFSPoolPlugin->register();
  58 PVE::Storage::ZFSPlugin->register();
  59 PVE::Storage::DRBDPlugin->register();
  60
  61 # load third-party plugins
  62 if ( -d '/usr/share/perl5/PVE/Storage/Custom' ) {
  63     dir_glob_foreach('/usr/share/perl5/PVE/Storage/Custom', '.*\.pm$', sub {
  64         my ($file) = @_;
  65         my $modname = 'PVE::Storage::Custom::' . $file;
  66         $modname =~ s!\.pm$!!;
  67         $file = 'PVE/Storage/Custom/' . $file;
  68
  69         eval {
  70             require $file;
  71
  72             # Check perl interface:
  73             die "not derived from PVE::Storage::Plugin\n"
  74                 if !$modname->isa('PVE::Storage::Plugin');
  75             die "does not provide an api() method\n"
  76                 if !$modname->can('api');
  77             # Check storage API version and that file is really storage plugin.
  78             my $version = $modname->api();
  79             die "implements an API version newer than current ($version > " . APIVER . ")\n"
  80                 if $version > APIVER;
  81             my $min_version = (APIVER - APIAGE);
  82             die "API version too old, please update the plugin ($version < $min_version)\n"
  83                 if $version < $min_version;
  84             import $file;
  85             $modname->register();
  86
  87             # If we got this far and the API version is not the same, make some
  88             # noise:
  89             warn "Plugin \"$modname\" is implementing an older storage API, an upgrade is recommended\n"
  90                 if $version != APIVER;
  91         };
  92         if ($@) {
  93             warn "Error loading storage plugin \"$modname\": $@";
  94         }
  95     });
  96 }
  97
  98 # initialize all plugins
  99 PVE::Storage::Plugin->init();
 100
 101 my $UDEVADM = '/sbin/udevadm';
 102
 103 our $iso_extension_re = qr/\.(?:iso|img)/i;
 104
 105 #  PVE::Storage utility functions
 106
 107 sub config {
 108     return cfs_read_file("storage.cfg");
 109 }
 110
 111 sub write_config {
 112     my ($cfg) = @_;
 113
 114     cfs_write_file('storage.cfg', $cfg);
 115 }
 116
 117 sub lock_storage_config {
 118     my ($code, $errmsg) = @_;
 119
 120     cfs_lock_file("storage.cfg", undef, $code);
 121     my $err = $@;
 122     if ($err) {
 123         $errmsg ? die "$errmsg: $err" : die $err;
 124     }
 125 }
 126
 127 sub storage_config {
 128     my ($cfg, $storeid, $noerr) = @_;
 129
 130     die "no storage ID specified\n" if !$storeid;
 131
 132     my $scfg = $cfg->{ids}->{$storeid};
 133
 134     die "storage '$storeid' does not exists\n" if (!$noerr && !$scfg);
 135
 136     return $scfg;
 137 }
 138
 139 sub storage_check_node {
 140     my ($cfg, $storeid, $node, $noerr) = @_;
 141
 142     my $scfg = storage_config($cfg, $storeid);
 143
 144     if ($scfg->{nodes}) {
 145         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
 146         if (!$scfg->{nodes}->{$node}) {
 147             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
 148             return undef;
 149         }
 150     }
 151
 152     return $scfg;
 153 }
 154
 155 sub storage_check_enabled {
 156     my ($cfg, $storeid, $node, $noerr) = @_;
 157
 158     my $scfg = storage_config($cfg, $storeid);
 159
 160     if ($scfg->{disable}) {
 161         die "storage '$storeid' is disabled\n" if !$noerr;
 162         return undef;
 163     }
 164
 165     return storage_check_node($cfg, $storeid, $node, $noerr);
 166 }
 167
 168 # storage_can_replicate:
 169 # return true if storage supports replication
 170 # (volumes alocated with vdisk_alloc() has replication feature)
 171 sub storage_can_replicate {
 172     my ($cfg, $storeid, $format) = @_;
 173
 174     my $scfg = storage_config($cfg, $storeid);
 175     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 176     return $plugin->storage_can_replicate($scfg, $storeid, $format);
 177 }
 178
 179 sub storage_ids {
 180     my ($cfg) = @_;
 181
 182     return keys %{$cfg->{ids}};
 183 }
 184
 185 sub file_size_info {
 186     my ($filename, $timeout) = @_;
 187
 188     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 189 }
 190
 191 sub volume_size_info {
 192     my ($cfg, $volid, $timeout) = @_;
 193
 194     my ($storeid, $volname) = parse_volume_id($volid, 1);
 195     if ($storeid) {
 196         my $scfg = storage_config($cfg, $storeid);
 197         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 198         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 199     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 200         return file_size_info($volid, $timeout);
 201     } else {
 202         return 0;
 203     }
 204 }
 205
 206 sub volume_resize {
 207     my ($cfg, $volid, $size, $running) = @_;
 208
 209     my ($storeid, $volname) = parse_volume_id($volid, 1);
 210     if ($storeid) {
 211         my $scfg = storage_config($cfg, $storeid);
 212         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 213         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 214     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 215         die "resize file/device '$volid' is not possible\n";
 216     } else {
 217         die "unable to parse volume ID '$volid'\n";
 218     }
 219 }
 220
 221 sub volume_rollback_is_possible {
 222     my ($cfg, $volid, $snap) = @_;
 223
 224     my ($storeid, $volname) = parse_volume_id($volid, 1);
 225     if ($storeid) {
 226         my $scfg = storage_config($cfg, $storeid);
 227         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 228         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 229     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 230         die "snapshot rollback file/device '$volid' is not possible\n";
 231     } else {
 232         die "unable to parse volume ID '$volid'\n";
 233     }
 234 }
 235
 236 sub volume_snapshot {
 237     my ($cfg, $volid, $snap) = @_;
 238
 239     my ($storeid, $volname) = parse_volume_id($volid, 1);
 240     if ($storeid) {
 241         my $scfg = storage_config($cfg, $storeid);
 242         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 243         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 244     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 245         die "snapshot file/device '$volid' is not possible\n";
 246     } else {
 247         die "unable to parse volume ID '$volid'\n";
 248     }
 249 }
 250
 251 sub volume_snapshot_rollback {
 252     my ($cfg, $volid, $snap) = @_;
 253
 254     my ($storeid, $volname) = parse_volume_id($volid, 1);
 255     if ($storeid) {
 256         my $scfg = storage_config($cfg, $storeid);
 257         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 258         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 259         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 260     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 261         die "snapshot rollback file/device '$volid' is not possible\n";
 262     } else {
 263         die "unable to parse volume ID '$volid'\n";
 264     }
 265 }
 266
 267 sub volume_snapshot_delete {
 268     my ($cfg, $volid, $snap, $running) = @_;
 269
 270     my ($storeid, $volname) = parse_volume_id($volid, 1);
 271     if ($storeid) {
 272         my $scfg = storage_config($cfg, $storeid);
 273         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 274         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 275     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 276         die "snapshot delete file/device '$volid' is not possible\n";
 277     } else {
 278         die "unable to parse volume ID '$volid'\n";
 279     }
 280 }
 281
 282 sub volume_has_feature {
 283     my ($cfg, $feature, $volid, $snap, $running) = @_;
 284
 285     my ($storeid, $volname) = parse_volume_id($volid, 1);
 286     if ($storeid) {
 287         my $scfg = storage_config($cfg, $storeid);
 288         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 289         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running);
 290     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 291         return undef;
 292     } else {
 293         return undef;
 294     }
 295 }
 296
 297 sub volume_snapshot_list {
 298     my ($cfg, $volid) = @_;
 299
 300     my ($storeid, $volname) = parse_volume_id($volid, 1);
 301     if ($storeid) {
 302         my $scfg = storage_config($cfg, $storeid);
 303         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 304         return $plugin->volume_snapshot_list($scfg, $storeid, $volname);
 305     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 306         die "send file/device '$volid' is not possible\n";
 307     } else {
 308         die "unable to parse volume ID '$volid'\n";
 309     }
 310     # return an empty array if dataset does not exist.
 311 }
 312
 313 sub get_image_dir {
 314     my ($cfg, $storeid, $vmid) = @_;
 315
 316     my $scfg = storage_config($cfg, $storeid);
 317     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 318
 319     my $path = $plugin->get_subdir($scfg, 'images');
 320
 321     return $vmid ? "$path/$vmid" : $path;
 322 }
 323
 324 sub get_private_dir {
 325     my ($cfg, $storeid, $vmid) = @_;
 326
 327     my $scfg = storage_config($cfg, $storeid);
 328     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 329
 330     my $path = $plugin->get_subdir($scfg, 'rootdir');
 331
 332     return $vmid ? "$path/$vmid" : $path;
 333 }
 334
 335 sub get_iso_dir {
 336     my ($cfg, $storeid) = @_;
 337
 338     my $scfg = storage_config($cfg, $storeid);
 339     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 340
 341     return $plugin->get_subdir($scfg, 'iso');
 342 }
 343
 344 sub get_vztmpl_dir {
 345     my ($cfg, $storeid) = @_;
 346
 347     my $scfg = storage_config($cfg, $storeid);
 348     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 349
 350     return $plugin->get_subdir($scfg, 'vztmpl');
 351 }
 352
 353 sub get_backup_dir {
 354     my ($cfg, $storeid) = @_;
 355
 356     my $scfg = storage_config($cfg, $storeid);
 357     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 358
 359     return $plugin->get_subdir($scfg, 'backup');
 360 }
 361
 362 # library implementation
 363
 364 sub parse_vmid {
 365     my $vmid = shift;
 366
 367     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 368
 369     return int($vmid);
 370 }
 371
 372 # NOTE: basename and basevmid are always undef for LVM-thin, where the
 373 # clone -> base reference is not encoded in the volume ID.
 374 # see note in PVE::Storage::LvmThinPlugin for details.
 375 sub parse_volname {
 376     my ($cfg, $volid) = @_;
 377
 378     my ($storeid, $volname) = parse_volume_id($volid);
 379
 380     my $scfg = storage_config($cfg, $storeid);
 381
 382     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 383
 384     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 385
 386     return $plugin->parse_volname($volname);
 387 }
 388
 389 sub parse_volume_id {
 390     my ($volid, $noerr) = @_;
 391
 392     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 393 }
 394
 395 # test if we have read access to volid
 396 sub check_volume_access {
 397     my ($rpcenv, $user, $cfg, $vmid, $volid) = @_;
 398
 399     my ($sid, $volname) = parse_volume_id($volid, 1);
 400     if ($sid) {
 401         my ($vtype, undef, $ownervm) = parse_volname($cfg, $volid);
 402         if ($vtype eq 'iso' || $vtype eq 'vztmpl') {
 403             # require at least read access to storage, (custom) templates/ISOs could be sensitive
 404             $rpcenv->check_any($user, "/storage/$sid", ['Datastore.AllocateSpace', 'Datastore.Audit']);
 405         } elsif (defined($ownervm) && defined($vmid) && ($ownervm == $vmid)) {
 406             # we are owner - allow access
 407         } elsif ($vtype eq 'backup' && $ownervm) {
 408             $rpcenv->check($user, "/storage/$sid", ['Datastore.AllocateSpace']);
 409             $rpcenv->check($user, "/vms/$ownervm", ['VM.Backup']);
 410         } else {
 411             # allow if we are Datastore administrator
 412             $rpcenv->check($user, "/storage/$sid", ['Datastore.Allocate']);
 413         }
 414     } else {
 415         die "Only root can pass arbitrary filesystem paths."
 416             if $user ne 'root@pam';
 417     }
 418
 419     return undef;
 420 }
 421
 422 my $volume_is_base_and_used__no_lock = sub {
 423     my ($scfg, $storeid, $plugin, $volname) = @_;
 424
 425     my ($vtype, $name, $vmid, undef, undef, $isBase, undef) =
 426         $plugin->parse_volname($volname);
 427
 428     if ($isBase) {
 429         my $vollist = $plugin->list_images($storeid, $scfg);
 430         foreach my $info (@$vollist) {
 431             my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 432             my $basename = undef;
 433             my $basevmid = undef;
 434
 435             eval{
 436                 (undef, undef, undef, $basename, $basevmid) =
 437                     $plugin->parse_volname($tmpvolname);
 438             };
 439
 440             if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 441                 return 1;
 442             }
 443         }
 444     }
 445     return 0;
 446 };
 447
 448 # NOTE: this check does not work for LVM-thin, where the clone -> base
 449 # reference is not encoded in the volume ID.
 450 # see note in PVE::Storage::LvmThinPlugin for details.
 451 sub volume_is_base_and_used {
 452     my ($cfg, $volid) = @_;
 453
 454     my ($storeid, $volname) = parse_volume_id($volid);
 455     my $scfg = storage_config($cfg, $storeid);
 456     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 457
 458     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 459         return &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 460     });
 461 }
 462
 463 # try to map a filesystem path to a volume identifier
 464 sub path_to_volume_id {
 465     my ($cfg, $path) = @_;
 466
 467     my $ids = $cfg->{ids};
 468
 469     my ($sid, $volname) = parse_volume_id($path, 1);
 470     if ($sid) {
 471         if (my $scfg = $ids->{$sid}) {
 472             if ($scfg->{path}) {
 473                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 474                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 475                 return ($vtype, $path);
 476             }
 477         }
 478         return ('');
 479     }
 480
 481     # Note: abs_path() return undef if $path doesn not exist
 482     # for example when nfs storage is not mounted
 483     $path = abs_path($path) || $path;
 484
 485     foreach my $sid (keys %$ids) {
 486         my $scfg = $ids->{$sid};
 487         next if !$scfg->{path};
 488         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 489         my $imagedir = $plugin->get_subdir($scfg, 'images');
 490         my $isodir = $plugin->get_subdir($scfg, 'iso');
 491         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 492         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 493         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 494
 495         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 496             my $vmid = $1;
 497             my $name = $2;
 498
 499             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 500             foreach my $info (@$vollist) {
 501                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 502                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 503                 if ($volpath eq $path) {
 504                     return ('images', $info->{volid});
 505                 }
 506             }
 507         } elsif ($path =~ m!^$isodir/([^/]+$iso_extension_re)$!) {
 508             my $name = $1;
 509             return ('iso', "$sid:iso/$name");
 510         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 511             my $name = $1;
 512             return ('vztmpl', "$sid:vztmpl/$name");
 513         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 514             my $vmid = $1;
 515             return ('rootdir', "$sid:rootdir/$vmid");
 516         } elsif ($path =~ m!^$backupdir/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!) {
 517             my $name = $1;
 518             return ('iso', "$sid:backup/$name");
 519         }
 520     }
 521
 522     # can't map path to volume id
 523     return ('');
 524 }
 525
 526 sub path {
 527     my ($cfg, $volid, $snapname) = @_;
 528
 529     my ($storeid, $volname) = parse_volume_id($volid);
 530
 531     my $scfg = storage_config($cfg, $storeid);
 532
 533     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 534     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 535     return wantarray ? ($path, $owner, $vtype) : $path;
 536 }
 537
 538 sub abs_filesystem_path {
 539     my ($cfg, $volid) = @_;
 540
 541     my $path;
 542     if (parse_volume_id ($volid, 1)) {
 543         activate_volumes($cfg, [ $volid ]);
 544         $path = PVE::Storage::path($cfg, $volid);
 545     } else {
 546         if (-f $volid) {
 547             my $abspath = abs_path($volid);
 548             if ($abspath && $abspath =~ m|^(/.+)$|) {
 549                 $path = $1; # untaint any path
 550             }
 551         }
 552     }
 553
 554     die "can't find file '$volid'\n" if !($path && -f $path);
 555
 556     return $path;
 557 }
 558
 559 sub storage_migrate {
 560     my ($cfg, $volid, $target_sshinfo, $target_storeid, $target_volname, $base_snapshot, $snapshot, $ratelimit_bps, $insecure, $with_snapshots, $logfunc) = @_;
 561
 562     my ($storeid, $volname) = parse_volume_id($volid);
 563     $target_volname = $volname if !$target_volname;
 564
 565     my $scfg = storage_config($cfg, $storeid);
 566
 567     # no need to migrate shared content
 568     return if $storeid eq $target_storeid && $scfg->{shared};
 569
 570     my $tcfg = storage_config($cfg, $target_storeid);
 571
 572     my $target_volid = "${target_storeid}:${target_volname}";
 573
 574     my $target_ip = $target_sshinfo->{ip};
 575     my $errstr = "unable to migrate '$volid' to '${target_volid}' on host '$target_sshinfo->{name}'";
 576
 577     my $ssh = PVE::Cluster::ssh_info_to_command($target_sshinfo);
 578     my $ssh_base = PVE::Cluster::ssh_info_to_command_base($target_sshinfo);
 579     local $ENV{RSYNC_RSH} = PVE::Tools::cmd2string($ssh_base);
 580
 581     my @cstream = ([ '/usr/bin/cstream', '-t', $ratelimit_bps ])
 582         if defined($ratelimit_bps);
 583
 584     my $migration_snapshot;
 585     if (!defined($snapshot)) {
 586         if ($scfg->{type} eq 'zfspool') {
 587             $migration_snapshot = 1;
 588             $snapshot = '__migration__';
 589         }
 590     }
 591
 592     my @formats = volume_transfer_formats($cfg, $volid, $target_volid, $snapshot, $base_snapshot, $with_snapshots);
 593     die "cannot migrate from storage type '$scfg->{type}' to '$tcfg->{type}'\n" if !@formats;
 594     my $format = $formats[0];
 595
 596     my $import_fn = '-'; # let pvesm import read from stdin per default
 597     if ($insecure) {
 598         my $net = $target_sshinfo->{network} // $target_sshinfo->{ip};
 599         $import_fn = "tcp://$net";
 600     }
 601
 602     $with_snapshots = $with_snapshots ? 1 : 0; # sanitize for passing as cli parameter
 603     my $send = ['pvesm', 'export', $volid, $format, '-', '-with-snapshots', $with_snapshots];
 604     my $recv = [@$ssh, '--', 'pvesm', 'import', $target_volid, $format, $import_fn, '-with-snapshots', $with_snapshots];
 605     if (defined($snapshot)) {
 606         push @$send, '-snapshot', $snapshot
 607     }
 608     if ($migration_snapshot) {
 609         push @$recv, '-delete-snapshot', $snapshot;
 610     }
 611
 612     if (defined($base_snapshot)) {
 613         # Check if the snapshot exists on the remote side:
 614         push @$send, '-base', $base_snapshot;
 615         push @$recv, '-base', $base_snapshot;
 616     }
 617
 618     volume_snapshot($cfg, $volid, $snapshot) if $migration_snapshot;
 619     eval {
 620         if ($insecure) {
 621             open(my $info, '-|', @$recv)
 622                 or die "receive command failed: $!\n";
 623             my ($ip) = <$info> =~ /^($PVE::Tools::IPRE)$/ or die "no tunnel IP received\n";
 624             my ($port) = <$info> =~ /^(\d+)$/ or die "no tunnel port received\n";
 625             my $socket = IO::Socket::IP->new(PeerHost => $ip, PeerPort => $port, Type => SOCK_STREAM)
 626                 or die "failed to connect to tunnel at $ip:$port\n";
 627             # we won't be reading from the socket
 628             shutdown($socket, 0);
 629             run_command([$send, @cstream], output => '>&'.fileno($socket));
 630             # don't close the connection entirely otherwise the receiving end
 631             # might not get all buffered data (and fails with 'connection reset by peer')
 632             shutdown($socket, 1);
 633             1 while <$info>; # wait for the remote process to finish
 634             # now close the socket
 635             close($socket);
 636             if (!close($info)) { # does waitpid()
 637                 die "import failed: $!\n" if $!;
 638                 die "import failed: exit code ".($?>>8)."\n";
 639             }
 640         } else {
 641             run_command([$send, @cstream, $recv], logfunc => $logfunc);
 642         }
 643     };
 644     my $err = $@;
 645     warn "send/receive failed, cleaning up snapshot(s)..\n" if $err;
 646     if ($migration_snapshot) {
 647         eval { volume_snapshot_delete($cfg, $volid, $snapshot, 0) };
 648         warn "could not remove source snapshot: $@\n" if $@;
 649     }
 650     die $err if $err;
 651 }
 652
 653 sub vdisk_clone {
 654     my ($cfg, $volid, $vmid, $snap) = @_;
 655
 656     my ($storeid, $volname) = parse_volume_id($volid);
 657
 658     my $scfg = storage_config($cfg, $storeid);
 659
 660     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 661
 662     activate_storage($cfg, $storeid);
 663
 664     # lock shared storage
 665     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 666         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 667         return "$storeid:$volname";
 668     });
 669 }
 670
 671 sub vdisk_create_base {
 672     my ($cfg, $volid) = @_;
 673
 674     my ($storeid, $volname) = parse_volume_id($volid);
 675
 676     my $scfg = storage_config($cfg, $storeid);
 677
 678     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 679
 680     activate_storage($cfg, $storeid);
 681
 682     # lock shared storage
 683     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 684         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 685         return "$storeid:$volname";
 686     });
 687 }
 688
 689 sub map_volume {
 690     my ($cfg, $volid, $snapname) = @_;
 691
 692     my ($storeid, $volname) = parse_volume_id($volid);
 693
 694     my $scfg = storage_config($cfg, $storeid);
 695
 696     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 697
 698     return $plugin->map_volume($storeid, $scfg, $volname, $snapname);
 699 }
 700
 701 sub unmap_volume {
 702     my ($cfg, $volid, $snapname) = @_;
 703
 704     my ($storeid, $volname) = parse_volume_id($volid);
 705
 706     my $scfg = storage_config($cfg, $storeid);
 707
 708     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 709
 710     return $plugin->unmap_volume($storeid, $scfg, $volname, $snapname);
 711 }
 712
 713 sub vdisk_alloc {
 714     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 715
 716     die "no storage ID specified\n" if !$storeid;
 717
 718     PVE::JSONSchema::parse_storage_id($storeid);
 719
 720     my $scfg = storage_config($cfg, $storeid);
 721
 722     die "no VMID specified\n" if !$vmid;
 723
 724     $vmid = parse_vmid($vmid);
 725
 726     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 727
 728     $fmt = $defformat if !$fmt;
 729
 730     activate_storage($cfg, $storeid);
 731
 732     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 733
 734     # lock shared storage
 735     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 736         my $old_umask = umask(umask|0037);
 737         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 738         my $err = $@;
 739         umask $old_umask;
 740         die $err if $err;
 741         return "$storeid:$volname";
 742     });
 743 }
 744
 745 sub vdisk_free {
 746     my ($cfg, $volid) = @_;
 747
 748     my ($storeid, $volname) = parse_volume_id($volid);
 749     my $scfg = storage_config($cfg, $storeid);
 750     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 751
 752     activate_storage($cfg, $storeid);
 753
 754     my $cleanup_worker;
 755
 756     # lock shared storage
 757     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 758         # LVM-thin allows deletion of still referenced base volumes!
 759         die "base volume '$volname' is still in use by linked clones\n"
 760             if &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 761
 762         my (undef, undef, undef, undef, undef, $isBase, $format) =
 763             $plugin->parse_volname($volname);
 764         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 765     });
 766
 767     return if !$cleanup_worker;
 768
 769     my $rpcenv = PVE::RPCEnvironment::get();
 770     my $authuser = $rpcenv->get_user();
 771
 772     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 773 }
 774
 775 sub vdisk_list {
 776     my ($cfg, $storeid, $vmid, $vollist) = @_;
 777
 778     my $ids = $cfg->{ids};
 779
 780     storage_check_enabled($cfg, $storeid) if ($storeid);
 781
 782     my $res = {};
 783
 784     # prepare/activate/refresh all storages
 785
 786     my $storage_list = [];
 787     if ($vollist) {
 788         foreach my $volid (@$vollist) {
 789             my ($sid, undef) = parse_volume_id($volid);
 790             next if !defined($ids->{$sid});
 791             next if !storage_check_enabled($cfg, $sid, undef, 1);
 792             push @$storage_list, $sid;
 793         }
 794     } else {
 795         foreach my $sid (keys %$ids) {
 796             next if $storeid && $storeid ne $sid;
 797             next if !storage_check_enabled($cfg, $sid, undef, 1);
 798             push @$storage_list, $sid;
 799         }
 800     }
 801
 802     my $cache = {};
 803
 804     activate_storage_list($cfg, $storage_list, $cache);
 805
 806     foreach my $sid (keys %$ids) {
 807         next if $storeid && $storeid ne $sid;
 808         next if !storage_check_enabled($cfg, $sid, undef, 1);
 809
 810         my $scfg = $ids->{$sid};
 811         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 812         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 813         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 814     }
 815
 816     return $res;
 817 }
 818
 819 sub template_list {
 820     my ($cfg, $storeid, $tt) = @_;
 821
 822     die "unknown template type '$tt'\n"
 823         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup' || $tt eq 'snippets');
 824
 825     my $ids = $cfg->{ids};
 826
 827     storage_check_enabled($cfg, $storeid) if ($storeid);
 828
 829     my $res = {};
 830
 831     # query the storage
 832     foreach my $sid (keys %$ids) {
 833         next if $storeid && $storeid ne $sid;
 834
 835         my $scfg = $ids->{$sid};
 836         my $type = $scfg->{type};
 837
 838         next if !$scfg->{content}->{$tt};
 839
 840         next if !storage_check_enabled($cfg, $sid, undef, 1);
 841
 842         $res->{$sid} = volume_list($cfg, $sid, undef, $tt);
 843     }
 844
 845     return $res;
 846 }
 847
 848 sub volume_list {
 849     my ($cfg, $storeid, $vmid, $content) = @_;
 850
 851     my @ctypes = qw(rootdir images vztmpl iso backup snippets);
 852
 853     my $cts = $content ? [ $content ] : [ @ctypes ];
 854
 855     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 856
 857     $cts = [ grep { defined($scfg->{content}->{$_}) } @$cts ];
 858
 859     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 860
 861     activate_storage($cfg, $storeid);
 862
 863     my $res = $plugin->list_volumes($storeid, $scfg, $vmid, $cts);
 864
 865     @$res = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @$res;
 866
 867     return $res;
 868 }
 869
 870 sub uevent_seqnum {
 871
 872     my $filename = "/sys/kernel/uevent_seqnum";
 873
 874     my $seqnum = 0;
 875     if (my $fh = IO::File->new($filename, "r")) {
 876         my $line = <$fh>;
 877         if ($line =~ m/^(\d+)$/) {
 878             $seqnum = int($1);
 879         }
 880         close ($fh);
 881     }
 882     return $seqnum;
 883 }
 884
 885 sub activate_storage {
 886     my ($cfg, $storeid, $cache) = @_;
 887
 888     $cache = {} if !$cache;
 889
 890     my $scfg = storage_check_enabled($cfg, $storeid);
 891
 892     return if $cache->{activated}->{$storeid};
 893
 894     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 895
 896     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 897
 898     if ($scfg->{base}) {
 899         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 900         activate_storage($cfg, $baseid, $cache);
 901     }
 902
 903     if (!$plugin->check_connection($storeid, $scfg)) {
 904         die "storage '$storeid' is not online\n";
 905     }
 906
 907     $plugin->activate_storage($storeid, $scfg, $cache);
 908
 909     my $newseq = uevent_seqnum ();
 910
 911     # only call udevsettle if there are events
 912     if ($newseq > $cache->{uevent_seqnum}) {
 913         my $timeout = 30;
 914         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
 915         $cache->{uevent_seqnum} = $newseq;
 916     }
 917
 918     $cache->{activated}->{$storeid} = 1;
 919 }
 920
 921 sub activate_storage_list {
 922     my ($cfg, $storeid_list, $cache) = @_;
 923
 924     $cache = {} if !$cache;
 925
 926     foreach my $storeid (@$storeid_list) {
 927         activate_storage($cfg, $storeid, $cache);
 928     }
 929 }
 930
 931 sub deactivate_storage {
 932     my ($cfg, $storeid) = @_;
 933
 934     my $scfg = storage_config ($cfg, $storeid);
 935     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 936
 937     my $cache = {};
 938     $plugin->deactivate_storage($storeid, $scfg, $cache);
 939 }
 940
 941 sub activate_volumes {
 942     my ($cfg, $vollist, $snapname) = @_;
 943
 944     return if !($vollist && scalar(@$vollist));
 945
 946     my $storagehash = {};
 947     foreach my $volid (@$vollist) {
 948         my ($storeid, undef) = parse_volume_id($volid);
 949         $storagehash->{$storeid} = 1;
 950     }
 951
 952     my $cache = {};
 953
 954     activate_storage_list($cfg, [keys %$storagehash], $cache);
 955
 956     foreach my $volid (@$vollist) {
 957         my ($storeid, $volname) = parse_volume_id($volid);
 958         my $scfg = storage_config($cfg, $storeid);
 959         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 960         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
 961     }
 962 }
 963
 964 sub deactivate_volumes {
 965     my ($cfg, $vollist, $snapname) = @_;
 966
 967     return if !($vollist && scalar(@$vollist));
 968
 969     my $cache = {};
 970
 971     my @errlist = ();
 972     foreach my $volid (@$vollist) {
 973         my ($storeid, $volname) = parse_volume_id($volid);
 974
 975         my $scfg = storage_config($cfg, $storeid);
 976         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 977
 978         eval {
 979             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
 980         };
 981         if (my $err = $@) {
 982             warn $err;
 983             push @errlist, $volid;
 984         }
 985     }
 986
 987     die "volume deactivation failed: " . join(' ', @errlist)
 988         if scalar(@errlist);
 989 }
 990
 991 sub storage_info {
 992     my ($cfg, $content, $includeformat) = @_;
 993
 994     my $ids = $cfg->{ids};
 995
 996     my $info = {};
 997
 998     my @ctypes = PVE::Tools::split_list($content);
 999
1000     my $slist = [];
1001     foreach my $storeid (keys %$ids) {
1002         my $storage_enabled = defined(storage_check_enabled($cfg, $storeid, undef, 1));
1003
1004         if (defined($content)) {
1005             my $want_ctype = 0;
1006             foreach my $ctype (@ctypes) {
1007                 if ($ids->{$storeid}->{content}->{$ctype}) {
1008                     $want_ctype = 1;
1009                     last;
1010                 }
1011             }
1012             next if !$want_ctype || !$storage_enabled;
1013         }
1014
1015         my $type = $ids->{$storeid}->{type};
1016
1017         $info->{$storeid} = {
1018             type => $type,
1019             total => 0,
1020             avail => 0,
1021             used => 0,
1022             shared => $ids->{$storeid}->{shared} ? 1 : 0,
1023             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
1024             active => 0,
1025             enabled => $storage_enabled ? 1 : 0,
1026         };
1027
1028         push @$slist, $storeid;
1029     }
1030
1031     my $cache = {};
1032
1033     foreach my $storeid (keys %$ids) {
1034         my $scfg = $ids->{$storeid};
1035
1036         next if !$info->{$storeid};
1037         next if !$info->{$storeid}->{enabled};
1038
1039         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1040         if ($includeformat) {
1041             my $pd = $plugin->plugindata();
1042             $info->{$storeid}->{format} = $pd->{format}
1043                 if $pd->{format};
1044             $info->{$storeid}->{select_existing} = $pd->{select_existing}
1045                 if $pd->{select_existing};
1046         }
1047
1048         eval { activate_storage($cfg, $storeid, $cache); };
1049         if (my $err = $@) {
1050             warn $err;
1051             next;
1052         }
1053
1054         my ($total, $avail, $used, $active) = eval { $plugin->status($storeid, $scfg, $cache); };
1055         warn $@ if $@;
1056         next if !$active;
1057         $info->{$storeid}->{total} = int($total);
1058         $info->{$storeid}->{avail} = int($avail);
1059         $info->{$storeid}->{used} = int($used);
1060         $info->{$storeid}->{active} = $active;
1061     }
1062
1063     return $info;
1064 }
1065
1066 sub resolv_server {
1067     my ($server) = @_;
1068
1069     my ($packed_ip, $family);
1070     eval {
1071         my @res = PVE::Tools::getaddrinfo_all($server);
1072         $family = $res[0]->{family};
1073         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1074     };
1075     if (defined $packed_ip) {
1076         return Socket::inet_ntop($family, $packed_ip);
1077     }
1078     return undef;
1079 }
1080
1081 sub scan_nfs {
1082     my ($server_in) = @_;
1083
1084     my $server;
1085     if (!($server = resolv_server ($server_in))) {
1086         die "unable to resolve address for server '${server_in}'\n";
1087     }
1088
1089     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1090
1091     my $res = {};
1092     run_command($cmd, outfunc => sub {
1093         my $line = shift;
1094
1095         # note: howto handle white spaces in export path??
1096         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1097             $res->{$1} = $2;
1098         }
1099     });
1100
1101     return $res;
1102 }
1103
1104 sub scan_cifs {
1105     my ($server_in, $user, $password, $domain) = @_;
1106
1107     my $server;
1108     if (!($server = resolv_server ($server_in))) {
1109         die "unable to resolve address for server '${server_in}'\n";
1110     }
1111
1112     # we support only Windows grater than 2012 cifsscan so use smb3
1113     my $cmd = ['/usr/bin/smbclient', '-m', 'smb3', '-d', '0', '-L', $server];
1114     if (defined($user)) {
1115         die "password is required" if !defined($password);
1116         push @$cmd, '-U', "$user\%$password";
1117         push @$cmd, '-W', $domain if defined($domain);
1118     } else {
1119         push @$cmd, '-N';
1120     }
1121
1122     my $res = {};
1123     run_command($cmd,
1124                 outfunc => sub {
1125                     my $line = shift;
1126                     if ($line =~ m/(\S+)\s*Disk\s*(\S*)/) {
1127                         $res->{$1} = $2;
1128                     } elsif ($line =~ m/(NT_STATUS_(\S*))/) {
1129                         $res->{$1} = '';
1130                     }
1131                 },
1132                 errfunc => sub {},
1133                 noerr => 1
1134     );
1135
1136     return $res;
1137 }
1138
1139 sub scan_zfs {
1140
1141     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-H', '-o', 'name,avail,used'];
1142
1143     my $res = [];
1144     run_command($cmd, outfunc => sub {
1145         my $line = shift;
1146
1147         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1148             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1149             my $size = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($size_str);
1150             my $used = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($used_str);
1151             # ignore subvolumes generated by our ZFSPoolPlugin
1152             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1153             return if $pool =~ m!/basevol-\d+-[^/]+$!;
1154             push @$res, { pool => $pool, size => $size, free => $size-$used };
1155         }
1156     });
1157
1158     return $res;
1159 }
1160
1161 sub resolv_portal {
1162     my ($portal, $noerr) = @_;
1163
1164     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1165     if ($server) {
1166         if (my $ip = resolv_server($server)) {
1167             $server = $ip;
1168             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1169             return $port ? "$server:$port" : $server;
1170         }
1171     }
1172     return undef if $noerr;
1173
1174     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1175 }
1176
1177
1178 sub scan_iscsi {
1179     my ($portal_in) = @_;
1180
1181     my $portal;
1182     if (!($portal = resolv_portal($portal_in))) {
1183         die "unable to parse/resolve portal address '${portal_in}'\n";
1184     }
1185
1186     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1187 }
1188
1189 sub storage_default_format {
1190     my ($cfg, $storeid) = @_;
1191
1192     my $scfg = storage_config ($cfg, $storeid);
1193
1194     return PVE::Storage::Plugin::default_format($scfg);
1195 }
1196
1197 sub vgroup_is_used {
1198     my ($cfg, $vgname) = @_;
1199
1200     foreach my $storeid (keys %{$cfg->{ids}}) {
1201         my $scfg = storage_config($cfg, $storeid);
1202         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1203             return 1;
1204         }
1205     }
1206
1207     return undef;
1208 }
1209
1210 sub target_is_used {
1211     my ($cfg, $target) = @_;
1212
1213     foreach my $storeid (keys %{$cfg->{ids}}) {
1214         my $scfg = storage_config($cfg, $storeid);
1215         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1216             return 1;
1217         }
1218     }
1219
1220     return undef;
1221 }
1222
1223 sub volume_is_used {
1224     my ($cfg, $volid) = @_;
1225
1226     foreach my $storeid (keys %{$cfg->{ids}}) {
1227         my $scfg = storage_config($cfg, $storeid);
1228         if ($scfg->{base} && $scfg->{base} eq $volid) {
1229             return 1;
1230         }
1231     }
1232
1233     return undef;
1234 }
1235
1236 sub storage_is_used {
1237     my ($cfg, $storeid) = @_;
1238
1239     foreach my $sid (keys %{$cfg->{ids}}) {
1240         my $scfg = storage_config($cfg, $sid);
1241         next if !$scfg->{base};
1242         my ($st) = parse_volume_id($scfg->{base});
1243         return 1 if $st && $st eq $storeid;
1244     }
1245
1246     return undef;
1247 }
1248
1249 sub foreach_volid {
1250     my ($list, $func) = @_;
1251
1252     return if !$list;
1253
1254     foreach my $sid (keys %$list) {
1255        foreach my $info (@{$list->{$sid}}) {
1256            my $volid = $info->{volid};
1257            my ($sid1, $volname) = parse_volume_id($volid, 1);
1258            if ($sid1 && $sid1 eq $sid) {
1259                &$func ($volid, $sid, $info);
1260            } else {
1261                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1262            }
1263        }
1264     }
1265 }
1266
1267 sub extract_vzdump_config_tar {
1268     my ($archive, $conf_re) = @_;
1269
1270     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
1271
1272     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
1273        die "unable to open file '$archive'\n";
1274
1275     my $file;
1276     while (defined($file = <$fh>)) {
1277         if ($file =~ $conf_re) {
1278             $file = $1; # untaint
1279             last;
1280         }
1281     }
1282
1283     kill 15, $pid;
1284     waitpid $pid, 0;
1285     close $fh;
1286
1287     die "ERROR: archive contains no configuration file\n" if !$file;
1288     chomp $file;
1289
1290     my $raw = '';
1291     my $out = sub {
1292         my $output = shift;
1293         $raw .= "$output\n";
1294     };
1295
1296     PVE::Tools::run_command(['tar', '-xpOf', $archive, $file, '--occurrence'], outfunc => $out);
1297
1298     return wantarray ? ($raw, $file) : $raw;
1299 }
1300
1301 sub extract_vzdump_config_vma {
1302     my ($archive, $comp) = @_;
1303
1304     my $cmd;
1305     my $raw = '';
1306     my $out = sub {
1307         my $output = shift;
1308         $raw .= "$output\n";
1309     };
1310
1311
1312     if ($comp) {
1313         my $uncomp;
1314         if ($comp eq 'gz') {
1315             $uncomp = ["zcat", $archive];
1316         } elsif ($comp eq 'lzo') {
1317             $uncomp = ["lzop", "-d", "-c", $archive];
1318         } else {
1319             die "unknown compression method '$comp'\n";
1320         }
1321         $cmd = [$uncomp, ["vma", "config", "-"]];
1322
1323         # in some cases, lzop/zcat exits with 1 when its stdout pipe is
1324         # closed early by vma, detect this and ignore the exit code later
1325         my $broken_pipe;
1326         my $errstring;
1327         my $err = sub {
1328             my $output = shift;
1329             if ($output =~ m/lzop: Broken pipe: <stdout>/ || $output =~ m/gzip: stdout: Broken pipe/) {
1330                 $broken_pipe = 1;
1331             } elsif (!defined ($errstring) && $output !~ m/^\s*$/) {
1332                 $errstring = "Failed to extract config from VMA archive: $output\n";
1333             }
1334         };
1335
1336         # in other cases, the pipeline will exit with exit code 141
1337         # because of the broken pipe, handle / ignore this as well
1338         my $rc;
1339         eval {
1340             $rc = PVE::Tools::run_command($cmd, outfunc => $out, errfunc => $err, noerr => 1);
1341         };
1342         my $rerr = $@;
1343
1344         # use exit code if no stderr output and not just broken pipe
1345         if (!$errstring && !$broken_pipe && $rc != 0 && $rc != 141) {
1346             die "$rerr\n" if $rerr;
1347             die "config extraction failed with exit code $rc\n";
1348         }
1349         die "$errstring\n" if $errstring;
1350     } else {
1351         # simple case without compression and weird piping behaviour
1352         PVE::Tools::run_command(["vma", "config", $archive], outfunc => $out);
1353     }
1354
1355     return wantarray ? ($raw, undef) : $raw;
1356 }
1357
1358 sub extract_vzdump_config {
1359     my ($cfg, $volid) = @_;
1360
1361     my $archive = abs_filesystem_path($cfg, $volid);
1362
1363     if ($volid =~ /vzdump-(lxc|openvz)-\d+-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2})\.(tgz|(tar(\.(gz|lzo))?))$/) {
1364         return extract_vzdump_config_tar($archive, qr!^(\./etc/vzdump/(pct|vps)\.conf)$!);
1365     } elsif ($volid =~ /vzdump-qemu-\d+-(\d{4})_(\d{2})_(\d{2})-(\d{2})_(\d{2})_(\d{2})\.(tgz|((tar|vma)(\.(gz|lzo))?))$/) {
1366         my $format;
1367         my $comp;
1368         if ($7 eq 'tgz') {
1369             $format = 'tar';
1370             $comp = 'gz';
1371         } else {
1372             $format = $9;
1373             $comp = $11 if defined($11);
1374         }
1375
1376         if ($format eq 'tar') {
1377             return extract_vzdump_config_tar($archive, qr!\(\./qemu-server\.conf\)!);
1378         } else {
1379             return extract_vzdump_config_vma($archive, $comp);
1380         }
1381     } else {
1382         die "cannot determine backup guest type for backup archive '$volid'\n";
1383     }
1384 }
1385
1386 sub volume_export {
1387     my ($cfg, $fh, $volid, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
1388
1389     my ($storeid, $volname) = parse_volume_id($volid, 1);
1390     die "cannot export volume '$volid'\n" if !$storeid;
1391     my $scfg = storage_config($cfg, $storeid);
1392     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1393     return $plugin->volume_export($scfg, $storeid, $fh, $volname, $format,
1394                                   $snapshot, $base_snapshot, $with_snapshots);
1395 }
1396
1397 sub volume_import {
1398     my ($cfg, $fh, $volid, $format, $base_snapshot, $with_snapshots) = @_;
1399
1400     my ($storeid, $volname) = parse_volume_id($volid, 1);
1401     die "cannot import into volume '$volid'\n" if !$storeid;
1402     my $scfg = storage_config($cfg, $storeid);
1403     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1404     return $plugin->volume_import($scfg, $storeid, $fh, $volname, $format,
1405                                   $base_snapshot, $with_snapshots);
1406 }
1407
1408 sub volume_export_formats {
1409     my ($cfg, $volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1410
1411     my ($storeid, $volname) = parse_volume_id($volid, 1);
1412     return if !$storeid;
1413     my $scfg = storage_config($cfg, $storeid);
1414     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1415     return $plugin->volume_export_formats($scfg, $storeid, $volname,
1416                                           $snapshot, $base_snapshot,
1417                                           $with_snapshots);
1418 }
1419
1420 sub volume_import_formats {
1421     my ($cfg, $volid, $base_snapshot, $with_snapshots) = @_;
1422
1423     my ($storeid, $volname) = parse_volume_id($volid, 1);
1424     return if !$storeid;
1425     my $scfg = storage_config($cfg, $storeid);
1426     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1427     return $plugin->volume_import_formats($scfg, $storeid, $volname,
1428                                           $base_snapshot, $with_snapshots);
1429 }
1430
1431 sub volume_transfer_formats {
1432     my ($cfg, $src_volid, $dst_volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1433     my @export_formats = volume_export_formats($cfg, $src_volid, $snapshot, $base_snapshot, $with_snapshots);
1434     my @import_formats = volume_import_formats($cfg, $dst_volid, $base_snapshot, $with_snapshots);
1435     my %import_hash = map { $_ => 1 } @import_formats;
1436     my @common = grep { $import_hash{$_} } @export_formats;
1437     return @common;
1438 }
1439
1440 # bash completion helper
1441
1442 sub complete_storage {
1443     my ($cmdname, $pname, $cvalue) = @_;
1444
1445     my $cfg = PVE::Storage::config();
1446
1447     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1448 }
1449
1450 sub complete_storage_enabled {
1451     my ($cmdname, $pname, $cvalue) = @_;
1452
1453     my $res = [];
1454
1455     my $cfg = PVE::Storage::config();
1456     foreach my $sid (keys %{$cfg->{ids}}) {
1457         next if !storage_check_enabled($cfg, $sid, undef, 1);
1458         push @$res, $sid;
1459     }
1460     return $res;
1461 }
1462
1463 sub complete_content_type {
1464     my ($cmdname, $pname, $cvalue) = @_;
1465
1466     return [qw(rootdir images vztmpl iso backup snippets)];
1467 }
1468
1469 sub complete_volume {
1470     my ($cmdname, $pname, $cvalue) = @_;
1471
1472     my $cfg = config();
1473
1474     my $storage_list = complete_storage_enabled();
1475
1476     if ($cvalue =~ m/^([^:]+):/) {
1477         $storage_list = [ $1 ];
1478     } else {
1479         if (scalar(@$storage_list) > 1) {
1480             # only list storage IDs to avoid large listings
1481             my $res = [];
1482             foreach my $storeid (@$storage_list) {
1483                 # Hack: simply return 2 artificial values, so that
1484                 # completions does not finish
1485                 push @$res, "$storeid:volname", "$storeid:...";
1486             }
1487             return $res;
1488         }
1489     }
1490
1491     my $res = [];
1492     foreach my $storeid (@$storage_list) {
1493         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1494
1495         foreach my $item (@$vollist) {
1496             push @$res, $item->{volid};
1497         }
1498     }
1499
1500     return $res;
1501 }
1502
1503 # Various io-heavy operations require io/bandwidth limits which can be
1504 # configured on multiple levels: The global defaults in datacenter.cfg, and
1505 # per-storage overrides. When we want to do a restore from storage A to storage
1506 # B, we should take the smaller limit defined for storages A and B, and if no
1507 # such limit was specified, use the one from datacenter.cfg.
1508 sub get_bandwidth_limit {
1509     my ($operation, $storage_list, $override) = @_;
1510
1511     # called for each limit (global, per-storage) with the 'default' and the
1512     # $operation limit and should udpate $override for every limit affecting
1513     # us.
1514     my $use_global_limits = 0;
1515     my $apply_limit = sub {
1516         my ($bwlimit) = @_;
1517         if (defined($bwlimit)) {
1518             my $limits = PVE::JSONSchema::parse_property_string('bwlimit', $bwlimit);
1519             my $limit = $limits->{$operation} // $limits->{default};
1520             if (defined($limit)) {
1521                 if (!$override || $limit < $override) {
1522                     $override = $limit;
1523                 }
1524                 return;
1525             }
1526         }
1527         # If there was no applicable limit, try to apply the global ones.
1528         $use_global_limits = 1;
1529     };
1530
1531     my ($rpcenv, $authuser);
1532     if (defined($override)) {
1533         $rpcenv = PVE::RPCEnvironment->get();
1534         $authuser = $rpcenv->get_user();
1535     }
1536
1537     # Apply per-storage limits - if there are storages involved.
1538     if (defined($storage_list) && @$storage_list) {
1539         my $config = config();
1540
1541         # The Datastore.Allocate permission allows us to modify the per-storage
1542         # limits, therefore it also allows us to override them.
1543         # Since we have most likely multiple storages to check, do a quick check on
1544         # the general '/storage' path to see if we can skip the checks entirely:
1545         return $override if $rpcenv && $rpcenv->check($authuser, '/storage', ['Datastore.Allocate'], 1);
1546
1547         my %done;
1548         foreach my $storage (@$storage_list) {
1549             next if !defined($storage);
1550             # Avoid duplicate checks:
1551             next if $done{$storage};
1552             $done{$storage} = 1;
1553
1554             # Otherwise we may still have individual /storage/$ID permissions:
1555             if (!$rpcenv || !$rpcenv->check($authuser, "/storage/$storage", ['Datastore.Allocate'], 1)) {
1556                 # And if not: apply the limits.
1557                 my $storecfg = storage_config($config, $storage);
1558                 $apply_limit->($storecfg->{bwlimit});
1559             }
1560         }
1561
1562         # Storage limits take precedence over the datacenter defaults, so if
1563         # a limit was applied:
1564         return $override if !$use_global_limits;
1565     }
1566
1567     # Sys.Modify on '/' means we can change datacenter.cfg which contains the
1568     # global default limits.
1569     if (!$rpcenv || !$rpcenv->check($authuser, '/', ['Sys.Modify'], 1)) {
1570         # So if we cannot modify global limits, apply them to our currently
1571         # requested override.
1572         my $dc = cfs_read_file('datacenter.cfg');
1573         $apply_limit->($dc->{bwlimit});
1574     }
1575
1576     return $override;
1577 }
1578
1579 # checks if the storage id is available and dies if not
1580 sub assert_sid_unused {
1581     my ($sid) = @_;
1582
1583     my $cfg = config();
1584     if (my $scfg = storage_config($cfg, $sid, 1)) {
1585         die "storage ID '$sid' already defined\n";
1586     }
1587
1588     return undef;
1589 }
1590
1591 1;