PVE/Storage/GlusterfsPlugin.pm

   1 package PVE::Storage::GlusterfsPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use IO::File;
   6 use File::Path;
   7 use PVE::Tools qw(run_command);
   8 use PVE::ProcFSTools;
   9 use PVE::Network;
  10 use PVE::Storage::Plugin;
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 use base qw(PVE::Storage::Plugin);
  14
  15 # Glusterfs helper functions
  16
  17 my $server_test_results = {};
  18
  19 my $get_active_server = sub {
  20     my ($scfg, $return_default_if_offline) = @_;
  21
  22     my $defaultserver = $scfg->{server} ? $scfg->{server} : 'localhost';
  23
  24     if ($return_default_if_offline && !defined($scfg->{server2})) {
  25         # avoid delays (there is no backup server anyways)
  26         return $defaultserver;
  27     }
  28
  29     my $serverlist = [ $defaultserver ];
  30     push @$serverlist, $scfg->{server2} if $scfg->{server2};
  31
  32     my $ctime = time();
  33     foreach my $server (@$serverlist) {
  34         my $stat = $server_test_results->{$server};
  35         return $server if $stat && $stat->{active} && (($ctime - $stat->{time}) <= 2);
  36     }
  37
  38     foreach my $server (@$serverlist) {
  39         my $status = 0;
  40
  41         if ($server && $server ne 'localhost' && $server ne '127.0.0.1' && $server ne '::1') {
  42
  43             # ping the echo port (7) without service check
  44             $status = PVE::Network::tcp_ping($server, undef, 2);
  45
  46         } else {
  47
  48             my $parser = sub {
  49                 my $line = shift;
  50
  51                 if ($line =~ m/Status: Started$/) {
  52                     $status = 1;
  53                 }
  54             };
  55
  56             my $cmd = ['/usr/sbin/gluster', 'volume', 'info', $scfg->{volume}];
  57
  58             run_command($cmd, errmsg => "glusterfs error", errfunc => sub {}, outfunc => $parser);
  59         }
  60
  61         $server_test_results->{$server} = { time => time(), active => $status };
  62         return $server if $status;
  63     }
  64
  65     return $defaultserver if $return_default_if_offline;
  66
  67     return undef;
  68 };
  69
  70 sub glusterfs_is_mounted {
  71     my ($volume, $mountpoint, $mountdata) = @_;
  72
  73     $mountdata = PVE::ProcFSTools::parse_proc_mounts() if !$mountdata;
  74
  75     return $mountpoint if grep {
  76         $_->[2] eq 'fuse.glusterfs' &&
  77         $_->[0] =~ /^\S+:\Q$volume\E$/ &&
  78         $_->[1] eq $mountpoint
  79     } @$mountdata;
  80     return undef;
  81 }
  82
  83 sub glusterfs_mount {
  84     my ($server, $volume, $mountpoint) = @_;
  85
  86     my $source = "$server:$volume";
  87
  88     my $cmd = ['/bin/mount', '-t', 'glusterfs', $source, $mountpoint];
  89
  90     run_command($cmd, errmsg => "mount error");
  91 }
  92
  93 # Configuration
  94
  95 sub type {
  96     return 'glusterfs';
  97 }
  98
  99 sub plugindata {
 100     return {
 101         content => [ { images => 1, vztmpl => 1, iso => 1, backup => 1},
 102                      { images => 1 }],
 103         format => [ { raw => 1, qcow2 => 1, vmdk => 1 } , 'raw' ],
 104     };
 105 }
 106
 107 sub properties {
 108     return {
 109         volume => {
 110             description => "Glusterfs Volume.",
 111             type => 'string',
 112         },
 113         server2 => {
 114             description => "Backup volfile server IP or DNS name.",
 115             type => 'string', format => 'pve-storage-server',
 116             requires => 'server',
 117         },
 118         transport => {
 119             description => "Gluster transport: tcp or rdma",
 120             type => 'string',
 121             enum => ['tcp', 'rdma', 'unix'],
 122         },
 123     };
 124 }
 125
 126 sub options {
 127     return {
 128         path => { fixed => 1 },
 129         server => { optional => 1 },
 130         server2 => { optional => 1 },
 131         volume => { fixed => 1 },
 132         transport => { optional => 1 },
 133         nodes => { optional => 1 },
 134         disable => { optional => 1 },
 135         maxfiles => { optional => 1 },
 136         content => { optional => 1 },
 137         format => { optional => 1 },
 138         mkdir => { optional => 1 },
 139         bwlimit => { optional => 1 },
 140     };
 141 }
 142
 143
 144 sub check_config {
 145     my ($class, $sectionId, $config, $create, $skipSchemaCheck) = @_;
 146
 147     $config->{path} = "/mnt/pve/$sectionId" if $create && !$config->{path};
 148
 149     return $class->SUPER::check_config($sectionId, $config, $create, $skipSchemaCheck);
 150 }
 151
 152 # Storage implementation
 153
 154 sub parse_name_dir {
 155     my $name = shift;
 156
 157     if ($name =~ m!^((base-)?[^/\s]+\.(raw|qcow2|vmdk))$!) {
 158         return ($1, $3, $2);
 159     }
 160
 161     die "unable to parse volume filename '$name'\n";
 162 }
 163
 164 my $find_free_diskname = sub {
 165     my ($imgdir, $vmid, $fmt, $scfg) = @_;
 166
 167     my $disk_list = [];
 168
 169     my $dh = IO::Dir->new ($imgdir);
 170     @$disk_list = $dh->read() if defined($dh);
 171
 172     return PVE::Storage::Plugin::get_next_vm_diskname($disk_list, $imgdir, $vmid, $fmt, $scfg, 1);
 173 };
 174
 175 sub path {
 176     my ($class, $scfg, $volname, $storeid, $snapname) = @_;
 177
 178     my ($vtype, $name, $vmid, undef, undef, $isBase, $format) =
 179         $class->parse_volname($volname);
 180
 181     # Note: qcow2/qed has internal snapshot, so path is always
 182     # the same (with or without snapshot => same file).
 183     die "can't snapshot this image format\n"
 184         if defined($snapname) && $format !~ m/^(qcow2|qed)$/;
 185
 186     my $path = undef;
 187     if ($vtype eq 'images') {
 188
 189         my $server = &$get_active_server($scfg, 1);
 190         my $glustervolume = $scfg->{volume};
 191         my $transport = $scfg->{transport};
 192         my $protocol = "gluster";
 193
 194         if ($transport) {
 195             $protocol = "gluster+$transport";
 196         }
 197
 198         $path = "$protocol://$server/$glustervolume/images/$vmid/$name";
 199
 200     } else {
 201         my $dir = $class->get_subdir($scfg, $vtype);
 202         $path = "$dir/$name";
 203     }
 204
 205     return wantarray ? ($path, $vmid, $vtype) : $path;
 206 }
 207
 208 sub clone_image {
 209     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 210
 211     die "storage definintion has no path\n" if !$scfg->{path};
 212
 213     my ($vtype, $basename, $basevmid, undef, undef, $isBase, $format) =
 214         $class->parse_volname($volname);
 215
 216     die "clone_image on wrong vtype '$vtype'\n" if $vtype ne 'images';
 217
 218     die "this storage type does not support clone_image on snapshot\n" if $snap;
 219
 220     die "this storage type does not support clone_image on subvolumes\n" if $format eq 'subvol';
 221
 222     die "clone_image only works on base images\n" if !$isBase;
 223
 224     my $imagedir = $class->get_subdir($scfg, 'images');
 225     $imagedir .= "/$vmid";
 226
 227     mkpath $imagedir;
 228
 229     my $name = $find_free_diskname->($imagedir, $vmid, "qcow2", $scfg);
 230
 231     warn "clone $volname: $vtype, $name, $vmid to $name (base=../$basevmid/$basename)\n";
 232
 233     my $path = "$imagedir/$name";
 234
 235     die "disk image '$path' already exists\n" if -e $path;
 236
 237     my $server = &$get_active_server($scfg, 1);
 238     my $glustervolume = $scfg->{volume};
 239     my $volumepath = "gluster://$server/$glustervolume/images/$vmid/$name";
 240
 241     my $cmd = ['/usr/bin/qemu-img', 'create', '-b', "../$basevmid/$basename",
 242                '-f', 'qcow2', $volumepath];
 243
 244     run_command($cmd, errmsg => "unable to create image");
 245
 246     return "$basevmid/$basename/$vmid/$name";
 247 }
 248
 249 sub alloc_image {
 250     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
 251
 252     my $imagedir = $class->get_subdir($scfg, 'images');
 253     $imagedir .= "/$vmid";
 254
 255     mkpath $imagedir;
 256
 257     $name = $find_free_diskname->($imagedir, $vmid, $fmt, $scfg) if !$name;
 258
 259     my (undef, $tmpfmt) = parse_name_dir($name);
 260
 261     die "illegal name '$name' - wrong extension for format ('$tmpfmt != '$fmt')\n"
 262         if $tmpfmt ne $fmt;
 263
 264     my $path = "$imagedir/$name";
 265
 266     die "disk image '$path' already exists\n" if -e $path;
 267
 268     my $server = &$get_active_server($scfg, 1);
 269     my $glustervolume = $scfg->{volume};
 270     my $volumepath = "gluster://$server/$glustervolume/images/$vmid/$name";
 271
 272     my $cmd = ['/usr/bin/qemu-img', 'create'];
 273
 274     push @$cmd, '-o', 'preallocation=metadata' if $fmt eq 'qcow2';
 275
 276     push @$cmd, '-f', $fmt, $volumepath, "${size}K";
 277
 278     run_command($cmd, errmsg => "unable to create image");
 279
 280     return "$vmid/$name";
 281 }
 282
 283 sub status {
 284     my ($class, $storeid, $scfg, $cache) = @_;
 285
 286     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 287         if !$cache->{mountdata};
 288
 289     my $path = $scfg->{path};
 290
 291     my $volume = $scfg->{volume};
 292
 293     return undef if !glusterfs_is_mounted($volume, $path, $cache->{mountdata});
 294
 295     return $class->SUPER::status($storeid, $scfg, $cache);
 296 }
 297
 298 sub activate_storage {
 299     my ($class, $storeid, $scfg, $cache) = @_;
 300
 301     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 302         if !$cache->{mountdata};
 303
 304     my $path = $scfg->{path};
 305     my $volume = $scfg->{volume};
 306
 307     if (!glusterfs_is_mounted($volume, $path, $cache->{mountdata})) {
 308
 309         mkpath $path if !(defined($scfg->{mkdir}) && !$scfg->{mkdir});
 310
 311         die "unable to activate storage '$storeid' - " .
 312             "directory '$path' does not exist\n" if ! -d $path;
 313
 314         my $server = &$get_active_server($scfg, 1);
 315
 316         glusterfs_mount($server, $volume, $path);
 317     }
 318
 319     $class->SUPER::activate_storage($storeid, $scfg, $cache);
 320 }
 321
 322 sub deactivate_storage {
 323     my ($class, $storeid, $scfg, $cache) = @_;
 324
 325     $cache->{mountdata} = PVE::ProcFSTools::parse_proc_mounts()
 326         if !$cache->{mountdata};
 327
 328     my $path = $scfg->{path};
 329     my $volume = $scfg->{volume};
 330
 331     if (glusterfs_is_mounted($volume, $path, $cache->{mountdata})) {
 332         my $cmd = ['/bin/umount', $path];
 333         run_command($cmd, errmsg => 'umount error');
 334     }
 335 }
 336
 337 sub activate_volume {
 338     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 339
 340     # do nothing by default
 341 }
 342
 343 sub deactivate_volume {
 344     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 345
 346     # do nothing by default
 347 }
 348
 349 sub check_connection {
 350     my ($class, $storeid, $scfg, $cache) = @_;
 351
 352     my $server = &$get_active_server($scfg);
 353
 354     return defined($server) ? 1 : 0;
 355 }
 356
 357 1;