PVE/Storage/CIFSPlugin.pm

   1 package PVE::Storage::CIFSPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use Net::IP;
   6 use PVE::Tools qw(run_command);
   7 use PVE::ProcFSTools;
   8 use File::Path;
   9 use PVE::Storage::Plugin;
  10 use PVE::JSONSchema qw(get_standard_option);
  11
  12 use base qw(PVE::Storage::Plugin);
  13
  14 # CIFS helper functions
  15
  16 sub cifs_is_mounted {
  17     my ($server, $share, $mountpoint, $mountdata) = @_;
  18
  19     $server = "[$server]" if Net::IP::ip_is_ipv6($server);
  20     my $source = "//${server}/$share";
  21     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  22
  23     return $mountpoint if grep {
  24         $_->[2] =~ /^cifs/ &&
  25         $_->[0] =~ m|^\Q$source\E/?$| &&
  26         $_->[1] eq $mountpoint
  27     } @$mountdata;
  28     return undef;
  29 }
  30
  31 sub cifs_cred_file_name {
  32     my ($storeid) = @_;
  33
  34     return "/etc/pve/priv/${storeid}.cred";
  35 }
  36
  37 sub cifs_set_credentials {
  38     my ($password, $storeid) = @_;
  39
  40     my $cred_file = cifs_cred_file_name($storeid);
  41
  42     PVE::Tools::file_set_contents($cred_file, "password=$password\n");
  43
  44     return $cred_file;
  45 }
  46
  47 sub get_cred_file {
  48     my ($storeid) = @_;
  49
  50     my $cred_file = cifs_cred_file_name($storeid);
  51
  52     return -e $cred_file ? $cred_file : undef;
  53 }
  54
  55 sub cifs_mount {
  56     my ($server, $share, $mountpoint, $storeid, $smbver, $user, $domain) = @_;
  57
  58     $server = "[$server]" if Net::IP::ip_is_ipv6($server);
  59     my $source = "//${server}/$share";
  60
  61     my $cmd = ['/bin/mount', '-t', 'cifs', $source, $mountpoint, '-o', 'soft', '-o'];
  62
  63     if (my $cred_file = get_cred_file($storeid)) {
  64         push @$cmd, "username=$user", '-o', "credentials=$cred_file";
  65         push @$cmd, '-o', "domain=$domain" if defined($domain);
  66     } else {
  67         push @$cmd, 'guest,username=guest';
  68     }
  69
  70     push @$cmd, '-o', defined($smbver) ? "vers=$smbver" : "vers=3.0";
  71
  72     run_command($cmd, errmsg => "mount error");
  73 }
  74
  75 # Configuration
  76
  77 sub type {
  78     return 'cifs';
  79 }
  80
  81 sub plugindata {
  82     return {
  83         content => [ { images => 1, rootdir => 1, vztmpl => 1, iso => 1,
  84                    backup => 1}, { images => 1 }],
  85         format => [ { raw => 1, qcow2 => 1, vmdk => 1 } , 'raw' ],
  86     };
  87 }
  88
  89 sub properties {
  90     return {
  91         share => {
  92             description => "CIFS share.",
  93             type => 'string',
  94         },
  95         password => {
  96             description => "Password for CIFS share.",
  97             type => 'string',
  98             maxLength => 256,
  99         },
 100         domain => {
 101             description => "CIFS domain.",
 102             type => 'string',
 103             optional => 1,
 104             maxLength => 256,
 105         },
 106         smbversion => {
 107             description => "SMB protocol version",
 108             type => 'string',
 109             enum => ['2.0', '2.1', '3.0'],
 110             optional => 1,
 111         },
 112     };
 113 }
 114
 115 sub options {
 116     return {
 117         path => { fixed => 1 },
 118         server => { fixed => 1 },
 119         share => { fixed => 1 },
 120         nodes => { optional => 1 },
 121         disable => { optional => 1 },
 122         maxfiles => { optional => 1 },
 123         content => { optional => 1 },
 124         format => { optional => 1 },
 125         username => { optional => 1 },
 126         password => { optional => 1},
 127         domain => { optional => 1},
 128         smbversion => { optional => 1},
 129     };
 130 }
 131
 132
 133 sub check_config {
 134     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 135
 136     $config->{path} = "/mnt/pve/$sectionId" if $create && !$config->{path};
 137
 138     return $class->SUPER::check_config($sectionId, $config, $create, $skipSchemaCheck);
 139 }
 140
 141 # Storage implementation
 142
 143 sub status {
 144     my ($class, $storeid, $scfg, $cache) = @_;
 145
 146     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 147         if !$cache->{mountdata};
 148
 149     my $path = $scfg->{path};
 150     my $server = $scfg->{server};
 151     my $share = $scfg->{share};
 152
 153     return undef
 154         if !cifs_is_mounted($server, $share, $path, $cache->{mountdata});
 155
 156     return $class->SUPER::status($storeid, $scfg, $cache);
 157 }
 158
 159 sub activate_storage {
 160     my ($class, $storeid, $scfg, $cache) = @_;
 161
 162     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 163         if !$cache->{mountdata};
 164
 165     my $path = $scfg->{path};
 166     my $server = $scfg->{server};
 167     my $share = $scfg->{share};
 168
 169     if (!cifs_is_mounted($server, $share, $path, $cache->{mountdata})) {
 170
 171         mkpath $path;
 172
 173         die "unable to activate storage '$storeid' - " .
 174             "directory '$path' does not exist\n" if ! -d $path;
 175
 176         cifs_mount($server, $share, $path, $storeid, $scfg->{smbversion},
 177             $scfg->{username}, $scfg->{domain});
 178     }
 179
 180     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 181 }
 182
 183 sub deactivate_storage {
 184     my ($class, $storeid, $scfg, $cache) = @_;
 185
 186     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 187         if !$cache->{mountdata};
 188
 189     my $path = $scfg->{path};
 190     my $server = $scfg->{server};
 191     my $share = $scfg->{share};
 192
 193     if (cifs_is_mounted($server, $share, $path, $cache->{mountdata})) {
 194         my $cmd = ['/bin/umount', $path];
 195         run_command($cmd, errmsg => 'umount error');
 196     }
 197 }
 198
 199 sub check_connection {
 200     my ($class, $storeid, $scfg) = @_;
 201
 202     my $servicename = '//'.$scfg->{server}.'/'.$scfg->{share};
 203
 204     my $cmd = ['/usr/bin/smbclient', $servicename, '-d', '0', '-m'];
 205
 206     push @$cmd, $scfg->{smbversion} ? "smb".int($scfg->{smbversion}) : 'smb3';
 207
 208     if (my $cred_file = get_cred_file($storeid)) {
 209         push @$cmd, '-U', $scfg->{username}, '-A', $cred_file;
 210         push @$cmd, '-W', $scfg->{domain} if defined($scfg->{domain});
 211     } else {
 212         push @$cmd, '-U', 'Guest','-N';
 213     }
 214
 215     push @$cmd, '-c', 'echo 1 0';
 216
 217     my $out_str;
 218     eval {
 219         run_command($cmd, timeout => 2, outfunc => sub {$out_str .= shift;},
 220                     errfunc => sub {});
 221     };
 222
 223     if (my $err = $@) {
 224         die "$out_str\n" if defined($out_str) &&
 225             ($out_str =~ m/NT_STATUS_ACCESS_DENIED/);
 226         return 0;
 227     }
 228
 229     return 1;
 230 }
 231
 232 1;