PVE/Storage/LvmThinPlugin.pm

   1 package PVE::Storage::LvmThinPlugin;
   2
   3 use strict;
   4 use warnings;
   5
   6 use IO::File;
   7
   8 use PVE::Tools qw(run_command trim);
   9 use PVE::Storage::Plugin;
  10 use PVE::Storage::LVMPlugin;
  11 use PVE::JSONSchema qw(get_standard_option);
  12
  13 # see: man lvmthin
  14 # lvcreate -n ThinDataLV -L LargeSize VG
  15 # lvconvert --type thin-pool VG/ThinDataLV
  16 # lvcreate -n pvepool -L 20G pve
  17 # lvconvert --type thin-pool pve/pvepool
  18
  19 # NOTE: volumes which were created as linked clones of another base volume
  20 # are currently not tracking this relationship in their volume IDs. this is
  21 # generally not a problem, as LVM thin allows deletion of such base volumes
  22 # without affecting the linked clones. this leads to increased disk usage
  23 # when migrating LVM-thin volumes, which is normally prevented for linked clones.
  24
  25 use base qw(PVE::Storage::LVMPlugin);
  26
  27 sub type {
  28     return 'lvmthin';
  29 }
  30
  31 sub plugindata {
  32     return {
  33         content => [ {images => 1, rootdir => 1}, { images => 1, rootdir => 1}],
  34     };
  35 }
  36
  37 sub properties {
  38     return {
  39         thinpool => {
  40             description => "LVM thin pool LV name.",
  41             type => 'string', format => 'pve-storage-vgname',
  42         },
  43     };
  44 }
  45
  46 sub options {
  47     return {
  48         thinpool => { fixed => 1 },
  49         vgname => { fixed => 1 },
  50         nodes => { optional => 1 },
  51         disable => { optional => 1 },
  52         content => { optional => 1 },
  53         bwlimit => { optional => 1 },
  54     };
  55 }
  56
  57 # NOTE: the fourth and fifth element of the returned array are always
  58 # undef, even if the volume is a linked clone of another volume. see note
  59 # at beginning of file.
  60 sub parse_volname {
  61     my ($class, $volname) = @_;
  62
  63     PVE::Storage::Plugin::parse_lvm_name($volname);
  64
  65     if ($volname =~ m/^((vm|base)-(\d+)-\S+)$/) {
  66         return ('images', $1, $3, undef, undef, $2 eq 'base', 'raw');
  67     }
  68
  69     die "unable to parse lvm volume name '$volname'\n";
  70 }
  71
  72 sub filesystem_path {
  73     my ($class, $scfg, $volname, $snapname) = @_;
  74
  75     my ($vtype, $name, $vmid) = $class->parse_volname($volname);
  76
  77     my $vg = $scfg->{vgname};
  78
  79     my $path = defined($snapname) ? "/dev/$vg/snap_${name}_$snapname": "/dev/$vg/$name";
  80
  81     return wantarray ? ($path, $vmid, $vtype) : $path;
  82 }
  83
  84 sub alloc_image {
  85     my ($class, $storeid, $scfg, $vmid, $fmt, $name, $size) = @_;
  86
  87     die "unsupported format '$fmt'" if $fmt ne 'raw';
  88
  89     die "illegal name '$name' - should be 'vm-$vmid-*'\n"
  90         if  $name && $name !~ m/^vm-$vmid-/;
  91
  92     my $vgs = PVE::Storage::LVMPlugin::lvm_vgs();
  93
  94     my $vg = $scfg->{vgname};
  95
  96     die "no such volume group '$vg'\n" if !defined ($vgs->{$vg});
  97
  98     $name = $class->find_free_diskname($storeid, $scfg, $vmid)
  99         if !$name;
 100
 101     my $cmd = ['/sbin/lvcreate', '-aly', '-V', "${size}k", '--name', $name,
 102                '--thinpool', "$vg/$scfg->{thinpool}" ];
 103
 104     run_command($cmd, errmsg => "lvcreate '$vg/$name' error");
 105
 106     return $name;
 107 }
 108
 109 sub free_image {
 110     my ($class, $storeid, $scfg, $volname, $isBase) = @_;
 111
 112     my $vg = $scfg->{vgname};
 113
 114     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 115
 116     if (my $dat = $lvs->{$scfg->{vgname}}) {
 117
 118         # remove all volume snapshots first
 119         foreach my $lv (keys %$dat) {
 120             next if $lv !~ m/^snap_${volname}_${PVE::JSONSchema::CONFIGID_RE}$/;
 121             my $cmd = ['/sbin/lvremove', '-f', "$vg/$lv"];
 122             run_command($cmd, errmsg => "lvremove snapshot '$vg/$lv' error");
 123         }
 124
 125         # finally remove original (if exists)
 126         if ($dat->{$volname}) {
 127             my $cmd = ['/sbin/lvremove', '-f', "$vg/$volname"];
 128             run_command($cmd, errmsg => "lvremove '$vg/$volname' error");
 129         }
 130     }
 131
 132     return undef;
 133 }
 134
 135 sub list_images {
 136     my ($class, $storeid, $scfg, $vmid, $vollist, $cache) = @_;
 137
 138     my $vgname = $scfg->{vgname};
 139
 140     $cache->{lvs} = PVE::Storage::LVMPlugin::lvm_list_volumes() if !$cache->{lvs};
 141
 142     my $res = [];
 143
 144     if (my $dat = $cache->{lvs}->{$vgname}) {
 145
 146         foreach my $volname (keys %$dat) {
 147
 148             next if $volname !~ m/^(vm|base)-(\d+)-/;
 149             my $owner = $2;
 150
 151             my $info = $dat->{$volname};
 152
 153             next if $info->{lv_type} ne 'V';
 154
 155             next if $info->{pool_lv} ne $scfg->{thinpool};
 156
 157             my $volid = "$storeid:$volname";
 158
 159             if ($vollist) {
 160                 my $found = grep { $_ eq $volid } @$vollist;
 161                 next if !$found;
 162             } else {
 163                 next if defined($vmid) && ($owner ne $vmid);
 164             }
 165
 166             push @$res, {
 167                 volid => $volid, format => 'raw', size => $info->{lv_size}, vmid => $owner,
 168                 ctime => $info->{ctime},
 169             };
 170         }
 171     }
 172
 173     return $res;
 174 }
 175
 176 sub list_thinpools {
 177     my ($vg) = @_;
 178
 179     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 180     my $thinpools = [];
 181
 182     foreach my $vg (keys %$lvs) {
 183         foreach my $lvname (keys %{$lvs->{$vg}}) {
 184             next if $lvs->{$vg}->{$lvname}->{lv_type} ne 't';
 185             my $lv = $lvs->{$vg}->{$lvname};
 186             $lv->{lv} = $lvname;
 187             $lv->{vg} = $vg;
 188             push @$thinpools, $lv;
 189         }
 190     }
 191
 192     return $thinpools;
 193 }
 194
 195 sub status {
 196     my ($class, $storeid, $scfg, $cache) = @_;
 197
 198     my $lvs = $cache->{lvs} ||= PVE::Storage::LVMPlugin::lvm_list_volumes();
 199
 200     return if !$lvs->{$scfg->{vgname}};
 201
 202     my $info = $lvs->{$scfg->{vgname}}->{$scfg->{thinpool}};
 203
 204     return if !$info || $info->{lv_type} ne 't' || !$info->{lv_size};
 205
 206     return ($info->{lv_size}, $info->{lv_size} - $info->{used}, $info->{used}, 1);
 207 }
 208
 209 sub activate_volume {
 210     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 211
 212     my $vg = $scfg->{vgname};
 213
 214     # only snapshot volumes needs activation
 215     if ($snapname) {
 216         my $snapvol = "snap_${volname}_$snapname";
 217         my $cmd = ['/sbin/lvchange', '-ay', '-K', "$vg/$snapvol"];
 218         run_command($cmd, errmsg => "activate_volume '$vg/$snapvol' error");
 219     } elsif ($volname =~ /^base-/) {
 220         my $cmd = ['/sbin/lvchange', '-ay', '-K', "$vg/$volname"];
 221         run_command($cmd, errmsg => "activate_volume '$vg/$volname' error");
 222     } else {
 223         # other volumes are active by default
 224     }
 225 }
 226
 227 sub deactivate_volume {
 228     my ($class, $storeid, $scfg, $volname, $snapname, $cache) = @_;
 229
 230     my $vg = $scfg->{vgname};
 231
 232     # we only deactivate snapshot volumes
 233     if ($snapname) {
 234         my $snapvol = "snap_${volname}_$snapname";
 235         my $cmd = ['/sbin/lvchange', '-an', "$vg/$snapvol"];
 236         run_command($cmd, errmsg => "deactivate_volume '$vg/$snapvol' error");
 237     } elsif ($volname =~ /^base-/) {
 238         my $cmd = ['/sbin/lvchange', '-an', "$vg/$volname"];
 239         run_command($cmd, errmsg => "deactivate_volume '$vg/$volname' error");
 240     } else {
 241         # other volumes are kept active
 242     }
 243 }
 244
 245 sub clone_image {
 246     my ($class, $scfg, $storeid, $volname, $vmid, $snap) = @_;
 247
 248     my $vg = $scfg->{vgname};
 249
 250     my $lv;
 251
 252     if ($snap) {
 253         $lv = "$vg/snap_${volname}_$snap";
 254     } else {
 255         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
 256             $class->parse_volname($volname);
 257
 258         die "clone_image only works on base images\n" if !$isBase;
 259
 260         $lv = "$vg/$volname";
 261     }
 262
 263     my $name = $class->find_free_diskname($storeid, $scfg, $vmid);
 264
 265     my $cmd = ['/sbin/lvcreate', '-n', $name, '-prw', '-kn', '-s', $lv];
 266     run_command($cmd, errmsg => "clone image '$lv' error");
 267
 268     return $name;
 269 }
 270
 271 sub create_base {
 272     my ($class, $storeid, $scfg, $volname) = @_;
 273
 274     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 275         $class->parse_volname($volname);
 276
 277     die "create_base not possible with base image\n" if $isBase;
 278
 279     my $vg = $scfg->{vgname};
 280     my $lvs = PVE::Storage::LVMPlugin::lvm_list_volumes($vg);
 281
 282     if (my $dat = $lvs->{$vg}) {
 283         # to avoid confusion, reject if we find volume snapshots
 284         foreach my $lv (keys %$dat) {
 285             die "unable to create base volume - found snaphost '$lv'\n"
 286                 if $lv =~ m/^snap_${volname}_(\w+)$/;
 287         }
 288     }
 289
 290     my $newname = $name;
 291     $newname =~ s/^vm-/base-/;
 292
 293     my $cmd = ['/sbin/lvrename', $vg, $volname, $newname];
 294     run_command($cmd, errmsg => "lvrename '$vg/$volname' => '$vg/$newname' error");
 295
 296     # set inactive, read-only and activationskip flags
 297     $cmd = ['/sbin/lvchange', '-an', '-pr', '-ky', "$vg/$newname"];
 298     eval { run_command($cmd); };
 299     warn $@ if $@;
 300
 301     my $newvolname = $newname;
 302
 303     return $newvolname;
 304 }
 305
 306 # sub volume_resize {} reuse code from parent class
 307
 308 sub volume_snapshot {
 309     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 310
 311     my $vg = $scfg->{vgname};
 312     my $snapvol = "snap_${volname}_$snap";
 313
 314     my $cmd = ['/sbin/lvcreate', '-n', $snapvol, '-pr', '-s', "$vg/$volname"];
 315     run_command($cmd, errmsg => "lvcreate snapshot '$vg/$snapvol' error");
 316
 317 }
 318
 319 sub volume_snapshot_rollback {
 320     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 321
 322     my $vg = $scfg->{vgname};
 323     my $snapvol = "snap_${volname}_$snap";
 324
 325     my $cmd = ['/sbin/lvremove', '-f', "$vg/$volname"];
 326     run_command($cmd, errmsg => "lvremove '$vg/$volname' error");
 327
 328     $cmd = ['/sbin/lvcreate', '-kn', '-n', $volname, '-s', "$vg/$snapvol"];
 329     run_command($cmd, errmsg => "lvm rollback '$vg/$snapvol' error");
 330 }
 331
 332 sub volume_snapshot_delete {
 333     my ($class, $scfg, $storeid, $volname, $snap) = @_;
 334
 335     my $vg = $scfg->{vgname};
 336     my $snapvol = "snap_${volname}_$snap";
 337
 338     my $cmd = ['/sbin/lvremove', '-f', "$vg/$snapvol"];
 339     run_command($cmd, errmsg => "lvremove snapshot '$vg/$snapvol' error");
 340 }
 341
 342 sub volume_has_feature {
 343     my ($class, $scfg, $feature, $storeid, $volname, $snapname, $running) = @_;
 344
 345     my $features = {
 346         snapshot => { current => 1 },
 347         clone => { base => 1, snap => 1},
 348         template => { current => 1},
 349         copy => { base => 1, current => 1, snap => 1},
 350         sparseinit => { base => 1, current => 1},
 351         rename => {current => 1},
 352     };
 353
 354     my ($vtype, $name, $vmid, $basename, $basevmid, $isBase) =
 355         $class->parse_volname($volname);
 356
 357     my $key = undef;
 358     if($snapname){
 359         $key = 'snap';
 360     }else{
 361         $key =  $isBase ? 'base' : 'current';
 362     }
 363     return 1 if $features->{$feature}->{$key};
 364
 365     return undef;
 366 }
 367
 368 # used in LVMPlugin->volume_import
 369 sub volume_import_write {
 370     my ($class, $input_fh, $output_file) = @_;
 371     run_command(['dd', "of=$output_file", 'conv=sparse', 'bs=64k'],
 372         input => '<&'.fileno($input_fh));
 373 }
 374
 375 1;