PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use File::Basename;
  11 use File::Path;
  12 use Cwd 'abs_path';
  13 use Socket;
  14
  15 use PVE::Tools qw(run_command file_read_firstline $IPV6RE);
  16 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  17 use PVE::Exception qw(raise_param_exc);
  18 use PVE::JSONSchema;
  19 use PVE::INotify;
  20 use PVE::RPCEnvironment;
  21
  22 use PVE::Storage::Plugin;
  23 use PVE::Storage::DirPlugin;
  24 use PVE::Storage::LVMPlugin;
  25 use PVE::Storage::LvmThinPlugin;
  26 use PVE::Storage::NFSPlugin;
  27 use PVE::Storage::ISCSIPlugin;
  28 use PVE::Storage::RBDPlugin;
  29 use PVE::Storage::SheepdogPlugin;
  30 use PVE::Storage::ISCSIDirectPlugin;
  31 use PVE::Storage::GlusterfsPlugin;
  32 use PVE::Storage::ZFSPoolPlugin;
  33 use PVE::Storage::ZFSPlugin;
  34 use PVE::Storage::DRBDPlugin;
  35
  36 # load and initialize all plugins
  37 PVE::Storage::DirPlugin->register();
  38 PVE::Storage::LVMPlugin->register();
  39 PVE::Storage::LvmThinPlugin->register();
  40 PVE::Storage::NFSPlugin->register();
  41 PVE::Storage::ISCSIPlugin->register();
  42 PVE::Storage::RBDPlugin->register();
  43 PVE::Storage::SheepdogPlugin->register();
  44 PVE::Storage::ISCSIDirectPlugin->register();
  45 PVE::Storage::GlusterfsPlugin->register();
  46 PVE::Storage::ZFSPoolPlugin->register();
  47 PVE::Storage::ZFSPlugin->register();
  48 PVE::Storage::DRBDPlugin->register();
  49 PVE::Storage::Plugin->init();
  50
  51 my $UDEVADM = '/sbin/udevadm';
  52
  53 #  PVE::Storage utility functions
  54
  55 sub config {
  56     return cfs_read_file("storage.cfg");
  57 }
  58
  59 sub write_config {
  60     my ($cfg) = @_;
  61
  62     cfs_write_file('storage.cfg', $cfg);
  63 }
  64
  65 sub lock_storage_config {
  66     my ($code, $errmsg) = @_;
  67
  68     cfs_lock_file("storage.cfg", undef, $code);
  69     my $err = $@;
  70     if ($err) {
  71         $errmsg ? die "$errmsg: $err" : die $err;
  72     }
  73 }
  74
  75 sub storage_config {
  76     my ($cfg, $storeid, $noerr) = @_;
  77
  78     die "no storage id specified\n" if !$storeid;
  79
  80     my $scfg = $cfg->{ids}->{$storeid};
  81
  82     die "storage '$storeid' does not exists\n" if (!$noerr && !$scfg);
  83
  84     return $scfg;
  85 }
  86
  87 sub storage_check_node {
  88     my ($cfg, $storeid, $node, $noerr) = @_;
  89
  90     my $scfg = storage_config($cfg, $storeid);
  91
  92     if ($scfg->{nodes}) {
  93         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
  94         if (!$scfg->{nodes}->{$node}) {
  95             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
  96             return undef;
  97         }
  98     }
  99
 100     return $scfg;
 101 }
 102
 103 sub storage_check_enabled {
 104     my ($cfg, $storeid, $node, $noerr) = @_;
 105
 106     my $scfg = storage_config($cfg, $storeid);
 107
 108     if ($scfg->{disable}) {
 109         die "storage '$storeid' is disabled\n" if !$noerr;
 110         return undef;
 111     }
 112
 113     return storage_check_node($cfg, $storeid, $node, $noerr);
 114 }
 115
 116 sub storage_ids {
 117     my ($cfg) = @_;
 118
 119     return keys %{$cfg->{ids}};
 120 }
 121
 122 sub file_size_info {
 123     my ($filename, $timeout) = @_;
 124
 125     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 126 }
 127
 128 sub volume_size_info {
 129     my ($cfg, $volid, $timeout) = @_;
 130
 131     my ($storeid, $volname) = parse_volume_id($volid, 1);
 132     if ($storeid) {
 133         my $scfg = storage_config($cfg, $storeid);
 134         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 135         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 136     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 137         return file_size_info($volid, $timeout);
 138     } else {
 139         return 0;
 140     }
 141 }
 142
 143 sub volume_resize {
 144     my ($cfg, $volid, $size, $running) = @_;
 145
 146     my ($storeid, $volname) = parse_volume_id($volid, 1);
 147     if ($storeid) {
 148         my $scfg = storage_config($cfg, $storeid);
 149         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 150         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 151     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 152         die "resize file/device '$volid' is not possible\n";
 153     } else {
 154         die "unable to parse volume ID '$volid'\n";
 155     }
 156 }
 157
 158 sub volume_rollback_is_possible {
 159     my ($cfg, $volid, $snap) = @_;
 160
 161     my ($storeid, $volname) = parse_volume_id($volid, 1);
 162     if ($storeid) {
 163         my $scfg = storage_config($cfg, $storeid);
 164         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 165         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 166     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 167         die "snapshot rollback file/device '$volid' is not possible\n";
 168     } else {
 169         die "unable to parse volume ID '$volid'\n";
 170     }
 171 }
 172
 173 sub volume_snapshot {
 174     my ($cfg, $volid, $snap) = @_;
 175
 176     my ($storeid, $volname) = parse_volume_id($volid, 1);
 177     if ($storeid) {
 178         my $scfg = storage_config($cfg, $storeid);
 179         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 180         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 181     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 182         die "snapshot file/device '$volid' is not possible\n";
 183     } else {
 184         die "unable to parse volume ID '$volid'\n";
 185     }
 186 }
 187
 188 sub volume_snapshot_rollback {
 189     my ($cfg, $volid, $snap) = @_;
 190
 191     my ($storeid, $volname) = parse_volume_id($volid, 1);
 192     if ($storeid) {
 193         my $scfg = storage_config($cfg, $storeid);
 194         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 195         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 196         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 197     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 198         die "snapshot rollback file/device '$volid' is not possible\n";
 199     } else {
 200         die "unable to parse volume ID '$volid'\n";
 201     }
 202 }
 203
 204 sub volume_snapshot_delete {
 205     my ($cfg, $volid, $snap, $running) = @_;
 206
 207     my ($storeid, $volname) = parse_volume_id($volid, 1);
 208     if ($storeid) {
 209         my $scfg = storage_config($cfg, $storeid);
 210         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 211         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 212     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 213         die "snapshot delete file/device '$volid' is not possible\n";
 214     } else {
 215         die "unable to parse volume ID '$volid'\n";
 216     }
 217 }
 218
 219 sub volume_has_feature {
 220     my ($cfg, $feature, $volid, $snap, $running) = @_;
 221
 222     my ($storeid, $volname) = parse_volume_id($volid, 1);
 223     if ($storeid) {
 224         my $scfg = storage_config($cfg, $storeid);
 225         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 226         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running);
 227     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 228         return undef;
 229     } else {
 230         return undef;
 231     }
 232 }
 233
 234 sub get_image_dir {
 235     my ($cfg, $storeid, $vmid) = @_;
 236
 237     my $scfg = storage_config($cfg, $storeid);
 238     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 239
 240     my $path = $plugin->get_subdir($scfg, 'images');
 241
 242     return $vmid ? "$path/$vmid" : $path;
 243 }
 244
 245 sub get_private_dir {
 246     my ($cfg, $storeid, $vmid) = @_;
 247
 248     my $scfg = storage_config($cfg, $storeid);
 249     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 250
 251     my $path = $plugin->get_subdir($scfg, 'rootdir');
 252
 253     return $vmid ? "$path/$vmid" : $path;
 254 }
 255
 256 sub get_iso_dir {
 257     my ($cfg, $storeid) = @_;
 258
 259     my $scfg = storage_config($cfg, $storeid);
 260     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 261
 262     return $plugin->get_subdir($scfg, 'iso');
 263 }
 264
 265 sub get_vztmpl_dir {
 266     my ($cfg, $storeid) = @_;
 267
 268     my $scfg = storage_config($cfg, $storeid);
 269     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 270
 271     return $plugin->get_subdir($scfg, 'vztmpl');
 272 }
 273
 274 sub get_backup_dir {
 275     my ($cfg, $storeid) = @_;
 276
 277     my $scfg = storage_config($cfg, $storeid);
 278     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 279
 280     return $plugin->get_subdir($scfg, 'backup');
 281 }
 282
 283 # library implementation
 284
 285 sub parse_vmid {
 286     my $vmid = shift;
 287
 288     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 289
 290     return int($vmid);
 291 }
 292
 293 sub parse_volname {
 294     my ($cfg, $volid) = @_;
 295
 296     my ($storeid, $volname) = parse_volume_id($volid);
 297
 298     my $scfg = storage_config($cfg, $storeid);
 299
 300     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 301
 302     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 303
 304     return $plugin->parse_volname($volname);
 305 }
 306
 307 sub parse_volume_id {
 308     my ($volid, $noerr) = @_;
 309
 310     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 311 }
 312
 313 sub volume_is_base {
 314     my ($cfg, $volid) = @_;
 315
 316     my ($sid, $volname) = parse_volume_id($volid, 1);
 317     return 0 if !$sid;
 318
 319     if (my $scfg = $cfg->{ids}->{$sid}) {
 320         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 321         my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 322             $plugin->parse_volname($volname);
 323         return $isBase ? 1 : 0;
 324     } else {
 325         # stale volid with undefined storage - so we can just guess
 326         if ($volid =~ m/base-/) {
 327             return 1;
 328         }
 329     }
 330
 331     return 0;
 332 }
 333
 334 # try to map a filesystem path to a volume identifier
 335 sub path_to_volume_id {
 336     my ($cfg, $path) = @_;
 337
 338     my $ids = $cfg->{ids};
 339
 340     my ($sid, $volname) = parse_volume_id($path, 1);
 341     if ($sid) {
 342         if (my $scfg = $ids->{$sid}) {
 343             if ($scfg->{path}) {
 344                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 345                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 346                 return ($vtype, $path);
 347             }
 348         }
 349         return ('');
 350     }
 351
 352     # Note: abs_path() return undef if $path doesn not exist
 353     # for example when nfs storage is not mounted
 354     $path = abs_path($path) || $path;
 355
 356     foreach my $sid (keys %$ids) {
 357         my $scfg = $ids->{$sid};
 358         next if !$scfg->{path};
 359         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 360         my $imagedir = $plugin->get_subdir($scfg, 'images');
 361         my $isodir = $plugin->get_subdir($scfg, 'iso');
 362         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 363         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 364         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 365
 366         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 367             my $vmid = $1;
 368             my $name = $2;
 369
 370             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 371             foreach my $info (@$vollist) {
 372                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 373                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 374                 if ($volpath eq $path) {
 375                     return ('images', $info->{volid});
 376                 }
 377             }
 378         } elsif ($path =~ m!^$isodir/([^/]+\.[Ii][Ss][Oo])$!) {
 379             my $name = $1;
 380             return ('iso', "$sid:iso/$name");
 381         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 382             my $name = $1;
 383             return ('vztmpl', "$sid:vztmpl/$name");
 384         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 385             my $vmid = $1;
 386             return ('rootdir', "$sid:rootdir/$vmid");
 387         } elsif ($path =~ m!^$backupdir/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!) {
 388             my $name = $1;
 389             return ('iso', "$sid:backup/$name");
 390         }
 391     }
 392
 393     # can't map path to volume id
 394     return ('');
 395 }
 396
 397 sub path {
 398     my ($cfg, $volid, $snapname) = @_;
 399
 400     my ($storeid, $volname) = parse_volume_id($volid);
 401
 402     my $scfg = storage_config($cfg, $storeid);
 403
 404     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 405     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 406     return wantarray ? ($path, $owner, $vtype) : $path;
 407 }
 408
 409 sub abs_filesystem_path {
 410     my ($cfg, $volid) = @_;
 411
 412     my $path;
 413     if (PVE::Storage::parse_volume_id ($volid, 1)) {
 414         PVE::Storage::activate_volumes($cfg, [ $volid ]);
 415         $path = PVE::Storage::path($cfg, $volid);
 416     } else {
 417         if (-f $volid) {
 418             my $abspath = abs_path($volid);
 419             if ($abspath && $abspath =~ m|^(/.+)$|) {
 420                 $path = $1; # untaint any path
 421             }
 422         }
 423     }
 424
 425     die "can't find file '$volid'\n" if !($path && -f $path);
 426
 427     return $path;
 428 }
 429
 430 sub storage_migrate {
 431     my ($cfg, $volid, $target_host, $target_storeid, $target_volname) = @_;
 432
 433     my ($storeid, $volname) = parse_volume_id($volid);
 434     $target_volname = $volname if !$target_volname;
 435
 436     my $scfg = storage_config($cfg, $storeid);
 437
 438     # no need to migrate shared content
 439     return if $storeid eq $target_storeid && $scfg->{shared};
 440
 441     my $tcfg = storage_config($cfg, $target_storeid);
 442
 443     my $target_volid = "${target_storeid}:${target_volname}";
 444
 445     my $errstr = "unable to migrate '$volid' to '${target_volid}' on host '$target_host'";
 446
 447     my $sshoptions = "-o 'BatchMode=yes'";
 448     my $ssh = "/usr/bin/ssh $sshoptions";
 449
 450     local $ENV{RSYNC_RSH} = $ssh;
 451
 452     # only implemented for file system based storage
 453     if ($scfg->{path}) {
 454         if ($tcfg->{path}) {
 455
 456             my $src_plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 457             my $dst_plugin = PVE::Storage::Plugin->lookup($tcfg->{type});
 458             my $src = $src_plugin->path($scfg, $volname, $storeid);
 459             my $dst = $dst_plugin->path($tcfg, $target_volname, $target_storeid);
 460
 461             my $dirname = dirname($dst);
 462
 463             if ($tcfg->{shared}) { # we can do a local copy
 464
 465                 run_command(['/bin/mkdir', '-p', $dirname]);
 466
 467                 run_command(['/bin/cp', $src, $dst]);
 468
 469             } else {
 470                 run_command(['/usr/bin/ssh', "root\@${target_host}",
 471                              '/bin/mkdir', '-p', $dirname]);
 472
 473                 # we use rsync with --sparse, so we can't use --inplace,
 474                 # so we remove file on the target if it already exists to
 475                 # save space
 476                 my ($size, $format) = PVE::Storage::Plugin::file_size_info($src);
 477                 if ($format && ($format eq 'raw') && $size) {
 478                     run_command(['/usr/bin/ssh', "root\@${target_host}",
 479                                  'rm', '-f', $dst],
 480                                 outfunc => sub {});
 481                 }
 482
 483                 my $cmd;
 484                 if ($format eq 'subvol') {
 485                     $cmd = ['/usr/bin/rsync', '--progress', '-X', '-A', '--numeric-ids',
 486                             '-aH', '--delete', '--no-whole-file', '--inplace',
 487                             '--one-file-system', "$src/", "[root\@${target_host}]:$dst"];
 488                 } else {
 489                     $cmd = ['/usr/bin/rsync', '--progress', '--sparse', '--whole-file',
 490                             $src, "[root\@${target_host}]:$dst"];
 491                 }
 492
 493                 my $percent = -1;
 494
 495                 run_command($cmd, outfunc => sub {
 496                     my $line = shift;
 497
 498                     if ($line =~ m/^\s*(\d+\s+(\d+)%\s.*)$/) {
 499                         if ($2 > $percent) {
 500                             $percent = $2;
 501                             print "rsync status: $1\n";
 502                             *STDOUT->flush();
 503                         }
 504                     } else {
 505                         print "$line\n";
 506                         *STDOUT->flush();
 507                     }
 508                 });
 509             }
 510         } else {
 511             die "$errstr - target type '$tcfg->{type}' not implemented\n";
 512         }
 513
 514     } elsif ($scfg->{type} eq 'zfspool') {
 515
 516         if ($tcfg->{type} eq 'zfspool') {
 517
 518             die "$errstr - pool on target has not same name as source!"
 519                 if $tcfg->{pool} ne $scfg->{pool};
 520
 521             my (undef, $volname) = parse_volname($cfg, $volid);
 522
 523             my $zfspath = "$scfg->{pool}\/$volname";
 524
 525             my $snap = ['zfs', 'snapshot', "$zfspath\@__migration__"];
 526
 527             my $send = [['zfs', 'send', '-Rpv', "$zfspath\@__migration__"], ['ssh', "root\@$target_host",
 528                         'zfs', 'recv', $zfspath]];
 529
 530             my $destroy_target = ['ssh', "root\@$target_host", 'zfs', 'destroy', "$zfspath\@__migration__"];
 531             run_command($snap);
 532             eval{
 533                 run_command($send);
 534             };
 535             my $err;
 536             if ($err = $@){
 537                 run_command(['zfs', 'destroy', "$zfspath\@__migration__"]);
 538                 die $err;
 539             }
 540             run_command($destroy_target);
 541
 542         } else {
 543             die "$errstr - target type $tcfg->{type} is not valid\n";
 544         }
 545     } else {
 546         die "$errstr - source type '$scfg->{type}' not implemented\n";
 547     }
 548 }
 549
 550 sub vdisk_clone {
 551     my ($cfg, $volid, $vmid, $snap) = @_;
 552
 553     my ($storeid, $volname) = parse_volume_id($volid);
 554
 555     my $scfg = storage_config($cfg, $storeid);
 556
 557     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 558
 559     activate_storage($cfg, $storeid);
 560
 561     # lock shared storage
 562     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 563         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 564         return "$storeid:$volname";
 565     });
 566 }
 567
 568 sub vdisk_create_base {
 569     my ($cfg, $volid) = @_;
 570
 571     my ($storeid, $volname) = parse_volume_id($volid);
 572
 573     my $scfg = storage_config($cfg, $storeid);
 574
 575     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 576
 577     activate_storage($cfg, $storeid);
 578
 579     # lock shared storage
 580     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 581         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 582         return "$storeid:$volname";
 583     });
 584 }
 585
 586 sub vdisk_alloc {
 587     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 588
 589     die "no storage id specified\n" if !$storeid;
 590
 591     PVE::JSONSchema::parse_storage_id($storeid);
 592
 593     my $scfg = storage_config($cfg, $storeid);
 594
 595     die "no VMID specified\n" if !$vmid;
 596
 597     $vmid = parse_vmid($vmid);
 598
 599     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 600
 601     $fmt = $defformat if !$fmt;
 602
 603     activate_storage($cfg, $storeid);
 604
 605     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 606
 607     # lock shared storage
 608     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 609         my $old_umask = umask(umask|0037);
 610         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 611         my $err = $@;
 612         umask $old_umask;
 613         die $err if $err;
 614         return "$storeid:$volname";
 615     });
 616 }
 617
 618 sub vdisk_free {
 619     my ($cfg, $volid) = @_;
 620
 621     my ($storeid, $volname) = parse_volume_id($volid);
 622
 623     my $scfg = storage_config($cfg, $storeid);
 624
 625     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 626
 627     activate_storage($cfg, $storeid);
 628
 629     my $cleanup_worker;
 630
 631     # lock shared storage
 632     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 633
 634         my ($vtype, $name, $vmid, undef, undef, $isBase, $format) =
 635             $plugin->parse_volname($volname);
 636         if ($isBase) {
 637             my $vollist = $plugin->list_images($storeid, $scfg);
 638             foreach my $info (@$vollist) {
 639                 my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 640                 my $basename = undef;
 641                 my $basevmid = undef;
 642
 643                 eval{
 644                     (undef, undef, undef, $basename, $basevmid) =
 645                         $plugin->parse_volname($tmpvolname);
 646                 };
 647
 648                 if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 649                     die "base volume '$volname' is still in use " .
 650                         "(use by '$tmpvolname')\n";
 651                 }
 652             }
 653         }
 654         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 655     });
 656
 657     return if !$cleanup_worker;
 658
 659     my $rpcenv = PVE::RPCEnvironment::get();
 660     my $authuser = $rpcenv->get_user();
 661
 662     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 663 }
 664
 665 #list iso or openvz template ($tt = <iso|vztmpl|backup>)
 666 sub template_list {
 667     my ($cfg, $storeid, $tt) = @_;
 668
 669     die "unknown template type '$tt'\n"
 670         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup');
 671
 672     my $ids = $cfg->{ids};
 673
 674     storage_check_enabled($cfg, $storeid) if ($storeid);
 675
 676     my $res = {};
 677
 678     # query the storage
 679
 680     foreach my $sid (keys %$ids) {
 681         next if $storeid && $storeid ne $sid;
 682
 683         my $scfg = $ids->{$sid};
 684         my $type = $scfg->{type};
 685
 686         next if !storage_check_enabled($cfg, $sid, undef, 1);
 687
 688         next if $tt eq 'iso' && !$scfg->{content}->{iso};
 689         next if $tt eq 'vztmpl' && !$scfg->{content}->{vztmpl};
 690         next if $tt eq 'backup' && !$scfg->{content}->{backup};
 691
 692         activate_storage($cfg, $sid);
 693
 694         if ($scfg->{path}) {
 695             my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 696
 697             my $path = $plugin->get_subdir($scfg, $tt);
 698
 699             foreach my $fn (<$path/*>) {
 700
 701                 my $info;
 702
 703                 if ($tt eq 'iso') {
 704                     next if $fn !~ m!/([^/]+\.[Ii][Ss][Oo])$!;
 705
 706                     $info = { volid => "$sid:iso/$1", format => 'iso' };
 707
 708                 } elsif ($tt eq 'vztmpl') {
 709                     next if $fn !~ m!/([^/]+\.tar\.([gx]z))$!;
 710
 711                     $info = { volid => "$sid:vztmpl/$1", format => "t$2" };
 712
 713                 } elsif ($tt eq 'backup') {
 714                     next if $fn !~ m!/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!;
 715
 716                     $info = { volid => "$sid:backup/$1", format => $2 };
 717                 }
 718
 719                 $info->{size} = -s $fn;
 720
 721                 push @{$res->{$sid}}, $info;
 722             }
 723
 724         }
 725
 726         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 727     }
 728
 729     return $res;
 730 }
 731
 732
 733 sub vdisk_list {
 734     my ($cfg, $storeid, $vmid, $vollist) = @_;
 735
 736     my $ids = $cfg->{ids};
 737
 738     storage_check_enabled($cfg, $storeid) if ($storeid);
 739
 740     my $res = {};
 741
 742     # prepare/activate/refresh all storages
 743
 744     my $storage_list = [];
 745     if ($vollist) {
 746         foreach my $volid (@$vollist) {
 747             my ($sid, undef) = parse_volume_id($volid);
 748             next if !defined($ids->{$sid});
 749             next if !storage_check_enabled($cfg, $sid, undef, 1);
 750             push @$storage_list, $sid;
 751         }
 752     } else {
 753         foreach my $sid (keys %$ids) {
 754             next if $storeid && $storeid ne $sid;
 755             next if !storage_check_enabled($cfg, $sid, undef, 1);
 756             push @$storage_list, $sid;
 757         }
 758     }
 759
 760     my $cache = {};
 761
 762     activate_storage_list($cfg, $storage_list, $cache);
 763
 764     foreach my $sid (keys %$ids) {
 765         next if $storeid && $storeid ne $sid;
 766         next if !storage_check_enabled($cfg, $sid, undef, 1);
 767
 768         my $scfg = $ids->{$sid};
 769         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 770         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 771         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 772     }
 773
 774     return $res;
 775 }
 776
 777 sub volume_list {
 778     my ($cfg, $storeid, $vmid, $content) = @_;
 779
 780     my @ctypes = qw(images vztmpl iso backup);
 781
 782     my $cts = $content ? [ $content ] : [ @ctypes ];
 783
 784     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 785
 786     my $res = [];
 787     foreach my $ct (@$cts) {
 788         my $data;
 789         if ($ct eq 'images') {
 790             $data = vdisk_list($cfg, $storeid, $vmid);
 791         } elsif ($ct eq 'iso' && !defined($vmid)) {
 792             $data = template_list($cfg, $storeid, 'iso');
 793         } elsif ($ct eq 'vztmpl'&& !defined($vmid)) {
 794             $data = template_list ($cfg, $storeid, 'vztmpl');
 795         } elsif ($ct eq 'backup') {
 796             $data = template_list ($cfg, $storeid, 'backup');
 797             foreach my $item (@{$data->{$storeid}}) {
 798                 if (defined($vmid)) {
 799                     @{$data->{$storeid}} = grep { $_->{volid} =~ m/\S+-$vmid-\S+/ } @{$data->{$storeid}};
 800                 }
 801             }
 802         }
 803
 804         next if !$data || !$data->{$storeid};
 805
 806         foreach my $item (@{$data->{$storeid}}) {
 807             $item->{content} = $ct;
 808             push @$res, $item;
 809         }
 810     }
 811
 812     return $res;
 813 }
 814
 815 sub uevent_seqnum {
 816
 817     my $filename = "/sys/kernel/uevent_seqnum";
 818
 819     my $seqnum = 0;
 820     if (my $fh = IO::File->new($filename, "r")) {
 821         my $line = <$fh>;
 822         if ($line =~ m/^(\d+)$/) {
 823             $seqnum = int($1);
 824         }
 825         close ($fh);
 826     }
 827     return $seqnum;
 828 }
 829
 830 sub activate_storage {
 831     my ($cfg, $storeid, $cache) = @_;
 832
 833     $cache = {} if !$cache;
 834
 835     my $scfg = storage_check_enabled($cfg, $storeid);
 836
 837     return if $cache->{activated}->{$storeid};
 838
 839     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 840
 841     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 842
 843     if ($scfg->{base}) {
 844         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 845         activate_storage($cfg, $baseid, $cache);
 846     }
 847
 848     if (!$plugin->check_connection($storeid, $scfg)) {
 849         die "storage '$storeid' is not online\n";
 850     }
 851
 852     $plugin->activate_storage($storeid, $scfg, $cache);
 853
 854     my $newseq = uevent_seqnum ();
 855
 856     # only call udevsettle if there are events
 857     if ($newseq > $cache->{uevent_seqnum}) {
 858         my $timeout = 30;
 859         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
 860         $cache->{uevent_seqnum} = $newseq;
 861     }
 862
 863     $cache->{activated}->{$storeid} = 1;
 864 }
 865
 866 sub activate_storage_list {
 867     my ($cfg, $storeid_list, $cache) = @_;
 868
 869     $cache = {} if !$cache;
 870
 871     foreach my $storeid (@$storeid_list) {
 872         activate_storage($cfg, $storeid, $cache);
 873     }
 874 }
 875
 876 sub deactivate_storage {
 877     my ($cfg, $storeid) = @_;
 878
 879     my $scfg = storage_config ($cfg, $storeid);
 880     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 881
 882     my $cache = {};
 883     $plugin->deactivate_storage($storeid, $scfg, $cache);
 884 }
 885
 886 sub activate_volumes {
 887     my ($cfg, $vollist, $snapname) = @_;
 888
 889     return if !($vollist && scalar(@$vollist));
 890
 891     my $storagehash = {};
 892     foreach my $volid (@$vollist) {
 893         my ($storeid, undef) = parse_volume_id($volid);
 894         $storagehash->{$storeid} = 1;
 895     }
 896
 897     my $cache = {};
 898
 899     activate_storage_list($cfg, [keys %$storagehash], $cache);
 900
 901     foreach my $volid (@$vollist) {
 902         my ($storeid, $volname) = parse_volume_id($volid);
 903         my $scfg = storage_config($cfg, $storeid);
 904         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 905         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
 906     }
 907 }
 908
 909 sub deactivate_volumes {
 910     my ($cfg, $vollist, $snapname) = @_;
 911
 912     return if !($vollist && scalar(@$vollist));
 913
 914     my $cache = {};
 915
 916     my @errlist = ();
 917     foreach my $volid (@$vollist) {
 918         my ($storeid, $volname) = parse_volume_id($volid);
 919
 920         my $scfg = storage_config($cfg, $storeid);
 921         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 922
 923         eval {
 924             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
 925         };
 926         if (my $err = $@) {
 927             warn $err;
 928             push @errlist, $volid;
 929         }
 930     }
 931
 932     die "volume deativation failed: " . join(' ', @errlist)
 933         if scalar(@errlist);
 934 }
 935
 936 sub storage_info {
 937     my ($cfg, $content) = @_;
 938
 939     my $ids = $cfg->{ids};
 940
 941     my $info = {};
 942
 943     my @ctypes = PVE::Tools::split_list($content);
 944
 945     my $slist = [];
 946     foreach my $storeid (keys %$ids) {
 947
 948         next if !storage_check_enabled($cfg, $storeid, undef, 1);
 949
 950         if (defined($content)) {
 951             my $want_ctype = 0;
 952             foreach my $ctype (@ctypes) {
 953                 if ($ids->{$storeid}->{content}->{$ctype}) {
 954                     $want_ctype = 1;
 955                     last;
 956                 }
 957             }
 958             next if !$want_ctype;
 959         }
 960
 961         my $type = $ids->{$storeid}->{type};
 962
 963         $info->{$storeid} = {
 964             type => $type,
 965             total => 0,
 966             avail => 0,
 967             used => 0,
 968             shared => $ids->{$storeid}->{shared} ? 1 : 0,
 969             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
 970             active => 0,
 971         };
 972
 973         push @$slist, $storeid;
 974     }
 975
 976     my $cache = {};
 977
 978     foreach my $storeid (keys %$ids) {
 979         my $scfg = $ids->{$storeid};
 980         next if !$info->{$storeid};
 981
 982         eval { activate_storage($cfg, $storeid, $cache); };
 983         if (my $err = $@) {
 984             warn $err;
 985             next;
 986         }
 987
 988         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 989         my ($total, $avail, $used, $active);
 990         eval { ($total, $avail, $used, $active) = $plugin->status($storeid, $scfg, $cache); };
 991         warn $@ if $@;
 992         next if !$active;
 993         $info->{$storeid}->{total} = $total;
 994         $info->{$storeid}->{avail} = $avail;
 995         $info->{$storeid}->{used} = $used;
 996         $info->{$storeid}->{active} = $active;
 997     }
 998
 999     return $info;
1000 }
1001
1002 sub resolv_server {
1003     my ($server) = @_;
1004
1005     my ($packed_ip, $family);
1006     eval {
1007         my @res = PVE::Tools::getaddrinfo_all($server);
1008         $family = $res[0]->{family};
1009         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1010     };
1011     if (defined $packed_ip) {
1012         return Socket::inet_ntop($family, $packed_ip);
1013     }
1014     return undef;
1015 }
1016
1017 sub scan_nfs {
1018     my ($server_in) = @_;
1019
1020     my $server;
1021     if (!($server = resolv_server ($server_in))) {
1022         die "unable to resolve address for server '${server_in}'\n";
1023     }
1024
1025     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1026
1027     my $res = {};
1028     run_command($cmd, outfunc => sub {
1029         my $line = shift;
1030
1031         # note: howto handle white spaces in export path??
1032         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1033             $res->{$1} = $2;
1034         }
1035     });
1036
1037     return $res;
1038 }
1039
1040 sub scan_zfs {
1041
1042     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-H', '-o', 'name,avail,used'];
1043
1044     my $res = [];
1045     run_command($cmd, outfunc => sub {
1046         my $line = shift;
1047
1048         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1049             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1050             my $size = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($size_str);
1051             my $used = PVE::Storage::ZFSPoolPlugin::zfs_parse_size($used_str);
1052             # ignore subvolumes generated by our ZFSPoolPlugin
1053             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1054             push @$res, { pool => $pool, size => $size, free => $size-$used };
1055         }
1056     });
1057
1058     return $res;
1059 }
1060
1061 sub resolv_portal {
1062     my ($portal, $noerr) = @_;
1063
1064     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1065     if ($server) {
1066         if (my $ip = resolv_server($server)) {
1067             $server = $ip;
1068             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1069             return $port ? "$server:$port" : $server;
1070         }
1071     }
1072     return undef if $noerr;
1073
1074     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1075 }
1076
1077 # idea is from usbutils package (/usr/bin/usb-devices) script
1078 sub __scan_usb_device {
1079     my ($res, $devpath, $parent, $level) = @_;
1080
1081     return if ! -d $devpath;
1082     return if $level && $devpath !~ m/^.*[-.](\d+)$/;
1083     my $port = $level ? int($1 - 1) : 0;
1084
1085     my $busnum = int(file_read_firstline("$devpath/busnum"));
1086     my $devnum = int(file_read_firstline("$devpath/devnum"));
1087
1088     my $d = {
1089         port => $port,
1090         level => $level,
1091         busnum => $busnum,
1092         devnum => $devnum,
1093         speed => file_read_firstline("$devpath/speed"),
1094         class => hex(file_read_firstline("$devpath/bDeviceClass")),
1095         vendid => file_read_firstline("$devpath/idVendor"),
1096         prodid => file_read_firstline("$devpath/idProduct"),
1097     };
1098
1099     if ($level) {
1100         my $usbpath = $devpath;
1101         $usbpath =~ s|^.*/\d+\-||;
1102         $d->{usbpath} = $usbpath;
1103     }
1104
1105     my $product = file_read_firstline("$devpath/product");
1106     $d->{product} = $product if $product;
1107
1108     my $manu = file_read_firstline("$devpath/manufacturer");
1109     $d->{manufacturer} = $manu if $manu;
1110
1111     my $serial => file_read_firstline("$devpath/serial");
1112     $d->{serial} = $serial if $serial;
1113
1114     push @$res, $d;
1115
1116     foreach my $subdev (<$devpath/$busnum-*>) {
1117         next if $subdev !~ m|/$busnum-[0-9]+(\.[0-9]+)*$|;
1118         __scan_usb_device($res, $subdev, $devnum, $level + 1);
1119     }
1120
1121 };
1122
1123 sub scan_usb {
1124
1125     my $devlist = [];
1126
1127     foreach my $device (</sys/bus/usb/devices/usb*>) {
1128         __scan_usb_device($devlist, $device, 0, 0);
1129     }
1130
1131     return $devlist;
1132 }
1133
1134 sub scan_iscsi {
1135     my ($portal_in) = @_;
1136
1137     my $portal;
1138     if (!($portal = resolv_portal($portal_in))) {
1139         die "unable to parse/resolve portal address '${portal_in}'\n";
1140     }
1141
1142     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1143 }
1144
1145 sub storage_default_format {
1146     my ($cfg, $storeid) = @_;
1147
1148     my $scfg = storage_config ($cfg, $storeid);
1149
1150     return PVE::Storage::Plugin::default_format($scfg);
1151 }
1152
1153 sub vgroup_is_used {
1154     my ($cfg, $vgname) = @_;
1155
1156     foreach my $storeid (keys %{$cfg->{ids}}) {
1157         my $scfg = storage_config($cfg, $storeid);
1158         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1159             return 1;
1160         }
1161     }
1162
1163     return undef;
1164 }
1165
1166 sub target_is_used {
1167     my ($cfg, $target) = @_;
1168
1169     foreach my $storeid (keys %{$cfg->{ids}}) {
1170         my $scfg = storage_config($cfg, $storeid);
1171         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1172             return 1;
1173         }
1174     }
1175
1176     return undef;
1177 }
1178
1179 sub volume_is_used {
1180     my ($cfg, $volid) = @_;
1181
1182     foreach my $storeid (keys %{$cfg->{ids}}) {
1183         my $scfg = storage_config($cfg, $storeid);
1184         if ($scfg->{base} && $scfg->{base} eq $volid) {
1185             return 1;
1186         }
1187     }
1188
1189     return undef;
1190 }
1191
1192 sub storage_is_used {
1193     my ($cfg, $storeid) = @_;
1194
1195     foreach my $sid (keys %{$cfg->{ids}}) {
1196         my $scfg = storage_config($cfg, $sid);
1197         next if !$scfg->{base};
1198         my ($st) = parse_volume_id($scfg->{base});
1199         return 1 if $st && $st eq $storeid;
1200     }
1201
1202     return undef;
1203 }
1204
1205 sub foreach_volid {
1206     my ($list, $func) = @_;
1207
1208     return if !$list;
1209
1210     foreach my $sid (keys %$list) {
1211        foreach my $info (@{$list->{$sid}}) {
1212            my $volid = $info->{volid};
1213            my ($sid1, $volname) = parse_volume_id($volid, 1);
1214            if ($sid1 && $sid1 eq $sid) {
1215                &$func ($volid, $sid, $info);
1216            } else {
1217                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1218            }
1219        }
1220     }
1221 }
1222
1223 # bash completion helper
1224
1225 sub complete_storage {
1226     my ($cmdname, $pname, $cvalue) = @_;
1227
1228     my $cfg = PVE::Storage::config();
1229
1230     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1231 }
1232
1233 sub complete_storage_enabled {
1234     my ($cmdname, $pname, $cvalue) = @_;
1235
1236     my $res = [];
1237
1238     my $cfg = PVE::Storage::config();
1239     foreach my $sid (keys %{$cfg->{ids}}) {
1240         next if !storage_check_enabled($cfg, $sid, undef, 1);
1241         push @$res, $sid;
1242     }
1243     return $res;
1244 }
1245
1246 sub complete_content_type {
1247     my ($cmdname, $pname, $cvalue) = @_;
1248
1249     return [qw(rootdir images vztmpl iso backup)];
1250 }
1251
1252 sub complete_volume {
1253     my ($cmdname, $pname, $cvalue) = @_;
1254
1255     my $cfg = config();
1256
1257     my $storage_list = complete_storage_enabled();
1258
1259     if ($cvalue =~ m/^([^:]+):/) {
1260         $storage_list = [ $1 ];
1261     } else {
1262         if (scalar(@$storage_list) > 1) {
1263             # only list storage IDs to avoid large listings
1264             my $res = [];
1265             foreach my $storeid (@$storage_list) {
1266                 # Hack: simply return 2 artificial values, so that
1267                 # completions does not finish
1268                 push @$res, "$storeid:volname", "$storeid:...";
1269             }
1270             return $res;
1271         }
1272     }
1273
1274     my $res = [];
1275     foreach my $storeid (@$storage_list) {
1276         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1277
1278         foreach my $item (@$vollist) {
1279             push @$res, $item->{volid};
1280         }
1281     }
1282
1283     return $res;
1284 }
1285
1286 1;