PVE/Storage/DirPlugin.pm

   1 package PVE::Storage::DirPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd;
   7 use File::Path;
   8 use POSIX;
   9
  10 use PVE::Storage::Plugin;
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 use base qw(PVE::Storage::Plugin);
  14
  15 # Configuration
  16
  17 sub type {
  18     return 'dir';
  19 }
  20
  21 sub plugindata {
  22     return {
  23         content => [ { images => 1, rootdir => 1, vztmpl => 1, iso => 1, backup => 1, snippets => 1, none => 1 },
  24                      { images => 1,  rootdir => 1 }],
  25         format => [ { raw => 1, qcow2 => 1, vmdk => 1, subvol => 1 } , 'raw' ],
  26     };
  27 }
  28
  29 sub properties {
  30     return {
  31         path => {
  32             description => "File system path.",
  33             type => 'string', format => 'pve-storage-path',
  34         },
  35         mkdir => {
  36             description => "Create the directory if it doesn't exist.",
  37             type => 'boolean',
  38             default => 'yes',
  39         },
  40         is_mountpoint => {
  41             description =>
  42                 "Assume the given path is an externally managed mountpoint " .
  43                 "and consider the storage offline if it is not mounted. ".
  44                 "Using a boolean (yes/no) value serves as a shortcut to using the target path in this field.",
  45             type => 'string',
  46             default => 'no',
  47         },
  48         bwlimit => get_standard_option('bwlimit'),
  49     };
  50 }
  51
  52 sub options {
  53     return {
  54         path => { fixed => 1 },
  55         nodes => { optional => 1 },
  56         shared => { optional => 1 },
  57         disable => { optional => 1 },
  58         maxfiles => { optional => 1 },
  59         'prune-backups' => { optional => 1 },
  60         content => { optional => 1 },
  61         format => { optional => 1 },
  62         mkdir => { optional => 1 },
  63         is_mountpoint => { optional => 1 },
  64         bwlimit => { optional => 1 },
  65         preallocation => { optional => 1 },
  66    };
  67 }
  68
  69 # Storage implementation
  70 #
  71
  72 # NOTE: should ProcFSTools::is_mounted accept an optional cache like this?
  73 sub path_is_mounted {
  74     my ($mountpoint, $mountdata) = @_;
  75
  76     $mountpoint = Cwd::realpath($mountpoint); # symlinks
  77     return 0 if !defined($mountpoint); # path does not exist
  78
  79     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  80     return 1 if grep { $_->[1] eq $mountpoint } @$mountdata;
  81     return undef;
  82 }
  83
  84 sub parse_is_mountpoint {
  85     my ($scfg) = @_;
  86     my $is_mp = $scfg->{is_mountpoint};
  87     return undef if !defined $is_mp;
  88     if (defined(my $bool = PVE::JSONSchema::parse_boolean($is_mp))) {
  89         return $bool ? $scfg->{path} : undef;
  90     }
  91     return $is_mp; # contains a path
  92 }
  93
  94 sub get_volume_notes {
  95     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
  96
  97     my ($vtype) = $class->parse_volname($volname);
  98     return if $vtype ne 'backup';
  99
 100     my $path = $class->filesystem_path($scfg, $volname);
 101     $path .= $class->SUPER::NOTES_EXT;
 102
 103     return PVE::Tools::file_get_contents($path) if -f $path;
 104
 105     return '';
 106 }
 107
 108 sub update_volume_notes {
 109     my ($class, $scfg, $storeid, $volname, $notes, $timeout) = @_;
 110
 111     my ($vtype) = $class->parse_volname($volname);
 112     die "only backups can have notes\n" if $vtype ne 'backup';
 113
 114     my $path = $class->filesystem_path($scfg, $volname);
 115     $path .= $class->SUPER::NOTES_EXT;
 116
 117     if (defined($notes) && $notes ne '') {
 118         PVE::Tools::file_set_contents($path, $notes);
 119     } else {
 120         unlink $path or $! == ENOENT or die "could not delete notes - $!\n";
 121     }
 122     return;
 123 }
 124
 125 sub status {
 126     my ($class, $storeid, $scfg, $cache) = @_;
 127
 128     if (defined(my $mp = parse_is_mountpoint($scfg))) {
 129         $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 130             if !$cache->{mountdata};
 131
 132         return undef if !path_is_mounted($mp, $cache->{mountdata});
 133     }
 134
 135     return $class->SUPER::status($storeid, $scfg, $cache);
 136 }
 137
 138
 139 sub activate_storage {
 140     my ($class, $storeid, $scfg, $cache) = @_;
 141
 142     my $path = $scfg->{path};
 143     if (!defined($scfg->{mkdir}) || $scfg->{mkdir}) {
 144         mkpath $path;
 145     }
 146
 147     my $mp = parse_is_mountpoint($scfg);
 148     if (defined($mp) && !path_is_mounted($mp, $cache->{mountdata})) {
 149         die "unable to activate storage '$storeid' - " .
 150             "directory is expected to be a mount point but is not mounted: '$mp'\n";
 151     }
 152
 153     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 154 }
 155
 156 sub check_config {
 157     my ($self, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 158     my $opts = PVE::SectionConfig::check_config($self, $sectionId, $config, $create, $skipSchemaCheck);
 159     return $opts if !$create;
 160     if ($opts->{path} !~ m@^/[-/a-zA-Z0-9_.]+$@) {
 161         die "illegal path for directory storage: $opts->{path}\n";
 162     }
 163     return $opts;
 164 }
 165
 166 1;