PVE/Storage/CephFSPlugin.pm

   1 package PVE::Storage::CephFSPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7 use Net::IP;
   8 use File::Path;
   9
  10 use PVE::CephConfig;
  11 use PVE::JSONSchema qw(get_standard_option);
  12 use PVE::ProcFSTools;
  13 use PVE::Storage::Plugin;
  14 use PVE::Systemd;
  15 use PVE::Tools qw(run_command file_set_contents);
  16
  17 use base qw(PVE::Storage::Plugin);
  18
  19 sub cephfs_is_mounted {
  20     my ($scfg, $storeid, $mountdata) = @_;
  21
  22     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  23     my $configfile = $cmd_option->{ceph_conf};
  24
  25     my $subdir = $scfg->{subdir} // '/';
  26     my $mountpoint = $scfg->{path};
  27
  28     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  29     return $mountpoint if grep {
  30         $_->[2] =~ m#^ceph|fuse\.ceph-fuse# &&
  31         $_->[0] =~ m#\Q:$subdir\E$|^ceph-fuse$# &&
  32         $_->[1] eq $mountpoint
  33     } @$mountdata;
  34
  35     warn "A filesystem is already mounted on $mountpoint\n"
  36         if grep { $_->[1] eq $mountpoint } @$mountdata;
  37
  38     return undef;
  39 }
  40
  41 # FIXME: remove once it's possible to specify _netdev for fuse.ceph mounts
  42 sub systemd_netmount {
  43     my ($where, $type, $what, $opts) = @_;
  44
  45 # don't do default deps, systemd v241 generator produces ordering deps on both
  46 # local-fs(-pre) and remote-fs(-pre) targets if we use the required _netdev
  47 # option. Over three corners this gets us an ordering cycle on shutdown, which
  48 # may make shutdown hang if the random cycle breaking hits the "wrong" unit to
  49 # delete.
  50     my $unit =  <<"EOF";
  51 [Unit]
  52 Description=${where}
  53 DefaultDependencies=no
  54 Requires=system.slice
  55 Wants=network-online.target
  56 Before=umount.target remote-fs.target
  57 After=systemd-journald.socket system.slice network.target -.mount remote-fs-pre.target network-online.target
  58 Conflicts=umount.target
  59
  60 [Mount]
  61 Where=${where}
  62 What=${what}
  63 Type=${type}
  64 Options=${opts}
  65 EOF
  66
  67     my $unit_fn = PVE::Systemd::escape_unit($where, 1) . ".mount";
  68     my $unit_path = "/run/systemd/system/$unit_fn";
  69     my $daemon_needs_reload = -e $unit_path;
  70
  71     file_set_contents($unit_path, $unit);
  72
  73     run_command(['systemctl', 'daemon-reload'], errmsg => "daemon-reload error")
  74         if $daemon_needs_reload;
  75     run_command(['systemctl', 'start', $unit_fn], errmsg => "mount error");
  76
  77 }
  78
  79 sub cephfs_mount {
  80     my ($scfg, $storeid) = @_;
  81
  82     my $mountpoint = $scfg->{path};
  83     my $subdir = $scfg->{subdir} // '/';
  84
  85     my $cmd_option = PVE::CephConfig::ceph_connect_option($scfg, $storeid);
  86     my $configfile = $cmd_option->{ceph_conf};
  87     my $secretfile = $cmd_option->{keyring};
  88     my $server = $cmd_option->{mon_host} // PVE::CephConfig::get_monaddr_list($configfile);
  89     my $type = 'ceph';
  90
  91     my @opts = ();
  92     if ($scfg->{fuse}) {
  93         $type = 'fuse.ceph';
  94         push @opts, "ceph.id=$cmd_option->{userid}";
  95         push @opts, "ceph.keyfile=$secretfile" if defined($secretfile);
  96         push @opts, "ceph.conf=$configfile" if defined($configfile);
  97     } else {
  98         push @opts, "name=$cmd_option->{userid}";
  99         push @opts, "secretfile=$secretfile" if defined($secretfile);
 100         push @opts, "conf=$configfile" if defined($configfile);
 101     }
 102
 103     push @opts, $scfg->{options} if $scfg->{options};
 104
 105     systemd_netmount($mountpoint, $type, "$server:$subdir", join(',', @opts));
 106 }
 107
 108 # Configuration
 109
 110 sub type {
 111     return 'cephfs';
 112 }
 113
 114 sub plugindata {
 115     return {
 116         content => [ { vztmpl => 1, iso => 1, backup => 1, snippets => 1},
 117                      { backup => 1 }],
 118     };
 119 }
 120
 121 sub properties {
 122     return {
 123         fuse => {
 124             description => "Mount CephFS through FUSE.",
 125             type => 'boolean',
 126         },
 127         subdir => {
 128             description => "Subdir to mount.",
 129             type => 'string', format => 'pve-storage-path',
 130         },
 131     };
 132 }
 133
 134 sub options {
 135     return {
 136         path => { fixed => 1 },
 137         monhost => { optional => 1},
 138         nodes => { optional => 1 },
 139         subdir => { optional => 1 },
 140         disable => { optional => 1 },
 141         options => { optional => 1 },
 142         username => { optional => 1 },
 143         content => { optional => 1 },
 144         format => { optional => 1 },
 145         mkdir => { optional => 1 },
 146         fuse => { optional => 1 },
 147         bwlimit => { optional => 1 },
 148         maxfiles => { optional => 1 },
 149         'prune-backups' => { optional => 1 },
 150     };
 151 }
 152
 153 sub check_config {
 154     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 155
 156     $config->{path} = "/mnt/pve/$sectionId" if $create && !$config->{path};
 157
 158     return $class->SUPER::check_config($sectionId, $config, $create, $skipSchemaCheck);
 159 }
 160
 161 # Storage implementation
 162
 163 sub on_add_hook {
 164     my ($class, $storeid, $scfg, %param) = @_;
 165
 166     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 167
 168     PVE::CephConfig::ceph_create_keyfile($scfg->{type}, $storeid);
 169
 170     return;
 171 }
 172
 173 sub on_delete_hook {
 174     my ($class, $storeid, $scfg) = @_;
 175
 176     return if defined($scfg->{monhost}); # nothing to do if not pve managed ceph
 177
 178     PVE::CephConfig::ceph_remove_keyfile($scfg->{type}, $storeid);
 179
 180     return;
 181 }
 182
 183 sub status {
 184     my ($class, $storeid, $scfg, $cache) = @_;
 185
 186     $cache->{mountdata} //= PVE::ProcFSTools::parse_proc_mounts();
 187
 188     return undef if !cephfs_is_mounted($scfg, $storeid, $cache->{mountdata});
 189
 190     return $class->SUPER::status($storeid, $scfg, $cache);
 191 }
 192
 193 sub activate_storage {
 194     my ($class, $storeid, $scfg, $cache) = @_;
 195
 196     $cache->{mountdata} //= PVE::ProcFSTools::parse_proc_mounts();
 197
 198     # NOTE: mkpath may hang if storage is mounted but not reachable
 199     if (!cephfs_is_mounted($scfg, $storeid, $cache->{mountdata})) {
 200         my $path = $scfg->{path};
 201
 202         mkpath $path if !(defined($scfg->{mkdir}) && !$scfg->{mkdir});
 203
 204         die "unable to activate storage '$storeid' - " .
 205             "directory '$path' does not exist\n" if ! -d $path;
 206
 207         cephfs_mount($scfg, $storeid);
 208     }
 209
 210     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 211 }
 212
 213 sub deactivate_storage {
 214     my ($class, $storeid, $scfg, $cache) = @_;
 215
 216     $cache->{mountdata} //= PVE::ProcFSTools::parse_proc_mounts();
 217
 218     my $path = $scfg->{path};
 219
 220     if (cephfs_is_mounted($scfg, $storeid, $cache->{mountdata})) {
 221         run_command(['/bin/umount', $path], errmsg => 'umount error');
 222     }
 223 }
 224
 225 sub get_volume_notes {
 226     my $class = shift;
 227     PVE::Storage::DirPlugin::get_volume_notes($class, @_);
 228 }
 229
 230 sub update_volume_notes {
 231     my $class = shift;
 232     PVE::Storage::DirPlugin::update_volume_notes($class, @_);
 233 }
 234
 235 1;