PVE/Storage/CIFSPlugin.pm

   1 package PVE::Storage::CIFSPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use Net::IP;
   6 use PVE::Tools qw(run_command);
   7 use PVE::ProcFSTools;
   8 use File::Path;
   9 use PVE::Storage::Plugin;
  10 use PVE::JSONSchema qw(get_standard_option);
  11
  12 use base qw(PVE::Storage::Plugin);
  13
  14 # CIFS helper functions
  15
  16 sub cifs_is_mounted {
  17     my ($server, $share, $mountpoint, $mountdata) = @_;
  18
  19     $server = "[$server]" if Net::IP::ip_is_ipv6($server);
  20     my $source = "//${server}/$share";
  21     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  22
  23     return $mountpoint if grep {
  24         $_->[2] =~ /^cifs/ &&
  25         $_->[0] =~ m|^\Q$source\E/?$| &&
  26         $_->[1] eq $mountpoint
  27     } @$mountdata;
  28     return undef;
  29 }
  30
  31 sub cifs_cred_file_name {
  32     my ($storeid) = @_;
  33     return "/etc/pve/priv/storage/${storeid}.cred";
  34 }
  35
  36 sub cifs_delete_credentials {
  37     my ($storeid) = @_;
  38
  39     if (my $cred_file = get_cred_file($storeid)) {
  40         unlink($cred_file) or warn "removing cifs credientials '$cred_file' failed: $!\n";
  41     }
  42 }
  43
  44 sub cifs_set_credentials {
  45     my ($password, $storeid) = @_;
  46
  47     my $cred_file = cifs_cred_file_name($storeid);
  48     mkdir "/etc/pve/priv/storage";
  49
  50     PVE::Tools::file_set_contents($cred_file, "password=$password\n");
  51
  52     return $cred_file;
  53 }
  54
  55 sub get_cred_file {
  56     my ($storeid) = @_;
  57
  58     my $cred_file = cifs_cred_file_name($storeid);
  59
  60     if (-e $cred_file) {
  61         return $cred_file;
  62     } elsif ("/etc/pve/priv/${storeid}.cred") {
  63         # FIXME: remove fallback with 7.0 by doing a rename on upgrade from 6.x
  64         return "/etc/pve/priv/${storeid}.cred";
  65     }
  66     return undef;
  67 }
  68
  69 sub cifs_mount {
  70     my ($server, $share, $mountpoint, $storeid, $smbver, $user, $domain) = @_;
  71
  72     $server = "[$server]" if Net::IP::ip_is_ipv6($server);
  73     my $source = "//${server}/$share";
  74
  75     my $cmd = ['/bin/mount', '-t', 'cifs', $source, $mountpoint, '-o', 'soft', '-o'];
  76
  77     if (my $cred_file = get_cred_file($storeid)) {
  78         push @$cmd, "username=$user", '-o', "credentials=$cred_file";
  79         push @$cmd, '-o', "domain=$domain" if defined($domain);
  80     } else {
  81         push @$cmd, 'guest,username=guest';
  82     }
  83
  84     push @$cmd, '-o', defined($smbver) ? "vers=$smbver" : "vers=3.0";
  85
  86     run_command($cmd, errmsg => "mount error");
  87 }
  88
  89 # Configuration
  90
  91 sub type {
  92     return 'cifs';
  93 }
  94
  95 sub plugindata {
  96     return {
  97         content => [ { images => 1, rootdir => 1, vztmpl => 1, iso => 1,
  98                    backup => 1, snippets => 1}, { images => 1 }],
  99         format => [ { raw => 1, qcow2 => 1, vmdk => 1 } , 'raw' ],
 100     };
 101 }
 102
 103 sub properties {
 104     return {
 105         share => {
 106             description => "CIFS share.",
 107             type => 'string',
 108         },
 109         password => {
 110             description => "Password for CIFS share.",
 111             type => 'string',
 112             maxLength => 256,
 113         },
 114         domain => {
 115             description => "CIFS domain.",
 116             type => 'string',
 117             optional => 1,
 118             maxLength => 256,
 119         },
 120         smbversion => {
 121             description => "SMB protocol version",
 122             type => 'string',
 123             enum => ['2.0', '2.1', '3.0'],
 124             optional => 1,
 125         },
 126     };
 127 }
 128
 129 sub options {
 130     return {
 131         path => { fixed => 1 },
 132         server => { fixed => 1 },
 133         share => { fixed => 1 },
 134         nodes => { optional => 1 },
 135         disable => { optional => 1 },
 136         maxfiles => { optional => 1 },
 137         content => { optional => 1 },
 138         format => { optional => 1 },
 139         username => { optional => 1 },
 140         password => { optional => 1},
 141         domain => { optional => 1},
 142         smbversion => { optional => 1},
 143         mkdir => { optional => 1 },
 144         bwlimit => { optional => 1 },
 145     };
 146 }
 147
 148
 149 sub check_config {
 150     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 151
 152     $config->{path} = "/mnt/pve/$sectionId" if $create && !$config->{path};
 153
 154     return $class->SUPER::check_config($sectionId, $config, $create, $skipSchemaCheck);
 155 }
 156
 157 # Storage implementation
 158
 159 sub on_add_hook {
 160     my ($class, $storeid, $scfg, %param) = @_;
 161
 162     if (defined($param{password})) {
 163         cifs_set_credentials($param{password}, $storeid);
 164     } else {
 165         cifs_delete_credentials($storeid);
 166     }
 167 }
 168
 169 sub on_update_hook {
 170     my ($class, $storeid, $scfg, %param) = @_;
 171
 172     return if !exists($param{password});
 173
 174     if (defined($param{password})) {
 175         cifs_set_credentials($param{password}, $storeid);
 176     } else {
 177         cifs_delete_credentials($storeid);
 178     }
 179 }
 180
 181 sub on_delete_hook {
 182     my ($class, $storeid, $scfg) = @_;
 183
 184     cifs_delete_credentials($storeid);
 185 }
 186
 187 sub status {
 188     my ($class, $storeid, $scfg, $cache) = @_;
 189
 190     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 191         if !$cache->{mountdata};
 192
 193     my $path = $scfg->{path};
 194     my $server = $scfg->{server};
 195     my $share = $scfg->{share};
 196
 197     return undef
 198         if !cifs_is_mounted($server, $share, $path, $cache->{mountdata});
 199
 200     return $class->SUPER::status($storeid, $scfg, $cache);
 201 }
 202
 203 sub activate_storage {
 204     my ($class, $storeid, $scfg, $cache) = @_;
 205
 206     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 207         if !$cache->{mountdata};
 208
 209     my $path = $scfg->{path};
 210     my $server = $scfg->{server};
 211     my $share = $scfg->{share};
 212
 213     if (!cifs_is_mounted($server, $share, $path, $cache->{mountdata})) {
 214
 215         mkpath $path if !(defined($scfg->{mkdir}) && !$scfg->{mkdir});
 216
 217         die "unable to activate storage '$storeid' - " .
 218             "directory '$path' does not exist\n" if ! -d $path;
 219
 220         cifs_mount($server, $share, $path, $storeid, $scfg->{smbversion},
 221             $scfg->{username}, $scfg->{domain});
 222     }
 223
 224     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 225 }
 226
 227 sub deactivate_storage {
 228     my ($class, $storeid, $scfg, $cache) = @_;
 229
 230     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 231         if !$cache->{mountdata};
 232
 233     my $path = $scfg->{path};
 234     my $server = $scfg->{server};
 235     my $share = $scfg->{share};
 236
 237     if (cifs_is_mounted($server, $share, $path, $cache->{mountdata})) {
 238         my $cmd = ['/bin/umount', $path];
 239         run_command($cmd, errmsg => 'umount error');
 240     }
 241 }
 242
 243 sub check_connection {
 244     my ($class, $storeid, $scfg) = @_;
 245
 246     my $servicename = '//'.$scfg->{server}.'/'.$scfg->{share};
 247
 248     my $cmd = ['/usr/bin/smbclient', $servicename, '-d', '0', '-m'];
 249
 250     push @$cmd, $scfg->{smbversion} ? "smb".int($scfg->{smbversion}) : 'smb3';
 251
 252     if (my $cred_file = get_cred_file($storeid)) {
 253         push @$cmd, '-U', $scfg->{username}, '-A', $cred_file;
 254         push @$cmd, '-W', $scfg->{domain} if defined($scfg->{domain});
 255     } else {
 256         push @$cmd, '-U', 'Guest','-N';
 257     }
 258
 259     push @$cmd, '-c', 'echo 1 0';
 260
 261     my $out_str;
 262     eval {
 263         run_command($cmd, timeout => 2, outfunc => sub {$out_str .= shift;},
 264                     errfunc => sub {});
 265     };
 266
 267     if (my $err = $@) {
 268         die "$out_str\n" if defined($out_str) &&
 269             ($out_str =~ m/NT_STATUS_ACCESS_DENIED/);
 270         return 0;
 271     }
 272
 273     return 1;
 274 }
 275
 276 1;