PVE/Storage.pm

   1 package PVE::Storage;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6
   7 use POSIX;
   8 use IO::Select;
   9 use IO::File;
  10 use IO::Socket::IP;
  11 use File::Basename;
  12 use File::Path;
  13 use Cwd 'abs_path';
  14 use Socket;
  15
  16 use PVE::Tools qw(run_command file_read_firstline dir_glob_foreach $IPV6RE);
  17 use PVE::Cluster qw(cfs_read_file cfs_write_file cfs_lock_file);
  18 use PVE::DataCenterConfig;
  19 use PVE::Exception qw(raise_param_exc);
  20 use PVE::JSONSchema;
  21 use PVE::INotify;
  22 use PVE::RPCEnvironment;
  23 use PVE::SSHInfo;
  24
  25 use PVE::Storage::Plugin;
  26 use PVE::Storage::DirPlugin;
  27 use PVE::Storage::LVMPlugin;
  28 use PVE::Storage::LvmThinPlugin;
  29 use PVE::Storage::NFSPlugin;
  30 use PVE::Storage::CIFSPlugin;
  31 use PVE::Storage::ISCSIPlugin;
  32 use PVE::Storage::RBDPlugin;
  33 use PVE::Storage::CephFSPlugin;
  34 use PVE::Storage::ISCSIDirectPlugin;
  35 use PVE::Storage::GlusterfsPlugin;
  36 use PVE::Storage::ZFSPoolPlugin;
  37 use PVE::Storage::ZFSPlugin;
  38 use PVE::Storage::DRBDPlugin;
  39 use PVE::Storage::PBSPlugin;
  40
  41 # Storage API version. Icrement it on changes in storage API interface.
  42 use constant APIVER => 5;
  43 # Age is the number of versions we're backward compatible with.
  44 # This is like having 'current=APIVER' and age='APIAGE' in libtool,
  45 # see https://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  46 use constant APIAGE => 4;
  47
  48 # load standard plugins
  49 PVE::Storage::DirPlugin->register();
  50 PVE::Storage::LVMPlugin->register();
  51 PVE::Storage::LvmThinPlugin->register();
  52 PVE::Storage::NFSPlugin->register();
  53 PVE::Storage::CIFSPlugin->register();
  54 PVE::Storage::ISCSIPlugin->register();
  55 PVE::Storage::RBDPlugin->register();
  56 PVE::Storage::CephFSPlugin->register();
  57 PVE::Storage::ISCSIDirectPlugin->register();
  58 PVE::Storage::GlusterfsPlugin->register();
  59 PVE::Storage::ZFSPoolPlugin->register();
  60 PVE::Storage::ZFSPlugin->register();
  61 PVE::Storage::DRBDPlugin->register();
  62 PVE::Storage::PBSPlugin->register();
  63
  64 # load third-party plugins
  65 if ( -d '/usr/share/perl5/PVE/Storage/Custom' ) {
  66     dir_glob_foreach('/usr/share/perl5/PVE/Storage/Custom', '.*\.pm$', sub {
  67         my ($file) = @_;
  68         my $modname = 'PVE::Storage::Custom::' . $file;
  69         $modname =~ s!\.pm$!!;
  70         $file = 'PVE/Storage/Custom/' . $file;
  71
  72         eval {
  73             require $file;
  74
  75             # Check perl interface:
  76             die "not derived from PVE::Storage::Plugin\n"
  77                 if !$modname->isa('PVE::Storage::Plugin');
  78             die "does not provide an api() method\n"
  79                 if !$modname->can('api');
  80             # Check storage API version and that file is really storage plugin.
  81             my $version = $modname->api();
  82             die "implements an API version newer than current ($version > " . APIVER . ")\n"
  83                 if $version > APIVER;
  84             my $min_version = (APIVER - APIAGE);
  85             die "API version too old, please update the plugin ($version < $min_version)\n"
  86                 if $version < $min_version;
  87             import $file;
  88             $modname->register();
  89
  90             # If we got this far and the API version is not the same, make some
  91             # noise:
  92             warn "Plugin \"$modname\" is implementing an older storage API, an upgrade is recommended\n"
  93                 if $version != APIVER;
  94         };
  95         if ($@) {
  96             warn "Error loading storage plugin \"$modname\": $@";
  97         }
  98     });
  99 }
 100
 101 # initialize all plugins
 102 PVE::Storage::Plugin->init();
 103
 104 my $UDEVADM = '/sbin/udevadm';
 105
 106 our $iso_extension_re = qr/\.(?:iso|img)/i;
 107
 108 #  PVE::Storage utility functions
 109
 110 sub config {
 111     return cfs_read_file("storage.cfg");
 112 }
 113
 114 sub write_config {
 115     my ($cfg) = @_;
 116
 117     cfs_write_file('storage.cfg', $cfg);
 118 }
 119
 120 sub lock_storage_config {
 121     my ($code, $errmsg) = @_;
 122
 123     cfs_lock_file("storage.cfg", undef, $code);
 124     my $err = $@;
 125     if ($err) {
 126         $errmsg ? die "$errmsg: $err" : die $err;
 127     }
 128 }
 129
 130 sub storage_config {
 131     my ($cfg, $storeid, $noerr) = @_;
 132
 133     die "no storage ID specified\n" if !$storeid;
 134
 135     my $scfg = $cfg->{ids}->{$storeid};
 136
 137     die "storage '$storeid' does not exist\n" if (!$noerr && !$scfg);
 138
 139     return $scfg;
 140 }
 141
 142 sub storage_check_node {
 143     my ($cfg, $storeid, $node, $noerr) = @_;
 144
 145     my $scfg = storage_config($cfg, $storeid);
 146
 147     if ($scfg->{nodes}) {
 148         $node = PVE::INotify::nodename() if !$node || ($node eq 'localhost');
 149         if (!$scfg->{nodes}->{$node}) {
 150             die "storage '$storeid' is not available on node '$node'\n" if !$noerr;
 151             return undef;
 152         }
 153     }
 154
 155     return $scfg;
 156 }
 157
 158 sub storage_check_enabled {
 159     my ($cfg, $storeid, $node, $noerr) = @_;
 160
 161     my $scfg = storage_config($cfg, $storeid);
 162
 163     if ($scfg->{disable}) {
 164         die "storage '$storeid' is disabled\n" if !$noerr;
 165         return undef;
 166     }
 167
 168     return storage_check_node($cfg, $storeid, $node, $noerr);
 169 }
 170
 171 # storage_can_replicate:
 172 # return true if storage supports replication
 173 # (volumes alocated with vdisk_alloc() has replication feature)
 174 sub storage_can_replicate {
 175     my ($cfg, $storeid, $format) = @_;
 176
 177     my $scfg = storage_config($cfg, $storeid);
 178     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 179     return $plugin->storage_can_replicate($scfg, $storeid, $format);
 180 }
 181
 182 sub storage_ids {
 183     my ($cfg) = @_;
 184
 185     return keys %{$cfg->{ids}};
 186 }
 187
 188 sub file_size_info {
 189     my ($filename, $timeout) = @_;
 190
 191     return PVE::Storage::Plugin::file_size_info($filename, $timeout);
 192 }
 193
 194 sub volume_size_info {
 195     my ($cfg, $volid, $timeout) = @_;
 196
 197     my ($storeid, $volname) = parse_volume_id($volid, 1);
 198     if ($storeid) {
 199         my $scfg = storage_config($cfg, $storeid);
 200         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 201         return $plugin->volume_size_info($scfg, $storeid, $volname, $timeout);
 202     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 203         return file_size_info($volid, $timeout);
 204     } else {
 205         return 0;
 206     }
 207 }
 208
 209 sub volume_resize {
 210     my ($cfg, $volid, $size, $running) = @_;
 211
 212     my $padding = (1024 - $size % 1024) % 1024;
 213     $size = $size + $padding;
 214
 215     my ($storeid, $volname) = parse_volume_id($volid, 1);
 216     if ($storeid) {
 217         my $scfg = storage_config($cfg, $storeid);
 218         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 219         return $plugin->volume_resize($scfg, $storeid, $volname, $size, $running);
 220     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 221         die "resize file/device '$volid' is not possible\n";
 222     } else {
 223         die "unable to parse volume ID '$volid'\n";
 224     }
 225 }
 226
 227 sub volume_rollback_is_possible {
 228     my ($cfg, $volid, $snap) = @_;
 229
 230     my ($storeid, $volname) = parse_volume_id($volid, 1);
 231     if ($storeid) {
 232         my $scfg = storage_config($cfg, $storeid);
 233         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 234         return $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 235     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 236         die "snapshot rollback file/device '$volid' is not possible\n";
 237     } else {
 238         die "unable to parse volume ID '$volid'\n";
 239     }
 240 }
 241
 242 sub volume_snapshot {
 243     my ($cfg, $volid, $snap) = @_;
 244
 245     my ($storeid, $volname) = parse_volume_id($volid, 1);
 246     if ($storeid) {
 247         my $scfg = storage_config($cfg, $storeid);
 248         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 249         return $plugin->volume_snapshot($scfg, $storeid, $volname, $snap);
 250     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 251         die "snapshot file/device '$volid' is not possible\n";
 252     } else {
 253         die "unable to parse volume ID '$volid'\n";
 254     }
 255 }
 256
 257 sub volume_snapshot_rollback {
 258     my ($cfg, $volid, $snap) = @_;
 259
 260     my ($storeid, $volname) = parse_volume_id($volid, 1);
 261     if ($storeid) {
 262         my $scfg = storage_config($cfg, $storeid);
 263         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 264         $plugin->volume_rollback_is_possible($scfg, $storeid, $volname, $snap);
 265         return $plugin->volume_snapshot_rollback($scfg, $storeid, $volname, $snap);
 266     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 267         die "snapshot rollback file/device '$volid' is not possible\n";
 268     } else {
 269         die "unable to parse volume ID '$volid'\n";
 270     }
 271 }
 272
 273 sub volume_snapshot_delete {
 274     my ($cfg, $volid, $snap, $running) = @_;
 275
 276     my ($storeid, $volname) = parse_volume_id($volid, 1);
 277     if ($storeid) {
 278         my $scfg = storage_config($cfg, $storeid);
 279         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 280         return $plugin->volume_snapshot_delete($scfg, $storeid, $volname, $snap, $running);
 281     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 282         die "snapshot delete file/device '$volid' is not possible\n";
 283     } else {
 284         die "unable to parse volume ID '$volid'\n";
 285     }
 286 }
 287
 288 # check if a volume or snapshot supports a given feature
 289 # $feature - one of:
 290 #            clone - linked clone is possible
 291 #            copy  - full clone is possible
 292 #            replicate - replication is possible
 293 #            snapshot - taking a snapshot is possible
 294 #            sparseinit - volume is sparsely initialized
 295 #            template - conversion to base image is possible
 296 # $snap - check if the feature is supported for a given snapshot
 297 # $running - if the guest owning the volume is running
 298 # $opts - hash with further options:
 299 #         valid_target_formats - list of formats for the target of a copy/clone
 300 #                                operation that the caller could work with. The
 301 #                                format of $volid is always considered valid and if
 302 #                                no list is specified, all formats are considered valid.
 303 sub volume_has_feature {
 304     my ($cfg, $feature, $volid, $snap, $running, $opts) = @_;
 305
 306     my ($storeid, $volname) = parse_volume_id($volid, 1);
 307     if ($storeid) {
 308         my $scfg = storage_config($cfg, $storeid);
 309         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 310         return $plugin->volume_has_feature($scfg, $feature, $storeid, $volname, $snap, $running, $opts);
 311     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 312         return undef;
 313     } else {
 314         return undef;
 315     }
 316 }
 317
 318 sub volume_snapshot_list {
 319     my ($cfg, $volid) = @_;
 320
 321     my ($storeid, $volname) = parse_volume_id($volid, 1);
 322     if ($storeid) {
 323         my $scfg = storage_config($cfg, $storeid);
 324         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 325         return $plugin->volume_snapshot_list($scfg, $storeid, $volname);
 326     } elsif ($volid =~ m|^(/.+)$| && -e $volid) {
 327         die "send file/device '$volid' is not possible\n";
 328     } else {
 329         die "unable to parse volume ID '$volid'\n";
 330     }
 331     # return an empty array if dataset does not exist.
 332 }
 333
 334 sub get_image_dir {
 335     my ($cfg, $storeid, $vmid) = @_;
 336
 337     my $scfg = storage_config($cfg, $storeid);
 338     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 339
 340     my $path = $plugin->get_subdir($scfg, 'images');
 341
 342     return $vmid ? "$path/$vmid" : $path;
 343 }
 344
 345 sub get_private_dir {
 346     my ($cfg, $storeid, $vmid) = @_;
 347
 348     my $scfg = storage_config($cfg, $storeid);
 349     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 350
 351     my $path = $plugin->get_subdir($scfg, 'rootdir');
 352
 353     return $vmid ? "$path/$vmid" : $path;
 354 }
 355
 356 sub get_iso_dir {
 357     my ($cfg, $storeid) = @_;
 358
 359     my $scfg = storage_config($cfg, $storeid);
 360     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 361
 362     return $plugin->get_subdir($scfg, 'iso');
 363 }
 364
 365 sub get_vztmpl_dir {
 366     my ($cfg, $storeid) = @_;
 367
 368     my $scfg = storage_config($cfg, $storeid);
 369     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 370
 371     return $plugin->get_subdir($scfg, 'vztmpl');
 372 }
 373
 374 sub get_backup_dir {
 375     my ($cfg, $storeid) = @_;
 376
 377     my $scfg = storage_config($cfg, $storeid);
 378     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 379
 380     return $plugin->get_subdir($scfg, 'backup');
 381 }
 382
 383 # library implementation
 384
 385 sub parse_vmid {
 386     my $vmid = shift;
 387
 388     die "VMID '$vmid' contains illegal characters\n" if $vmid !~ m/^\d+$/;
 389
 390     return int($vmid);
 391 }
 392
 393 # NOTE: basename and basevmid are always undef for LVM-thin, where the
 394 # clone -> base reference is not encoded in the volume ID.
 395 # see note in PVE::Storage::LvmThinPlugin for details.
 396 sub parse_volname {
 397     my ($cfg, $volid) = @_;
 398
 399     my ($storeid, $volname) = parse_volume_id($volid);
 400
 401     my $scfg = storage_config($cfg, $storeid);
 402
 403     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 404
 405     # returns ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $format)
 406
 407     return $plugin->parse_volname($volname);
 408 }
 409
 410 sub parse_volume_id {
 411     my ($volid, $noerr) = @_;
 412
 413     return PVE::Storage::Plugin::parse_volume_id($volid, $noerr);
 414 }
 415
 416 # test if we have read access to volid
 417 sub check_volume_access {
 418     my ($rpcenv, $user, $cfg, $vmid, $volid) = @_;
 419
 420     my ($sid, $volname) = parse_volume_id($volid, 1);
 421     if ($sid) {
 422         my ($vtype, undef, $ownervm) = parse_volname($cfg, $volid);
 423         if ($vtype eq 'iso' || $vtype eq 'vztmpl') {
 424             # require at least read access to storage, (custom) templates/ISOs could be sensitive
 425             $rpcenv->check_any($user, "/storage/$sid", ['Datastore.AllocateSpace', 'Datastore.Audit']);
 426         } elsif (defined($ownervm) && defined($vmid) && ($ownervm == $vmid)) {
 427             # we are owner - allow access
 428         } elsif ($vtype eq 'backup' && $ownervm) {
 429             $rpcenv->check($user, "/storage/$sid", ['Datastore.AllocateSpace']);
 430             $rpcenv->check($user, "/vms/$ownervm", ['VM.Backup']);
 431         } else {
 432             # allow if we are Datastore administrator
 433             $rpcenv->check($user, "/storage/$sid", ['Datastore.Allocate']);
 434         }
 435     } else {
 436         die "Only root can pass arbitrary filesystem paths."
 437             if $user ne 'root@pam';
 438     }
 439
 440     return undef;
 441 }
 442
 443 my $volume_is_base_and_used__no_lock = sub {
 444     my ($scfg, $storeid, $plugin, $volname) = @_;
 445
 446     my ($vtype, $name, $vmid, undef, undef, $isBase, undef) =
 447         $plugin->parse_volname($volname);
 448
 449     if ($isBase) {
 450         my $vollist = $plugin->list_images($storeid, $scfg);
 451         foreach my $info (@$vollist) {
 452             my (undef, $tmpvolname) = parse_volume_id($info->{volid});
 453             my $basename = undef;
 454             my $basevmid = undef;
 455
 456             eval{
 457                 (undef, undef, undef, $basename, $basevmid) =
 458                     $plugin->parse_volname($tmpvolname);
 459             };
 460
 461             if ($basename && defined($basevmid) && $basevmid == $vmid && $basename eq $name) {
 462                 return 1;
 463             }
 464         }
 465     }
 466     return 0;
 467 };
 468
 469 # NOTE: this check does not work for LVM-thin, where the clone -> base
 470 # reference is not encoded in the volume ID.
 471 # see note in PVE::Storage::LvmThinPlugin for details.
 472 sub volume_is_base_and_used {
 473     my ($cfg, $volid) = @_;
 474
 475     my ($storeid, $volname) = parse_volume_id($volid);
 476     my $scfg = storage_config($cfg, $storeid);
 477     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 478
 479     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 480         return &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 481     });
 482 }
 483
 484 # try to map a filesystem path to a volume identifier
 485 sub path_to_volume_id {
 486     my ($cfg, $path) = @_;
 487
 488     my $ids = $cfg->{ids};
 489
 490     my ($sid, $volname) = parse_volume_id($path, 1);
 491     if ($sid) {
 492         if (my $scfg = $ids->{$sid}) {
 493             if ($scfg->{path}) {
 494                 my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 495                 my ($vtype, $name, $vmid) = $plugin->parse_volname($volname);
 496                 return ($vtype, $path);
 497             }
 498         }
 499         return ('');
 500     }
 501
 502     # Note: abs_path() return undef if $path doesn not exist
 503     # for example when nfs storage is not mounted
 504     $path = abs_path($path) || $path;
 505
 506     foreach my $sid (keys %$ids) {
 507         my $scfg = $ids->{$sid};
 508         next if !$scfg->{path};
 509         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 510         my $imagedir = $plugin->get_subdir($scfg, 'images');
 511         my $isodir = $plugin->get_subdir($scfg, 'iso');
 512         my $tmpldir = $plugin->get_subdir($scfg, 'vztmpl');
 513         my $backupdir = $plugin->get_subdir($scfg, 'backup');
 514         my $privatedir = $plugin->get_subdir($scfg, 'rootdir');
 515
 516         if ($path =~ m!^$imagedir/(\d+)/([^/\s]+)$!) {
 517             my $vmid = $1;
 518             my $name = $2;
 519
 520             my $vollist = $plugin->list_images($sid, $scfg, $vmid);
 521             foreach my $info (@$vollist) {
 522                 my ($storeid, $volname) = parse_volume_id($info->{volid});
 523                 my $volpath = $plugin->path($scfg, $volname, $storeid);
 524                 if ($volpath eq $path) {
 525                     return ('images', $info->{volid});
 526                 }
 527             }
 528         } elsif ($path =~ m!^$isodir/([^/]+$iso_extension_re)$!) {
 529             my $name = $1;
 530             return ('iso', "$sid:iso/$name");
 531         } elsif ($path =~ m!^$tmpldir/([^/]+\.tar\.gz)$!) {
 532             my $name = $1;
 533             return ('vztmpl', "$sid:vztmpl/$name");
 534         } elsif ($path =~ m!^$privatedir/(\d+)$!) {
 535             my $vmid = $1;
 536             return ('rootdir', "$sid:rootdir/$vmid");
 537         } elsif ($path =~ m!^$backupdir/([^/]+\.(tar|tar\.gz|tar\.lzo|tgz|vma|vma\.gz|vma\.lzo))$!) {
 538             my $name = $1;
 539             return ('backup', "$sid:backup/$name");
 540         }
 541     }
 542
 543     # can't map path to volume id
 544     return ('');
 545 }
 546
 547 sub path {
 548     my ($cfg, $volid, $snapname) = @_;
 549
 550     my ($storeid, $volname) = parse_volume_id($volid);
 551
 552     my $scfg = storage_config($cfg, $storeid);
 553
 554     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 555     my ($path, $owner, $vtype) = $plugin->path($scfg, $volname, $storeid, $snapname);
 556     return wantarray ? ($path, $owner, $vtype) : $path;
 557 }
 558
 559 sub abs_filesystem_path {
 560     my ($cfg, $volid) = @_;
 561
 562     my $path;
 563     if (parse_volume_id ($volid, 1)) {
 564         activate_volumes($cfg, [ $volid ]);
 565         $path = PVE::Storage::path($cfg, $volid);
 566     } else {
 567         if (-f $volid) {
 568             my $abspath = abs_path($volid);
 569             if ($abspath && $abspath =~ m|^(/.+)$|) {
 570                 $path = $1; # untaint any path
 571             }
 572         }
 573     }
 574
 575     die "can't find file '$volid'\n" if !($path && -f $path);
 576
 577     return $path;
 578 }
 579
 580 my $volname_for_storage = sub {
 581     my ($cfg, $volid, $target_storeid) = @_;
 582
 583     my (undef, $name, $vmid, undef, undef, undef, $format) = parse_volname($cfg, $volid);
 584     my $target_scfg = storage_config($cfg, $target_storeid);
 585
 586     my (undef, $valid_formats) = PVE::Storage::Plugin::default_format($target_scfg);
 587     my $format_is_valid = grep { $_ eq $format } @$valid_formats;
 588     die "unsupported format '$format' for storage type $target_scfg->{type}\n" if !$format_is_valid;
 589
 590     (my $name_without_extension = $name) =~ s/\.$format$//;
 591
 592     if ($target_scfg->{path}) {
 593        return "$vmid/$name_without_extension.$format";
 594     } else {
 595        return "$name_without_extension";
 596     }
 597 };
 598
 599 sub storage_migrate {
 600     my ($cfg, $volid, $target_sshinfo, $target_storeid, $opts, $logfunc) = @_;
 601
 602     my $base_snapshot = $opts->{base_snapshot};
 603     my $snapshot = $opts->{snapshot};
 604     my $ratelimit_bps = $opts->{ratelimit_bps};
 605     my $insecure = $opts->{insecure};
 606     my $with_snapshots = $opts->{with_snapshots} ? 1 : 0;
 607     my $allow_rename = $opts->{allow_rename} ? 1 : 0;
 608
 609     my ($storeid, $volname) = parse_volume_id($volid);
 610
 611     my $scfg = storage_config($cfg, $storeid);
 612
 613     # no need to migrate shared content
 614     return $volid if $storeid eq $target_storeid && $scfg->{shared};
 615
 616     my $tcfg = storage_config($cfg, $target_storeid);
 617
 618     my $vtype = (parse_volname($cfg, $volid))[0];
 619
 620     die "content type '$vtype' is not available on storage '$target_storeid'\n"
 621         if !$tcfg->{content}->{$vtype};
 622
 623     my $target_volname;
 624     if ($opts->{target_volname}) {
 625         $target_volname = $opts->{target_volname};
 626     } elsif ($scfg->{type} eq $tcfg->{type}) {
 627         $target_volname = $volname;
 628     } else {
 629         $target_volname = $volname_for_storage->($cfg, $volid, $target_storeid);
 630     }
 631
 632     my $target_volid = "${target_storeid}:${target_volname}";
 633
 634     my $target_ip = $target_sshinfo->{ip};
 635
 636     my $ssh = PVE::SSHInfo::ssh_info_to_command($target_sshinfo);
 637     my $ssh_base = PVE::SSHInfo::ssh_info_to_command_base($target_sshinfo);
 638     local $ENV{RSYNC_RSH} = PVE::Tools::cmd2string($ssh_base);
 639
 640     my @cstream = ([ '/usr/bin/cstream', '-t', $ratelimit_bps ])
 641         if defined($ratelimit_bps);
 642
 643     my $migration_snapshot;
 644     if (!defined($snapshot)) {
 645         if ($scfg->{type} eq 'zfspool') {
 646             $migration_snapshot = 1;
 647             $snapshot = '__migration__';
 648         }
 649     }
 650
 651     my @formats = volume_transfer_formats($cfg, $volid, $target_volid, $snapshot, $base_snapshot, $with_snapshots);
 652     die "cannot migrate from storage type '$scfg->{type}' to '$tcfg->{type}'\n" if !@formats;
 653     my $format = $formats[0];
 654
 655     my $import_fn = '-'; # let pvesm import read from stdin per default
 656     if ($insecure) {
 657         my $net = $target_sshinfo->{network} // $target_sshinfo->{ip};
 658         $import_fn = "tcp://$net";
 659     }
 660
 661     my $target_apiver = 1; # if there is no apiinfo call, assume 1
 662     my $get_api_version = [@$ssh, 'pvesm', 'apiinfo'];
 663     my $match_api_version = sub { $target_apiver = $1 if $_[0] =~ m!^APIVER (\d+)$!; };
 664     eval { run_command($get_api_version, logfunc => $match_api_version); };
 665
 666     my $send = ['pvesm', 'export', $volid, $format, '-', '-with-snapshots', $with_snapshots];
 667     my $recv = [@$ssh, '--', 'pvesm', 'import', $target_volid, $format, $import_fn, '-with-snapshots', $with_snapshots];
 668     if (defined($snapshot)) {
 669         push @$send, '-snapshot', $snapshot
 670     }
 671     if ($migration_snapshot) {
 672         push @$recv, '-delete-snapshot', $snapshot;
 673     }
 674     push @$recv, '-allow-rename', $allow_rename if $target_apiver >= 5;
 675
 676     if (defined($base_snapshot)) {
 677         # Check if the snapshot exists on the remote side:
 678         push @$send, '-base', $base_snapshot;
 679         push @$recv, '-base', $base_snapshot;
 680     }
 681
 682     my $new_volid;
 683     my $pattern = volume_imported_message(undef, 1);
 684     my $match_volid_and_log = sub {
 685         my $line = shift;
 686
 687         $new_volid = $1 if ($line =~ $pattern);
 688
 689         if ($logfunc) {
 690             chomp($line);
 691             $logfunc->($line);
 692         }
 693     };
 694
 695     volume_snapshot($cfg, $volid, $snapshot) if $migration_snapshot;
 696     eval {
 697         if ($insecure) {
 698             open(my $info, '-|', @$recv)
 699                 or die "receive command failed: $!\n";
 700             my ($ip) = <$info> =~ /^($PVE::Tools::IPRE)$/ or die "no tunnel IP received\n";
 701             my ($port) = <$info> =~ /^(\d+)$/ or die "no tunnel port received\n";
 702             my $socket = IO::Socket::IP->new(PeerHost => $ip, PeerPort => $port, Type => SOCK_STREAM)
 703                 or die "failed to connect to tunnel at $ip:$port\n";
 704             # we won't be reading from the socket
 705             shutdown($socket, 0);
 706             run_command([$send, @cstream], output => '>&'.fileno($socket), errfunc => $logfunc);
 707             # don't close the connection entirely otherwise the receiving end
 708             # might not get all buffered data (and fails with 'connection reset by peer')
 709             shutdown($socket, 1);
 710
 711             # wait for the remote process to finish
 712             while (my $line = <$info>) {
 713                 $match_volid_and_log->("[$target_sshinfo->{name}] $line");
 714             }
 715
 716             # now close the socket
 717             close($socket);
 718             if (!close($info)) { # does waitpid()
 719                 die "import failed: $!\n" if $!;
 720                 die "import failed: exit code ".($?>>8)."\n";
 721             }
 722         } else {
 723             run_command([$send, @cstream, $recv], logfunc => $match_volid_and_log);
 724         }
 725
 726         die "unable to get ID of the migrated volume\n"
 727             if !defined($new_volid) && $target_apiver >= 5;
 728     };
 729     my $err = $@;
 730     warn "send/receive failed, cleaning up snapshot(s)..\n" if $err;
 731     if ($migration_snapshot) {
 732         eval { volume_snapshot_delete($cfg, $volid, $snapshot, 0) };
 733         warn "could not remove source snapshot: $@\n" if $@;
 734     }
 735     die $err if $err;
 736
 737     return $new_volid // $target_volid;
 738 }
 739
 740 sub vdisk_clone {
 741     my ($cfg, $volid, $vmid, $snap) = @_;
 742
 743     my ($storeid, $volname) = parse_volume_id($volid);
 744
 745     my $scfg = storage_config($cfg, $storeid);
 746
 747     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 748
 749     activate_storage($cfg, $storeid);
 750
 751     # lock shared storage
 752     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 753         my $volname = $plugin->clone_image($scfg, $storeid, $volname, $vmid, $snap);
 754         return "$storeid:$volname";
 755     });
 756 }
 757
 758 sub vdisk_create_base {
 759     my ($cfg, $volid) = @_;
 760
 761     my ($storeid, $volname) = parse_volume_id($volid);
 762
 763     my $scfg = storage_config($cfg, $storeid);
 764
 765     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 766
 767     activate_storage($cfg, $storeid);
 768
 769     # lock shared storage
 770     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 771         my $volname = $plugin->create_base($storeid, $scfg, $volname);
 772         return "$storeid:$volname";
 773     });
 774 }
 775
 776 sub map_volume {
 777     my ($cfg, $volid, $snapname) = @_;
 778
 779     my ($storeid, $volname) = parse_volume_id($volid);
 780
 781     my $scfg = storage_config($cfg, $storeid);
 782
 783     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 784
 785     return $plugin->map_volume($storeid, $scfg, $volname, $snapname);
 786 }
 787
 788 sub unmap_volume {
 789     my ($cfg, $volid, $snapname) = @_;
 790
 791     my ($storeid, $volname) = parse_volume_id($volid);
 792
 793     my $scfg = storage_config($cfg, $storeid);
 794
 795     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 796
 797     return $plugin->unmap_volume($storeid, $scfg, $volname, $snapname);
 798 }
 799
 800 sub vdisk_alloc {
 801     my ($cfg, $storeid, $vmid, $fmt, $name, $size) = @_;
 802
 803     die "no storage ID specified\n" if !$storeid;
 804
 805     PVE::JSONSchema::parse_storage_id($storeid);
 806
 807     my $scfg = storage_config($cfg, $storeid);
 808
 809     die "no VMID specified\n" if !$vmid;
 810
 811     $vmid = parse_vmid($vmid);
 812
 813     my $defformat = PVE::Storage::Plugin::default_format($scfg);
 814
 815     $fmt = $defformat if !$fmt;
 816
 817     activate_storage($cfg, $storeid);
 818
 819     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 820
 821     # lock shared storage
 822     return $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 823         my $old_umask = umask(umask|0037);
 824         my $volname = eval { $plugin->alloc_image($storeid, $scfg, $vmid, $fmt, $name, $size) };
 825         my $err = $@;
 826         umask $old_umask;
 827         die $err if $err;
 828         return "$storeid:$volname";
 829     });
 830 }
 831
 832 sub vdisk_free {
 833     my ($cfg, $volid) = @_;
 834
 835     my ($storeid, $volname) = parse_volume_id($volid);
 836     my $scfg = storage_config($cfg, $storeid);
 837     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 838
 839     activate_storage($cfg, $storeid);
 840
 841     my $cleanup_worker;
 842
 843     # lock shared storage
 844     $plugin->cluster_lock_storage($storeid, $scfg->{shared}, undef, sub {
 845         # LVM-thin allows deletion of still referenced base volumes!
 846         die "base volume '$volname' is still in use by linked clones\n"
 847             if &$volume_is_base_and_used__no_lock($scfg, $storeid, $plugin, $volname);
 848
 849         my (undef, undef, undef, undef, undef, $isBase, $format) =
 850             $plugin->parse_volname($volname);
 851         $cleanup_worker = $plugin->free_image($storeid, $scfg, $volname, $isBase, $format);
 852     });
 853
 854     return if !$cleanup_worker;
 855
 856     my $rpcenv = PVE::RPCEnvironment::get();
 857     my $authuser = $rpcenv->get_user();
 858
 859     $rpcenv->fork_worker('imgdel', undef, $authuser, $cleanup_worker);
 860 }
 861
 862 sub vdisk_list {
 863     my ($cfg, $storeid, $vmid, $vollist) = @_;
 864
 865     my $ids = $cfg->{ids};
 866
 867     storage_check_enabled($cfg, $storeid) if ($storeid);
 868
 869     my $res = {};
 870
 871     # prepare/activate/refresh all storages
 872
 873     my $storage_list = [];
 874     if ($vollist) {
 875         foreach my $volid (@$vollist) {
 876             my ($sid, undef) = parse_volume_id($volid);
 877             next if !defined($ids->{$sid});
 878             next if !storage_check_enabled($cfg, $sid, undef, 1);
 879             push @$storage_list, $sid;
 880         }
 881     } else {
 882         foreach my $sid (keys %$ids) {
 883             next if $storeid && $storeid ne $sid;
 884             next if !storage_check_enabled($cfg, $sid, undef, 1);
 885             push @$storage_list, $sid;
 886         }
 887     }
 888
 889     my $cache = {};
 890
 891     activate_storage_list($cfg, $storage_list, $cache);
 892
 893     foreach my $sid (keys %$ids) {
 894         next if $storeid && $storeid ne $sid;
 895         next if !storage_check_enabled($cfg, $sid, undef, 1);
 896
 897         my $scfg = $ids->{$sid};
 898         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 899         $res->{$sid} = $plugin->list_images($sid, $scfg, $vmid, $vollist, $cache);
 900         @{$res->{$sid}} = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @{$res->{$sid}} if $res->{$sid};
 901     }
 902
 903     return $res;
 904 }
 905
 906 sub template_list {
 907     my ($cfg, $storeid, $tt) = @_;
 908
 909     die "unknown template type '$tt'\n"
 910         if !($tt eq 'iso' || $tt eq 'vztmpl' || $tt eq 'backup' || $tt eq 'snippets');
 911
 912     my $ids = $cfg->{ids};
 913
 914     storage_check_enabled($cfg, $storeid) if ($storeid);
 915
 916     my $res = {};
 917
 918     # query the storage
 919     foreach my $sid (keys %$ids) {
 920         next if $storeid && $storeid ne $sid;
 921
 922         my $scfg = $ids->{$sid};
 923         my $type = $scfg->{type};
 924
 925         next if !$scfg->{content}->{$tt};
 926
 927         next if !storage_check_enabled($cfg, $sid, undef, 1);
 928
 929         $res->{$sid} = volume_list($cfg, $sid, undef, $tt);
 930     }
 931
 932     return $res;
 933 }
 934
 935 sub volume_list {
 936     my ($cfg, $storeid, $vmid, $content) = @_;
 937
 938     my @ctypes = qw(rootdir images vztmpl iso backup snippets);
 939
 940     my $cts = $content ? [ $content ] : [ @ctypes ];
 941
 942     my $scfg = PVE::Storage::storage_config($cfg, $storeid);
 943
 944     $cts = [ grep { defined($scfg->{content}->{$_}) } @$cts ];
 945
 946     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 947
 948     activate_storage($cfg, $storeid);
 949
 950     my $res = $plugin->list_volumes($storeid, $scfg, $vmid, $cts);
 951
 952     @$res = sort {lc($a->{volid}) cmp lc ($b->{volid}) } @$res;
 953
 954     return $res;
 955 }
 956
 957 sub uevent_seqnum {
 958
 959     my $filename = "/sys/kernel/uevent_seqnum";
 960
 961     my $seqnum = 0;
 962     if (my $fh = IO::File->new($filename, "r")) {
 963         my $line = <$fh>;
 964         if ($line =~ m/^(\d+)$/) {
 965             $seqnum = int($1);
 966         }
 967         close ($fh);
 968     }
 969     return $seqnum;
 970 }
 971
 972 sub activate_storage {
 973     my ($cfg, $storeid, $cache) = @_;
 974
 975     $cache = {} if !$cache;
 976
 977     my $scfg = storage_check_enabled($cfg, $storeid);
 978
 979     return if $cache->{activated}->{$storeid};
 980
 981     $cache->{uevent_seqnum} = uevent_seqnum() if !$cache->{uevent_seqnum};
 982
 983     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
 984
 985     if ($scfg->{base}) {
 986         my ($baseid, undef) = parse_volume_id ($scfg->{base});
 987         activate_storage($cfg, $baseid, $cache);
 988     }
 989
 990     if (!$plugin->check_connection($storeid, $scfg)) {
 991         die "storage '$storeid' is not online\n";
 992     }
 993
 994     $plugin->activate_storage($storeid, $scfg, $cache);
 995
 996     my $newseq = uevent_seqnum ();
 997
 998     # only call udevsettle if there are events
 999     if ($newseq > $cache->{uevent_seqnum}) {
1000         my $timeout = 30;
1001         system ("$UDEVADM settle --timeout=$timeout"); # ignore errors
1002         $cache->{uevent_seqnum} = $newseq;
1003     }
1004
1005     $cache->{activated}->{$storeid} = 1;
1006 }
1007
1008 sub activate_storage_list {
1009     my ($cfg, $storeid_list, $cache) = @_;
1010
1011     $cache = {} if !$cache;
1012
1013     foreach my $storeid (@$storeid_list) {
1014         activate_storage($cfg, $storeid, $cache);
1015     }
1016 }
1017
1018 sub deactivate_storage {
1019     my ($cfg, $storeid) = @_;
1020
1021     my $scfg = storage_config ($cfg, $storeid);
1022     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1023
1024     my $cache = {};
1025     $plugin->deactivate_storage($storeid, $scfg, $cache);
1026 }
1027
1028 sub activate_volumes {
1029     my ($cfg, $vollist, $snapname) = @_;
1030
1031     return if !($vollist && scalar(@$vollist));
1032
1033     my $storagehash = {};
1034     foreach my $volid (@$vollist) {
1035         my ($storeid, undef) = parse_volume_id($volid);
1036         $storagehash->{$storeid} = 1;
1037     }
1038
1039     my $cache = {};
1040
1041     activate_storage_list($cfg, [keys %$storagehash], $cache);
1042
1043     foreach my $volid (@$vollist) {
1044         my ($storeid, $volname) = parse_volume_id($volid);
1045         my $scfg = storage_config($cfg, $storeid);
1046         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1047         $plugin->activate_volume($storeid, $scfg, $volname, $snapname, $cache);
1048     }
1049 }
1050
1051 sub deactivate_volumes {
1052     my ($cfg, $vollist, $snapname) = @_;
1053
1054     return if !($vollist && scalar(@$vollist));
1055
1056     my $cache = {};
1057
1058     my @errlist = ();
1059     foreach my $volid (@$vollist) {
1060         my ($storeid, $volname) = parse_volume_id($volid);
1061
1062         my $scfg = storage_config($cfg, $storeid);
1063         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1064
1065         eval {
1066             $plugin->deactivate_volume($storeid, $scfg, $volname, $snapname, $cache);
1067         };
1068         if (my $err = $@) {
1069             warn $err;
1070             push @errlist, $volid;
1071         }
1072     }
1073
1074     die "volume deactivation failed: " . join(' ', @errlist)
1075         if scalar(@errlist);
1076 }
1077
1078 sub storage_info {
1079     my ($cfg, $content, $includeformat) = @_;
1080
1081     my $ids = $cfg->{ids};
1082
1083     my $info = {};
1084
1085     my @ctypes = PVE::Tools::split_list($content);
1086
1087     my $slist = [];
1088     foreach my $storeid (keys %$ids) {
1089         my $storage_enabled = defined(storage_check_enabled($cfg, $storeid, undef, 1));
1090
1091         if (defined($content)) {
1092             my $want_ctype = 0;
1093             foreach my $ctype (@ctypes) {
1094                 if ($ids->{$storeid}->{content}->{$ctype}) {
1095                     $want_ctype = 1;
1096                     last;
1097                 }
1098             }
1099             next if !$want_ctype || !$storage_enabled;
1100         }
1101
1102         my $type = $ids->{$storeid}->{type};
1103
1104         $info->{$storeid} = {
1105             type => $type,
1106             total => 0,
1107             avail => 0,
1108             used => 0,
1109             shared => $ids->{$storeid}->{shared} ? 1 : 0,
1110             content => PVE::Storage::Plugin::content_hash_to_string($ids->{$storeid}->{content}),
1111             active => 0,
1112             enabled => $storage_enabled ? 1 : 0,
1113         };
1114
1115         push @$slist, $storeid;
1116     }
1117
1118     my $cache = {};
1119
1120     foreach my $storeid (keys %$ids) {
1121         my $scfg = $ids->{$storeid};
1122
1123         next if !$info->{$storeid};
1124         next if !$info->{$storeid}->{enabled};
1125
1126         my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1127         if ($includeformat) {
1128             my $pd = $plugin->plugindata();
1129             $info->{$storeid}->{format} = $pd->{format}
1130                 if $pd->{format};
1131             $info->{$storeid}->{select_existing} = $pd->{select_existing}
1132                 if $pd->{select_existing};
1133         }
1134
1135         eval { activate_storage($cfg, $storeid, $cache); };
1136         if (my $err = $@) {
1137             warn $err;
1138             next;
1139         }
1140
1141         my ($total, $avail, $used, $active) = eval { $plugin->status($storeid, $scfg, $cache); };
1142         warn $@ if $@;
1143         next if !$active;
1144         $info->{$storeid}->{total} = int($total);
1145         $info->{$storeid}->{avail} = int($avail);
1146         $info->{$storeid}->{used} = int($used);
1147         $info->{$storeid}->{active} = $active;
1148     }
1149
1150     return $info;
1151 }
1152
1153 sub resolv_server {
1154     my ($server) = @_;
1155
1156     my ($packed_ip, $family);
1157     eval {
1158         my @res = PVE::Tools::getaddrinfo_all($server);
1159         $family = $res[0]->{family};
1160         $packed_ip = (PVE::Tools::unpack_sockaddr_in46($res[0]->{addr}))[2];
1161     };
1162     if (defined $packed_ip) {
1163         return Socket::inet_ntop($family, $packed_ip);
1164     }
1165     return undef;
1166 }
1167
1168 sub scan_nfs {
1169     my ($server_in) = @_;
1170
1171     my $server;
1172     if (!($server = resolv_server ($server_in))) {
1173         die "unable to resolve address for server '${server_in}'\n";
1174     }
1175
1176     my $cmd = ['/sbin/showmount',  '--no-headers', '--exports', $server];
1177
1178     my $res = {};
1179     run_command($cmd, outfunc => sub {
1180         my $line = shift;
1181
1182         # note: howto handle white spaces in export path??
1183         if ($line =~ m!^(/\S+)\s+(.+)$!) {
1184             $res->{$1} = $2;
1185         }
1186     });
1187
1188     return $res;
1189 }
1190
1191 sub scan_cifs {
1192     my ($server_in, $user, $password, $domain) = @_;
1193
1194     my $server;
1195     if (!($server = resolv_server ($server_in))) {
1196         die "unable to resolve address for server '${server_in}'\n";
1197     }
1198
1199     # we support only Windows grater than 2012 cifsscan so use smb3
1200     my $cmd = ['/usr/bin/smbclient', '-m', 'smb3', '-d', '0', '-L', $server];
1201     if (defined($user)) {
1202         die "password is required" if !defined($password);
1203         push @$cmd, '-U', "$user\%$password";
1204         push @$cmd, '-W', $domain if defined($domain);
1205     } else {
1206         push @$cmd, '-N';
1207     }
1208
1209     my $res = {};
1210     run_command($cmd,
1211                 outfunc => sub {
1212                     my $line = shift;
1213                     if ($line =~ m/(\S+)\s*Disk\s*(\S*)/) {
1214                         $res->{$1} = $2;
1215                     } elsif ($line =~ m/(NT_STATUS_(\S*))/) {
1216                         $res->{$1} = '';
1217                     }
1218                 },
1219                 errfunc => sub {},
1220                 noerr => 1
1221     );
1222
1223     return $res;
1224 }
1225
1226 sub scan_zfs {
1227
1228     my $cmd = ['zfs',  'list', '-t', 'filesystem', '-Hp', '-o', 'name,avail,used'];
1229
1230     my $res = [];
1231     run_command($cmd, outfunc => sub {
1232         my $line = shift;
1233
1234         if ($line =~m/^(\S+)\s+(\S+)\s+(\S+)$/) {
1235             my ($pool, $size_str, $used_str) = ($1, $2, $3);
1236             my $size = $size_str + 0;
1237             my $used = $used_str + 0;
1238             # ignore subvolumes generated by our ZFSPoolPlugin
1239             return if $pool =~ m!/subvol-\d+-[^/]+$!;
1240             return if $pool =~ m!/basevol-\d+-[^/]+$!;
1241             push @$res, { pool => $pool, size => $size, free => $size-$used };
1242         }
1243     });
1244
1245     return $res;
1246 }
1247
1248 sub resolv_portal {
1249     my ($portal, $noerr) = @_;
1250
1251     my ($server, $port) = PVE::Tools::parse_host_and_port($portal);
1252     if ($server) {
1253         if (my $ip = resolv_server($server)) {
1254             $server = $ip;
1255             $server = "[$server]" if $server =~ /^$IPV6RE$/;
1256             return $port ? "$server:$port" : $server;
1257         }
1258     }
1259     return undef if $noerr;
1260
1261     raise_param_exc({ portal => "unable to resolve portal address '$portal'" });
1262 }
1263
1264
1265 sub scan_iscsi {
1266     my ($portal_in) = @_;
1267
1268     my $portal;
1269     if (!($portal = resolv_portal($portal_in))) {
1270         die "unable to parse/resolve portal address '${portal_in}'\n";
1271     }
1272
1273     return PVE::Storage::ISCSIPlugin::iscsi_discovery($portal);
1274 }
1275
1276 sub storage_default_format {
1277     my ($cfg, $storeid) = @_;
1278
1279     my $scfg = storage_config ($cfg, $storeid);
1280
1281     return PVE::Storage::Plugin::default_format($scfg);
1282 }
1283
1284 sub vgroup_is_used {
1285     my ($cfg, $vgname) = @_;
1286
1287     foreach my $storeid (keys %{$cfg->{ids}}) {
1288         my $scfg = storage_config($cfg, $storeid);
1289         if ($scfg->{type} eq 'lvm' && $scfg->{vgname} eq $vgname) {
1290             return 1;
1291         }
1292     }
1293
1294     return undef;
1295 }
1296
1297 sub target_is_used {
1298     my ($cfg, $target) = @_;
1299
1300     foreach my $storeid (keys %{$cfg->{ids}}) {
1301         my $scfg = storage_config($cfg, $storeid);
1302         if ($scfg->{type} eq 'iscsi' && $scfg->{target} eq $target) {
1303             return 1;
1304         }
1305     }
1306
1307     return undef;
1308 }
1309
1310 sub volume_is_used {
1311     my ($cfg, $volid) = @_;
1312
1313     foreach my $storeid (keys %{$cfg->{ids}}) {
1314         my $scfg = storage_config($cfg, $storeid);
1315         if ($scfg->{base} && $scfg->{base} eq $volid) {
1316             return 1;
1317         }
1318     }
1319
1320     return undef;
1321 }
1322
1323 sub storage_is_used {
1324     my ($cfg, $storeid) = @_;
1325
1326     foreach my $sid (keys %{$cfg->{ids}}) {
1327         my $scfg = storage_config($cfg, $sid);
1328         next if !$scfg->{base};
1329         my ($st) = parse_volume_id($scfg->{base});
1330         return 1 if $st && $st eq $storeid;
1331     }
1332
1333     return undef;
1334 }
1335
1336 sub foreach_volid {
1337     my ($list, $func) = @_;
1338
1339     return if !$list;
1340
1341     foreach my $sid (keys %$list) {
1342        foreach my $info (@{$list->{$sid}}) {
1343            my $volid = $info->{volid};
1344            my ($sid1, $volname) = parse_volume_id($volid, 1);
1345            if ($sid1 && $sid1 eq $sid) {
1346                &$func ($volid, $sid, $info);
1347            } else {
1348                warn "detected strange volid '$volid' in volume list for '$sid'\n";
1349            }
1350        }
1351     }
1352 }
1353
1354 sub decompressor_info {
1355     my ($format, $comp) = @_;
1356
1357     if ($format eq 'tgz' && !defined($comp)) {
1358         ($format, $comp) = ('tar', 'gz');
1359     }
1360
1361     my $decompressor = {
1362         tar => {
1363             gz => ['tar', '-z'],
1364             lzo => ['tar', '--lzop'],
1365         },
1366         vma => {
1367             gz => ['zcat'],
1368             lzo => ['lzop', '-d', '-c'],
1369         },
1370     };
1371
1372     die "ERROR: archive format not defined\n"
1373         if !defined($decompressor->{$format});
1374
1375     my $decomp = $decompressor->{$format}->{$comp} if $comp;
1376
1377     my $info = {
1378         format => $format,
1379         compression => $comp,
1380         decompressor => $decomp,
1381     };
1382
1383     return $info;
1384 }
1385
1386 sub archive_info {
1387     my ($archive) = shift;
1388     my $info;
1389
1390     my $volid = basename($archive);
1391     if ($volid =~ /vzdump-(lxc|openvz|qemu)-\d+-(?:\d{4})_(?:\d{2})_(?:\d{2})-(?:\d{2})_(?:\d{2})_(?:\d{2})\.(tgz$|tar|vma)(?:\.(gz|lzo))?$/) {
1392         $info = decompressor_info($2, $3);
1393         $info->{type} = $1;
1394     } else {
1395         die "ERROR: couldn't determine format and compression type\n";
1396     }
1397
1398     return $info;
1399 }
1400
1401 sub extract_vzdump_config_tar {
1402     my ($archive, $conf_re) = @_;
1403
1404     die "ERROR: file '$archive' does not exist\n" if ! -f $archive;
1405
1406     my $pid = open(my $fh, '-|', 'tar', 'tf', $archive) ||
1407        die "unable to open file '$archive'\n";
1408
1409     my $file;
1410     while (defined($file = <$fh>)) {
1411         if ($file =~ $conf_re) {
1412             $file = $1; # untaint
1413             last;
1414         }
1415     }
1416
1417     kill 15, $pid;
1418     waitpid $pid, 0;
1419     close $fh;
1420
1421     die "ERROR: archive contains no configuration file\n" if !$file;
1422     chomp $file;
1423
1424     my $raw = '';
1425     my $out = sub {
1426         my $output = shift;
1427         $raw .= "$output\n";
1428     };
1429
1430     PVE::Tools::run_command(['tar', '-xpOf', $archive, $file, '--occurrence'], outfunc => $out);
1431
1432     return wantarray ? ($raw, $file) : $raw;
1433 }
1434
1435 sub extract_vzdump_config_vma {
1436     my ($archive, $comp) = @_;
1437
1438     my $cmd;
1439     my $raw = '';
1440     my $out = sub {
1441         my $output = shift;
1442         $raw .= "$output\n";
1443     };
1444
1445
1446     my $info = archive_info($archive);
1447     $comp //= $info->{compression};
1448     my $decompressor = $info->{decompressor};
1449
1450     if ($comp) {
1451         $cmd = [ [@$decompressor, $archive], ["vma", "config", "-"] ];
1452
1453         # in some cases, lzop/zcat exits with 1 when its stdout pipe is
1454         # closed early by vma, detect this and ignore the exit code later
1455         my $broken_pipe;
1456         my $errstring;
1457         my $err = sub {
1458             my $output = shift;
1459             if ($output =~ m/lzop: Broken pipe: <stdout>/ || $output =~ m/gzip: stdout: Broken pipe/) {
1460                 $broken_pipe = 1;
1461             } elsif (!defined ($errstring) && $output !~ m/^\s*$/) {
1462                 $errstring = "Failed to extract config from VMA archive: $output\n";
1463             }
1464         };
1465
1466         # in other cases, the pipeline will exit with exit code 141
1467         # because of the broken pipe, handle / ignore this as well
1468         my $rc;
1469         eval {
1470             $rc = PVE::Tools::run_command($cmd, outfunc => $out, errfunc => $err, noerr => 1);
1471         };
1472         my $rerr = $@;
1473
1474         # use exit code if no stderr output and not just broken pipe
1475         if (!$errstring && !$broken_pipe && $rc != 0 && $rc != 141) {
1476             die "$rerr\n" if $rerr;
1477             die "config extraction failed with exit code $rc\n";
1478         }
1479         die "$errstring\n" if $errstring;
1480     } else {
1481         # simple case without compression and weird piping behaviour
1482         PVE::Tools::run_command(["vma", "config", $archive], outfunc => $out);
1483     }
1484
1485     return wantarray ? ($raw, undef) : $raw;
1486 }
1487
1488 sub extract_vzdump_config {
1489     my ($cfg, $volid) = @_;
1490
1491     my ($storeid, $volname) = parse_volume_id($volid);
1492     if (defined($storeid)) {
1493         my $scfg = storage_config($cfg, $storeid);
1494         if ($scfg->{type} eq 'pbs') {
1495             storage_check_enabled($cfg, $storeid);
1496             return PVE::Storage::PBSPlugin->extract_vzdump_config($scfg, $volname, $storeid);
1497         }
1498     }
1499
1500     my $archive = abs_filesystem_path($cfg, $volid);
1501     my $info = archive_info($archive);
1502     my $format = $info->{format};
1503     my $comp = $info->{compression};
1504     my $type = $info->{type};
1505
1506     if ($type eq 'lxc' || $type eq 'openvz') {
1507         return extract_vzdump_config_tar($archive, qr!^(\./etc/vzdump/(pct|vps)\.conf)$!);
1508     } elsif ($type eq 'qemu') {
1509         if ($format eq 'tar') {
1510             return extract_vzdump_config_tar($archive, qr!\(\./qemu-server\.conf\)!);
1511         } else {
1512             return extract_vzdump_config_vma($archive, $comp);
1513         }
1514     } else {
1515         die "cannot determine backup guest type for backup archive '$volid'\n";
1516     }
1517 }
1518
1519 sub volume_export {
1520     my ($cfg, $fh, $volid, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
1521
1522     my ($storeid, $volname) = parse_volume_id($volid, 1);
1523     die "cannot export volume '$volid'\n" if !$storeid;
1524     my $scfg = storage_config($cfg, $storeid);
1525     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1526     return $plugin->volume_export($scfg, $storeid, $fh, $volname, $format,
1527                                   $snapshot, $base_snapshot, $with_snapshots);
1528 }
1529
1530 sub volume_import {
1531     my ($cfg, $fh, $volid, $format, $base_snapshot, $with_snapshots, $allow_rename) = @_;
1532
1533     my ($storeid, $volname) = parse_volume_id($volid, 1);
1534     die "cannot import into volume '$volid'\n" if !$storeid;
1535     my $scfg = storage_config($cfg, $storeid);
1536     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1537     return $plugin->volume_import($scfg, $storeid, $fh, $volname, $format,
1538                                   $base_snapshot, $with_snapshots, $allow_rename) // $volid;
1539 }
1540
1541 sub volume_export_formats {
1542     my ($cfg, $volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1543
1544     my ($storeid, $volname) = parse_volume_id($volid, 1);
1545     return if !$storeid;
1546     my $scfg = storage_config($cfg, $storeid);
1547     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1548     return $plugin->volume_export_formats($scfg, $storeid, $volname,
1549                                           $snapshot, $base_snapshot,
1550                                           $with_snapshots);
1551 }
1552
1553 sub volume_import_formats {
1554     my ($cfg, $volid, $base_snapshot, $with_snapshots) = @_;
1555
1556     my ($storeid, $volname) = parse_volume_id($volid, 1);
1557     return if !$storeid;
1558     my $scfg = storage_config($cfg, $storeid);
1559     my $plugin = PVE::Storage::Plugin->lookup($scfg->{type});
1560     return $plugin->volume_import_formats($scfg, $storeid, $volname,
1561                                           $base_snapshot, $with_snapshots);
1562 }
1563
1564 sub volume_transfer_formats {
1565     my ($cfg, $src_volid, $dst_volid, $snapshot, $base_snapshot, $with_snapshots) = @_;
1566     my @export_formats = volume_export_formats($cfg, $src_volid, $snapshot, $base_snapshot, $with_snapshots);
1567     my @import_formats = volume_import_formats($cfg, $dst_volid, $base_snapshot, $with_snapshots);
1568     my %import_hash = map { $_ => 1 } @import_formats;
1569     my @common = grep { $import_hash{$_} } @export_formats;
1570     return @common;
1571 }
1572
1573 sub volume_imported_message {
1574     my ($volid, $want_pattern) = @_;
1575
1576     if ($want_pattern) {
1577         return qr/successfully imported '([^']*)'$/;
1578     } else {
1579         return "successfully imported '$volid'\n";
1580     }
1581 }
1582
1583 # bash completion helper
1584
1585 sub complete_storage {
1586     my ($cmdname, $pname, $cvalue) = @_;
1587
1588     my $cfg = PVE::Storage::config();
1589
1590     return  $cmdname eq 'add' ? [] : [ PVE::Storage::storage_ids($cfg) ];
1591 }
1592
1593 sub complete_storage_enabled {
1594     my ($cmdname, $pname, $cvalue) = @_;
1595
1596     my $res = [];
1597
1598     my $cfg = PVE::Storage::config();
1599     foreach my $sid (keys %{$cfg->{ids}}) {
1600         next if !storage_check_enabled($cfg, $sid, undef, 1);
1601         push @$res, $sid;
1602     }
1603     return $res;
1604 }
1605
1606 sub complete_content_type {
1607     my ($cmdname, $pname, $cvalue) = @_;
1608
1609     return [qw(rootdir images vztmpl iso backup snippets)];
1610 }
1611
1612 sub complete_volume {
1613     my ($cmdname, $pname, $cvalue) = @_;
1614
1615     my $cfg = config();
1616
1617     my $storage_list = complete_storage_enabled();
1618
1619     if ($cvalue =~ m/^([^:]+):/) {
1620         $storage_list = [ $1 ];
1621     } else {
1622         if (scalar(@$storage_list) > 1) {
1623             # only list storage IDs to avoid large listings
1624             my $res = [];
1625             foreach my $storeid (@$storage_list) {
1626                 # Hack: simply return 2 artificial values, so that
1627                 # completions does not finish
1628                 push @$res, "$storeid:volname", "$storeid:...";
1629             }
1630             return $res;
1631         }
1632     }
1633
1634     my $res = [];
1635     foreach my $storeid (@$storage_list) {
1636         my $vollist = PVE::Storage::volume_list($cfg, $storeid);
1637
1638         foreach my $item (@$vollist) {
1639             push @$res, $item->{volid};
1640         }
1641     }
1642
1643     return $res;
1644 }
1645
1646 # Various io-heavy operations require io/bandwidth limits which can be
1647 # configured on multiple levels: The global defaults in datacenter.cfg, and
1648 # per-storage overrides. When we want to do a restore from storage A to storage
1649 # B, we should take the smaller limit defined for storages A and B, and if no
1650 # such limit was specified, use the one from datacenter.cfg.
1651 sub get_bandwidth_limit {
1652     my ($operation, $storage_list, $override) = @_;
1653
1654     # called for each limit (global, per-storage) with the 'default' and the
1655     # $operation limit and should udpate $override for every limit affecting
1656     # us.
1657     my $use_global_limits = 0;
1658     my $apply_limit = sub {
1659         my ($bwlimit) = @_;
1660         if (defined($bwlimit)) {
1661             my $limits = PVE::JSONSchema::parse_property_string('bwlimit', $bwlimit);
1662             my $limit = $limits->{$operation} // $limits->{default};
1663             if (defined($limit)) {
1664                 if (!$override || $limit < $override) {
1665                     $override = $limit;
1666                 }
1667                 return;
1668             }
1669         }
1670         # If there was no applicable limit, try to apply the global ones.
1671         $use_global_limits = 1;
1672     };
1673
1674     my ($rpcenv, $authuser);
1675     if (defined($override)) {
1676         $rpcenv = PVE::RPCEnvironment->get();
1677         $authuser = $rpcenv->get_user();
1678     }
1679
1680     # Apply per-storage limits - if there are storages involved.
1681     if (defined($storage_list) && @$storage_list) {
1682         my $config = config();
1683
1684         # The Datastore.Allocate permission allows us to modify the per-storage
1685         # limits, therefore it also allows us to override them.
1686         # Since we have most likely multiple storages to check, do a quick check on
1687         # the general '/storage' path to see if we can skip the checks entirely:
1688         return $override if $rpcenv && $rpcenv->check($authuser, '/storage', ['Datastore.Allocate'], 1);
1689
1690         my %done;
1691         foreach my $storage (@$storage_list) {
1692             next if !defined($storage);
1693             # Avoid duplicate checks:
1694             next if $done{$storage};
1695             $done{$storage} = 1;
1696
1697             # Otherwise we may still have individual /storage/$ID permissions:
1698             if (!$rpcenv || !$rpcenv->check($authuser, "/storage/$storage", ['Datastore.Allocate'], 1)) {
1699                 # And if not: apply the limits.
1700                 my $storecfg = storage_config($config, $storage);
1701                 $apply_limit->($storecfg->{bwlimit});
1702             }
1703         }
1704
1705         # Storage limits take precedence over the datacenter defaults, so if
1706         # a limit was applied:
1707         return $override if !$use_global_limits;
1708     }
1709
1710     # Sys.Modify on '/' means we can change datacenter.cfg which contains the
1711     # global default limits.
1712     if (!$rpcenv || !$rpcenv->check($authuser, '/', ['Sys.Modify'], 1)) {
1713         # So if we cannot modify global limits, apply them to our currently
1714         # requested override.
1715         my $dc = cfs_read_file('datacenter.cfg');
1716         $apply_limit->($dc->{bwlimit});
1717     }
1718
1719     return $override;
1720 }
1721
1722 # checks if the storage id is available and dies if not
1723 sub assert_sid_unused {
1724     my ($sid) = @_;
1725
1726     my $cfg = config();
1727     if (my $scfg = storage_config($cfg, $sid, 1)) {
1728         die "storage ID '$sid' already defined\n";
1729     }
1730
1731     return undef;
1732 }
1733
1734 1;