PVE/Storage/DirPlugin.pm

   1 package PVE::Storage::DirPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use Cwd;
   6 use File::Path;
   7 use PVE::Storage::Plugin;
   8 use PVE::JSONSchema qw(get_standard_option);
   9
  10 use base qw(PVE::Storage::Plugin);
  11
  12 # Configuration
  13
  14 sub type {
  15     return 'dir';
  16 }
  17
  18 sub plugindata {
  19     return {
  20         content => [ { images => 1, rootdir => 1, vztmpl => 1, iso => 1, backup => 1, snippets => 1, none => 1 },
  21                      { images => 1,  rootdir => 1 }],
  22         format => [ { raw => 1, qcow2 => 1, vmdk => 1, subvol => 1 } , 'raw' ],
  23     };
  24 }
  25
  26 sub properties {
  27     return {
  28         path => {
  29             description => "File system path.",
  30             type => 'string', format => 'pve-storage-path',
  31         },
  32         mkdir => {
  33             description => "Create the directory if it doesn't exist.",
  34             type => 'boolean',
  35             default => 'yes',
  36         },
  37         is_mountpoint => {
  38             description =>
  39                 "Assume the given path is an externally managed mountpoint " .
  40                 "and consider the storage offline if it is not mounted. ".
  41                 "Using a boolean (yes/no) value serves as a shortcut to using the target path in this field.",
  42             type => 'string',
  43             default => 'no',
  44         },
  45         bwlimit => get_standard_option('bwlimit'),
  46     };
  47 }
  48
  49 sub options {
  50     return {
  51         path => { fixed => 1 },
  52         nodes => { optional => 1 },
  53         shared => { optional => 1 },
  54         disable => { optional => 1 },
  55         maxfiles => { optional => 1 },
  56         'prune-backups' => { optional => 1 },
  57         content => { optional => 1 },
  58         format => { optional => 1 },
  59         mkdir => { optional => 1 },
  60         is_mountpoint => { optional => 1 },
  61         bwlimit => { optional => 1 },
  62    };
  63 }
  64
  65 # Storage implementation
  66 #
  67
  68 # NOTE: should ProcFSTools::is_mounted accept an optional cache like this?
  69 sub path_is_mounted {
  70     my ($mountpoint, $mountdata) = @_;
  71
  72     $mountpoint = Cwd::realpath($mountpoint); # symlinks
  73     return 0 if !defined($mountpoint); # path does not exist
  74
  75     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  76     return 1 if grep { $_->[1] eq $mountpoint } @$mountdata;
  77     return undef;
  78 }
  79
  80 sub parse_is_mountpoint {
  81     my ($scfg) = @_;
  82     my $is_mp = $scfg->{is_mountpoint};
  83     return undef if !defined $is_mp;
  84     if (defined(my $bool = PVE::JSONSchema::parse_boolean($is_mp))) {
  85         return $bool ? $scfg->{path} : undef;
  86     }
  87     return $is_mp; # contains a path
  88 }
  89
  90 sub status {
  91     my ($class, $storeid, $scfg, $cache) = @_;
  92
  93     if (defined(my $mp = parse_is_mountpoint($scfg))) {
  94         $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
  95             if !$cache->{mountdata};
  96
  97         return undef if !path_is_mounted($mp, $cache->{mountdata});
  98     }
  99
 100     return $class->SUPER::status($storeid, $scfg, $cache);
 101 }
 102
 103
 104 sub activate_storage {
 105     my ($class, $storeid, $scfg, $cache) = @_;
 106
 107     my $path = $scfg->{path};
 108     if (!defined($scfg->{mkdir}) || $scfg->{mkdir}) {
 109         mkpath $path;
 110     }
 111
 112     my $mp = parse_is_mountpoint($scfg);
 113     if (defined($mp) && !path_is_mounted($mp, $cache->{mountdata})) {
 114         die "unable to activate storage '$storeid' - " .
 115             "directory is expected to be a mount point but is not mounted: '$mp'\n";
 116     }
 117
 118     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 119 }
 120
 121 sub check_config {
 122     my ($self, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 123     my $opts = PVE::SectionConfig::check_config($self, $sectionId, $config, $create, $skipSchemaCheck);
 124     return $opts if !$create;
 125     if ($opts->{path} !~ m@^/[-/a-zA-Z0-9_.]+$@) {
 126         die "illegal path for directory storage: $opts->{path}\n";
 127     }
 128     return $opts;
 129 }
 130
 131 1;