PVE/Storage/CIFSPlugin.pm

   1 package PVE::Storage::CIFSPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use Net::IP;
   6 use PVE::Tools qw(run_command);
   7 use PVE::ProcFSTools;
   8 use File::Path;
   9 use PVE::Storage::Plugin;
  10 use PVE::JSONSchema qw(get_standard_option);
  11
  12 use base qw(PVE::Storage::Plugin);
  13
  14 # CIFS helper functions
  15
  16 sub cifs_is_mounted {
  17     my ($server, $share, $mountpoint, $mountdata) = @_;
  18
  19     $server = "[$server]" if Net::IP::ip_is_ipv6($server);
  20     my $source = "//${server}/$share";
  21     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  22
  23     return $mountpoint if grep {
  24         $_->[2] =~ /^cifs/ &&
  25         $_->[0] =~ m|^\Q$source\E/?$| &&
  26         $_->[1] eq $mountpoint
  27     } @$mountdata;
  28     return undef;
  29 }
  30
  31 sub cifs_cred_file_name {
  32     my ($storeid) = @_;
  33
  34     return "/etc/pve/priv/${storeid}.cred";
  35 }
  36
  37 sub cifs_set_credentials {
  38     my ($password, $storeid) = @_;
  39
  40     my $cred_file = cifs_cred_file_name($storeid);
  41
  42     PVE::Tools::file_set_contents($cred_file, "password=$password\n");
  43
  44     return $cred_file;
  45 }
  46
  47 sub get_cred_file {
  48     my ($storeid) = @_;
  49
  50     my $cred_file = cifs_cred_file_name($storeid);
  51
  52     return -e $cred_file ? $cred_file : undef;
  53 }
  54
  55 sub cifs_mount {
  56     my ($server, $share, $mountpoint, $storeid, $smbver, $user, $domain) = @_;
  57
  58     $server = "[$server]" if Net::IP::ip_is_ipv6($server);
  59     my $source = "//${server}/$share";
  60
  61     my $cmd = ['/bin/mount', '-t', 'cifs', $source, $mountpoint, '-o', 'soft', '-o'];
  62
  63     if (my $cred_file = get_cred_file($storeid)) {
  64         push @$cmd, "username=$user", '-o', "credentials=$cred_file";
  65         push @$cmd, '-o', "domain=$domain" if defined($domain);
  66     } else {
  67         push @$cmd, 'guest,username=guest';
  68     }
  69
  70     push @$cmd, '-o', defined($smbver) ? "vers=$smbver" : "vers=3.0";
  71
  72     run_command($cmd, errmsg => "mount error");
  73 }
  74
  75 # Configuration
  76
  77 sub type {
  78     return 'cifs';
  79 }
  80
  81 sub plugindata {
  82     return {
  83         content => [ { images => 1, rootdir => 1, vztmpl => 1, iso => 1,
  84                    backup => 1}, { images => 1 }],
  85         format => [ { raw => 1, qcow2 => 1, vmdk => 1 } , 'raw' ],
  86     };
  87 }
  88
  89 sub properties {
  90     return {
  91         share => {
  92             description => "CIFS share.",
  93             type => 'string',
  94         },
  95         password => {
  96             description => "Password for CIFS share.",
  97             type => 'string',
  98             maxLength => 256,
  99         },
 100         domain => {
 101             description => "CIFS domain.",
 102             type => 'string',
 103             optional => 1,
 104             maxLength => 256,
 105         },
 106         smbversion => {
 107             description => "SMB protocol version",
 108             type => 'string',
 109             enum => ['2.0', '2.1', '3.0'],
 110             optional => 1,
 111         },
 112     };
 113 }
 114
 115 sub options {
 116     return {
 117         path => { fixed => 1 },
 118         server => { fixed => 1 },
 119         share => { fixed => 1 },
 120         nodes => { optional => 1 },
 121         disable => { optional => 1 },
 122         maxfiles => { optional => 1 },
 123         content => { optional => 1 },
 124         format => { optional => 1 },
 125         username => { optional => 1 },
 126         password => { optional => 1},
 127         domain => { optional => 1},
 128         smbversion => { optional => 1},
 129         mkdir => { optional => 1 },
 130     };
 131 }
 132
 133
 134 sub check_config {
 135     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 136
 137     $config->{path} = "/mnt/pve/$sectionId" if $create && !$config->{path};
 138
 139     return $class->SUPER::check_config($sectionId, $config, $create, $skipSchemaCheck);
 140 }
 141
 142 # Storage implementation
 143
 144 sub on_add_hook {
 145     my ($class, $storeid, $scfg, %param) = @_;
 146
 147     if (my $password = $param{password}) {
 148         cifs_set_credentials($password, $storeid);
 149     }
 150 }
 151
 152 sub on_delete_hook {
 153     my ($class, $storeid, $scfg) = @_;
 154
 155     my $cred_file = cifs_cred_file_name($storeid);
 156     if (-f $cred_file) {
 157         unlink($cred_file) or warn "removing cifs credientials '$cred_file' failed: $!\n";
 158     }
 159 }
 160
 161 sub status {
 162     my ($class, $storeid, $scfg, $cache) = @_;
 163
 164     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 165         if !$cache->{mountdata};
 166
 167     my $path = $scfg->{path};
 168     my $server = $scfg->{server};
 169     my $share = $scfg->{share};
 170
 171     return undef
 172         if !cifs_is_mounted($server, $share, $path, $cache->{mountdata});
 173
 174     return $class->SUPER::status($storeid, $scfg, $cache);
 175 }
 176
 177 sub activate_storage {
 178     my ($class, $storeid, $scfg, $cache) = @_;
 179
 180     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 181         if !$cache->{mountdata};
 182
 183     my $path = $scfg->{path};
 184     my $server = $scfg->{server};
 185     my $share = $scfg->{share};
 186
 187     if (!cifs_is_mounted($server, $share, $path, $cache->{mountdata})) {
 188
 189         mkpath $path if !(defined($scfg->{mkdir}) && !$scfg->{mkdir});
 190
 191         die "unable to activate storage '$storeid' - " .
 192             "directory '$path' does not exist\n" if ! -d $path;
 193
 194         cifs_mount($server, $share, $path, $storeid, $scfg->{smbversion},
 195             $scfg->{username}, $scfg->{domain});
 196     }
 197
 198     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 199 }
 200
 201 sub deactivate_storage {
 202     my ($class, $storeid, $scfg, $cache) = @_;
 203
 204     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 205         if !$cache->{mountdata};
 206
 207     my $path = $scfg->{path};
 208     my $server = $scfg->{server};
 209     my $share = $scfg->{share};
 210
 211     if (cifs_is_mounted($server, $share, $path, $cache->{mountdata})) {
 212         my $cmd = ['/bin/umount', $path];
 213         run_command($cmd, errmsg => 'umount error');
 214     }
 215 }
 216
 217 sub check_connection {
 218     my ($class, $storeid, $scfg) = @_;
 219
 220     my $servicename = '//'.$scfg->{server}.'/'.$scfg->{share};
 221
 222     my $cmd = ['/usr/bin/smbclient', $servicename, '-d', '0', '-m'];
 223
 224     push @$cmd, $scfg->{smbversion} ? "smb".int($scfg->{smbversion}) : 'smb3';
 225
 226     if (my $cred_file = get_cred_file($storeid)) {
 227         push @$cmd, '-U', $scfg->{username}, '-A', $cred_file;
 228         push @$cmd, '-W', $scfg->{domain} if defined($scfg->{domain});
 229     } else {
 230         push @$cmd, '-U', 'Guest','-N';
 231     }
 232
 233     push @$cmd, '-c', 'echo 1 0';
 234
 235     my $out_str;
 236     eval {
 237         run_command($cmd, timeout => 2, outfunc => sub {$out_str .= shift;},
 238                     errfunc => sub {});
 239     };
 240
 241     if (my $err = $@) {
 242         die "$out_str\n" if defined($out_str) &&
 243             ($out_str =~ m/NT_STATUS_ACCESS_DENIED/);
 244         return 0;
 245     }
 246
 247     return 1;
 248 }
 249
 250 1;