PVE/Storage/DirPlugin.pm

   1 package PVE::Storage::DirPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Cwd;
   7 use File::Path;
   8 use POSIX;
   9
  10 use PVE::Storage::Plugin;
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 use base qw(PVE::Storage::Plugin);
  14
  15 # Configuration
  16
  17 sub type {
  18     return 'dir';
  19 }
  20
  21 sub plugindata {
  22     return {
  23         content => [ { images => 1, rootdir => 1, vztmpl => 1, iso => 1, backup => 1, snippets => 1, none => 1 },
  24                      { images => 1,  rootdir => 1 }],
  25         format => [ { raw => 1, qcow2 => 1, vmdk => 1, subvol => 1 } , 'raw' ],
  26     };
  27 }
  28
  29 sub properties {
  30     return {
  31         path => {
  32             description => "File system path.",
  33             type => 'string', format => 'pve-storage-path',
  34         },
  35         mkdir => {
  36             description => "Create the directory if it doesn't exist.",
  37             type => 'boolean',
  38             default => 'yes',
  39         },
  40         is_mountpoint => {
  41             description =>
  42                 "Assume the given path is an externally managed mountpoint " .
  43                 "and consider the storage offline if it is not mounted. ".
  44                 "Using a boolean (yes/no) value serves as a shortcut to using the target path in this field.",
  45             type => 'string',
  46             default => 'no',
  47         },
  48         bwlimit => get_standard_option('bwlimit'),
  49     };
  50 }
  51
  52 sub options {
  53     return {
  54         path => { fixed => 1 },
  55         nodes => { optional => 1 },
  56         shared => { optional => 1 },
  57         disable => { optional => 1 },
  58         maxfiles => { optional => 1 },
  59         'prune-backups' => { optional => 1 },
  60         content => { optional => 1 },
  61         format => { optional => 1 },
  62         mkdir => { optional => 1 },
  63         is_mountpoint => { optional => 1 },
  64         bwlimit => { optional => 1 },
  65         preallocation => { optional => 1 },
  66    };
  67 }
  68
  69 # Storage implementation
  70 #
  71
  72 # NOTE: should ProcFSTools::is_mounted accept an optional cache like this?
  73 sub path_is_mounted {
  74     my ($mountpoint, $mountdata) = @_;
  75
  76     $mountpoint = Cwd::realpath($mountpoint); # symlinks
  77     return 0 if !defined($mountpoint); # path does not exist
  78
  79     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  80     return 1 if grep { $_->[1] eq $mountpoint } @$mountdata;
  81     return undef;
  82 }
  83
  84 sub parse_is_mountpoint {
  85     my ($scfg) = @_;
  86     my $is_mp = $scfg->{is_mountpoint};
  87     return undef if !defined $is_mp;
  88     if (defined(my $bool = PVE::JSONSchema::parse_boolean($is_mp))) {
  89         return $bool ? $scfg->{path} : undef;
  90     }
  91     return $is_mp; # contains a path
  92 }
  93
  94 # FIXME remove on the next APIAGE reset.
  95 # Deprecated, use get_volume_attribute instead.
  96 sub get_volume_notes {
  97     my ($class, $scfg, $storeid, $volname, $timeout) = @_;
  98
  99     my ($vtype) = $class->parse_volname($volname);
 100     return if $vtype ne 'backup';
 101
 102     my $path = $class->filesystem_path($scfg, $volname);
 103     $path .= $class->SUPER::NOTES_EXT;
 104
 105     return PVE::Tools::file_get_contents($path) if -f $path;
 106
 107     return '';
 108 }
 109
 110 # FIXME remove on the next APIAGE reset.
 111 # Deprecated, use update_volume_attribute instead.
 112 sub update_volume_notes {
 113     my ($class, $scfg, $storeid, $volname, $notes, $timeout) = @_;
 114
 115     my ($vtype) = $class->parse_volname($volname);
 116     die "only backups can have notes\n" if $vtype ne 'backup';
 117
 118     my $path = $class->filesystem_path($scfg, $volname);
 119     $path .= $class->SUPER::NOTES_EXT;
 120
 121     if (defined($notes) && $notes ne '') {
 122         PVE::Tools::file_set_contents($path, $notes);
 123     } else {
 124         unlink $path or $! == ENOENT or die "could not delete notes - $!\n";
 125     }
 126     return;
 127 }
 128
 129 sub get_volume_attribute {
 130     my ($class, $scfg, $storeid, $volname, $attribute) = @_;
 131
 132     if ($attribute eq 'notes') {
 133         return $class->get_volume_notes($scfg, $storeid, $volname);
 134     }
 135
 136     return;
 137 }
 138
 139 sub update_volume_attribute {
 140     my ($class, $scfg, $storeid, $volname, $attribute, $value) = @_;
 141
 142     if ($attribute eq 'notes') {
 143         return $class->update_volume_notes($scfg, $storeid, $volname, $value);
 144     }
 145
 146     die "attribute '$attribute' is not supported for storage type '$scfg->{type}'\n";
 147 }
 148
 149 sub status {
 150     my ($class, $storeid, $scfg, $cache) = @_;
 151
 152     if (defined(my $mp = parse_is_mountpoint($scfg))) {
 153         $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 154             if !$cache->{mountdata};
 155
 156         return undef if !path_is_mounted($mp, $cache->{mountdata});
 157     }
 158
 159     return $class->SUPER::status($storeid, $scfg, $cache);
 160 }
 161
 162
 163 sub activate_storage {
 164     my ($class, $storeid, $scfg, $cache) = @_;
 165
 166     my $path = $scfg->{path};
 167     if (!defined($scfg->{mkdir}) || $scfg->{mkdir}) {
 168         mkpath $path;
 169     }
 170
 171     my $mp = parse_is_mountpoint($scfg);
 172     if (defined($mp) && !path_is_mounted($mp, $cache->{mountdata})) {
 173         die "unable to activate storage '$storeid' - " .
 174             "directory is expected to be a mount point but is not mounted: '$mp'\n";
 175     }
 176
 177     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 178 }
 179
 180 sub check_config {
 181     my ($self, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 182     my $opts = PVE::SectionConfig::check_config($self, $sectionId, $config, $create, $skipSchemaCheck);
 183     return $opts if !$create;
 184     if ($opts->{path} !~ m@^/[-/a-zA-Z0-9_.]+$@) {
 185         die "illegal path for directory storage: $opts->{path}\n";
 186     }
 187     return $opts;
 188 }
 189
 190 1;