PVE/Storage/LvmThinPlugin.pm

   1 package PVE::Storage::LvmThinPlugin;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use IO::File;
   7 use PVE::Tools qw(run_command trim);
   8 use PVE::Storage::Plugin;
   9 use PVE::Storage::LVMPlugin;
  10 use PVE::JSONSchema qw(get_standard_option);
  11
  12 # see: man lvmthin
  13 # lvcreate -n ThinDataLV -L LargeSize VG
  14 # lvconvert --type thin-pool VG/ThinDataLV
  15 # lvcreate -n pvepool -L 20G pve
  16 # lvconvert --type thin-pool pve/pvepool
  17
  18 use base qw(PVE::Storage::LVMPlugin);
  19
  20 sub type {
  21     return 'lvmthin';
  22 }
  23
  24 sub plugindata {
  25     return {
  26         content => [ {images => 1, rootdir => 1}, { images => 1, rootdir => 1}],
  27     };
  28 }
  29
  30 sub properties {
  31     return {
  32         thinpool => {
  33             description => "LVM thin pool LV name.",
  34             type => 'string', format => 'pve-storage-vgname',
  35         },
  36     };
  37 }
  38
  39 sub options {
  40     return {
  41         thinpool => { fixed => 1 },
  42         vgname => { fixed => 1 },
  43         nodes => { optional => 1 },
  44         disable => { optional => 1 },
  45         content => { optional => 1 },
  46     };
  47 }
  48
  49 sub parse_volname {
  50     my ($class, $volname) = @_;
  51
  52     PVE::Storage::Plugin::parse_lvm_name($volname);
  53
  54     if ($volname =~ m/^((vm|base)-(\d+)-\S+)$/) {
  55         return ('images', $1, $3, undef, undef, $2 eq 'base', 'raw');
  56     }
  57
  58     die "unable to parse lvm volume name '$volname'\n";
  59 }
  60
  61 sub filesystem_path {
  62     my ($class, $scfg, $volname, $snapname) = @_;
  63
  64     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
  65
  66     my $vg = $scfg->{vgname};
  67
  68     my $path = defined($snapname) ? "/dev/$vg/snap_${name}_$snapname": "/dev/$vg/$name";
  69
  70     return wantarray ? ($path, $vmid, $vtype) : $path;
  71 }
  72
  73 sub alloc_image {
  74     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
  75
  76     die "unsupported format '$fmt'" if $fmt ne 'raw';
  77
  78     die "illegal name '$name' - sould be 'vm-$vmid-*'\n"
  79         if  $name && $name !~ m/^vm-$vmid-/;
  80
  81     my $vgs = PVE::Storage::LVMPlugin::lvm_vgs();
  82
  83     my $vg = $scfg->{vgname};
  84
  85     die "no such volume group '$vg'\n" if !defined ($vgs->{$vg});
  86
  87     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
  88
  89     $name = PVE::Storage::LVMPlugin::lvm_find_free_diskname($lvs, $vg, $storeid, $vmid)
  90         if !$name;
  91
  92     my $cmd = ['/sbin/lvcreate', '-aly', '-V', "${size}k", '--name', $name,
  93                '--thinpool', "$vg/$scfg->{thinpool}" ];
  94
  95     run_command($cmd, errmsg => "lvcreate '$vg/$name' error");
  96
  97     return $name;
  98 }
  99
 100 sub free_image {
 101     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 102
 103     my $vg = $scfg->{vgname};
 104
 105     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 106
 107     if (my $dat = $lvs->{$scfg->{vgname}}) {
 108
 109         # remove all volume snapshots first
 110         foreach my $lv (keys %$dat) {
 111             next if $lv !~ m/^snap_${volname}_(\w+)$/;
 112             my $cmd = ['/sbin/lvremove', '-f', "$vg/$lv"];
 113             run_command($cmd, errmsg => "lvremove snapshot '$vg/$lv' error");
 114         }
 115
 116         # finally remove original (if exists)
 117         if ($dat->{$volname}) {
 118             my $cmd = ['/sbin/lvremove', '-f', "$vg/$volname"];
 119             run_command($cmd, errmsg => "lvremove '$vg/$volname' error");
 120         }
 121     }
 122
 123     return undef;
 124 }
 125
 126 sub list_images {
 127     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 128
 129     my $vgname = $scfg->{vgname};
 130
 131     $cache->{lvs} = PVE::Storage::LVMPlugin::lvm_list_volumes() if !$cache->{lvs};
 132
 133     my $res = [];
 134
 135     if (my $dat = $cache->{lvs}->{$vgname}) {
 136
 137         foreach my $volname (keys %$dat) {
 138
 139             next if $volname !~ m/^(vm|base)-(\d+)-/;
 140             my $owner = $2;
 141
 142             my $info = $dat->{$volname};
 143
 144             next if $info->{lv_type} ne 'V';
 145
 146             next if $info->{pool_lv} ne $scfg->{thinpool};
 147
 148             my $volid = "$storeid:$volname";
 149
 150             if ($vollist) {
 151                 my $found = grep { $_ eq $volid } @$vollist;
 152                 next if !$found;
 153             } else {
 154                 next if defined($vmid) && ($owner ne $vmid);
 155             }
 156
 157             push @$res, {
 158                 volid => $volid, format => 'raw', size => $info->{lv_size}, vmid => $owner,
 159             };
 160         }
 161     }
 162
 163     return $res;
 164 }
 165
 166 sub status {
 167     my ($class, $storeid, $scfg, $cache) = @_;
 168
 169     my $lvname = "$scfg->{vgname}/$scfg->{thinpool}";
 170
 171     $cache->{lvs} = PVE::Storage::LVMPlugin::lvm_list_volumes() if !$cache->{lvs};
 172
 173     my $lvs = $cache->{lvs};
 174
 175     return undef if !$lvs->{$scfg->{vgname}};
 176
 177     my $info = $lvs->{$scfg->{vgname}}->{$scfg->{thinpool}};
 178
 179     return undef if !$info;
 180
 181     return undef if $info->{lv_type} ne 't';
 182
 183     return ($info->{lv_size}, $info->{lv_size} - $info->{used}, $info->{used}, 1) if $info->{lv_size};
 184
 185     return undef;
 186 }
 187
 188 sub activate_volume {
 189     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 190
 191     my $vg = $scfg->{vgname};
 192
 193     # only snapshot volumes needs activation
 194     if ($snapname) {
 195         my $snapvol = "snap_${volname}_$snapname";
 196         my $cmd = ['/sbin/lvchange', '-ay', '-K', "$vg/$snapvol"];
 197         run_command($cmd, errmsg => "activate_volume '$vg/$snapvol' error");
 198     } else {
 199         # other volumes are active by default
 200     }
 201 }
 202
 203 sub deactivate_volume {
 204     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 205
 206     my $vg = $scfg->{vgname};
 207
 208     # we only deactivate snapshot volumes
 209     if ($snapname) {
 210         my $snapvol = "snap_${volname}_$snapname";
 211         my $cmd = ['/sbin/lvchange', '-an', "$vg/$snapvol"];
 212         run_command($cmd, errmsg => "deactivate_volume '$vg/$snapvol' error");
 213     } else {
 214         # other volumes are kept active
 215     }
 216 }
 217
 218 sub clone_image {
 219     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 220
 221     my $vg = $scfg->{vgname};
 222
 223     my $lv;
 224
 225     if ($snap) {
 226         $lv = "$vg/snap_${volname}_$snap";
 227     } else {
 228         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
 229             $class->parse_volname($volname);
 230
 231         die "clone_image only works on base images\n" if !$isBase;
 232
 233         $lv = "$vg/$volname";
 234     }
 235
 236     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 237
 238     my $name =  PVE::Storage::LVMPlugin::lvm_find_free_diskname($lvs, $vg, $storeid, $vmid);
 239
 240     my $cmd = ['/sbin/lvcreate', '-n', $name, '-prw', '-kn', '-s', $lv];
 241     run_command($cmd, errmsg => "clone image '$lv' error");
 242
 243     return $name;
 244 }
 245
 246 sub create_base {
 247     my ($class, $storeid, $scfg, $volname) = @_;
 248
 249     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 250         $class->parse_volname($volname);
 251
 252     die "create_base not possible with base image\n" if $isBase;
 253
 254     my $vg = $scfg->{vgname};
 255     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 256
 257     if (my $dat = $lvs->{$vg}) {
 258         # to avoid confusion, reject if we find volume snapshots
 259         foreach my $lv (keys %$dat) {
 260             die "unable to create base volume - found snaphost '$lv'\n"
 261                 if $lv =~ m/^snap_${volname}_(\w+)$/;
 262         }
 263     }
 264
 265     my $newname = $name;
 266     $newname =~ s/^vm-/base-/;
 267
 268     my $cmd = ['/sbin/lvrename', $vg, $volname, $newname];
 269     run_command($cmd, errmsg => "lvrename '$vg/$volname' => '$vg/$newname' error");
 270
 271     # set inactive, read-only and activationskip flags
 272     $cmd = ['/sbin/lvchange', '-an', '-pr', '-ky', "$vg/$newname"];
 273     eval { run_command($cmd); };
 274     warn $@ if $@;
 275
 276     my $newvolname = $newname;
 277
 278     return $newvolname;
 279 }
 280
 281 # sub volume_resize {} reuse code from parent class
 282
 283 sub volume_snapshot {
 284     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 285
 286     my $vg = $scfg->{vgname};
 287     my $snapvol = "snap_${volname}_$snap";
 288
 289     my $cmd = ['/sbin/lvcreate', '-n', $snapvol, '-pr', '-s', "$vg/$volname"];
 290     run_command($cmd, errmsg => "lvcreate snapshot '$vg/$snapvol' error");
 291
 292 }
 293
 294 sub volume_snapshot_rollback {
 295     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 296
 297     my $vg = $scfg->{vgname};
 298     my $snapvol = "snap_${volname}_$snap";
 299
 300     my $cmd = ['/sbin/lvremove', '-f', "$vg/$volname"];
 301     run_command($cmd, errmsg => "lvremove '$vg/$volname' error");
 302
 303     $cmd = ['/sbin/lvcreate', '-kn', '-n', $volname, '-s', "$vg/$snapvol"];
 304     run_command($cmd, errmsg => "lvm rollback '$vg/$snapvol' error");
 305 }
 306
 307 sub volume_snapshot_delete {
 308     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 309
 310     my $vg = $scfg->{vgname};
 311     my $snapvol = "snap_${volname}_$snap";
 312
 313     my $cmd = ['/sbin/lvremove', '-f', "$vg/$snapvol"];
 314     run_command($cmd, errmsg => "lvremove snapshot '$vg/$snapvol' error");
 315 }
 316
 317 sub volume_has_feature {
 318     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 319
 320     my $features = {
 321         snapshot => { current => 1 },
 322         clone => { base => 1, snap => 1},
 323         template => { current => 1},
 324         copy => { base => 1, current => 1, snap => 1},
 325     };
 326
 327     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 328         $class->parse_volname($volname);
 329
 330     my $key = undef;
 331     if($snapname){
 332         $key = 'snap';
 333     }else{
 334         $key =  $isBase ? 'base' : 'current';
 335     }
 336     return 1 if $features->{$feature}->{$key};
 337
 338     return undef;
 339 }
 340
 341 1;