PVE/Storage/LvmThinPlugin.pm

   1 package PVE::Storage::LvmThinPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7
   8 use PVE::Tools qw(run_command trim);
   9 use PVE::Storage::Plugin;
  10 use PVE::Storage::LVMPlugin;
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 # see: man lvmthin
  14 # lvcreate -n ThinDataLV -L LargeSize VG
  15 # lvconvert --type thin-pool VG/ThinDataLV
  16 # lvcreate -n pvepool -L 20G pve
  17 # lvconvert --type thin-pool pve/pvepool
  18
  19 # NOTE: volumes which were created as linked clones of another base volume
  20 # are currently not tracking this relationship in their volume IDs. this is
  21 # generally not a problem, as LVM thin allows deletion of such base volumes
  22 # without affecting the linked clones. this leads to increased disk usage
  23 # when migrating LVM-thin volumes, which is normally prevented for linked clones.
  24
  25 use base qw(PVE::Storage::LVMPlugin);
  26
  27 sub type {
  28     return 'lvmthin';
  29 }
  30
  31 sub plugindata {
  32     return {
  33         content => [ {images => 1, rootdir => 1}, { images => 1, rootdir => 1}],
  34     };
  35 }
  36
  37 sub properties {
  38     return {
  39         thinpool => {
  40             description => "LVM thin pool LV name.",
  41             type => 'string', format => 'pve-storage-vgname',
  42         },
  43     };
  44 }
  45
  46 sub options {
  47     return {
  48         thinpool => { fixed => 1 },
  49         vgname => { fixed => 1 },
  50         nodes => { optional => 1 },
  51         disable => { optional => 1 },
  52         content => { optional => 1 },
  53         bwlimit => { optional => 1 },
  54     };
  55 }
  56
  57 # NOTE: the fourth and fifth element of the returned array are always
  58 # undef, even if the volume is a linked clone of another volume. see note
  59 # at beginning of file.
  60 sub parse_volname {
  61     my ($class, $volname) = @_;
  62
  63     PVE::Storage::Plugin::parse_lvm_name($volname);
  64
  65     if ($volname =~ m/^((vm|base)-(\d+)-\S+)$/) {
  66         return ('images', $1, $3, undef, undef, $2 eq 'base', 'raw');
  67     }
  68
  69     die "unable to parse lvm volume name '$volname'\n";
  70 }
  71
  72 sub filesystem_path {
  73     my ($class, $scfg, $volname, $snapname) = @_;
  74
  75     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
  76
  77     my $vg = $scfg->{vgname};
  78
  79     my $path = defined($snapname) ? "/dev/$vg/snap_${name}_$snapname": "/dev/$vg/$name";
  80
  81     return wantarray ? ($path, $vmid, $vtype) : $path;
  82 }
  83
  84 sub alloc_image {
  85     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
  86
  87     die "unsupported format '$fmt'" if $fmt ne 'raw';
  88
  89     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
  90         if  $name && $name !~ m/^vm-$vmid-/;
  91
  92     my $vgs = PVE::Storage::LVMPlugin::lvm_vgs();
  93
  94     my $vg = $scfg->{vgname};
  95
  96     die "no such volume group '$vg'\n" if !defined ($vgs->{$vg});
  97
  98     $name = $class->find_free_diskname($storeid, $scfg, $vmid)
  99         if !$name;
 100
 101     my $cmd = ['/sbin/lvcreate', '-aly', '-V', "${size}k", '--name', $name,
 102                '--thinpool', "$vg/$scfg->{thinpool}" ];
 103
 104     run_command($cmd, errmsg => "lvcreate '$vg/$name' error");
 105
 106     return $name;
 107 }
 108
 109 sub free_image {
 110     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 111
 112     my $vg = $scfg->{vgname};
 113
 114     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 115
 116     if (my $dat = $lvs->{$scfg->{vgname}}) {
 117
 118         # remove all volume snapshots first
 119         foreach my $lv (keys %$dat) {
 120             next if $lv !~ m/^snap_${volname}_${PVE::JSONSchema::CONFIGID_RE}$/;
 121             my $cmd = ['/sbin/lvremove', '-f', "$vg/$lv"];
 122             run_command($cmd, errmsg => "lvremove snapshot '$vg/$lv' error");
 123         }
 124
 125         # finally remove original (if exists)
 126         if ($dat->{$volname}) {
 127             my $cmd = ['/sbin/lvremove', '-f', "$vg/$volname"];
 128             run_command($cmd, errmsg => "lvremove '$vg/$volname' error");
 129         }
 130     }
 131
 132     return undef;
 133 }
 134
 135 sub list_images {
 136     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 137
 138     my $vgname = $scfg->{vgname};
 139
 140     $cache->{lvs} = PVE::Storage::LVMPlugin::lvm_list_volumes() if !$cache->{lvs};
 141
 142     my $res = [];
 143
 144     if (my $dat = $cache->{lvs}->{$vgname}) {
 145
 146         foreach my $volname (keys %$dat) {
 147
 148             next if $volname !~ m/^(vm|base)-(\d+)-/;
 149             my $owner = $2;
 150
 151             my $info = $dat->{$volname};
 152
 153             next if $info->{lv_type} ne 'V';
 154
 155             next if $info->{pool_lv} ne $scfg->{thinpool};
 156
 157             my $volid = "$storeid:$volname";
 158
 159             if ($vollist) {
 160                 my $found = grep { $_ eq $volid } @$vollist;
 161                 next if !$found;
 162             } else {
 163                 next if defined($vmid) && ($owner ne $vmid);
 164             }
 165
 166             push @$res, {
 167                 volid => $volid, format => 'raw', size => $info->{lv_size}, vmid => $owner,
 168                 ctime => $info->{ctime},
 169             };
 170         }
 171     }
 172
 173     return $res;
 174 }
 175
 176 sub list_thinpools {
 177     my ($vg) = @_;
 178
 179     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 180     my $thinpools = [];
 181
 182     foreach my $vg (keys %$lvs) {
 183         foreach my $lvname (keys %{$lvs->{$vg}}) {
 184             next if $lvs->{$vg}->{$lvname}->{lv_type} ne 't';
 185             my $lv = $lvs->{$vg}->{$lvname};
 186             $lv->{lv} = $lvname;
 187             push @$thinpools, $lv;
 188         }
 189     }
 190
 191     return $thinpools;
 192 }
 193
 194 sub status {
 195     my ($class, $storeid, $scfg, $cache) = @_;
 196
 197     my $lvname = "$scfg->{vgname}/$scfg->{thinpool}";
 198
 199     $cache->{lvs} = PVE::Storage::LVMPlugin::lvm_list_volumes() if !$cache->{lvs};
 200
 201     my $lvs = $cache->{lvs};
 202
 203     return undef if !$lvs->{$scfg->{vgname}};
 204
 205     my $info = $lvs->{$scfg->{vgname}}->{$scfg->{thinpool}};
 206
 207     return undef if !$info;
 208
 209     return undef if $info->{lv_type} ne 't';
 210
 211     return ($info->{lv_size}, $info->{lv_size} - $info->{used}, $info->{used}, 1) if $info->{lv_size};
 212
 213     return undef;
 214 }
 215
 216 sub activate_volume {
 217     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 218
 219     my $vg = $scfg->{vgname};
 220
 221     # only snapshot volumes needs activation
 222     if ($snapname) {
 223         my $snapvol = "snap_${volname}_$snapname";
 224         my $cmd = ['/sbin/lvchange', '-ay', '-K', "$vg/$snapvol"];
 225         run_command($cmd, errmsg => "activate_volume '$vg/$snapvol' error");
 226     } elsif ($volname =~ /^base-/) {
 227         my $cmd = ['/sbin/lvchange', '-ay', '-K', "$vg/$volname"];
 228         run_command($cmd, errmsg => "activate_volume '$vg/$volname' error");
 229     } else {
 230         # other volumes are active by default
 231     }
 232 }
 233
 234 sub deactivate_volume {
 235     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 236
 237     my $vg = $scfg->{vgname};
 238
 239     # we only deactivate snapshot volumes
 240     if ($snapname) {
 241         my $snapvol = "snap_${volname}_$snapname";
 242         my $cmd = ['/sbin/lvchange', '-an', "$vg/$snapvol"];
 243         run_command($cmd, errmsg => "deactivate_volume '$vg/$snapvol' error");
 244     } elsif ($volname =~ /^base-/) {
 245         my $cmd = ['/sbin/lvchange', '-an', "$vg/$volname"];
 246         run_command($cmd, errmsg => "deactivate_volume '$vg/$volname' error");
 247     } else {
 248         # other volumes are kept active
 249     }
 250 }
 251
 252 sub clone_image {
 253     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 254
 255     my $vg = $scfg->{vgname};
 256
 257     my $lv;
 258
 259     if ($snap) {
 260         $lv = "$vg/snap_${volname}_$snap";
 261     } else {
 262         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
 263             $class->parse_volname($volname);
 264
 265         die "clone_image only works on base images\n" if !$isBase;
 266
 267         $lv = "$vg/$volname";
 268     }
 269
 270     my $name = $class->find_free_diskname($storeid, $scfg, $vmid);
 271
 272     my $cmd = ['/sbin/lvcreate', '-n', $name, '-prw', '-kn', '-s', $lv];
 273     run_command($cmd, errmsg => "clone image '$lv' error");
 274
 275     return $name;
 276 }
 277
 278 sub create_base {
 279     my ($class, $storeid, $scfg, $volname) = @_;
 280
 281     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 282         $class->parse_volname($volname);
 283
 284     die "create_base not possible with base image\n" if $isBase;
 285
 286     my $vg = $scfg->{vgname};
 287     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 288
 289     if (my $dat = $lvs->{$vg}) {
 290         # to avoid confusion, reject if we find volume snapshots
 291         foreach my $lv (keys %$dat) {
 292             die "unable to create base volume - found snaphost '$lv'\n"
 293                 if $lv =~ m/^snap_${volname}_(\w+)$/;
 294         }
 295     }
 296
 297     my $newname = $name;
 298     $newname =~ s/^vm-/base-/;
 299
 300     my $cmd = ['/sbin/lvrename', $vg, $volname, $newname];
 301     run_command($cmd, errmsg => "lvrename '$vg/$volname' => '$vg/$newname' error");
 302
 303     # set inactive, read-only and activationskip flags
 304     $cmd = ['/sbin/lvchange', '-an', '-pr', '-ky', "$vg/$newname"];
 305     eval { run_command($cmd); };
 306     warn $@ if $@;
 307
 308     my $newvolname = $newname;
 309
 310     return $newvolname;
 311 }
 312
 313 # sub volume_resize {} reuse code from parent class
 314
 315 sub volume_snapshot {
 316     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 317
 318     my $vg = $scfg->{vgname};
 319     my $snapvol = "snap_${volname}_$snap";
 320
 321     my $cmd = ['/sbin/lvcreate', '-n', $snapvol, '-pr', '-s', "$vg/$volname"];
 322     run_command($cmd, errmsg => "lvcreate snapshot '$vg/$snapvol' error");
 323
 324 }
 325
 326 sub volume_snapshot_rollback {
 327     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 328
 329     my $vg = $scfg->{vgname};
 330     my $snapvol = "snap_${volname}_$snap";
 331
 332     my $cmd = ['/sbin/lvremove', '-f', "$vg/$volname"];
 333     run_command($cmd, errmsg => "lvremove '$vg/$volname' error");
 334
 335     $cmd = ['/sbin/lvcreate', '-kn', '-n', $volname, '-s', "$vg/$snapvol"];
 336     run_command($cmd, errmsg => "lvm rollback '$vg/$snapvol' error");
 337 }
 338
 339 sub volume_snapshot_delete {
 340     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 341
 342     my $vg = $scfg->{vgname};
 343     my $snapvol = "snap_${volname}_$snap";
 344
 345     my $cmd = ['/sbin/lvremove', '-f', "$vg/$snapvol"];
 346     run_command($cmd, errmsg => "lvremove snapshot '$vg/$snapvol' error");
 347 }
 348
 349 sub volume_has_feature {
 350     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 351
 352     my $features = {
 353         snapshot => { current => 1 },
 354         clone => { base => 1, snap => 1},
 355         template => { current => 1},
 356         copy => { base => 1, current => 1, snap => 1},
 357         sparseinit => { base => 1, current => 1},
 358         rename => {current => 1},
 359     };
 360
 361     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 362         $class->parse_volname($volname);
 363
 364     my $key = undef;
 365     if($snapname){
 366         $key = 'snap';
 367     }else{
 368         $key =  $isBase ? 'base' : 'current';
 369     }
 370     return 1 if $features->{$feature}->{$key};
 371
 372     return undef;
 373 }
 374
 375 # used in LVMPlugin->volume_import
 376 sub volume_import_write {
 377     my ($class, $input_fh, $output_file) = @_;
 378     run_command(['dd', "of=$output_file", 'conv=sparse', 'bs=64k'],
 379         input => '<&'.fileno($input_fh));
 380 }
 381
 382 1;